lisp/net/zeroconf.el

   1 ;;; zeroconf.el --- Service browser using Avahi.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2008-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6 ;; Keywords: comm, hardware
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package provides an interface to the Avahi, the zeroconf
  26 ;; daemon under GNU/Linux.  The communication mean with Avahi is
  27 ;; D-Bus.
  28
  29 ;; In order to activate this package, you must add the following code
  30 ;; into your .emacs:
  31
  32 ;;   (require 'zeroconf)
  33 ;;   (zeroconf-init "dns-sd.org")
  34
  35 ;; "dns-sd.org" is an example the domain you wish to resolve services
  36 ;; for.  It can also be nil or "", which means the default local
  37 ;; domain "local".
  38
  39 ;; The `zeroconf-init' function installs several handlers, which are
  40 ;; activated by D-Bus signals sent from the Avahi daemon.
  41 ;; Immediately, when a service is added or removed in the domain, a
  42 ;; corresponding handler in Emacs is called.
  43
  44 ;; Service Discovery
  45 ;; -----------------
  46
  47 ;; The main purpose of zeroconf is service discovery.  This means,
  48 ;; that services are detected as soon as they appear or disappear in a
  49 ;; given domain.  A service is offered by a network device.  It is
  50 ;; assigned to a service type.
  51
  52 ;; In order to see all offered service types of the initialized
  53 ;; domain, you can call
  54
  55 ;;   (zeroconf-list-service-types)
  56
  57 ;; Service types are described at <http://www.dns-sd.org/ServiceTypes.html>.
  58 ;; Detected services for a given service type, let's say "_ipp._tcp",
  59 ;; are listed by
  60
  61 ;;   (zeroconf-list-services "_ipp._tcp")
  62
  63 ;; It is possible to register an own handler (function) to be called
  64 ;; when a service has been added or removed in the domain.  The
  65 ;; service type "_ipp._tcp" is used for printer services supporting
  66 ;; the Internet Printing Protocol.
  67
  68 ;;   (defun my-add-printer (service)
  69 ;;     (message "Printer `%s' detected" (zeroconf-service-name service)))
  70
  71 ;;   (defun my-remove-printer (service)
  72 ;;     (message "Printer `%s' removed" (zeroconf-service-name service)))
  73
  74 ;;   (zeroconf-service-add-hook "_ipp._tcp" :new     'my-add-printer)
  75 ;;   (zeroconf-service-add-hook "_ipp._tcp" :removed 'my-remove-printer)
  76
  77 ;; There are several functions returning information about a service,
  78 ;; see the doc string of `zeroconf-service-add-hook'.
  79
  80 ;; Service Publishing
  81 ;; ------------------
  82
  83 ;; The function `zeroconf-publish-service' publishes a new service to
  84 ;; the Avahi daemon.  Although the domain, where to the service is
  85 ;; published, can be specified by this function, it is usually the
  86 ;; default domain "local" (also written as nil or "").
  87
  88 ;;   (zeroconf-publish-service
  89 ;;    "Example service" ;; Service name.
  90 ;;    "_example._tcp"   ;; Service type.
  91 ;;    nil               ;; Default domain ("local").
  92 ;;    nil               ;; Default host (concat (getenv "HOST") ".local").
  93 ;;    111               ;; Port number of the host, the service is offered.
  94 ;;    "1.2.3.4"         ;; IPv4 address of the host.
  95 ;;    '("version=1.0"   ;; TXT fields describing the service.
  96 ;;      "abc=456"))
  97
  98 ;; The lifetime of a published service is the lifetime of Emacs.
  99
 100 ;;; Code:
 101
 102 (eval-when-compile (require 'cl-lib))
 103
 104 (require 'dbus)
 105
 106 (defvar zeroconf-debug nil
 107   "Write messages during service discovery")
 108
 109 (defconst zeroconf-service-avahi "org.freedesktop.Avahi"
 110   "The D-Bus name used to talk to Avahi.")
 111
 112 (defconst zeroconf-path-avahi "/"
 113   "The D-Bus root object path used to talk to Avahi.")
 114
 115 (defvar zeroconf-path-avahi-service-type-browser nil
 116   "The D-Bus object path used to talk to the Avahi service type browser.")
 117
 118 (defvar zeroconf-path-avahi-service-browser-hash (make-hash-table :test 'equal)
 119   "The D-Bus object paths used to talk to the Avahi service browser.")
 120
 121 (defvar zeroconf-path-avahi-service-resolver-hash (make-hash-table :test 'equal)
 122   "The D-Bus object paths used to talk to the Avahi service resolver.")
 123
 124 ;; Methods: "Free", "Commit", "Reset", "GetState", "IsEmpty",
 125 ;; "AddService", "AddServiceSubtype", "UpdateServiceTxt", "AddAddress"
 126 ;; and "AddRecord".
 127 ;; Signals: "StateChanged".
 128 (defconst zeroconf-interface-avahi-entry-group
 129   (concat zeroconf-service-avahi ".EntryGroup")
 130   "The D-Bus entry group interface exported by Avahi.")
 131
 132 ;; Methods: "GetVersionString", "GetAPIVersion", "GetHostName",
 133 ;; "SetHostName", "GetHostNameFqdn", "GetDomainName",
 134 ;; "IsNSSSupportAvailable", "GetState", "GetLocalServiceCookie",
 135 ;; "GetAlternativeHostName", "GetAlternativeServiceName",
 136 ;; "GetNetworkInterfaceNameByIndex", "GetNetworkInterfaceIndexByName",
 137 ;; "ResolveHostName", "ResolveAddress", "ResolveService",
 138 ;; "EntryGroupNew", "DomainBrowserNew", "ServiceTypeBrowserNew",
 139 ;; "ServiceBrowserNew", "ServiceResolverNew", "HostNameResolverNew",
 140 ;; "AddressResolverNew" and "RecordBrowserNew".
 141 ;; Signals: "StateChanged".
 142 (defconst zeroconf-interface-avahi-server
 143   (concat zeroconf-service-avahi ".Server")
 144   "The D-Bus server interface exported by Avahi.")
 145
 146 ;; Methods: "Free".
 147 ;; Signals: "ItemNew", "ItemRemove", "CacheExhausted", "AllForNow" and
 148 ;; "Failure".
 149 (defconst zeroconf-interface-avahi-service-type-browser
 150   (concat zeroconf-service-avahi ".ServiceTypeBrowser")
 151   "The D-Bus service type browser interface exported by Avahi.")
 152
 153 ;; Methods: "Free".
 154 ;; Signals: "ItemNew", "ItemRemove", "CacheExhausted", "AllForNow" and
 155 ;; "Failure".
 156 (defconst zeroconf-interface-avahi-service-browser
 157   (concat zeroconf-service-avahi ".ServiceBrowser")
 158   "The D-Bus service browser interface exported by Avahi.")
 159
 160 ;; Methods: "Free".
 161 ;; Available signals are "Found" and "Failure".
 162 (defconst zeroconf-interface-avahi-service-resolver
 163   (concat zeroconf-service-avahi ".ServiceResolver")
 164   "The D-Bus service resolver interface exported by Avahi.")
 165
 166 (defconst zeroconf-avahi-interface-unspec -1
 167   "Wildcard Avahi interface spec.")
 168
 169 (defconst zeroconf-avahi-protocol-unspec -1
 170   "Wildcard Avahi protocol spec.")
 171
 172 (defconst zeroconf-avahi-protocol-inet4 0
 173   "Avahi INET4 address protocol family.")
 174
 175 (defconst zeroconf-avahi-protocol-inet6 1
 176   "Avahi INET6 address protocol family.")
 177
 178 (defconst zeroconf-avahi-domain-unspec ""
 179   "Empty Avahi domain.")
 180
 181 (defvar zeroconf-avahi-current-domain zeroconf-avahi-domain-unspec
 182   "Domain name services are resolved for.")
 183
 184 (defconst zeroconf-avahi-flags-unspec 0
 185   "No Avahi flags.")
 186
 187 \f
 188 ;;; Services retrieval.
 189
 190 (defvar zeroconf-services-hash (make-hash-table :test 'equal)
 191   "Hash table of discovered Avahi services.
 192
 193 The key of an entry is the concatenation of the service name and
 194 service type of a discovered service.  The value is the service
 195 itself.  The format of a service is
 196
 197   \(INTERFACE PROTOCOL NAME TYPE DOMAIN FLAGS)
 198
 199 The INTERFACE is a number, which represents the network interface
 200 the service is located at.  The corresponding network interface
 201 name, like \"eth0\", can be retrieved with the function
 202 `zeroconf-get-interface-name'.
 203
 204 PROTOCOL describes the used network protocol family the service
 205 can be accessed.  `zeroconf-avahi-protocol-inet4' means INET4,
 206 `zeroconf-avahi-protocol-inet6' means INET6.  An unspecified
 207 protocol family is coded with `zeroconf-avahi-protocol-unspec'.
 208
 209 NAME is the string the service is known at Avahi.  A service can
 210 be known under the same name for different service types.
 211
 212 Each TYPE stands for a discovered service type of Avahi.  The
 213 format is described in RFC 2782.  It is of the form
 214
 215   \"_APPLICATION-PROTOCOL._TRANSPORT-PROTOCOL\".
 216
 217 TRANSPORT-PROTOCOL must be either \"tcp\" or \"udp\".
 218 APPLICATION-PROTOCOL must be a protocol name as specified in URL
 219 `http://www.dns-sd.org/ServiceTypes.html'.  Typical service types
 220 are \"_workstation._tcp\" or \"_printer._tcp\".
 221
 222 DOMAIN is the domain name the service is registered in, like \"local\".
 223
 224 FLAGS, an integer, is used inside Avahi.  When publishing a
 225 service (see `zeroconf-publish-service', the flag 0 is used.")
 226
 227 (defvar zeroconf-resolved-services-hash (make-hash-table :test 'equal)
 228   "Hash table of resolved Avahi services.
 229 The key of an entry is the concatenation of the service name and
 230 service type of a resolved service.  The value is the service
 231 itself.  The format of a service is
 232
 233   (INTERFACE PROTOCOL NAME TYPE DOMAIN HOST APROTOCOL ADDRESS PORT TXT FLAGS)
 234
 235 INTERFACE, PROTOCOL, NAME, TYPE, DOMAIN and FLAGS have the same
 236 meaning as in `zeroconf-services-hash'.
 237
 238 HOST is the host name the service is registered.  It is a fully
 239 qualified name, i.e., it contains DOMAIN.
 240
 241 APROTOCOL stands for the network protocol family ADDRESS is
 242 encoded (`zeroconf-avahi-protocol-inet4' means INET4,
 243 `zeroconf-avahi-protocol-inet6' means INET6).  It can be
 244 different from PROTOCOL, when an address resolution has been
 245 requested for another protocol family but the default one.
 246
 247 ADDRESS is the service address, encoded according to the
 248 APROTOCOL network protocol family.  PORT is the corresponding
 249 port the service can be reached on ADDRESS.
 250
 251 TXT is an array of strings, describing additional attributes of
 252 the service.  Usually, every string is a key=value pair.  The
 253 supported keys depend on the service type.")
 254
 255 (defun zeroconf-list-service-names ()
 256   "Returns all discovered Avahi service names as list."
 257   (let (result)
 258     (maphash
 259      (lambda (_key value) (add-to-list 'result (zeroconf-service-name value)))
 260      zeroconf-services-hash)
 261     result))
 262
 263 (defun zeroconf-list-service-types ()
 264   "Returns all discovered Avahi service types as list."
 265   (let (result)
 266     (maphash
 267      (lambda (_key value) (add-to-list 'result (zeroconf-service-type value)))
 268      zeroconf-services-hash)
 269     result))
 270
 271 (defun zeroconf-list-services (type)
 272   "Returns all discovered Avahi services for a given service type TYPE.
 273 The service type is one of the returned values of
 274 `zeroconf-list-service-types'.  The return value is a list
 275 \(SERVICE1 SERVICE2 ...).  See `zeroconf-services-hash' for the
 276 format of SERVICE."
 277   (let (result)
 278     (maphash
 279      (lambda (_key value)
 280        (when (equal type (zeroconf-service-type value))
 281          (add-to-list 'result value)))
 282      zeroconf-services-hash)
 283     result))
 284
 285 (defvar zeroconf-service-added-hooks-hash (make-hash-table :test 'equal)
 286   "Hash table of hooks for newly added services.
 287 The key of an entry is a service type.")
 288
 289 (defvar zeroconf-service-removed-hooks-hash (make-hash-table :test 'equal)
 290   "Hash table of hooks for removed services.
 291 The key of an entry is a service type.")
 292
 293 (defun zeroconf-service-add-hook (type event function)
 294   "Add FUNCTION to the hook of service type TYPE.
 295
 296 EVENT must be either `:new' or `:removed', indicating whether
 297 FUNCTION shall be called when a new service has been newly
 298 detected, or removed.
 299
 300 FUNCTION must accept one argument SERVICE, which identifies the
 301 new service.  Initially, when EVENT is :new, FUNCTION is called
 302 for all already detected services of service type TYPE.
 303
 304 The attributes of SERVICE can be retrieved via the functions
 305
 306   `zeroconf-service-interface'
 307   `zeroconf-service-protocol'
 308   `zeroconf-service-name'
 309   `zeroconf-service-type'
 310   `zeroconf-service-domain'
 311   `zeroconf-service-flags'
 312   `zeroconf-service-host'
 313   `zeroconf-service-aprotocol'
 314   `zeroconf-service-address'
 315   `zeroconf-service-port'
 316   `zeroconf-service-txt'"
 317
 318   (cond
 319    ((equal event :new)
 320     (cl-pushnew function (gethash type zeroconf-service-added-hooks-hash)
 321                 :test #'equal)
 322     (dolist (service (zeroconf-list-services type))
 323       (funcall function service)))
 324    ((equal event :removed)
 325     (cl-pushnew function (gethash type zeroconf-service-removed-hooks-hash)
 326                 :test #'equal))
 327    (t (error "EVENT must be either `:new' or `:removed'"))))
 328
 329 (defun zeroconf-service-remove-hook (type event function)
 330   "Remove FUNCTION from the hook of service type TYPE.
 331
 332 EVENT must be either :new or :removed and has to match the event
 333 type used when registering FUNCTION."
 334   (let* ((table (pcase event
 335                   (:new zeroconf-service-added-hooks-hash)
 336                   (:removed zeroconf-service-removed-hooks-hash)
 337                   (_ (error "EVENT must be either `:new' or `:removed'"))))
 338          (functions (remove function (gethash type table))))
 339     (if functions
 340         (puthash type functions table)
 341       (remhash type table))))
 342
 343 (defun zeroconf-get-host ()
 344   "Returns the local host name as string."
 345   (dbus-call-method
 346    :system zeroconf-service-avahi zeroconf-path-avahi
 347    zeroconf-interface-avahi-server "GetHostName"))
 348
 349 (defun zeroconf-get-domain ()
 350   "Returns the domain name as string."
 351   (dbus-call-method
 352    :system zeroconf-service-avahi zeroconf-path-avahi
 353    zeroconf-interface-avahi-server "GetDomainName"))
 354
 355 (defun zeroconf-get-host-domain ()
 356   "Returns the local host name FQDN as string."
 357   (dbus-call-method
 358    :system zeroconf-service-avahi zeroconf-path-avahi
 359    zeroconf-interface-avahi-server "GetHostNameFqdn"))
 360
 361 (defun zeroconf-get-interface-name (number)
 362   "Return the interface name of internal interface NUMBER."
 363   (dbus-call-method
 364    :system zeroconf-service-avahi zeroconf-path-avahi
 365    zeroconf-interface-avahi-server "GetNetworkInterfaceNameByIndex"
 366    :int32 number))
 367
 368 (defun zeroconf-get-interface-number (name)
 369   "Return the internal interface number of interface NAME."
 370   (dbus-call-method
 371    :system zeroconf-service-avahi zeroconf-path-avahi
 372    zeroconf-interface-avahi-server "GetNetworkInterfaceIndexByName"
 373    name))
 374
 375 (defun zeroconf-get-service (name type)
 376   "Return the service description of service NAME as list.
 377 NAME must be a string.  The service must be of service type
 378 TYPE. The resulting list has the format
 379
 380   (INTERFACE PROTOCOL NAME TYPE DOMAIN FLAGS)."
 381   ;; Due to the service browser, all known services are kept in
 382   ;; `zeroconf-services-hash'.
 383   (gethash (concat name "/" type) zeroconf-services-hash nil))
 384
 385 (defvar dbus-debug)
 386
 387 (defun zeroconf-resolve-service (service)
 388   "Return all service attributes SERVICE as list.
 389 NAME must be a string.  The service must be of service type
 390 TYPE. The resulting list has the format
 391
 392   (INTERFACE PROTOCOL NAME TYPE DOMAIN HOST APROTOCOL ADDRESS PORT TXT FLAGS)."
 393   (let* ((name (zeroconf-service-name service))
 394          (type (zeroconf-service-type service))
 395          (key (concat name "/" type)))
 396
 397     (or
 398      ;; Check whether we know this service already.
 399      (gethash key zeroconf-resolved-services-hash nil)
 400
 401      ;; Resolve the service.  We don't propagate D-Bus errors.
 402      (dbus-ignore-errors
 403        (let* ((result
 404                (dbus-call-method
 405                 :system zeroconf-service-avahi zeroconf-path-avahi
 406                 zeroconf-interface-avahi-server "ResolveService"
 407                 zeroconf-avahi-interface-unspec
 408                 zeroconf-avahi-protocol-unspec
 409                 name type
 410                 zeroconf-avahi-current-domain
 411                 zeroconf-avahi-protocol-unspec
 412                 zeroconf-avahi-flags-unspec))
 413               (elt (nth 9 result))) ;; TXT.
 414          ;; The TXT field has the signature "aay".  Transform to "as".
 415          (while elt
 416            (setcar elt (dbus-byte-array-to-string (car elt)))
 417            (setq elt (cdr elt)))
 418
 419          (when nil ;; We discard it, no use so far.
 420          ;; Register a service resolver.
 421          (let ((object-path (zeroconf-register-service-resolver name type)))
 422            ;; Register the signals.
 423            (dolist (member '("Found" "Failure"))
 424              (dbus-register-signal
 425               :system zeroconf-service-avahi object-path
 426               zeroconf-interface-avahi-service-resolver member
 427               'zeroconf-service-resolver-handler)))
 428          )
 429
 430          ;; Return the resolved service.
 431          (puthash key result zeroconf-resolved-services-hash))))))
 432
 433 (defun zeroconf-service-interface (service)
 434   "Return the internal interface number of SERVICE."
 435   (nth 0 service))
 436
 437 (defun zeroconf-service-protocol (service)
 438   "Return the protocol number of SERVICE."
 439   (nth 1 service))
 440
 441 (defun zeroconf-service-name (service)
 442   "Return the service name of SERVICE."
 443   (nth 2 service))
 444
 445 (defun zeroconf-service-type (service)
 446   "Return the type name of SERVICE."
 447   (nth 3 service))
 448
 449 (defun zeroconf-service-domain (service)
 450   "Return the domain name of SERVICE."
 451   (nth 4 service))
 452
 453 (defun zeroconf-service-flags (service)
 454   "Return the flags of SERVICE."
 455   (nth 5 service))
 456
 457 (defun zeroconf-service-host (service)
 458   "Return the host name of SERVICE."
 459   (nth 5 (zeroconf-resolve-service service)))
 460
 461 (defun zeroconf-service-aprotocol (service)
 462   "Return the aprotocol number of SERVICE."
 463   (nth 6 (zeroconf-resolve-service service)))
 464
 465 (defun zeroconf-service-address (service)
 466   "Return the IP address of SERVICE."
 467   (nth 7 (zeroconf-resolve-service service)))
 468
 469 (defun zeroconf-service-port (service)
 470   "Return the port number of SERVICE."
 471   (nth 8 (zeroconf-resolve-service service)))
 472
 473 (defun zeroconf-service-txt (service)
 474   "Return the text strings of SERVICE."
 475   (nth 9 (zeroconf-resolve-service service)))
 476
 477 \f
 478 ;;; Services signaling.
 479
 480 ;; Register for the service type browser.  Service registrations will
 481 ;; happen in `zeroconf-service-type-browser-handler', when there is an
 482 ;; "ItemNew" signal from the service type browser.
 483 (defun zeroconf-init (&optional domain)
 484   "Instantiate an Avahi service type browser for domain DOMAIN.
 485 DOMAIN is a string, like \"dns-sd.org\" or \"local\".  When
 486 DOMAIN is nil, the local domain is used."
 487   (when (and (or (null domain) (stringp domain))
 488              (dbus-ping :system zeroconf-service-avahi)
 489              (dbus-call-method
 490               :system zeroconf-service-avahi zeroconf-path-avahi
 491               zeroconf-interface-avahi-server "GetVersionString"))
 492
 493     ;; Reset all stored values.
 494     (setq zeroconf-path-avahi-service-type-browser nil
 495           zeroconf-avahi-current-domain (or domain
 496                                             zeroconf-avahi-domain-unspec))
 497     (clrhash zeroconf-path-avahi-service-browser-hash)
 498     (clrhash zeroconf-path-avahi-service-resolver-hash)
 499     (clrhash zeroconf-services-hash)
 500     (clrhash zeroconf-resolved-services-hash)
 501     (clrhash zeroconf-service-added-hooks-hash)
 502     (clrhash zeroconf-service-removed-hooks-hash)
 503
 504     ;; Register a service type browser.
 505     (let ((object-path (zeroconf-register-service-type-browser)))
 506       ;; Register the signals.
 507       (dolist (member '("ItemNew" "ItemRemove" "Failure"))
 508         (dbus-register-signal
 509          :system zeroconf-service-avahi object-path
 510          zeroconf-interface-avahi-service-type-browser member
 511          'zeroconf-service-type-browser-handler)))
 512
 513     ;; Register state changed signal.
 514     (dbus-register-signal
 515      :system zeroconf-service-avahi zeroconf-path-avahi
 516      zeroconf-interface-avahi-service-type-browser "StateChanged"
 517      'zeroconf-service-type-browser-handler)))
 518
 519 (defun zeroconf-register-service-type-browser ()
 520   "Register a service type browser at the Avahi daemon."
 521   (or zeroconf-path-avahi-service-type-browser
 522       (setq zeroconf-path-avahi-service-type-browser
 523             (dbus-call-method
 524              :system zeroconf-service-avahi zeroconf-path-avahi
 525              zeroconf-interface-avahi-server "ServiceTypeBrowserNew"
 526              zeroconf-avahi-interface-unspec
 527              zeroconf-avahi-protocol-unspec
 528              zeroconf-avahi-current-domain
 529              zeroconf-avahi-flags-unspec))))
 530
 531 (defun zeroconf-service-type-browser-handler (&rest val)
 532   "Registered service type browser handler at the Avahi daemon."
 533   (when zeroconf-debug
 534     (message "zeroconf-service-type-browser-handler: %s %S"
 535              (dbus-event-member-name last-input-event) val))
 536   (cond
 537    ((string-equal (dbus-event-member-name last-input-event) "ItemNew")
 538     ;; Parameters: (interface protocol type domain flags)
 539     ;; Register a service browser.
 540     (let ((object-path (zeroconf-register-service-browser (nth 2 val))))
 541       ;; Register the signals.
 542       (dolist (member '("ItemNew" "ItemRemove" "Failure"))
 543         (dbus-register-signal
 544          :system zeroconf-service-avahi object-path
 545          zeroconf-interface-avahi-service-browser member
 546          'zeroconf-service-browser-handler))))))
 547
 548 (defun zeroconf-register-service-browser (type)
 549   "Register a service browser at the Avahi daemon."
 550   (or (gethash type zeroconf-path-avahi-service-browser-hash nil)
 551       (puthash type
 552                (dbus-call-method
 553                 :system zeroconf-service-avahi zeroconf-path-avahi
 554                 zeroconf-interface-avahi-server "ServiceBrowserNew"
 555                 zeroconf-avahi-interface-unspec
 556                 zeroconf-avahi-protocol-unspec
 557                 type
 558                 zeroconf-avahi-current-domain
 559                 zeroconf-avahi-flags-unspec)
 560                zeroconf-path-avahi-service-browser-hash)))
 561
 562 (defun zeroconf-service-browser-handler (&rest val)
 563   "Registered service browser handler at the Avahi daemon."
 564   ;; Parameters: (interface protocol name type domain flags)
 565   (when zeroconf-debug
 566     (message "zeroconf-service-browser-handler: %s %S"
 567              (dbus-event-member-name last-input-event) val))
 568   (let* ((name (zeroconf-service-name val))
 569          (type (zeroconf-service-type val))
 570          (key (concat name "/" type))
 571          (ahook (gethash type zeroconf-service-added-hooks-hash nil))
 572          (rhook (gethash type zeroconf-service-removed-hooks-hash nil)))
 573     (cond
 574      ((string-equal (dbus-event-member-name last-input-event) "ItemNew")
 575       ;; Add new service.
 576       (puthash key val zeroconf-services-hash)
 577       (dolist (f ahook) (funcall f val)))
 578
 579      ((string-equal (dbus-event-member-name last-input-event) "ItemRemove")
 580       ;; Remove the service.
 581       (remhash key zeroconf-services-hash)
 582       (remhash key zeroconf-resolved-services-hash)
 583       (dolist (f rhook) (funcall f val))))))
 584
 585 (defun zeroconf-register-service-resolver (name type)
 586   "Register a service resolver at the Avahi daemon."
 587   (let ((key (concat name "/" type)))
 588     (or (gethash key zeroconf-path-avahi-service-resolver-hash nil)
 589         (puthash key
 590                  (dbus-call-method
 591                   :system zeroconf-service-avahi zeroconf-path-avahi
 592                   zeroconf-interface-avahi-server "ServiceResolverNew"
 593                   zeroconf-avahi-interface-unspec
 594                   zeroconf-avahi-protocol-unspec
 595                   name type
 596                   zeroconf-avahi-current-domain
 597                   zeroconf-avahi-protocol-unspec
 598                   zeroconf-avahi-flags-unspec)
 599                  zeroconf-resolved-services-hash))))
 600
 601 (defun zeroconf-service-resolver-handler (&rest val)
 602   "Registered service resolver handler at the Avahi daemon."
 603   ;; Parameters: (interface protocol name type domain host aprotocol
 604   ;;              address port txt flags)
 605   ;; The "TXT" field has the signature "aay".  Transform to "as".
 606   (let ((elt (nth 9 val)))
 607     (while elt
 608       (setcar elt (dbus-byte-array-to-string (car elt)))
 609       (setq elt (cdr elt))))
 610   (when zeroconf-debug
 611     (message "zeroconf-service-resolver-handler: %s %S"
 612              (dbus-event-member-name last-input-event) val))
 613   (cond
 614    ;; A new service has been detected.  Add it to
 615    ;; `zeroconf-resolved-services-hash'.
 616    ((string-equal (dbus-event-member-name last-input-event) "Found")
 617     (puthash
 618      (concat (zeroconf-service-name val) "/" (zeroconf-service-type val))
 619      val zeroconf-resolved-services-hash))))
 620
 621 \f
 622 ;;; Services publishing.
 623
 624 (defun zeroconf-publish-service (name type domain host port address txt)
 625   "Publish a service at the Avahi daemon.
 626 For the description of arguments, see `zeroconf-resolved-services-hash'."
 627   ;; NAME and TYPE must not be empty.
 628   (when (zerop (length name))
 629     (error "Invalid argument NAME: %s" name))
 630   (when (zerop (length type))
 631     (error "Invalid argument TYPE: %s" type))
 632
 633   ;; Set default values for DOMAIN, HOST and PORT.
 634   (when (zerop (length domain))
 635     (setq domain (zeroconf-get-domain)))
 636   (when (zerop (length host))
 637     (setq host (zeroconf-get-host-domain)))
 638   (when (null port)
 639     (setq port 0))
 640
 641   ;; Create an entry in the daemon.
 642   (let ((object-path
 643          (dbus-call-method
 644           :system zeroconf-service-avahi zeroconf-path-avahi
 645           zeroconf-interface-avahi-server "EntryGroupNew"))
 646         result)
 647
 648     ;; The TXT field has the signature "as".  Transform to "aay".
 649     (dolist (elt txt)
 650       (cl-pushnew (dbus-string-to-byte-array elt) result :test #'equal))
 651
 652     ;; Add the service.
 653     (dbus-call-method
 654      :system zeroconf-service-avahi object-path
 655      zeroconf-interface-avahi-entry-group "AddService"
 656      zeroconf-avahi-interface-unspec
 657      zeroconf-avahi-protocol-unspec
 658      zeroconf-avahi-flags-unspec
 659      name type domain host :uint16 port (append '(:array) result))
 660
 661     ;; Add the address.
 662     (unless (zerop (length address))
 663       (dbus-call-method
 664        :system zeroconf-service-avahi object-path
 665        zeroconf-interface-avahi-entry-group "AddAddress"
 666        zeroconf-avahi-interface-unspec
 667        zeroconf-avahi-protocol-unspec
 668        zeroconf-avahi-flags-unspec
 669        host address))
 670
 671     ;; Make it persistent in the daemon.
 672     (dbus-call-method
 673      :system zeroconf-service-avahi object-path
 674      zeroconf-interface-avahi-entry-group "Commit")))
 675
 676 (provide 'zeroconf)
 677
 678 ;;; zeroconf.el ends here