lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992,1993,1994,1995,1996,1998,1999,2000,2001,2002,2004
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   ;; Warning suppression -- can't require x-win in batch:
  33   (autoload 'xw-defined-colors "x-win"))
  34
  35 \f
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; Font selection.
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39
  40 (defgroup font-selection nil
  41   "Influencing face font selection."
  42   :group 'faces)
  43
  44
  45 (defcustom face-font-selection-order
  46   '(:width :height :weight :slant)
  47   "*A list specifying how face font selection chooses fonts.
  48 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  49 must appear once in the list, and the list must not contain any other
  50 elements.  Font selection tries to find a best matching font for
  51 those face attributes first that appear first in the list.  For
  52 example, if `:slant' appears before `:height', font selection first
  53 tries to find a font with a suitable slant, even if this results in
  54 a font height that isn't optimal."
  55   :tag "Font selection order"
  56   :type '(list symbol symbol symbol symbol)
  57   :group 'font-selection
  58   :set #'(lambda (symbol value)
  59            (set-default symbol value)
  60            (internal-set-font-selection-order value)))
  61
  62
  63 ;; This is defined originally in xfaces.c.
  64 (defcustom face-font-family-alternatives
  65   '(("courier" "fixed")
  66     ("helv" "helvetica" "arial" "fixed"))
  67   "*Alist of alternative font family names.
  68 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  69 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  70 ALTERNATIVE2 etc."
  71   :tag "Alternative font families to try"
  72   :type '(repeat (repeat string))
  73   :group 'font-selection
  74   :set #'(lambda (symbol value)
  75            (set-default symbol value)
  76            (internal-set-alternative-font-family-alist value)))
  77
  78
  79 ;; This is defined originally in xfaces.c.
  80 (defcustom face-font-registry-alternatives
  81   (if (eq system-type 'windows-nt)
  82       '(("iso8859-1" "ms-oemlatin")
  83         ("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try"
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame, NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned."
 200   (or (facep name)
 201       (check-face name)))
 202 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 203
 204 \f
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;;; Predicates, type checks.
 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 208
 209 (defun facep (face)
 210   "Return non-nil if FACE is a face name."
 211   (internal-lisp-face-p face))
 212
 213
 214 (defun check-face (face)
 215   "Signal an error if FACE doesn't name a face.
 216 Value is FACE."
 217   (unless (facep face)
 218     (error "Not a face: %s" face))
 219   face)
 220
 221
 222 ;; The ID returned is not to be confused with the internally used IDs
 223 ;; of realized faces.  The ID assigned to Lisp faces is used to
 224 ;; support faces in display table entries.
 225
 226 (defun face-id (face &optional frame)
 227   "Return the internal ID of face with name FACE.
 228 If optional argument FRAME is nil or omitted, use the selected frame."
 229   (check-face face)
 230   (get face 'face))
 231
 232
 233 (defun face-equal (face1 face2 &optional frame)
 234   "Non-nil if faces FACE1 and FACE2 are equal.
 235 Faces are considered equal if all their attributes are equal.
 236 If the optional argument FRAME is given, report on face FACE in that frame.
 237 If FRAME is t, report on the defaults for face FACE (for new frames).
 238 If FRAME is omitted or nil, use the selected frame."
 239   (internal-lisp-face-equal-p face1 face2 frame))
 240
 241
 242 (defun face-differs-from-default-p (face &optional frame)
 243   "Return non-nil if FACE displays differently from the default face.
 244 If the optional argument FRAME is given, report on face FACE in that frame.
 245 If FRAME is t, report on the defaults for face FACE (for new frames).
 246 If FRAME is omitted or nil, use the selected frame."
 247   (let ((attrs
 248          '(:family :width :height :weight :slant :foreground
 249            :foreground :background :underline :overline
 250            :strike-through :box :inverse-video))
 251         (differs nil))
 252     (while (and attrs (not differs))
 253       (let* ((attr (pop attrs))
 254              (attr-val (face-attribute face attr frame t)))
 255         (when (and
 256                (not (eq attr-val 'unspecified))
 257                (display-supports-face-attributes-p (list attr attr-val)
 258                                                    frame))
 259           (setq differs attr))))
 260     differs))
 261
 262
 263 (defun face-nontrivial-p (face &optional frame)
 264   "True if face FACE has some non-nil attribute.
 265 If the optional argument FRAME is given, report on face FACE in that frame.
 266 If FRAME is t, report on the defaults for face FACE (for new frames).
 267 If FRAME is omitted or nil, use the selected frame."
 268   (not (internal-lisp-face-empty-p face frame)))
 269
 270
 271 \f
 272 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 273 ;;; Setting face attributes from X resources.
 274 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 275
 276 (defcustom face-x-resources
 277   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 278     (:width (".attributeWidth" . "Face.AttributeWidth"))
 279     (:height (".attributeHeight" . "Face.AttributeHeight"))
 280     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 281     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 282     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 283     (:background (".attributeBackground" . "Face.AttributeBackground"))
 284     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 285     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 286     (:box (".attributeBox" . "Face.AttributeBox"))
 287     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 288     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 289     (:stipple
 290      (".attributeStipple" . "Face.AttributeStipple")
 291      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 292     (:bold (".attributeBold" . "Face.AttributeBold"))
 293     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 294     (:font (".attributeFont" . "Face.AttributeFont"))
 295     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 296   "*List of X resources and classes for face attributes.
 297 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 298 the name of a face attribute, and each ENTRY is a cons of the form
 299 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 300 X resource class for the attribute."
 301   :type '(repeat (cons symbol (repeat (cons string string))))
 302   :group 'faces)
 303
 304
 305 (defun set-face-attribute-from-resource (face attribute resource class frame)
 306   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 307 Value is the attribute value specified by the resource, or nil
 308 if not present.  This function displays a message if the resource
 309 specifies an invalid attribute."
 310   (let* ((face-name (face-name face))
 311          (value (internal-face-x-get-resource (concat face-name resource)
 312                                               class frame)))
 313     (when value
 314       (condition-case ()
 315           (internal-set-lisp-face-attribute-from-resource
 316            face attribute (downcase value) frame)
 317         (error
 318          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 319                   face-name frame attribute value))))
 320     value))
 321
 322
 323 (defun set-face-attributes-from-resources (face frame)
 324   "Set attributes of FACE from X resources for FRAME."
 325   (when (memq (framep frame) '(x w32 mac))
 326     (dolist (definition face-x-resources)
 327       (let ((attribute (car definition)))
 328         (dolist (entry (cdr definition))
 329           (set-face-attribute-from-resource face attribute (car entry)
 330                                             (cdr entry) frame))))))
 331
 332
 333 (defun make-face-x-resource-internal (face &optional frame)
 334   "Fill frame-local FACE on FRAME from X resources.
 335 FRAME nil or not specified means do it for all frames."
 336   (if (null frame)
 337       (dolist (frame (frame-list))
 338         (set-face-attributes-from-resources face frame))
 339     (set-face-attributes-from-resources face frame)))
 340
 341
 342 \f
 343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 344 ;;; Retrieving face attributes.
 345 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 346
 347 (defun face-name (face)
 348   "Return the name of face FACE."
 349   (symbol-name (check-face face)))
 350
 351
 352 (defun face-attribute (face attribute &optional frame inherit)
 353   "Return the value of FACE's ATTRIBUTE on FRAME.
 354 If the optional argument FRAME is given, report on face FACE in that frame.
 355 If FRAME is t, report on the defaults for face FACE (for new frames).
 356 If FRAME is omitted or nil, use the selected frame.
 357
 358 If INHERIT is nil, only attributes directly defined by FACE are considered,
 359   so the return value may be `unspecified', or a relative value.
 360 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 361   faces specified by its `:inherit' attribute; however the return value
 362   may still be `unspecified' or relative.
 363 If INHERIT is a face or a list of faces, then the result is further merged
 364   with that face (or faces), until it becomes specified and absolute.
 365
 366 To ensure that the return value is always specified and absolute, use a
 367 value of `default' for INHERIT; this will resolve any unspecified or
 368 relative values by merging with the `default' face (which is always
 369 completely specified)."
 370   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 371     (when (and inherit (face-attribute-relative-p attribute value))
 372       ;; VALUE is relative, so merge with inherited faces
 373       (let ((inh-from (face-attribute face :inherit frame)))
 374         (unless (or (null inh-from) (eq inh-from 'unspecified))
 375           (setq value
 376                 (face-attribute-merged-with attribute value inh-from frame)))))
 377     (when (and inherit
 378                (not (eq inherit t))
 379                (face-attribute-relative-p attribute value))
 380       ;; We should merge with INHERIT as well
 381       (setq value (face-attribute-merged-with attribute value inherit frame)))
 382     value))
 383
 384 (defun face-attribute-merged-with (attribute value faces &optional frame)
 385   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 386 FACES may be either a single face or a list of faces.
 387 \[This is an internal function]"
 388   (cond ((not (face-attribute-relative-p attribute value))
 389          value)
 390         ((null faces)
 391          value)
 392         ((consp faces)
 393          (face-attribute-merged-with
 394           attribute
 395           (face-attribute-merged-with attribute value (car faces) frame)
 396           (cdr faces)
 397           frame))
 398         (t
 399          (merge-face-attribute attribute
 400                                value
 401                                (face-attribute faces attribute frame t)))))
 402
 403
 404 (defmacro face-attribute-specified-or (value &rest body)
 405   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 406   (let ((temp (make-symbol "value")))
 407     `(let ((,temp ,value))
 408        (if (not (eq ,temp 'unspecified))
 409            ,temp
 410          ,@body))))
 411
 412 (defun face-foreground (face &optional frame inherit)
 413   "Return the foreground color name of FACE, or nil if unspecified.
 414 If the optional argument FRAME is given, report on face FACE in that frame.
 415 If FRAME is t, report on the defaults for face FACE (for new frames).
 416 If FRAME is omitted or nil, use the selected frame.
 417
 418 If INHERIT is nil, only a foreground color directly defined by FACE is
 419   considered, so the return value may be nil.
 420 If INHERIT is t, and FACE doesn't define a foreground color, then any
 421   foreground color that FACE inherits through its `:inherit' attribute
 422   is considered as well; however the return value may still be nil.
 423 If INHERIT is a face or a list of faces, then it is used to try to
 424   resolve an unspecified foreground color.
 425
 426 To ensure that a valid color is always returned, use a value of
 427 `default' for INHERIT; this will resolve any unspecified values by
 428 merging with the `default' face (which is always completely specified)."
 429   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 430                                nil))
 431
 432 (defun face-background (face &optional frame inherit)
 433   "Return the background color name of FACE, or nil if unspecified.
 434 If the optional argument FRAME is given, report on face FACE in that frame.
 435 If FRAME is t, report on the defaults for face FACE (for new frames).
 436 If FRAME is omitted or nil, use the selected frame.
 437
 438 If INHERIT is nil, only a background color directly defined by FACE is
 439   considered, so the return value may be nil.
 440 If INHERIT is t, and FACE doesn't define a background color, then any
 441   background color that FACE inherits through its `:inherit' attribute
 442   is considered as well; however the return value may still be nil.
 443 If INHERIT is a face or a list of faces, then it is used to try to
 444   resolve an unspecified background color.
 445
 446 To ensure that a valid color is always returned, use a value of
 447 `default' for INHERIT; this will resolve any unspecified values by
 448 merging with the `default' face (which is always completely specified)."
 449   (face-attribute-specified-or (face-attribute face :background frame inherit)
 450                                nil))
 451
 452 (defun face-stipple (face &optional frame inherit)
 453  "Return the stipple pixmap name of FACE, or nil if unspecified.
 454 If the optional argument FRAME is given, report on face FACE in that frame.
 455 If FRAME is t, report on the defaults for face FACE (for new frames).
 456 If FRAME is omitted or nil, use the selected frame.
 457
 458 If INHERIT is nil, only a stipple directly defined by FACE is
 459   considered, so the return value may be nil.
 460 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 461   that FACE inherits through its `:inherit' attribute is considered as
 462   well; however the return value may still be nil.
 463 If INHERIT is a face or a list of faces, then it is used to try to
 464   resolve an unspecified stipple.
 465
 466 To ensure that a valid stipple or nil is always returned, use a value of
 467 `default' for INHERIT; this will resolve any unspecified values by merging
 468 with the `default' face (which is always completely specified)."
 469   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 470                                nil))
 471
 472
 473 (defalias 'face-background-pixmap 'face-stipple)
 474
 475
 476 (defun face-underline-p (face &optional frame)
 477  "Return non-nil if FACE is underlined.
 478 If the optional argument FRAME is given, report on face FACE in that frame.
 479 If FRAME is t, report on the defaults for face FACE (for new frames).
 480 If FRAME is omitted or nil, use the selected frame."
 481  (eq (face-attribute face :underline frame) t))
 482
 483
 484 (defun face-inverse-video-p (face &optional frame)
 485  "Return non-nil if FACE is in inverse video on FRAME.
 486 If the optional argument FRAME is given, report on face FACE in that frame.
 487 If FRAME is t, report on the defaults for face FACE (for new frames).
 488 If FRAME is omitted or nil, use the selected frame."
 489  (eq (face-attribute face :inverse-video frame) t))
 490
 491
 492 (defun face-bold-p (face &optional frame)
 493   "Return non-nil if the font of FACE is bold on FRAME.
 494 If the optional argument FRAME is given, report on face FACE in that frame.
 495 If FRAME is t, report on the defaults for face FACE (for new frames).
 496 If FRAME is omitted or nil, use the selected frame.
 497 Use `face-attribute' for finer control."
 498   (let ((bold (face-attribute face :weight frame)))
 499     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 500
 501
 502 (defun face-italic-p (face &optional frame)
 503   "Return non-nil if the font of FACE is italic on FRAME.
 504 If the optional argument FRAME is given, report on face FACE in that frame.
 505 If FRAME is t, report on the defaults for face FACE (for new frames).
 506 If FRAME is omitted or nil, use the selected frame.
 507 Use `face-attribute' for finer control."
 508   (let ((italic (face-attribute face :slant frame)))
 509     (memq italic '(italic oblique))))
 510
 511
 512 \f
 513 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 514 ;;; Face documentation.
 515 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 516
 517 (defun face-documentation (face)
 518   "Get the documentation string for FACE."
 519   (get face 'face-documentation))
 520
 521
 522 (defun set-face-documentation (face string)
 523   "Set the documentation string for FACE to STRING."
 524   ;; Perhaps the text should go in DOC.
 525   (put face 'face-documentation (purecopy string)))
 526
 527
 528 (defalias 'face-doc-string 'face-documentation)
 529 (defalias 'set-face-doc-string 'set-face-documentation)
 530
 531
 532 \f
 533 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 534 ;; Setting face attributes.
 535 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 536
 537
 538 (defun set-face-attribute (face frame &rest args)
 539   "Set attributes of FACE on FRAME from ARGS.
 540
 541 FRAME nil means change attributes on all frames.  FRAME t means change
 542 the default for new frames (this is done automatically each time an
 543 attribute is changed on all frames).
 544
 545 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 546 face attribute name.  All attributes can be set to `unspecified';
 547 this fact is not further mentioned below.
 548
 549 The following attributes are recognized:
 550
 551 `:family'
 552
 553 VALUE must be a string specifying the font family, e.g. ``courier'',
 554 or a fontset alias name.  If a font family is specified, wild-cards `*'
 555 and `?' are allowed.
 556
 557 `:width'
 558
 559 VALUE specifies the relative proportionate width of the font to use.
 560 It must be one of the symbols `ultra-condensed', `extra-condensed',
 561 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 562 `extra-expanded', or `ultra-expanded'.
 563
 564 `:height'
 565
 566 VALUE must be either an integer specifying the height of the font to use
 567 in 1/10 pt, a floating point number specifying the amount by which to
 568 scale any underlying face, or a function, which is called with the old
 569 height (from the underlying face), and should return the new height.
 570
 571 `:weight'
 572
 573 VALUE specifies the weight of the font to use.  It must be one of the
 574 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 575 `semi-light', `light', `extra-light', `ultra-light'.
 576
 577 `:slant'
 578
 579 VALUE specifies the slant of the font to use.  It must be one of the
 580 symbols `italic', `oblique', `normal', `reverse-italic', or
 581 `reverse-oblique'.
 582
 583 `:foreground', `:background'
 584
 585 VALUE must be a color name, a string.
 586
 587 `:underline'
 588
 589 VALUE specifies whether characters in FACE should be underlined.  If
 590 VALUE is t, underline with foreground color of the face.  If VALUE is
 591 a string, underline with that color.  If VALUE is nil, explicitly
 592 don't underline.
 593
 594 `:overline'
 595
 596 VALUE specifies whether characters in FACE should be overlined.  If
 597 VALUE is t, overline with foreground color of the face.  If VALUE is a
 598 string, overline with that color.  If VALUE is nil, explicitly don't
 599 overline.
 600
 601 `:strike-through'
 602
 603 VALUE specifies whether characters in FACE should be drawn with a line
 604 striking through them.  If VALUE is t, use the foreground color of the
 605 face.  If VALUE is a string, strike-through with that color.  If VALUE
 606 is nil, explicitly don't strike through.
 607
 608 `:box'
 609
 610 VALUE specifies whether characters in FACE should have a box drawn
 611 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 612 VALUE is t, draw a box with lines of width 1 in the foreground color
 613 of the face.  If VALUE is a string, the string must be a color name,
 614 and the box is drawn in that color with a line width of 1.  Otherwise,
 615 VALUE must be a property list of the form `(:line-width WIDTH
 616 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 617 the property list, a default value will be used for the value, as
 618 specified below.  WIDTH specifies the width of the lines to draw; it
 619 defaults to 1.  If WIDTH is negative, the absolute value is the width
 620 of the lines, and draw top/bottom lines inside the characters area,
 621 not around it.  COLOR is the name of the color to draw in, default is
 622 the foreground color of the face for simple boxes, and the background
 623 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 624 should be draw.  If STYLE is `released-button', draw a box looking
 625 like a released 3D button.  If STYLE is `pressed-button' draw a box
 626 that appears like a pressed button.  If STYLE is nil, the default if
 627 the property list doesn't contain a style specification, draw a 2D
 628 box.
 629
 630 `:inverse-video'
 631
 632 VALUE specifies whether characters in FACE should be displayed in
 633 inverse video.  VALUE must be one of t or nil.
 634
 635 `:stipple'
 636
 637 If VALUE is a string, it must be the name of a file of pixmap data.
 638 The directories listed in the `x-bitmap-file-path' variable are
 639 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 640 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 641 is a string containing the raw bits of the bitmap.  VALUE nil means
 642 explicitly don't use a stipple pattern.
 643
 644 For convenience, attributes `:family', `:width', `:height', `:weight',
 645 and `:slant' may also be set in one step from an X font name:
 646
 647 `:font'
 648
 649 Set font-related face attributes from VALUE.  VALUE must be a valid
 650 XLFD font name.  If it is a font name pattern, the first matching font
 651 will be used.
 652
 653 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 654 be used to specify that a bold or italic font should be used.  VALUE
 655 must be t or nil in that case.  A value of `unspecified' is not allowed.
 656
 657 `:inherit'
 658
 659 VALUE is the name of a face from which to inherit attributes, or a list
 660 of face names.  Attributes from inherited faces are merged into the face
 661 like an underlying face would be, with higher priority than underlying faces."
 662   (let ((where (if (null frame) 0 frame)))
 663     (setq args (purecopy args))
 664     ;; If we set the new-frame defaults, this face is modified outside Custom.
 665     (if (memq where '(0 t))
 666         (put face 'face-modified t))
 667     (while args
 668       (internal-set-lisp-face-attribute face (car args)
 669                                         (purecopy (cadr args))
 670                                         where)
 671       (setq args (cdr (cdr args))))))
 672
 673
 674 (defun make-face-bold (face &optional frame noerror)
 675   "Make the font of FACE be bold, if possible.
 676 FRAME nil or not specified means change face on all frames.
 677 Argument NOERROR is ignored and retained for compatibility.
 678 Use `set-face-attribute' for finer control of the font weight."
 679   (interactive (list (read-face-name "Make which face bold")))
 680   (set-face-attribute face frame :weight 'bold))
 681
 682
 683 (defun make-face-unbold (face &optional frame noerror)
 684   "Make the font of FACE be non-bold, if possible.
 685 FRAME nil or not specified means change face on all frames.
 686 Argument NOERROR is ignored and retained for compatibility."
 687   (interactive (list (read-face-name "Make which face non-bold")))
 688   (set-face-attribute face frame :weight 'normal))
 689
 690
 691 (defun make-face-italic (face &optional frame noerror)
 692   "Make the font of FACE be italic, if possible.
 693 FRAME nil or not specified means change face on all frames.
 694 Argument NOERROR is ignored and retained for compatibility.
 695 Use `set-face-attribute' for finer control of the font slant."
 696   (interactive (list (read-face-name "Make which face italic")))
 697   (set-face-attribute face frame :slant 'italic))
 698
 699
 700 (defun make-face-unitalic (face &optional frame noerror)
 701   "Make the font of FACE be non-italic, if possible.
 702 FRAME nil or not specified means change face on all frames.
 703 Argument NOERROR is ignored and retained for compatibility."
 704   (interactive (list (read-face-name "Make which face non-italic")))
 705   (set-face-attribute face frame :slant 'normal))
 706
 707
 708 (defun make-face-bold-italic (face &optional frame noerror)
 709   "Make the font of FACE be bold and italic, if possible.
 710 FRAME nil or not specified means change face on all frames.
 711 Argument NOERROR is ignored and retained for compatibility.
 712 Use `set-face-attribute' for finer control of font weight and slant."
 713   (interactive (list (read-face-name "Make which face bold-italic")))
 714   (set-face-attribute face frame :weight 'bold :slant 'italic))
 715
 716
 717 (defun set-face-font (face font &optional frame)
 718   "Change font-related attributes of FACE to those of FONT (a string).
 719 FRAME nil or not specified means change face on all frames.
 720 This sets the attributes `:family', `:width', `:height', `:weight',
 721 and `:slant'.  When called interactively, prompt for the face and font."
 722   (interactive (read-face-and-attribute :font))
 723   (set-face-attribute face frame :font font))
 724
 725
 726 ;; Implementation note: Emulating gray background colors with a
 727 ;; stipple pattern is now part of the face realization process, and is
 728 ;; done in C depending on the frame on which the face is realized.
 729
 730 (defun set-face-background (face color &optional frame)
 731   "Change the background color of face FACE to COLOR (a string).
 732 FRAME nil or not specified means change face on all frames.
 733 When called interactively, prompt for the face and color."
 734   (interactive (read-face-and-attribute :background))
 735   (set-face-attribute face frame :background (or color 'unspecified)))
 736
 737
 738 (defun set-face-foreground (face color &optional frame)
 739   "Change the foreground color of face FACE to COLOR (a string).
 740 FRAME nil or not specified means change face on all frames.
 741 When called interactively, prompt for the face and color."
 742   (interactive (read-face-and-attribute :foreground))
 743   (set-face-attribute face frame :foreground (or color 'unspecified)))
 744
 745
 746 (defun set-face-stipple (face stipple &optional frame)
 747   "Change the stipple pixmap of face FACE to STIPPLE.
 748 FRAME nil or not specified means change face on all frames.
 749 STIPPLE should be a string, the name of a file of pixmap data.
 750 The directories listed in the `x-bitmap-file-path' variable are searched.
 751
 752 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 753 where WIDTH and HEIGHT are the size in pixels,
 754 and DATA is a string, containing the raw bits of the bitmap."
 755   (interactive (read-face-and-attribute :stipple))
 756   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 757
 758
 759 (defun set-face-underline (face underline &optional frame)
 760   "Specify whether face FACE is underlined.
 761 UNDERLINE nil means FACE explicitly doesn't underline.
 762 UNDERLINE non-nil means FACE explicitly does underlining
 763 with the same of the foreground color.
 764 If UNDERLINE is a string, underline with the color named UNDERLINE.
 765 FRAME nil or not specified means change face on all frames.
 766 Use `set-face-attribute' to ``unspecify'' underlining."
 767   (interactive
 768    (let ((list (read-face-and-attribute :underline)))
 769      (list (car list) (eq (car (cdr list)) t))))
 770   (set-face-attribute face frame :underline underline))
 771
 772
 773 (defun set-face-underline-p (face underline-p &optional frame)
 774   "Specify whether face FACE is underlined.
 775 UNDERLINE-P nil means FACE explicitly doesn't underline.
 776 UNDERLINE-P non-nil means FACE explicitly does underlining.
 777 FRAME nil or not specified means change face on all frames.
 778 Use `set-face-attribute' to ``unspecify'' underlining."
 779   (interactive
 780    (let ((list (read-face-and-attribute :underline)))
 781      (list (car list) (eq (car (cdr list)) t))))
 782   (set-face-attribute face frame :underline underline-p))
 783
 784
 785 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 786   "Specify whether face FACE is in inverse video.
 787 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 788 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 789 FRAME nil or not specified means change face on all frames.
 790 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 791   (interactive
 792    (let ((list (read-face-and-attribute :inverse-video)))
 793      (list (car list) (eq (car (cdr list)) t))))
 794   (set-face-attribute face frame :inverse-video inverse-video-p))
 795
 796
 797 (defun set-face-bold-p (face bold-p &optional frame)
 798   "Specify whether face FACE is bold.
 799 BOLD-P non-nil means FACE should explicitly display bold.
 800 BOLD-P nil means FACE should explicitly display non-bold.
 801 FRAME nil or not specified means change face on all frames.
 802 Use `set-face-attribute' or `modify-face' for finer control."
 803   (if (null bold-p)
 804       (make-face-unbold face frame)
 805     (make-face-bold face frame)))
 806
 807
 808 (defun set-face-italic-p (face italic-p &optional frame)
 809   "Specify whether face FACE is italic.
 810 ITALIC-P non-nil means FACE should explicitly display italic.
 811 ITALIC-P nil means FACE should explicitly display non-italic.
 812 FRAME nil or not specified means change face on all frames.
 813 Use `set-face-attribute' or `modify-face' for finer control."
 814   (if (null italic-p)
 815       (make-face-unitalic face frame)
 816     (make-face-italic face frame)))
 817
 818
 819 (defalias 'set-face-background-pixmap 'set-face-stipple)
 820
 821
 822 (defun invert-face (face &optional frame)
 823   "Swap the foreground and background colors of FACE.
 824 If FRAME is omitted or nil, it means change face on all frames.
 825 If FACE specifies neither foreground nor background color,
 826 set its foreground and background to the background and foreground
 827 of the default face.  Value is FACE."
 828   (interactive (list (read-face-name "Invert face")))
 829   (let ((fg (face-attribute face :foreground frame))
 830         (bg (face-attribute face :background frame)))
 831     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 832         (set-face-attribute face frame :foreground bg :background fg)
 833       (set-face-attribute face frame
 834                           :foreground
 835                           (face-attribute 'default :background frame)
 836                           :background
 837                           (face-attribute 'default :foreground frame))))
 838   face)
 839
 840 \f
 841 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 842 ;;; Interactively modifying faces.
 843 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 844
 845 (defun read-face-name (prompt &optional string-describing-default multiple)
 846   "Read a face, defaulting to the face or faces on the char after point.
 847 If it has a `read-face-name' property, that overrides the `face' property.
 848 PROMPT describes what you will do with the face (don't end in a space).
 849 STRING-DESCRIBING-DEFAULT describes what default you will use
 850 if this function returns nil.
 851 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 852 Otherwise, return a single face."
 853   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 854                       (get-char-property (point) 'face)))
 855         faces)
 856     ;; Make a list of the named faces that the `face' property uses.
 857     (if (listp faceprop)
 858         (dolist (f faceprop)
 859           (if (symbolp f)
 860               (push f faces)))
 861       (if (symbolp faceprop)
 862           (setq faces (list faceprop))))
 863     ;; If there are none, try to get a face name from the buffer.
 864     (if (and (null faces)
 865              (memq (intern-soft (thing-at-point 'symbol)) (face-list)))
 866         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 867
 868     ;; If we only want one, and the default is more than one,
 869     ;; discard the unwanted ones now.
 870     (unless multiple
 871       (if faces
 872           (setq faces (list (car faces)))))
 873     (let* ((input
 874             ;; Read the input.
 875             (completing-read
 876              (if (or faces string-describing-default)
 877                  (format "%s (default %s): " prompt
 878                          (if faces (mapconcat 'symbol-name faces ", ")
 879                            string-describing-default))
 880                (format "%s: " prompt))
 881              obarray 'custom-facep t))
 882            ;; Canonicalize the output.
 883            (output
 884             (if (equal input "")
 885                 faces
 886               (if (stringp input)
 887                   (list (intern input))
 888                 input))))
 889       ;; Return either a list of faces or just one face.
 890       (if multiple
 891           output
 892         (car output)))))
 893
 894
 895 (defun face-valid-attribute-values (attribute &optional frame)
 896   "Return valid values for face attribute ATTRIBUTE.
 897 The optional argument FRAME is used to determine available fonts
 898 and colors.  If it is nil or not specified, the selected frame is
 899 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 900 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 901 an integer value."
 902   (let ((valid
 903          (case attribute
 904            (:family
 905             (if window-system
 906                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 907                         (x-font-family-list))
 908               ;; Only one font on TTYs.
 909               (list (cons "default" "default"))))
 910            ((:width :weight :slant :inverse-video)
 911             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 912                     (internal-lisp-face-attribute-values attribute)))
 913            ((:underline :overline :strike-through :box)
 914             (if window-system
 915                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 916                                (internal-lisp-face-attribute-values attribute))
 917                        (mapcar #'(lambda (c) (cons c c))
 918                                (x-defined-colors frame)))
 919               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 920                       (internal-lisp-face-attribute-values attribute))))
 921            ((:foreground :background)
 922             (mapcar #'(lambda (c) (cons c c))
 923                     (defined-colors frame)))
 924            ((:height)
 925             'integerp)
 926            (:stipple
 927             (and (memq window-system '(x w32 mac))
 928                  (mapcar #'list
 929                          (apply #'nconc
 930                                 (mapcar (lambda (dir)
 931                                           (and (file-readable-p dir)
 932                                                (file-directory-p dir)
 933                                                (directory-files dir)))
 934                                         x-bitmap-file-path)))))
 935            (:inherit
 936             (cons '("none" . nil)
 937                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 938                           (face-list))))
 939            (t
 940             (error "Internal error")))))
 941     (if (and (listp valid) (not (memq attribute '(:inherit))))
 942         (nconc (list (cons "unspecified" 'unspecified)) valid)
 943       valid)))
 944
 945
 946 (defvar face-attribute-name-alist
 947   '((:family . "font family")
 948     (:width . "character set width")
 949     (:height . "height in 1/10 pt")
 950     (:weight . "weight")
 951     (:slant . "slant")
 952     (:underline . "underline")
 953     (:overline . "overline")
 954     (:strike-through . "strike-through")
 955     (:box . "box")
 956     (:inverse-video . "inverse-video display")
 957     (:foreground . "foreground color")
 958     (:background . "background color")
 959     (:stipple . "background stipple")
 960     (:inherit . "inheritance"))
 961   "An alist of descriptive names for face attributes.
 962 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 963 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 964 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 965
 966
 967 (defun face-descriptive-attribute-name (attribute)
 968   "Return a descriptive name for ATTRIBUTE."
 969   (cdr (assq attribute face-attribute-name-alist)))
 970
 971
 972 (defun face-read-string (face default name &optional completion-alist)
 973   "Interactively read a face attribute string value.
 974 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 975 default string to return if no new value is entered.  NAME is a
 976 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 977 alist of valid values, if non-nil.
 978
 979 Entering nothing accepts the default string DEFAULT.
 980 Value is the new attribute value."
 981   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 982   ;; each word in a string separately).
 983   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 984   (let* ((completion-ignore-case t)
 985          (value (completing-read
 986                  (if default
 987                      (format "%s for face `%s' (default %s): "
 988                              name face default)
 989                    (format "%s for face `%s': " name face))
 990                  completion-alist)))
 991     (if (equal value "") default value)))
 992
 993
 994 (defun face-read-integer (face default name)
 995   "Interactively read an integer face attribute value.
 996 FACE is the face whose attribute is read.  DEFAULT is the default
 997 value to return if no new value is entered.  NAME is a descriptive
 998 name of the attribute for prompting.  Value is the new attribute value."
 999   (let ((new-value
1000          (face-read-string face
1001                            (format "%s" default)
1002                            name
1003                            (list (cons "unspecified" 'unspecified)))))
1004     (cond ((equal new-value "unspecified")
1005            'unspecified)
1006           ((member new-value '("unspecified-fg" "unspecified-bg"))
1007            new-value)
1008           (t
1009            (string-to-int new-value)))))
1010
1011
1012 (defun read-face-attribute (face attribute &optional frame)
1013   "Interactively read a new value for FACE's ATTRIBUTE.
1014 Optional argument FRAME nil or unspecified means read an attribute value
1015 of a global face.  Value is the new attribute value."
1016   (let* ((old-value (face-attribute face attribute frame))
1017          (attribute-name (face-descriptive-attribute-name attribute))
1018          (valid (face-valid-attribute-values attribute frame))
1019          new-value)
1020     ;; Represent complex attribute values as strings by printing them
1021     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1022     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1023     ;; SHADOW)'.
1024     (when (and (or (eq attribute :stipple)
1025                    (eq attribute :box))
1026                (or (consp old-value)
1027                    (vectorp old-value)))
1028       (setq old-value (prin1-to-string old-value)))
1029     (cond ((listp valid)
1030            (let ((default
1031                    (or (car (rassoc old-value valid))
1032                        (format "%s" old-value))))
1033              (setq new-value
1034                    (face-read-string face default attribute-name valid))
1035              (if (equal new-value default)
1036                  ;; Nothing changed, so don't bother with all the stuff
1037                  ;; below.  In particular, this avoids a non-tty color
1038                  ;; from being canonicalized for a tty when the user
1039                  ;; just uses the default.
1040                  (setq new-value old-value)
1041                ;; Terminal frames can support colors that don't appear
1042                ;; explicitly in VALID, using color approximation code
1043                ;; in tty-colors.el.
1044                (when (and (memq attribute '(:foreground :background))
1045                           (not (memq window-system '(x w32 mac)))
1046                           (not (member new-value
1047                                        '("unspecified"
1048                                          "unspecified-fg" "unspecified-bg"))))
1049                  (setq new-value (car (tty-color-desc new-value frame))))
1050                (when (assoc new-value valid)
1051                  (setq new-value (cdr (assoc new-value valid)))))))
1052           ((eq valid 'integerp)
1053            (setq new-value (face-read-integer face old-value attribute-name)))
1054           (t (error "Internal error")))
1055     ;; Convert stipple and box value text we read back to a list or
1056     ;; vector if it looks like one.  This makes the assumption that a
1057     ;; pixmap file name won't start with an open-paren.
1058     (when (and (or (eq attribute :stipple)
1059                    (eq attribute :box))
1060                (stringp new-value)
1061                (string-match "^[[(]" new-value))
1062       (setq new-value (read new-value)))
1063     new-value))
1064
1065
1066 (defun read-face-font (face &optional frame)
1067   "Read the name of a font for FACE on FRAME.
1068 If optional argument FRAME Is nil or omitted, use the selected frame."
1069   (let ((completion-ignore-case t))
1070     (completing-read (format "Set font attributes of face `%s' from font: " face)
1071                      (x-list-fonts "*" nil frame))))
1072
1073
1074 (defun read-all-face-attributes (face &optional frame)
1075   "Interactively read all attributes for FACE.
1076 If optional argument FRAME Is nil or omitted, use the selected frame.
1077 Value is a property list of attribute names and new values."
1078   (let (result)
1079     (dolist (attribute face-attribute-name-alist result)
1080       (setq result (cons (car attribute)
1081                          (cons (read-face-attribute face (car attribute) frame)
1082                                result))))))
1083
1084 (defun modify-face (&optional face foreground background stipple
1085                               bold-p italic-p underline-p inverse-p frame)
1086   "Modify attributes of faces interactively.
1087 If optional argument FRAME is nil or omitted, modify the face used
1088 for newly created frame, i.e. the global face.
1089 For non-interactive use, `set-face-attribute' is preferred.
1090 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
1091 and the face and its settings are obtained by querying the user."
1092   (interactive)
1093   (if face
1094       (set-face-attribute face frame
1095                           :foreground (or foreground 'unspecified)
1096                           :background (or background 'unspecified)
1097                           :stipple stipple
1098                           :bold bold-p
1099                           :italic italic-p
1100                           :underline underline-p
1101                           :inverse-video inverse-p)
1102     (setq face (read-face-name "Modify face"))
1103     (apply #'set-face-attribute face frame
1104            (read-all-face-attributes face frame))))
1105
1106 (defun read-face-and-attribute (attribute &optional frame)
1107   "Read face name and face attribute value.
1108 ATTRIBUTE is the attribute whose new value is read.
1109 FRAME nil or unspecified means read attribute value of global face.
1110 Value is a list (FACE NEW-VALUE) where FACE is the face read
1111 \(a symbol), and NEW-VALUE is value read."
1112   (cond ((eq attribute :font)
1113          (let* ((prompt "Set font-related attributes of face")
1114                 (face (read-face-name prompt))
1115                 (font (read-face-font face frame)))
1116            (list face font)))
1117         (t
1118          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1119                 (prompt (format "Set %s of face" attribute-name))
1120                 (face (read-face-name prompt))
1121                 (new-value (read-face-attribute face attribute frame)))
1122            (list face new-value)))))
1123
1124
1125 \f
1126 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1127 ;;; Listing faces.
1128 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1129
1130 (defvar list-faces-sample-text
1131   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1132   "*Text string to display as the sample text for `list-faces-display'.")
1133
1134
1135 ;; The name list-faces would be more consistent, but let's avoid a
1136 ;; conflict with Lucid, which uses that name differently.
1137
1138 (defvar help-xref-stack)
1139 (defun list-faces-display ()
1140   "List all faces, using the same sample text in each.
1141 The sample text is a string that comes from the variable
1142 `list-faces-sample-text'."
1143   (interactive)
1144   (let ((faces (sort (face-list) #'string-lessp))
1145         (face nil)
1146         (frame (selected-frame))
1147         disp-frame window face-name)
1148     (with-output-to-temp-buffer "*Faces*"
1149       (save-excursion
1150         (set-buffer standard-output)
1151         (setq truncate-lines t)
1152         (insert
1153          (substitute-command-keys
1154           (concat
1155            "Use "
1156            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1157            "\\[help-follow] on a face name to customize it\n"
1158            "or on its sample text for a description of the face.\n\n")))
1159         (setq help-xref-stack nil)
1160         (while faces
1161           (setq face (car faces))
1162           (setq faces (cdr faces))
1163           (setq face-name (symbol-name face))
1164           (insert (format "%25s " face-name))
1165           ;; Hyperlink to a customization buffer for the face.  Using
1166           ;; the help xref mechanism may not be the best way.
1167           (save-excursion
1168             (save-match-data
1169               (search-backward face-name)
1170               (help-xref-button 0 'help-customize-face face)))
1171           (let ((beg (point))
1172                 (line-beg (line-beginning-position)))
1173             (insert list-faces-sample-text)
1174             ;; Hyperlink to a help buffer for the face.
1175             (save-excursion
1176               (save-match-data
1177                 (search-backward list-faces-sample-text)
1178                 (help-xref-button 0 'help-face face)))
1179             (insert "\n")
1180             (put-text-property beg (1- (point)) 'face face)
1181             ;; Make all face commands default to the proper face
1182             ;; anywhere in the line.
1183             (put-text-property line-beg (1- (point)) 'read-face-name face)
1184             ;; If the sample text has multiple lines, line up all of them.
1185             (goto-char beg)
1186             (forward-line 1)
1187             (while (not (eobp))
1188               (insert "                          ")
1189               (forward-line 1))))
1190         (goto-char (point-min)))
1191       (print-help-return-message))
1192     ;; If the *Faces* buffer appears in a different frame,
1193     ;; copy all the face definitions from FRAME,
1194     ;; so that the display will reflect the frame that was selected.
1195     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1196     (setq disp-frame (if window (window-frame window)
1197                        (car (frame-list))))
1198     (or (eq frame disp-frame)
1199         (let ((faces (face-list)))
1200           (while faces
1201             (copy-face (car faces) (car faces) frame disp-frame)
1202             (setq faces (cdr faces)))))))
1203
1204 (defun describe-face (face &optional frame)
1205   "Display the properties of face FACE on FRAME.
1206 Interactively, FACE defaults to the faces of the character after point
1207 and FRAME defaults to the selected frame.
1208
1209 If the optional argument FRAME is given, report on face FACE in that frame.
1210 If FRAME is t, report on the defaults for face FACE (for new frames).
1211 If FRAME is omitted or nil, use the selected frame."
1212   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1213   (let* ((attrs '((:family . "Family")
1214                   (:width . "Width")
1215                   (:height . "Height")
1216                   (:weight . "Weight")
1217                   (:slant . "Slant")
1218                   (:foreground . "Foreground")
1219                   (:background . "Background")
1220                   (:underline . "Underline")
1221                   (:overline . "Overline")
1222                   (:strike-through . "Strike-through")
1223                   (:box . "Box")
1224                   (:inverse-video . "Inverse")
1225                   (:stipple . "Stipple")
1226                   (:font . "Font or fontset")
1227                   (:inherit . "Inherit")))
1228         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1229                                         attrs))))
1230     (help-setup-xref (list #'describe-face face) (interactive-p))
1231     (unless face
1232       (setq face 'default))
1233     (if (not (listp face))
1234         (setq face (list face)))
1235     (with-output-to-temp-buffer (help-buffer)
1236       (save-excursion
1237         (set-buffer standard-output)
1238         (dolist (f face)
1239           (insert "Face: " (symbol-name f))
1240           (if (not (facep f))
1241               (insert "   undefined face.\n")
1242             (let ((customize-label "customize this face"))
1243               (princ (concat " (" customize-label ")\n"))
1244               (insert "Documentation: "
1245                       (or (face-documentation f)
1246                           "Not documented as a face.")
1247                       "\n\n")
1248               (with-current-buffer standard-output
1249                 (save-excursion
1250                   (re-search-backward
1251                    (concat "\\(" customize-label "\\)") nil t)
1252                   (help-xref-button 1 'help-customize-face f)))
1253               (dolist (a attrs)
1254                 (let ((attr (face-attribute f (car a) frame)))
1255                   (insert (make-string (- max-width (length (cdr a))) ?\ )
1256                           (cdr a) ": " (format "%s" attr) "\n")))))
1257           (terpri)))
1258       (print-help-return-message))))
1259
1260 \f
1261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1262 ;;; Face specifications (defface).
1263 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1264
1265 ;; Parameter FRAME Is kept for call compatibility to with previous
1266 ;; face implementation.
1267
1268 (defun face-attr-construct (face &optional frame)
1269   "Return a defface-style attribute list for FACE on FRAME.
1270 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1271 face attributes of FACE where ATTRIBUTE is the attribute name and
1272 VALUE is the specified value of that attribute."
1273   (let (result)
1274     (dolist (entry face-attribute-name-alist result)
1275       (let* ((attribute (car entry))
1276              (value (face-attribute face attribute)))
1277         (unless (eq value 'unspecified)
1278           (setq result (nconc (list attribute value) result)))))))
1279
1280
1281 (defun face-spec-set-match-display (display frame)
1282   "Non-nil if DISPLAY matches FRAME.
1283 DISPLAY is part of a spec such as can be used in `defface'.
1284 If FRAME is nil, the current FRAME is used."
1285   (let* ((conjuncts display)
1286          conjunct req options
1287          ;; t means we have succeeded against all the conjuncts in
1288          ;; DISPLAY that have been tested so far.
1289          (match t))
1290     (if (eq conjuncts t)
1291         (setq conjuncts nil))
1292     (while (and conjuncts match)
1293       (setq conjunct (car conjuncts)
1294             conjuncts (cdr conjuncts)
1295             req (car conjunct)
1296             options (cdr conjunct)
1297             match (cond ((eq req 'type)
1298                          (or (memq window-system options)
1299                              ;; FIXME: This should be revisited to use
1300                              ;; display-graphic-p, provided that the
1301                              ;; color selection depends on the number
1302                              ;; of supported colors, and all defface's
1303                              ;; are changed to look at number of colors
1304                              ;; instead of (type graphic) etc.
1305                              (and (null window-system)
1306                                   (memq 'tty options))
1307                              (and (memq 'motif options)
1308                                   (featurep 'motif))
1309                              (and (memq 'gtk options)
1310                                   (featurep 'gtk))
1311                              (and (memq 'lucid options)
1312                                   (featurep 'x-toolkit)
1313                                   (not (featurep 'motif))
1314                                   (not (featurep 'gtk)))
1315                              (and (memq 'x-toolkit options)
1316                                   (featurep 'x-toolkit))))
1317                         ((eq req 'min-colors)
1318                          (>= (display-color-cells frame) (car options)))
1319                         ((eq req 'class)
1320                          (memq (frame-parameter frame 'display-type) options))
1321                         ((eq req 'background)
1322                          (memq (frame-parameter frame 'background-mode)
1323                                options))
1324                         ((eq req 'supports)
1325                          (display-supports-face-attributes-p options frame))
1326                         (t (error "Unknown req `%S' with options `%S'"
1327                                   req options)))))
1328     match))
1329
1330
1331 (defun face-spec-choose (spec &optional frame)
1332   "Choose the proper attributes for FRAME, out of SPEC.
1333 If SPEC is nil, return nil."
1334   (unless frame
1335     (setq frame (selected-frame)))
1336   (let ((tail spec)
1337         result all)
1338     (while tail
1339       (let* ((entry (pop tail))
1340              (display (car entry))
1341              (attrs (cdr entry)))
1342         (when (face-spec-set-match-display display frame)
1343           (setq result (if (null (cdr attrs)) ;; was (listp (car attrs))
1344                            ;; Old-style entry, the attribute list is the
1345                            ;; first element.
1346                            (car attrs)
1347                          attrs))
1348           (if (eq display t)
1349               (setq all result result nil)
1350             (setq tail nil)))))
1351     (if all (append result all) result)))
1352
1353
1354 (defun face-spec-reset-face (face &optional frame)
1355   "Reset all attributes of FACE on FRAME to unspecified."
1356   (let ((attrs face-attribute-name-alist))
1357     (while attrs
1358       (let ((attr-and-name (car attrs)))
1359         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1360       (setq attrs (cdr attrs)))))
1361
1362
1363 (defun face-spec-set (face spec &optional frame)
1364   "Set FACE's attributes according to the first matching entry in SPEC.
1365 FRAME is the frame whose frame-local face is set.  FRAME nil means
1366 do it on all frames.  See `defface' for information about SPEC.
1367 If SPEC is nil, do nothing."
1368   (let ((attrs (face-spec-choose spec frame)))
1369     (when attrs
1370       (face-spec-reset-face face frame))
1371     (while attrs
1372       (let ((attribute (car attrs))
1373             (value (car (cdr attrs))))
1374         ;; Support some old-style attribute names and values.
1375         (case attribute
1376           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1377           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1378           ((:foreground :background)
1379            ;; Compatibility with 20.x.  Some bogus face specs seem to
1380            ;; exist containing things like `:foreground nil'.
1381            (if (null value) (setq value 'unspecified)))
1382           (t (unless (assq attribute face-x-resources)
1383                (setq attribute nil))))
1384         (when attribute
1385           (set-face-attribute face frame attribute value)))
1386       (setq attrs (cdr (cdr attrs)))))
1387   ;; When we reset the face based on its spec, then it is unmodified
1388   ;; as far as Custom is concerned.
1389   (if (null frame)
1390       (put face 'face-modified nil)))
1391
1392
1393 (defun face-attr-match-p (face attrs &optional frame)
1394   "Return t if attributes of FACE match values in plist ATTRS.
1395 Optional parameter FRAME is the frame whose definition of FACE
1396 is used.  If nil or omitted, use the selected frame."
1397   (unless frame
1398     (setq frame (selected-frame)))
1399   (let ((list face-attribute-name-alist)
1400         (match t))
1401     (while (and match (not (null list)))
1402       (let* ((attr (car (car list)))
1403              (specified-value
1404               (if (plist-member attrs attr)
1405                   (plist-get attrs attr)
1406                 'unspecified))
1407              (value-now (face-attribute face attr frame)))
1408         (setq match (equal specified-value value-now))
1409         (setq list (cdr list))))
1410     match))
1411
1412 (defun face-spec-match-p (face spec &optional frame)
1413   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1414   (face-attr-match-p face (face-spec-choose spec frame) frame))
1415
1416 (defsubst face-default-spec (face)
1417   "Return the default face-spec for FACE, ignoring any user customization.
1418 If there is no default for FACE, return nil."
1419   (get face 'face-defface-spec))
1420
1421 (defsubst face-user-default-spec (face)
1422   "Return the user's customized face-spec for FACE, or the default if none.
1423 If there is neither a user setting nor a default for FACE, return nil."
1424   (or (get face 'saved-face)
1425       (face-default-spec face)))
1426
1427 \f
1428 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1429 ;;; Frame-type independent color support.
1430 ;;; We keep the old x-* names as aliases for back-compatibility.
1431 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1432
1433 (defun defined-colors (&optional frame)
1434   "Return a list of colors supported for a particular frame.
1435 The argument FRAME specifies which frame to try.
1436 The value may be different for frames on different display types.
1437 If FRAME doesn't support colors, the value is nil."
1438   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1439       (xw-defined-colors frame)
1440     (mapcar 'car (tty-color-alist frame))))
1441 (defalias 'x-defined-colors 'defined-colors)
1442
1443 (defun color-defined-p (color &optional frame)
1444   "Return non-nil if color COLOR is supported on frame FRAME.
1445 If FRAME is omitted or nil, use the selected frame.
1446 If COLOR is the symbol `unspecified' or one of the strings
1447 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1448   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1449       nil
1450     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1451         (xw-color-defined-p color frame)
1452       (numberp (tty-color-translate color frame)))))
1453 (defalias 'x-color-defined-p 'color-defined-p)
1454
1455 (defun color-values (color &optional frame)
1456   "Return a description of the color named COLOR on frame FRAME.
1457 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1458 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1459 If FRAME is omitted or nil, use the selected frame.
1460 If FRAME cannot display COLOR, the value is nil.
1461 If COLOR is the symbol `unspecified' or one of the strings
1462 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1463   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1464       nil
1465     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1466         (xw-color-values color frame)
1467       (tty-color-values color frame))))
1468 (defalias 'x-color-values 'color-values)
1469
1470 (defun display-color-p (&optional display)
1471   "Return t if DISPLAY supports color.
1472 The optional argument DISPLAY specifies which display to ask about.
1473 DISPLAY should be either a frame or a display name (a string).
1474 If omitted or nil, that stands for the selected frame's display."
1475   (if (memq (framep-on-display display) '(x w32 mac))
1476       (xw-display-color-p display)
1477     (tty-display-color-p display)))
1478 (defalias 'x-display-color-p 'display-color-p)
1479
1480 (defun display-grayscale-p (&optional display)
1481   "Return non-nil if frames on DISPLAY can display shades of gray."
1482   (let ((frame-type (framep-on-display display)))
1483     (cond
1484      ((memq frame-type '(x w32 mac))
1485       (x-display-grayscale-p display))
1486      (t
1487       (> (tty-color-gray-shades display) 2)))))
1488
1489 \f
1490 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1491 ;;; Background mode.
1492 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1493
1494 (defcustom frame-background-mode nil
1495   "*The brightness of the background.
1496 Set this to the symbol `dark' if your background color is dark, `light' if
1497 your background is light, or nil (default) if you want Emacs to
1498 examine the brightness for you.  Don't set this variable with `setq';
1499 this won't have the expected effect."
1500   :group 'faces
1501   :set #'(lambda (var value)
1502            (set-default var value)
1503            (mapc 'frame-set-background-mode (frame-list)))
1504   :initialize 'custom-initialize-changed
1505   :type '(choice (choice-item dark)
1506                  (choice-item light)
1507                  (choice-item :tag "default" nil)))
1508
1509
1510 (defun frame-set-background-mode (frame)
1511   "Set up display-dependent faces on FRAME.
1512 Display-dependent faces are those which have different definitions
1513 according to the `background-mode' and `display-type' frame parameters."
1514   (let* ((bg-resource
1515           (and window-system
1516                (x-get-resource "backgroundMode" "BackgroundMode")))
1517          (bg-color (frame-parameter frame 'background-color))
1518          (bg-mode
1519           (cond (frame-background-mode)
1520                 (bg-resource
1521                  (intern (downcase bg-resource)))
1522                 ((and (null window-system) (null bg-color))
1523                  ;; No way to determine this automatically (?).
1524                  'dark)
1525                 ;; Unspecified frame background color can only happen
1526                 ;; on tty's.
1527                 ((member bg-color '(unspecified "unspecified-bg"))
1528                  'dark)
1529                 ((equal bg-color "unspecified-fg") ; inverted colors
1530                  'light)
1531                 ((>= (apply '+ (x-color-values bg-color frame))
1532                     ;; Just looking at the screen, colors whose
1533                     ;; values add up to .6 of the white total
1534                     ;; still look dark to me.
1535                     (* (apply '+ (x-color-values "white" frame)) .6))
1536                  'light)
1537                 (t 'dark)))
1538          (display-type
1539           (cond ((null window-system)
1540                  (if (tty-display-color-p frame) 'color 'mono))
1541                 ((x-display-color-p frame)
1542                  'color)
1543                 ((x-display-grayscale-p frame)
1544                  'grayscale)
1545                 (t 'mono)))
1546          (old-bg-mode
1547           (frame-parameter frame 'background-mode))
1548          (old-display-type
1549           (frame-parameter frame 'display-type)))
1550
1551     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1552       (let ((locally-modified-faces nil))
1553         ;; Before modifying the frame parameters, we collect a list of
1554         ;; faces that don't match what their face-spec says they should
1555         ;; look like; we then avoid changing these faces below.  A
1556         ;; negative list is used on the assumption that most faces will
1557         ;; be unmodified, so we can avoid consing in the common case.
1558         (dolist (face (face-list))
1559           (when (not (face-spec-match-p face
1560                                         (face-user-default-spec face)
1561                                         (selected-frame)))
1562             (push face locally-modified-faces)))
1563         ;; Now change to the new frame parameters
1564         (modify-frame-parameters frame
1565                                  (list (cons 'background-mode bg-mode)
1566                                        (cons 'display-type display-type)))
1567         ;; For all named faces, choose face specs matching the new frame
1568         ;; parameters, unless they have been locally modified.
1569         (dolist (face (face-list))
1570           (unless (memq face locally-modified-faces)
1571             (face-spec-set face (face-user-default-spec face) frame)))))))
1572
1573 \f
1574 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1575 ;;; Frame creation.
1576 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1577
1578 (defun x-handle-named-frame-geometry (parameters)
1579   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1580 Value is the new parameter list."
1581   (let* ((name (or (cdr (assq 'name parameters))
1582                    (cdr (assq 'name default-frame-alist))))
1583          (x-resource-name name)
1584          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1585     (when res-geometry
1586       (let ((parsed (x-parse-geometry res-geometry)))
1587         ;; If the resource specifies a position, call the position
1588         ;; and size "user-specified".
1589         (when (or (assq 'top parsed)
1590                   (assq 'left parsed))
1591           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1592         ;; Put the geometry parameters at the end.  Copy
1593         ;; default-frame-alist so that they go after it.
1594         (setq parameters (append parameters default-frame-alist parsed))))
1595     parameters))
1596
1597
1598 (defun x-handle-reverse-video (frame parameters)
1599   "Handle the reverse-video frame parameter and X resource.
1600 `x-create-frame' does not handle this one."
1601   (when (cdr (or (assq 'reverse parameters)
1602                  (assq 'reverse default-frame-alist)
1603                  (let ((resource (x-get-resource "reverseVideo"
1604                                                  "ReverseVideo")))
1605                    (if resource
1606                        (cons nil (member (downcase resource)
1607                                          '("on" "true")))))))
1608       (let* ((params (frame-parameters frame))
1609              (bg (cdr (assq 'foreground-color params)))
1610              (fg (cdr (assq 'background-color params))))
1611         (modify-frame-parameters frame
1612                                  (list (cons 'foreground-color fg)
1613                                        (cons 'background-color bg)))
1614         (if (equal bg (cdr (assq 'border-color params)))
1615             (modify-frame-parameters frame
1616                                      (list (cons 'border-color fg))))
1617         (if (equal bg (cdr (assq 'mouse-color params)))
1618             (modify-frame-parameters frame
1619                                      (list (cons 'mouse-color fg))))
1620         (if (equal bg (cdr (assq 'cursor-color params)))
1621             (modify-frame-parameters frame
1622                                      (list (cons 'cursor-color fg)))))))
1623
1624
1625 (defun x-create-frame-with-faces (&optional parameters)
1626   "Create a frame from optional frame parameters PARAMETERS.
1627 Parameters not specified by PARAMETERS are taken from
1628 `default-frame-alist'.  If PARAMETERS specify a frame name,
1629 handle X geometry resources for that name.  If either PARAMETERS
1630 or `default-frame-alist' contains a `reverse' parameter, or
1631 the X resource ``reverseVideo'' is present, handle that.
1632 Value is the new frame created."
1633   (setq parameters (x-handle-named-frame-geometry parameters))
1634   (let ((visibility-spec (assq 'visibility parameters))
1635         (frame-list (frame-list))
1636         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1637         success)
1638     (unwind-protect
1639         (progn
1640           (x-handle-reverse-video frame parameters)
1641           (frame-set-background-mode frame)
1642           (face-set-after-frame-default frame)
1643           (if (or (null frame-list) (null visibility-spec))
1644               (make-frame-visible frame)
1645             (modify-frame-parameters frame (list visibility-spec)))
1646           (setq success t))
1647       (unless success
1648         (delete-frame frame)))
1649     frame))
1650
1651
1652 (defun face-set-after-frame-default (frame)
1653   "Set frame-local faces of FRAME from face specs and resources.
1654 Initialize colors of certain faces from frame parameters."
1655   (if (face-attribute 'default :font t)
1656       (set-face-attribute 'default frame :font
1657                           (face-attribute 'default :font t))
1658     (set-face-attribute 'default frame :family
1659                         (face-attribute 'default :family t))
1660     (set-face-attribute 'default frame :height
1661                         (face-attribute 'default :height t))
1662     (set-face-attribute 'default frame :slant
1663                         (face-attribute 'default :slant t))
1664     (set-face-attribute 'default frame :weight
1665                         (face-attribute 'default :weight t))
1666     (set-face-attribute 'default frame :width
1667                         (face-attribute 'default :width t)))
1668   (dolist (face (face-list))
1669     ;; Don't let frame creation fail because of an invalid face spec.
1670     (condition-case ()
1671         (when (not (equal face 'default))
1672           (face-spec-set face (face-user-default-spec face) frame)
1673           (internal-merge-in-global-face face frame)
1674           (when (and (memq window-system '(x w32 mac))
1675                      (or (not (boundp 'inhibit-default-face-x-resources))
1676                          (not (eq face 'default))))
1677             (make-face-x-resource-internal face frame)))
1678       (error nil)))
1679   ;; Initialize attributes from frame parameters.
1680   (let ((params '((foreground-color default :foreground)
1681                   (background-color default :background)
1682                   (border-color border :background)
1683                   (cursor-color cursor :background)
1684                   (scroll-bar-foreground scroll-bar :foreground)
1685                   (scroll-bar-background scroll-bar :background)
1686                   (mouse-color mouse :background))))
1687     (dolist (param params)
1688       (let ((frame-param (frame-parameter frame (nth 0 param)))
1689             (face (nth 1 param))
1690             (attr (nth 2 param)))
1691         (when (and frame-param
1692                    ;; Don't override face attributes explicitly
1693                    ;; specified for new frames.
1694                    (eq (face-attribute face attr t) 'unspecified))
1695           (set-face-attribute face frame attr frame-param))))))
1696
1697
1698 (defun tty-handle-reverse-video (frame parameters)
1699   "Handle the reverse-video frame parameter for terminal frames."
1700   (when (cdr (or (assq 'reverse parameters)
1701                  (assq 'reverse default-frame-alist)))
1702     (let* ((params (frame-parameters frame))
1703            (bg (cdr (assq 'foreground-color params)))
1704            (fg (cdr (assq 'background-color params))))
1705       (modify-frame-parameters frame
1706                                (list (cons 'foreground-color fg)
1707                                      (cons 'background-color bg)))
1708       (if (equal bg (cdr (assq 'mouse-color params)))
1709           (modify-frame-parameters frame
1710                                    (list (cons 'mouse-color fg))))
1711       (if (equal bg (cdr (assq 'cursor-color params)))
1712           (modify-frame-parameters frame
1713                                    (list (cons 'cursor-color fg)))))))
1714
1715
1716 (defun tty-create-frame-with-faces (&optional parameters)
1717   "Create a frame from optional frame parameters PARAMETERS.
1718 Parameters not specified by PARAMETERS are taken from
1719 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1720 contains a `reverse' parameter, handle that.  Value is the new frame
1721 created."
1722   (let ((frame (make-terminal-frame parameters))
1723         success)
1724     (unwind-protect
1725         (progn
1726           (tty-handle-reverse-video frame (frame-parameters frame))
1727           (frame-set-background-mode frame)
1728           (face-set-after-frame-default frame)
1729           (setq success t))
1730       (unless success
1731         (delete-frame frame)))
1732     frame))
1733
1734
1735 ;; Called from C function init_display to initialize faces of the
1736 ;; dumped terminal frame on startup.
1737
1738 (defun tty-set-up-initial-frame-faces ()
1739   (let ((frame (selected-frame)))
1740     (frame-set-background-mode frame)
1741     (face-set-after-frame-default frame)))
1742
1743
1744
1745 \f
1746 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1747 ;;; Compatiblity with 20.2
1748 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1749
1750 ;; Update a frame's faces when we change its default font.
1751
1752 (defalias 'frame-update-faces 'ignore "")
1753 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
1754
1755 ;; Update the colors of FACE, after FRAME's own colors have been
1756 ;; changed.
1757
1758 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1759 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1760
1761 \f
1762 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1763 ;;; Standard faces.
1764 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1765
1766 (defgroup basic-faces nil
1767   "The standard faces of Emacs."
1768   :group 'faces)
1769
1770
1771 (defface default
1772   '((t nil))
1773   "Basic default face."
1774   :group 'basic-faces)
1775
1776
1777 (defface mode-line
1778   '((((type x w32 mac) (class color))
1779      :box (:line-width -1 :style released-button)
1780      :background "grey75" :foreground "black")
1781     (t
1782      :inverse-video t))
1783   "Basic mode line face for selected window."
1784   :version "21.1"
1785   :group 'modeline
1786   :group 'basic-faces)
1787
1788 (defface mode-line-inactive
1789   '((t
1790      :inherit mode-line)
1791     (((type x w32 mac) (background light) (class color))
1792      :weight light
1793      :box (:line-width -1 :color "grey75" :style nil)
1794      :foreground "grey20" :background "grey90")
1795     (((type x w32 mac) (background dark) (class color))
1796      :weight light
1797      :box (:line-width -1 :color "grey40" :style nil)
1798      :foreground "grey80" :background "grey30"))
1799   "Basic mode line face for non-selected windows."
1800   :version "21.4"
1801   :group 'modeline
1802   :group 'basic-faces)
1803
1804 ;; Make `modeline' an alias for `mode-line', for compatibility.
1805 (put 'modeline 'face-alias 'mode-line)
1806 (put 'modeline-inactive 'face-alias 'mode-line-inactive)
1807
1808 (defface header-line
1809   '((t
1810      :inherit mode-line)
1811     (((type tty))
1812      ;; This used to be `:inverse-video t', but that doesn't look very
1813      ;; good when combined with inverse-video mode-lines and multiple
1814      ;; windows.  Underlining looks better, and is more consistent with
1815      ;; the window-system face variants, which deemphasize the
1816      ;; header-line in relation to the mode-line face.  If a terminal
1817      ;; can't underline, then the header-line will end up without any
1818      ;; highlighting; this may be too confusing in general, although it
1819      ;; happens to look good with the only current use of header-lines,
1820      ;; the info browser. XXX
1821      :inverse-video nil        ;Override the value inherited from mode-line.
1822      :underline t)
1823     (((class color grayscale) (background light))
1824      :background "grey90" :foreground "grey20"
1825      :box nil)
1826     (((class color grayscale) (background dark))
1827      :background "grey20" :foreground "grey90"
1828      :box nil)
1829     (((class mono) (background light))
1830      :background "white" :foreground "black"
1831      :inverse-video nil
1832      :box nil
1833      :underline t)
1834     (((class mono) (background dark))
1835      :background "black" :foreground "white"
1836      :inverse-video nil
1837      :box nil
1838      :underline t))
1839   "Basic header-line face."
1840   :version "21.1"
1841   :group 'basic-faces)
1842
1843
1844 (defface tool-bar
1845   '((t
1846      :box (:line-width 1 :style released-button)
1847      :foreground "black")
1848     (((type x w32 mac) (class color))
1849      :background "grey75")
1850     (((type x) (class mono))
1851      :background "grey"))
1852   "Basic tool-bar face."
1853   :version "21.1"
1854   :group 'basic-faces)
1855
1856
1857 (defface minibuffer-prompt '((((background dark)) :foreground "cyan")
1858                              (((type pc)) :foreground "magenta")
1859                              (t :foreground "dark blue"))
1860   "Face for minibuffer prompts."
1861   :version "21.4"
1862   :group 'basic-faces)
1863
1864 (setq minibuffer-prompt-properties
1865       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1866
1867 (defface region
1868   '((((class color) (min-colors 88) (background dark))
1869      :background "blue3")
1870     (((class color) (min-colors 88) (background light))
1871      :background "lightgoldenrod2")
1872     (((class color) (min-colors 16) (background dark))
1873      :background "blue3")
1874     (((class color) (min-colors 16) (background light))
1875      :background "lightgoldenrod2")
1876     (((class color) (min-colors 8))
1877      :background "blue" :foreground "white")
1878     (((type tty) (class mono))
1879      :inverse-video t)
1880     (t :background "gray"))
1881   "Basic face for highlighting the region."
1882   :version "21.1"
1883   :group 'basic-faces)
1884
1885
1886 (defface fringe
1887   '((((class color) (background light))
1888      :background "grey95")
1889     (((class color) (background dark))
1890      :background "grey10")
1891     (t
1892      :background "gray"))
1893   "Basic face for the fringes to the left and right of windows under X."
1894   :version "21.1"
1895   :group 'frames
1896   :group 'basic-faces)
1897
1898
1899 (defface scroll-bar '()
1900   "Basic face for the scroll bar colors under X."
1901   :version "21.1"
1902   :group 'frames
1903   :group 'basic-faces)
1904
1905
1906 (defface menu
1907   '((((type tty))
1908      :inverse-video t)
1909     (((type x-toolkit))
1910      )
1911     (t
1912      :inverse-video t))
1913   "Basic face for the font and colors of the menu bar and popup menus."
1914   :version "21.1"
1915   :group 'menu
1916   :group 'basic-faces)
1917
1918
1919 (defface border '()
1920   "Basic face for the frame border under X."
1921   :version "21.1"
1922   :group 'frames
1923   :group 'basic-faces)
1924
1925
1926 (defface cursor '()
1927   "Basic face for the cursor color under X.
1928 Note: Other faces cannot inherit from the cursor face."
1929   :version "21.1"
1930   :group 'cursor
1931   :group 'basic-faces)
1932
1933 (put 'cursor 'face-no-inherit t)
1934
1935 (defface mouse '()
1936   "Basic face for the mouse color under X."
1937   :version "21.1"
1938   :group 'mouse
1939   :group 'basic-faces)
1940
1941
1942 (defface bold '((t :weight bold))
1943   "Basic bold face."
1944   :group 'basic-faces)
1945
1946
1947 (defface italic
1948   '((((supports :slant italic))
1949      :slant italic)
1950     (((supports :underline t))
1951      :underline t)
1952     (t
1953      ;; default to italic, even it doesn't appear to be supported,
1954      ;; because in some cases the display engine will do it's own
1955      ;; workaround (to `dim' on ttys)
1956      :slant italic))
1957   "Basic italic font."
1958   :group 'basic-faces)
1959
1960
1961 (defface bold-italic '((t :weight bold :slant italic))
1962   "Basic bold-italic face."
1963   :group 'basic-faces)
1964
1965
1966 (defface underline '((t :underline t))
1967   "Basic underlined face."
1968   :group 'basic-faces)
1969
1970
1971 (defface highlight
1972   '((((class color) (min-colors 88) (background light))
1973      :background "darkseagreen2")
1974     (((class color) (min-colors 88) (background dark))
1975      :background "darkolivegreen")
1976     (((class color) (min-colors 16) (background light))
1977      :background "darkseagreen2")
1978     (((class color) (min-colors 16) (background dark))
1979      :background "darkolivegreen")
1980     (((class color) (min-colors 8))
1981      :background "green" :foreground "black")
1982     (t :inverse-video t))
1983   "Basic face for highlighting."
1984   :group 'basic-faces)
1985
1986
1987 (defface secondary-selection
1988   '((((class color) (min-colors 88) (background light))
1989      :background "yellow")
1990     (((class color) (min-colors 88) (background dark))
1991      :background "SkyBlue4")
1992     (((class color) (min-colors 16) (background light))
1993      :background "yellow")
1994     (((class color) (min-colors 16) (background dark))
1995      :background "SkyBlue4")
1996     (((class color) (min-colors 8))
1997      :background "cyan" :foreground "black")
1998     (t :inverse-video t))
1999   "Basic face for displaying the secondary selection."
2000   :group 'basic-faces)
2001
2002
2003 (defface fixed-pitch '((t :family "courier"))
2004   "The basic fixed-pitch face."
2005   :group 'basic-faces)
2006
2007
2008 (defface variable-pitch '((t :family "helv"))
2009   "The basic variable-pitch face."
2010   :group 'basic-faces)
2011
2012
2013 (defface trailing-whitespace
2014   '((((class color) (background light))
2015      :background "red")
2016     (((class color) (background dark))
2017      :background "red")
2018     (t :inverse-video t))
2019   "Basic face for highlighting trailing whitespace."
2020   :version "21.1"
2021   :group 'font-lock                     ; like `show-trailing-whitespace'
2022   :group 'basic-faces)
2023
2024
2025 \f
2026 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2027 ;;; Manipulating font names.
2028 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2029
2030 ;; This is here for compatibilty with Emacs 20.2.  For example,
2031 ;; international/fontset.el uses x-resolve-font-name.  The following
2032 ;; functions are not used in the face implementation itself.
2033
2034 (defvar x-font-regexp nil)
2035 (defvar x-font-regexp-head nil)
2036 (defvar x-font-regexp-weight nil)
2037 (defvar x-font-regexp-slant nil)
2038
2039 (defconst x-font-regexp-weight-subnum 1)
2040 (defconst x-font-regexp-slant-subnum 2)
2041 (defconst x-font-regexp-swidth-subnum 3)
2042 (defconst x-font-regexp-adstyle-subnum 4)
2043
2044 ;;; Regexps matching font names in "Host Portable Character Representation."
2045 ;;;
2046 (let ((-                "[-?]")
2047       (foundry          "[^-]+")
2048       (family           "[^-]+")
2049       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2050 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2051       (weight\?         "\\([^-]*\\)")                                  ; 1
2052       (slant            "\\([ior]\\)")                                  ; 2
2053 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2054       (slant\?          "\\([^-]?\\)")                                  ; 2
2055 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2056       (swidth           "\\([^-]*\\)")                                  ; 3
2057 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2058       (adstyle          "\\([^-]*\\)")                                  ; 4
2059       (pixelsize        "[0-9]+")
2060       (pointsize        "[0-9][0-9]+")
2061       (resx             "[0-9][0-9]+")
2062       (resy             "[0-9][0-9]+")
2063       (spacing          "[cmp?*]")
2064       (avgwidth         "[0-9]+")
2065       (registry         "[^-]+")
2066       (encoding         "[^-]+")
2067       )
2068   (setq x-font-regexp
2069         (concat "\\`\\*?[-?*]"
2070                 foundry - family - weight\? - slant\? - swidth - adstyle -
2071                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2072                 registry - encoding "\\*?\\'"
2073                 ))
2074   (setq x-font-regexp-head
2075         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2076                 "\\([-*?]\\|\\'\\)"))
2077   (setq x-font-regexp-slant (concat - slant -))
2078   (setq x-font-regexp-weight (concat - weight -))
2079   nil)
2080
2081
2082 (defun x-resolve-font-name (pattern &optional face frame)
2083   "Return a font name matching PATTERN.
2084 All wildcards in PATTERN are instantiated.
2085 If PATTERN is nil, return the name of the frame's base font, which never
2086 contains wildcards.
2087 Given optional arguments FACE and FRAME, return a font which is
2088 also the same size as FACE on FRAME, or fail."
2089   (or (symbolp face)
2090       (setq face (face-name face)))
2091   (and (eq frame t)
2092        (setq frame nil))
2093   (if pattern
2094       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2095       (let ((fonts (x-list-fonts pattern face frame 1)))
2096         (or fonts
2097             (if face
2098                 (if (string-match "\\*" pattern)
2099                     (if (null (face-font face))
2100                         (error "No matching fonts are the same height as the frame default font")
2101                       (error "No matching fonts are the same height as face `%s'" face))
2102                   (if (null (face-font face))
2103                       (error "Height of font `%s' doesn't match the frame default font"
2104                              pattern)
2105                     (error "Height of font `%s' doesn't match face `%s'"
2106                            pattern face)))
2107               (error "No fonts match `%s'" pattern)))
2108         (car fonts))
2109     (cdr (assq 'font (frame-parameters (selected-frame))))))
2110
2111
2112 (defun x-frob-font-weight (font which)
2113   (let ((case-fold-search t))
2114     (cond ((string-match x-font-regexp font)
2115            (concat (substring font 0
2116                               (match-beginning x-font-regexp-weight-subnum))
2117                    which
2118                    (substring font (match-end x-font-regexp-weight-subnum)
2119                               (match-beginning x-font-regexp-adstyle-subnum))
2120                    ;; Replace the ADD_STYLE_NAME field with *
2121                    ;; because the info in it may not be the same
2122                    ;; for related fonts.
2123                    "*"
2124                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2125           ((string-match x-font-regexp-head font)
2126            (concat (substring font 0 (match-beginning 1)) which
2127                    (substring font (match-end 1))))
2128           ((string-match x-font-regexp-weight font)
2129            (concat (substring font 0 (match-beginning 1)) which
2130                    (substring font (match-end 1)))))))
2131 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2132
2133 (defun x-frob-font-slant (font which)
2134   (let ((case-fold-search t))
2135     (cond ((string-match x-font-regexp font)
2136            (concat (substring font 0
2137                               (match-beginning x-font-regexp-slant-subnum))
2138                    which
2139                    (substring font (match-end x-font-regexp-slant-subnum)
2140                               (match-beginning x-font-regexp-adstyle-subnum))
2141                    ;; Replace the ADD_STYLE_NAME field with *
2142                    ;; because the info in it may not be the same
2143                    ;; for related fonts.
2144                    "*"
2145                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2146           ((string-match x-font-regexp-head font)
2147            (concat (substring font 0 (match-beginning 2)) which
2148                    (substring font (match-end 2))))
2149           ((string-match x-font-regexp-slant font)
2150            (concat (substring font 0 (match-beginning 1)) which
2151                    (substring font (match-end 1)))))))
2152 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2153
2154 ;; These aliases are here so that we don't get warnings about obsolete
2155 ;; functions from the byte compiler.
2156 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2157 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2158
2159 (defun x-make-font-bold (font)
2160   "Given an X font specification, make a bold version of it.
2161 If that can't be done, return nil."
2162   (internal-frob-font-weight font "bold"))
2163 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2164
2165 (defun x-make-font-demibold (font)
2166   "Given an X font specification, make a demibold version of it.
2167 If that can't be done, return nil."
2168   (internal-frob-font-weight font "demibold"))
2169 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2170
2171 (defun x-make-font-unbold (font)
2172   "Given an X font specification, make a non-bold version of it.
2173 If that can't be done, return nil."
2174   (internal-frob-font-weight font "medium"))
2175 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2176
2177 (defun x-make-font-italic (font)
2178   "Given an X font specification, make an italic version of it.
2179 If that can't be done, return nil."
2180   (internal-frob-font-slant font "i"))
2181 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2182
2183 (defun x-make-font-oblique (font) ; you say tomayto...
2184   "Given an X font specification, make an oblique version of it.
2185 If that can't be done, return nil."
2186   (internal-frob-font-slant font "o"))
2187 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2188
2189 (defun x-make-font-unitalic (font)
2190   "Given an X font specification, make a non-italic version of it.
2191 If that can't be done, return nil."
2192   (internal-frob-font-slant font "r"))
2193 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2194
2195 (defun x-make-font-bold-italic (font)
2196   "Given an X font specification, make a bold and italic version of it.
2197 If that can't be done, return nil."
2198   (and (setq font (internal-frob-font-weight font "bold"))
2199        (internal-frob-font-slant font "i")))
2200 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2201
2202 (provide 'faces)
2203
2204 ;;; arch-tag: 19a4759f-2963-445f-b004-425b9aadd7d6
2205 ;;; faces.el ends here