configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## Makefile.in needs the cache file name.
 186 AC_SUBST(cache_file)
 187
 188 ## This is an option because I do not know if all info/man support
 189 ## compressed files, nor how to test if they do so.
 190 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 191 if test $with_compress_info = yes; then
 192    GZIP_INFO=yes
 193 else
 194    GZIP_INFO=
 195 fi
 196 AC_SUBST(GZIP_INFO)
 197
 198 AC_ARG_WITH([pkg-config-prog],dnl
 199 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 200                   [path to pkg-config for finding GTK and librsvg])])
 201 if test "X${with_pkg_config_prog}" != X; then
 202    if test "${with_pkg_config_prog}" != yes; then
 203       PKG_CONFIG="${with_pkg_config_prog}"
 204    fi
 205 fi
 206
 207 CRT_DIR=
 208 AC_ARG_WITH([crt-dir],dnl
 209 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 210 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 211 CRT_DIR="${with_crt_dir}"
 212
 213 AC_ARG_WITH(gameuser,dnl
 214 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 215 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 216   && gameuser="${with_gameuser}"
 217 test "X$gameuser" = X && gameuser=games
 218
 219 AC_ARG_WITH([gnustep-conf],dnl
 220 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 221 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 222   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 223 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 224      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 225
 226 AC_ARG_ENABLE(ns-self-contained,
 227 [AS_HELP_STRING([--disable-ns-self-contained],
 228                 [disable self contained build under NeXTstep])],
 229    EN_NS_SELF_CONTAINED=$enableval,
 230    EN_NS_SELF_CONTAINED=yes)
 231
 232 AC_ARG_ENABLE(asserts,
 233 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 234       USE_XASSERTS=$enableval,
 235       USE_XASSERTS=no)
 236
 237 AC_ARG_ENABLE(maintainer-mode,
 238 [AS_HELP_STRING([--disable-maintainer-mode],
 239                 [disable make rules and dependencies not useful (and sometimes
 240                  confusing) to the casual installer])],
 241       USE_MAINTAINER_MODE=$enableval,
 242       USE_MAINTAINER_MODE=yes)
 243 if test $USE_MAINTAINER_MODE = yes; then
 244   MAINT=
 245 else
 246   MAINT=#
 247 fi
 248 AC_SUBST(MAINT)
 249
 250 AC_ARG_ENABLE(locallisppath,
 251 [AS_HELP_STRING([--enable-locallisppath=PATH],
 252                 [directories Emacs should search for lisp files specific
 253                  to this site])],
 254 if test "${enableval}" = "no"; then
 255   locallisppath=
 256 elif test "${enableval}" != "yes"; then
 257   locallisppath=${enableval}
 258 fi)
 259
 260 AC_ARG_ENABLE(checking,
 261 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 262                 [enable expensive run-time checks.  With LIST,
 263                  enable only specific categories of checks.
 264                  Categories are: all,yes,no.
 265                  Flags are: stringbytes, stringoverrun, stringfreelist,
 266                  xmallocoverrun, conslist])],
 267 [ac_checking_flags="${enableval}"],[])
 268 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 269 for check in $ac_checking_flags
 270 do
 271         case $check in
 272         # these set all the flags to specific states
 273         yes)            ac_enable_checking=1 ;;
 274         no)             ac_enable_checking= ;
 275                         ac_gc_check_stringbytes= ;
 276                         ac_gc_check_string_overrun= ;
 277                         ac_gc_check_string_free_list= ;
 278                         ac_xmalloc_overrun= ;
 279                         ac_gc_check_cons_list= ;;
 280         all)            ac_enable_checking=1 ;
 281                         ac_gc_check_stringbytes=1 ;
 282                         ac_gc_check_string_overrun=1 ;
 283                         ac_gc_check_string_free_list=1 ;
 284                         ac_xmalloc_overrun=1 ;
 285                         ac_gc_check_cons_list=1 ;;
 286         # these enable particular checks
 287         stringbytes)    ac_gc_check_stringbytes=1 ;;
 288         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 289         stringfreelist) ac_gc_check_string_free_list=1 ;;
 290         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 291         conslist)       ac_gc_check_cons_list=1 ;;
 292         *)      AC_MSG_ERROR(unknown check category $check) ;;
 293         esac
 294 done
 295 IFS="$ac_save_IFS"
 296
 297 if test x$ac_enable_checking != x ; then
 298   AC_DEFINE(ENABLE_CHECKING, 1,
 299 [Enable expensive run-time checking of data types?])
 300 fi
 301 if test x$ac_gc_check_stringbytes != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 303 [Define this temporarily to hunt a bug.  If defined, the size of
 304    strings is redundantly recorded in sdata structures so that it can
 305    be compared to the sizes recorded in Lisp strings.])
 306 fi
 307 if test x$ac_gc_check_string_overrun != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 309 [Define this to check for short string overrun.])
 310 fi
 311 if test x$ac_gc_check_string_free_list != x ; then
 312   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 313 [Define this to check the string free list.])
 314 fi
 315 if test x$ac_xmalloc_overrun != x ; then
 316   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 317 [Define this to check for malloc buffer overrun.])
 318 fi
 319 if test x$ac_gc_check_cons_list != x ; then
 320   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 321 [Define this to check for errors in cons list.])
 322 fi
 323
 324 AC_ARG_ENABLE(use-lisp-union-type,
 325 [AS_HELP_STRING([--enable-use-lisp-union-type],
 326                 [use a union for the Lisp_Object data type.
 327                 This is only useful for development for catching certain types of bugs.])],
 328 if test "${enableval}" != "no"; then
 329    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 330    [Define this to use a lisp union for the Lisp_Object data type.])
 331 fi)
 332
 333
 334 AC_ARG_ENABLE(profiling,
 335 [AS_HELP_STRING([--enable-profiling],
 336                 [build emacs with profiling support.
 337                  This might not work on all platforms])],
 338 [ac_enable_profiling="${enableval}"],[])
 339 if test x$ac_enable_profiling != x ; then
 340    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 341 else
 342    PROFILING_CFLAGS=
 343 fi
 344 AC_SUBST(PROFILING_CFLAGS)
 345
 346 AC_ARG_ENABLE(autodepend,
 347 [AS_HELP_STRING([--enable-autodepend],
 348                 [automatically generate dependencies to .h-files.
 349                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 350                  found])],
 351 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 352
 353 #### Make srcdir absolute, if it isn't already.  It's important to
 354 #### avoid running the path through pwd unnecessarily, since pwd can
 355 #### give you automounter prefixes, which can go away.  We do all this
 356 #### so Emacs can find its files when run uninstalled.
 357 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 358 unset CDPATH
 359 case "${srcdir}" in
 360   /* ) ;;
 361   . )
 362     ## We may be able to use the $PWD environment variable to make this
 363     ## absolute.  But sometimes PWD is inaccurate.
 364     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 365     ## but that tested only for a well-formed and valid PWD,
 366     ## it did not object when PWD was well-formed and valid but just wrong.
 367     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 368     then
 369       srcdir="$PWD"
 370     else
 371       srcdir="`(cd ${srcdir}; pwd)`"
 372     fi
 373   ;;
 374   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 375 esac
 376
 377 #### Given the configuration name, set machfile and opsysfile to the
 378 #### names of the m/*.h and s/*.h files we should use.
 379
 380 ### Canonicalize the configuration name.
 381
 382 AC_CANONICAL_HOST
 383 canonical=$host
 384 configuration=${host_alias-${build_alias-$host}}
 385
 386 dnl This used to use changequote, but, apart from `changequote is evil'
 387 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 388 dnl the great gob of text.  Thus it's not processed for possible expansion.
 389 dnl Just make sure the brackets remain balanced.
 390 dnl
 391 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 392 dnl indicated by comments.
 393 dnl quotation begins
 394 [
 395
 396 ### If you add support for a new configuration, add code to this
 397 ### switch statement to recognize your configuration name and select
 398 ### the appropriate operating system and machine description files.
 399
 400 ### You would hope that you could choose an m/*.h file pretty much
 401 ### based on the machine portion of the configuration name, and an s/*.h
 402 ### file based on the operating system portion.  However, it turns out
 403 ### that each m/*.h file is pretty manufacturer-specific - for
 404 ### example mips.h is MIPS
 405 ### So we basically have to have a special case for each
 406 ### configuration name.
 407 ###
 408 ### As far as handling version numbers on operating systems is
 409 ### concerned, make sure things will fail in a fixable way.  If
 410 ### /etc/MACHINES doesn't say anything about version numbers, be
 411 ### prepared to handle anything reasonably.  If version numbers
 412 ### matter, be sure /etc/MACHINES says something about it.
 413
 414 machine='' opsys='' unported=no
 415 case "${canonical}" in
 416
 417   ## GNU/Linux and similar ports
 418   *-*-linux* )
 419     opsys=gnu-linux
 420     case ${canonical} in
 421       alpha*)   machine=alpha ;;
 422       s390x-*)  machine=ibms390x ;;
 423       powerpc*) machine=macppc ;;
 424       sparc*)   machine=sparc ;;
 425       ia64*)    machine=ia64 ;;
 426       m68k*)    machine=m68k ;;
 427       x86_64*)  machine=amdx86-64 ;;
 428     esac
 429   ;;
 430
 431   ## FreeBSD ports
 432   *-*-freebsd* )
 433     opsys=freebsd
 434     case "${canonical}" in
 435       alpha*)           machine=alpha ;;
 436       amd64-*|x86_64-*) machine=amdx86-64 ;;
 437       ia64-*)           machine=ia64 ;;
 438       i[3456]86-*)      machine=intel386 ;;
 439       powerpc-*)        machine=macppc ;;
 440       sparc-*)          machine=sparc ;;
 441       sparc64-*)        machine=sparc ;;
 442     esac
 443   ;;
 444
 445   ## FreeBSD kernel + glibc based userland
 446   *-*-kfreebsd*gnu* )
 447     opsys=gnu-kfreebsd
 448     case "${canonical}" in
 449       alpha*)           machine=alpha ;;
 450       amd64-*|x86_64-*) machine=amdx86-64 ;;
 451       ia64-*)           machine=ia64 ;;
 452       i[3456]86-*)      machine=intel386 ;;
 453       powerpc-*)        machine=macppc ;;
 454       sparc-*)          machine=sparc ;;
 455       sparc64-*)        machine=sparc ;;
 456     esac
 457   ;;
 458
 459   ## NetBSD ports
 460   *-*-netbsd* )
 461     opsys=netbsd
 462     case "${canonical}" in
 463       alpha*)      machine=alpha ;;
 464       x86_64-*)    machine=amdx86-64 ;;
 465       i[3456]86-*) machine=intel386 ;;
 466       m68k-*)      machine=m68k ;;
 467       powerpc-*)   machine=macppc ;;
 468       sparc*-)     machine=sparc ;;
 469       vax-*)       machine=vax ;;
 470     esac
 471   ;;
 472
 473   ## OpenBSD ports
 474   *-*-openbsd* )
 475     opsys=openbsd
 476     case "${canonical}" in
 477       alpha*)    machine=alpha ;;
 478       x86_64-*)  machine=amdx86-64 ;;
 479       i386-*)    machine=intel386 ;;
 480       powerpc-*) machine=macppc ;;
 481       sparc*)    machine=sparc ;;
 482       vax-*)     machine=vax ;;
 483     esac
 484   ;;
 485
 486   ## Apple Darwin / Mac OS X
 487   *-apple-darwin* )
 488     case "${canonical}" in
 489       i[3456]86-* )  machine=intel386 ;;
 490       powerpc-* )    machine=macppc ;;
 491       x86_64-* )     machine=amdx86-64 ;;
 492       * )            unported=yes ;;
 493     esac
 494     opsys=darwin
 495     ## Use fink packages if available.
 496     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 497 ##    if test -d /sw/include && test -d /sw/lib; then
 498 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 499 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 500 ##    fi
 501   ;;
 502
 503   ## HP 9000 series 700 and 800, running HP/UX
 504   hppa*-hp-hpux10.2* )
 505     opsys=hpux10-20
 506   ;;
 507   hppa*-hp-hpux1[1-9]* )
 508     opsys=hpux11
 509     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 510   ;;
 511
 512   ## IBM machines
 513   rs6000-ibm-aix4.[23]* )
 514     machine=ibmrs6000 opsys=aix4-2
 515   ;;
 516   powerpc-ibm-aix4.[23]*  )
 517     machine=ibmrs6000 opsys=aix4-2
 518   ;;
 519   rs6000-ibm-aix[56]* )
 520     machine=ibmrs6000 opsys=aix4-2
 521   ;;
 522   powerpc-ibm-aix[56]*  )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525
 526   ## Silicon Graphics machines
 527   ## Iris 4D
 528   mips-sgi-irix6.5 )
 529     opsys=irix6-5
 530     # Without defining _LANGUAGE_C, things get masked out in the headers
 531     # so that, for instance, grepping for `free' in stdlib.h fails and
 532     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 533     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 534   ;;
 535
 536   ## Suns
 537   *-sun-solaris* \
 538     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 539     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 540     case "${canonical}" in
 541       i[3456]86-*-* )     machine=intel386 ;;
 542       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 543       sparc* )          machine=sparc ;;
 544       * )               unported=yes ;;
 545     esac
 546     case "${canonical}" in
 547       *-sunos5.6* | *-solaris2.6* )
 548                 opsys=sol2-6
 549                 RANLIB="ar -ts"
 550                 ;;
 551       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 552                 opsys=sol2-6
 553                 emacs_check_sunpro_c=yes
 554                 ;;
 555       *-sunos5* | *-solaris* )
 556                 opsys=sol2-10
 557                 emacs_check_sunpro_c=yes
 558                 ;;
 559     esac
 560     ## Watch out for a compiler that we know will not work.
 561     case "${canonical}" in
 562      *-solaris* | *-sunos5* )
 563                 if [ "x$CC" = x/usr/ucb/cc ]; then
 564                   ## /usr/ucb/cc doesn't work;
 565                   ## we should find some other compiler that does work.
 566                   unset CC
 567                 fi
 568                 ;;
 569       *) ;;
 570     esac
 571   ;;
 572
 573   ## Intel 386 machines where we don't care about the manufacturer.
 574   i[3456]86-*-* )
 575     machine=intel386
 576     case "${canonical}" in
 577       *-cygwin )                opsys=cygwin ;;
 578       *-darwin* )               opsys=darwin ;;
 579       *-sysv4.2uw* )            opsys=unixware ;;
 580       *-sysv5uw* )              opsys=unixware ;;
 581       *-sysv5OpenUNIX* )        opsys=unixware ;;
 582       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 583     esac
 584   ;;
 585
 586   * )
 587     unported=yes
 588   ;;
 589 esac
 590
 591 ### If the code above didn't choose an operating system, just choose
 592 ### an operating system based on the configuration name.  You really
 593 ### only want to use this when you have no idea what the right
 594 ### operating system is; if you know what operating systems a machine
 595 ### runs, it's cleaner to make it explicit in the case statement
 596 ### above.
 597 if test x"${opsys}" = x; then
 598   case "${canonical}" in
 599     *-gnu* )                            opsys=gnu ;;
 600     * )
 601       unported=yes
 602     ;;
 603   esac
 604 fi
 605
 606 ]
 607 dnl quotation ends
 608
 609 if test $unported = yes; then
 610   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 611 Check `etc/MACHINES' for recognized configuration names.])
 612 fi
 613
 614 if test -n "$machine"; then
 615   machfile="m/${machine}.h"
 616 else
 617   machfile=
 618 fi
 619 opsysfile="s/${opsys}.h"
 620
 621
 622 #### Choose a compiler.
 623
 624 dnl Sets GCC=yes if using gcc.
 625 AC_PROG_CC
 626 AM_PROG_CC_C_O
 627
 628 if test x$GCC = xyes; then
 629   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 630 else
 631   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 632 fi
 633
 634 # Initialize gnulib right after choosing the compiler.
 635 gl_EARLY
 636
 637 AC_ARG_ENABLE([gcc-warnings],
 638   [AS_HELP_STRING([--enable-gcc-warnings],
 639                   [turn on lots of GCC warnings (for developers)])],
 640   [case $enableval in
 641      yes|no) ;;
 642      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 643    esac
 644    gl_gcc_warnings=$enableval],
 645   [gl_gcc_warnings=no]
 646 )
 647
 648 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 649 # ------------------------------------------------
 650 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 651 # Otherwise, run RUN-IF-NOT-FOUND.
 652 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 653   [AC_PREPROC_IFELSE(
 654     [AC_LANG_PROGRAM(
 655       [[
 656 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 657 /* ok */
 658 #else
 659 # error "your version of gcc is older than $1.$2"
 660 #endif
 661       ]]),
 662     ], [$3], [$4])
 663   ]
 664 )
 665
 666 # When compiling with GCC, prefer -isystem to -I when including system
 667 # include files, to avoid generating useless diagnostics for the files.
 668 if test "$gl_gcc_warnings" != yes; then
 669   isystem='-I'
 670 else
 671   isystem='-isystem '
 672
 673   # This, $nw, is the list of warnings we disable.
 674   nw=
 675
 676   case $with_x_toolkit in
 677     lucid | athena | motif)
 678        # Old toolkits mishandle 'const'.
 679        nw="$nw -Wwrite-strings"
 680        ;;
 681     *)
 682        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 683        ;;
 684   esac
 685   AC_SUBST([WERROR_CFLAGS])
 686
 687   nw="$nw -Waggregate-return"       # anachronistic
 688   nw="$nw -Wlong-long"              # C90 is anachronistic
 689   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 690   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 691   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 692   nw="$nw -Wcast-qual"              # Too many warnings for now
 693   nw="$nw -Wconversion"             # Too many warnings for now
 694   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 695   nw="$nw -Wsign-conversion"        # Too many warnings for now
 696   nw="$nw -Woverlength-strings"     # Not a problem these days
 697   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 698   nw="$nw -Wpadded"                 # Our structs are not padded
 699   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 700   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 701   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 702   nw="$nw -Wvla"                    # warnings in gettext.h
 703   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 704   nw="$nw -Wswitch-enum"            # Too many warnings for now
 705   nw="$nw -Wswitch-default"         # Too many warnings for now
 706   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 707   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 708
 709   # Emacs doesn't care about shadowing; see
 710   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 711   nw="$nw -Wshadow"
 712
 713   # The following lines should be removable at some point.
 714   nw="$nw -Wstack-protector"
 715   nw="$nw -Wstrict-overflow"
 716   nw="$nw -Wsuggest-attribute=const"
 717   nw="$nw -Wsuggest-attribute=pure"
 718
 719   gl_MANYWARN_ALL_GCC([ws])
 720   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 721   for w in $ws; do
 722     gl_WARN_ADD([$w])
 723   done
 724   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 725   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 726   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 727   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 728   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 729   gl_WARN_ADD([-Wno-format-nonliteral])
 730
 731   # In spite of excluding -Wlogical-op above, it is enabled, as of
 732   # gcc 4.5.0 20090517.
 733   gl_WARN_ADD([-Wno-logical-op])
 734
 735   gl_WARN_ADD([-fdiagnostics-show-option])
 736   gl_WARN_ADD([-funit-at-a-time])
 737
 738   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 739   AC_DEFINE([_FORTIFY_SOURCE], [2],
 740     [enable compile-time and run-time bounds-checking, and some warnings])
 741   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 742
 743   # We use a slightly smaller set of warning options for lib/.
 744   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 745   nw=
 746   nw="$nw -Wunused-macros"
 747
 748   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 749   AC_SUBST([GNULIB_WARN_CFLAGS])
 750 fi
 751
 752
 753
 754 dnl Some other nice autoconf tests.
 755 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 756 dnl AC_PROG_INSTALL
 757 dnl AC_PROG_MKDIR_P
 758 dnl if test "x$RANLIB" = x; then
 759 dnl   AC_PROG_RANLIB
 760 dnl fi
 761
 762 ## Although we're running on an amd64 kernel, we're actually compiling for
 763 ## the x86 architecture.  The user should probably have provided an
 764 ## explicit --build to `configure', but if everything else than the kernel
 765 ## is running in i386 mode, we can help them out.
 766 if test "$machine" = "amdx86-64"; then
 767   AC_CHECK_DECL([i386])
 768   if test "$ac_cv_have_decl_i386" = "yes"; then
 769     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 770     machine=intel386
 771     machfile="m/${machine}.h"
 772   fi
 773 fi
 774
 775 AC_PATH_PROG(INSTALL_INFO, install-info)
 776 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 777 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 778 dnl Don't use GZIP, which is used by gzip for additional parameters.
 779 AC_PATH_PROG(GZIP_PROG, gzip)
 780
 781
 782 ## Need makeinfo >= 4.7 (?) to build the manuals.
 783 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 784 dnl By this stage, configure has already checked for egrep and set EGREP,
 785 dnl or exited with an error if no egrep was found.
 786 if test "$MAKEINFO" != "no" && \
 787   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 788    MAKEINFO=no
 789 fi
 790
 791 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 792 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 793 ## therefore in the category of "special tools" not normally required, which
 794 ## configure does not have to check for (eg autoconf itself).
 795 ## In a Bazaar checkout on the other hand, the manuals are not included.
 796 ## So makeinfo is a requirement to build from Bazaar, and configure
 797 ## should test for it as it does for any other build requirement.
 798 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 799 ## with pre-built manuals, from a Bazaar checkout.
 800 HAVE_MAKEINFO=yes
 801
 802 if test "$MAKEINFO" = "no"; then
 803   MAKEINFO=makeinfo
 804   if test "x${with_makeinfo}" = "xno"; then
 805     HAVE_MAKEINFO=no
 806   elif test ! -e $srcdir/info/emacs; then
 807     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 808 source tree does not seem to have pre-built manuals in the `info' directory.
 809 Either install a suitable version of makeinfo, or re-run configure
 810 with the `--without-makeinfo' option to build without the manuals.] )
 811   fi
 812 fi
 813 AC_SUBST(HAVE_MAKEINFO)
 814
 815 dnl Just so that there is only a single place we need to edit.
 816 INFO_EXT=.info
 817 INFO_OPTS=--no-split
 818 AC_SUBST(INFO_EXT)
 819 AC_SUBST(INFO_OPTS)
 820
 821 dnl Add our options to ac_link now, after it is set up.
 822
 823 if test x$GCC = xyes; then
 824   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 825     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 826 else
 827   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 828     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 829 fi
 830
 831 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 832 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 833 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 834 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 835 dnl if not built to support GNU ld.
 836
 837 late_LDFLAGS=$LDFLAGS
 838 if test x$GCC = xyes; then
 839   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 840 else
 841   LDFLAGS="$LDFLAGS -znocombreloc"
 842 fi
 843
 844 AC_MSG_CHECKING([for -znocombreloc])
 845 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 846   [AC_MSG_RESULT(yes)],
 847   LDFLAGS=$late_LDFLAGS
 848   [AC_MSG_RESULT(no)])
 849
 850
 851 dnl The function dump-emacs will not be defined and temacs will do
 852 dnl (load "loadup") automatically unless told otherwise.
 853 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 854 case "$opsys" in
 855   your-opsys-here) CANNOT_DUMP=yes ;;
 856 esac
 857
 858 test "$CANNOT_DUMP" = "yes" && \
 859   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 860
 861 AC_SUBST(CANNOT_DUMP)
 862
 863
 864 UNEXEC_OBJ=unexelf.o
 865 case "$opsys" in
 866   # MSDOS uses unexcoff.o
 867   # MSWindows uses unexw32.o
 868   aix4-2)
 869    UNEXEC_OBJ=unexaix.o
 870    ;;
 871   cygwin)
 872    UNEXEC_OBJ=unexcw.o
 873    ;;
 874   darwin)
 875    UNEXEC_OBJ=unexmacosx.o
 876    ;;
 877   hpux10-20 | hpux11)
 878    UNEXEC_OBJ=unexhp9k800.o
 879    ;;
 880   sol2-10)
 881    # Use the Solaris dldump() function, called from unexsol.c, to dump
 882    # emacs, instead of the generic ELF dump code found in unexelf.c.
 883    # The resulting binary has a complete symbol table, and is better
 884    # for debugging and other observability tools (debuggers, pstack, etc).
 885    #
 886    # If you encounter a problem using dldump(), please consider sending
 887    # a message to the OpenSolaris tools-linking mailing list:
 888    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 889    #
 890    # It is likely that dldump() works with older Solaris too, but this has
 891    # not been tested, so for now this change is for Solaris 10 or newer.
 892    UNEXEC_OBJ=unexsol.o
 893    ;;
 894 esac
 895
 896 LD_SWITCH_SYSTEM=
 897 case "$opsys" in
 898   freebsd)
 899    ## Let `ld' find image libs and similar things in /usr/local/lib.
 900    ## The system compiler, GCC, has apparently been modified to not
 901    ## look there, contrary to what a stock GCC would do.
 902 ### It's not our place to do this.  See bug#10313#17.
 903 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 904       :
 905    ;;
 906
 907   gnu-linux)
 908    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 909    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 910    ;;
 911
 912   netbsd)
 913 ### It's not our place to do this.  See bug#10313#17.
 914 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 915       :
 916    ;;
 917
 918   openbsd)
 919    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 920    ## otherwise Emacs dumps core on elf systems.
 921    LD_SWITCH_SYSTEM="-Z"
 922    ;;
 923 esac
 924 AC_SUBST(LD_SWITCH_SYSTEM)
 925
 926 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 927
 928 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 929 ## which has not been defined yet.  When this was handled with cpp,
 930 ## it was expanded to null when configure sourced the s/*.h file.
 931 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 932 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 933 ## (or somesuch), but because it is supposed to go at the _front_
 934 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 935 ## Compare with the gnu-linux case below, which added to the end
 936 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 937 ## LD_SWITCH_SYSTEM_TEMACS.
 938 case "$opsys" in
 939   netbsd|openbsd)
 940    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 941 esac
 942
 943
 944 C_SWITCH_MACHINE=
 945 if test "$machine" = "alpha"; then
 946   AC_CHECK_DECL([__ELF__])
 947   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 948     ## With ELF, make sure that all common symbols get allocated to in the
 949     ## data section.  Otherwise, the dump of temacs may miss variables in
 950     ## the shared library that have been initialized.  For example, with
 951     ## GNU libc, __malloc_initialized would normally be resolved to the
 952     ## shared library's .bss section, which is fatal.
 953     if test "x$GCC" = "xyes"; then
 954       C_SWITCH_MACHINE="-fno-common"
 955     else
 956       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 957     fi
 958   else
 959     UNEXEC_OBJ=unexalpha.o
 960   fi
 961 fi
 962 AC_SUBST(C_SWITCH_MACHINE)
 963
 964 AC_SUBST(UNEXEC_OBJ)
 965
 966 C_SWITCH_SYSTEM=
 967 ## Some programs in src produce warnings saying certain subprograms
 968 ## are too complex and need a MAXMEM value greater than 2000 for
 969 ## additional optimization.  --nils@exp-math.uni-essen.de
 970 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 971   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 972 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 973 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 974 AC_SUBST(C_SWITCH_SYSTEM)
 975
 976
 977 LIBS_SYSTEM=
 978 case "$opsys" in
 979   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 980   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 981
 982   freebsd) LIBS_SYSTEM="-lutil" ;;
 983
 984   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 985
 986   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 987
 988   ## Motif needs -lgen.
 989   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 990 esac
 991 AC_SUBST(LIBS_SYSTEM)
 992
 993
 994 ### Make sure subsequent tests use flags consistent with the build flags.
 995
 996 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 997   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 998 else
 999   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1000 fi
