lisp/battery.el

   1 ;;; battery.el --- display battery status information  -*- coding: utf-8 -*-
   2
   3 ;; Copyright (C) 1997-1998, 2000-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Ralph Schleicher <rs@nunatak.allgaeu.org>
   6 ;; Keywords: hardware
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; There is at present support for GNU/Linux, OS X and Windows.  This
  26 ;; library supports both the `/proc/apm' file format of Linux version
  27 ;; 1.3.58 or newer and the `/proc/acpi/' directory structure of Linux
  28 ;; 2.4.20 and 2.6.  Darwin (OS X) is supported by using the `pmset'
  29 ;; program.  Windows is supported by the GetSystemPowerStatus API call.
  30
  31 ;;; Code:
  32
  33 (require 'timer)
  34 (eval-when-compile (require 'cl-lib))
  35 \f
  36 (defgroup battery nil
  37   "Display battery status information."
  38   :prefix "battery-"
  39   :group 'hardware)
  40
  41 ;; Either BATn or yeeloong-bat, basically.
  42 (defconst battery--linux-sysfs-regexp "[bB][aA][tT][0-9]?$")
  43
  44 (defcustom battery-status-function
  45   (cond ((and (eq system-type 'gnu/linux)
  46               (file-readable-p "/proc/apm"))
  47          'battery-linux-proc-apm)
  48         ((and (eq system-type 'gnu/linux)
  49               (file-directory-p "/proc/acpi/battery"))
  50          'battery-linux-proc-acpi)
  51         ((and (eq system-type 'gnu/linux)
  52               (file-directory-p "/sys/class/power_supply/")
  53               (directory-files "/sys/class/power_supply/" nil
  54                                battery--linux-sysfs-regexp))
  55          'battery-linux-sysfs)
  56         ((and (eq system-type 'berkeley-unix)
  57               (file-executable-p "/usr/sbin/apm"))
  58          'battery-bsd-apm)
  59         ((and (eq system-type 'darwin)
  60               (condition-case nil
  61                   (with-temp-buffer
  62                     (and (eq (call-process "pmset" nil t nil "-g" "ps") 0)
  63                          (> (buffer-size) 0)))
  64                 (error nil)))
  65          'battery-pmset)
  66         ((fboundp 'w32-battery-status)
  67          'w32-battery-status))
  68   "Function for getting battery status information.
  69 The function has to return an alist of conversion definitions.
  70 Its cons cells are of the form
  71
  72     (CONVERSION . REPLACEMENT-TEXT)
  73
  74 CONVERSION is the character code of a \"conversion specification\"
  75 introduced by a `%' character in a control string."
  76   :type '(choice (const nil) function)
  77   :group 'battery)
  78
  79 (defcustom battery-echo-area-format
  80   (cond ((eq battery-status-function 'battery-linux-proc-acpi)
  81          "Power %L, battery %B at %r (%p%% load, remaining time %t)")
  82         ((eq battery-status-function 'battery-linux-sysfs)
  83          "Power %L, battery %B (%p%% load, remaining time %t)")
  84         ((eq battery-status-function 'battery-pmset)
  85          "%L power, battery %B (%p%% load, remaining time %t)")
  86         (battery-status-function
  87          "Power %L, battery %B (%p%% load, remaining time %t)"))
  88   "Control string formatting the string to display in the echo area.
  89 Ordinary characters in the control string are printed as-is, while
  90 conversion specifications introduced by a `%' character in the control
  91 string are substituted as defined by the current value of the variable
  92 `battery-status-function'.  Here are the ones generally available:
  93 %c Current capacity (mAh or mWh)
  94 %r Current rate of charge or discharge
  95 %B Battery status (verbose)
  96 %b Battery status: empty means high, `-' means low,
  97    `!' means critical, and `+' means charging
  98 %d Temperature (in degrees Celsius)
  99 %L AC line status (verbose)
 100 %p Battery load percentage
 101 %m Remaining time (to charge or discharge) in minutes
 102 %h Remaining time (to charge or discharge) in hours
 103 %t Remaining time (to charge or discharge) in the form `h:min'"
 104   :type '(choice string (const nil))
 105   :group 'battery)
 106
 107 (defvar battery-mode-line-string nil
 108   "String to display in the mode line.")
 109 ;;;###autoload (put 'battery-mode-line-string 'risky-local-variable t)
 110
 111 (defcustom battery-mode-line-limit 100
 112   "Percentage of full battery load below which display battery status"
 113   :version "24.1"
 114   :type 'integer
 115   :group 'battery)
 116
 117 (defcustom battery-mode-line-format
 118   (cond ((eq battery-status-function 'battery-linux-proc-acpi)
 119          "[%b%p%%,%d°C]")
 120         (battery-status-function
 121          "[%b%p%%]"))
 122   "Control string formatting the string to display in the mode line.
 123 Ordinary characters in the control string are printed as-is, while
 124 conversion specifications introduced by a `%' character in the control
 125 string are substituted as defined by the current value of the variable
 126 `battery-status-function'.  Here are the ones generally available:
 127 %c Current capacity (mAh or mWh)
 128 %r Current rate of charge or discharge
 129 %B Battery status (verbose)
 130 %b Battery status: empty means high, `-' means low,
 131    `!' means critical, and `+' means charging
 132 %d Temperature (in degrees Celsius)
 133 %L AC line status (verbose)
 134 %p Battery load percentage
 135 %m Remaining time (to charge or discharge) in minutes
 136 %h Remaining time (to charge or discharge) in hours
 137 %t Remaining time (to charge or discharge) in the form `h:min'"
 138   :type '(choice string (const nil))
 139   :group 'battery)
 140
 141 (defcustom battery-update-interval 60
 142   "Seconds after which the battery status will be updated."
 143   :type 'integer
 144   :group 'battery)
 145
 146 (defcustom battery-load-low 25
 147   "Upper bound of low battery load percentage.
 148 A battery load percentage below this number is considered low."
 149   :type 'integer
 150   :group 'battery)
 151
 152 (defcustom battery-load-critical 10
 153   "Upper bound of critical battery load percentage.
 154 A battery load percentage below this number is considered critical."
 155   :type 'integer
 156   :group 'battery)
 157
 158 (defvar battery-update-timer nil
 159   "Interval timer object.")
 160
 161 ;;;###autoload
 162 (defun battery ()
 163   "Display battery status information in the echo area.
 164 The text being displayed in the echo area is controlled by the variables
 165 `battery-echo-area-format' and `battery-status-function'."
 166   (interactive)
 167   (message "%s" (if (and battery-echo-area-format battery-status-function)
 168                     (battery-format battery-echo-area-format
 169                                     (funcall battery-status-function))
 170                   "Battery status not available")))
 171
 172 ;;;###autoload
 173 (define-minor-mode display-battery-mode
 174   "Toggle battery status display in mode line (Display Battery mode).
 175 With a prefix argument ARG, enable Display Battery mode if ARG is
 176 positive, and disable it otherwise.  If called from Lisp, enable
 177 the mode if ARG is omitted or nil.
 178
 179 The text displayed in the mode line is controlled by
 180 `battery-mode-line-format' and `battery-status-function'.
 181 The mode line is be updated every `battery-update-interval'
 182 seconds."
 183   :global t :group 'battery
 184   (setq battery-mode-line-string "")
 185   (or global-mode-string (setq global-mode-string '("")))
 186   (and battery-update-timer (cancel-timer battery-update-timer))
 187   (if (and battery-status-function battery-mode-line-format)
 188       (if (not display-battery-mode)
 189           (setq global-mode-string
 190                 (delq 'battery-mode-line-string global-mode-string))
 191         (add-to-list 'global-mode-string 'battery-mode-line-string t)
 192         (setq battery-update-timer (run-at-time nil battery-update-interval
 193                                                 'battery-update-handler))
 194         (battery-update))
 195     (message "Battery status not available")
 196     (setq display-battery-mode nil)))
 197
 198 (defun battery-update-handler ()
 199   (battery-update)
 200   (sit-for 0))
 201
 202 (defun battery-update ()
 203   "Update battery status information in the mode line."
 204   (let ((data (and battery-status-function (funcall battery-status-function))))
 205     (setq battery-mode-line-string
 206           (propertize (if (and battery-mode-line-format
 207                                (<= (car (read-from-string (cdr (assq ?p data))))
 208                                    battery-mode-line-limit))
 209                           (battery-format
 210                            battery-mode-line-format
 211                            data)
 212                         "")
 213                       'face
 214                       (and (<= (car (read-from-string (cdr (assq ?p data))))
 215                                    battery-load-critical)
 216                            'error)
 217                       'help-echo "Battery status information")))
 218   (force-mode-line-update))
 219 \f
 220 ;;; `/proc/apm' interface for Linux.
 221
 222 (defconst battery-linux-proc-apm-regexp
 223   (concat "^\\([^ ]+\\)"                ; Driver version.
 224           " \\([^ ]+\\)"                ; APM BIOS version.
 225           " 0x\\([0-9a-f]+\\)"          ; APM BIOS flags.
 226           " 0x\\([0-9a-f]+\\)"          ; AC line status.
 227           " 0x\\([0-9a-f]+\\)"          ; Battery status.
 228           " 0x\\([0-9a-f]+\\)"          ; Battery flags.
 229           " \\(-?[0-9]+\\)%"            ; Load percentage.
 230           " \\(-?[0-9]+\\)"             ; Remaining time.
 231           " \\(.*\\)"                   ; Time unit.
 232           "$")
 233   "Regular expression matching contents of `/proc/apm'.")
 234
 235 (defun battery-linux-proc-apm ()
 236   "Get APM status information from Linux (the kernel).
 237 This function works only with the new `/proc/apm' format introduced
 238 in Linux version 1.3.58.
 239
 240 The following %-sequences are provided:
 241 %v Linux driver version
 242 %V APM BIOS version
 243 %I APM BIOS status (verbose)
 244 %L AC line status (verbose)
 245 %B Battery status (verbose)
 246 %b Battery status, empty means high, `-' means low,
 247    `!' means critical, and `+' means charging
 248 %p Battery load percentage
 249 %s Remaining time (to charge or discharge) in seconds
 250 %m Remaining time (to charge or discharge) in minutes
 251 %h Remaining time (to charge or discharge) in hours
 252 %t Remaining time (to charge or discharge) in the form `h:min'"
 253   (let (driver-version bios-version bios-interface line-status
 254         battery-status battery-status-symbol load-percentage
 255         seconds minutes hours remaining-time tem)
 256     (with-temp-buffer
 257       (ignore-errors (insert-file-contents "/proc/apm"))
 258       (when (re-search-forward battery-linux-proc-apm-regexp)
 259         (setq driver-version (match-string 1))
 260         (setq bios-version (match-string 2))
 261         (setq tem (string-to-number (match-string 3) 16))
 262         (if (not (logand tem 2))
 263             (setq bios-interface "not supported")
 264           (setq bios-interface "enabled")
 265           (cond ((logand tem 16) (setq bios-interface "disabled"))
 266                 ((logand tem 32) (setq bios-interface "disengaged")))
 267           (setq tem (string-to-number (match-string 4) 16))
 268           (cond ((= tem 0) (setq line-status "off-line"))
 269                 ((= tem 1) (setq line-status "on-line"))
 270                 ((= tem 2) (setq line-status "on backup")))
 271           (setq tem (string-to-number (match-string 6) 16))
 272           (if (= tem 255)
 273               (setq battery-status "N/A")
 274             (setq tem (string-to-number (match-string 5) 16))
 275             (cond ((= tem 0) (setq battery-status "high"
 276                                    battery-status-symbol ""))
 277                   ((= tem 1) (setq battery-status "low"
 278                                    battery-status-symbol "-"))
 279                   ((= tem 2) (setq battery-status "critical"
 280                                    battery-status-symbol "!"))
 281                   ((= tem 3) (setq battery-status "charging"
 282                                    battery-status-symbol "+")))
 283             (setq load-percentage (match-string 7))
 284             (setq seconds (string-to-number (match-string 8)))
 285             (and (string-equal (match-string 9) "min")
 286                  (setq seconds (* 60 seconds)))
 287             (setq minutes (/ seconds 60)
 288                   hours (/ seconds 3600))
 289             (setq remaining-time
 290                   (format "%d:%02d" hours (- minutes (* 60 hours))))))))
 291     (list (cons ?v (or driver-version "N/A"))
 292           (cons ?V (or bios-version "N/A"))
 293           (cons ?I (or bios-interface "N/A"))
 294           (cons ?L (or line-status "N/A"))
 295           (cons ?B (or battery-status "N/A"))
 296           (cons ?b (or battery-status-symbol ""))
 297           (cons ?p (or load-percentage "N/A"))
 298           (cons ?s (or (and seconds (number-to-string seconds)) "N/A"))
 299           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 300           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 301           (cons ?t (or remaining-time "N/A")))))
 302
 303 \f
 304 ;;; `/proc/acpi/' interface for Linux.
 305
 306 (defun battery-linux-proc-acpi ()
 307   "Get ACPI status information from Linux (the kernel).
 308 This function works only with the `/proc/acpi/' format introduced
 309 in Linux version 2.4.20 and 2.6.0.
 310
 311 The following %-sequences are provided:
 312 %c Current capacity (mAh)
 313 %r Current rate
 314 %B Battery status (verbose)
 315 %b Battery status, empty means high, `-' means low,
 316    `!' means critical, and `+' means charging
 317 %d Temperature (in degrees Celsius)
 318 %L AC line status (verbose)
 319 %p Battery load percentage
 320 %m Remaining time (to charge or discharge) in minutes
 321 %h Remaining time (to charge or discharge) in hours
 322 %t Remaining time (to charge or discharge) in the form `h:min'"
 323   (let ((design-capacity 0)
 324         (last-full-capacity 0)
 325         full-capacity
 326         (warn 0)
 327         (low 0)
 328         capacity rate rate-type charging-state minutes hours)
 329     ;; ACPI provides information about each battery present in the system in
 330     ;; a separate subdirectory.  We are going to merge the available
 331     ;; information together since displaying for a variable amount of
 332     ;; batteries seems overkill for format-strings.
 333     (with-temp-buffer
 334       (dolist (dir (ignore-errors (directory-files "/proc/acpi/battery/"
 335                                                    t "\\`[^.]")))
 336         (erase-buffer)
 337         (ignore-errors (insert-file-contents (expand-file-name "state" dir)))
 338         (when (re-search-forward "present: +yes$" nil t)
 339           (and (re-search-forward "charging state: +\\(.*\\)$" nil t)
 340                (member charging-state '("unknown" "charged" nil))
 341                ;; On most multi-battery systems, most of the time only one
 342                ;; battery is "charging"/"discharging", the others are
 343                ;; "unknown".
 344                (setq charging-state (match-string 1)))
 345           (when (re-search-forward "present rate: +\\([0-9]+\\) \\(m[AW]\\)$"
 346                                    nil t)
 347             (setq rate (+ (or rate 0) (string-to-number (match-string 1))))
 348             (when (> rate 0)
 349               (setq rate-type (or (and rate-type
 350                                      (if (string= rate-type (match-string 2))
 351                                          rate-type
 352                                        (error
 353                                         "Inconsistent rate types (%s vs. %s)"
 354                                         rate-type (match-string 2))))
 355                                   (match-string 2)))))
 356           (when (re-search-forward "remaining capacity: +\\([0-9]+\\) m[AW]h$"
 357                                    nil t)
 358             (setq capacity
 359                   (+ (or capacity 0) (string-to-number (match-string 1))))))
 360         (goto-char (point-max))
 361         (ignore-errors (insert-file-contents (expand-file-name "info" dir)))
 362         (when (re-search-forward "present: +yes$" nil t)
 363           (when (re-search-forward "design capacity: +\\([0-9]+\\) m[AW]h$"
 364                                    nil t)
 365             (cl-incf design-capacity (string-to-number (match-string 1))))
 366           (when (re-search-forward "last full capacity: +\\([0-9]+\\) m[AW]h$"
 367                                    nil t)
 368             (cl-incf last-full-capacity (string-to-number (match-string 1))))
 369           (when (re-search-forward
 370                  "design capacity warning: +\\([0-9]+\\) m[AW]h$" nil t)
 371             (cl-incf warn (string-to-number (match-string 1))))
 372           (when (re-search-forward "design capacity low: +\\([0-9]+\\) m[AW]h$"
 373                                    nil t)
 374             (cl-incf low (string-to-number (match-string 1)))))))
 375     (setq full-capacity (if (> last-full-capacity 0)
 376                             last-full-capacity design-capacity))
 377     (and capacity rate
 378          (setq minutes (if (zerop rate) 0
 379                          (floor (* (/ (float (if (string= charging-state
 380                                                           "charging")
 381                                                  (- full-capacity capacity)
 382                                                capacity))
 383                                       rate)
 384                                    60)))
 385                hours (/ minutes 60)))
 386     (list (cons ?c (or (and capacity (number-to-string capacity)) "N/A"))
 387           (cons ?L (or (battery-search-for-one-match-in-files
 388                         (mapcar (lambda (e) (concat e "/state"))
 389                                 (ignore-errors
 390                                   (directory-files "/proc/acpi/ac_adapter/"
 391                                                    t "\\`[^.]")))
 392                         "state: +\\(.*\\)$" 1)
 393
 394                        "N/A"))
 395           (cons ?d (or (battery-search-for-one-match-in-files
 396                         (mapcar (lambda (e) (concat e "/temperature"))
 397                                 (ignore-errors
 398                                   (directory-files "/proc/acpi/thermal_zone/"
 399                                                    t "\\`[^.]")))
 400                         "temperature: +\\([0-9]+\\) C$" 1)
 401
 402                        "N/A"))
 403           (cons ?r (or (and rate (concat (number-to-string rate) " "
 404                                          rate-type)) "N/A"))
 405           (cons ?B (or charging-state "N/A"))
 406           (cons ?b (or (and (string= charging-state "charging") "+")
 407                        (and capacity (< capacity low) "!")
 408                        (and capacity (< capacity warn) "-")
 409                        ""))
 410           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 411           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 412           (cons ?t (or (and minutes
 413                             (format "%d:%02d" hours (- minutes (* 60 hours))))
 414                        "N/A"))
 415           (cons ?p (or (and full-capacity capacity
 416                             (> full-capacity 0)
 417                             (number-to-string
 418                              (floor (/ capacity
 419                                        (/ (float full-capacity) 100)))))
 420                        "N/A")))))
 421
 422 \f
 423 ;;; `/sys/class/power_supply/BATN' interface for Linux.
 424
 425 (defun battery-linux-sysfs ()
 426   "Get ACPI status information from Linux kernel.
 427 This function works only with the new `/sys/class/power_supply/'
 428 format introduced in Linux version 2.4.25.
 429
 430 The following %-sequences are provided:
 431 %c Current capacity (mAh or mWh)
 432 %r Current rate
 433 %B Battery status (verbose)
 434 %d Temperature (in degrees Celsius)
 435 %p Battery load percentage
 436 %L AC line status (verbose)
 437 %m Remaining time (to charge or discharge) in minutes
 438 %h Remaining time (to charge or discharge) in hours
 439 %t Remaining time (to charge or discharge) in the form `h:min'"
 440   (let (charging-state rate temperature hours
 441         (charge-full 0.0)
 442         (charge-now 0.0)
 443         (energy-full 0.0)
 444         (energy-now 0.0))
 445     ;; SysFS provides information about each battery present in the
 446     ;; system in a separate subdirectory.  We are going to merge the
 447     ;; available information together.
 448     (with-temp-buffer
 449       (dolist (dir (ignore-errors
 450                     (directory-files
 451                      "/sys/class/power_supply/" t
 452                      battery--linux-sysfs-regexp)))
 453         (erase-buffer)
 454         (ignore-errors (insert-file-contents
 455                         (expand-file-name "uevent" dir)))
 456         (when (re-search-forward "POWER_SUPPLY_PRESENT=1$" nil t)
 457           (goto-char (point-min))
 458           (and (re-search-forward "POWER_SUPPLY_STATUS=\\(.*\\)$" nil t)
 459                (member charging-state '("Unknown" "Full" nil))
 460                (setq charging-state (match-string 1)))
 461           (when (re-search-forward
 462                  "POWER_SUPPLY_\\(CURRENT\\|POWER\\)_NOW=\\([0-9]*\\)$"
 463                  nil t)
 464             (setq rate (float (string-to-number (match-string 2)))))
 465           (when (re-search-forward "POWER_SUPPLY_TEMP=\\([0-9]*\\)$" nil t)
 466             (setq temperature (match-string 1)))
 467           (let (full-string now-string)
 468             ;; Sysfs may list either charge (mAh) or energy (mWh).
 469             ;; Keep track of both, and choose which to report later.
 470             (cond ((and (re-search-forward
 471                          "POWER_SUPPLY_CHARGE_FULL=\\([0-9]*\\)$" nil t)
 472                         (setq full-string (match-string 1))
 473                         (re-search-forward
 474                          "POWER_SUPPLY_CHARGE_NOW=\\([0-9]*\\)$" nil t)
 475                         (setq now-string (match-string 1)))
 476                    (setq charge-full (+ charge-full
 477                                         (string-to-number full-string))
 478                          charge-now  (+ charge-now
 479                                         (string-to-number now-string))))
 480                   ((and (re-search-forward
 481                          "POWER_SUPPLY_ENERGY_FULL=\\([0-9]*\\)$" nil t)
 482                         (setq full-string (match-string 1))
 483                         (re-search-forward
 484                          "POWER_SUPPLY_ENERGY_NOW=\\([0-9]*\\)$" nil t)
 485                         (setq now-string (match-string 1)))
 486                    (setq energy-full (+ energy-full
 487                                         (string-to-number full-string))
 488                          energy-now  (+ energy-now
 489                                         (string-to-number now-string))))))
 490           (goto-char (point-min))
 491           (when (and energy-now rate (not (zerop rate))
 492                      (re-search-forward
 493                       "POWER_SUPPLY_VOLTAGE_NOW=\\([0-9]*\\)$" nil t))
 494             (let ((remaining (if (string= charging-state "Discharging")
 495                                  energy-now
 496                                (- energy-full energy-now))))
 497               (setq hours (/ (/ (* remaining (string-to-number
 498                                               (match-string 1)))
 499                                 rate)
 500                              10000000.0)))))))
 501     (list (cons ?c (cond ((or (> charge-full 0) (> charge-now 0))
 502                           (number-to-string charge-now))
 503                          ((or (> energy-full 0) (> energy-now 0))
 504                           (number-to-string energy-now))
 505                          (t "N/A")))
 506           (cons ?r (if rate (format "%.1f" (/ rate 1000000.0)) "N/A"))
 507           (cons ?m (if hours (format "%d" (* hours 60)) "N/A"))
 508           (cons ?h (if hours (format "%d" hours) "N/A"))
 509           (cons ?t (if hours
 510                        (format "%d:%02d" hours (* (- hours (floor hours)) 60))
 511                      "N/A"))
 512           (cons ?d (or temperature "N/A"))
 513           (cons ?B (or charging-state "N/A"))
 514           (cons ?p (cond ((and (> charge-full 0) (> charge-now 0))
 515                           (format "%.1f"
 516                                   (/ (* 100 charge-now) charge-full)))
 517                          ((> energy-full 0)
 518                           (format "%.1f"
 519                                   (/ (* 100 energy-now) energy-full)))
 520                          (t "N/A")))
 521           (cons ?L (if (file-readable-p "/sys/class/power_supply/AC/online")
 522                        (if (battery-search-for-one-match-in-files
 523                             (list "/sys/class/power_supply/AC/online"
 524                                   "/sys/class/power_supply/ACAD/online")
 525                             "1" 0)
 526                            "AC"
 527                          "BAT")
 528                      "N/A")))))
 529
 530 \f
 531 ;;; `apm' interface for BSD.
 532 (defun battery-bsd-apm ()
 533   "Get APM status information from BSD apm binary.
 534 The following %-sequences are provided:
 535 %L AC line status (verbose)
 536 %B Battery status (verbose)
 537 %b Battery status, empty means high, `-' means low,
 538  `!' means critical, and `+' means charging
 539 %P Advanced power saving mode state (verbose)
 540 %p Battery charge percentage
 541 %s Remaining battery charge time in seconds
 542 %m Remaining battery charge time in minutes
 543 %h Remaining battery charge time in hours
 544 %t Remaining battery charge time in the form `h:min'"
 545   (let* ((os-name (car (split-string
 546                         (shell-command-to-string "/usr/bin/uname"))))
 547          (apm-flag (if (equal os-name "OpenBSD") "P" "s"))
 548          (apm-cmd (concat "/usr/sbin/apm -ablm" apm-flag))
 549          (apm-output (split-string (shell-command-to-string apm-cmd)))
 550          ;; Battery status
 551          (battery-status
 552           (let ((stat (string-to-number (nth 0 apm-output))))
 553             (cond ((eq stat 0) '("high" . ""))
 554                   ((eq stat 1) '("low" . "-"))
 555                   ((eq stat 2) '("critical" . "!"))
 556                   ((eq stat 3) '("charging" . "+"))
 557                   ((eq stat 4) '("absent" . nil)))))
 558          ;; Battery percentage
 559          (battery-percentage (nth 1 apm-output))
 560          ;; Battery life
 561          (battery-life (nth 2 apm-output))
 562          ;; AC status
 563          (line-status
 564           (let ((ac (string-to-number (nth 3 apm-output))))
 565             (cond ((eq ac 0) "disconnected")
 566                   ((eq ac 1) "connected")
 567                   ((eq ac 2) "backup power"))))
 568          ;; Advanced power savings mode
 569          (apm-mode
 570           (let ((apm (string-to-number (nth 4 apm-output))))
 571             (if (string= os-name "OpenBSD")
 572                 (cond ((eq apm 0) "manual")
 573                       ((eq apm 1) "automatic")
 574                       ((eq apm 2) "cool running"))
 575               (if (eq apm 1) "on" "off"))))
 576          seconds minutes hours remaining-time)
 577     (unless (member battery-life '("unknown" "-1"))
 578       (if (member os-name '("OpenBSD" "NetBSD"))
 579           (setq minutes (string-to-number battery-life)
 580                 seconds (* 60 minutes))
 581         (setq seconds (string-to-number battery-life)
 582               minutes (truncate (/ seconds 60))))
 583       (setq hours (truncate (/ minutes 60))
 584             remaining-time (format "%d:%02d" hours
 585                                    (- minutes (* 60 hours)))))
 586     (list (cons ?L (or line-status "N/A"))
 587           (cons ?B (or (car battery-status) "N/A"))
 588           (cons ?b (or (cdr battery-status) "N/A"))
 589           (cons ?p (if (string= battery-percentage "255")
 590                        "N/A"
 591                      battery-percentage))
 592           (cons ?P (or apm-mode "N/A"))
 593           (cons ?s (or (and seconds (number-to-string seconds)) "N/A"))
 594           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 595           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 596           (cons ?t (or remaining-time "N/A")))))
 597
 598 \f
 599 ;;; `pmset' interface for Darwin (OS X).
 600
 601 (defun battery-pmset ()
 602   "Get battery status information using `pmset'.
 603
 604 The following %-sequences are provided:
 605 %L Power source (verbose)
 606 %B Battery status (verbose)
 607 %b Battery status, empty means high, `-' means low,
 608    `!' means critical, and `+' means charging
 609 %p Battery load percentage
 610 %h Remaining time in hours
 611 %m Remaining time in minutes
 612 %t Remaining time in the form `h:min'"
 613   (let (power-source load-percentage battery-status battery-status-symbol
 614         remaining-time hours minutes)
 615     (with-temp-buffer
 616       (ignore-errors (call-process "pmset" nil t nil "-g" "ps"))
 617       (goto-char (point-min))
 618       (when (re-search-forward "\\(?:Currentl?y\\|Now\\) drawing from '\\(AC\\|Battery\\) Power'" nil t)
 619         (setq power-source (match-string 1))
 620         (when (re-search-forward "^ -InternalBattery-0[ \t]+" nil t)
 621           (when (looking-at "\\([0-9]\\{1,3\\}\\)%")
 622             (setq load-percentage (match-string 1))
 623             (goto-char (match-end 0))
 624             (cond ((looking-at "; charging")
 625                    (setq battery-status "charging"
 626                          battery-status-symbol "+"))
 627                   ((< (string-to-number load-percentage) battery-load-low)
 628                    (setq battery-status "low"
 629                          battery-status-symbol "-"))
 630                   ((< (string-to-number load-percentage) battery-load-critical)
 631                    (setq battery-status "critical"
 632                          battery-status-symbol "!"))
 633                   (t
 634                    (setq battery-status "high"
 635                          battery-status-symbol "")))
 636             (when (re-search-forward "\\(\\([0-9]+\\):\\([0-9]+\\)\\) remaining"  nil t)
 637               (setq remaining-time (match-string 1))
 638               (let ((h (string-to-number (match-string 2)))
 639                     (m (string-to-number (match-string 3))))
 640                 (setq hours (number-to-string (+ h (if (< m 30) 0 1)))
 641                       minutes (number-to-string (+ (* h 60) m)))))))))
 642     (list (cons ?L (or power-source "N/A"))
 643           (cons ?p (or load-percentage "N/A"))
 644           (cons ?B (or battery-status "N/A"))
 645           (cons ?b (or battery-status-symbol ""))
 646           (cons ?h (or hours "N/A"))
 647           (cons ?m (or minutes "N/A"))
 648           (cons ?t (or remaining-time "N/A")))))
 649
 650 \f
 651 ;;; Private functions.
 652
 653 (defun battery-format (format alist)
 654   "Substitute %-sequences in FORMAT."
 655   (replace-regexp-in-string
 656    "%."
 657    (lambda (str)
 658      (let ((char (aref str 1)))
 659        (if (eq char ?%) "%"
 660          (or (cdr (assoc char alist)) ""))))
 661    format t t))
 662
 663 (defun battery-search-for-one-match-in-files (files regexp match-num)
 664   "Search REGEXP in the content of the files listed in FILES.
 665 If a match occurred, return the parenthesized expression numbered by
 666 MATCH-NUM in the match.  Otherwise, return nil."
 667   (with-temp-buffer
 668     (catch 'found
 669       (dolist (file files)
 670         (and (ignore-errors (insert-file-contents file nil nil nil 'replace))
 671              (re-search-forward regexp nil t)
 672              (throw 'found (match-string match-num)))))))
 673
 674 \f
 675 (provide 'battery)
 676
 677 ;;; battery.el ends here