lisp/minibuf-eldef.el

   1 ;;; minibuf-eldef.el --- Only show defaults in prompts when applicable
   2 ;;
   3 ;; Copyright (C) 2000, 2001, 2004 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Miles Bader <miles@gnu.org>
   6 ;; Keywords: convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; Defines the mode `minibuffer-electric-default-mode'.
  28 ;;
  29 ;; When active, minibuffer prompts that show a default value only show
  30 ;; the default when it's applicable -- that is, when hitting RET would
  31 ;; yield the default value.  If the user modifies the input such that
  32 ;; hitting RET would enter a non-default value, the prompt is modified
  33 ;; to remove the default indication (which is restored if the input is
  34 ;; ever restore to the match the initial input).
  35
  36 ;;; Code:
  37
  38 (defvar minibuffer-default-in-prompt-regexps
  39   '(("\\( (default\\>.*)\\):? \\'" . 1) ("\\( \\[.*\\]\\):? *\\'" . 1))
  40   "*A list of regexps matching the parts of minibuffer prompts showing defaults.
  41 When `minibuffer-electric-default-mode' is active, these regexps are
  42 used to identify the portions of prompts to elide.
  43
  44 Each entry is either a string, which should be a regexp matching the
  45 default portion of the prompt, or a cons cell, who's car is a regexp
  46 matching the default part of the prompt, and who's cdr indicates the
  47 regexp subexpression that matched.")
  48
  49 \f
  50 ;;; Internal variables
  51
  52 ;; A list of minibuffers to which we've added a post-command-hook.
  53 (defvar minibuf-eldef-frobbed-minibufs nil)
  54
  55 ;;; The following are all local variables in the minibuffer
  56
  57 ;; Input pre-inserted into the minibuffer before the user can edit it.
  58 (defvar minibuf-eldef-initial-input)
  59 (make-variable-buffer-local 'minibuf-eldef-initial-input)
  60 ;; and the length of the buffer with it inserted.
  61 (defvar minibuf-eldef-initial-buffer-length)
  62 (make-variable-buffer-local 'minibuf-eldef-initial-buffer-length)
  63
  64 ;; True if the current minibuffer prompt contains the default spec.
  65 (defvar minibuf-eldef-showing-default-in-prompt)
  66 (make-variable-buffer-local 'minibuf-eldef-showing-default-in-prompt)
  67
  68 ;; An overlay covering the default portion of the prompt
  69 (defvar minibuf-eldef-overlay)
  70 (make-variable-buffer-local 'minibuf-eldef-overlay)
  71
  72 \f
  73 ;;; Hook functions
  74
  75 ;; This function goes on minibuffer-setup-hook
  76 (defun minibuf-eldef-setup-minibuffer ()
  77   "Set up a minibuffer for `minibuffer-electric-default-mode'.
  78 The prompt and initial input should already have been inserted."
  79   (let ((regexps minibuffer-default-in-prompt-regexps)
  80         (match nil)
  81         (inhibit-point-motion-hooks t))
  82     (save-excursion
  83       (save-restriction
  84         ;; Narrow to only the prompt
  85         (goto-char (point-min))
  86         (narrow-to-region (point) (minibuffer-prompt-end))
  87         ;; See the prompt contains a default input indicator
  88         (while regexps
  89           (setq match (pop regexps))
  90           (if (re-search-forward (if (stringp match) match (car match)) nil t)
  91               (setq regexps nil)
  92             (setq match nil)))))
  93     (if (not match)
  94         ;; Nope, so just make sure our post-command-hook isn't left around.
  95         (remove-hook 'post-command-hook #'minibuf-eldef-update-minibuffer t)
  96       ;; Yup; set things up so we can frob the prompt as the state of
  97       ;; the input string changes.
  98       (setq match (if (consp match) (cdr match) 0))
  99       (setq minibuf-eldef-overlay
 100             (make-overlay (match-beginning match) (match-end match)))
 101       (setq minibuf-eldef-showing-default-in-prompt t)
 102       (setq minibuf-eldef-initial-input
 103             (minibuffer-contents-no-properties))
 104       (setq minibuf-eldef-initial-buffer-length (point-max))
 105       (add-to-list 'minibuf-eldef-frobbed-minibufs (current-buffer))
 106       (add-hook 'post-command-hook #'minibuf-eldef-update-minibuffer nil t))))
 107
 108 ;; post-command-hook to swap prompts when necessary
 109 (defun minibuf-eldef-update-minibuffer ()
 110   "Update a minibuffer's prompt to include a default only when applicable.
 111 This is intended to be used as a minibuffer post-command-hook for
 112 `minibuffer-electric-default-mode'; the minibuffer should have already
 113 been set up by `minibuf-eldef-setup-minibuffer'."
 114   (unless (eq minibuf-eldef-showing-default-in-prompt
 115               (and (= (point-max) minibuf-eldef-initial-buffer-length)
 116                    (string-equal (minibuffer-contents-no-properties)
 117                                  minibuf-eldef-initial-input)))
 118     ;; swap state
 119     (setq minibuf-eldef-showing-default-in-prompt
 120           (not minibuf-eldef-showing-default-in-prompt))
 121     (cond (minibuf-eldef-showing-default-in-prompt
 122            (overlay-put minibuf-eldef-overlay 'invisible nil)
 123            (overlay-put minibuf-eldef-overlay 'intangible nil))
 124           (t
 125            (overlay-put minibuf-eldef-overlay 'invisible t)
 126            (overlay-put minibuf-eldef-overlay 'intangible t)))))
 127
 128 \f
 129 ;;; Note this definition must be at the end of the file, because
 130 ;;; `define-minor-mode' actually calls the mode-function if the
 131 ;;; associated variable is non-nil, which requires that all needed
 132 ;;; functions be already defined.  [This is arguably a bug in d-m-m]
 133 ;;;###autoload
 134 (define-minor-mode minibuffer-electric-default-mode
 135   "Toggle Minibuffer Electric Default mode.
 136 When active, minibuffer prompts that show a default value only show the
 137 default when it's applicable -- that is, when hitting RET would yield
 138 the default value.  If the user modifies the input such that hitting RET
 139 would enter a non-default value, the prompt is modified to remove the
 140 default indication.
 141
 142 With prefix argument ARG, turn on if positive, otherwise off.
 143 Returns non-nil if the new state is enabled."
 144   :global t
 145   :group 'minibuffer
 146   (if minibuffer-electric-default-mode
 147       ;; Enable the mode
 148       (add-hook 'minibuffer-setup-hook 'minibuf-eldef-setup-minibuffer)
 149     ;; Disable the mode
 150     (remove-hook 'minibuffer-setup-hook 'minibuf-eldef-setup-minibuffer)
 151     ;; Remove our entry from any post-command-hook variable's it's still in
 152     (dolist (minibuf minibuf-eldef-frobbed-minibufs)
 153       (with-current-buffer minibuf
 154         (remove-hook 'post-command-hook #'minibuf-eldef-update-minibuffer t)))
 155     (setq minibuf-eldef-frobbed-minibufs nil)))
 156
 157
 158 (provide 'minibuf-eldef)
 159
 160 ;; arch-tag: 7e421fae-c275-4729-b0da-7836af377d3d
 161 ;;; minibuf-eldef.el ends here