lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@gnu.org>
   6 ;; Keywords: archives msdog editing major-mode
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  29 ;; to files whose name end in ".arc"
  30 ;;
  31 ;; This code does not decode any files internally, although it does
  32 ;; understand the directory level of the archives.  For this reason,
  33 ;; you should expect this code to need more fiddling than tar-mode.el
  34 ;; (although it at present has fewer bugs :-)  In particular, I have
  35 ;; not tested this under Ms-Dog myself.
  36 ;; -------------------------------------
  37 ;; INTERACTION: arc-mode.el should play together with
  38 ;;
  39 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  40 ;;                to you) are handled by doing all updates on a local
  41 ;;                copy.  When you make changes to a remote file the
  42 ;;                changes will first take effect when the archive buffer
  43 ;;                is saved.  You will be warned about this.
  44 ;;
  45 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  46 ;;                conversion.
  47 ;;
  48 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  49 ;; such this could be fixed (but wouldn't be useful) by declaring such
  50 ;; archives to be "remote".  For the members this is a general Emacs
  51 ;; problem that 19.29's file formats may fix.
  52 ;; -------------------------------------
  53 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  54 ;; structure for handling just about anything is in place.
  55 ;;
  56 ;;                        Arc     Lzh     Zip     Zoo
  57 ;;                        --------------------------------
  58 ;; View listing           Intern  Intern  Intern  Intern
  59 ;; Extract member         Y       Y       Y       Y
  60 ;; Save changed member    Y       Y       Y       Y
  61 ;; Add new member         N       N       N       N
  62 ;; Delete member          Y       Y       Y       Y
  63 ;; Rename member          Y       Y       N       N
  64 ;; Chmod                  -       Y       Y       -
  65 ;; Chown                  -       Y       -       -
  66 ;; Chgrp                  -       Y       -       -
  67 ;;
  68 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  69 ;; on the first released version of this package.
  70 ;;
  71 ;; This code is partly based on tar-mode.el from Emacs.
  72 ;; -------------------------------------
  73 ;; ARCHIVE STRUCTURES:
  74 ;; (This is mostly for myself.)
  75 ;;
  76 ;; ARC         A series of (header,file).  No interactions among members.
  77 ;;
  78 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  79 ;;             interaction among members.
  80 ;;             Headers come in three flavours called level 0, 1 and 2 headers.
  81 ;;             Level 2 header is free of DOS specific restrictions and most
  82 ;;             prevalently used.  Also level 1 and 2 headers consist of base
  83 ;;             and extension headers.  For more details see
  84 ;;             http://homepage1.nifty.com/dangan/en/Content/Program/Java/jLHA/Notes/Notes.html
  85 ;;             http://www.osirusoft.com/joejared/lzhformat.html
  86 ;;
  87 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  88 ;;             which is a series of (cheader) followed by an end-of-
  89 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  90 ;;             links to c-d.  cheaders link to lheaders which are basically
  91 ;;             cut-down versions of the cheaders.
  92 ;;
  93 ;; ZOO         An archive header followed by a series of (header,file).
  94 ;;             Each member header points to the next.  The archive is
  95 ;;             terminated by a bogus header with a zero next link.
  96 ;; -------------------------------------
  97 ;; HOOKS: `foo' means one of the supported archive types.
  98 ;;
  99 ;; archive-mode-hook
 100 ;; archive-foo-mode-hook
 101 ;; archive-extract-hooks
 102
 103 ;;; Code:
 104
 105 ;; -------------------------------------------------------------------------
 106 ;; Section: Configuration.
 107
 108 (defgroup archive nil
 109   "Simple editing of archives."
 110   :group 'data)
 111
 112 (defgroup archive-arc nil
 113   "ARC-specific options to archive."
 114   :group 'archive)
 115
 116 (defgroup archive-lzh nil
 117   "LZH-specific options to archive."
 118   :group 'archive)
 119
 120 (defgroup archive-zip nil
 121   "ZIP-specific options to archive."
 122   :group 'archive)
 123
 124 (defgroup archive-zoo nil
 125   "ZOO-specific options to archive."
 126   :group 'archive)
 127
 128 (defcustom archive-tmpdir
 129   ;; make-temp-name is safe here because we use this name
 130   ;; to create a directory.
 131   (make-temp-name
 132    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 133                      temporary-file-directory))
 134   "*Directory for temporary files made by arc-mode.el"
 135   :type 'directory
 136   :group 'archive)
 137
 138 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 139   "*Regexp recognizing archive files names that are not local.
 140 A non-local file is one whose file name is not proper outside Emacs.
 141 A local copy of the archive will be used when updating."
 142   :type 'regexp
 143   :group 'archive)
 144
 145 (defcustom archive-extract-hooks nil
 146   "*Hooks to run when an archive member has been extracted."
 147   :type 'hook
 148   :group 'archive)
 149 ;; ------------------------------
 150 ;; Arc archive configuration
 151
 152 ;; We always go via a local file since there seems to be no reliable way
 153 ;; to extract to stdout without junk getting added.
 154 (defcustom archive-arc-extract
 155   '("arc" "x")
 156   "*Program and its options to run in order to extract an arc file member.
 157 Extraction should happen to the current directory.  Archive and member
 158 name will be added."
 159   :type '(list (string :tag "Program")
 160                 (repeat :tag "Options"
 161                         :inline t
 162                         (string :format "%v")))
 163   :group 'archive-arc)
 164
 165 (defcustom archive-arc-expunge
 166   '("arc" "d")
 167   "*Program and its options to run in order to delete arc file members.
 168 Archive and member names will be added."
 169   :type '(list (string :tag "Program")
 170                 (repeat :tag "Options"
 171                         :inline t
 172                         (string :format "%v")))
 173   :group 'archive-arc)
 174
 175 (defcustom archive-arc-write-file-member
 176   '("arc" "u")
 177   "*Program and its options to run in order to update an arc file member.
 178 Archive and member name will be added."
 179   :type '(list (string :tag "Program")
 180                 (repeat :tag "Options"
 181                         :inline t
 182                         (string :format "%v")))
 183   :group 'archive-arc)
 184 ;; ------------------------------
 185 ;; Lzh archive configuration
 186
 187 (defcustom archive-lzh-extract
 188   '("lha" "pq")
 189   "*Program and its options to run in order to extract an lzh file member.
 190 Extraction should happen to standard output.  Archive and member name will
 191 be added."
 192   :type '(list (string :tag "Program")
 193                 (repeat :tag "Options"
 194                         :inline t
 195                         (string :format "%v")))
 196   :group 'archive-lzh)
 197
 198 (defcustom archive-lzh-expunge
 199   '("lha" "d")
 200   "*Program and its options to run in order to delete lzh file members.
 201 Archive and member names will be added."
 202   :type '(list (string :tag "Program")
 203                 (repeat :tag "Options"
 204                         :inline t
 205                         (string :format "%v")))
 206   :group 'archive-lzh)
 207
 208 (defcustom archive-lzh-write-file-member
 209   '("lha" "a")
 210   "*Program and its options to run in order to update an lzh file member.
 211 Archive and member name will be added."
 212   :type '(list (string :tag "Program")
 213                 (repeat :tag "Options"
 214                         :inline t
 215                         (string :format "%v")))
 216   :group 'archive-lzh)
 217 ;; ------------------------------
 218 ;; Zip archive configuration
 219
 220 (defcustom archive-zip-extract
 221   (if (locate-file "unzip" nil 'file-executable-p)
 222       '("unzip" "-qq" "-c")
 223     (if (locate-file "pkunzip" nil 'file-executable-p)
 224         '("pkunzip" "-e" "-o-")
 225       '("unzip" "-qq" "-c")))
 226   "*Program and its options to run in order to extract a zip file member.
 227 Extraction should happen to standard output.  Archive and member name will
 228 be added.  If `archive-zip-use-pkzip' is non-nil then this program is
 229 expected to extract to a file junking the directory part of the name."
 230   :type '(list (string :tag "Program")
 231                 (repeat :tag "Options"
 232                         :inline t
 233                         (string :format "%v")))
 234   :group 'archive-zip)
 235
 236 ;; For several reasons the latter behaviour is not desirable in general.
 237 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 238 ;; existent.  (3) It tends to do funny things with other systems' file
 239 ;; names.
 240
 241 (defcustom archive-zip-expunge
 242   (if (locate-file "zip" nil 'file-executable-p)
 243       '("zip" "-d" "-q")
 244     (if (locate-file "pkzip" nil 'file-executable-p)
 245          '("pkzip" "-d")
 246       '("zip" "-d" "-q")))
 247   "*Program and its options to run in order to delete zip file members.
 248 Archive and member names will be added."
 249   :type '(list (string :tag "Program")
 250                 (repeat :tag "Options"
 251                         :inline t
 252                         (string :format "%v")))
 253   :group 'archive-zip)
 254
 255 (defcustom archive-zip-update
 256   (if (locate-file "zip" nil 'file-executable-p)
 257       '("zip" "-q")
 258     (if (locate-file "pkzip" nil 'file-executable-p)
 259          '("pkzip" "-u" "-P")
 260       '("zip" "-q")))
 261   "*Program and its options to run in order to update a zip file member.
 262 Options should ensure that specified directory will be put into the zip
 263 file.  Archive and member name will be added."
 264   :type '(list (string :tag "Program")
 265                 (repeat :tag "Options"
 266                         :inline t
 267                         (string :format "%v")))
 268   :group 'archive-zip)
 269
 270 (defcustom archive-zip-update-case
 271   (if (locate-file "zip" nil 'file-executable-p)
 272       '("zip" "-q" "-k")
 273     (if (locate-file "pkzip" nil 'file-executable-p)
 274          '("pkzip" "-u" "-P")
 275       '("zip" "-q" "-k")))
 276   "*Program and its options to run in order to update a case fiddled zip member.
 277 Options should ensure that specified directory will be put into the zip file.
 278 Archive and member name will be added."
 279   :type '(list (string :tag "Program")
 280                 (repeat :tag "Options"
 281                         :inline t
 282                         (string :format "%v")))
 283   :group 'archive-zip)
 284
 285 (defcustom archive-zip-case-fiddle t
 286   "*If non-nil then zip file members may be down-cased.
 287 This case fiddling will only happen for members created by a system
 288 that uses caseless file names."
 289   :type 'boolean
 290   :group 'archive-zip)
 291 ;; ------------------------------
 292 ;; Zoo archive configuration
 293
 294 (defcustom archive-zoo-extract
 295   '("zoo" "xpq")
 296   "*Program and its options to run in order to extract a zoo file member.
 297 Extraction should happen to standard output.  Archive and member name will
 298 be added."
 299   :type '(list (string :tag "Program")
 300                 (repeat :tag "Options"
 301                         :inline t
 302                         (string :format "%v")))
 303   :group 'archive-zoo)
 304
 305 (defcustom archive-zoo-expunge
 306   '("zoo" "DqPP")
 307   "*Program and its options to run in order to delete zoo file members.
 308 Archive and member names will be added."
 309   :type '(list (string :tag "Program")
 310                 (repeat :tag "Options"
 311                         :inline t
 312                         (string :format "%v")))
 313   :group 'archive-zoo)
 314
 315 (defcustom archive-zoo-write-file-member
 316   '("zoo" "a")
 317   "*Program and its options to run in order to update a zoo file member.
 318 Archive and member name will be added."
 319   :type '(list (string :tag "Program")
 320                 (repeat :tag "Options"
 321                         :inline t
 322                         (string :format "%v")))
 323   :group 'archive-zoo)
 324 ;; -------------------------------------------------------------------------
 325 ;; Section: Variables
 326
 327 (defvar archive-subtype nil "Symbol describing archive type.")
 328 (defvar archive-file-list-start nil "Position of first contents line.")
 329 (defvar archive-file-list-end nil "Position just after last contents line.")
 330 (defvar archive-proper-file-start nil "Position of real archive's start.")
 331 (defvar archive-read-only nil "Non-nil if the archive is read-only on disk.")
 332 (defvar archive-local-name nil "Name of local copy of remote archive.")
 333 (defvar archive-mode-map nil "Local keymap for archive mode listings.")
 334 (defvar archive-file-name-indent nil "Column where file names start.")
 335
 336 (defvar archive-remote nil "Non-nil if the archive is outside file system.")
 337 (make-variable-buffer-local 'archive-remote)
 338 (put 'archive-remote 'permanent-local t)
 339
 340 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 341 (make-variable-buffer-local 'archive-member-coding-system)
 342
 343 (defvar archive-alternate-display nil
 344   "Non-nil when alternate information is shown.")
 345 (make-variable-buffer-local 'archive-alternate-display)
 346 (put 'archive-alternate-display 'permanent-local t)
 347
 348 (defvar archive-superior-buffer nil "In archive members, points to archive.")
 349 (put 'archive-superior-buffer 'permanent-local t)
 350
 351 (defvar archive-subfile-mode nil "Non-nil in archive member buffers.")
 352 (make-variable-buffer-local 'archive-subfile-mode)
 353 (put 'archive-subfile-mode 'permanent-local t)
 354
 355 (defvar archive-files nil
 356   "Vector of file descriptors.
 357 Each descriptor is a vector of the form
 358  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 359 (make-variable-buffer-local 'archive-files)
 360
 361 (defvar archive-lemacs
 362   (string-match "\\(Lucid\\|Xemacs\\)" emacs-version)
 363   "*Non-nil when running under under Lucid Emacs or Xemacs.")
 364 ;; -------------------------------------------------------------------------
 365 ;; Section: Support functions.
 366
 367 (defsubst archive-name (suffix)
 368   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 369
 370 (defun archive-l-e (str &optional len)
 371   "Convert little endian string/vector to integer.
 372 Alternatively, first argument may be a buffer position in the current buffer
 373 in which case a second argument, length, should be supplied."
 374   (if (stringp str)
 375       (setq len (length str))
 376     (setq str (buffer-substring str (+ str len))))
 377   (let ((result 0)
 378         (i 0))
 379     (while (< i len)
 380       (setq i (1+ i)
 381             result (+ (ash result 8) (aref str (- len i)))))
 382     result))
 383
 384 (defun archive-int-to-mode (mode)
 385   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 386   ;; FIXME: merge with tar-grind-file-mode.
 387   (string
 388     (if (zerop (logand  8192 mode))
 389         (if (zerop (logand 16384 mode)) ?- ?d)
 390       ?c) ; completeness
 391     (if (zerop (logand   256 mode)) ?- ?r)
 392     (if (zerop (logand   128 mode)) ?- ?w)
 393     (if (zerop (logand    64 mode))
 394         (if (zerop (logand  1024 mode)) ?- ?S)
 395       (if (zerop (logand  1024 mode)) ?x ?s))
 396     (if (zerop (logand    32 mode)) ?- ?r)
 397     (if (zerop (logand    16 mode)) ?- ?w)
 398     (if (zerop (logand     8 mode))
 399         (if (zerop (logand  2048 mode)) ?- ?S)
 400       (if (zerop (logand  2048 mode)) ?x ?s))
 401     (if (zerop (logand     4 mode)) ?- ?r)
 402     (if (zerop (logand     2 mode)) ?- ?w)
 403     (if (zerop (logand     1 mode)) ?- ?x)))
 404
 405 (defun archive-calc-mode (oldmode newmode &optional error)
 406   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 407 NEWMODE may be an octal number including a leading zero in which case it
 408 will become the new mode.\n
 409 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 410 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 411 If optional third argument ERROR is non-nil an error will be signaled if
 412 the mode is invalid.  If ERROR is nil then nil will be returned."
 413   (cond ((string-match "^0[0-7]*$" newmode)
 414          (let ((result 0)
 415                (len (length newmode))
 416                (i 1))
 417            (while (< i len)
 418              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 419                    i (1+ i)))
 420            (logior (logand oldmode 65024) result)))
 421         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 422          (let ((who 0)
 423                (result oldmode)
 424                (op (aref newmode (match-beginning 2)))
 425                (bits 0)
 426                (i (match-beginning 3)))
 427            (while (< i (match-end 3))
 428              (let ((rwx (aref newmode i)))
 429                (setq bits (logior bits (cond ((= rwx ?r)  292)
 430                                              ((= rwx ?w)  146)
 431                                              ((= rwx ?x)   73)
 432                                              ((= rwx ?s) 3072)
 433                                              ((= rwx ?t)  512)))
 434                      i (1+ i))))
 435            (while (< who (match-end 1))
 436              (let* ((whoc (aref newmode who))
 437                     (whomask (cond ((= whoc ?a) 4095)
 438                                    ((= whoc ?u) 1472)
 439                                    ((= whoc ?g) 2104)
 440                                    ((= whoc ?o)    7))))
 441                (if (= op ?=)
 442                    (setq result (logand result (lognot whomask))))
 443                (if (= op ?-)
 444                    (setq result (logand result (lognot (logand whomask bits))))
 445                  (setq result (logior result (logand whomask bits)))))
 446              (setq who (1+ who)))
 447            result))
 448         (t
 449          (if error
 450              (error "Invalid mode specification: %s" newmode)))))
 451
 452 (defun archive-dosdate (date)
 453   "Stringify dos packed DATE record."
 454   (let ((year (+ 1980 (logand (ash date -9) 127)))
 455         (month (logand (ash date -5) 15))
 456         (day (logand date 31)))
 457     (if (or (> month 12) (< month 1))
 458         ""
 459       (format "%2d-%s-%d"
 460               day
 461               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 462                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 463               year))))
 464
 465 (defun archive-dostime (time)
 466   "Stringify dos packed TIME record."
 467   (let ((hour (logand (ash time -11) 31))
 468         (minute (logand (ash time -5) 63))
 469         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 470     (format "%02d:%02d:%02d" hour minute second)))
 471
 472 (defun archive-unixdate (low high)
 473   "Stringify unix (LOW HIGH) date."
 474   (let ((str (current-time-string (cons high low))))
 475     (format "%s-%s-%s"
 476             (substring str 8 10)
 477             (substring str 4 7)
 478             (substring str 20 24))))
 479
 480 (defun archive-unixtime (low high)
 481   "Stringify unix (LOW HIGH) time."
 482   (let ((str (current-time-string (cons high low))))
 483     (substring str 11 19)))
 484
 485 (defun archive-get-lineno ()
 486   (if (>= (point) archive-file-list-start)
 487       (count-lines archive-file-list-start
 488                    (save-excursion (beginning-of-line) (point)))
 489     0))
 490
 491 (defun archive-get-descr (&optional noerror)
 492   "Return the descriptor vector for file at point.
 493 Does not signal an error if optional second argument NOERROR is non-nil."
 494   (let ((no (archive-get-lineno)))
 495     (if (and (>= (point) archive-file-list-start)
 496              (< no (length archive-files)))
 497         (let ((item (aref archive-files no)))
 498           (if (vectorp item)
 499               item
 500             (if (not noerror)
 501                 (error "Entry is not a regular member of the archive"))))
 502       (if (not noerror)
 503           (error "Line does not describe a member of the archive")))))
 504 ;; -------------------------------------------------------------------------
 505 ;; Section: the mode definition
 506
 507 ;;;###autoload
 508 (defun archive-mode (&optional force)
 509   "Major mode for viewing an archive file in a dired-like way.
 510 You can move around using the usual cursor motion commands.
 511 Letters no longer insert themselves.
 512 Type `e' to pull a file out of the archive and into its own buffer;
 513 or click mouse-2 on the file's line in the archive mode buffer.
 514
 515 If you edit a sub-file of this archive (as with the `e' command) and
 516 save it, the contents of that buffer will be saved back into the
 517 archive.
 518
 519 \\{archive-mode-map}"
 520   ;; This is not interactive because you shouldn't be turning this
 521   ;; mode on and off.  You can corrupt things that way.
 522   (if (zerop (buffer-size))
 523       ;; At present we cannot create archives from scratch
 524       (funcall default-major-mode)
 525     (if (and (not force) archive-files) nil
 526       (let* ((type (archive-find-type))
 527              (typename (capitalize (symbol-name type))))
 528         (kill-all-local-variables)
 529         (make-local-variable 'archive-subtype)
 530         (setq archive-subtype type)
 531
 532         ;; Buffer contains treated image of file before the file contents
 533         (make-local-variable 'revert-buffer-function)
 534         (setq revert-buffer-function 'archive-mode-revert)
 535         (auto-save-mode 0)
 536
 537         ;; Remote archives are not written by a hook.
 538         (if archive-remote nil
 539           (make-local-variable 'write-contents-hooks)
 540           (add-hook 'write-contents-hooks 'archive-write-file))
 541
 542         (make-local-variable 'require-final-newline)
 543         (setq require-final-newline nil)
 544         (make-local-variable 'local-enable-local-variables)
 545         (setq local-enable-local-variables nil)
 546
 547         ;; Prevent loss of data when saving the file.
 548         (make-local-variable 'file-precious-flag)
 549         (setq file-precious-flag t)
 550
 551         (make-local-variable 'archive-read-only)
 552         ;; Archives which are inside other archives and whose
 553         ;; names are invalid for this OS, can't be written.
 554         (setq archive-read-only
 555               (or (not (file-writable-p (buffer-file-name)))
 556                   (and archive-subfile-mode
 557                        (string-match file-name-invalid-regexp
 558                                      (aref archive-subfile-mode 0)))))
 559
 560         ;; Should we use a local copy when accessing from outside Emacs?
 561         (make-local-variable 'archive-local-name)
 562
 563         ;; An archive can contain another archive whose name is invalid
 564         ;; on local filesystem.  Treat such archives as remote.
 565         (or archive-remote
 566             (setq archive-remote
 567                   (or (string-match archive-remote-regexp (buffer-file-name))
 568                       (string-match file-name-invalid-regexp
 569                                     (buffer-file-name)))))
 570
 571         (setq major-mode 'archive-mode)
 572         (setq mode-name (concat typename "-Archive"))
 573         ;; Run archive-foo-mode-hook and archive-mode-hook
 574         (run-hooks (archive-name "mode-hook") 'archive-mode-hook)
 575         (use-local-map archive-mode-map))
 576
 577       (make-local-variable 'archive-proper-file-start)
 578       (make-local-variable 'archive-file-list-start)
 579       (make-local-variable 'archive-file-list-end)
 580       (make-local-variable 'archive-file-name-indent)
 581       (archive-summarize nil)
 582       (setq buffer-read-only t))))
 583
 584 ;; Archive mode is suitable only for specially formatted data.
 585 (put 'archive-mode 'mode-class 'special)
 586 ;; -------------------------------------------------------------------------
 587 ;; Section: Key maps
 588
 589 (if archive-mode-map nil
 590   (setq archive-mode-map (make-keymap))
 591   (suppress-keymap archive-mode-map)
 592   (define-key archive-mode-map " " 'archive-next-line)
 593   (define-key archive-mode-map "a" 'archive-alternate-display)
 594   ;;(define-key archive-mode-map "c" 'archive-copy)
 595   (define-key archive-mode-map "d" 'archive-flag-deleted)
 596   (define-key archive-mode-map "\C-d" 'archive-flag-deleted)
 597   (define-key archive-mode-map "e" 'archive-extract)
 598   (define-key archive-mode-map "f" 'archive-extract)
 599   (define-key archive-mode-map "\C-m" 'archive-extract)
 600   (define-key archive-mode-map "g" 'revert-buffer)
 601   (define-key archive-mode-map "h" 'describe-mode)
 602   (define-key archive-mode-map "m" 'archive-mark)
 603   (define-key archive-mode-map "n" 'archive-next-line)
 604   (define-key archive-mode-map "\C-n" 'archive-next-line)
 605   (define-key archive-mode-map [down] 'archive-next-line)
 606   (define-key archive-mode-map "o" 'archive-extract-other-window)
 607   (define-key archive-mode-map "p" 'archive-previous-line)
 608   (define-key archive-mode-map "q" 'quit-window)
 609   (define-key archive-mode-map "\C-p" 'archive-previous-line)
 610   (define-key archive-mode-map [up] 'archive-previous-line)
 611   (define-key archive-mode-map "r" 'archive-rename-entry)
 612   (define-key archive-mode-map "u" 'archive-unflag)
 613   (define-key archive-mode-map "\M-\C-?" 'archive-unmark-all-files)
 614   (define-key archive-mode-map "v" 'archive-view)
 615   (define-key archive-mode-map "x" 'archive-expunge)
 616   (define-key archive-mode-map "\177" 'archive-unflag-backwards)
 617   (define-key archive-mode-map "E" 'archive-extract-other-window)
 618   (define-key archive-mode-map "M" 'archive-chmod-entry)
 619   (define-key archive-mode-map "G" 'archive-chgrp-entry)
 620   (define-key archive-mode-map "O" 'archive-chown-entry)
 621
 622   (if archive-lemacs
 623       (progn
 624         ;; Not a nice "solution" but it'll have to do
 625         (define-key archive-mode-map "\C-xu" 'archive-undo)
 626         (define-key archive-mode-map "\C-_" 'archive-undo))
 627     (define-key archive-mode-map [remap advertised-undo] 'archive-undo)
 628     (define-key archive-mode-map [remap undo] 'archive-undo))
 629
 630   (define-key archive-mode-map
 631     (if archive-lemacs 'button2 [mouse-2]) 'archive-mouse-extract)
 632
 633   (if archive-lemacs
 634       ()                                ; out of luck
 635
 636     (define-key archive-mode-map [menu-bar immediate]
 637       (cons "Immediate" (make-sparse-keymap "Immediate")))
 638     (define-key archive-mode-map [menu-bar immediate alternate]
 639       '(menu-item "Alternate Display" archive-alternate-display
 640                   :enable (boundp (archive-name "alternate-display"))
 641                   :help "Toggle alternate file info display"))
 642     (define-key archive-mode-map [menu-bar immediate view]
 643       '(menu-item "View This File" archive-view
 644                   :help "Display file at cursor in View Mode"))
 645     (define-key archive-mode-map [menu-bar immediate display]
 646       '(menu-item "Display in Other Window" archive-display-other-window
 647                   :help "Display file at cursor in another window"))
 648     (define-key archive-mode-map [menu-bar immediate find-file-other-window]
 649       '(menu-item "Find in Other Window" archive-extract-other-window
 650                   :help "Edit file at cursor in another window"))
 651     (define-key archive-mode-map [menu-bar immediate find-file]
 652       '(menu-item "Find This File" archive-extract
 653                   :help "Extract file at cursor and edit it"))
 654
 655     (define-key archive-mode-map [menu-bar mark]
 656       (cons "Mark" (make-sparse-keymap "Mark")))
 657     (define-key archive-mode-map [menu-bar mark unmark-all]
 658       '(menu-item "Unmark All" archive-unmark-all-files
 659                   :help "Unmark all marked files"))
 660     (define-key archive-mode-map [menu-bar mark deletion]
 661       '(menu-item "Flag" archive-flag-deleted
 662                   :help "Flag file at cursor for deletion"))
 663     (define-key archive-mode-map [menu-bar mark unmark]
 664       '(menu-item "Unflag" archive-unflag
 665                   :help "Unmark file at cursor"))
 666     (define-key archive-mode-map [menu-bar mark mark]
 667       '(menu-item "Mark" archive-mark
 668                   :help "Mark file at cursor"))
 669
 670     (define-key archive-mode-map [menu-bar operate]
 671       (cons "Operate" (make-sparse-keymap "Operate")))
 672     (define-key archive-mode-map [menu-bar operate chown]
 673       '(menu-item "Change Owner..." archive-chown-entry
 674                   :enable (fboundp (archive-name "chown-entry"))
 675                   :help "Change owner of marked files"))
 676     (define-key archive-mode-map [menu-bar operate chgrp]
 677       '(menu-item "Change Group..." archive-chgrp-entry
 678                   :enable (fboundp (archive-name "chgrp-entry"))
 679                   :help "Change group ownership of marked files"))
 680     (define-key archive-mode-map [menu-bar operate chmod]
 681       '(menu-item "Change Mode..." archive-chmod-entry
 682                   :enable (fboundp (archive-name "chmod-entry"))
 683                   :help "Change mode (permissions) of marked files"))
 684     (define-key archive-mode-map [menu-bar operate rename]
 685       '(menu-item "Rename to..." archive-rename-entry
 686                   :enable (fboundp (archive-name "rename-entry"))
 687                   :help "Rename marked files"))
 688     ;;(define-key archive-mode-map [menu-bar operate copy]
 689     ;;  '(menu-item "Copy to..." archive-copy))
 690     (define-key archive-mode-map [menu-bar operate expunge]
 691       '(menu-item "Expunge Marked Files" archive-expunge
 692                   :help "Delete all flagged files from archive"))
 693   ))
 694
 695 (let* ((item1 '(archive-subfile-mode " Archive"))
 696        (items (list item1)))
 697   (or (member item1 minor-mode-alist)
 698       (setq minor-mode-alist (append items minor-mode-alist))))
 699 ;; -------------------------------------------------------------------------
 700 (defun archive-find-type ()
 701   (widen)
 702   (goto-char (point-min))
 703   ;; The funny [] here make it unlikely that the .elc file will be treated
 704   ;; as an archive by other software.
 705   (let (case-fold-search)
 706     (cond ((looking-at "[P]K\003\004") 'zip)
 707           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 708           ((looking-at "....................[\334]\247\304\375") 'zoo)
 709           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 710                 (string-match "\\.[aA][rR][cC]$"
 711                               (or buffer-file-name (buffer-name))))
 712            'arc)
 713           (t (error "Buffer format not recognized")))))
 714 ;; -------------------------------------------------------------------------
 715 (defun archive-summarize (&optional shut-up)
 716   "Parse the contents of the archive file in the current buffer.
 717 Place a dired-like listing on the front;
 718 then narrow to it, so that only that listing
 719 is visible (and the real data of the buffer is hidden).
 720 Optional argument SHUT-UP, if non-nil, means don't print messages
 721 when parsing the archive."
 722   (widen)
 723   (set-buffer-multibyte nil)
 724   (let (buffer-read-only)
 725     (or shut-up
 726         (message "Parsing archive file..."))
 727     (buffer-disable-undo (current-buffer))
 728     (setq archive-files (funcall (archive-name "summarize")))
 729     (or shut-up
 730         (message "Parsing archive file...done."))
 731     (setq archive-proper-file-start (point-marker))
 732     (narrow-to-region (point-min) (point))
 733     (set-buffer-modified-p nil)
 734     (buffer-enable-undo))
 735   (goto-char archive-file-list-start)
 736   (archive-next-line 0))
 737
 738 (defun archive-resummarize ()
 739   "Recreate the contents listing of an archive."
 740   (let ((modified (buffer-modified-p))
 741         (no (archive-get-lineno))
 742         buffer-read-only)
 743     (widen)
 744     (delete-region (point-min) archive-proper-file-start)
 745     (archive-summarize t)
 746     (set-buffer-modified-p modified)
 747     (goto-char archive-file-list-start)
 748     (archive-next-line no)))
 749
 750 (defun archive-summarize-files (files)
 751   "Insert a description of a list of files annotated with proper mouse face."
 752   (setq archive-file-list-start (point-marker))
 753   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 754   ;; We don't want to do an insert for each element since that takes too
 755   ;; long when the archive -- which has to be moved in memory -- is large.
 756   (insert
 757    (apply
 758     (function concat)
 759     (mapcar
 760      (function
 761       (lambda (fil)
 762         ;; Using `concat' here copies the text also, so we can add
 763         ;; properties without problems.
 764         (let ((text (concat (aref fil 0) "\n")))
 765           (if archive-lemacs
 766               ()                        ; out of luck
 767             (add-text-properties
 768              (aref fil 1) (aref fil 2)
 769              '(mouse-face highlight
 770                help-echo "mouse-2: extract this file into a buffer")
 771              text))
 772           text)))
 773      files)))
 774   (setq archive-file-list-end (point-marker)))
 775
 776 (defun archive-alternate-display ()
 777   "Toggle alternative display.
 778 To avoid very long lines some archive mode don't show all information.
 779 This function changes the set of information shown for each files."
 780   (interactive)
 781   (setq archive-alternate-display (not archive-alternate-display))
 782   (archive-resummarize))
 783 ;; -------------------------------------------------------------------------
 784 ;; Section: Local archive copy handling
 785
 786 (defun archive-unique-fname (fname dir)
 787   "Make sure a file FNAME can be created uniquely in directory DIR.
 788
 789 If FNAME can be uniquely created in DIR, it is returned unaltered.
 790 If FNAME is something our underlying filesystem can't grok, or if another
 791 file by that name already exists in DIR, a unique new name is generated
 792 using `make-temp-file', and the generated name is returned."
 793   (let ((fullname (expand-file-name fname dir))
 794         (alien (string-match file-name-invalid-regexp fname)))
 795     (if (or alien (file-exists-p fullname))
 796         (make-temp-file
 797          (expand-file-name
 798           (if (if (fboundp 'msdos-long-file-names)
 799                   (not (msdos-long-file-names)))
 800               "am"
 801             "arc-mode.")
 802           dir))
 803       fullname)))
 804
 805 (defun archive-maybe-copy (archive)
 806   (let ((coding-system-for-write 'no-conversion))
 807     (if archive-remote
 808         (let ((start (point-max))
 809               ;; Sometimes ARCHIVE is invalid while its actual name, as
 810               ;; recorded in its parent archive, is not.  For example, an
 811               ;; archive bar.zip inside another archive foo.zip gets a name
 812               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 813               ;; So use the actual name if available.
 814               (archive-name
 815                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 816                    archive)))
 817           (make-directory archive-tmpdir t)
 818           ;; If ARCHIVE includes leading directories, make sure they
 819           ;; exist under archive-tmpdir.
 820           (let ((arch-dir (file-name-directory archive)))
 821             (if arch-dir
 822                 (make-directory (concat
 823                                  (file-name-as-directory archive-tmpdir)
 824                                  arch-dir)
 825                                 t)))
 826           (setq archive-local-name
 827                 (archive-unique-fname archive-name archive-tmpdir))
 828           (save-restriction
 829             (widen)
 830             (write-region start (point-max) archive-local-name nil 'nomessage))
 831           archive-local-name)
 832       (if (buffer-modified-p) (save-buffer))
 833       archive)))
 834
 835 (defun archive-maybe-update (unchanged)
 836   (if archive-remote
 837       (let ((name archive-local-name)
 838             (modified (buffer-modified-p))
 839             (coding-system-for-read 'no-conversion)
 840             (lno (archive-get-lineno))
 841             buffer-read-only)
 842         (if unchanged nil
 843           (setq archive-files nil)
 844           (erase-buffer)
 845           (insert-file-contents name)
 846           (archive-mode t)
 847           (goto-char archive-file-list-start)
 848           (archive-next-line lno))
 849         (archive-delete-local name)
 850         (if (not unchanged)
 851             (message
 852              "Buffer `%s' must be saved for changes to take effect"
 853              (buffer-name (current-buffer))))
 854         (set-buffer-modified-p (or modified (not unchanged))))))
 855
 856 (defun archive-delete-local (name)
 857   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 858   (let ((again t)
 859         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 860     (condition-case nil
 861         (delete-file name)
 862       (error nil))
 863     (while again
 864       (setq name (directory-file-name (file-name-directory name)))
 865       (condition-case nil
 866           (delete-directory name)
 867         (error nil))
 868       (if (string= name top) (setq again nil)))))
 869 ;; -------------------------------------------------------------------------
 870 ;; Section: Member extraction
 871
 872 (defun archive-file-name-handler (op &rest args)
 873   (or (eq op 'file-exists-p)
 874       (let ((file-name-handler-alist nil))
 875         (apply op args))))
 876
 877 (defun archive-set-buffer-as-visiting-file (filename)
 878   "Set the current buffer as if it were visiting FILENAME."
 879   (save-excursion
 880     (goto-char (point-min))
 881     (let ((coding
 882            (or coding-system-for-read
 883                (and set-auto-coding-function
 884                     (save-excursion
 885                       (funcall set-auto-coding-function
 886                                filename (- (point-max) (point-min)))))
 887                ;; dos-w32.el defines find-operation-coding-system for
 888                ;; DOS/Windows systems which preserves the coding-system
 889                ;; of existing files.  We want it to act here as if the
 890                ;; extracted file existed.
 891                (let ((file-name-handler-alist
 892                       '(("" . archive-file-name-handler))))
 893                  (car (find-operation-coding-system 'insert-file-contents
 894                                                     filename t))))))
 895       (if (and (not coding-system-for-read)
 896                (not enable-multibyte-characters))
 897           (setq coding
 898                 (coding-system-change-text-conversion coding 'raw-text)))
 899       (if (and coding
 900                (not (eq coding 'no-conversion)))
 901           (decode-coding-region (point-min) (point-max) coding)
 902         (setq last-coding-system-used coding))
 903       (set-buffer-modified-p nil)
 904       (kill-local-variable 'buffer-file-coding-system)
 905       (after-insert-file-set-coding (- (point-max) (point-min))))))
 906
 907 (defun archive-mouse-extract (event)
 908   "Extract a file whose name you click on."
 909   (interactive "e")
 910   (mouse-set-point event)
 911   (switch-to-buffer
 912    (save-excursion
 913      (archive-extract)
 914      (current-buffer))))
 915
 916 (defun archive-extract (&optional other-window-p)
 917   "In archive mode, extract this entry of the archive into its own buffer."
 918   (interactive)
 919   (let* ((view-p (eq other-window-p 'view))
 920          (descr (archive-get-descr))
 921          (ename (aref descr 0))
 922          (iname (aref descr 1))
 923          (archive-buffer (current-buffer))
 924          (arcdir default-directory)
 925          (archive (buffer-file-name))
 926          (arcname (file-name-nondirectory archive))
 927          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 928          (extractor (archive-name "extract"))
 929          ;; Members with file names which aren't valid for the
 930          ;; underlying filesystem, are treated as read-only.
 931          (read-only-p (or archive-read-only
 932                           view-p
 933                           (string-match file-name-invalid-regexp ename)))
 934          (buffer (get-buffer bufname))
 935          (just-created nil))
 936       (if buffer
 937           nil
 938         (setq archive (archive-maybe-copy archive))
 939         (setq buffer (get-buffer-create bufname))
 940         (setq just-created t)
 941         (save-excursion
 942           (set-buffer buffer)
 943           (setq buffer-file-name
 944                 (expand-file-name (concat arcname ":" iname)))
 945           (setq buffer-file-truename
 946                 (abbreviate-file-name buffer-file-name))
 947           ;; Set the default-directory to the dir of the superior buffer.
 948           (setq default-directory arcdir)
 949           (make-local-variable 'archive-superior-buffer)
 950           (setq archive-superior-buffer archive-buffer)
 951           (make-local-variable 'local-write-file-hooks)
 952           (add-hook 'local-write-file-hooks 'archive-write-file-member)
 953           (setq archive-subfile-mode descr)
 954           (if (and
 955                (null
 956                 (let (;; We may have to encode file name arguement for
 957                       ;; external programs.
 958                       (coding-system-for-write
 959                        (and enable-multibyte-characters
 960                             file-name-coding-system))
 961                       ;; We read an archive member by no-conversion at
 962                       ;; first, then decode appropriately by calling
 963                       ;; archive-set-buffer-as-visiting-file later.
 964                       (coding-system-for-read 'no-conversion))
 965                   (condition-case err
 966                       (if (fboundp extractor)
 967                           (funcall extractor archive ename)
 968                         (archive-*-extract archive ename
 969                                            (symbol-value extractor)))
 970                     (error
 971                      (ding (message "%s" (error-message-string err)))
 972                      nil))))
 973                just-created)
 974               (progn
 975                 (set-buffer-modified-p nil)
 976                 (kill-buffer buffer))
 977             (archive-set-buffer-as-visiting-file ename)
 978             (goto-char (point-min))
 979             (rename-buffer bufname)
 980             (setq buffer-read-only read-only-p)
 981             (setq buffer-undo-list nil)
 982             (set-buffer-modified-p nil)
 983             (setq buffer-saved-size (buffer-size))
 984             (normal-mode)
 985             ;; Just in case an archive occurs inside another archive.
 986             (if (eq major-mode 'archive-mode)
 987                 (progn
 988                   (setq archive-remote t)
 989                   (if read-only-p (setq archive-read-only t))
 990                   ;; We will write out the archive ourselves if it is
 991                   ;; part of another archive.
 992                   (remove-hook 'write-contents-hooks 'archive-write-file t)))
 993             (run-hooks 'archive-extract-hooks)
 994             (if archive-read-only
 995                 (message "Note: altering this archive is not implemented."))))
 996         (archive-maybe-update t))
 997       (or (not (buffer-name buffer))
 998           (progn
 999             (if view-p
1000                 (view-buffer buffer (and just-created 'kill-buffer))
1001               (if (eq other-window-p 'display)
1002                   (display-buffer buffer)
1003                 (if other-window-p
1004                     (switch-to-buffer-other-window buffer)
1005                   (switch-to-buffer buffer))))))))
1006
1007 (defun archive-*-extract (archive name command)
1008   (let* ((default-directory (file-name-as-directory archive-tmpdir))
1009          (tmpfile (expand-file-name (file-name-nondirectory name)
1010                                     default-directory))
1011          exit-status success)
1012     (make-directory (directory-file-name default-directory) t)
1013     (setq exit-status
1014           (apply 'call-process
1015                  (car command)
1016                  nil
1017                  nil
1018                  nil
1019                  (append (cdr command) (list archive name))))
1020     (cond ((and (numberp exit-status) (= exit-status 0))
1021            (if (not (file-exists-p tmpfile))
1022                (ding (message "`%s': no such file or directory" tmpfile))
1023              (insert-file-contents tmpfile)
1024              (setq success t)))
1025           ((numberp exit-status)
1026            (ding
1027             (message "`%s' exited with status %d" (car command) exit-status)))
1028           ((stringp exit-status)
1029            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1030           (t
1031            (ding (message "`%s' failed" (car command)))))
1032     (archive-delete-local tmpfile)
1033     success))
1034
1035 (defun archive-extract-by-stdout (archive name command)
1036   (apply 'call-process
1037          (car command)
1038          nil
1039          t
1040          nil
1041          (append (cdr command) (list archive name))))
1042
1043 (defun archive-extract-other-window ()
1044   "In archive mode, find this member in another window."
1045   (interactive)
1046   (archive-extract t))
1047
1048 (defun archive-display-other-window ()
1049   "In archive mode, display this member in another window."
1050   (interactive)
1051   (archive-extract 'display))
1052
1053 (defun archive-view ()
1054   "In archive mode, view the member on this line."
1055   (interactive)
1056   (archive-extract 'view))
1057
1058 (defun archive-add-new-member (arcbuf name)
1059   "Add current buffer to the archive in ARCBUF naming it NAME."
1060   (interactive
1061    (list (get-buffer
1062           (read-buffer "Buffer containing archive: "
1063                        ;; Find first archive buffer and suggest that
1064                        (let ((bufs (buffer-list)))
1065                          (while (and bufs (not (eq (save-excursion
1066                                                      (set-buffer (car bufs))
1067                                                      major-mode)
1068                                                    'archive-mode)))
1069                            (setq bufs (cdr bufs)))
1070                          (if bufs
1071                              (car bufs)
1072                            (error "There are no archive buffers")))
1073                        t))
1074          (read-string "File name in archive: "
1075                       (if buffer-file-name
1076                           (file-name-nondirectory buffer-file-name)
1077                         ""))))
1078   (save-excursion
1079     (set-buffer arcbuf)
1080     (or (eq major-mode 'archive-mode)
1081         (error "Buffer is not an archive buffer"))
1082     (if archive-read-only
1083         (error "Archive is read-only")))
1084   (if (eq arcbuf (current-buffer))
1085       (error "An archive buffer cannot be added to itself"))
1086   (if (string= name "")
1087       (error "Archive members may not be given empty names"))
1088   (let ((func (save-excursion (set-buffer arcbuf)
1089                               (archive-name "add-new-member")))
1090         (membuf (current-buffer)))
1091     (if (fboundp func)
1092         (save-excursion
1093           (set-buffer arcbuf)
1094           (funcall func buffer-file-name membuf name))
1095       (error "Adding a new member is not supported for this archive type"))))
1096 ;; -------------------------------------------------------------------------
1097 ;; Section: IO stuff
1098
1099 (defun archive-write-file-member ()
1100   (save-excursion
1101     (save-restriction
1102       (message "Updating archive...")
1103       (widen)
1104       (let ((writer  (save-excursion (set-buffer archive-superior-buffer)
1105                                      (archive-name "write-file-member")))
1106             (archive (save-excursion (set-buffer archive-superior-buffer)
1107                                      (archive-maybe-copy (buffer-file-name)))))
1108         (if (fboundp writer)
1109             (funcall writer archive archive-subfile-mode)
1110           (archive-*-write-file-member archive
1111                                        archive-subfile-mode
1112                                        (symbol-value writer)))
1113         (set-buffer-modified-p nil)
1114         (message "Updating archive...done"))
1115       (set-buffer archive-superior-buffer)
1116       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1117   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1118   ;; won't reset the coding-system of this archive member.
1119   (if (local-variable-p 'archive-member-coding-system)
1120       (setq last-coding-system-used archive-member-coding-system))
1121   t)
1122
1123 (defun archive-*-write-file-member (archive descr command)
1124   (let* ((ename (aref descr 0))
1125          (tmpfile (expand-file-name ename archive-tmpdir))
1126          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1127          (default-directory (file-name-as-directory top)))
1128     (unwind-protect
1129         (progn
1130           (make-directory (file-name-directory tmpfile) t)
1131           ;; If the member is itself an archive, write it without
1132           ;; the dired-like listing we created.
1133           (if (eq major-mode 'archive-mode)
1134               (archive-write-file tmpfile)
1135             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1136           ;; basic-save-buffer needs last-coding-system-used to have
1137           ;; the value used to write the file, so save it before any
1138           ;; further processing clobbers it (we restore it in
1139           ;; archive-write-file-member, above).
1140           (setq archive-member-coding-system last-coding-system-used)
1141           (if (aref descr 3)
1142               ;; Set the file modes, but make sure we can read it.
1143               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1144           (if enable-multibyte-characters
1145               (setq ename
1146                     (encode-coding-string ename file-name-coding-system)))
1147           (let ((exitcode (apply 'call-process
1148                                  (car command)
1149                                  nil
1150                                  nil
1151                                  nil
1152                                  (append (cdr command) (list archive ename)))))
1153             (if (equal exitcode 0)
1154                 nil
1155               (error "Updating was unsuccessful (%S)" exitcode))))
1156       (archive-delete-local tmpfile))))
1157
1158 (defun archive-write-file (&optional file)
1159   (save-excursion
1160     (let ((coding-system-for-write 'no-conversion))
1161       (write-region archive-proper-file-start (point-max)
1162                     (or file buffer-file-name) nil t)
1163       (set-buffer-modified-p nil))
1164     t))
1165 ;; -------------------------------------------------------------------------
1166 ;; Section: Marking and unmarking.
1167
1168 (defun archive-flag-deleted (p &optional type)
1169   "In archive mode, mark this member to be deleted from the archive.
1170 With a prefix argument, mark that many files."
1171   (interactive "p")
1172   (or type (setq type ?D))
1173   (beginning-of-line)
1174   (let ((sign (if (>= p 0) +1 -1))
1175         (modified (buffer-modified-p))
1176         buffer-read-only)
1177     (while (not (zerop p))
1178       (if (archive-get-descr t)
1179           (progn
1180             (delete-char 1)
1181             (insert type)))
1182       (forward-line sign)
1183       (setq p (- p sign)))
1184     (set-buffer-modified-p modified))
1185   (archive-next-line 0))
1186
1187 (defun archive-unflag (p)
1188   "In archive mode, un-mark this member if it is marked to be deleted.
1189 With a prefix argument, un-mark that many files forward."
1190   (interactive "p")
1191   (archive-flag-deleted p ? ))
1192
1193 (defun archive-unflag-backwards (p)
1194   "In archive mode, un-mark this member if it is marked to be deleted.
1195 With a prefix argument, un-mark that many members backward."
1196   (interactive "p")
1197   (archive-flag-deleted (- p) ? ))
1198
1199 (defun archive-unmark-all-files ()
1200   "Remove all marks."
1201   (interactive)
1202   (let ((modified (buffer-modified-p))
1203         buffer-read-only)
1204     (save-excursion
1205       (goto-char archive-file-list-start)
1206       (while (< (point) archive-file-list-end)
1207         (or (= (following-char) ? )
1208             (progn (delete-char 1) (insert ? )))
1209         (forward-line 1)))
1210     (set-buffer-modified-p modified)))
1211
1212 (defun archive-mark (p)
1213   "In archive mode, mark this member for group operations.
1214 With a prefix argument, mark that many members.
1215 Use \\[archive-unmark-all-files] to remove all marks."
1216   (interactive "p")
1217   (archive-flag-deleted p ?*))
1218
1219 (defun archive-get-marked (mark &optional default)
1220   (let (files)
1221     (save-excursion
1222       (goto-char archive-file-list-start)
1223       (while (< (point) archive-file-list-end)
1224         (if (= (following-char) mark)
1225             (setq files (cons (archive-get-descr) files)))
1226         (forward-line 1)))
1227     (or (nreverse files)
1228         (and default
1229              (list (archive-get-descr))))))
1230 ;; -------------------------------------------------------------------------
1231 ;; Section: Operate
1232
1233 (defun archive-next-line (p)
1234   (interactive "p")
1235   (forward-line p)
1236   (or (eobp)
1237       (forward-char archive-file-name-indent)))
1238
1239 (defun archive-previous-line (p)
1240   (interactive "p")
1241   (archive-next-line (- p)))
1242
1243 (defun archive-chmod-entry (new-mode)
1244   "Change the protection bits associated with all marked or this member.
1245 The new protection bits can either be specified as an octal number or
1246 as a relative change like \"g+rw\" as for chmod(2)"
1247   (interactive "sNew mode (octal or relative): ")
1248   (if archive-read-only (error "Archive is read-only"))
1249   (let ((func (archive-name "chmod-entry")))
1250     (if (fboundp func)
1251         (progn
1252           (funcall func new-mode (archive-get-marked ?* t))
1253           (archive-resummarize))
1254       (error "Setting mode bits is not supported for this archive type"))))
1255
1256 (defun archive-chown-entry (new-uid)
1257   "Change the owner of all marked or this member."
1258   (interactive "nNew uid: ")
1259   (if archive-read-only (error "Archive is read-only"))
1260   (let ((func (archive-name "chown-entry")))
1261     (if (fboundp func)
1262         (progn
1263           (funcall func new-uid (archive-get-marked ?* t))
1264           (archive-resummarize))
1265       (error "Setting owner is not supported for this archive type"))))
1266
1267 (defun archive-chgrp-entry (new-gid)
1268   "Change the group of all marked or this member."
1269   (interactive "nNew gid: ")
1270   (if archive-read-only (error "Archive is read-only"))
1271   (let ((func (archive-name "chgrp-entry")))
1272     (if (fboundp func)
1273         (progn
1274           (funcall func new-gid (archive-get-marked ?* t))
1275           (archive-resummarize))
1276       (error "Setting group is not supported for this archive type"))))
1277
1278 (defun archive-expunge ()
1279   "Do the flagged deletions."
1280   (interactive)
1281   (let (files)
1282     (save-excursion
1283       (goto-char archive-file-list-start)
1284       (while (< (point) archive-file-list-end)
1285         (if (= (following-char) ?D)
1286             (setq files (cons (aref (archive-get-descr) 0) files)))
1287         (forward-line 1)))
1288     (setq files (nreverse files))
1289     (and files
1290          (or (not archive-read-only)
1291              (error "Archive is read-only"))
1292          (or (yes-or-no-p (format "Really delete %d member%s? "
1293                                   (length files)
1294                                   (if (null (cdr files)) "" "s")))
1295              (error "Operation aborted"))
1296          (let ((archive (archive-maybe-copy (buffer-file-name)))
1297                (expunger (archive-name "expunge")))
1298            (if (fboundp expunger)
1299                (funcall expunger archive files)
1300              (archive-*-expunge archive files (symbol-value expunger)))
1301            (archive-maybe-update nil)
1302            (if archive-remote
1303                (archive-resummarize)
1304              (revert-buffer))))))
1305
1306 (defun archive-*-expunge (archive files command)
1307   (apply 'call-process
1308          (car command)
1309          nil
1310          nil
1311          nil
1312          (append (cdr command) (cons archive files))))
1313
1314 (defun archive-rename-entry (newname)
1315   "Change the name associated with this entry in the tar file."
1316   (interactive "sNew name: ")
1317   (if archive-read-only (error "Archive is read-only"))
1318   (if (string= newname "")
1319       (error "Archive members may not be given empty names"))
1320   (let ((func (archive-name "rename-entry"))
1321         (descr (archive-get-descr)))
1322     (if (fboundp func)
1323         (progn
1324           (funcall func (buffer-file-name)
1325                    (if enable-multibyte-characters
1326                        (encode-coding-string newname file-name-coding-system)
1327                      newname)
1328                    descr)
1329           (archive-resummarize))
1330       (error "Renaming is not supported for this archive type"))))
1331
1332 ;; Revert the buffer and recompute the dired-like listing.
1333 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1334   (let ((no (archive-get-lineno)))
1335     (setq archive-files nil)
1336     (let ((revert-buffer-function nil)
1337           (coding-system-for-read 'no-conversion))
1338       (set-buffer-multibyte nil)
1339       (revert-buffer t t))
1340     (archive-mode)
1341     (goto-char archive-file-list-start)
1342     (archive-next-line no)))
1343
1344 (defun archive-undo ()
1345   "Undo in an archive buffer.
1346 This doesn't recover lost files, it just undoes changes in the buffer itself."
1347   (interactive)
1348   (let (buffer-read-only)
1349     (undo)))
1350 ;; -------------------------------------------------------------------------
1351 ;; Section: Arc Archives
1352
1353 (defun archive-arc-summarize ()
1354   (let ((p 1)
1355         (totalsize 0)
1356         (maxlen 8)
1357         files
1358         visual)
1359     (while (and (< (+ p 29) (point-max))
1360                 (= (char-after p) ?\C-z)
1361                 (> (char-after (1+ p)) 0))
1362       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1363              (fnlen   (or (string-match "\0" namefld) 13))
1364              (efnname (substring namefld 0 fnlen))
1365              (csize   (archive-l-e (+ p 15) 4))
1366              (moddate (archive-l-e (+ p 19) 2))
1367              (modtime (archive-l-e (+ p 21) 2))
1368              (ucsize  (archive-l-e (+ p 25) 4))
1369              (fiddle  (string= efnname (upcase efnname)))
1370              (ifnname (if fiddle (downcase efnname) efnname))
1371              (text    (format "  %8d  %-11s  %-8s  %s"
1372                               ucsize
1373                               (archive-dosdate moddate)
1374                               (archive-dostime modtime)
1375                               ifnname)))
1376         (setq maxlen (max maxlen fnlen)
1377               totalsize (+ totalsize ucsize)
1378               visual (cons (vector text
1379                                    (- (length text) (length ifnname))
1380                                    (length text))
1381                            visual)
1382               files (cons (vector efnname ifnname fiddle nil (1- p))
1383                           files)
1384               p (+ p 29 csize))))
1385     (goto-char (point-min))
1386     (let ((dash (concat "- --------  -----------  --------  "
1387                         (make-string maxlen ?-)
1388                         "\n")))
1389       (insert "M   Length  Date         Time      File\n"
1390               dash)
1391       (archive-summarize-files (nreverse visual))
1392       (insert dash
1393               (format "  %8d                         %d file%s"
1394                       totalsize
1395                       (length files)
1396                       (if (= 1 (length files)) "" "s"))
1397               "\n"))
1398     (apply 'vector (nreverse files))))
1399
1400 (defun archive-arc-rename-entry (archive newname descr)
1401   (if (string-match "[:\\\\/]" newname)
1402       (error "File names in arc files must not contain a directory component"))
1403   (if (> (length newname) 12)
1404       (error "File names in arc files are limited to 12 characters"))
1405   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1406                                          (length newname))))
1407         buffer-read-only)
1408     (save-restriction
1409       (save-excursion
1410         (widen)
1411         (set-buffer-multibyte nil)
1412         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1413         (delete-char 13)
1414         (insert name)))))
1415 ;; -------------------------------------------------------------------------
1416 ;; Section: Lzh Archives
1417
1418 (defun archive-lzh-summarize ()
1419   (let ((p 1)
1420         (totalsize 0)
1421         (maxlen 8)
1422         files
1423         visual)
1424     (while (progn (goto-char p)         ;beginning of a base header.
1425                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1426       (let* ((hsize   (char-after p))   ;size of the base header (level 0 and 1)
1427              (csize   (archive-l-e (+ p 7) 4)) ;size of a compressed file to follow (level 0 and 2),
1428                                         ;size of extended headers + the compressed file to follow (level 1).
1429              (ucsize  (archive-l-e (+ p 11) 4)) ;size of an uncompressed file.
1430              (time1   (archive-l-e (+ p 15) 2)) ;date/time (MSDOS format in level 0, 1 headers
1431              (time2   (archive-l-e (+ p 17) 2)) ;and UNIX format in level 2 header.)
1432              (hdrlvl  (char-after (+ p 20))) ;header level
1433              thsize             ;total header size (base + extensions)
1434              fnlen efnname fiddle ifnname width p2 creator
1435              neh        ;beginning of next extension header (level 1 and 2)
1436              mode modestr uid gid text dir prname
1437              gname uname modtime moddate)
1438         (if (= hdrlvl 3) (error "can't handle lzh level 3 header type"))
1439         (when (or (= hdrlvl 0) (= hdrlvl 1))
1440           (setq fnlen   (char-after (+ p 21))) ;filename length
1441           (setq efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen)))) ;filename from offset 22
1442                         (if file-name-coding-system
1443                             (decode-coding-string str file-name-coding-system)
1444                           (string-as-multibyte str))))
1445           (setq p2      (+ p 22 fnlen))) ;
1446         (if (= hdrlvl 1)
1447             (progn              ;specific to level 1 header
1448               (setq creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1449               (setq neh (+ p2 3)))
1450           (if (= hdrlvl 2)
1451               (progn            ;specific to level 2 header
1452                 (setq creator (char-after (+ p 23)) )
1453                 (setq neh (+ p 24)))))
1454         (if neh         ;if level 1 or 2 we expect extension headers to follow
1455             (let* ((ehsize (archive-l-e neh 2)) ;size of the extension header
1456                    (etype (char-after (+ neh 2)))) ;extension type
1457               (while (not (= ehsize 0))
1458                   (cond
1459                  ((= etype 1)   ;file name
1460                   (let ((i (+ neh 3)))
1461                     (while (< i (+ neh ehsize))
1462                       (setq efnname (concat efnname (char-to-string (char-after i))))
1463                       (setq i (1+ i)))))
1464                  ((= etype 2)   ;directory name
1465                   (let ((i (+ neh 3)))
1466                     (while (< i (+ neh ehsize))
1467                                     (setq dir (concat dir
1468                                                        (if (= (char-after i)
1469                                                               255)
1470                                                            "/"
1471                                                          (char-to-string
1472                                                           (char-after i)))))
1473                                     (setq i (1+ i)))))
1474                  ((= etype 80)          ;Unix file permission
1475                   (setq mode (archive-l-e (+ neh 3) 2)))
1476                  ((= etype 81)          ;UNIX file group/user ID
1477                   (progn (setq uid (archive-l-e (+ neh 3) 2))
1478                          (setq gid (archive-l-e (+ neh 5) 2))))
1479                  ((= etype 82)          ;UNIX file group name
1480                   (let ((i (+ neh 3)))
1481                     (while (< i (+ neh ehsize))
1482                       (setq gname (concat gname (char-to-string (char-after i))))
1483                       (setq i (1+ i)))))
1484                  ((= etype 83)          ;UNIX file user name
1485                   (let ((i (+ neh 3)))
1486                     (while (< i (+ neh ehsize))
1487                       (setq uname (concat uname (char-to-string (char-after i))))
1488                       (setq i (1+ i)))))
1489                    )
1490                 (setq neh (+ neh ehsize))
1491                 (setq ehsize (archive-l-e neh 2))
1492                 (setq etype (char-after (+ neh 2))))
1493               ;;get total header size for level 1 and 2 headers
1494               (setq thsize (- neh p))))
1495         (if (= hdrlvl 0)  ;total header size
1496             (setq thsize hsize))
1497         (setq fiddle  (if efnname (string= efnname (upcase efnname))))
1498         (setq ifnname (if fiddle (downcase efnname) efnname))
1499         (setq prname (if dir (concat dir ifnname) ifnname))
1500         (setq width (if prname (string-width prname) 0))
1501         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1502         (setq moddate (if (= hdrlvl 2)
1503                           (archive-unixdate time1 time2) ;level 2 header in UNIX format
1504                         (archive-dosdate time2))) ;level 0 and 1 header in DOS format
1505         (setq modtime (if (= hdrlvl 2)
1506                           (archive-unixtime time1 time2)
1507                         (archive-dostime time1)))
1508         (setq text    (if archive-alternate-display
1509                           (format "  %8d  %5S  %5S  %s"
1510                                   ucsize
1511                                   (or uid "?")
1512                                   (or gid "?")
1513                                   ifnname)
1514                         (format "  %10s  %8d  %-11s  %-8s  %s"
1515                                 modestr
1516                                 ucsize
1517                                 moddate
1518                                 modtime
1519                                 prname)))
1520         (setq maxlen (max maxlen width)
1521               totalsize (+ totalsize ucsize)
1522               visual (cons (vector text
1523                                    (- (length text) (length prname))
1524                                    (length text))
1525                            visual)
1526               files (cons (vector prname ifnname fiddle mode (1- p))
1527                           files))
1528         (cond ((= hdrlvl 1)
1529                (setq p (+ p hsize 2 csize)))
1530               ((or (= hdrlvl 2) (= hdrlvl 0))
1531                (setq p (+ p thsize 2 csize))))
1532         ))
1533     (goto-char (point-min))
1534     (set-buffer-multibyte default-enable-multibyte-characters)
1535     (let ((dash (concat (if archive-alternate-display
1536                             "- --------  -----  -----  "
1537                           "- ----------  --------  -----------  --------  ")
1538                         (make-string maxlen ?-)
1539                         "\n"))
1540           (header (if archive-alternate-display
1541                        "M   Length    Uid    Gid  File\n"
1542                     "M   Filemode    Length  Date         Time      File\n"))
1543           (sumline (if archive-alternate-display
1544                        "  %8d                %d file%s"
1545                      "              %8d                         %d file%s")))
1546       (insert header dash)
1547       (archive-summarize-files (nreverse visual))
1548       (insert dash
1549               (format sumline
1550                       totalsize
1551                       (length files)
1552                       (if (= 1 (length files)) "" "s"))
1553               "\n"))
1554     (apply 'vector (nreverse files))))
1555
1556 (defconst archive-lzh-alternate-display t)
1557
1558 (defun archive-lzh-extract (archive name)
1559   (archive-extract-by-stdout archive name archive-lzh-extract))
1560
1561 (defun archive-lzh-resum (p count)
1562   (let ((sum 0))
1563     (while (> count 0)
1564       (setq count (1- count)
1565             sum (+ sum (char-after p))
1566             p (1+ p)))
1567     (logand sum 255)))
1568
1569 (defun archive-lzh-rename-entry (archive newname descr)
1570   (save-restriction
1571     (save-excursion
1572       (widen)
1573       (set-buffer-multibyte nil)
1574       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1575              (oldhsize (char-after p))
1576              (oldfnlen (char-after (+ p 21)))
1577              (newfnlen (length newname))
1578              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1579              buffer-read-only)
1580         (if (> newhsize 255)
1581             (error "The file name is too long"))
1582         (goto-char (+ p 21))
1583         (delete-char (1+ oldfnlen))
1584         (insert newfnlen newname)
1585         (goto-char p)
1586         (delete-char 2)
1587         (insert newhsize (archive-lzh-resum p newhsize))))))
1588
1589 (defun archive-lzh-ogm (newval files errtxt ofs)
1590   (save-restriction
1591     (save-excursion
1592       (widen)
1593       (set-buffer-multibyte nil)
1594       (while files
1595         (let* ((fil (car files))
1596                (p (+ archive-proper-file-start (aref fil 4)))
1597                (hsize   (char-after p))
1598                (fnlen   (char-after (+ p 21)))
1599                (p2      (+ p 22 fnlen))
1600                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1601                buffer-read-only)
1602           (if (= creator ?U)
1603               (progn
1604                 (or (numberp newval)
1605                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1606                 (goto-char (+ p2 ofs))
1607                 (delete-char 2)
1608                 (insert (logand newval 255) (lsh newval -8))
1609                 (goto-char (1+ p))
1610                 (delete-char 1)
1611                 (insert (archive-lzh-resum (1+ p) hsize)))
1612             (message "Member %s does not have %s field"
1613                      (aref fil 1) errtxt)))
1614         (setq files (cdr files))))))
1615
1616 (defun archive-lzh-chown-entry (newuid files)
1617   (archive-lzh-ogm newuid files "an uid" 10))
1618
1619 (defun archive-lzh-chgrp-entry (newgid files)
1620   (archive-lzh-ogm newgid files "a gid" 12))
1621
1622 (defun archive-lzh-chmod-entry (newmode files)
1623   (archive-lzh-ogm
1624    ;; This should work even though newmode will be dynamically accessed.
1625    (function (lambda (old) (archive-calc-mode old newmode t)))
1626    files "a unix-style mode" 8))
1627 ;; -------------------------------------------------------------------------
1628 ;; Section: Zip Archives
1629
1630 (defun archive-zip-summarize ()
1631   (goto-char (- (point-max) (- 22 18)))
1632   (search-backward-regexp "[P]K\005\006")
1633   (let ((p (+ (point-min) (archive-l-e (+ (point) 16) 4)))
1634         (maxlen 8)
1635         (totalsize 0)
1636         files
1637         visual)
1638     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1639       (let* ((creator (char-after (+ p 5)))
1640              (method  (archive-l-e (+ p 10) 2))
1641              (modtime (archive-l-e (+ p 12) 2))
1642              (moddate (archive-l-e (+ p 14) 2))
1643              (ucsize  (archive-l-e (+ p 24) 4))
1644              (fnlen   (archive-l-e (+ p 28) 2))
1645              (exlen   (archive-l-e (+ p 30) 2))
1646              (fclen   (archive-l-e (+ p 32) 2))
1647              (lheader (archive-l-e (+ p 42) 4))
1648              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1649                         (if file-name-coding-system
1650                             (decode-coding-string str file-name-coding-system)
1651                           (string-as-multibyte str))))
1652              (isdir   (and (= ucsize 0)
1653                            (string= (file-name-nondirectory efnname) "")))
1654              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1655                              (archive-l-e (+ p 40) 2))
1656                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1657                              (logior ?\444
1658                                      (if isdir (logior 16384 ?\111) 0)
1659                                      (if (zerop
1660                                           (logand 1 (char-after (+ p 38))))
1661                                          ?\222 0)))
1662                             (t nil)))
1663              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1664              (fiddle  (and archive-zip-case-fiddle
1665                            (not (not (memq creator '(0 2 4 5 9))))
1666                            (string= (upcase efnname) efnname)))
1667              (ifnname (if fiddle (downcase efnname) efnname))
1668              (width (string-width ifnname))
1669              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1670                               modestr
1671                               ucsize
1672                               (archive-dosdate moddate)
1673                               (archive-dostime modtime)
1674                               ifnname)))
1675         (setq maxlen (max maxlen width)
1676               totalsize (+ totalsize ucsize)
1677               visual (cons (vector text
1678                                    (- (length text) (length ifnname))
1679                                    (length text))
1680                            visual)
1681               files (cons (if isdir
1682                               nil
1683                             (vector efnname ifnname fiddle mode
1684                                     (list (1- p) lheader)))
1685                           files)
1686               p (+ p 46 fnlen exlen fclen))))
1687     (goto-char (point-min))
1688     (let ((dash (concat "- ----------  --------  -----------  --------  "
1689                         (make-string maxlen ?-)
1690                         "\n")))
1691       (insert "M Filemode      Length  Date         Time      File\n"
1692               dash)
1693       (archive-summarize-files (nreverse visual))
1694       (insert dash
1695               (format "              %8d                         %d file%s"
1696                       totalsize
1697                       (length files)
1698                       (if (= 1 (length files)) "" "s"))
1699               "\n"))
1700     (apply 'vector (nreverse files))))
1701
1702 (defun archive-zip-extract (archive name)
1703   (if (equal (car archive-zip-extract) "pkzip")
1704       (archive-*-extract archive name archive-zip-extract)
1705     (archive-extract-by-stdout archive name archive-zip-extract)))
1706
1707 (defun archive-zip-write-file-member (archive descr)
1708   (archive-*-write-file-member
1709    archive
1710    descr
1711    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1712
1713 (defun archive-zip-chmod-entry (newmode files)
1714   (save-restriction
1715     (save-excursion
1716       (widen)
1717       (set-buffer-multibyte nil)
1718       (while files
1719         (let* ((fil (car files))
1720                (p (+ archive-proper-file-start (car (aref fil 4))))
1721                (creator (char-after (+ p 5)))
1722                (oldmode (aref fil 3))
1723                (newval  (archive-calc-mode oldmode newmode t))
1724                buffer-read-only)
1725           (cond ((memq creator '(2 3)) ; Unix + VMS
1726                  (goto-char (+ p 40))
1727                  (delete-char 2)
1728                  (insert (logand newval 255) (lsh newval -8)))
1729                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1730                  (goto-char (+ p 38))
1731                  (insert (logior (logand (char-after (point)) 254)
1732                                  (logand (logxor 1 (lsh newval -7)) 1)))
1733                  (delete-char 1))
1734                 (t (message "Don't know how to change mode for this member"))))
1735         (setq files (cdr files))))))
1736 ;; -------------------------------------------------------------------------
1737 ;; Section: Zoo Archives
1738
1739 (defun archive-zoo-summarize ()
1740   (let ((p (1+ (archive-l-e 25 4)))
1741         (maxlen 8)
1742         (totalsize 0)
1743         files
1744         visual)
1745     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1746                 (> (archive-l-e (+ p 6) 4) 0))
1747       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1748              (moddate (archive-l-e (+ p 14) 2))
1749              (modtime (archive-l-e (+ p 16) 2))
1750              (ucsize  (archive-l-e (+ p 20) 4))
1751              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1752              (dirtype (char-after (+ p 4)))
1753              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1754              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1755              (fnlen   (or (string-match "\0" namefld) 13))
1756              (efnname (let ((str
1757                              (concat
1758                               (if (> ldirlen 0)
1759                                   (concat (buffer-substring
1760                                            (+ p 58 lfnlen)
1761                                            (+ p 58 lfnlen ldirlen -1))
1762                                           "/")
1763                                 "")
1764                               (if (> lfnlen 0)
1765                                   (buffer-substring (+ p 58)
1766                                                     (+ p 58 lfnlen -1))
1767                                 (substring namefld 0 fnlen)))))
1768                         (if file-name-coding-system
1769                             (decode-coding-string str file-name-coding-system)
1770                           (string-as-multibyte str))))
1771              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1772              (ifnname (if fiddle (downcase efnname) efnname))
1773              (width (string-width ifnname))
1774              (text    (format "  %8d  %-11s  %-8s  %s"
1775                               ucsize
1776                               (archive-dosdate moddate)
1777                               (archive-dostime modtime)
1778                               ifnname)))
1779         (setq maxlen (max maxlen width)
1780               totalsize (+ totalsize ucsize)
1781               visual (cons (vector text
1782                                    (- (length text) (length ifnname))
1783                                    (length text))
1784                            visual)
1785               files (cons (vector efnname ifnname fiddle nil (1- p))
1786                           files)
1787               p next)))
1788     (goto-char (point-min))
1789     (let ((dash (concat "- --------  -----------  --------  "
1790                         (make-string maxlen ?-)
1791                         "\n")))
1792       (insert "M   Length  Date         Time      File\n"
1793               dash)
1794       (archive-summarize-files (nreverse visual))
1795       (insert dash
1796               (format "  %8d                         %d file%s"
1797                       totalsize
1798                       (length files)
1799                       (if (= 1 (length files)) "" "s"))
1800               "\n"))
1801     (apply 'vector (nreverse files))))
1802
1803 (defun archive-zoo-extract (archive name)
1804   (archive-extract-by-stdout archive name archive-zoo-extract))
1805 ;; -------------------------------------------------------------------------
1806 ;; This line was a mistake; it is kept now for compatibility.
1807 ;; rms  15 Oct 98
1808 (provide 'archive-mode)
1809
1810 (provide 'arc-mode)
1811
1812 ;;; arch-tag: e5966a01-35ec-4f27-8095-a043a79b457b
1813 ;;; arc-mode.el ends here