lisp/abbrev.el

   1 ;;; abbrev.el --- abbrev mode commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: abbrev convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This facility is documented in the Emacs Manual.
  28
  29 ;;; Code:
  30
  31 (defcustom only-global-abbrevs nil
  32   "Non-nil means user plans to use global abbrevs only.
  33 This makes the commands that normally define mode-specific abbrevs
  34 define global abbrevs instead."
  35   :type 'boolean
  36   :group 'abbrev-mode
  37   :group 'convenience)
  38
  39 (defun abbrev-mode (&optional arg)
  40   "Toggle Abbrev mode in the current buffer.
  41 With argument ARG, turn abbrev mode on iff ARG is positive.
  42 In Abbrev mode, inserting an abbreviation causes it to expand
  43 and be replaced by its expansion."
  44   (interactive "P")
  45   (setq abbrev-mode
  46         (if (null arg) (not abbrev-mode)
  47           (> (prefix-numeric-value arg) 0)))
  48   (force-mode-line-update))
  49
  50 (defcustom abbrev-mode nil
  51   "Enable or disable Abbrev mode.
  52 Non-nil means automatically expand abbrevs as they are inserted.
  53
  54 Setting this variable with `setq' changes it for the current buffer.
  55 Changing it with \\[customize] sets the default value.
  56 Interactively, use the command `abbrev-mode'
  57 to enable or disable Abbrev mode in the current buffer."
  58   :type 'boolean
  59   :group 'abbrev-mode)
  60
  61 \f
  62 (defvar edit-abbrevs-map
  63   (let ((map (make-sparse-keymap)))
  64     (define-key map "\C-x\C-s" 'edit-abbrevs-redefine)
  65     (define-key map "\C-c\C-c" 'edit-abbrevs-redefine)
  66     map)
  67   "Keymap used in `edit-abbrevs'.")
  68
  69 (defun kill-all-abbrevs ()
  70   "Undefine all defined abbrevs."
  71   (interactive)
  72   (let ((tables abbrev-table-name-list))
  73     (while tables
  74       (clear-abbrev-table (symbol-value (car tables)))
  75       (setq tables (cdr tables)))))
  76
  77 (defun copy-abbrev-table (table)
  78   "Make a new abbrev-table with the same abbrevs as TABLE."
  79   (let ((new-table (make-abbrev-table)))
  80     (mapatoms
  81      (lambda (symbol)
  82        (define-abbrev new-table
  83          (symbol-name symbol)
  84          (symbol-value symbol)
  85          (symbol-function symbol)))
  86      table)
  87     new-table))
  88
  89 (defun insert-abbrevs ()
  90   "Insert after point a description of all defined abbrevs.
  91 Mark is set after the inserted text."
  92   (interactive)
  93   (push-mark
  94    (save-excursion
  95     (let ((tables abbrev-table-name-list))
  96       (while tables
  97         (insert-abbrev-table-description (car tables) t)
  98         (setq tables (cdr tables))))
  99     (point))))
 100
 101 (defun list-abbrevs (&optional local)
 102   "Display a list of defined abbrevs.
 103 If LOCAL is non-nil, interactively when invoked with a
 104 prefix arg, display only local, i.e. mode-specific, abbrevs.
 105 Otherwise display all abbrevs."
 106   (interactive "P")
 107   (display-buffer (prepare-abbrev-list-buffer local)))
 108
 109 (defun abbrev-table-name (table)
 110   "Value is the name of abbrev table TABLE."
 111   (let ((tables abbrev-table-name-list)
 112         found)
 113     (while (and (not found) tables)
 114       (when (eq (symbol-value (car tables)) table)
 115         (setq found (car tables)))
 116       (setq tables (cdr tables)))
 117     found))
 118
 119 (defun prepare-abbrev-list-buffer (&optional local)
 120   (save-excursion
 121     (let ((table local-abbrev-table))
 122       (set-buffer (get-buffer-create "*Abbrevs*"))
 123       (erase-buffer)
 124       (if local
 125           (insert-abbrev-table-description (abbrev-table-name table) t)
 126         (dolist (table abbrev-table-name-list)
 127           (insert-abbrev-table-description table t)))
 128       (goto-char (point-min))
 129       (set-buffer-modified-p nil)
 130       (edit-abbrevs-mode)
 131       (current-buffer))))
 132
 133 (defun edit-abbrevs-mode ()
 134   "Major mode for editing the list of abbrev definitions.
 135 \\{edit-abbrevs-map}"
 136   (interactive)
 137   (setq major-mode 'edit-abbrevs-mode)
 138   (setq mode-name "Edit-Abbrevs")
 139   (use-local-map edit-abbrevs-map))
 140
 141 (defun edit-abbrevs ()
 142   "Alter abbrev definitions by editing a list of them.
 143 Selects a buffer containing a list of abbrev definitions.
 144 You can edit them and type \\<edit-abbrevs-map>\\[edit-abbrevs-redefine] to redefine abbrevs
 145 according to your editing.
 146 Buffer contains a header line for each abbrev table,
 147  which is the abbrev table name in parentheses.
 148 This is followed by one line per abbrev in that table:
 149 NAME   USECOUNT   EXPANSION   HOOK
 150 where NAME and EXPANSION are strings with quotes,
 151 USECOUNT is an integer, and HOOK is any valid function
 152 or may be omitted (it is usually omitted)."
 153   (interactive)
 154   (switch-to-buffer (prepare-abbrev-list-buffer)))
 155
 156 (defun edit-abbrevs-redefine ()
 157   "Redefine abbrevs according to current buffer contents."
 158   (interactive)
 159   (define-abbrevs t)
 160   (set-buffer-modified-p nil))
 161
 162 (defun define-abbrevs (&optional arg)
 163   "Define abbrevs according to current visible buffer contents.
 164 See documentation of `edit-abbrevs' for info on the format of the
 165 text you must have in the buffer.
 166 With argument, eliminate all abbrev definitions except
 167 the ones defined from the buffer now."
 168   (interactive "P")
 169   (if arg (kill-all-abbrevs))
 170   (save-excursion
 171    (goto-char (point-min))
 172    (while (and (not (eobp)) (re-search-forward "^(" nil t))
 173      (let* ((buf (current-buffer))
 174             (table (read buf))
 175             abbrevs name hook exp count)
 176        (forward-line 1)
 177        (while (progn (forward-line 1)
 178                      (not (eolp)))
 179          (setq name (read buf) count (read buf) exp (read buf))
 180          (skip-chars-backward " \t\n\f")
 181          (setq hook (if (not (eolp)) (read buf)))
 182          (skip-chars-backward " \t\n\f")
 183          (setq abbrevs (cons (list name exp hook count) abbrevs)))
 184        (define-abbrev-table table abbrevs)))))
 185
 186 (defun read-abbrev-file (&optional file quietly)
 187   "Read abbrev definitions from file written with `write-abbrev-file'.
 188 Optional argument FILE is the name of the file to read;
 189 it defaults to the value of `abbrev-file-name'.
 190 Optional second argument QUIETLY non-nil means don't display a message."
 191   (interactive "fRead abbrev file: ")
 192   (load (if (and file (> (length file) 0)) file abbrev-file-name)
 193         nil quietly)
 194   (setq abbrevs-changed nil))
 195
 196 (defun quietly-read-abbrev-file (&optional file)
 197   "Read abbrev definitions from file written with `write-abbrev-file'.
 198 Optional argument FILE is the name of the file to read;
 199 it defaults to the value of `abbrev-file-name'.
 200 Does not display any message."
 201   ;(interactive "fRead abbrev file: ")
 202   (read-abbrev-file file t))
 203
 204 (defun write-abbrev-file (&optional file)
 205   "Write all user-level abbrev definitions to a file of Lisp code.
 206 This does not include system abbrevs; it includes only the abbrev tables
 207 listed in listed in `abbrev-table-name-list'.
 208 The file written can be loaded in another session to define the same abbrevs.
 209 The argument FILE is the file name to write.  If omitted or nil, the file
 210 specified in `abbrev-file-name' is used."
 211   (interactive
 212    (list
 213     (read-file-name "Write abbrev file: "
 214                     (file-name-directory (expand-file-name abbrev-file-name))
 215                     abbrev-file-name)))
 216   (or (and file (> (length file) 0))
 217       (setq file abbrev-file-name))
 218   (let ((coding-system-for-write 'emacs-mule))
 219     (with-temp-file file
 220       (insert ";;-*-coding: emacs-mule;-*-\n")
 221       (dolist (table abbrev-table-name-list)
 222         (insert-abbrev-table-description table nil)))))
 223 \f
 224 (defun add-mode-abbrev (arg)
 225   "Define mode-specific abbrev for last word(s) before point.
 226 Argument is how many words before point form the expansion;
 227 or zero means the region is the expansion.
 228 A negative argument means to undefine the specified abbrev.
 229 Reads the abbreviation in the minibuffer.
 230
 231 Don't use this function in a Lisp program; use `define-abbrev' instead."
 232   (interactive "p")
 233   (add-abbrev
 234    (if only-global-abbrevs
 235        global-abbrev-table
 236      (or local-abbrev-table
 237          (error "No per-mode abbrev table")))
 238    "Mode" arg))
 239
 240 (defun add-global-abbrev (arg)
 241   "Define global (all modes) abbrev for last word(s) before point.
 242 The prefix argument specifies the number of words before point that form the
 243 expansion; or zero means the region is the expansion.
 244 A negative argument means to undefine the specified abbrev.
 245 This command uses the minibuffer to read the abbreviation.
 246
 247 Don't use this function in a Lisp program; use `define-abbrev' instead."
 248   (interactive "p")
 249   (add-abbrev global-abbrev-table "Global" arg))
 250
 251 (defun add-abbrev (table type arg)
 252   (let ((exp (and (>= arg 0)
 253                   (buffer-substring-no-properties
 254                    (point)
 255                    (if (= arg 0) (mark)
 256                      (save-excursion (forward-word (- arg)) (point))))))
 257         name)
 258     (setq name
 259           (read-string (format (if exp "%s abbrev for \"%s\": "
 260                                  "Undefine %s abbrev: ")
 261                                type exp)))
 262     (set-text-properties 0 (length name) nil name)
 263     (if (or (null exp)
 264             (not (abbrev-expansion name table))
 265             (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 266                               name (abbrev-expansion name table))))
 267         (define-abbrev table (downcase name) exp))))
 268
 269 (defun inverse-add-mode-abbrev (arg)
 270   "Define last word before point as a mode-specific abbrev.
 271 With prefix argument N, defines the Nth word before point.
 272 This command uses the minibuffer to read the expansion.
 273 Expands the abbreviation after defining it."
 274   (interactive "p")
 275   (inverse-add-abbrev
 276    (if only-global-abbrevs
 277        global-abbrev-table
 278      (or local-abbrev-table
 279          (error "No per-mode abbrev table")))
 280    "Mode" arg))
 281
 282 (defun inverse-add-global-abbrev (arg)
 283   "Define last word before point as a global (mode-independent) abbrev.
 284 With prefix argument N, defines the Nth word before point.
 285 This command uses the minibuffer to read the expansion.
 286 Expands the abbreviation after defining it."
 287   (interactive "p")
 288   (inverse-add-abbrev global-abbrev-table "Global" arg))
 289
 290 (defun inverse-add-abbrev (table type arg)
 291   (let (name exp start end)
 292     (save-excursion
 293       (forward-word (1+ (- arg)))
 294       (setq end (point))
 295       (backward-word 1)
 296       (setq start (point)
 297             name (buffer-substring-no-properties start end)))
 298
 299     (setq exp (read-string (format "%s expansion for \"%s\": " type name)
 300                            nil nil nil t))
 301     (when (or (not (abbrev-expansion name table))
 302               (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 303                                 name (abbrev-expansion name table))))
 304       (define-abbrev table (downcase name) exp)
 305       (save-excursion
 306         (goto-char end)
 307         (expand-abbrev)))))
 308
 309 (defun abbrev-prefix-mark (&optional arg)
 310   "Mark current point as the beginning of an abbrev.
 311 Abbrev to be expanded starts here rather than at beginning of word.
 312 This way, you can expand an abbrev with a prefix: insert the prefix,
 313 use this command, then insert the abbrev.  This command inserts a
 314 temporary hyphen after the prefix \(until the intended abbrev
 315 expansion occurs).
 316 If the prefix is itself an abbrev, this command expands it, unless
 317 ARG is non-nil.  Interactively, ARG is the prefix argument."
 318   (interactive "P")
 319   (or arg (expand-abbrev))
 320   (setq abbrev-start-location (point-marker)
 321         abbrev-start-location-buffer (current-buffer))
 322   (insert "-"))
 323
 324 (defun expand-region-abbrevs (start end &optional noquery)
 325   "For abbrev occurrence in the region, offer to expand it.
 326 The user is asked to type y or n for each occurrence.
 327 A prefix argument means don't query; expand all abbrevs.
 328 If called from a Lisp program, arguments are START END &optional NOQUERY."
 329   (interactive "r\nP")
 330   (save-excursion
 331     (goto-char start)
 332     (let ((lim (- (point-max) end))
 333           pnt string)
 334       (while (and (not (eobp))
 335                   (progn (forward-word 1)
 336                          (<= (setq pnt (point)) (- (point-max) lim))))
 337         (if (abbrev-expansion
 338              (setq string
 339                    (buffer-substring-no-properties
 340                     (save-excursion (forward-word -1) (point))
 341                     pnt)))
 342             (if (or noquery (y-or-n-p (format "Expand `%s'? " string)))
 343                 (expand-abbrev)))))))
 344
 345 ;;; arch-tag: dbd6f3ae-dfe3-40ba-b00f-f9e3ff960df5
 346 ;;; abbrev.el ends here