1001
1002 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1003 AC_DEFUN([AC_TYPE_SIZE_T])
1004 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1005 AC_DEFUN([AC_TYPE_UID_T])
1006
1007 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1008 AC_SYS_LARGEFILE
1009
1010
1011 LIB_MATH=-lm
1012 LIB_STANDARD=
1013 START_FILES=
1014
1015 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1016 case $opsys in
1017   cygwin )
1018     LIB_MATH=
1019     START_FILES='pre-crt0.o'
1020     ;;
1021   darwin )
1022     ## Adding -lm confuses the dynamic linker, so omit it.
1023     LIB_MATH=
1024     START_FILES='pre-crt0.o'
1025     ;;
1026   freebsd )
1027     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1028     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1029     ;;
1030   gnu-linux | gnu-kfreebsd )
1031     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1032     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1033     ;;
1034   hpux10-20 | hpux11 )
1035     LIB_STANDARD=-lc
1036     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1037     ;;
1038   dnl NB this may be adjusted below.
1039   netbsd | openbsd )
1040     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1041     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1042     ;;
1043 esac
1044
1045 AC_SUBST(LIB_MATH)
1046 AC_SUBST(START_FILES)
1047
1048 dnl Not all platforms use crtn.o files.  Check if the current one does.
1049 crt_files=
1050
1051 for file in x $LIB_STANDARD $START_FILES; do
1052   case "$file" in
1053     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1054   esac
1055 done
1056
1057 if test "x$crt_files" != x; then
1058
1059   ## If user specified a crt-dir, use that unconditionally.
1060   crt_gcc=no
1061
1062   if test "X$CRT_DIR" = "X"; then
1063
1064     CRT_DIR=/usr/lib            # default
1065
1066     case "$canonical" in
1067       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1068       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1069       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1070       ## For anything else (eg /usr/lib32), it is up the user to specify
1071       ## the location (bug#5655).
1072       ## Test for crtn.o, not just the directory, because sometimes the
1073       ## directory exists but does not have the relevant files (bug#1287).
1074       ## FIXME better to test for binary compatibility somehow.
1075       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1076       ;;
1077
1078       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1079     esac
1080
1081     case "$opsys" in
1082       hpux10-20) CRT_DIR=/lib ;;
1083     esac
1084
1085     test "x${GCC}" = xyes && crt_gcc=yes
1086
1087   fi                            # CRT_DIR = ""
1088
1089   crt_missing=
1090
1091   for file in $crt_files; do
1092
1093     ## If we're using gcc, try to determine it automatically by asking
1094     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1095     ## system-dependent default from above.]
1096     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1097
1098        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1099        case "$crt_file" in
1100          */*)
1101            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1102            ;;
1103        esac
1104     fi
1105
1106     dnl We expect all the files to be in a single directory, so after the
1107     dnl first there is no point asking gcc.
1108     crt_gcc=no
1109
1110     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1111   done                          # $crt_files
1112
1113   test "x$crt_missing" = x || \
1114     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1115 Try using the --with-crt-dir option.])
1116
1117 fi                              # crt_files != ""
1118
1119 AC_SUBST(CRT_DIR)
1120
1121 case $opsys in
1122   netbsd | openbsd )
1123     if test -f $CRT_DIR/crti.o; then
1124
1125         test -f $CRT_DIR/crtn.o || \
1126           AC_MSG_ERROR([Required file not found: crtn.o])
1127
1128         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1129         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1130     fi
1131     ;;
1132 esac
1133
1134
1135 dnl This function definition taken from Gnome 2.0
1136 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1137 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1138 dnl also defines GSTUFF_PKG_ERRORS on error
1139 AC_DEFUN([PKG_CHECK_MODULES], [
1140   succeeded=no
1141
1142   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1143
1144   if test "$PKG_CONFIG" = "no" ; then
1145      ifelse([$4], , [AC_MSG_ERROR([
1146       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1147   else
1148      PKG_CONFIG_MIN_VERSION=0.9.0
1149      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1150         AC_MSG_CHECKING(for $2)
1151
1152         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1153            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1154            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1155             edit_cflags="
1156               s,///*,/,g
1157               s/^/ /
1158               s/ -I/ $isystem/g
1159               s/^ //
1160             "
1161             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1162             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1163             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1164             succeeded=yes
1165         else
1166             AC_MSG_RESULT(no)
1167             $1_CFLAGS=""
1168             $1_LIBS=""
1169             ## If we have a custom action on failure, don't print errors, but
1170             ## do set a variable so people can do so.
1171             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1172             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1173         fi
1174
1175         AC_SUBST($1_CFLAGS)
1176         AC_SUBST($1_LIBS)
1177      else
1178         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1179         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1180      fi
1181   fi
1182
1183   if test $succeeded = yes; then
1184      ifelse([$3], , :, [$3])
1185   else
1186      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1187   fi
1188 ])
1189
1190
1191 if test "${with_sound}" != "no"; then
1192   # Sound support for GNU/Linux and the free BSDs.
1193   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1194     have_sound_header=yes)
1195   # Emulation library used on NetBSD.
1196   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1197   AC_SUBST(LIBSOUND)
1198
1199   ALSA_REQUIRED=1.0.0
1200   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1201   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1202   if test $HAVE_ALSA = yes; then
1203     SAVE_CFLAGS="$CFLAGS"
1204     SAVE_LIBS="$LIBS"
1205     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1206     LIBS="$ALSA_LIBS $LIBS"
1207     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1208                     emacs_alsa_normal=yes,
1209                     emacs_alsa_normal=no)
1210     if test "$emacs_alsa_normal" != yes; then
1211       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1212                      [[snd_lib_error_set_handler (0);]])],
1213                      emacs_alsa_subdir=yes,
1214                      emacs_alsa_subdir=no)
1215       if test "$emacs_alsa_subdir" != yes; then
1216         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1217       fi
1218       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1219     fi
1220
1221     CFLAGS="$SAVE_CFLAGS"
1222     LIBS="$SAVE_LIBS"
1223     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1224     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1225     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1226   fi
1227
1228   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1229   dnl compiles only on the specified platforms.  For others, it
1230   dnl probably doesn't make sense to try.
1231   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1232      case "$opsys" in
1233        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1234        gnu-linux|freebsd|netbsd)
1235          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1236          ;;
1237      esac
1238   fi
1239
1240   AC_SUBST(CFLAGS_SOUND)
1241 fi
1242
1243 dnl checks for header files
1244 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1245   linux/version.h sys/systeminfo.h \
1246   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1247   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1248   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1249
1250 AC_MSG_CHECKING(if personality LINUX32 can be set)
1251 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1252                emacs_cv_personality_linux32=yes,
1253                emacs_cv_personality_linux32=no)
1254 AC_MSG_RESULT($emacs_cv_personality_linux32)
1255
1256 if test $emacs_cv_personality_linux32 = yes; then
1257   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1258             [Define to 1 if personality LINUX32 can be set.])
1259 fi
1260
1261 dnl On Solaris 8 there's a compilation warning for term.h because
1262 dnl it doesn't define `bool'.
1263 AC_CHECK_HEADERS(term.h, , , -)
1264 AC_HEADER_TIME
1265 AC_CHECK_DECLS([sys_siglist])
1266 if test $ac_cv_have_decl_sys_siglist != yes; then
1267   # For Tru64, at least:
1268   AC_CHECK_DECLS([__sys_siglist])
1269   if test $ac_cv_have_decl___sys_siglist = yes; then
1270     AC_DEFINE(sys_siglist, __sys_siglist,
1271               [Define to any substitute for sys_siglist.])
1272   fi
1273 fi
1274 AC_HEADER_SYS_WAIT
1275
1276 dnl Some systems have utime.h but don't declare the struct anyplace.
1277 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1278 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1279 #include <sys/time.h>
1280 #include <time.h>
1281 #else
1282 #ifdef HAVE_SYS_TIME_H
1283 #include <sys/time.h>
1284 #else
1285 #include <time.h>
1286 #endif
1287 #endif
1288 #ifdef HAVE_UTIME_H
1289 #include <utime.h>
1290 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1291   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1292 if test $emacs_cv_struct_utimbuf = yes; then
1293   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1294 fi
1295
1296 dnl Check for speed_t typedef.
1297 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1298   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1299     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1300 if test $emacs_cv_speed_t = yes; then
1301   AC_DEFINE(HAVE_SPEED_T, 1,
1302            [Define to 1 if `speed_t' is declared by <termios.h>.])
1303 fi
1304
1305 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1306 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1307 #include <sys/time.h>
1308 #include <time.h>
1309 #else
1310 #ifdef HAVE_SYS_TIME_H
1311 #include <sys/time.h>
1312 #else
1313 #include <time.h>
1314 #endif
1315 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1316   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1317 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1318 if test $emacs_cv_struct_timeval = yes; then
1319   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1320 fi
1321
1322 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1323 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1324 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1325   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1326 HAVE_EXCEPTION=$emacs_cv_struct_exception
1327 if test $emacs_cv_struct_exception != yes; then
1328   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1329 fi
1330
1331 AC_CHECK_HEADERS(sys/socket.h)
1332 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1333 #if HAVE_SYS_SOCKET_H
1334 #include <sys/socket.h>
1335 #endif])
1336 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1337 #if HAVE_SYS_SOCKET_H
1338 #include <sys/socket.h>
1339 #endif])
1340 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1341 #if HAVE_SYS_SOCKET_H
1342 #include <sys/socket.h>
1343 #endif])
1344 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1345
1346 dnl checks for structure members
1347 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1348                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1349                   struct ifreq.ifr_addr,
1350                   struct ifreq.ifr_addr.sa_len], , ,
1351                  [AC_INCLUDES_DEFAULT
1352 #if HAVE_SYS_SOCKET_H
1353 #include <sys/socket.h>
1354 #endif
1355 #if HAVE_NET_IF_H
1356 #include <net/if.h>
1357 #endif])
1358
1359 dnl checks for compiler characteristics
1360
1361 dnl Testing __STDC__ to determine prototype support isn't good enough.
1362 dnl DEC C, for instance, doesn't define it with default options, and
1363 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1364 dnl and void *.
1365 AC_C_PROTOTYPES
1366 AC_C_VOLATILE
1367 AC_C_CONST
1368 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1369   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1370                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1371 if test $emacs_cv_void_star = yes; then
1372   AC_DEFINE(POINTER_TYPE, void)
1373 else
1374   AC_DEFINE(POINTER_TYPE, char)
1375 fi
1376 AH_TEMPLATE(POINTER_TYPE,
1377             [Define as `void' if your compiler accepts `void *'; otherwise
1378              define as `char'.])dnl
1379
1380 dnl Check for endianness.
1381 AC_C_BIGENDIAN
1382
1383 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1384   [emacs_cv_attribute_aligned],
1385   [AC_COMPILE_IFELSE(
1386      [AC_LANG_PROGRAM(
1387         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1388         [[]])],
1389      [emacs_cv_attribute_aligned=yes],
1390      [emacs_cv_attribute_aligned=no])])
1391 if test $emacs_cv_attribute_aligned = yes; then
1392   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1393     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1394 fi
1395
1396 dnl check for Make feature
1397 AC_PROG_MAKE_SET
1398
1399 DEPFLAGS=
1400 MKDEPDIR=":"
1401 deps_frag=deps.mk
1402 dnl check for GNU Make if we have GCC and autodepend is on.
1403 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1404    AC_MSG_CHECKING([whether we are using GNU Make])
1405    HAVE_GNU_MAKE=no
1406    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1407    if test "x$testval" != x; then
1408       HAVE_GNU_MAKE=yes
1409    else
1410       ac_enable_autodepend=no
1411    fi
1412    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1413    if test $HAVE_GNU_MAKE = yes; then
1414       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1415       SAVE_CFLAGS="$CFLAGS"
1416       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1417       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1418       CFLAGS="$SAVE_CFLAGS"
1419       test -f deps.d || ac_enable_autodepend=no
1420       rm -rf deps.d
1421       AC_MSG_RESULT([$ac_enable_autodepend])
1422    fi
1423    if test $ac_enable_autodepend = yes; then
1424       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1425       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1426       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1427       deps_frag=autodeps.mk
1428    fi
1429 fi
1430 deps_frag=$srcdir/src/$deps_frag
1431 AC_SUBST(MKDEPDIR)
1432 AC_SUBST(DEPFLAGS)
1433 AC_SUBST_FILE(deps_frag)
1434
1435
1436 lisp_frag=$srcdir/src/lisp.mk
1437 AC_SUBST_FILE(lisp_frag)
1438
1439
1440 dnl checks for operating system services
1441 AC_SYS_LONG_FILE_NAMES
1442
1443 #### Choose a window system.
1444
1445 AC_PATH_X
1446 if test "$no_x" = yes; then
1447   window_system=none
1448 else
1449   window_system=x11
1450 fi
1451
1452 LD_SWITCH_X_SITE_RPATH=
1453 if test "${x_libraries}" != NONE; then
1454   if test -n "${x_libraries}"; then
1455     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1456     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1457   fi
1458   x_default_search_path=""
1459   x_search_path=${x_libraries}
1460   if test -z "${x_search_path}"; then
1461     x_search_path=/usr/lib
1462   fi
1463   for x_library in `echo ${x_search_path}: | \
1464                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1465     x_search_path="\
1466 ${x_library}/X11/%L/%T/%N%C%S:\
1467 ${x_library}/X11/%l/%T/%N%C%S:\
1468 ${x_library}/X11/%T/%N%C%S:\
1469 ${x_library}/X11/%L/%T/%N%S:\
1470 ${x_library}/X11/%l/%T/%N%S:\
1471 ${x_library}/X11/%T/%N%S"
1472     if test x"${x_default_search_path}" = x; then
1473       x_default_search_path=${x_search_path}
1474     else
1475       x_default_search_path="${x_search_path}:${x_default_search_path}"
1476     fi
1477   done
1478 fi
1479 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1480
1481 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1482   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1483 fi
1484
1485 if test x"${x_includes}" = x; then
1486   bitmapdir=/usr/include/X11/bitmaps
1487 else
1488   # accumulate include directories that have X11 bitmap subdirectories
1489   bmd_acc="dummyval"
1490   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1491     if test -d "${bmd}/X11/bitmaps"; then
1492       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1493     fi
1494     if test -d "${bmd}/bitmaps"; then
1495       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1496     fi
1497   done
1498   if test ${bmd_acc} != "dummyval"; then
1499     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1500   fi
1501 fi
1502
1503 HAVE_NS=no
1504 NS_IMPL_COCOA=no
1505 NS_IMPL_GNUSTEP=no
1506 tmp_CPPFLAGS="$CPPFLAGS"
1507 tmp_CFLAGS="$CFLAGS"
1508 CPPFLAGS="$CPPFLAGS -x objective-c"
1509 CFLAGS="$CFLAGS -x objective-c"
1510 TEMACS_LDFLAGS2="\${LDFLAGS}"
1511 GNU_OBJC_CFLAGS=
1512 if test "${with_ns}" != no; then
1513   if test "${opsys}" = darwin; then
1514      NS_IMPL_COCOA=yes
1515      ns_appdir=`pwd`/nextstep/Emacs.app
1516      ns_appbindir=${ns_appdir}/Contents/MacOS
1517      ns_appresdir=${ns_appdir}/Contents/Resources
1518      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1519   elif test -f $GNUSTEP_CONFIG_FILE; then
1520      NS_IMPL_GNUSTEP=yes
1521      ns_appdir=`pwd`/nextstep/Emacs.app
1522      ns_appbindir=${ns_appdir}
1523      ns_appresdir=${ns_appdir}/Resources
1524      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1525      dnl FIXME sourcing this several times in subshells seems inefficient.
1526      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1527      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1528      dnl I seemed to need these as well with GNUstep-startup 0.25.
1529      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1530      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1531      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1532        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1533      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1534        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1535      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1536      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1537      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1538      LIB_STANDARD=
1539      START_FILES=
1540      TEMACS_LDFLAGS2=
1541      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1542      dnl If they had chosen to either define it or not, we could have
1543      dnl just used AC_CHECK_DECL here.
1544      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1545        emacs_cv_objc_exceptions,
1546 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1547 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1548 1;
1549 #else
1550 fail;
1551 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1552      if test $emacs_cv_objc_exceptions = yes; then
1553        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1554        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1555          [Define if GNUstep uses ObjC exceptions.])
1556        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1557      fi
1558   fi
1559
1560   dnl This is only used while we test the NS headers, it gets reset below.
1561   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1562
1563   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1564                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1565   files are missing or cannot be compiled.])])
1566   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1567                                      [NSInteger i;])],
1568                     ns_have_nsinteger=yes,
1569                     ns_have_nsinteger=no)
1570   if test $ns_have_nsinteger = yes; then
1571     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1572   fi
1573 fi
1574 AC_SUBST(TEMACS_LDFLAGS2)
1575
1576 INSTALL_ARCH_INDEP_EXTRA=install-etc
1577 LEIM_INSTALLDIR="\${install_prefix}/leim"
1578 ns_self_contained=no
1579 ns_frag=/dev/null
1580 NS_OBJ=
1581 NS_OBJC_OBJ=
1582 if test "${HAVE_NS}" = yes; then
1583   if test "$with_toolkit_scroll_bars" = "no"; then
1584     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1585   fi
1586
1587   window_system=nextstep
1588   with_xft=no
1589   # set up packaging dirs
1590   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1591      ns_self_contained=yes
1592      prefix=${ns_appresdir}
1593      exec_prefix=${ns_appbindir}
1594      dnl This one isn't really used, only archlibdir is.
1595      libexecdir="\${ns_appbindir}/libexec"
1596      archlibdir="\${ns_appbindir}/libexec"
1597      docdir="\${ns_appresdir}/etc"
1598      etcdir="\${ns_appresdir}/etc"
1599      dnl FIXME maybe set datarootdir instead.
1600      dnl That would also get applications, icons, man.
1601      infodir="\${ns_appresdir}/info"
1602      mandir="\${ns_appresdir}/man"
1603      lispdir="\${ns_appresdir}/lisp"
1604      LEIM_INSTALLDIR="\${ns_appresdir}/leim"
1605      INSTALL_ARCH_INDEP_EXTRA=
1606   fi
1607   ns_frag=$srcdir/src/ns.mk
1608   NS_OBJ="fontset.o fringe.o image.o"
1609   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1610 fi
1611 CFLAGS="$tmp_CFLAGS"
1612 CPPFLAGS="$tmp_CPPFLAGS"
1613 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1614 AC_SUBST(LEIM_INSTALLDIR)
1615 AC_SUBST(ns_self_contained)
1616 AC_SUBST(NS_OBJ)
1617 AC_SUBST(NS_OBJC_OBJ)
1618 AC_SUBST(LIB_STANDARD)
1619 AC_SUBST_FILE(ns_frag)
1620
1621 case "${window_system}" in
1622   x11 )
1623     HAVE_X_WINDOWS=yes
1624     HAVE_X11=yes
1625     case "${with_x_toolkit}" in
1626       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1627       motif ) USE_X_TOOLKIT=MOTIF ;;
1628       gtk ) with_gtk=yes
1629 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1630 dnl USE_X_TOOLKIT is set.
1631             USE_X_TOOLKIT=none ;;
1632       gtk3 ) with_gtk3=yes
1633              USE_X_TOOLKIT=none ;;
1634       no ) USE_X_TOOLKIT=none ;;
1635 dnl If user did not say whether to use a toolkit, make this decision later:
1636 dnl use the toolkit if we have gtk, or X11R5 or newer.
1637       * ) USE_X_TOOLKIT=maybe ;;
1638     esac
1639   ;;
1640   nextstep | none )
1641     HAVE_X_WINDOWS=no
1642     HAVE_X11=no
1643     USE_X_TOOLKIT=none
1644   ;;
1645 esac
1646
1647 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1648    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1649    if test "$HAVE_XSERVER" = true ||
1650       test -n "$DISPLAY" ||
1651       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1652         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1653 were found.  You should install the relevant development files for X
1654 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1655 sure you have development files for image handling, i.e.
1656 tiff, gif, jpeg, png and xpm.
1657 If you are sure you want Emacs compiled without X window support, pass
1658   --without-x
1659 to configure.])
1660    fi
1661 fi
1662
1663 ### If we're using X11, we should use the X menu package.
1664 HAVE_MENUS=no
1665 case ${HAVE_X11} in
1666   yes ) HAVE_MENUS=yes ;;
1667 esac
1668
1669 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1670 # Assume not, until told otherwise.
1671 GNU_MALLOC=yes
1672
1673 AC_CACHE_CHECK(
1674   [whether malloc is Doug Lea style],
1675   [emacs_cv_var_doug_lea_malloc],
1676   [AC_LINK_IFELSE(
1677      [AC_LANG_PROGRAM(
1678         [[#include <malloc.h>
1679           static void hook (void) {}]],
1680         [[malloc_set_state (malloc_get_state ());
1681           __after_morecore_hook = hook;
1682           __malloc_initialize_hook = hook;]])],
1683      [emacs_cv_var_doug_lea_malloc=yes],
1684      [emacs_cv_var_doug_lea_malloc=no])])
1685 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1686
1687
1688 dnl See comments in aix4-2.h about maybe using system malloc there.
1689 system_malloc=no
1690 case "$opsys" in
1691   ## darwin ld insists on the use of malloc routines in the System framework.
1692   darwin|sol2-10) system_malloc=yes ;;
1693 esac
1694
1695 if test "${system_malloc}" = "yes"; then
1696   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1697   GNU_MALLOC=no
1698   GNU_MALLOC_reason="
1699     (The GNU allocators don't work with this system configuration.)"
1700   GMALLOC_OBJ=
1701   VMLIMIT_OBJ=
1702 else
1703   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1704   VMLIMIT_OBJ=vm-limit.o
1705 fi
1706 AC_SUBST(GMALLOC_OBJ)
1707 AC_SUBST(VMLIMIT_OBJ)
1708
1709 if test "$doug_lea_malloc" = "yes" ; then
1710   if test "$GNU_MALLOC" = yes ; then
1711     GNU_MALLOC_reason="
1712       (Using Doug Lea's new malloc from the GNU C Library.)"
1713   fi
1714   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1715             [Define to 1 if you are using the GNU C Library.])
1716
1717   ## Use mmap directly for allocating larger buffers.
1718   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1719   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1720   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1721   case "$opsys" in
1722     gnu*) REL_ALLOC=no ;;
1723   esac
1724 fi
1725
1726 if test x"${REL_ALLOC}" = x; then
1727   REL_ALLOC=${GNU_MALLOC}
1728 fi
1729
1730 use_mmap_for_buffers=no
1731 case "$opsys" in
1732   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1733 esac
1734
1735 AC_FUNC_MMAP
1736 if test $use_mmap_for_buffers = yes; then
1737   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1738   REL_ALLOC=no
1739 fi
1740
1741 LIBS="$LIBS_SYSTEM $LIBS"
1742
1743 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1744 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1745 AC_CHECK_LIB(dnet, dnet_ntoa)
1746 dnl This causes -lresolv to get used in subsequent tests,
1747 dnl which causes failures on some systems such as HPUX 9.
1748 dnl AC_CHECK_LIB(resolv, gethostbyname)
1749
1750 dnl FIXME replace main with a function we actually want from this library.
1751 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1752
1753 dnl Check if pthreads is available.
1754 LIB_PTHREAD=
1755 AC_CHECK_HEADERS(pthread.h)
1756 if test "$ac_cv_header_pthread_h"; then
1757   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1758   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1759   dnl testing for pthread_self if Emacs uses gmalloc.c.
1760   if test "$GMALLOC_OBJ" = gmalloc.o; then
1761     emacs_pthread_function=pthread_atfork
1762   else
1763     emacs_pthread_function=pthread_self
1764   fi
1765   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1766 fi
1767 if test "$HAVE_PTHREAD" = yes; then
1768   case "${canonical}" in
1769     *-hpux*) ;;
1770     *) LIB_PTHREAD="-lpthread"
1771        LIBS="$LIB_PTHREAD $LIBS" ;;
1772   esac
1773   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1774 fi
1775 AC_SUBST([LIB_PTHREAD])
1776
1777 AC_CHECK_LIB(pthreads, cma_open)
1778
1779 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1780 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1781 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1782 ## added to LIBS in configure would never contain the pthreads part,
1783 ## but the value used in Makefiles might.  FIXME?
1784 ##
1785 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1786 ## be harmless on older versions of X where it happens to exist.
1787 test "$opsys" = "aix4-2" && \
1788   test $ac_cv_lib_pthreads_cma_open = yes && \
1789   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1790
1791 dnl Check for need for bigtoc support on IBM AIX
1792
1793 case ${host_os} in
1794 aix*)
1795   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1796     case $GCC in
1797     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1798     *) gdb_cv_bigtoc=-bbigtoc ;;
1799     esac
1800
1801     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1802     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1803   ])
1804   ;;
1805 esac
1806
1807 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1808 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1809 # REAL_CPPFLAGS later on.
1810
1811 REAL_CFLAGS="$CFLAGS"
1812 REAL_CPPFLAGS="$CPPFLAGS"
1813
1814 if test "${HAVE_X11}" = "yes"; then
1815   DEFS="$C_SWITCH_X_SITE $DEFS"
1816   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1817   LIBS="-lX11 $LIBS"
1818   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1819   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1820
1821   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1822   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1823   # but it's more convenient here to set LD_RUN_PATH since this
1824   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1825   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1826     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1827     export LD_RUN_PATH
1828   fi
1829
1830   if test "${opsys}" = "gnu-linux"; then
1831     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1832     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1833      [[XOpenDisplay ("foo");]])],
1834      [xgnu_linux_first_failure=no],
1835      [xgnu_linux_first_failure=yes])
1836     if test "${xgnu_linux_first_failure}" = "yes"; then
1837       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1838       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1839       OLD_CPPFLAGS="$CPPFLAGS"
1840       OLD_LIBS="$LIBS"
1841       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1842       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1843       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1844       LIBS="$LIBS -b i486-linuxaout"
1845       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1846        [[XOpenDisplay ("foo");]])],
1847        [xgnu_linux_second_failure=no],
1848        [xgnu_linux_second_failure=yes])
1849       if test "${xgnu_linux_second_failure}" = "yes"; then
1850         # If we get the same failure with -b, there is no use adding -b.
1851         # So take it out.  This plays safe.
1852         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1853         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1854         CPPFLAGS="$OLD_CPPFLAGS"
1855         LIBS="$OLD_LIBS"
1856         AC_MSG_RESULT(no)
1857       else
1858         AC_MSG_RESULT(yes)
1859       fi
1860     else
1861       AC_MSG_RESULT(no)
1862     fi
1863   fi
1864
1865   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1866   # header files included from there.
1867   AC_MSG_CHECKING(for Xkb)
1868   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1869 #include <X11/XKBlib.h>]],
1870         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1871         emacs_xkb=yes, emacs_xkb=no)
1872   AC_MSG_RESULT($emacs_xkb)
1873   if test $emacs_xkb = yes; then
1874     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1875   fi
1876
1877   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1878 XScreenNumberOfScreen XSetWMProtocols)
1879 fi
1880
1881 if test "${window_system}" = "x11"; then
1882   AC_MSG_CHECKING(X11 version 6)
1883   AC_CACHE_VAL(emacs_cv_x11_version_6,
1884   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1885 [[#if XlibSpecificationRelease < 6
1886 fail;
1887 #endif
1888 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1889   if test $emacs_cv_x11_version_6 = yes; then
1890     AC_MSG_RESULT(6 or newer)
1891     AC_DEFINE(HAVE_X11R6, 1,
1892               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1893     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1894     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1895     ## XIM support.
1896     case "$opsys" in
1897       sol2-*) : ;;
1898       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1899            [Define if you have usable X11R6-style XIM support.])
1900          ;;
1901     esac
1902   else
1903     AC_MSG_RESULT(before 6)
1904   fi
1905 fi
1906
1907
1908 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1909 HAVE_RSVG=no
1910 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1911   if test "${with_rsvg}" != "no"; then
1912     RSVG_REQUIRED=2.11.0
1913     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1914
1915     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1916     AC_SUBST(RSVG_CFLAGS)
1917     AC_SUBST(RSVG_LIBS)
1918
1919     if test $HAVE_RSVG = yes; then
1920       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1921       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1922       LIBS="$RSVG_LIBS $LIBS"
1923     fi
1924   fi
1925 fi
1926
1927 HAVE_IMAGEMAGICK=no
1928 if test "${HAVE_X11}" = "yes"; then
1929   if test "${with_imagemagick}" != "no"; then
1930     ## 6.2.8 is the earliest version known to work, but earlier versions
1931     ## might work - let us know if you find one.
1932     ## 6.0.7 does not work.  See bug#7955.
1933     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1934     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1935     AC_SUBST(IMAGEMAGICK_CFLAGS)
1936     AC_SUBST(IMAGEMAGICK_LIBS)
1937
1938     if test $HAVE_IMAGEMAGICK = yes; then
1939       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1940       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1941       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1942       AC_CHECK_FUNCS(MagickExportImagePixels)
1943     fi
1944   fi
1945 fi
1946
1947
1948 HAVE_GTK=no
1949 GTK_OBJ=
1950 if test "${with_gtk3}" = "yes"; then
1951   GLIB_REQUIRED=2.28
1952   GTK_REQUIRED=3.0
1953   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1954
1955   dnl Checks for libraries.
1956   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1957   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1958      AC_MSG_ERROR($GTK_PKG_ERRORS)
1959   fi
1960   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1961   GTK_OBJ=emacsgtkfixed.o
1962 fi
1963
1964 if test "$pkg_check_gtk" != "yes"; then
1965   HAVE_GTK=no
1966 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1967   GLIB_REQUIRED=2.10
1968   GTK_REQUIRED=2.10
1969   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1970
1971   dnl Checks for libraries.
1972   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1973   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1974      AC_MSG_ERROR($GTK_PKG_ERRORS)
1975   fi
1976 fi
1977 fi
1978
1979 if test x"$pkg_check_gtk" = xyes; then
1980
1981   AC_SUBST(GTK_CFLAGS)
1982   AC_SUBST(GTK_LIBS)
1983   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1984   CFLAGS="$CFLAGS $GTK_CFLAGS"
1985   LIBS="$GTK_LIBS $LIBS"
1986   dnl Try to compile a simple GTK program.
1987   GTK_COMPILES=no
1988   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1989   if test "${GTK_COMPILES}" != "yes"; then
1990     if test "$USE_X_TOOLKIT" != "maybe"; then
1991       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1992     fi
1993   else
1994     HAVE_GTK=yes
1995     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1996     GTK_OBJ="gtkutil.o $GTK_OBJ"
1997     USE_X_TOOLKIT=none
1998     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1999       :
2000     else
2001       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2002        closing open displays.  This is no problem if you just use
2003        one display, but if you use more than one and close one of them
2004        Emacs may crash.]])
2005       sleep 3
2006     fi
2007   fi
2008
2009 fi
2010 AC_SUBST(GTK_OBJ)
2011
2012
2013 if test "${HAVE_GTK}" = "yes"; then
2014
2015   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2016   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2017   if test "$with_toolkit_scroll_bars" != no; then
2018     with_toolkit_scroll_bars=yes
2019   fi
2020
2021   dnl  Check if we have the old file selection dialog declared and
2022   dnl  in the link library.  In 2.x it may be in the library,
2023   dnl  but not declared if deprecated featured has been selected out.
2024   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2025   HAVE_GTK_FILE_SELECTION=no
2026   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2027                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2028 #include <gtk/gtk.h>])
2029   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2030     AC_CHECK_FUNCS(gtk_file_selection_new)
2031   fi
2032
2033
2034   dnl Check for functions introduced in 2.14 and later.
2035   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2036                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2037                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2038                  gtk_orientable_set_orientation \
2039                  gtk_window_set_has_resize_grip)
2040 fi
2041
2042 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2043 dnl other platforms.
2044 HAVE_DBUS=no
2045 DBUS_OBJ=
2046 if test "${with_dbus}" = "yes"; then
2047    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2048    if test "$HAVE_DBUS" = yes; then
2049      LIBS="$LIBS $DBUS_LIBS"
2050      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2051      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2052      dnl dbus_validate_* have been introduced in D-Bus 1.5.12.
2053      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2054                     dbus_validate_bus_name \
2055                     dbus_validate_path \
2056                     dbus_validate_interface \
2057                     dbus_validate_member)
2058      DBUS_OBJ=dbusbind.o
2059    fi
2060 fi
2061 AC_SUBST(DBUS_OBJ)
2062
2063 dnl GSettings has been tested under GNU/Linux only.
2064 HAVE_GSETTINGS=no
2065 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2066    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2067    if test "$HAVE_GSETTINGS" = "yes"; then
2068       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2069       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2070       SETTINGS_LIBS="$GSETTINGS_LIBS"
2071    fi
2072 fi
2073
2074 dnl GConf has been tested under GNU/Linux only.
2075 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2076 HAVE_GCONF=no
2077 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2078    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2079    if test "$HAVE_GCONF" = yes; then
2080       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2081       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2082       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2083       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2084    fi
2085 fi
2086
2087 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2088     SAVE_CFLAGS="$CFLAGS"
2089     SAVE_LIBS="$LIBS"
2090     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2091     LIBS="$SETTINGS_LIBS $LIBS"
2092     AC_CHECK_FUNCS([g_type_init])
2093     CFLAGS="$SAVE_CFLAGS"
2094     LIBS="$SAVE_LIBS"
2095 fi
2096 AC_SUBST(SETTINGS_CFLAGS)
2097 AC_SUBST(SETTINGS_LIBS)
2098
2099
2100 dnl SELinux is available for GNU/Linux only.
2101 HAVE_LIBSELINUX=no
2102 LIBSELINUX_LIBS=
2103 if test "${with_selinux}" = "yes"; then
2104    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2105    if test "$HAVE_LIBSELINUX" = yes; then
2106       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2107       LIBSELINUX_LIBS=-lselinux
2108    fi
2109 fi
2110 AC_SUBST(LIBSELINUX_LIBS)
2111
2112 HAVE_GNUTLS=no
2113 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2114 if test "${with_gnutls}" = "yes" ; then
2115   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2116   if test "${HAVE_GNUTLS}" = "yes"; then
2117     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2118   fi
2119
2120   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2121   LIBS="$LIBGNUTLS_LIBS $LIBS"
2122   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2123
2124   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2125     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2126   fi
2127 fi
2128
2129 AC_SUBST(LIBGNUTLS_LIBS)
2130 AC_SUBST(LIBGNUTLS_CFLAGS)
2131
2132 dnl Do not put whitespace before the #include statements below.
2133 dnl Older compilers (eg sunos4 cc) choke on it.
2134 HAVE_XAW3D=no
2135 LUCID_LIBW=
2136 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2137   if test "$with_xaw3d" != no; then
2138     AC_MSG_CHECKING(for xaw3d)
2139     AC_CACHE_VAL(emacs_cv_xaw3d,
2140     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2141 #include <X11/Intrinsic.h>
2142 #include <X11/Xaw3d/Simple.h>]],
2143       [[]])],
2144       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2145                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2146       emacs_cv_xaw3d=no)])
2147   else
2148     emacs_cv_xaw3d=no
2149   fi
2150   if test $emacs_cv_xaw3d = yes; then
2151     AC_MSG_RESULT([yes; using Lucid toolkit])
2152     USE_X_TOOLKIT=LUCID
2153     HAVE_XAW3D=yes
2154     LUCID_LIBW=-lXaw3d
2155     AC_DEFINE(HAVE_XAW3D, 1,
2156               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2157   else
2158     AC_MSG_RESULT(no)
2159     AC_MSG_CHECKING(for libXaw)
2160     AC_CACHE_VAL(emacs_cv_xaw,
2161     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2162 #include <X11/Intrinsic.h>
2163 #include <X11/Xaw/Simple.h>]],
2164       [[]])],
2165       emacs_cv_xaw=yes,
2166       emacs_cv_xaw=no)])
2167     if test $emacs_cv_xaw = yes; then
2168       AC_MSG_RESULT([yes; using Lucid toolkit])
2169       USE_X_TOOLKIT=LUCID
2170       LUCID_LIBW=-lXaw
2171     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2172       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2173     else
2174       AC_MSG_ERROR([No X toolkit could be found.
2175 If you are sure you want Emacs compiled without an X toolkit, pass
2176   --with-x-toolkit=no
2177 to configure.  Otherwise, install the development libraries for the toolkit
2178 that you want to use (e.g. Gtk+) and re-run configure.])
2179     fi
2180   fi
2181 fi
2182
2183 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2184
2185 LIBXTR6=
2186 if test "${USE_X_TOOLKIT}" != "none"; then
2187   AC_MSG_CHECKING(X11 toolkit version)
2188   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2189   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2190 [[#if XtSpecificationRelease < 6
2191 fail;
2192 #endif
2193 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2194   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2195   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2196     AC_MSG_RESULT(6 or newer)
2197     AC_DEFINE(HAVE_X11XTR6, 1,
2198               [Define to 1 if you have the X11R6 or newer version of Xt.])
2199     LIBXTR6="-lSM -lICE"
2200     case "$opsys" in
2201       ## Use libw.a along with X11R6 Xt.
2202       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2203     esac
2204   else
2205     AC_MSG_RESULT(before 6)
2206   fi
2207
2208 dnl If using toolkit, check whether libXmu.a exists.
2209 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2210   OLDLIBS="$LIBS"
2211   if test x$HAVE_X11XTR6 = xyes; then
2212     LIBS="-lXt -lSM -lICE $LIBS"
2213   else
2214     LIBS="-lXt $LIBS"
2215   fi
2216   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2217   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2218 fi
2219 AC_SUBST(LIBXTR6)
2220
2221 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2222 dnl Why not just test for libxmu in the normal way?
2223 LIBXMU=-lXmu
2224 case $opsys in
2225   ## These systems don't supply Xmu.
2226   hpux* | aix4-2 )
2227     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2228     ;;
2229 esac
2230 AC_SUBST(LIBXMU)
2231
2232 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2233 if test "${HAVE_X11}" = "yes"; then
2234   if test "${USE_X_TOOLKIT}" != "none"; then
2235     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2236   fi
2237 fi
2238
2239 LIBXP=
2240 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2241   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2242   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2243     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2244 int x = 5;
2245 #else
2246 Motif version prior to 2.1.
2247 #endif]])],
2248     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2249   if test $emacs_cv_motif_version_2_1 = yes; then
2250     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2251   else
2252     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2253     # We put this in CFLAGS temporarily to precede other -I options
2254     # that might be in CFLAGS temporarily.
2255     # We put this in CPPFLAGS where it precedes the other -I options.
2256     OLD_CPPFLAGS=$CPPFLAGS
2257     OLD_CFLAGS=$CFLAGS
2258     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2259     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2260     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2261       [[int x = 5;]])],
2262       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2263     if test $emacs_cv_lesstif = yes; then
2264       # Make sure this -I option remains in CPPFLAGS after it is set
2265       # back to REAL_CPPFLAGS.
2266       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2267       # have those other -I options anyway.  Ultimately, having this
2268       # directory ultimately in CPPFLAGS will be enough.
2269       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2270       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2271     else
2272       CFLAGS=$OLD_CFLAGS
2273       CPPFLAGS=$OLD_CPPFLAGS
2274     fi
2275   fi
2276   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2277     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2278 fi
2279
2280 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2281 dnl using Motif or Xaw3d is available, and unless
2282 dnl --with-toolkit-scroll-bars=no was specified.
2283
2284 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2285             [Define to 1 if we should use toolkit scroll bars.])dnl
2286 USE_TOOLKIT_SCROLL_BARS=no
2287 if test "${with_toolkit_scroll_bars}" != "no"; then
2288   if test "${USE_X_TOOLKIT}" != "none"; then
2289     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2290       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2291       HAVE_XAW3D=no
2292       USE_TOOLKIT_SCROLL_BARS=yes
2293     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2294       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2295       USE_TOOLKIT_SCROLL_BARS=yes
2296     fi
2297   elif test "${HAVE_GTK}" = "yes"; then
2298     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2299     USE_TOOLKIT_SCROLL_BARS=yes
2300   elif test "${HAVE_NS}" = "yes"; then
2301     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2302     USE_TOOLKIT_SCROLL_BARS=yes
2303   fi
2304 fi
2305
2306 dnl See if XIM is available.
2307 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2308           #include <X11/Xlib.h>
2309           #include <X11/Xresource.h>]],
2310          [[XIMProc  callback;]])],
2311          [HAVE_XIM=yes
2312          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2313          HAVE_XIM=no)
2314
2315 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2316
2317 if test "${with_xim}" != "no"; then
2318   AC_DEFINE(USE_XIM, 1,
2319             [Define to 1 if we should use XIM, if it is available.])
2320 fi
2321
2322
2323 if test "${HAVE_XIM}" != "no"; then
2324   late_CFLAGS=$CFLAGS
2325   if test "$GCC" = yes; then
2326     CFLAGS="$CFLAGS --pedantic-errors"
2327   fi
2328   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2329 #include <X11/Xlib.h>
2330 #include <X11/Xresource.h>]],
2331 [[Display *display;
2332 XrmDatabase db;
2333 char *res_name;
2334 char *res_class;
2335 XIMProc  callback;
2336 XPointer *client_data;
2337 #ifndef __GNUC__
2338 /* If we're not using GCC, it's probably not XFree86, and this is
2339    probably right, but we can't use something like --pedantic-errors.  */
2340 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2341                                            char*, XIMProc, XPointer*);
2342 #endif
2343 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2344    client_data);]])],
2345     [emacs_cv_arg6_star=yes])
2346   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2347          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2348 either XPointer or XPointer*.])dnl
2349   if test "$emacs_cv_arg6_star" = yes; then
2350     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2351   else
2352     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2353   fi
2354   CFLAGS=$late_CFLAGS
2355 fi
2356
2357 ### Start of font-backend (under any platform) section.
2358 # (nothing here yet -- this is a placeholder)
2359 ### End of font-backend (under any platform) section.
2360
2361 ### Start of font-backend (under X11) section.
2362 if test "${HAVE_X11}" = "yes"; then
2363    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2364
2365    ## Use -lXft if available, unless `--with-xft=no'.
2366    HAVE_XFT=maybe
2367     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2368       with_xft="no";
2369     fi
2370     if test "x${with_xft}" != "xno"; then
2371
2372       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2373       ## Because xftfont.c uses XRenderQueryExtension, we also
2374       ## need to link to -lXrender.
2375       HAVE_XRENDER=no
2376       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2377       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2378         OLD_CPPFLAGS="$CPPFLAGS"
2379         OLD_CFLAGS="$CFLAGS"
2380         OLD_LIBS="$LIBS"
2381         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2382         CFLAGS="$CFLAGS $XFT_CFLAGS"
2383         XFT_LIBS="-lXrender $XFT_LIBS"
2384         LIBS="$XFT_LIBS $LIBS"
2385         AC_CHECK_HEADER(X11/Xft/Xft.h,
2386           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2387
2388         if test "${HAVE_XFT}" = "yes"; then
2389           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2390             AC_SUBST(XFT_LIBS)
2391           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2392         else
2393           CPPFLAGS="$OLD_CPPFLAGS"
2394           CFLAGS="$OLD_CFLAGS"
2395           LIBS="$OLD_LIBS"
2396         fi                        # "${HAVE_XFT}" = "yes"
2397       fi                          # "$HAVE_XFT" != no
2398     fi                            # "x${with_xft}" != "xno"
2399
2400     ## We used to allow building with FreeType and without Xft.
2401     ## However, the ftx font backend driver is not in good shape.
2402     if test "$HAVE_XFT" != "yes"; then
2403        dnl For the "Does Emacs use" message at the end.
2404        HAVE_XFT=no
2405        HAVE_FREETYPE=no
2406     else
2407        dnl Strict linkers fail with
2408        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2409        dnl if -lfreetype is not specified.
2410        dnl The following is needed to set FREETYPE_LIBS.
2411        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2412                          HAVE_FREETYPE=no)
2413
2414        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2415     fi
2416
2417     HAVE_LIBOTF=no
2418     if test "${HAVE_FREETYPE}" = "yes"; then
2419       AC_DEFINE(HAVE_FREETYPE, 1,
2420                 [Define to 1 if using the freetype and fontconfig libraries.])
2421       if test "${with_libotf}" != "no"; then
2422         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2423                           HAVE_LIBOTF=no)
2424         if test "$HAVE_LIBOTF" = "yes"; then
2425           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2426           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2427                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2428                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2429           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2430             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2431                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2432           fi
2433         fi
2434       fi
2435     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2436     dnl Does the new font backend require it, or can it work without it?
2437     fi
2438
2439     HAVE_M17N_FLT=no
2440     if test "${HAVE_LIBOTF}" = yes; then
2441       if test "${with_m17n_flt}" != "no"; then
2442         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2443         if test "$HAVE_M17N_FLT" = "yes"; then
2444           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2445         fi
2446       fi
2447     fi
2448 else
2449     HAVE_XFT=no
2450     HAVE_FREETYPE=no
2451     HAVE_LIBOTF=no
2452     HAVE_M17N_FLT=no
2453 fi
2454
2455 ### End of font-backend (under X11) section.
2456
2457 AC_SUBST(FREETYPE_CFLAGS)
2458 AC_SUBST(FREETYPE_LIBS)
2459 AC_SUBST(FONTCONFIG_CFLAGS)
2460 AC_SUBST(FONTCONFIG_LIBS)
2461 AC_SUBST(LIBOTF_CFLAGS)
2462 AC_SUBST(LIBOTF_LIBS)
2463 AC_SUBST(M17N_FLT_CFLAGS)
2464 AC_SUBST(M17N_FLT_LIBS)
2465
2466 ### Use -lXpm if available, unless `--with-xpm=no'.
2467 HAVE_XPM=no
2468 LIBXPM=
2469 if test "${HAVE_X11}" = "yes"; then
2470   if test "${with_xpm}" != "no"; then
2471     AC_CHECK_HEADER(X11/xpm.h,
2472       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2473     if test "${HAVE_XPM}" = "yes"; then
2474       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2475       AC_EGREP_CPP(no_return_alloc_pixels,
2476       [#include "X11/xpm.h"
2477 #ifndef XpmReturnAllocPixels
2478 no_return_alloc_pixels
2479 #endif
2480       ], HAVE_XPM=no, HAVE_XPM=yes)
2481
2482       if test "${HAVE_XPM}" = "yes"; then
2483         AC_MSG_RESULT(yes)
2484       else
2485         AC_MSG_RESULT(no)
2486       fi
2487     fi
2488   fi
2489
2490   if test "${HAVE_XPM}" = "yes"; then
2491     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2492     LIBXPM=-lXpm
2493   fi
2494 fi
2495 AC_SUBST(LIBXPM)
2496
2497 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2498 HAVE_JPEG=no
2499 LIBJPEG=
2500 if test "${HAVE_X11}" = "yes"; then
2501   if test "${with_jpeg}" != "no"; then
2502     dnl Checking for jpeglib.h can lose because of a redefinition of
2503     dnl  HAVE_STDLIB_H.
2504     AC_CHECK_HEADER(jerror.h,
2505       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2506   fi
2507
2508   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2509   if test "${HAVE_JPEG}" = "yes"; then
2510     AC_DEFINE(HAVE_JPEG)
2511     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2512         [#include <jpeglib.h>
2513          version=JPEG_LIB_VERSION
2514 ],
2515         [AC_DEFINE(HAVE_JPEG)],
2516         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2517         HAVE_JPEG=no])
2518   fi
2519   if test "${HAVE_JPEG}" = "yes"; then
2520     LIBJPEG=-ljpeg
2521   fi
2522 fi
2523 AC_SUBST(LIBJPEG)
2524
2525 ### Use -lpng if available, unless `--with-png=no'.
2526 HAVE_PNG=no
2527 LIBPNG=
2528 if test "${HAVE_X11}" = "yes"; then
2529   if test "${with_png}" != "no"; then
2530     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2531     # in /usr/include/libpng.
2532     AC_CHECK_HEADERS(png.h libpng/png.h)
2533     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2534       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2535     fi
2536   fi
2537
2538   if test "${HAVE_PNG}" = "yes"; then
2539     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2540     LIBPNG="-lpng -lz -lm"
2541   fi
2542 fi
2543 AC_SUBST(LIBPNG)
2544
2545 ### Use -ltiff if available, unless `--with-tiff=no'.
2546 HAVE_TIFF=no
2547 LIBTIFF=
2548 if test "${HAVE_X11}" = "yes"; then
2549   if test "${with_tiff}" != "no"; then
2550     AC_CHECK_HEADER(tiffio.h,
2551       [tifflibs="-lz -lm"
2552       # At least one tiff package requires the jpeg library.
2553       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2554       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2555   fi
2556
2557   if test "${HAVE_TIFF}" = "yes"; then
2558     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2559     dnl FIXME -lz -lm, as per libpng?
2560     LIBTIFF=-ltiff
2561   fi
2562 fi
2563 AC_SUBST(LIBTIFF)
2564
2565 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2566 HAVE_GIF=no
2567 LIBGIF=
2568 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2569   AC_CHECK_HEADER(gif_lib.h,
2570 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2571 # Earlier versions can crash Emacs.
2572     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2573
2574   if test "$HAVE_GIF" = yes; then
2575     LIBGIF=-lgif
2576   elif test "$HAVE_GIF" = maybe; then
2577 # If gif_lib.h but no libgif, try libungif.
2578     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2579     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2580   fi
2581
2582   if test "${HAVE_GIF}" = "yes"; then
2583     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2584   fi
2585 fi
2586 AC_SUBST(LIBGIF)
2587
2588 dnl Check for required libraries.
2589 if test "${HAVE_X11}" = "yes"; then
2590   MISSING=""
2591   WITH_NO=""
2592   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2593     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2594   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2595     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2596   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2597     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2598   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2599     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2600   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2601     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2602
2603   if test "X${MISSING}" != X; then
2604     AC_MSG_ERROR([The following required libraries were not found:
2605     $MISSING
2606 Maybe some development libraries/packages are missing?
2607 If you don't want to link with them give
2608     $WITH_NO
2609 as options to configure])
2610   fi
2611 fi
2612
2613 ### Use -lgpm if available, unless `--with-gpm=no'.
2614 HAVE_GPM=no
2615 LIBGPM=
2616 if test "${with_gpm}" != "no"; then
2617   AC_CHECK_HEADER(gpm.h,
2618     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2619
2620   if test "${HAVE_GPM}" = "yes"; then
2621     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2622     LIBGPM=-lgpm
2623   fi
2624 fi
2625 AC_SUBST(LIBGPM)
2626
2627 dnl Check for malloc/malloc.h on darwin
2628 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2629
2630 GNUSTEP_CFLAGS=
2631 ### Use NeXTstep API to implement GUI.
2632 if test "${HAVE_NS}" = "yes"; then
2633   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2634   if test "${NS_IMPL_COCOA}" = "yes"; then
2635     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2636   fi
2637   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2638     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2639     # See also .m.o rule in Makefile.in */
2640     # FIXME: are all these flags really needed?  Document here why.  */
2641     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2642     ## Extra CFLAGS applied to src/*.m files.
2643     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2644   fi
2645   # We also have mouse menus.
2646   HAVE_MENUS=yes
2647   OTHER_FILES=ns-app
2648 fi
2649
2650
2651 ### Use session management (-lSM -lICE) if available
2652 HAVE_X_SM=no
2653 LIBXSM=
2654 if test "${HAVE_X11}" = "yes"; then
2655   AC_CHECK_HEADER(X11/SM/SMlib.h,
2656     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2657
2658   if test "${HAVE_X_SM}" = "yes"; then
2659     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2660     LIBXSM="-lSM -lICE"
2661     case "$LIBS" in
2662       *-lSM*) ;;
2663       *)      LIBS="$LIBXSM $LIBS" ;;
2664     esac
2665   fi
2666 fi
2667 AC_SUBST(LIBXSM)
2668
2669 ### Use libxml (-lxml2) if available
2670 HAVE_LIBXML2=no
2671 if test "${with_xml2}" != "no"; then
2672   ### I'm not sure what the version number should be, so I just guessed.
2673   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2674   if test "${HAVE_LIBXML2}" = "yes"; then
2675     LIBS="$LIBXML2_LIBS $LIBS"
2676     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2677     if test "${HAVE_LIBXML2}" = "yes"; then
2678       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2679     else
2680       LIBXML2_LIBS=""
2681       LIBXML2_CFLAGS=""
2682     fi
2683   fi
2684 fi
2685 AC_SUBST(LIBXML2_LIBS)
2686 AC_SUBST(LIBXML2_CFLAGS)
2687
2688 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2689 AC_CACHE_CHECK(whether netdb declares h_errno,
2690                emacs_cv_netdb_declares_h_errno,
2691 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2692   [[return h_errno;]])],
2693   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2694 if test $emacs_cv_netdb_declares_h_errno = yes; then
2695   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2696 fi
2697
2698 # fmod, logb, and frexp are found in -lm on most systems.
2699 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2700 AC_CHECK_LIB(m, sqrt)
2701
2702 # Check for mail-locking functions in a "mail" library.  Probably this should
2703 # have the same check as for liblockfile below.
2704 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2705 if test $have_mail = yes; then
2706   LIBS_MAIL=-lmail
2707   LIBS="$LIBS_MAIL $LIBS"
2708   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2709 else
2710   LIBS_MAIL=
2711 fi
2712 dnl Debian, at least:
2713 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2714 if test $have_lockfile = yes; then
2715    LIBS_MAIL=-llockfile
2716    LIBS="$LIBS_MAIL $LIBS"
2717    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2718 else
2719 # If we have the shared liblockfile, assume we must use it for mail
2720 # locking (e.g. Debian).  If we couldn't link against liblockfile
2721 # (no liblockfile.a installed), ensure that we don't need to.
2722   dnl This works for files generally, not just executables.
2723   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2724   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2725                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2726   if test $ac_cv_prog_liblockfile = yes; then
2727     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2728 This probably means that movemail could lose mail.
2729 There may be a `development' package to install containing liblockfile.])
2730   fi
2731 fi
2732 AC_CHECK_FUNCS(touchlock)
2733 AC_CHECK_HEADERS(maillock.h)
2734 AC_SUBST(LIBS_MAIL)
2735
2736 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2737 ## interlock access to the mail spool.  The alternative is a lock file named
2738 ## /usr/spool/mail/$USER.lock.
2739 mail_lock=no
2740 case "$opsys" in
2741   aix4-2) mail_lock="lockf" ;;
2742
2743   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2744
2745   ## On GNU/Linux systems, both methods are used by various mail programs.
2746   ## I assume most people are using newer mailers that have heard of flock.
2747   ## Change this if you need to.
2748   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2749   ## configure gets the right answers, and that means *NOT* using flock.
2750   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2751   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2752   ## Debian maintainer hasn't provided a clean fix for Emacs.
2753   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2754   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2755   ## correct logic.  -- fx
2756   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2757   ## liblockfile is a Free Software replacement for libmail, used on
2758   ## Debian systems and elsewhere. -rfr.
2759   gnu-*)
2760     mail_lock="flock"
2761     if test $have_mail = yes || test $have_lockfile = yes; then
2762       test $ac_cv_header_maillock_h = yes && mail_lock=no
2763     fi
2764     ;;
2765 esac
2766
2767 BLESSMAIL_TARGET=
2768 case "$mail_lock" in
2769   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2770
2771   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2772
2773   *) BLESSMAIL_TARGET="need-blessmail" ;;
2774 esac
2775 AC_SUBST(BLESSMAIL_TARGET)
2776
2777
2778 AC_CHECK_FUNCS(gethostname getdomainname \
2779 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2780 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2781 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2782 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2783 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2784 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2785 gai_strerror mkstemp getline getdelim mremap fsync sync \
2786 difftime mempcpy mblen mbrlen posix_memalign \
2787 getpwent endpwent getgrent endgrent \
2788 cfmakeraw cfsetspeed copysign __executable_start)
2789
2790 dnl Cannot use AC_CHECK_FUNCS
2791 AC_CACHE_CHECK([for __builtin_unwind_init],
2792                emacs_cv_func___builtin_unwind_init,
2793 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2794                 emacs_cv_func___builtin_unwind_init=yes,
2795                 emacs_cv_func___builtin_unwind_init=no)])
2796 if test $emacs_cv_func___builtin_unwind_init = yes; then
2797   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2798             [Define to 1 if you have the `__builtin_unwind_init' function.])
2799 fi
2800
2801 AC_CHECK_HEADERS(sys/un.h)
2802
2803 AC_FUNC_FSEEKO
2804
2805 AC_FUNC_GETPGRP
2806
2807 # UNIX98 PTYs.
2808 AC_CHECK_FUNCS(grantpt)
2809
2810 # PTY-related GNU extensions.
2811 AC_CHECK_FUNCS(getpt)
2812
2813 # Check this now, so that we will NOT find the above functions in ncurses.
2814 # That is because we have not set up to link ncurses in lib-src.
2815 # It's better to believe a function is not available
2816 # than to expect to find it in ncurses.
2817 # Also we need tputs and friends to be able to build at all.
2818 AC_MSG_CHECKING([for library containing tputs])
2819 # Run a test program that contains a call to tputs, a call that is
2820 # never executed.  This tests whether a pre-'main' dynamic linker
2821 # works with the library.  It's too much trouble to actually call
2822 # tputs in the test program, due to portability hassles.  When
2823 # cross-compiling, assume the test program will run if it links.
2824 AC_DEFUN([tputs_link_source], [
2825   AC_LANG_SOURCE(
2826      [[extern void tputs (const char *, int, int (*)(int));
2827        int main (int argc, char **argv)
2828        {
2829           if (argc == 10000)
2830             tputs (argv[0], 0, 0);
2831           return 0;
2832        }]])
2833 ])
2834 # Maybe curses should be tried earlier?
2835 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2836 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2837   OLIBS=$LIBS
2838   if test -z "$tputs_library"; then
2839     LIBS_TERMCAP=
2840     msg='none required'
2841   else
2842     LIBS_TERMCAP=-l$tputs_library
2843     msg=$LIBS_TERMCAP
2844     LIBS="$LIBS_TERMCAP $LIBS"
2845   fi
2846   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2847     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2848   LIBS=$OLIBS
2849   if test "X$msg" != Xno; then
2850     break
2851   fi
2852 done
2853 AC_MSG_RESULT([$msg])
2854 if test "X$msg" = Xno; then
2855   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2856 The following libraries were tried (in order):
2857   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2858 Please try installing whichever of these libraries is most appropriate
2859 for your system, together with its header files.
2860 For example, a libncurses-dev(el) or similar package.])
2861 fi
2862
2863 ## Use termcap instead of terminfo?
2864 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2865 TERMINFO=yes
2866 ## FIXME?  In the cases below where we unconditionally set
2867 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2868 ## if that was found above to have tputs.
2869 ## Should we use the gnu* logic everywhere?
2870 case "$opsys" in
2871   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2872   ##  The ncurses library has been moved out of the System framework in
2873   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2874   ##  option to use it.
2875   darwin) LIBS_TERMCAP="-lncurses" ;;
2876
2877   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2878
2879   freebsd)
2880     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2881     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2882     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2883 [[#if __FreeBSD_version < 400000
2884 fail;
2885 #endif
2886 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2887
2888     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2889
2890     if test $emacs_cv_freebsd_terminfo = yes; then
2891       LIBS_TERMCAP="-lncurses"
2892     else
2893       TERMINFO=no
2894       LIBS_TERMCAP="-ltermcap"
2895     fi
2896     ;;
2897
2898   netbsd)
2899     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2900       TERMINFO=no
2901       LIBS_TERMCAP="-ltermcap"
2902     fi
2903     ;;
2904
2905   openbsd) LIBS_TERMCAP="-lncurses" ;;
2906
2907   ## hpux: Make sure we get select from libc rather than from libcurses
2908   ##  because libcurses on HPUX 10.10 has a broken version of select.
2909   ##  We used to use -lc -lcurses, but this may be cleaner.
2910   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2911   # set that way, now it uses the default).  Isn't this a contradiction?
2912   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2913
2914 esac
2915
2916 TERMCAP_OBJ=tparam.o
2917 if test $TERMINFO = yes; then
2918   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2919   TERMCAP_OBJ=terminfo.o
2920 fi
2921 AC_SUBST(LIBS_TERMCAP)
2922 AC_SUBST(TERMCAP_OBJ)
2923
2924
2925 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2926 resolv=no
2927 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2928 #include <arpa/nameser.h>
2929 #include <resolv.h>]],
2930     [[return res_init();]])],
2931     have_res_init=yes, have_res_init=no)
2932 if test "$have_res_init" = no; then
2933   OLIBS="$LIBS"
2934   LIBS="$LIBS -lresolv"
2935   AC_MSG_CHECKING(for res_init with -lresolv)
2936   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2937 #include <arpa/nameser.h>
2938 #include <resolv.h>]],
2939     [[return res_init();]])],
2940     have_res_init=yes, have_res_init=no)
2941   AC_MSG_RESULT($have_res_init)
2942   if test "$have_res_init" = yes ; then
2943     resolv=yes
2944   fi
2945   LIBS="$OLIBS"
2946 fi
2947
2948 if test "$have_res_init" = yes; then
2949   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2950 fi
2951
2952 # Do we need the Hesiod library to provide the support routines?
2953 LIBHESIOD=
2954 if test "$with_hesiod" != no ; then
2955   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2956   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2957      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2958                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2959   if test "$resolv" = yes ; then
2960     RESOLVLIB=-lresolv
2961   else
2962     RESOLVLIB=
2963   fi
2964   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2965         hesiod=yes, :, $RESOLVLIB)])
2966
2967   if test x"$hesiod" = xyes; then
2968     AC_DEFINE(HAVE_LIBHESIOD, 1,
2969               [Define to 1 if you have the hesiod library (-lhesiod).])
2970     LIBHESIOD=-lhesiod
2971   fi
2972 fi
2973 AC_SUBST(LIBHESIOD)
2974
2975 # Do we need libresolv (due to res_init or Hesiod)?
2976 if test "$resolv" = yes ; then
2977   AC_DEFINE(HAVE_LIBRESOLV, 1,
2978             [Define to 1 if you have the resolv library (-lresolv).])
2979   LIBRESOLV=-lresolv
2980 else
2981   LIBRESOLV=
2982 fi
2983 AC_SUBST(LIBRESOLV)
2984
2985 # These tell us which Kerberos-related libraries to use.
2986 COM_ERRLIB=
2987 CRYPTOLIB=
2988 KRB5LIB=
2989 DESLIB=
2990 KRB4LIB=
2991
2992 if test "${with_kerberos}" != no; then
2993   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2994   if test $have_com_err = yes; then
2995     COM_ERRLIB=-lcom_err
2996     LIBS="$COM_ERRLIB $LIBS"
2997     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2998   fi
2999   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3000   if test $have_crypto = yes; then
3001     CRYPTOLIB=-lcrypto
3002     LIBS="$CRYPTOLIB $LIBS"
3003     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3004   fi
3005   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3006   if test $have_k5crypto = yes; then
3007     CRYPTOLIB=-lk5crypto
3008     LIBS="$CRYPTOLIB $LIBS"
3009     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3010   fi
3011   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3012   if test $have_krb5=yes; then
3013     KRB5LIB=-lkrb5
3014     LIBS="$KRB5LIB $LIBS"
3015     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3016   fi
3017   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3018   if test "${with_kerberos5}" = no; then
3019     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3020     if test $have_des425 = yes; then
3021       DESLIB=-ldes425
3022       LIBS="$DESLIB $LIBS"
3023       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3024     else
3025       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3026       if test $have_des = yes; then
3027         DESLIB=-ldes
3028         LIBS="$DESLIB $LIBS"
3029         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3030       fi
3031     fi
3032     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3033     if test $have_krb4 = yes; then
3034       KRB4LIB=-lkrb4
3035       LIBS="$KRB4LIB $LIBS"
3036       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3037     else
3038       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3039       if test $have_krb = yes; then
3040         KRB4LIB=-lkrb
3041         LIBS="$KRB4LIB $LIBS"
3042         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3043       fi
3044     fi
3045   fi
3046
3047   if test "${with_kerberos5}" != no; then
3048     AC_CHECK_HEADERS(krb5.h,
3049       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3050                         [#include <krb5.h>])])
3051   else
3052     AC_CHECK_HEADERS(des.h,,
3053                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3054                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3055     AC_CHECK_HEADERS(krb.h,,
3056                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3057                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3058   fi
3059   AC_CHECK_HEADERS(com_err.h)
3060 fi
3061
3062 AC_SUBST(COM_ERRLIB)
3063 AC_SUBST(CRYPTOLIB)
3064 AC_SUBST(KRB5LIB)
3065 AC_SUBST(DESLIB)
3066 AC_SUBST(KRB4LIB)
3067
3068 AC_MSG_CHECKING(whether localtime caches TZ)
3069 AC_CACHE_VAL(emacs_cv_localtime_cache,
3070 [if test x$ac_cv_func_tzset = xyes; then
3071 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3072 char TZ_GMT0[] = "TZ=GMT0";
3073 char TZ_PST8[] = "TZ=PST8";
3074 main()
3075 {
3076   time_t now = time ((time_t *) 0);
3077   int hour_GMT0, hour_unset;
3078   if (putenv (TZ_GMT0) != 0)
3079     exit (1);
3080   hour_GMT0 = localtime (&now)->tm_hour;
3081   unsetenv("TZ");
3082   hour_unset = localtime (&now)->tm_hour;
3083   if (putenv (TZ_PST8) != 0)
3084     exit (1);
3085   if (localtime (&now)->tm_hour == hour_GMT0)
3086     exit (1);
3087   unsetenv("TZ");
3088   if (localtime (&now)->tm_hour != hour_unset)
3089     exit (1);
3090   exit (0);
3091 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3092 [# If we have tzset, assume the worst when cross-compiling.
3093 emacs_cv_localtime_cache=yes])
3094 else
3095         # If we lack tzset, report that localtime does not cache TZ,
3096         # since we can't invalidate the cache if we don't have tzset.
3097         emacs_cv_localtime_cache=no
3098 fi])dnl
3099 AC_MSG_RESULT($emacs_cv_localtime_cache)
3100 if test $emacs_cv_localtime_cache = yes; then
3101   AC_DEFINE(LOCALTIME_CACHE, 1,
3102             [Define to 1 if localtime caches TZ.])
3103 fi
3104
3105 if test "x$HAVE_TIMEVAL" = xyes; then
3106   AC_CHECK_FUNCS(gettimeofday)
3107   if test $ac_cv_func_gettimeofday = yes; then
3108     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3109                    emacs_cv_gettimeofday_two_arguments,
3110     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3111 #ifdef TIME_WITH_SYS_TIME
3112 #include <sys/time.h>
3113 #include <time.h>
3114 #else
3115 #ifdef HAVE_SYS_TIME_H
3116 #include <sys/time.h>
3117 #else
3118 #include <time.h>
3119 #endif
3120 #endif]],
3121       [[struct timeval time;
3122        gettimeofday (&time, 0);]])],
3123       emacs_cv_gettimeofday_two_arguments=yes,
3124       emacs_cv_gettimeofday_two_arguments=no)])
3125     if test $emacs_cv_gettimeofday_two_arguments = no; then
3126       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3127                 [Define to 1 if gettimeofday accepts only one argument.])
3128     fi
3129   fi
3130 fi
3131
3132 ok_so_far=yes
3133 AC_CHECK_FUNC(socket, , ok_so_far=no)
3134 if test $ok_so_far = yes; then
3135   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3136 fi
3137 if test $ok_so_far = yes; then
3138   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3139 fi
3140 if test $ok_so_far = yes; then
3141 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3142   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3143             [Define to 1 if you have inet sockets.])
3144 fi
3145
3146 if test -f /usr/lpp/X11/bin/smt.exp; then
3147   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3148             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3149 fi
3150
3151 AC_MSG_CHECKING(whether system supports dynamic ptys)
3152 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3153   AC_MSG_RESULT(yes)
3154   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3155 else
3156   AC_MSG_RESULT(no)
3157 fi
3158
3159 AC_FUNC_FORK
3160
3161 AC_CHECK_FUNCS(snprintf)
3162
3163 dnl Adapted from Haible's version.
3164 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3165   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3166     [[char* cs = nl_langinfo(CODESET);]])],
3167     emacs_cv_langinfo_codeset=yes,
3168     emacs_cv_langinfo_codeset=no)
3169   ])
3170 if test $emacs_cv_langinfo_codeset = yes; then
3171   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3172     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3173 fi
3174
3175 AC_TYPE_MBSTATE_T
3176
3177 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3178   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3179                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3180 if test "$emacs_cv_c_restrict_arr" = yes; then
3181   AC_DEFINE(__restrict_arr, __restrict,
3182     [Define to compiler's equivalent of C99 restrict keyword in array
3183      declarations.  Define as empty for no equivalent.])
3184 fi
3185
3186 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3187 dnl how the tty code is related to POSIX and/or other versions of termios.
3188 dnl The following looks like a useful start.
3189 dnl
3190 dnl AC_SYS_POSIX_TERMIOS
3191 dnl if test $ac_cv_sys_posix_termios = yes; then
3192 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3193 dnl                                and macros for terminal control.])
3194 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3195 dnl fi
3196
3197 # Set up the CFLAGS for real compilation, so we can substitute it.
3198 CFLAGS="$REAL_CFLAGS"
3199 CPPFLAGS="$REAL_CPPFLAGS"
3200
3201 ## Hack to detect a buggy GCC version.
3202 if test "x$GCC" = xyes \
3203    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3204    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3205    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3206    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3207 fi
3208
3209 version=$PACKAGE_VERSION
3210
3211 ### Specify what sort of things we'll be editing into Makefile and config.h.
3212 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3213 AC_SUBST(version)
3214 AC_SUBST(configuration)
3215 ## Unused?
3216 AC_SUBST(canonical)
3217 AC_SUBST(srcdir)
3218 AC_SUBST(prefix)
3219 AC_SUBST(exec_prefix)
3220 AC_SUBST(bindir)
3221 AC_SUBST(datadir)
3222 AC_SUBST(sharedstatedir)
3223 AC_SUBST(libexecdir)
3224 AC_SUBST(mandir)
3225 AC_SUBST(infodir)
3226 AC_SUBST(lispdir)
3227 AC_SUBST(locallisppath)
3228 AC_SUBST(lisppath)
3229 AC_SUBST(x_default_search_path)
3230 AC_SUBST(etcdir)
3231 AC_SUBST(archlibdir)
3232 AC_SUBST(docdir)
3233 AC_SUBST(bitmapdir)
3234 AC_SUBST(gamedir)
3235 AC_SUBST(gameuser)
3236 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3237 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3238 ## end of LIBX_BASE, but nothing ever set it.
3239 AC_SUBST(LD_SWITCH_X_SITE)
3240 AC_SUBST(C_SWITCH_X_SITE)
3241 AC_SUBST(GNUSTEP_CFLAGS)
3242 AC_SUBST(CFLAGS)
3243 ## Used in lwlib/Makefile.in.
3244 AC_SUBST(X_TOOLKIT_TYPE)
3245 if test -n "${machfile}"; then
3246   M_FILE="\$(srcdir)/${machfile}"
3247 else
3248   M_FILE=
3249 fi
3250 S_FILE="\$(srcdir)/${opsysfile}"
3251 AC_SUBST(M_FILE)
3252 AC_SUBST(S_FILE)
3253 AC_SUBST(ns_appdir)
3254 AC_SUBST(ns_appbindir)
3255 AC_SUBST(ns_appresdir)
3256 AC_SUBST(ns_appsrc)
3257 AC_SUBST(GNU_OBJC_CFLAGS)
3258 AC_SUBST(OTHER_FILES)
3259
3260 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3261                    [Define to the canonical Emacs configuration name.])
3262 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3263                    [Define to the options passed to configure.])
3264 if test -n "$machfile"; then
3265   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3266                      [Define to the used machine dependent file.])
3267 fi
3268 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3269                    [Define to the used os dependent file.])
3270
3271 XMENU_OBJ=
3272 XOBJ=
3273 FONT_OBJ=
3274 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3275   AC_DEFINE(HAVE_X_WINDOWS, 1,
3276             [Define to 1 if you want to use the X window system.])
3277   XMENU_OBJ=xmenu.o
3278   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3279   FONT_OBJ=xfont.o
3280   if test "$HAVE_XFT" = "yes"; then
3281     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3282   elif test "$HAVE_FREETYPE" = "yes"; then
3283     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3284   fi
3285   AC_SUBST(FONT_OBJ)
3286 fi
3287 AC_SUBST(XMENU_OBJ)
3288 AC_SUBST(XOBJ)
3289 AC_SUBST(FONT_OBJ)
3290
3291 WIDGET_OBJ=
3292 MOTIF_LIBW=
3293 if test "${USE_X_TOOLKIT}" != "none" ; then
3294   WIDGET_OBJ=widget.o
3295   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3296   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3297     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3298   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3299     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3300     MOTIF_LIBW=-lXm
3301     case "$opsys" in
3302       gnu-linux)
3303         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3304         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3305         ;;
3306
3307       unixware)
3308         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3309         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3310         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3311         ;;
3312
3313       aix4-2)
3314         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3315         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3316         ;;
3317     esac
3318     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3319   fi
3320 fi
3321 AC_SUBST(WIDGET_OBJ)
3322
3323 TOOLKIT_LIBW=
3324 case "$USE_X_TOOLKIT" in
3325   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3326   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3327   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3328 esac
3329 AC_SUBST(TOOLKIT_LIBW)
3330
3331 if test "$USE_X_TOOLKIT" = "none"; then
3332   LIBXT_OTHER="\$(LIBXSM)"
3333   OLDXMENU_TARGET="really-oldXMenu"
3334 else
3335   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3336   OLDXMENU_TARGET="really-lwlib"
3337 fi
3338 AC_SUBST(LIBXT_OTHER)
3339
3340 ## The X Menu stuff is present in the X10 distribution, but missing
3341 ## from X11.  If we have X10, just use the installed library;
3342 ## otherwise, use our own copy.
3343 if test "${HAVE_X11}" = "yes" ; then
3344   AC_DEFINE(HAVE_X11, 1,
3345             [Define to 1 if you want to use version 11 of X windows.
3346              Otherwise, Emacs expects to use version 10.])
3347
3348   if test "$USE_X_TOOLKIT" = "none"; then
3349     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3350   else
3351     OLDXMENU="\${lwlibdir}/liblw.a"
3352   fi
3353   LIBXMENU="\$(OLDXMENU)"
3354   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3355   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3356 else
3357   ## For a syntactically valid Makefile; not actually used for anything.
3358   ## See comments in src/Makefile.in.
3359   OLDXMENU=nothing
3360   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3361   if test "${HAVE_X_WINDOWS}" = "yes"; then
3362     LIBXMENU="-lXMenu"
3363   else
3364     LIBXMENU=
3365   fi
3366   LIBX_OTHER=
3367   OLDXMENU_DEPS=
3368 fi
3369
3370 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3371   OLDXMENU_TARGET=
3372   OLDXMENU=nothing
3373   LIBXMENU=
3374   OLDXMENU_DEPS=
3375 fi
3376
3377 AC_SUBST(OLDXMENU_TARGET)
3378 AC_SUBST(OLDXMENU)
3379 AC_SUBST(LIBXMENU)
3380 AC_SUBST(LIBX_OTHER)
3381 AC_SUBST(OLDXMENU_DEPS)
3382
3383 if test "${HAVE_MENUS}" = "yes" ; then
3384   AC_DEFINE(HAVE_MENUS, 1,
3385             [Define to 1 if you have mouse menus.
3386              (This is automatic if you use X, but the option to specify it remains.)
3387              It is also defined with other window systems that support xmenu.c.])
3388 fi
3389
3390 if test "${GNU_MALLOC}" = "yes" ; then
3391   AC_DEFINE(GNU_MALLOC, 1,
3392             [Define to 1 if you want to use the GNU memory allocator.])
3393 fi
3394
3395 RALLOC_OBJ=
3396 if test "${REL_ALLOC}" = "yes" ; then
3397   AC_DEFINE(REL_ALLOC, 1,
3398             [Define REL_ALLOC if you want to use the relocating allocator for
3399              buffer space.])
3400
3401   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3402 fi
3403 AC_SUBST(RALLOC_OBJ)
3404
3405 if test "$opsys" = "cygwin"; then
3406   CYGWIN_OBJ="sheap.o"
3407   ## Cygwin differs because of its unexec().
3408   PRE_ALLOC_OBJ=
3409   POST_ALLOC_OBJ=lastfile.o
3410 else
3411   CYGWIN_OBJ=
3412   PRE_ALLOC_OBJ=lastfile.o
3413   POST_ALLOC_OBJ=
3414 fi
3415 AC_SUBST(CYGWIN_OBJ)
3416 AC_SUBST(PRE_ALLOC_OBJ)
3417 AC_SUBST(POST_ALLOC_OBJ)
3418
3419 # Configure gnulib here, now that we know LIBS.
3420 gl_ASSERT_NO_GNULIB_POSIXCHECK
3421 gl_ASSERT_NO_GNULIB_TESTS
3422 gl_INIT
3423
3424 case "$opsys" in
3425   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3426
3427   darwin)
3428    ## The -headerpad option tells ld (see man page) to leave room at the
3429    ## end of the header for adding load commands.  Needed for dumping.
3430    ## 0x690 is the total size of 30 segment load commands (at 56
3431    ## each); under Cocoa 31 commands are required.
3432    if test "$HAVE_NS" = "yes"; then
3433      libs_nsgui="-framework AppKit"
3434      headerpad_extra=6C8
3435    else
3436      libs_nsgui=
3437      headerpad_extra=690
3438    fi
3439    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3440
3441    ## This is here because src/Makefile.in did some extra fiddling around
3442    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3443    ##   #ifndef LD_SWITCH_SYSTEM
3444    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3445    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3446    ## not using gcc, darwin system not on an alpha (ie darwin, since
3447    ## darwin + alpha does not occur).
3448    ## Because this was done in src/Makefile.in, the resulting part of
3449    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3450    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3451    ## rather than LD_SWITCH_SYSTEM.
3452    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3453      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3454    ;;
3455
3456   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3457   ## find X at run-time.
3458   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3459   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3460   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3461   ## had different values in configure (in ac_link) and src/Makefile.in.
3462   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3463   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3464
3465   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3466 esac
3467
3468 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3469   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3470 fi
3471
3472 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3473
3474
3475 LD_FIRSTFLAG=
3476 ORDINARY_LINK=
3477 case "$opsys" in
3478   ## gnu: GNU needs its own crt0.
3479   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3480
3481   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3482   ## library search parth, i.e. it won't search /usr/lib for libc and
3483   ## friends.  Using -nostartfiles instead avoids this problem, and
3484   ## will also work on earlier NetBSD releases.
3485   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3486
3487   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3488   ##   MkLinux/LinuxPPC needs this.
3489   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3490   gnu-*)
3491     case "$machine" in
3492       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3493     esac
3494     ;;
3495 esac
3496
3497
3498 if test "x$ORDINARY_LINK" = "xyes"; then
3499
3500   LD_FIRSTFLAG=""
3501   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3502
3503 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3504 ## freebsd, gnu-* not on macppc|ibms390x.
3505 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3506
3507   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3508   ## places that are difficult to figure out at make time.  Fortunately,
3509   ## these same versions allow you to pass arbitrary flags on to the
3510   ## linker, so there is no reason not to use it as a linker.
3511   ##
3512   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3513   ## searching for libraries in its internal directories, so we have to
3514   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3515   LD_FIRSTFLAG="-nostdlib"
3516 fi
3517
3518 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3519 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3520
3521 AC_SUBST(LD_FIRSTFLAG)
3522
3523
3524 ## FIXME? The logic here is not precisely the same as that above.
3525 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3526 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3527 LIB_GCC=
3528 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3529
3530   case "$opsys" in
3531     freebsd|netbsd|openbsd) LIB_GCC= ;;
3532
3533     gnu-*)
3534       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3535       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3536       case $host_cpu in
3537       arm*)
3538         LIB_GCC="-lgcc_s"
3539         ;;
3540       *)
3541         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3542         ## immediately undefine it again and redefine it to empty.
3543         ## Was the C_SWITCH_X_SITE part really necessary?
3544 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3545         LIB_GCC=
3546         ;;
3547       esac
3548       ;;
3549
3550     ## Ask GCC where to find libgcc.a.
3551     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3552   esac
3553 fi                              dnl if $GCC
3554 AC_SUBST(LIB_GCC)
3555
3556
3557 ## If we're using X11/GNUstep, define some consequences.
3558 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3559   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3560   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3561 fi
3562
3563
3564 AH_TOP([/* GNU Emacs site configuration template file.
3565
3566 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3567   Free Software Foundation, Inc.
3568
3569 This file is part of GNU Emacs.
3570
3571 GNU Emacs is free software: you can redistribute it and/or modify
3572 it under the terms of the GNU General Public License as published by
3573 the Free Software Foundation, either version 3 of the License, or
3574 (at your option) any later version.
3575
3576 GNU Emacs is distributed in the hope that it will be useful,
3577 but WITHOUT ANY WARRANTY; without even the implied warranty of
3578 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3579 GNU General Public License for more details.
3580
3581 You should have received a copy of the GNU General Public License
3582 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3583
3584
3585 /* No code in Emacs #includes config.h twice, but some bits of code
3586    intended to work with other packages as well (like gmalloc.c)
3587    think they can include it as many times as they like.  */
3588 #ifndef EMACS_CONFIG_H
3589 #define EMACS_CONFIG_H
3590 ])dnl
3591
3592 AH_BOTTOM([
3593 /* On AIX 3 this must be included before any other include file.  */
3594 #include <alloca.h>
3595 #if ! HAVE_ALLOCA
3596 # error "alloca not available on this machine"
3597 #endif
3598
3599 /* Define AMPERSAND_FULL_NAME if you use the convention
3600    that & in the full name stands for the login id.  */
3601 /* Turned on June 1996 supposing nobody will mind it.  */
3602 #define AMPERSAND_FULL_NAME
3603
3604 /* `subprocesses' should be defined if you want to
3605    have code for asynchronous subprocesses
3606    (as used in M-x compile and M-x shell).
3607    Only MSDOS does not support this (it overrides
3608    this in its config_opsysfile below).  */
3609
3610 #define subprocesses
3611
3612 /* Include the os and machine dependent files.  */
3613 #include config_opsysfile
3614 #ifdef config_machfile
3615 # include config_machfile
3616 #endif
3617
3618 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3619    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3620   (There is probably a better place to do this, but right now the
3621    Cocoa side does this in s/darwin.h and we cannot parallel this
3622    exactly since GNUstep is multi-OS.  */
3623 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3624 #  define SYSTEM_PURESIZE_EXTRA 30000
3625 #endif
3626
3627 #ifdef emacs /* Don't do this for lib-src.  */
3628 /* Tell regex.c to use a type compatible with Emacs.  */
3629 #define RE_TRANSLATE_TYPE Lisp_Object
3630 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3631 #ifdef make_number
3632 /* If make_number is a macro, use it.  */
3633 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3634 #else
3635 /* If make_number is a function, avoid it.  */
3636 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3637 #endif
3638 #endif
3639
3640 /* These default definitions are good for almost all machines.
3641    Any exceptions should override them in m/MACHINE.h.
3642    They must be usable in preprocessor conditionals.  */
3643
3644 #ifndef BITS_PER_CHAR
3645 #define BITS_PER_CHAR 8
3646 #endif
3647
3648 #ifndef BITS_PER_SHORT
3649 #define BITS_PER_SHORT 16
3650 #endif
3651
3652 #ifndef BITS_PER_INT
3653 #define BITS_PER_INT 32
3654 #endif
3655
3656 #ifndef BITS_PER_LONG
3657 #ifdef _LP64
3658 #define BITS_PER_LONG 64
3659 #else
3660 #define BITS_PER_LONG 32
3661 #endif
3662 #endif
3663
3664 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3665 #define BITS_PER_LONG_LONG 64
3666 #endif
3667
3668 /* Define if the compiler supports function prototypes.  It may do so but
3669    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3670 #undef PROTOTYPES
3671
3672 #include <string.h>
3673 #include <stdlib.h>
3674
3675 #if defined __GNUC__ && (__GNUC__ > 2 \
3676                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3677 #define NO_RETURN       __attribute__ ((__noreturn__))
3678 #else
3679 #define NO_RETURN       /* nothing */
3680 #endif
3681
3682 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3683 #define NO_INLINE __attribute__((noinline))
3684 #else
3685 #define NO_INLINE
3686 #endif
3687
3688 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3689 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3690 #else
3691 #define EXTERNALLY_VISIBLE
3692 #endif
3693
3694 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3695 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3696 #else
3697 # define ATTRIBUTE_FORMAT(spec) /* empty */
3698 #endif
3699
3700 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3701 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3702    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3703 #else
3704 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3705    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3706 #endif
3707
3708 /* Some versions of GNU/Linux define noinline in their headers.  */
3709 #ifdef noinline
3710 #undef noinline
3711 #endif
3712
3713 /* These won't be used automatically yet.  We also need to know, at least,
3714    that the stack is continuous.  */
3715 #ifdef __GNUC__
3716 #  ifndef GC_SETJMP_WORKS
3717   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3718 #    define GC_SETJMP_WORKS 1
3719 #  endif
3720 #endif
3721
3722 #endif /* EMACS_CONFIG_H */
3723
3724 /*
3725 Local Variables:
3726 mode: c
3727 End:
3728 */
3729 ])dnl
3730
3731 #### Report on what we decided to do.
3732 #### Report GTK as a toolkit, even if it doesn't use Xt.
3733 #### It makes printing result more understandable as using GTK sets
3734 #### toolkit_scroll_bars to yes by default.
3735 if test "${HAVE_GTK}" = "yes"; then
3736   USE_X_TOOLKIT=GTK
3737 fi
3738
3739 and_machfile=
3740 if test -n "$machfile"; then
3741   and_machfile=" and \`${machfile}'"
3742 fi
3743
3744 echo "
3745 Configured for \`${canonical}'.
3746
3747   Where should the build process find the source code?    ${srcdir}
3748   What operating system and machine description files should Emacs use?
3749         \`${opsysfile}'${and_machfile}
3750   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3751   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3752   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3753   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3754   What window system should Emacs use?                    ${window_system}
3755   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3756
3757 if test -n "${x_includes}"; then
3758 echo "  Where do we find X Windows header files?                ${x_includes}"
3759 else
3760 echo "  Where do we find X Windows header files?                Standard dirs"
3761 fi
3762 if test -n "${x_libraries}"; then
3763 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3764 else
3765 echo "  Where do we find X Windows libraries?                   Standard dirs"
3766 fi
3767
3768 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3769 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3770 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3771 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3772 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3773 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3774 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3775 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3776
3777 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3778 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3779 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3780 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3781 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3782 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3783 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3784
3785 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3786 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3787 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3788 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3789
3790 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3791 echo
3792
3793 if test -n "${EMACSDATA}"; then
3794    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3795 fi
3796 if test -n "${EMACSDOC}"; then
3797    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3798 fi
3799
3800 if test $USE_XASSERTS = yes; then
3801    echo "  Compiling with asserts turned on."
3802    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3803 fi
3804
3805 echo
3806
3807 if test "$HAVE_NS" = "yes"; then
3808    echo
3809    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3810 The installed application will go to nextstep/Emacs.app and can be
3811 run or moved from there."
3812    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3813       echo "The application will be fully self-contained."
3814     else
3815       echo "The lisp resources for the application will be installed under ${prefix}.
3816 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3817 to run if these resources are not installed."
3818    fi
3819    echo
3820 fi
3821
3822 if test "${opsys}" = "cygwin"; then
3823   case `uname -r` in
3824     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3825            echo
3826            ;;
3827   esac
3828 fi
3829
3830 # Remove any trailing slashes in these variables.
3831 [test "${prefix}" != NONE &&
3832   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3833 test "${exec_prefix}" != NONE &&
3834   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3835
3836 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3837 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3838 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3839 dnl (else you get "no `Makefile.am' found for any configure output").
3840 dnl This will work, but you get a config.status that is not quite right
3841 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3842 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3843 dnl it seems better to just live with the duplication.
3844 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3845
3846 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3847        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3848        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3849        leim/Makefile])
3850
3851 dnl test/ is not present in release tarfiles.
3852 opt_makefile=test/automated/Makefile
3853
3854 if test -f $srcdir/${opt_makefile}.in; then
3855   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3856   dnl Again, it's best not to use a variable.  Though you can add
3857   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3858   AC_CONFIG_FILES([test/automated/Makefile])
3859 fi
3860
3861
3862 dnl admin/ may or may not be present.
3863 opt_makefile=admin/unidata/Makefile
3864
3865 if test -f $srcdir/${opt_makefile}.in; then
3866   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3867   AC_CONFIG_FILES([admin/unidata/Makefile])
3868 fi
3869
3870
3871 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3872
3873 AC_SUBST(SUBDIR_MAKEFILES_IN)
3874
3875 dnl Make the necessary directories, if they don't exist.
3876 AC_CONFIG_COMMANDS([mkdirs], [
3877 for dir in etc lisp ; do
3878   test -d ${dir} || mkdir ${dir}
3879 done
3880 ])
3881
3882 dnl You might wonder (I did) why epaths.h is generated by running make,
3883 dnl rather than just letting configure generate it from epaths.in.
3884 dnl One reason is that the various paths are not fully expanded (see above);
3885 dnl eg gamedir=${prefix}/var/games/emacs.
3886 dnl Secondly, the GNU Coding standards require that one should be able
3887 dnl to run `make prefix=/some/where/else' and override the values set
3888 dnl by configure.  This also explains the `move-if-change' test and
3889 dnl the use of force in the `epaths-force' rule in Makefile.in.
3890 AC_CONFIG_COMMANDS([epaths], [
3891 echo creating src/epaths.h
3892 ${MAKE-make} epaths-force
3893 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3894
3895 AC_CONFIG_COMMANDS([gdbinit], [
3896 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3897   echo creating src/.gdbinit
3898   echo source $srcdir/src/.gdbinit > src/.gdbinit
3899 fi
3900 ])
3901
3902 AC_OUTPUT
3903
3904 dnl configure.in ends here