lisp/longlines.el

   1 ;;; longlines.el --- automatically wrap long lines
   2
   3 ;; Copyright (C) 2000, 2001, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Authors:    Kai Grossjohann <Kai.Grossjohann@CS.Uni-Dortmund.DE>
   6 ;;             Alex Schroeder <alex@gnu.org>
   7 ;;             Chong Yidong <cyd@stupidchicken.com>
   8 ;; Maintainer: Chong Yidong <cyd@stupidchicken.com>
   9 ;; Keywords: convenience, wp
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Some text editors save text files with long lines, and they
  31 ;; automatically break these lines at whitespace, without actually
  32 ;; inserting any newline characters.  When doing `M-q' in Emacs, you
  33 ;; are inserting newline characters.  Longlines mode provides a file
  34 ;; format which wraps the long lines when reading a file and unwraps
  35 ;; the lines when saving the file.  It can also wrap and unwrap
  36 ;; automatically as editing takes place.
  37
  38 ;; Special thanks to Rod Smith for many useful bug reports.
  39
  40 ;;; Code:
  41
  42 (defgroup longlines nil
  43   "Automatic wrapping of long lines when loading files."
  44   :group 'fill)
  45
  46 (defcustom longlines-auto-wrap t
  47   "Non-nil means long lines are automatically wrapped after each command.
  48 Otherwise, you can perform filling using `fill-paragraph' or
  49 `auto-fill-mode'.  In any case, the soft newlines will be removed
  50 when the file is saved to disk."
  51   :group 'longlines
  52   :type 'boolean)
  53
  54 (defcustom longlines-wrap-follows-window-size nil
  55   "Non-nil means wrapping and filling happen at the edge of the window.
  56 Otherwise, `fill-column' is used, regardless of the window size.  This
  57 does not work well when the buffer is displayed in multiple windows
  58 with differing widths.
  59
  60 If the value is an integer, that specifies the distance from the
  61 right edge of the window at which wrapping occurs.  For any other
  62 non-nil value, wrapping occurs 2 characters from the right edge."
  63   :group 'longlines
  64   :type 'boolean)
  65
  66 (defcustom longlines-show-hard-newlines nil
  67   "Non-nil means each hard newline is marked on the screen.
  68 \(The variable `longlines-show-effect' controls what they look like.)
  69 You can also enable the display temporarily, using the command
  70 `longlines-show-hard-newlines'."
  71   :group 'longlines
  72   :type 'boolean)
  73
  74 (defcustom longlines-show-effect (propertize "|\n" 'face 'escape-glyph)
  75   "A string to display when showing hard newlines.
  76 This is used when `longlines-show-hard-newlines' is on."
  77   :group 'longlines
  78   :type 'string)
  79
  80 ;; Internal variables
  81
  82 (defvar longlines-wrap-beg nil)
  83 (defvar longlines-wrap-end nil)
  84 (defvar longlines-wrap-point nil)
  85 (defvar longlines-showing nil)
  86 (defvar longlines-decoded nil)
  87
  88 (make-variable-buffer-local 'longlines-wrap-beg)
  89 (make-variable-buffer-local 'longlines-wrap-end)
  90 (make-variable-buffer-local 'longlines-wrap-point)
  91 (make-variable-buffer-local 'longlines-showing)
  92 (make-variable-buffer-local 'longlines-decoded)
  93
  94 ;; Mode
  95
  96 ;;;###autoload
  97 (define-minor-mode longlines-mode
  98   "Toggle Long Lines mode.
  99 In Long Lines mode, long lines are wrapped if they extend beyond
 100 `fill-column'.  The soft newlines used for line wrapping will not
 101 show up when the text is yanked or saved to disk.
 102
 103 If the variable `longlines-auto-wrap' is non-nil, lines are automatically
 104 wrapped whenever the buffer is changed.  You can always call
 105 `fill-paragraph' to fill individual paragraphs.
 106
 107 If the variable `longlines-show-hard-newlines' is non-nil, hard newlines
 108 are indicated with a symbol."
 109   :group 'longlines :lighter " ll"
 110   (if longlines-mode
 111       ;; Turn on longlines mode
 112       (progn
 113         (use-hard-newlines 1 'never)
 114         (set (make-local-variable 'require-final-newline) nil)
 115         (add-to-list 'buffer-file-format 'longlines)
 116         (add-hook 'change-major-mode-hook 'longlines-mode-off nil t)
 117         (add-hook 'before-revert-hook 'longlines-before-revert-hook nil t)
 118         (make-local-variable 'buffer-substring-filters)
 119         (make-local-variable 'longlines-auto-wrap)
 120         (set (make-local-variable 'isearch-search-fun-function)
 121              'longlines-search-function)
 122         (add-to-list 'buffer-substring-filters 'longlines-encode-string)
 123         (when longlines-wrap-follows-window-size
 124           (let ((dw (if (and (integerp longlines-wrap-follows-window-size)
 125                              (>= longlines-wrap-follows-window-size 0)
 126                              (< longlines-wrap-follows-window-size
 127                                 (window-width)))
 128                         longlines-wrap-follows-window-size
 129                       2)))
 130             (set (make-local-variable 'fill-column)
 131                  (- (window-width) dw)))
 132           (add-hook 'window-configuration-change-hook
 133                     'longlines-window-change-function nil t))
 134         (let ((buffer-undo-list t)
 135               (inhibit-read-only t)
 136               (after-change-functions nil)
 137               (mod (buffer-modified-p)))
 138           ;; Turning off undo is OK since (spaces + newlines) is
 139           ;; conserved, except for a corner case in
 140           ;; longlines-wrap-lines that we'll never encounter from here
 141           (save-restriction
 142             (widen)
 143             (unless longlines-decoded
 144               (longlines-decode-buffer)
 145               (setq longlines-decoded t))
 146             (longlines-wrap-region (point-min) (point-max)))
 147           (set-buffer-modified-p mod))
 148         (when (and longlines-show-hard-newlines
 149                    (not longlines-showing))
 150           (longlines-show-hard-newlines))
 151
 152         ;; Hacks to make longlines play nice with various modes.
 153         (cond ((eq major-mode 'mail-mode)
 154                (add-hook 'mail-setup-hook 'longlines-decode-buffer nil t)
 155                (or mail-citation-hook
 156                    (add-hook 'mail-citation-hook 'mail-indent-citation nil t))
 157                (add-hook 'mail-citation-hook 'longlines-decode-region nil t))
 158               ((eq major-mode 'message-mode)
 159                (add-hook 'message-setup-hook 'longlines-decode-buffer nil t)
 160                (make-local-variable 'message-indent-citation-function)
 161                (if (not (listp message-indent-citation-function))
 162                    (setq message-indent-citation-function
 163                          (list message-indent-citation-function)))
 164                (add-to-list 'message-indent-citation-function
 165                             'longlines-decode-region t)))
 166
 167         (add-hook 'after-change-functions 'longlines-after-change-function nil t)
 168         (add-hook 'post-command-hook 'longlines-post-command-function nil t)
 169         (when longlines-auto-wrap
 170           (auto-fill-mode 0)))
 171     ;; Turn off longlines mode
 172     (setq buffer-file-format (delete 'longlines buffer-file-format))
 173     (if longlines-showing
 174         (longlines-unshow-hard-newlines))
 175     (let ((buffer-undo-list t)
 176           (after-change-functions nil)
 177           (inhibit-read-only t))
 178       (if longlines-decoded
 179           (save-restriction
 180             (widen)
 181             (longlines-encode-region (point-min) (point-max))
 182             (setq longlines-decoded nil))))
 183     (remove-hook 'change-major-mode-hook 'longlines-mode-off t)
 184     (remove-hook 'after-change-functions 'longlines-after-change-function t)
 185     (remove-hook 'post-command-hook 'longlines-post-command-function t)
 186     (remove-hook 'before-revert-hook 'longlines-before-revert-hook t)
 187     (remove-hook 'window-configuration-change-hook
 188                  'longlines-window-change-function t)
 189     (when longlines-wrap-follows-window-size
 190       (kill-local-variable 'fill-column))
 191     (kill-local-variable 'isearch-search-fun-function)
 192     (kill-local-variable 'require-final-newline)
 193     (kill-local-variable 'buffer-substring-filters)
 194     (kill-local-variable 'use-hard-newlines)))
 195
 196 (defun longlines-mode-off ()
 197   "Turn off longlines mode.
 198 This function exists to be called by `change-major-mode-hook' when the
 199 major mode changes."
 200   (longlines-mode 0))
 201
 202 ;; Showing the effect of hard newlines in the buffer
 203
 204 (defun longlines-show-hard-newlines (&optional arg)
 205   "Make hard newlines visible by adding a face.
 206 With optional argument ARG, make the hard newlines invisible again."
 207   (interactive "P")
 208   (let ((buffer-undo-list t)
 209         (mod (buffer-modified-p)))
 210     (if arg
 211         (longlines-unshow-hard-newlines)
 212       (setq longlines-showing t)
 213       (longlines-show-region (point-min) (point-max)))
 214     (set-buffer-modified-p mod)))
 215
 216 (defun longlines-show-region (beg end)
 217   "Make hard newlines between BEG and END visible."
 218   (let* ((pmin (min beg end))
 219          (pmax (max beg end))
 220          (pos (text-property-not-all pmin pmax 'hard nil))
 221          (inhibit-read-only t))
 222     (while pos
 223       (put-text-property pos (1+ pos) 'display
 224                          (copy-sequence longlines-show-effect))
 225       (setq pos (text-property-not-all (1+ pos) pmax 'hard nil)))))
 226
 227 (defun longlines-unshow-hard-newlines ()
 228   "Make hard newlines invisible again."
 229   (interactive)
 230   (setq longlines-showing nil)
 231   (let ((pos (text-property-not-all (point-min) (point-max) 'hard nil)))
 232     (while pos
 233       (remove-text-properties pos (1+ pos) '(display))
 234       (setq pos (text-property-not-all (1+ pos) (point-max) 'hard nil)))))
 235
 236 ;; Wrapping the paragraphs.
 237
 238 (defun longlines-wrap-region (beg end)
 239   "Wrap each successive line, starting with the line before BEG.
 240 Stop when we reach lines after END that don't need wrapping, or the
 241 end of the buffer."
 242   (let ((mod (buffer-modified-p)))
 243     (setq longlines-wrap-point (point))
 244     (goto-char beg)
 245     (forward-line -1)
 246     ;; Two successful longlines-wrap-line's in a row mean successive
 247     ;; lines don't need wrapping.
 248     (while (null (and (longlines-wrap-line)
 249                       (or (eobp)
 250                           (and (>= (point) end)
 251                                (longlines-wrap-line))))))
 252     (goto-char longlines-wrap-point)
 253     (set-buffer-modified-p mod)))
 254
 255 (defun longlines-wrap-line ()
 256   "If the current line needs to be wrapped, wrap it and return nil.
 257 If wrapping is performed, point remains on the line.  If the line does
 258 not need to be wrapped, move point to the next line and return t."
 259   (if (longlines-set-breakpoint)
 260       (progn (insert-before-markers ?\n)
 261              (backward-char 1)
 262              (delete-char -1)
 263              (forward-char 1)
 264              nil)
 265     (if (longlines-merge-lines-p)
 266         (progn (end-of-line)
 267      ;; After certain commands (e.g. kill-line), there may be two
 268      ;; successive soft newlines in the buffer.  In this case, we
 269      ;; replace these two newlines by a single space.  Unfortunately,
 270      ;; this breaks the conservation of (spaces + newlines), so we
 271      ;; have to fiddle with longlines-wrap-point.
 272                (if (or (prog1 (bolp) (forward-char 1)) (eolp))
 273                    (progn
 274                      (delete-char -1)
 275                      (if (> longlines-wrap-point (point))
 276                          (setq longlines-wrap-point
 277                                (1- longlines-wrap-point))))
 278                  (insert-before-markers-and-inherit ?\s)
 279                  (backward-char 1)
 280                  (delete-char -1)
 281                  (forward-char 1))
 282                nil)
 283       (forward-line 1)
 284       t)))
 285
 286 (defun longlines-set-breakpoint ()
 287   "Place point where we should break the current line, and return t.
 288 If the line should not be broken, return nil; point remains on the
 289 line."
 290   (move-to-column fill-column)
 291   (if (and (re-search-forward "[^ ]" (line-end-position) 1)
 292            (> (current-column) fill-column))
 293       ;; This line is too long.  Can we break it?
 294       (or (longlines-find-break-backward)
 295           (progn (move-to-column fill-column)
 296                  (longlines-find-break-forward)))))
 297
 298 (defun longlines-find-break-backward ()
 299   "Move point backward to the first available breakpoint and return t.
 300 If no breakpoint is found, return nil."
 301   (and (search-backward " " (line-beginning-position) 1)
 302        (save-excursion
 303          (skip-chars-backward " " (line-beginning-position))
 304          (null (bolp)))
 305        (progn (forward-char 1)
 306               (if (and fill-nobreak-predicate
 307                        (run-hook-with-args-until-success
 308                         'fill-nobreak-predicate))
 309                   (progn (skip-chars-backward " " (line-beginning-position))
 310                          (longlines-find-break-backward))
 311                 t))))
 312
 313 (defun longlines-find-break-forward ()
 314   "Move point forward to the first available breakpoint and return t.
 315 If no break point is found, return nil."
 316   (and (search-forward " " (line-end-position) 1)
 317        (progn (skip-chars-forward " " (line-end-position))
 318               (null (eolp)))
 319        (if (and fill-nobreak-predicate
 320                 (run-hook-with-args-until-success
 321                  'fill-nobreak-predicate))
 322            (longlines-find-break-forward)
 323          t)))
 324
 325 (defun longlines-merge-lines-p ()
 326   "Return t if part of the next line can fit onto the current line.
 327 Otherwise, return nil.  Text cannot be moved across hard newlines."
 328   (save-excursion
 329     (end-of-line)
 330     (and (null (eobp))
 331          (null (get-text-property (point) 'hard))
 332          (let ((space (- fill-column (current-column))))
 333            (forward-line 1)
 334            (if (eq (char-after) ? )
 335                t ; We can always merge some spaces
 336              (<= (if (search-forward " " (line-end-position) 1)
 337                      (current-column)
 338                    (1+ (current-column)))
 339                  space))))))
 340
 341 (defun longlines-decode-region (&optional beg end)
 342   "Turn all newlines between BEG and END into hard newlines.
 343 If BEG and END are nil, the point and mark are used."
 344   (if (null beg) (setq beg (point)))
 345   (if (null end) (setq end (mark t)))
 346   (save-excursion
 347     (let ((reg-max (max beg end)))
 348       (goto-char (min beg end))
 349       (while (search-forward "\n" reg-max t)
 350         (set-hard-newline-properties
 351          (match-beginning 0) (match-end 0))))))
 352
 353 (defun longlines-decode-buffer ()
 354   "Turn all newlines in the buffer into hard newlines."
 355   (longlines-decode-region (point-min) (point-max)))
 356
 357 (defun longlines-encode-region (beg end &optional buffer)
 358   "Replace each soft newline between BEG and END with exactly one space.
 359 Hard newlines are left intact.  The optional argument BUFFER exists for
 360 compatibility with `format-alist', and is ignored."
 361   (save-excursion
 362     (let ((reg-max (max beg end))
 363           (mod (buffer-modified-p)))
 364       (goto-char (min beg end))
 365       (while (search-forward "\n" reg-max t)
 366         (unless (get-text-property (match-beginning 0) 'hard)
 367           (replace-match " ")))
 368       (set-buffer-modified-p mod)
 369       end)))
 370
 371 (defun longlines-encode-string (string)
 372   "Return a copy of STRING with each soft newline replaced by a space.
 373 Hard newlines are left intact."
 374   (let* ((str (copy-sequence string))
 375          (pos (string-match "\n" str)))
 376     (while pos
 377       (if (null (get-text-property pos 'hard str))
 378           (aset str pos ? ))
 379       (setq pos (string-match "\n" str (1+ pos))))
 380     str))
 381
 382 ;; Auto wrap
 383
 384 (defun longlines-auto-wrap (&optional arg)
 385   "Toggle automatic line wrapping.
 386 With optional argument ARG, turn on line wrapping if and only if ARG is positive.
 387 If automatic line wrapping is turned on, wrap the entire buffer."
 388   (interactive "P")
 389   (setq arg (if arg
 390                 (> (prefix-numeric-value arg) 0)
 391               (not longlines-auto-wrap)))
 392   (if arg
 393       (progn
 394         (setq longlines-auto-wrap t)
 395         (longlines-wrap-region (point-min) (point-max))
 396         (message "Auto wrap enabled."))
 397     (setq longlines-auto-wrap nil)
 398     (message "Auto wrap disabled.")))
 399
 400 (defun longlines-after-change-function (beg end len)
 401   "Update `longlines-wrap-beg' and `longlines-wrap-end'.
 402 This is called by `after-change-functions' to keep track of the region
 403 that has changed."
 404   (when (and longlines-auto-wrap (not undo-in-progress))
 405     (setq longlines-wrap-beg
 406           (if longlines-wrap-beg (min longlines-wrap-beg beg) beg))
 407     (setq longlines-wrap-end
 408           (if longlines-wrap-end (max longlines-wrap-end end) end))))
 409
 410 (defun longlines-post-command-function ()
 411   "Perform line wrapping on the parts of the buffer that have changed.
 412 This is called by `post-command-hook' after each command."
 413   (when (and longlines-auto-wrap longlines-wrap-beg)
 414     (if (or (eq this-command 'yank)
 415             (eq this-command 'yank-pop))
 416         (longlines-decode-region (point) (mark t)))
 417     (if longlines-showing
 418         (longlines-show-region longlines-wrap-beg longlines-wrap-end))
 419     (unless (or (eq this-command 'fill-paragraph)
 420                 (eq this-command 'fill-region))
 421       (longlines-wrap-region longlines-wrap-beg longlines-wrap-end))
 422     (setq longlines-wrap-beg nil)
 423     (setq longlines-wrap-end nil)))
 424
 425 (defun longlines-window-change-function ()
 426   "Re-wrap the buffer if the window width has changed.
 427 This is called by `window-configuration-change-hook'."
 428   (let ((dw (if (and (integerp longlines-wrap-follows-window-size)
 429                      (>= longlines-wrap-follows-window-size 0)
 430                      (< longlines-wrap-follows-window-size (window-width)))
 431                 longlines-wrap-follows-window-size
 432               2)))
 433     (when (/= fill-column (- (window-width) dw))
 434       (setq fill-column (- (window-width) dw))
 435       (longlines-wrap-region (point-min) (point-max)))))
 436
 437 ;; Isearch
 438
 439 (defun longlines-search-function ()
 440   (cond
 441    (isearch-word
 442     (if isearch-forward 'word-search-forward 'word-search-backward))
 443    (isearch-regexp
 444     (if isearch-forward 're-search-forward 're-search-backward))
 445    (t
 446     (if isearch-forward
 447         'longlines-search-forward
 448       'longlines-search-backward))))
 449
 450 (defun longlines-search-forward (string &optional bound noerror count)
 451   (let ((search-spaces-regexp "[ \n]+"))
 452     (re-search-forward (regexp-quote string) bound noerror count)))
 453
 454 (defun longlines-search-backward (string &optional bound noerror count)
 455   (let ((search-spaces-regexp "[ \n]+"))
 456     (re-search-backward (regexp-quote string) bound noerror count)))
 457
 458 ;; Loading and saving
 459
 460 (defun longlines-before-revert-hook ()
 461   (add-hook 'after-revert-hook 'longlines-after-revert-hook nil t)
 462   (longlines-mode 0))
 463
 464 (defun longlines-after-revert-hook ()
 465   (remove-hook 'after-revert-hook 'longlines-after-revert-hook t)
 466   (longlines-mode 1))
 467
 468 (add-to-list
 469  'format-alist
 470  (list 'longlines "Automatically wrap long lines." nil nil
 471        'longlines-encode-region t nil))
 472
 473 (provide 'longlines)
 474
 475 ;; arch-tag: 3489d225-5506-47b9-8659-d8807b77c624
 476 ;;; longlines.el ends here