lisp/desktop.el

   1 ;;; desktop.el --- save partial status of Emacs when killed
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Morten Welinder <terra@diku.dk>
   7 ;; Keywords: convenience
   8 ;; Favourite-brand-of-beer: None, I hate beer.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Save the Desktop, i.e.,
  30 ;;      - some global variables
  31 ;;      - the list of buffers with associated files.  For each buffer also
  32 ;;              - the major mode
  33 ;;              - the default directory
  34 ;;              - the point
  35 ;;              - the mark & mark-active
  36 ;;              - buffer-read-only
  37 ;;              - some local variables
  38
  39 ;; To use this, use customize to turn on desktop-save-mode or add the
  40 ;; following line somewhere in your .emacs file:
  41 ;;
  42 ;;      (desktop-save-mode 1)
  43 ;;
  44 ;; For further usage information, look at the section
  45 ;; "Saving Emacs Sessions" in the GNU Emacs Manual.
  46
  47 ;; When the desktop module is loaded, the function `desktop-kill' is
  48 ;; added to the `kill-emacs-hook'.  This function is responsible for
  49 ;; saving the desktop when Emacs is killed.  Furthermore an anonymous
  50 ;; function is added to the `after-init-hook'.  This function is
  51 ;; responsible for loading the desktop when Emacs is started.
  52
  53 ;; Special handling.
  54 ;; -----------------
  55 ;; Variables `desktop-buffer-mode-handlers' and `desktop-minor-mode-handlers'
  56 ;; are supplied to handle special major and minor modes respectively.
  57 ;; `desktop-buffer-mode-handlers' is an alist of major mode specific functions
  58 ;; to restore a desktop buffer.  Elements must have the form
  59 ;;
  60 ;;    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
  61 ;;
  62 ;; Functions listed are called by `desktop-create-buffer' when `desktop-read'
  63 ;; evaluates the desktop file.  Buffers with a major mode not specified here,
  64 ;; are restored by the default handler `desktop-restore-file-buffer'.
  65 ;; `desktop-minor-mode-handlers' is an alist of functions to restore
  66 ;; non-standard minor modes.  Elements must have the form
  67 ;;
  68 ;;    (MINOR-MODE . RESTORE-FUNCTION).
  69 ;;
  70 ;; Functions are called by `desktop-create-buffer' to restore minor modes.
  71 ;; Minor modes not specified here, are restored by the standard minor mode
  72 ;; function.  If you write a module that defines a major or minor mode that
  73 ;; needs a special handler, then place code like
  74
  75 ;;    (defun foo-restore-desktop-buffer
  76 ;;    ...
  77 ;;    (add-to-list 'desktop-buffer-mode-handlers
  78 ;;                 '(foo-mode . foo-restore-desktop-buffer))
  79
  80 ;; or
  81
  82 ;;    (defun bar-desktop-restore
  83 ;;    ...
  84 ;;    (add-to-list 'desktop-minor-mode-handlers
  85 ;;                 '(bar-mode . bar-desktop-restore))
  86
  87 ;; in the module itself, and make shure that the mode function is
  88 ;; autoloaded.  See the docstrings of `desktop-buffer-mode-handlers' and
  89 ;; `desktop-minor-mode-handlers' for more info.
  90
  91 ;; Minor modes.
  92 ;; ------------
  93 ;; Conventional minor modes (see node "Minor Mode Conventions" in the elisp
  94 ;; manual) are handled in the following way:
  95 ;; When `desktop-save' saves the state of a buffer to the desktop file, it
  96 ;; saves as `desktop-minor-modes' the list of names of those variables in
  97 ;; `minor-mode-alist' that have a non-nil value.
  98 ;; When `desktop-create' restores the buffer, each of the symbols in
  99 ;; `desktop-minor-modes' is called as function with parameter 1.
 100 ;; The variables `desktop-minor-mode-table' and `desktop-minor-mode-handlers'
 101 ;; are used to handle non-conventional minor modes.  `desktop-save' uses
 102 ;; `desktop-minor-mode-table' to map minor mode variables to minor mode
 103 ;; functions before writing `desktop-minor-modes'.  If a minor mode has a
 104 ;; variable name that is different form its function name, an entry
 105
 106 ;;    (NAME RESTORE-FUNCTION)
 107
 108 ;; should be added to `desktop-minor-mode-table'.  If a minor mode should not
 109 ;; be restored, RESTORE-FUNCTION should be set to nil.  `desktop-create' uses
 110 ;; `desktop-minor-mode-handlers' to lookup minor modes that needs a restore
 111 ;; function different from the usual minor mode function.
 112 ;; ---------------------------------------------------------------------------
 113
 114 ;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
 115 ;; in your home directory is used for that.  Saving global default values
 116 ;; for buffers is an example of misuse.
 117
 118 ;; PLEASE NOTE: The kill ring can be saved as specified by the variable
 119 ;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
 120 ;; things you did not mean to keep.  Use M-x desktop-clear RET.
 121
 122 ;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
 123 ;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
 124 ;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
 125 ;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
 126 ;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
 127 ;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
 128 ;;            pot@cnuce.cnr.it (Francesco Potorti`)  for misc. tips.
 129 ;; ---------------------------------------------------------------------------
 130 ;; TODO:
 131 ;;
 132 ;; Save window configuration.
 133 ;; Recognize more minor modes.
 134 ;; Save mark rings.
 135
 136 ;;; Code:
 137
 138 (defvar uniquify-managed)
 139
 140 (defvar desktop-file-version "206"
 141   "Version number of desktop file format.
 142 Written into the desktop file and used at desktop read to provide
 143 backward compatibility.")
 144
 145 ;; ----------------------------------------------------------------------------
 146 ;; USER OPTIONS -- settings you might want to play with.
 147 ;; ----------------------------------------------------------------------------
 148
 149 (defgroup desktop nil
 150   "Save status of Emacs when you exit."
 151   :group 'frames)
 152
 153 ;;;###autoload
 154 (define-minor-mode desktop-save-mode
 155   "Toggle desktop saving mode.
 156 With numeric ARG, turn desktop saving on if ARG is positive, off
 157 otherwise.  If desktop saving is turned on, the state of Emacs is
 158 saved from one session to another.  See variable `desktop-save'
 159 and function `desktop-read' for details."
 160   :global t
 161   :group 'desktop)
 162
 163 ;; Maintained for backward compatibility
 164 (define-obsolete-variable-alias 'desktop-enable
 165                                 'desktop-save-mode "22.1")
 166
 167 (defun desktop-save-mode-off ()
 168   "Disable `desktop-save-mode'.  Provided for use in hooks."
 169   (desktop-save-mode 0))
 170
 171 (defcustom desktop-save 'ask-if-new
 172   "*Specifies whether the desktop should be saved when it is killed.
 173 A desktop is killed when the user changes desktop or quits Emacs.
 174 Possible values are:
 175    t             -- always save.
 176    ask           -- always ask.
 177    ask-if-new    -- ask if no desktop file exists, otherwise just save.
 178    ask-if-exists -- ask if desktop file exists, otherwise don't save.
 179    if-exists     -- save if desktop file exists, otherwise don't save.
 180    nil           -- never save.
 181 The desktop is never saved when `desktop-save-mode' is nil.
 182 The variables `desktop-dirname' and `desktop-base-file-name'
 183 determine where the desktop is saved."
 184   :type
 185   '(choice
 186     (const :tag "Always save" t)
 187     (const :tag "Always ask" ask)
 188     (const :tag "Ask if desktop file is new, else do save" ask-if-new)
 189     (const :tag "Ask if desktop file exists, else don't save" ask-if-exists)
 190     (const :tag "Save if desktop file exists, else don't" if-exists)
 191     (const :tag "Never save" nil))
 192   :group 'desktop
 193   :version "22.1")
 194
 195 (defcustom desktop-load-locked-desktop 'ask
 196   "Specifies whether the desktop should be loaded if locked.
 197 Possible values are:
 198    t    -- load anyway.
 199    nil  -- don't load.
 200    ask  -- ask the user.
 201 If the value is nil, or `ask' and the user chooses not to load the desktop,
 202 the normal hook `desktop-not-loaded-hook' is run."
 203   :type
 204   '(choice
 205     (const :tag "Load anyway" t)
 206     (const :tag "Don't load" nil)
 207     (const :tag "Ask the user" ask))
 208   :group 'desktop
 209   :version "22.2")
 210
 211 (defcustom desktop-base-file-name
 212   (convert-standard-filename ".emacs.desktop")
 213   "Name of file for Emacs desktop, excluding the directory part."
 214   :type 'file
 215   :group 'desktop)
 216 (define-obsolete-variable-alias 'desktop-basefilename
 217                                 'desktop-base-file-name "22.1")
 218
 219 (defcustom desktop-base-lock-name
 220   (convert-standard-filename ".emacs.desktop.lock")
 221   "Name of lock file for Emacs desktop, excluding the directory part."
 222   :type 'file
 223   :group 'desktop
 224   :version "22.2")
 225
 226 (defcustom desktop-path '("." "~")
 227   "List of directories to search for the desktop file.
 228 The base name of the file is specified in `desktop-base-file-name'."
 229   :type '(repeat directory)
 230   :group 'desktop
 231   :version "22.1")
 232
 233 (defcustom desktop-missing-file-warning nil
 234   "If non-nil, offer to recreate the buffer of a deleted file.
 235 Also pause for a moment to display message about errors signaled in
 236 `desktop-buffer-mode-handlers'.
 237
 238 If nil, just print error messages in the message buffer."
 239   :type 'boolean
 240   :group 'desktop
 241   :version "22.1")
 242
 243 (defcustom desktop-no-desktop-file-hook nil
 244   "Normal hook run when `desktop-read' can't find a desktop file.
 245 Run in the directory in which the desktop file was sought.
 246 May be used to show a dired buffer."
 247   :type 'hook
 248   :group 'desktop
 249   :version "22.1")
 250
 251 (defcustom desktop-not-loaded-hook nil
 252   "Normal hook run when the user declines to re-use a desktop file.
 253 Run in the directory in which the desktop file was found.
 254 May be used to deal with accidental multiple Emacs jobs."
 255   :type 'hook
 256   :group 'desktop
 257   :options '(desktop-save-mode-off save-buffers-kill-emacs)
 258   :version "22.2")
 259
 260 (defcustom desktop-after-read-hook nil
 261   "Normal hook run after a successful `desktop-read'.
 262 May be used to show a buffer list."
 263   :type 'hook
 264   :group 'desktop
 265   :options '(list-buffers)
 266   :version "22.1")
 267
 268 (defcustom desktop-save-hook nil
 269   "Normal hook run before the desktop is saved in a desktop file.
 270 Run with the desktop buffer current with only the header present.
 271 May be used to add to the desktop code or to truncate history lists,
 272 for example."
 273   :type 'hook
 274   :group 'desktop)
 275
 276 (defcustom desktop-globals-to-save
 277   '(desktop-missing-file-warning
 278     tags-file-name
 279     tags-table-list
 280     search-ring
 281     regexp-search-ring
 282     register-alist)
 283   "List of global variables saved by `desktop-save'.
 284 An element may be variable name (a symbol) or a cons cell of the form
 285 \(VAR . MAX-SIZE), which means to truncate VAR's value to at most
 286 MAX-SIZE elements (if the value is a list) before saving the value.
 287 Feature: Saving `kill-ring' implies saving `kill-ring-yank-pointer'."
 288   :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
 289   :group 'desktop)
 290
 291 (defcustom desktop-globals-to-clear
 292   '(kill-ring
 293     kill-ring-yank-pointer
 294     search-ring
 295     search-ring-yank-pointer
 296     regexp-search-ring
 297     regexp-search-ring-yank-pointer)
 298   "List of global variables that `desktop-clear' will clear.
 299 An element may be variable name (a symbol) or a cons cell of the form
 300 \(VAR . FORM).  Symbols are set to nil and for cons cells VAR is set
 301 to the value obtained by evaluating FORM."
 302   :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
 303   :group 'desktop
 304   :version "22.1")
 305
 306 (defcustom desktop-clear-preserve-buffers
 307   '("\\*scratch\\*" "\\*Messages\\*" "\\*server\\*" "\\*tramp/.+\\*")
 308   "*List of buffers that `desktop-clear' should not delete.
 309 Each element is a regular expression.  Buffers with a name matched by any of
 310 these won't be deleted."
 311   :type '(repeat string)
 312   :group 'desktop)
 313
 314 ;;;###autoload
 315 (defcustom desktop-locals-to-save
 316   '(desktop-locals-to-save  ; Itself!  Think it over.
 317     truncate-lines
 318     case-fold-search
 319     case-replace
 320     fill-column
 321     overwrite-mode
 322     change-log-default-name
 323     line-number-mode
 324     column-number-mode
 325     size-indication-mode
 326     buffer-file-coding-system
 327     indent-tabs-mode
 328     tab-width
 329     indicate-buffer-boundaries
 330     indicate-empty-lines
 331     show-trailing-whitespace)
 332   "List of local variables to save for each buffer.
 333 The variables are saved only when they really are local.  Conventional minor
 334 modes are restored automatically; they should not be listed here."
 335   :type '(repeat symbol)
 336   :group 'desktop)
 337
 338 ;; We skip .log files because they are normally temporary.
 339 ;;         (ftp) files because they require passwords and whatnot.
 340 (defcustom desktop-buffers-not-to-save
 341   "\\(^nn\\.a[0-9]+\\|\\.log\\|(ftp)\\)$"
 342   "Regexp identifying buffers that are to be excluded from saving."
 343   :type 'regexp
 344   :group 'desktop)
 345
 346 ;; Skip tramp and ange-ftp files
 347 (defcustom desktop-files-not-to-save
 348   "^/[^/:]*:"
 349   "Regexp identifying files whose buffers are to be excluded from saving."
 350   :type 'regexp
 351   :group 'desktop)
 352
 353 ;; We skip TAGS files to save time (tags-file-name is saved instead).
 354 (defcustom desktop-modes-not-to-save
 355   '(tags-table-mode)
 356   "List of major modes whose buffers should not be saved."
 357   :type '(repeat symbol)
 358   :group 'desktop)
 359
 360 (defcustom desktop-file-name-format 'absolute
 361   "*Format in which desktop file names should be saved.
 362 Possible values are:
 363    absolute -- Absolute file name.
 364    tilde    -- Relative to ~.
 365    local    -- Relative to directory of desktop file."
 366   :type '(choice (const absolute) (const tilde) (const local))
 367   :group 'desktop
 368   :version "22.1")
 369
 370 (defcustom desktop-restore-eager t
 371   "Number of buffers to restore immediately.
 372 Remaining buffers are restored lazily (when Emacs is idle).
 373 If value is t, all buffers are restored immediately."
 374   :type '(choice (const t) integer)
 375   :group 'desktop
 376   :version "22.1")
 377
 378 (defcustom desktop-lazy-verbose t
 379   "Verbose reporting of lazily created buffers."
 380   :type 'boolean
 381   :group 'desktop
 382   :version "22.1")
 383
 384 (defcustom desktop-lazy-idle-delay 5
 385   "Idle delay before starting to create buffers.
 386 See `desktop-restore-eager'."
 387   :type 'integer
 388   :group 'desktop
 389   :version "22.1")
 390
 391 ;;;###autoload
 392 (defvar desktop-save-buffer nil
 393   "When non-nil, save buffer status in desktop file.
 394 This variable becomes buffer local when set.
 395
 396 If the value is a function, it is called by `desktop-save' with argument
 397 DESKTOP-DIRNAME to obtain auxiliary information to save in the desktop
 398 file along with the state of the buffer for which it was called.
 399
 400 When file names are returned, they should be formatted using the call
 401 \"(desktop-file-name FILE-NAME DESKTOP-DIRNAME)\".
 402
 403 Later, when `desktop-read' evaluates the desktop file, auxiliary information
 404 is passed as the argument DESKTOP-BUFFER-MISC to functions in
 405 `desktop-buffer-mode-handlers'.")
 406 (make-variable-buffer-local 'desktop-save-buffer)
 407 (make-obsolete-variable 'desktop-buffer-modes-to-save
 408                         'desktop-save-buffer "22.1")
 409 (make-obsolete-variable 'desktop-buffer-misc-functions
 410                         'desktop-save-buffer "22.1")
 411
 412 ;;;###autoload
 413 (defvar desktop-buffer-mode-handlers
 414   nil
 415   "Alist of major mode specific functions to restore a desktop buffer.
 416 Functions listed are called by `desktop-create-buffer' when `desktop-read'
 417 evaluates the desktop file.  List elements must have the form
 418
 419    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
 420
 421 Buffers with a major mode not specified here, are restored by the default
 422 handler `desktop-restore-file-buffer'.
 423
 424 Handlers are called with argument list
 425
 426    (DESKTOP-BUFFER-FILE-NAME DESKTOP-BUFFER-NAME DESKTOP-BUFFER-MISC)
 427
 428 Furthermore, they may use the following variables:
 429
 430    desktop-file-version
 431    desktop-buffer-major-mode
 432    desktop-buffer-minor-modes
 433    desktop-buffer-point
 434    desktop-buffer-mark
 435    desktop-buffer-read-only
 436    desktop-buffer-locals
 437
 438 If a handler returns a buffer, then the saved mode settings
 439 and variable values for that buffer are copied into it.
 440
 441 Modules that define a major mode that needs a special handler should contain
 442 code like
 443
 444    (defun foo-restore-desktop-buffer
 445    ...
 446    (add-to-list 'desktop-buffer-mode-handlers
 447                 '(foo-mode . foo-restore-desktop-buffer))
 448
 449 Furthermore the major mode function must be autoloaded.")
 450
 451 ;;;###autoload
 452 (put 'desktop-buffer-mode-handlers 'risky-local-variable t)
 453 (make-obsolete-variable 'desktop-buffer-handlers
 454                         'desktop-buffer-mode-handlers "22.1")
 455
 456 (defcustom desktop-minor-mode-table
 457   '((auto-fill-function auto-fill-mode)
 458     (vc-mode nil)
 459     (vc-dired-mode nil)
 460     (erc-track-minor-mode nil))
 461   "Table mapping minor mode variables to minor mode functions.
 462 Each entry has the form (NAME RESTORE-FUNCTION).
 463 NAME is the name of the buffer-local variable indicating that the minor
 464 mode is active.  RESTORE-FUNCTION is the function to activate the minor mode.
 465 RESTORE-FUNCTION nil means don't try to restore the minor mode.
 466 Only minor modes for which the name of the buffer-local variable
 467 and the name of the minor mode function are different have to be added to
 468 this table.  See also `desktop-minor-mode-handlers'."
 469   :type 'sexp
 470   :group 'desktop)
 471
 472 ;;;###autoload
 473 (defvar desktop-minor-mode-handlers
 474   nil
 475   "Alist of functions to restore non-standard minor modes.
 476 Functions are called by `desktop-create-buffer' to restore minor modes.
 477 List elements must have the form
 478
 479    (MINOR-MODE . RESTORE-FUNCTION).
 480
 481 Minor modes not specified here, are restored by the standard minor mode
 482 function.
 483
 484 Handlers are called with argument list
 485
 486    (DESKTOP-BUFFER-LOCALS)
 487
 488 Furthermore, they may use the following variables:
 489
 490    desktop-file-version
 491    desktop-buffer-file-name
 492    desktop-buffer-name
 493    desktop-buffer-major-mode
 494    desktop-buffer-minor-modes
 495    desktop-buffer-point
 496    desktop-buffer-mark
 497    desktop-buffer-read-only
 498    desktop-buffer-misc
 499
 500 When a handler is called, the buffer has been created and the major mode has
 501 been set, but local variables listed in desktop-buffer-locals has not yet been
 502 created and set.
 503
 504 Modules that define a minor mode that needs a special handler should contain
 505 code like
 506
 507    (defun foo-desktop-restore
 508    ...
 509    (add-to-list 'desktop-minor-mode-handlers
 510                 '(foo-mode . foo-desktop-restore))
 511
 512 Furthermore the minor mode function must be autoloaded.
 513
 514 See also `desktop-minor-mode-table'.")
 515
 516 ;;;###autoload
 517 (put 'desktop-minor-mode-handlers 'risky-local-variable t)
 518
 519 ;; ----------------------------------------------------------------------------
 520 (defvar desktop-dirname nil
 521   "The directory in which the desktop file should be saved.")
 522
 523 (defun desktop-full-file-name (&optional dirname)
 524   "Return the full name of the desktop file in DIRNAME.
 525 DIRNAME omitted or nil means use `desktop-dirname'."
 526   (expand-file-name desktop-base-file-name (or dirname desktop-dirname)))
 527
 528 (defun desktop-full-lock-name (&optional dirname)
 529   "Return the full name of the desktop lock file in DIRNAME.
 530 DIRNAME omitted or nil means use `desktop-dirname'."
 531   (expand-file-name desktop-base-lock-name (or dirname desktop-dirname)))
 532
 533 (defconst desktop-header
 534 ";; --------------------------------------------------------------------------
 535 ;; Desktop File for Emacs
 536 ;; --------------------------------------------------------------------------
 537 " "*Header to place in Desktop file.")
 538
 539 (defvar desktop-delay-hook nil
 540   "Hooks run after all buffers are loaded; intended for internal use.")
 541
 542 ;; ----------------------------------------------------------------------------
 543 ;; Desktop file conflict detection
 544 (defvar desktop-file-modtime nil
 545   "When the desktop file was last modified to the knowledge of this Emacs.
 546 Used to detect desktop file conflicts.")
 547
 548 (defun desktop-owner (&optional dirname)
 549   "Return the PID of the Emacs process that owns the desktop file in DIRNAME.
 550 Return nil if no desktop file found or no Emacs process is using it.
 551 DIRNAME omitted or nil means use `desktop-dirname'."
 552   (let (owner)
 553     (and (file-exists-p (desktop-full-lock-name dirname))
 554          (condition-case nil
 555              (with-temp-buffer
 556                (insert-file-contents-literally (desktop-full-lock-name dirname))
 557                (goto-char (point-min))
 558                (setq owner (read (current-buffer)))
 559                (integerp owner))
 560            (error nil))
 561          owner)))
 562
 563 (defun desktop-claim-lock (&optional dirname)
 564   "Record this Emacs process as the owner of the desktop file in DIRNAME.
 565 DIRNAME omitted or nil means use `desktop-dirname'."
 566   (write-region (number-to-string (emacs-pid)) nil
 567                 (desktop-full-lock-name dirname)))
 568
 569 (defun desktop-release-lock (&optional dirname)
 570   "Remove the lock file for the desktop in DIRNAME.
 571 DIRNAME omitted or nil means use `desktop-dirname'."
 572   (let ((file (desktop-full-lock-name dirname)))
 573     (when (file-exists-p file) (delete-file file))))
 574
 575 ;; ----------------------------------------------------------------------------
 576 (defun desktop-truncate (list n)
 577   "Truncate LIST to at most N elements destructively."
 578   (let ((here (nthcdr (1- n) list)))
 579     (when (consp here)
 580       (setcdr here nil))))
 581
 582 ;; ----------------------------------------------------------------------------
 583 ;;;###autoload
 584 (defun desktop-clear ()
 585   "Empty the Desktop.
 586 This kills all buffers except for internal ones and those with names matched by
 587 a regular expression in the list `desktop-clear-preserve-buffers'.
 588 Furthermore, it clears the variables listed in `desktop-globals-to-clear'."
 589   (interactive)
 590   (desktop-lazy-abort)
 591   (dolist (var desktop-globals-to-clear)
 592     (if (symbolp var)
 593         (eval `(setq-default ,var nil))
 594       (eval `(setq-default ,(car var) ,(cdr var)))))
 595   (let ((buffers (buffer-list))
 596         (preserve-regexp (concat "^\\("
 597                                  (mapconcat (lambda (regexp)
 598                                               (concat "\\(" regexp "\\)"))
 599                                             desktop-clear-preserve-buffers
 600                                             "\\|")
 601                                  "\\)$")))
 602     (while buffers
 603       (let ((bufname (buffer-name (car buffers))))
 604          (or
 605            (null bufname)
 606            (string-match preserve-regexp bufname)
 607            ;; Don't kill buffers made for internal purposes.
 608            (and (not (equal bufname "")) (eq (aref bufname 0) ?\s))
 609            (kill-buffer (car buffers))))
 610       (setq buffers (cdr buffers))))
 611   (delete-other-windows))
 612
 613 ;; ----------------------------------------------------------------------------
 614 (add-hook 'kill-emacs-hook 'desktop-kill)
 615
 616 (defun desktop-kill ()
 617   "If `desktop-save-mode' is non-nil, do what `desktop-save' says to do.
 618 If the desktop should be saved and `desktop-dirname'
 619 is nil, ask the user where to save the desktop."
 620   (when (and desktop-save-mode
 621              (let ((exists (file-exists-p (desktop-full-file-name))))
 622                (or (eq desktop-save t)
 623                    (and exists (memq desktop-save '(ask-if-new if-exists)))
 624                    (and
 625                     (or (memq desktop-save '(ask ask-if-new))
 626                         (and exists (eq desktop-save 'ask-if-exists)))
 627                     (y-or-n-p "Save desktop? ")))))
 628     (unless desktop-dirname
 629       (setq desktop-dirname
 630             (file-name-as-directory
 631              (expand-file-name
 632               (read-directory-name "Directory for desktop file: " nil nil t)))))
 633     (condition-case err
 634         (desktop-save desktop-dirname t)
 635       (file-error
 636        (unless (yes-or-no-p "Error while saving the desktop.  Ignore? ")
 637          (signal (car err) (cdr err))))))
 638   ;; If we own it, we don't anymore.
 639   (when (eq (emacs-pid) (desktop-owner)) (desktop-release-lock)))
 640
 641 ;; ----------------------------------------------------------------------------
 642 (defun desktop-list* (&rest args)
 643   (if (null (cdr args))
 644       (car args)
 645     (setq args (nreverse args))
 646     (let ((value (cons (nth 1 args) (car args))))
 647       (setq args (cdr (cdr args)))
 648       (while args
 649         (setq value (cons (car args) value))
 650         (setq args (cdr args)))
 651       value)))
 652
 653 ;; ----------------------------------------------------------------------------
 654 (declare-function uniquify-item-base "uniquify" (cl-x) t) ; defstruct
 655
 656 (defun desktop-buffer-info (buffer)
 657   (set-buffer buffer)
 658   (list
 659    ;; basic information
 660    (desktop-file-name (buffer-file-name) desktop-dirname)
 661    (if (bound-and-true-p uniquify-managed)
 662        (uniquify-item-base (car uniquify-managed))
 663      (buffer-name))
 664    major-mode
 665    ;; minor modes
 666    (let (ret)
 667      (mapc
 668       #'(lambda (minor-mode)
 669           (and (boundp minor-mode)
 670                (symbol-value minor-mode)
 671                (let* ((special (assq minor-mode desktop-minor-mode-table))
 672                       (value (cond (special (cadr special))
 673                                    ((functionp minor-mode) minor-mode))))
 674                  (when value (add-to-list 'ret value)))))
 675       (mapcar #'car minor-mode-alist))
 676      ret)
 677    ;; point and mark, and read-only status
 678    (point)
 679    (list (mark t) mark-active)
 680    buffer-read-only
 681    ;; auxiliary information
 682    (when (functionp desktop-save-buffer)
 683      (funcall desktop-save-buffer desktop-dirname))
 684    ;; local variables
 685    (let ((locals desktop-locals-to-save)
 686          (loclist (buffer-local-variables))
 687          (ll))
 688      (while locals
 689        (let ((here (assq (car locals) loclist)))
 690          (if here
 691              (setq ll (cons here ll))
 692            (when (member (car locals) loclist)
 693              (setq ll (cons (car locals) ll)))))
 694        (setq locals (cdr locals)))
 695      ll)))
 696
 697 ;; ----------------------------------------------------------------------------
 698 (defun desktop-internal-v2s (value)
 699   "Convert VALUE to a pair (QUOTE . TXT); (eval (read TXT)) gives VALUE.
 700 TXT is a string that when read and evaluated yields value.
 701 QUOTE may be `may' (value may be quoted),
 702 `must' (values must be quoted), or nil (value may not be quoted)."
 703   (cond
 704     ((or (numberp value) (null value) (eq t value) (keywordp value))
 705      (cons 'may (prin1-to-string value)))
 706     ((stringp value)
 707      (let ((copy (copy-sequence value)))
 708        (set-text-properties 0 (length copy) nil copy)
 709        ;; Get rid of text properties because we cannot read them
 710        (cons 'may (prin1-to-string copy))))
 711     ((symbolp value)
 712      (cons 'must (prin1-to-string value)))
 713     ((vectorp value)
 714      (let* ((special nil)
 715             (pass1 (mapcar
 716                     (lambda (el)
 717                       (let ((res (desktop-internal-v2s el)))
 718                         (if (null (car res))
 719                             (setq special t))
 720                         res))
 721                     value)))
 722        (if special
 723            (cons nil (concat "(vector "
 724                              (mapconcat (lambda (el)
 725                                           (if (eq (car el) 'must)
 726                                               (concat "'" (cdr el))
 727                                             (cdr el)))
 728                                         pass1
 729                                         " ")
 730                              ")"))
 731          (cons 'may (concat "[" (mapconcat 'cdr pass1 " ") "]")))))
 732     ((consp value)
 733      (let ((p value)
 734            newlist
 735            use-list*
 736            anynil)
 737        (while (consp p)
 738          (let ((q.txt (desktop-internal-v2s (car p))))
 739            (or anynil (setq anynil (null (car q.txt))))
 740            (setq newlist (cons q.txt newlist)))
 741          (setq p (cdr p)))
 742        (if p
 743            (let ((last (desktop-internal-v2s p)))
 744              (or anynil (setq anynil (null (car last))))
 745              (or anynil
 746                  (setq newlist (cons '(must . ".") newlist)))
 747              (setq use-list* t)
 748              (setq newlist (cons last newlist))))
 749        (setq newlist (nreverse newlist))
 750        (if anynil
 751            (cons nil
 752                  (concat (if use-list* "(desktop-list* "  "(list ")
 753                          (mapconcat (lambda (el)
 754                                       (if (eq (car el) 'must)
 755                                           (concat "'" (cdr el))
 756                                         (cdr el)))
 757                                     newlist
 758                                     " ")
 759                          ")"))
 760          (cons 'must
 761                (concat "(" (mapconcat 'cdr newlist " ") ")")))))
 762     ((subrp value)
 763      (cons nil (concat "(symbol-function '"
 764                        (substring (prin1-to-string value) 7 -1)
 765                        ")")))
 766     ((markerp value)
 767      (let ((pos (prin1-to-string (marker-position value)))
 768            (buf (prin1-to-string (buffer-name (marker-buffer value)))))
 769        (cons nil (concat "(let ((mk (make-marker)))"
 770                          " (add-hook 'desktop-delay-hook"
 771                          " (list 'lambda '() (list 'set-marker mk "
 772                          pos " (get-buffer " buf ")))) mk)"))))
 773     (t                                   ; save as text
 774      (cons 'may "\"Unprintable entity\""))))
 775
 776 ;; ----------------------------------------------------------------------------
 777 (defun desktop-value-to-string (value)
 778   "Convert VALUE to a string that when read evaluates to the same value.
 779 Not all types of values are supported."
 780   (let* ((print-escape-newlines t)
 781          (float-output-format nil)
 782          (quote.txt (desktop-internal-v2s value))
 783          (quote (car quote.txt))
 784          (txt (cdr quote.txt)))
 785     (if (eq quote 'must)
 786         (concat "'" txt)
 787       txt)))
 788
 789 ;; ----------------------------------------------------------------------------
 790 (defun desktop-outvar (varspec)
 791   "Output a setq statement for variable VAR to the desktop file.
 792 The argument VARSPEC may be the variable name VAR (a symbol),
 793 or a cons cell of the form (VAR . MAX-SIZE),
 794 which means to truncate VAR's value to at most MAX-SIZE elements
 795 \(if the value is a list) before saving the value."
 796   (let (var size)
 797     (if (consp varspec)
 798         (setq var (car varspec) size (cdr varspec))
 799       (setq var varspec))
 800     (when (boundp var)
 801       (when (and (integerp size)
 802                  (> size 0)
 803                  (listp (eval var)))
 804         (desktop-truncate (eval var) size))
 805       (insert "(setq "
 806               (symbol-name var)
 807               " "
 808               (desktop-value-to-string (symbol-value var))
 809               ")\n"))))
 810
 811 ;; ----------------------------------------------------------------------------
 812 (defun desktop-save-buffer-p (filename bufname mode &rest dummy)
 813   "Return t if buffer should have its state saved in the desktop file.
 814 FILENAME is the visited file name, BUFNAME is the buffer name, and
 815 MODE is the major mode.
 816 \n\(fn FILENAME BUFNAME MODE)"
 817   (let ((case-fold-search nil))
 818     (and (not (string-match desktop-buffers-not-to-save bufname))
 819          (not (memq mode desktop-modes-not-to-save))
 820          (or (and filename
 821                   (not (string-match desktop-files-not-to-save filename)))
 822              (and (eq mode 'dired-mode)
 823                   (with-current-buffer bufname
 824                     (not (string-match desktop-files-not-to-save
 825                                        default-directory))))
 826              (and (null filename)
 827                   (with-current-buffer bufname desktop-save-buffer))))))
 828
 829 ;; ----------------------------------------------------------------------------
 830 (defun desktop-file-name (filename dirname)
 831   "Convert FILENAME to format specified in `desktop-file-name-format'.
 832 DIRNAME must be the directory in which the desktop file will be saved."
 833   (cond
 834     ((not filename) nil)
 835     ((eq desktop-file-name-format 'tilde)
 836      (let ((relative-name (file-relative-name (expand-file-name filename) "~")))
 837        (cond
 838          ((file-name-absolute-p relative-name) relative-name)
 839          ((string= "./" relative-name) "~/")
 840          ((string= "." relative-name) "~")
 841          (t (concat "~/" relative-name)))))
 842     ((eq desktop-file-name-format 'local) (file-relative-name filename dirname))
 843     (t (expand-file-name filename))))
 844
 845
 846 ;; ----------------------------------------------------------------------------
 847 ;;;###autoload
 848 (defun desktop-save (dirname &optional release)
 849   "Save the desktop in a desktop file.
 850 Parameter DIRNAME specifies where to save the desktop file.
 851 Optional parameter RELEASE says whether we're done with this desktop.
 852 See also `desktop-base-file-name'."
 853   (interactive "DDirectory to save desktop file in: ")
 854   (setq desktop-dirname (file-name-as-directory (expand-file-name dirname)))
 855   (save-excursion
 856     (let ((eager desktop-restore-eager)
 857           (new-modtime (nth 5 (file-attributes (desktop-full-file-name)))))
 858       (when
 859           (or (not new-modtime)         ; nothing to overwrite
 860               (equal desktop-file-modtime new-modtime)
 861               (yes-or-no-p (if desktop-file-modtime
 862                                (if (> (float-time new-modtime) (float-time desktop-file-modtime))
 863                                    "Desktop file is more recent than the one loaded.  Save anyway? "
 864                                  "Desktop file isn't the one loaded.  Overwrite it? ")
 865                              "Current desktop was not loaded from a file.  Overwrite this desktop file? "))
 866               (unless release (error "Desktop file conflict")))
 867
 868         ;; If we're done with it, release the lock.
 869         ;; Otherwise, claim it if it's unclaimed or if we created it.
 870         (if release
 871             (desktop-release-lock)
 872           (unless (and new-modtime (desktop-owner)) (desktop-claim-lock)))
 873
 874         (with-temp-buffer
 875           (insert
 876            ";; -*- mode: emacs-lisp; coding: emacs-mule; -*-\n"
 877            desktop-header
 878            ";; Created " (current-time-string) "\n"
 879            ";; Desktop file format version " desktop-file-version "\n"
 880            ";; Emacs version " emacs-version "\n")
 881           (save-excursion (run-hooks 'desktop-save-hook))
 882           (goto-char (point-max))
 883           (insert "\n;; Global section:\n")
 884           (mapc (function desktop-outvar) desktop-globals-to-save)
 885           (when (memq 'kill-ring desktop-globals-to-save)
 886             (insert
 887              "(setq kill-ring-yank-pointer (nthcdr "
 888              (int-to-string (- (length kill-ring) (length kill-ring-yank-pointer)))
 889              " kill-ring))\n"))
 890
 891           (insert "\n;; Buffer section -- buffers listed in same order as in buffer list:\n")
 892           (dolist (l (mapcar 'desktop-buffer-info (buffer-list)))
 893             (when (apply 'desktop-save-buffer-p l)
 894               (insert "("
 895                       (if (or (not (integerp eager))
 896                               (if (zerop eager)
 897                                   nil
 898                                 (setq eager (1- eager))))
 899                           "desktop-create-buffer"
 900                         "desktop-append-buffer-args")
 901                       " "
 902                       desktop-file-version)
 903               (dolist (e l)
 904                 (insert "\n  " (desktop-value-to-string e)))
 905               (insert ")\n\n")))
 906
 907           (setq default-directory desktop-dirname)
 908           (let ((coding-system-for-write 'emacs-mule))
 909             (write-region (point-min) (point-max) (desktop-full-file-name) nil 'nomessage))
 910           ;; We remember when it was modified (which is presumably just now).
 911           (setq desktop-file-modtime (nth 5 (file-attributes (desktop-full-file-name)))))))))
 912
 913 ;; ----------------------------------------------------------------------------
 914 ;;;###autoload
 915 (defun desktop-remove ()
 916   "Delete desktop file in `desktop-dirname'.
 917 This function also sets `desktop-dirname' to nil."
 918   (interactive)
 919   (when desktop-dirname
 920     (let ((filename (desktop-full-file-name)))
 921       (setq desktop-dirname nil)
 922       (when (file-exists-p filename)
 923         (delete-file filename)))))
 924
 925 (defvar desktop-buffer-args-list nil
 926   "List of args for `desktop-create-buffer'.")
 927
 928 (defvar desktop-lazy-timer nil)
 929
 930 ;; ----------------------------------------------------------------------------
 931 ;;;###autoload
 932 (defun desktop-read (&optional dirname)
 933   "Read and process the desktop file in directory DIRNAME.
 934 Look for a desktop file in DIRNAME, or if DIRNAME is omitted, look in
 935 directories listed in `desktop-path'.  If a desktop file is found, it
 936 is processed and `desktop-after-read-hook' is run.  If no desktop file
 937 is found, clear the desktop and run `desktop-no-desktop-file-hook'.
 938 This function is a no-op when Emacs is running in batch mode.
 939 It returns t if a desktop file was loaded, nil otherwise."
 940   (interactive)
 941   (unless noninteractive
 942     (setq desktop-dirname
 943           (file-name-as-directory
 944            (expand-file-name
 945             (or
 946              ;; If DIRNAME is specified, use it.
 947              (and (< 0 (length dirname)) dirname)
 948              ;; Otherwise search desktop file in desktop-path.
 949              (let ((dirs desktop-path))
 950                (while (and dirs
 951                            (not (file-exists-p
 952                                  (desktop-full-file-name (car dirs)))))
 953                  (setq dirs (cdr dirs)))
 954                (and dirs (car dirs)))
 955              ;; If not found and `desktop-path' is non-nil, use its first element.
 956              (and desktop-path (car desktop-path))
 957              ;; Default: Home directory.
 958              "~"))))
 959     (if (file-exists-p (desktop-full-file-name))
 960         ;; Desktop file found, but is it already in use?
 961         (let ((desktop-first-buffer nil)
 962               (desktop-buffer-ok-count 0)
 963               (desktop-buffer-fail-count 0)
 964               (owner (desktop-owner))
 965               ;; Avoid desktop saving during evaluation of desktop buffer.
 966               (desktop-save nil))
 967           (if (and owner
 968                    (memq desktop-load-locked-desktop '(nil ask))
 969                    (or (null desktop-load-locked-desktop)
 970                        (not (y-or-n-p (format "Warning: desktop file appears to be in use by PID %s.\n\
 971 Using it may cause conflicts.  Use it anyway? " owner)))))
 972               (progn
 973                 (let ((default-directory desktop-dirname))
 974                   (run-hooks 'desktop-not-loaded-hook))
 975                 (setq desktop-dirname nil)
 976                 (message "Desktop file in use; not loaded."))
 977             (desktop-lazy-abort)
 978             ;; Evaluate desktop buffer and remember when it was modified.
 979             (load (desktop-full-file-name) t t t)
 980             (setq desktop-file-modtime (nth 5 (file-attributes (desktop-full-file-name))))
 981             ;; If it wasn't already, mark it as in-use, to bother other
 982             ;; desktop instances.
 983             (unless owner
 984               (condition-case nil
 985                   (desktop-claim-lock)
 986                 (file-error (message "Couldn't record use of desktop file")
 987                             (sit-for 1))))
 988
 989             ;; `desktop-create-buffer' puts buffers at end of the buffer list.
 990             ;; We want buffers existing prior to evaluating the desktop (and
 991             ;; not reused) to be placed at the end of the buffer list, so we
 992             ;; move them here.
 993             (mapc 'bury-buffer
 994                   (nreverse (cdr (memq desktop-first-buffer (nreverse (buffer-list))))))
 995             (switch-to-buffer (car (buffer-list)))
 996             (run-hooks 'desktop-delay-hook)
 997             (setq desktop-delay-hook nil)
 998             (run-hooks 'desktop-after-read-hook)
 999             (message "Desktop: %d buffer%s restored%s%s."
1000                      desktop-buffer-ok-count
1001                      (if (= 1 desktop-buffer-ok-count) "" "s")
1002                      (if (< 0 desktop-buffer-fail-count)
1003                          (format ", %d failed to restore" desktop-buffer-fail-count)
1004                        "")
1005                      (if desktop-buffer-args-list
1006                          (format ", %d to restore lazily"
1007                                  (length desktop-buffer-args-list))
1008                        ""))
1009             t))
1010       ;; No desktop file found.
1011       (desktop-clear)
1012       (let ((default-directory desktop-dirname))
1013         (run-hooks 'desktop-no-desktop-file-hook))
1014       (message "No desktop file.")
1015       nil)))
1016
1017 ;; ----------------------------------------------------------------------------
1018 ;; Maintained for backward compatibility
1019 ;;;###autoload
1020 (defun desktop-load-default ()
1021   "Load the `default' start-up library manually.
1022 Also inhibit further loading of it."
1023   (unless inhibit-default-init          ; safety check
1024     (load "default" t t)
1025     (setq inhibit-default-init t)))
1026 (make-obsolete 'desktop-load-default
1027                'desktop-save-mode "22.1")
1028
1029 ;; ----------------------------------------------------------------------------
1030 ;;;###autoload
1031 (defun desktop-change-dir (dirname)
1032   "Change to desktop saved in DIRNAME.
1033 Kill the desktop as specified by variables `desktop-save-mode' and
1034 `desktop-save', then clear the desktop and load the desktop file in
1035 directory DIRNAME."
1036   (interactive "DChange to directory: ")
1037   (setq dirname (file-name-as-directory (expand-file-name dirname desktop-dirname)))
1038   (desktop-kill)
1039   (desktop-clear)
1040   (desktop-read dirname))
1041
1042 ;; ----------------------------------------------------------------------------
1043 ;;;###autoload
1044 (defun desktop-save-in-desktop-dir ()
1045   "Save the desktop in directory `desktop-dirname'."
1046   (interactive)
1047   (if desktop-dirname
1048       (desktop-save desktop-dirname)
1049     (call-interactively 'desktop-save))
1050   (message "Desktop saved in %s" desktop-dirname))
1051
1052 ;; ----------------------------------------------------------------------------
1053 ;;;###autoload
1054 (defun desktop-revert ()
1055   "Revert to the last loaded desktop."
1056   (interactive)
1057   (unless desktop-dirname
1058     (error "Unknown desktop directory"))
1059   (unless (file-exists-p (desktop-full-file-name))
1060     (error "No desktop file found"))
1061   (desktop-clear)
1062   (desktop-read desktop-dirname))
1063
1064 (defvar desktop-buffer-major-mode)
1065 (defvar desktop-buffer-locals)
1066 ;; ----------------------------------------------------------------------------
1067 (defun desktop-restore-file-buffer (desktop-buffer-file-name
1068                                     desktop-buffer-name
1069                                     desktop-buffer-misc)
1070   "Restore a file buffer."
1071   (when desktop-buffer-file-name
1072     (if (or (file-exists-p desktop-buffer-file-name)
1073             (let ((msg (format "Desktop: File \"%s\" no longer exists."
1074                                desktop-buffer-file-name)))
1075               (if desktop-missing-file-warning
1076                   (y-or-n-p (concat msg " Re-create buffer? "))
1077                 (message "%s" msg)
1078                 nil)))
1079         (let* ((auto-insert nil) ; Disable auto insertion
1080                (coding-system-for-read
1081                 (or coding-system-for-read
1082                     (cdr (assq 'buffer-file-coding-system
1083                                desktop-buffer-locals))))
1084                (buf (find-file-noselect desktop-buffer-file-name)))
1085           (condition-case nil
1086               (switch-to-buffer buf)
1087             (error (pop-to-buffer buf)))
1088           (and (not (eq major-mode desktop-buffer-major-mode))
1089                (functionp desktop-buffer-major-mode)
1090                (funcall desktop-buffer-major-mode))
1091           buf)
1092       nil)))
1093
1094 (defun desktop-load-file (function)
1095   "Load the file where auto loaded FUNCTION is defined."
1096   (when function
1097     (let ((fcell (and (fboundp function) (symbol-function function))))
1098       (when (and (listp fcell)
1099                  (eq 'autoload (car fcell)))
1100         (load (cadr fcell))))))
1101
1102 ;; ----------------------------------------------------------------------------
1103 ;; Create a buffer, load its file, set its mode, ...;
1104 ;; called from Desktop file only.
1105
1106 ;; Just to silence the byte compiler.
1107
1108 (defvar desktop-first-buffer)          ; Dynamically bound in `desktop-read'
1109
1110 ;; Bound locally in `desktop-read'.
1111 (defvar desktop-buffer-ok-count)
1112 (defvar desktop-buffer-fail-count)
1113
1114 (defun desktop-create-buffer
1115   (desktop-file-version
1116    desktop-buffer-file-name
1117    desktop-buffer-name
1118    desktop-buffer-major-mode
1119    desktop-buffer-minor-modes
1120    desktop-buffer-point
1121    desktop-buffer-mark
1122    desktop-buffer-read-only
1123    desktop-buffer-misc
1124    &optional
1125    desktop-buffer-locals)
1126   ;; To make desktop files with relative file names possible, we cannot
1127   ;; allow `default-directory' to change. Therefore we save current buffer.
1128   (save-current-buffer
1129     ;; Give major mode module a chance to add a handler.
1130     (desktop-load-file desktop-buffer-major-mode)
1131     (let ((buffer-list (buffer-list))
1132           (result
1133            (condition-case err
1134                (funcall (or (cdr (assq desktop-buffer-major-mode
1135                                        desktop-buffer-mode-handlers))
1136                             'desktop-restore-file-buffer)
1137                         desktop-buffer-file-name
1138                         desktop-buffer-name
1139                         desktop-buffer-misc)
1140              (error
1141               (message "Desktop: Can't load buffer %s: %s"
1142                        desktop-buffer-name
1143                        (error-message-string err))
1144               (when desktop-missing-file-warning (sit-for 1))
1145               nil))))
1146       (if (bufferp result)
1147           (setq desktop-buffer-ok-count (1+ desktop-buffer-ok-count))
1148         (setq desktop-buffer-fail-count (1+ desktop-buffer-fail-count))
1149         (setq result nil))
1150       ;; Restore buffer list order with new buffer at end. Don't change
1151       ;; the order for old desktop files (old desktop module behaviour).
1152       (unless (< desktop-file-version 206)
1153         (mapc 'bury-buffer buffer-list)
1154         (when result (bury-buffer result)))
1155       (when result
1156         (unless (or desktop-first-buffer (< desktop-file-version 206))
1157           (setq desktop-first-buffer result))
1158         (set-buffer result)
1159         (unless (equal (buffer-name) desktop-buffer-name)
1160           (rename-buffer desktop-buffer-name t))
1161         ;; minor modes
1162         (cond ((equal '(t) desktop-buffer-minor-modes) ; backwards compatible
1163                (auto-fill-mode 1))
1164               ((equal '(nil) desktop-buffer-minor-modes) ; backwards compatible
1165                (auto-fill-mode 0))
1166               (t
1167                (dolist (minor-mode desktop-buffer-minor-modes)
1168                  ;; Give minor mode module a chance to add a handler.
1169                  (desktop-load-file minor-mode)
1170                  (let ((handler (cdr (assq minor-mode desktop-minor-mode-handlers))))
1171                    (if handler
1172                        (funcall handler desktop-buffer-locals)
1173                      (when (functionp minor-mode)
1174                        (funcall minor-mode 1)))))))
1175         ;; Even though point and mark are non-nil when written by
1176         ;; `desktop-save', they may be modified by handlers wanting to set
1177         ;; point or mark themselves.
1178         (when desktop-buffer-point
1179           (goto-char
1180             (condition-case err
1181                 ;; Evaluate point.  Thus point can be something like
1182                 ;; '(search-forward ...
1183                 (eval desktop-buffer-point)
1184               (error (message "%s" (error-message-string err)) 1))))
1185         (when desktop-buffer-mark
1186           (if (consp desktop-buffer-mark)
1187               (progn
1188                 (set-mark (car desktop-buffer-mark))
1189                 (setq mark-active (car (cdr desktop-buffer-mark))))
1190             (set-mark desktop-buffer-mark)))
1191         ;; Never override file system if the file really is read-only marked.
1192         (when desktop-buffer-read-only (setq buffer-read-only desktop-buffer-read-only))
1193         (while desktop-buffer-locals
1194           (let ((this (car desktop-buffer-locals)))
1195             (if (consp this)
1196                 ;; an entry of this form `(symbol . value)'
1197                 (progn
1198                   (make-local-variable (car this))
1199                   (set (car this) (cdr this)))
1200               ;; an entry of the form `symbol'
1201               (make-local-variable this)
1202               (makunbound this)))
1203           (setq desktop-buffer-locals (cdr desktop-buffer-locals)))))))
1204
1205 ;; ----------------------------------------------------------------------------
1206 ;; Backward compatibility -- update parameters to 205 standards.
1207 (defun desktop-buffer (desktop-buffer-file-name desktop-buffer-name
1208                        desktop-buffer-major-mode
1209                        mim pt mk ro tl fc cfs cr desktop-buffer-misc)
1210   (desktop-create-buffer 205 desktop-buffer-file-name desktop-buffer-name
1211                          desktop-buffer-major-mode (cdr mim) pt mk ro
1212                          desktop-buffer-misc
1213                          (list (cons 'truncate-lines tl)
1214                                (cons 'fill-column fc)
1215                                (cons 'case-fold-search cfs)
1216                                (cons 'case-replace cr)
1217                                (cons 'overwrite-mode (car mim)))))
1218
1219 (defun desktop-append-buffer-args (&rest args)
1220   "Append ARGS at end of `desktop-buffer-args-list'.
1221 ARGS must be an argument list for `desktop-create-buffer'."
1222   (setq desktop-buffer-args-list (nconc desktop-buffer-args-list (list args)))
1223   (unless desktop-lazy-timer
1224     (setq desktop-lazy-timer
1225           (run-with-idle-timer desktop-lazy-idle-delay t 'desktop-idle-create-buffers))))
1226
1227 (defun desktop-lazy-create-buffer ()
1228   "Pop args from `desktop-buffer-args-list', create buffer and bury it."
1229   (when desktop-buffer-args-list
1230     (let* ((remaining (length desktop-buffer-args-list))
1231            (args (pop desktop-buffer-args-list))
1232            (buffer-name (nth 2 args))
1233            (msg (format "Desktop lazily opening %s (%s remaining)..."
1234                             buffer-name remaining)))
1235       (when desktop-lazy-verbose
1236         (message "%s" msg))
1237       (let ((desktop-first-buffer nil)
1238             (desktop-buffer-ok-count 0)
1239             (desktop-buffer-fail-count 0))
1240         (apply 'desktop-create-buffer args)
1241         (run-hooks 'desktop-delay-hook)
1242         (setq desktop-delay-hook nil)
1243         (bury-buffer (get-buffer buffer-name))
1244         (when desktop-lazy-verbose
1245           (message "%s%s" msg (if (> desktop-buffer-ok-count 0) "done" "failed")))))))
1246
1247 (defun desktop-idle-create-buffers ()
1248   "Create buffers until the user does something, then stop.
1249 If there are no buffers left to create, kill the timer."
1250   (let ((repeat 1))
1251     (while (and repeat desktop-buffer-args-list)
1252       (save-window-excursion
1253         (desktop-lazy-create-buffer))
1254       (setq repeat (sit-for 0.2))
1255     (unless desktop-buffer-args-list
1256       (cancel-timer desktop-lazy-timer)
1257       (setq desktop-lazy-timer nil)
1258       (message "Lazy desktop load complete")
1259       (sit-for 3)
1260       (message "")))))
1261
1262 (defun desktop-lazy-complete ()
1263   "Run the desktop load to completion."
1264   (interactive)
1265   (let ((desktop-lazy-verbose t))
1266     (while desktop-buffer-args-list
1267       (save-window-excursion
1268         (desktop-lazy-create-buffer)))
1269     (message "Lazy desktop load complete")))
1270
1271 (defun desktop-lazy-abort ()
1272   "Abort lazy loading of the desktop."
1273   (interactive)
1274   (when desktop-lazy-timer
1275     (cancel-timer desktop-lazy-timer)
1276     (setq desktop-lazy-timer nil))
1277   (when desktop-buffer-args-list
1278     (setq desktop-buffer-args-list nil)
1279     (when (interactive-p)
1280       (message "Lazy desktop load aborted"))))
1281
1282 ;; ----------------------------------------------------------------------------
1283 ;; When `desktop-save-mode' is non-nil and "--no-desktop" is not specified on the
1284 ;; command line, we do the rest of what it takes to use desktop, but do it
1285 ;; after finishing loading the init file.
1286 ;; We cannot use `command-switch-alist' to process "--no-desktop" because these
1287 ;; functions are processed after `after-init-hook'.
1288 (add-hook
1289   'after-init-hook
1290   (lambda ()
1291     (let ((key "--no-desktop"))
1292       (when (member key command-line-args)
1293         (setq command-line-args (delete key command-line-args))
1294         (setq desktop-save-mode nil)))
1295     (when desktop-save-mode (desktop-read))))
1296
1297 (provide 'desktop)
1298
1299 ;; arch-tag: 221907c3-1771-4fd3-9c2e-c6f700c6ede9
1300 ;;; desktop.el ends here