lisp/linum.el

   1 ;;; linum.el --- display line numbers in the left margin
   2
   3 ;; Copyright (C) 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Markus Triska <markus.triska@gmx.at>
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Display line numbers for the current buffer.
  27 ;;
  28 ;; Toggle display of line numbers with M-x linum-mode.  To enable
  29 ;; line numbering in all buffers, use M-x global-linum-mode.
  30
  31 ;;; Code:
  32
  33 (defconst linum-version "0.9x")
  34
  35 (defvar linum-overlays nil "Overlays used in this buffer.")
  36 (defvar linum-available nil "Overlays available for reuse.")
  37 (defvar linum-before-numbering-hook nil
  38   "Functions run in each buffer before line numbering starts.")
  39
  40 (mapc #'make-variable-buffer-local '(linum-overlays linum-available))
  41
  42 (defgroup linum nil
  43   "Show line numbers in the left margin."
  44   :group 'convenience)
  45
  46 ;;;###autoload
  47 (defcustom linum-format 'dynamic
  48   "Format used to display line numbers.
  49 Either a format string like \"%7d\", `dynamic' to adapt the width
  50 as needed, or a function that is called with a line number as its
  51 argument and should evaluate to a string to be shown on that line.
  52 See also `linum-before-numbering-hook'."
  53   :group 'linum
  54   :type 'sexp)
  55
  56 (defface linum
  57   '((t :inherit (shadow default)))
  58   "Face for displaying line numbers in the display margin."
  59   :group 'linum)
  60
  61 (defcustom linum-eager t
  62   "Whether line numbers should be updated after each command.
  63 The conservative setting `nil' might miss some buffer changes,
  64 and you have to scroll or press \\[recenter-top-bottom] to update the numbers."
  65   :group 'linum
  66   :type 'boolean)
  67
  68 (defcustom linum-delay nil
  69   "Delay updates to give Emacs a chance for other changes."
  70   :group 'linum
  71   :type 'boolean)
  72
  73 ;;;###autoload
  74 (define-minor-mode linum-mode
  75   "Toggle display of line numbers in the left margin."
  76   :lighter ""                           ; for desktop.el
  77   (if linum-mode
  78       (progn
  79         (if linum-eager
  80             (add-hook 'post-command-hook (if linum-delay
  81                                              'linum-schedule
  82                                            'linum-update-current) nil t)
  83           (add-hook 'after-change-functions 'linum-after-change nil t))
  84         (add-hook 'window-scroll-functions 'linum-after-scroll nil t)
  85         ;; Using both window-size-change-functions and
  86         ;; window-configuration-change-hook seems redundant. --Stef
  87         ;; (add-hook 'window-size-change-functions 'linum-after-size nil t)
  88         (add-hook 'change-major-mode-hook 'linum-delete-overlays nil t)
  89         (add-hook 'window-configuration-change-hook
  90                   ;; FIXME: If the buffer is shown in N windows, this
  91                   ;; will be called N times rather than once.  We should use
  92                   ;; something like linum-update-window instead.
  93                   'linum-update-current nil t)
  94         (linum-update-current))
  95     (remove-hook 'post-command-hook 'linum-update-current t)
  96     (remove-hook 'post-command-hook 'linum-schedule t)
  97     ;; (remove-hook 'window-size-change-functions 'linum-after-size t)
  98     (remove-hook 'window-scroll-functions 'linum-after-scroll t)
  99     (remove-hook 'after-change-functions 'linum-after-change t)
 100     (remove-hook 'window-configuration-change-hook 'linum-update-current t)
 101     (remove-hook 'change-major-mode-hook 'linum-delete-overlays t)
 102     (linum-delete-overlays)))
 103
 104 ;;;###autoload
 105 (define-globalized-minor-mode global-linum-mode linum-mode linum-on)
 106
 107 (defun linum-on ()
 108   (unless (minibufferp)
 109     (linum-mode 1)))
 110
 111 (defun linum-delete-overlays ()
 112   "Delete all overlays displaying line numbers for this buffer."
 113   (mapc #'delete-overlay linum-overlays)
 114   (setq linum-overlays nil)
 115   (dolist (w (get-buffer-window-list (current-buffer) nil t))
 116     (set-window-margins w 0 (cdr (window-margins w)))))
 117
 118 (defun linum-update-current ()
 119   "Update line numbers for the current buffer."
 120   (linum-update (current-buffer)))
 121
 122 (defun linum-update (buffer)
 123   "Update line numbers for all windows displaying BUFFER."
 124   (with-current-buffer buffer
 125     (when linum-mode
 126       (setq linum-available linum-overlays)
 127       (setq linum-overlays nil)
 128       (save-excursion
 129         (mapc #'linum-update-window
 130               (get-buffer-window-list buffer nil 'visible)))
 131       (mapc #'delete-overlay linum-available)
 132       (setq linum-available nil))))
 133
 134 (defun linum-update-window (win)
 135   "Update line numbers for the portion visible in window WIN."
 136   (goto-char (window-start win))
 137   (let ((line (line-number-at-pos))
 138         (limit (window-end win t))
 139         (fmt (cond ((stringp linum-format) linum-format)
 140                    ((eq linum-format 'dynamic)
 141                     (let ((w (length (number-to-string
 142                                       (count-lines (point-min) (point-max))))))
 143                       (concat "%" (number-to-string w) "d")))))
 144         (width 0))
 145     (run-hooks 'linum-before-numbering-hook)
 146     ;; Create an overlay (or reuse an existing one) for each
 147     ;; line visible in this window, if necessary.
 148     (while (and (not (eobp)) (<= (point) limit))
 149       (let* ((str (if fmt
 150                       (propertize (format fmt line) 'face 'linum)
 151                     (funcall linum-format line)))
 152              (visited (catch 'visited
 153                         (dolist (o (overlays-in (point) (point)))
 154                           (when (equal-including-properties
 155                                  (overlay-get o 'linum-str) str)
 156                             (unless (memq o linum-overlays)
 157                               (push o linum-overlays))
 158                             (setq linum-available (delq o linum-available))
 159                             (throw 'visited t))))))
 160         (setq width (max width (length str)))
 161         (unless visited
 162           (let ((ov (if (null linum-available)
 163                         (make-overlay (point) (point))
 164                       (move-overlay (pop linum-available) (point) (point)))))
 165             (push ov linum-overlays)
 166             (overlay-put ov 'before-string
 167                          (propertize " " 'display `((margin left-margin) ,str)))
 168             (overlay-put ov 'linum-str str))))
 169       (forward-line)
 170       (setq line (1+ line)))
 171     (set-window-margins win width (cdr (window-margins win)))))
 172
 173 (defun linum-after-change (beg end len)
 174   ;; update overlays on deletions, and after newlines are inserted
 175   (when (or (= beg end)
 176             (= end (point-max))
 177             (string-match-p "\n" (buffer-substring-no-properties beg end)))
 178     (linum-update-current)))
 179
 180 (defun linum-after-scroll (win start)
 181   (linum-update (window-buffer win)))
 182
 183 ;; (defun linum-after-size (frame)
 184 ;;   (linum-after-config))
 185
 186 (defun linum-schedule ()
 187   ;; schedule an update; the delay gives Emacs a chance for display changes
 188   (run-with-idle-timer 0 nil #'linum-update-current))
 189
 190 ;; (defun linum-after-config ()
 191 ;;   (walk-windows (lambda (w) (linum-update (window-buffer w))) nil 'visible))
 192
 193 (defun linum-unload-function ()
 194   "Unload the Linum library."
 195   (global-linum-mode -1)
 196   ;; continue standard unloading
 197   nil)
 198
 199 (provide 'linum)
 200
 201 ;; arch-tag: dea45631-ed3c-4867-8b49-1c41c80aec6a
 202 ;;; linum.el ends here