lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter
   2
   3 ;; Copyright (C) 1989, 1994, 1998, 2001, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do M-x `describe-mode'.
  33 ;;
  34 ;; NOTE: Remember to change `hexl-program' or `hexl-options' if needed.
  35 ;;
  36 ;; Currently hexl only supports big endian hex output with 16 bit
  37 ;; grouping.
  38 ;;
  39 ;; -iso in `hexl-options' will allow iso characters to display in the
  40 ;; ASCII region of the screen (if your emacs supports this) instead of
  41 ;; changing them to dots.
  42
  43 ;;; Code:
  44
  45 ;;
  46 ;; vars here
  47 ;;
  48
  49 (defgroup hexl nil
  50   "Edit a file in a hex dump format using the hexl filter."
  51   :group 'data)
  52
  53
  54 (defcustom hexl-program "hexl"
  55   "The program that will hexlify and dehexlify its stdin.
  56 `hexl-program' will always be concatenated with `hexl-options'
  57 and \"-de\" when dehexlifying a buffer."
  58   :type 'string
  59   :group 'hexl)
  60
  61 (defcustom hexl-iso ""
  62   "If your emacs can handle ISO characters, this should be set to
  63 \"-iso\" otherwise it should be \"\"."
  64   :type 'string
  65   :group 'hexl)
  66
  67 (defcustom hexl-options (format "-hex %s" hexl-iso)
  68   "Space separated options to `hexl-program' that suit your needs.
  69 Quoting cannot be used, so the arguments cannot themselves contain spaces."
  70   :type 'string
  71   :group 'hexl)
  72
  73 (defcustom hexl-follow-ascii t
  74   "If non-nil then highlight the ASCII character corresponding to point."
  75   :type 'boolean
  76   :group 'hexl
  77   :version "20.3")
  78
  79 (defvar hexl-max-address 0
  80   "Maximum offset into hexl buffer.")
  81
  82 (defvar hexl-mode-map nil)
  83
  84 (defvar hexl-mode-old-local-map)
  85 (defvar hexl-mode-old-mode-name)
  86 (defvar hexl-mode-old-major-mode)
  87 (defvar hexl-mode-old-isearch-search-fun-function)
  88 (defvar hexl-mode-old-require-final-newline)
  89 (defvar hexl-mode-old-syntax-table)
  90
  91 (defvar hexl-ascii-overlay nil
  92   "Overlay used to highlight ASCII element corresponding to current point.")
  93 (make-variable-buffer-local 'hexl-ascii-overlay)
  94
  95 ;; routines
  96
  97 (put 'hexl-mode 'mode-class 'special)
  98
  99 ;;;###autoload
 100 (defun hexl-mode (&optional arg)
 101   "\\<hexl-mode-map>A mode for editing binary files in hex dump format.
 102 This is not an ordinary major mode; it alters some aspects
 103 of the current mode's behavior, but not all; also, you can exit
 104 Hexl mode and return to the previous mode using `hexl-mode-exit'.
 105
 106 This function automatically converts a buffer into the hexl format
 107 using the function `hexlify-buffer'.
 108
 109 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 110 representing the offset into the file that the characters on this line
 111 are at and 16 characters from the file (displayed as hexadecimal
 112 values grouped every 16 bits) and as their ASCII values.
 113
 114 If any of the characters (displayed as ASCII characters) are
 115 unprintable (control or meta characters) they will be replaced as
 116 periods.
 117
 118 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 119 in hexl format.
 120
 121 A sample format:
 122
 123   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 124   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 125   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 126   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 127   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 128   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 129   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 130   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 131   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 132   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 133   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 134   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 135   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 136   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 137   000000c0: 7265 6769 6f6e 2e0a                      region..
 138
 139 Movement is as simple as movement in a normal emacs text buffer.  Most
 140 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 141 to move the cursor left, right, down, and up).
 142
 143 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 144 also supported.
 145
 146 There are several ways to change text in hexl mode:
 147
 148 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 149 bound to self-insert so you can simply type the character and it will
 150 insert itself (actually overstrike) into the buffer.
 151
 152 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 153 it isn't bound to self-insert.  An octal number can be supplied in place
 154 of another key to insert the octal number's ASCII representation.
 155
 156 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 157 into the buffer at the current point.
 158
 159 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 160 into the buffer at the current point.
 161
 162 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 163 into the buffer at the current point.
 164
 165 \\[hexl-mode-exit] will exit hexl-mode.
 166
 167 Note: saving the file with any of the usual Emacs commands
 168 will actually convert it back to binary format while saving.
 169
 170 You can use \\[hexl-find-file] to visit a file in Hexl mode.
 171
 172 \\[describe-bindings] for advanced commands."
 173   (interactive "p")
 174   (unless (eq major-mode 'hexl-mode)
 175     (let ((modified (buffer-modified-p))
 176           (inhibit-read-only t)
 177           (original-point (- (point) (point-min)))
 178           max-address)
 179       (and (eobp) (not (bobp))
 180            (setq original-point (1- original-point)))
 181       (if (not (or (eq arg 1) (not arg)))
 182           ;; if no argument then we guess at hexl-max-address
 183           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 184         (setq max-address (1- (buffer-size)))
 185         ;; If the buffer's EOL type is -dos, we need to account for
 186         ;; extra CR characters added when hexlify-buffer writes the
 187         ;; buffer to a file.
 188         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 189           (setq max-address (+ (count-lines (point-min) (point-max))
 190                                max-address))
 191           ;; But if there's no newline at the last line, we are off by
 192           ;; one; adjust.
 193           (or (eq (char-before (point-max)) ?\n)
 194               (setq max-address (1- max-address)))
 195           (setq original-point (+ (count-lines (point-min) (point))
 196                                   original-point))
 197           (or (bolp) (setq original-point (1- original-point))))
 198         (hexlify-buffer)
 199         (set-buffer-modified-p modified))
 200       (make-local-variable 'hexl-max-address)
 201       (setq hexl-max-address max-address)
 202       (hexl-goto-address original-point))
 203
 204     ;; We do not turn off the old major mode; instead we just
 205     ;; override most of it.  That way, we can restore it perfectly.
 206     (make-local-variable 'hexl-mode-old-local-map)
 207     (setq hexl-mode-old-local-map (current-local-map))
 208     (use-local-map hexl-mode-map)
 209
 210     (make-local-variable 'hexl-mode-old-mode-name)
 211     (setq hexl-mode-old-mode-name mode-name)
 212     (setq mode-name "Hexl")
 213
 214     (set (make-local-variable 'hexl-mode-old-isearch-search-fun-function)
 215          isearch-search-fun-function)
 216     (set (make-local-variable 'isearch-search-fun-function)
 217          'hexl-isearch-search-function)
 218
 219     (make-local-variable 'hexl-mode-old-major-mode)
 220     (setq hexl-mode-old-major-mode major-mode)
 221     (setq major-mode 'hexl-mode)
 222
 223     (make-local-variable 'hexl-mode-old-syntax-table)
 224     (setq hexl-mode-old-syntax-table (syntax-table))
 225     (set-syntax-table (standard-syntax-table))
 226
 227     (add-hook 'write-contents-functions 'hexl-save-buffer nil t)
 228
 229     (make-local-variable 'hexl-mode-old-require-final-newline)
 230     (setq hexl-mode-old-require-final-newline require-final-newline)
 231     (make-local-variable 'require-final-newline)
 232     (setq require-final-newline nil)
 233
 234     ;; Add hooks to rehexlify or dehexlify on various events.
 235     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 236
 237     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 238
 239     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 240   (run-hooks 'hexl-mode-hook))
 241
 242
 243 (defun hexl-isearch-search-function ()
 244   (if (and (not isearch-regexp) (not isearch-word))
 245       (lambda (string &optional bound noerror count)
 246         (funcall
 247          (if isearch-forward 're-search-forward 're-search-backward)
 248          (if (> (length string) 80)
 249              (regexp-quote string)
 250            (mapconcat 'string string "\\(?:\n\\(?:[:a-f0-9]+ \\)+ \\)?"))
 251          bound noerror count))
 252     (let ((isearch-search-fun-function nil))
 253       (isearch-search-fun))))
 254
 255 (defun hexl-after-revert-hook ()
 256   (setq hexl-max-address (1- (buffer-size)))
 257   (hexlify-buffer)
 258   (set-buffer-modified-p nil))
 259
 260 (defvar hexl-in-save-buffer nil)
 261
 262 (defun hexl-save-buffer ()
 263   "Save a hexl format buffer as binary in visited file if modified."
 264   (interactive)
 265   (if hexl-in-save-buffer nil
 266     (set-buffer-modified-p (if (buffer-modified-p)
 267                                (save-excursion
 268                                  (let ((buf (generate-new-buffer " hexl"))
 269                                        (name (buffer-name))
 270                                        (file-name (buffer-file-name))
 271                                        (start (point-min))
 272                                        (end (point-max))
 273                                        modified)
 274                                    (set-buffer buf)
 275                                    (insert-buffer-substring name start end)
 276                                    (set-buffer name)
 277                                    (dehexlify-buffer)
 278                                    ;; Prevent infinite recursion.
 279                                    (let ((hexl-in-save-buffer t))
 280                                      (save-buffer))
 281                                    (setq modified (buffer-modified-p))
 282                                    (delete-region (point-min) (point-max))
 283                                    (insert-buffer-substring buf start end)
 284                                    (kill-buffer buf)
 285                                    modified))
 286                              (message "(No changes need to be saved)")
 287                              nil))
 288     ;; Return t to indicate we have saved t
 289     t))
 290
 291 ;;;###autoload
 292 (defun hexl-find-file (filename)
 293   "Edit file FILENAME in hexl-mode.
 294 Switch to a buffer visiting file FILENAME, creating one in none exists."
 295   (interactive
 296    (list
 297     (let ((completion-ignored-extensions nil))
 298       (read-file-name "Filename: " nil nil 'ret-must-match))))
 299   (find-file-literally filename)
 300   (if (not (eq major-mode 'hexl-mode))
 301       (hexl-mode)))
 302
 303 (defun hexl-mode-exit (&optional arg)
 304   "Exit Hexl mode, returning to previous mode.
 305 With arg, don't unhexlify buffer."
 306   (interactive "p")
 307   (if (or (eq arg 1) (not arg))
 308       (let ((modified (buffer-modified-p))
 309             (inhibit-read-only t)
 310             (original-point (1+ (hexl-current-address))))
 311         (dehexlify-buffer)
 312         (remove-hook 'write-contents-functions 'hexl-save-buffer t)
 313         (set-buffer-modified-p modified)
 314         (goto-char original-point)
 315         ;; Maybe adjust point for the removed CR characters.
 316         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 317           (setq original-point (- original-point
 318                                   (count-lines (point-min) (point))))
 319           (or (bobp) (setq original-point (1+ original-point))))
 320         (goto-char original-point)))
 321
 322   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 323   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 324   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 325   (setq hexl-ascii-overlay nil)
 326
 327   (setq require-final-newline hexl-mode-old-require-final-newline)
 328   (setq mode-name hexl-mode-old-mode-name)
 329   (setq isearch-search-fun-function hexl-mode-old-isearch-search-fun-function)
 330   (use-local-map hexl-mode-old-local-map)
 331   (set-syntax-table hexl-mode-old-syntax-table)
 332   (setq major-mode hexl-mode-old-major-mode)
 333   (force-mode-line-update))
 334
 335 (defun hexl-maybe-dehexlify-buffer ()
 336   "Convert a hexl format buffer to binary.
 337 Ask the user for confirmation."
 338   (if (y-or-n-p "Convert contents back to binary format? ")
 339       (let ((modified (buffer-modified-p))
 340             (inhibit-read-only t)
 341             (original-point (1+ (hexl-current-address))))
 342         (dehexlify-buffer)
 343         (remove-hook 'write-contents-functions 'hexl-save-buffer t)
 344         (set-buffer-modified-p modified)
 345         (goto-char original-point))))
 346
 347 (defun hexl-current-address (&optional validate)
 348   "Return current hexl-address."
 349   (interactive)
 350   (let ((current-column (- (% (- (point) (point-min) -1) 68) 11))
 351         (hexl-address 0))
 352     (if (< current-column 0)
 353         (if validate
 354             (error "Point is not on a character in the file")
 355           (setq current-column 0)))
 356     (setq hexl-address
 357           (+ (* (/ (- (point) (point-min) -1) 68) 16)
 358              (if (>= current-column 41)
 359                  (- current-column 41)
 360                (/ (- current-column  (/ current-column 5)) 2))))
 361     (when (interactive-p)
 362       (message "Current address is %d" hexl-address))
 363     hexl-address))
 364
 365 (defun hexl-address-to-marker (address)
 366   "Return buffer position for ADDRESS."
 367   (interactive "nAddress: ")
 368   (+ (* (/ address 16) 68) 10 (point-min) (/ (* (% address 16) 5) 2)))
 369
 370 (defun hexl-goto-address (address)
 371   "Goto hexl-mode (decimal) address ADDRESS.
 372 Signal error if ADDRESS out of range."
 373   (interactive "nAddress: ")
 374   (if (or (< address 0) (> address hexl-max-address))
 375           (error "Out of hexl region"))
 376   (goto-char (hexl-address-to-marker address)))
 377
 378 (defun hexl-goto-hex-address (hex-address)
 379   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 380 Signal error if HEX-ADDRESS is out of range."
 381   (interactive "sHex Address: ")
 382   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 383
 384 (defun hexl-hex-string-to-integer (hex-string)
 385   "Return decimal integer for HEX-STRING."
 386   (interactive "sHex number: ")
 387   (let ((hex-num 0))
 388     (while (not (equal hex-string ""))
 389       (setq hex-num (+ (* hex-num 16)
 390                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 391       (setq hex-string (substring hex-string 1)))
 392     hex-num))
 393
 394 (defun hexl-octal-string-to-integer (octal-string)
 395   "Return decimal integer for OCTAL-STRING."
 396   (interactive "sOctal number: ")
 397   (let ((oct-num 0))
 398     (while (not (equal octal-string ""))
 399       (setq oct-num (+ (* oct-num 8)
 400                        (hexl-oct-char-to-integer
 401                         (string-to-char octal-string))))
 402       (setq octal-string (substring octal-string 1)))
 403     oct-num))
 404
 405 ;; move point functions
 406
 407 (defun hexl-backward-char (arg)
 408   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 409   (interactive "p")
 410   (hexl-goto-address (- (hexl-current-address) arg)))
 411
 412 (defun hexl-forward-char (arg)
 413   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 414   (interactive "p")
 415   (hexl-goto-address (+ (hexl-current-address) arg)))
 416
 417 (defun hexl-backward-short (arg)
 418   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 419   (interactive "p")
 420   (hexl-goto-address (let ((address (hexl-current-address)))
 421                        (if (< arg 0)
 422                            (progn
 423                              (setq arg (- arg))
 424                              (while (> arg 0)
 425                                (if (not (equal address (logior address 3)))
 426                                    (if (> address hexl-max-address)
 427                                        (progn
 428                                          (message "End of buffer.")
 429                                          (setq address hexl-max-address))
 430                                      (setq address (logior address 3)))
 431                                  (if (> address hexl-max-address)
 432                                      (progn
 433                                        (message "End of buffer.")
 434                                        (setq address hexl-max-address))
 435                                    (setq address (+ address 4))))
 436                                (setq arg (1- arg)))
 437                              (if (> address hexl-max-address)
 438                                  (progn
 439                                    (message "End of buffer.")
 440                                    (setq address hexl-max-address))
 441                                (setq address (logior address 3))))
 442                          (while (> arg 0)
 443                            (if (not (equal address (logand address -4)))
 444                                (setq address (logand address -4))
 445                              (if (not (equal address 0))
 446                                  (setq address (- address 4))
 447                                (message "Beginning of buffer.")))
 448                            (setq arg (1- arg))))
 449                        address)))
 450
 451 (defun hexl-forward-short (arg)
 452   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 453   (interactive "p")
 454   (hexl-backward-short (- arg)))
 455
 456 (defun hexl-backward-word (arg)
 457   "Move to left ARG words (right if ARG negative) in hexl-mode."
 458   (interactive "p")
 459   (hexl-goto-address (let ((address (hexl-current-address)))
 460                        (if (< arg 0)
 461                            (progn
 462                              (setq arg (- arg))
 463                              (while (> arg 0)
 464                                (if (not (equal address (logior address 7)))
 465                                    (if (> address hexl-max-address)
 466                                        (progn
 467                                          (message "End of buffer.")
 468                                          (setq address hexl-max-address))
 469                                      (setq address (logior address 7)))
 470                                  (if (> address hexl-max-address)
 471                                      (progn
 472                                        (message "End of buffer.")
 473                                        (setq address hexl-max-address))
 474                                    (setq address (+ address 8))))
 475                                (setq arg (1- arg)))
 476                              (if (> address hexl-max-address)
 477                                  (progn
 478                                    (message "End of buffer.")
 479                                    (setq address hexl-max-address))
 480                                (setq address (logior address 7))))
 481                          (while (> arg 0)
 482                            (if (not (equal address (logand address -8)))
 483                                (setq address (logand address -8))
 484                              (if (not (equal address 0))
 485                                  (setq address (- address 8))
 486                                (message "Beginning of buffer.")))
 487                            (setq arg (1- arg))))
 488                        address)))
 489
 490 (defun hexl-forward-word (arg)
 491   "Move right ARG words (left if ARG negative) in hexl-mode."
 492   (interactive "p")
 493   (hexl-backward-word (- arg)))
 494
 495 (defun hexl-previous-line (arg)
 496   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 497 If there is byte at the target address move to the last byte in that line."
 498   (interactive "p")
 499   (hexl-next-line (- arg)))
 500
 501 (defun hexl-next-line (arg)
 502   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 503 If there is no byte at the target address move to the last byte in that line."
 504   (interactive "p")
 505   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 506                        (if (and (< arg 0) (< address 0))
 507                                 (progn (message "Out of hexl region.")
 508                                        (setq address
 509                                              (% (hexl-current-address) 16)))
 510                          (if (and (> address hexl-max-address)
 511                                   (< (% hexl-max-address 16) (% address 16)))
 512                              (setq address hexl-max-address)
 513                            (if (> address hexl-max-address)
 514                                (progn (message "Out of hexl region.")
 515                                       (setq
 516                                        address
 517                                        (+ (logand hexl-max-address -16)
 518                                           (% (hexl-current-address) 16)))))))
 519                        address)))
 520
 521 (defun hexl-beginning-of-buffer (arg)
 522   "Move to the beginning of the hexl buffer.
 523 Leaves `hexl-mark' at previous position.
 524 With prefix arg N, puts point N bytes of the way from the true beginning."
 525   (interactive "p")
 526   (push-mark (point))
 527   (hexl-goto-address (+ 0 (1- arg))))
 528
 529 (defun hexl-end-of-buffer (arg)
 530   "Go to `hexl-max-address' minus ARG."
 531   (interactive "p")
 532   (push-mark (point))
 533   (hexl-goto-address (- hexl-max-address (1- arg))))
 534
 535 (defun hexl-beginning-of-line ()
 536   "Goto beginning of line in hexl mode."
 537   (interactive)
 538   (goto-char (+ (* (/ (point) 68) 68) 11)))
 539
 540 (defun hexl-end-of-line ()
 541   "Goto end of line in hexl mode."
 542   (interactive)
 543   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 544                        (if (> address hexl-max-address)
 545                            (setq address hexl-max-address))
 546                        address)))
 547
 548 (defun hexl-scroll-down (arg)
 549   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 550   (interactive "P")
 551   (if (null arg)
 552       (setq arg (1- (window-height)))
 553     (setq arg (prefix-numeric-value arg)))
 554   (hexl-scroll-up (- arg)))
 555
 556 (defun hexl-scroll-up (arg)
 557   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG.
 558 If there's no byte at the target address, move to the first or last line."
 559   (interactive "P")
 560   (if (null arg)
 561       (setq arg (1- (window-height)))
 562     (setq arg (prefix-numeric-value arg)))
 563   (let* ((movement (* arg 16))
 564          (address (hexl-current-address))
 565          (dest (+ address movement)))
 566     (cond
 567      ;; If possible, try to stay at the same offset from the beginning
 568      ;; of the 16-byte group, even if we move to the first or last
 569      ;; group.
 570      ((and (> dest hexl-max-address)
 571            (>= (% hexl-max-address 16) (% address 16)))
 572       (setq dest (+ (logand hexl-max-address -16) (% address 16))))
 573      ((> dest hexl-max-address)
 574       (setq dest hexl-max-address))
 575      ((< dest 0)
 576       (setq dest (% address 16))))
 577     (if (/= dest (+ address movement))
 578         (message "Out of hexl region."))
 579     (hexl-goto-address dest)
 580     (recenter 0)))
 581
 582 (defun hexl-beginning-of-1k-page ()
 583   "Go to beginning of 1k boundary."
 584   (interactive)
 585   (hexl-goto-address (logand (hexl-current-address) -1024)))
 586
 587 (defun hexl-end-of-1k-page ()
 588   "Go to end of 1k boundary."
 589   (interactive)
 590   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 591                        (if (> address hexl-max-address)
 592                            (setq address hexl-max-address))
 593                        address)))
 594
 595 (defun hexl-beginning-of-512b-page ()
 596   "Go to beginning of 512 byte boundary."
 597   (interactive)
 598   (hexl-goto-address (logand (hexl-current-address) -512)))
 599
 600 (defun hexl-end-of-512b-page ()
 601   "Go to end of 512 byte boundary."
 602   (interactive)
 603   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 604                        (if (> address hexl-max-address)
 605                            (setq address hexl-max-address))
 606                        address)))
 607
 608 (defun hexl-quoted-insert (arg)
 609   "Read next input character and insert it.
 610 Useful for inserting control characters and non-ASCII characters given their
 611 numerical code.
 612 You may also type octal digits, to insert a character with that code."
 613   (interactive "p")
 614   (hexl-insert-multibyte-char (read-quoted-char) arg))
 615
 616 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 617
 618 ;;;###autoload
 619 (defun hexlify-buffer ()
 620   "Convert a binary buffer to hexl format.
 621 This discards the buffer's undo information."
 622   (interactive)
 623   (and buffer-undo-list
 624        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 625            (error "Aborted")))
 626   (setq buffer-undo-list nil)
 627   ;; Don't decode text in the ASCII part of `hexl' program output.
 628   (let ((coding-system-for-read 'raw-text)
 629         (coding-system-for-write buffer-file-coding-system)
 630         (buffer-undo-list t))
 631     (apply 'call-process-region (point-min) (point-max)
 632            (expand-file-name hexl-program exec-directory)
 633            t t nil (split-string hexl-options))
 634     (if (> (point) (hexl-address-to-marker hexl-max-address))
 635         (hexl-goto-address hexl-max-address))))
 636
 637 (defun dehexlify-buffer ()
 638   "Convert a hexl format buffer to binary.
 639 This discards the buffer's undo information."
 640   (interactive)
 641   (and buffer-undo-list
 642        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 643            (error "Aborted")))
 644   (setq buffer-undo-list nil)
 645   (let ((coding-system-for-write 'raw-text)
 646         (coding-system-for-read buffer-file-coding-system)
 647         (buffer-undo-list t))
 648     (apply 'call-process-region (point-min) (point-max)
 649            (expand-file-name hexl-program exec-directory)
 650            t t nil "-de" (split-string hexl-options))))
 651
 652 (defun hexl-char-after-point ()
 653   "Return char for ASCII hex digits at point."
 654   (hexl-htoi (char-after (point))
 655              (char-after (1+ (point)))))
 656
 657 (defun hexl-htoi (lh rh)
 658   "Hex (char) LH (char) RH to integer."
 659     (+ (* (hexl-hex-char-to-integer lh) 16)
 660        (hexl-hex-char-to-integer rh)))
 661
 662 (defun hexl-hex-char-to-integer (character)
 663   "Take a char and return its value as if it was a hex digit."
 664   (if (and (>= character ?0) (<= character ?9))
 665       (- character ?0)
 666     (let ((ch (logior character 32)))
 667       (if (and (>= ch ?a) (<= ch ?f))
 668           (- ch (- ?a 10))
 669         (error "Invalid hex digit `%c'" ch)))))
 670
 671 (defun hexl-oct-char-to-integer (character)
 672   "Take a char and return its value as if it was a octal digit."
 673   (if (and (>= character ?0) (<= character ?7))
 674       (- character ?0)
 675     (error "Invalid octal digit `%c'" character)))
 676
 677 (defun hexl-printable-character (ch)
 678   "Return a displayable string for character CH."
 679   (format "%c" (if hexl-iso
 680                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 681                        46
 682                      ch)
 683                  (if (or (< ch 32) (>= ch 127))
 684                      46
 685                    ch))))
 686
 687 (defun hexl-insert-multibyte-char (ch num)
 688   "Insert a possibly multibyte character CH NUM times.
 689
 690 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 691 and their encoded form is inserted byte by byte."
 692   (let ((charset (char-charset ch))
 693         (coding (if (or (null buffer-file-coding-system)
 694                         ;; coding-system-type equals t means undecided.
 695                         (eq (coding-system-type buffer-file-coding-system) t))
 696                     default-buffer-file-coding-system
 697                   buffer-file-coding-system)))
 698     (cond ((and (> ch 0) (< ch 256))
 699            (hexl-insert-char ch num))
 700           ((eq charset 'unknown)
 701            (error
 702             "0x%x -- invalid character code; use \\[hexl-insert-hex-string]"
 703             ch))
 704           (t
 705            (let ((encoded (encode-coding-char ch coding))
 706                  (internal (string-as-unibyte (char-to-string ch)))
 707                  internal-hex)
 708              ;; If encode-coding-char returns nil, it means our character
 709              ;; cannot be safely encoded with buffer-file-coding-system.
 710              ;; In that case, we offer to insert the internal representation
 711              ;; of that character, byte by byte.
 712              (when (null encoded)
 713                (setq internal-hex
 714                      (mapconcat (function (lambda (c) (format "%x" c)))
 715                                 internal " "))
 716                (if (yes-or-no-p
 717                     (format
 718                      "Insert char 0x%x's internal representation \"%s\"? "
 719                      ch internal-hex))
 720                    (setq encoded internal)
 721                  (error
 722                   "Can't encode `0x%x' with this buffer's coding system; try \\[hexl-insert-hex-string]"
 723                   ch)))
 724              (while (> num 0)
 725                (mapc
 726                 (function (lambda (c) (hexl-insert-char c 1))) encoded)
 727                (setq num (1- num))))))))
 728
 729 (defun hexl-self-insert-command (arg)
 730   "Insert this character.
 731 Interactively, with a numeric argument, insert this character that many times.
 732
 733 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 734 and their encoded form is inserted byte by byte."
 735   (interactive "p")
 736   (hexl-insert-multibyte-char last-command-char arg))
 737
 738 (defun hexl-insert-char (ch num)
 739   "Insert the character CH NUM times in a hexl buffer.
 740
 741 CH must be a unibyte character whose value is between 0 and 255."
 742   (if (or (< ch 0) (> ch 255))
 743       (error "Invalid character 0x%x -- must be in the range [0..255]"))
 744   (let ((address (hexl-current-address t)))
 745     (while (> num 0)
 746       (let ((hex-position
 747              (+ (* (/ address 16) 68)
 748                 10 (point-min)
 749                 (* 2 (% address 16))
 750                 (/ (% address 16) 2)))
 751             (ascii-position
 752              (+ (* (/ address 16) 68) 51 (point-min) (% address 16)))
 753             at-ascii-position)
 754         (if (= (point) ascii-position)
 755             (setq at-ascii-position t))
 756         (goto-char hex-position)
 757         (delete-char 2)
 758         (insert (format "%02x" ch))
 759         (goto-char ascii-position)
 760         (delete-char 1)
 761         (insert (hexl-printable-character ch))
 762         (or (eq address hexl-max-address)
 763             (setq address (1+ address)))
 764         (hexl-goto-address address)
 765         (if at-ascii-position
 766             (progn
 767               (beginning-of-line)
 768               (forward-char 51)
 769               (forward-char (% address 16)))))
 770       (setq num (1- num)))))
 771
 772 ;; hex conversion
 773
 774 (defun hexl-insert-hex-char (arg)
 775   "Insert a character given by its hexadecimal code ARG times at point."
 776   (interactive "p")
 777   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 778     (if (< num 0)
 779         (error "Hex number out of range")
 780       (hexl-insert-multibyte-char num arg))))
 781
 782 (defun hexl-insert-hex-string (str arg)
 783   "Insert hexadecimal string STR at point ARG times.
 784 Embedded whitespace, dashes, and periods in the string are ignored."
 785   (interactive "sHex string: \np")
 786   (setq str (replace-regexp-in-string "[- \t.]" "" str))
 787   (let ((chars '()))
 788     (let ((len (length str))
 789           (idx 0))
 790       (if (eq (logand len 1) 1)
 791           (let ((num (hexl-hex-string-to-integer (substring str 0 1))))
 792             (setq chars (cons num chars))
 793             (setq idx 1)))
 794       (while (< idx len)
 795         (let* ((nidx (+ idx 2))
 796                (num (hexl-hex-string-to-integer (substring str idx nidx))))
 797           (setq chars (cons num chars))
 798           (setq idx nidx))))
 799     (setq chars (nreverse chars))
 800     (while (> arg 0)
 801       (let ((chars chars))
 802         (while chars
 803           (hexl-insert-char (car chars) 1)
 804           (setq chars (cdr chars))))
 805       (setq arg (- arg 1)))))
 806
 807 (defun hexl-insert-decimal-char (arg)
 808   "Insert a character given by its decimal code ARG times at point."
 809   (interactive "p")
 810   (let ((num (string-to-int (read-string "Decimal Number: "))))
 811     (if (< num 0)
 812         (error "Decimal number out of range")
 813       (hexl-insert-multibyte-char num arg))))
 814
 815 (defun hexl-insert-octal-char (arg)
 816   "Insert a character given by its octal code ARG times at point."
 817   (interactive "p")
 818   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 819     (if (< num 0)
 820         (error "Decimal number out of range")
 821       (hexl-insert-multibyte-char num arg))))
 822
 823 (defun hexl-follow-ascii (&optional arg)
 824   "Toggle following ASCII in Hexl buffers.
 825 With prefix ARG, turn on following if and only if ARG is positive.
 826 When following is enabled, the ASCII character corresponding to the
 827 element under the point is highlighted.
 828 Customize the variable `hexl-follow-ascii' to disable this feature."
 829   (interactive "P")
 830   (let ((on-p (if arg
 831                   (> (prefix-numeric-value arg) 0)
 832                (not hexl-ascii-overlay))))
 833
 834     (if on-p
 835       ;; turn it on
 836       (if (not hexl-ascii-overlay)
 837           (progn
 838             (setq hexl-ascii-overlay (make-overlay 1 1)
 839                   hexl-follow-ascii t)
 840             (overlay-put hexl-ascii-overlay 'face 'highlight)
 841             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
 842       ;; turn it off
 843       (if hexl-ascii-overlay
 844           (progn
 845             (delete-overlay hexl-ascii-overlay)
 846             (setq hexl-ascii-overlay nil
 847                   hexl-follow-ascii nil)
 848             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 849             )))))
 850
 851 (defun hexl-follow-ascii-find ()
 852   "Find and highlight the ASCII element corresponding to current point."
 853   (let ((pos (+ 51
 854                 (- (point) (current-column))
 855                 (mod (hexl-current-address) 16))))
 856     (move-overlay hexl-ascii-overlay pos (1+ pos))
 857     ))
 858
 859 ;; startup stuff.
 860
 861 (if hexl-mode-map
 862     nil
 863   (setq hexl-mode-map (make-keymap))
 864   ;; Make all self-inserting keys go through hexl-self-insert-command,
 865   ;; because we need to convert them to unibyte characters before
 866   ;; inserting them into the buffer.
 867   (substitute-key-definition 'self-insert-command 'hexl-self-insert-command
 868                              hexl-mode-map (current-global-map))
 869
 870   (define-key hexl-mode-map [left] 'hexl-backward-char)
 871   (define-key hexl-mode-map [right] 'hexl-forward-char)
 872   (define-key hexl-mode-map [up] 'hexl-previous-line)
 873   (define-key hexl-mode-map [down] 'hexl-next-line)
 874   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 875   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 876   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 877   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 878   (define-key hexl-mode-map [home] 'hexl-beginning-of-line)
 879   (define-key hexl-mode-map [end] 'hexl-end-of-line)
 880   (define-key hexl-mode-map [C-home] 'hexl-beginning-of-buffer)
 881   (define-key hexl-mode-map [C-end] 'hexl-end-of-buffer)
 882   (define-key hexl-mode-map [deletechar] 'undefined)
 883   (define-key hexl-mode-map [deleteline] 'undefined)
 884   (define-key hexl-mode-map [insertline] 'undefined)
 885   (define-key hexl-mode-map [S-delete] 'undefined)
 886   (define-key hexl-mode-map "\177" 'undefined)
 887
 888   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 889   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 890   (define-key hexl-mode-map "\C-d" 'undefined)
 891   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 892   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 893
 894   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 895       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 896
 897   (define-key hexl-mode-map "\C-k" 'undefined)
 898   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 899   (define-key hexl-mode-map "\C-o" 'undefined)
 900   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 901   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 902   (define-key hexl-mode-map "\C-t" 'undefined)
 903   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 904   (define-key hexl-mode-map "\C-w" 'undefined)
 905   (define-key hexl-mode-map "\C-y" 'undefined)
 906
 907   (fset 'hexl-ESC-prefix (copy-keymap 'ESC-prefix))
 908   (define-key hexl-mode-map "\e" 'hexl-ESC-prefix)
 909   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 910   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 911   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 912   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 913   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 914   (define-key hexl-mode-map "\e\C-i" 'undefined)
 915   (define-key hexl-mode-map "\e\C-j" 'undefined)
 916   (define-key hexl-mode-map "\e\C-k" 'undefined)
 917   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 918   (define-key hexl-mode-map "\e\C-q" 'undefined)
 919   (define-key hexl-mode-map "\e\C-t" 'undefined)
 920   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 921   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 922   (define-key hexl-mode-map "\ec" 'undefined)
 923   (define-key hexl-mode-map "\ed" 'undefined)
 924   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 925   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 926   (define-key hexl-mode-map "\ei" 'undefined)
 927   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 928   (define-key hexl-mode-map "\ek" 'undefined)
 929   (define-key hexl-mode-map "\el" 'undefined)
 930   (define-key hexl-mode-map "\eq" 'undefined)
 931   (define-key hexl-mode-map "\es" 'undefined)
 932   (define-key hexl-mode-map "\et" 'undefined)
 933   (define-key hexl-mode-map "\eu" 'undefined)
 934   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 935   (define-key hexl-mode-map "\ey" 'undefined)
 936   (define-key hexl-mode-map "\ez" 'undefined)
 937   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 938   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 939
 940   (fset 'hexl-C-c-prefix (copy-keymap mode-specific-map))
 941   (define-key hexl-mode-map "\C-c" 'hexl-C-c-prefix)
 942   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 943
 944   (fset 'hexl-C-x-prefix (copy-keymap 'Control-X-prefix))
 945   (define-key hexl-mode-map "\C-x" 'hexl-C-x-prefix)
 946   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 947   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 948   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 949   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 950   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 951
 952 (provide 'hexl)
 953
 954 ;;; hexl.el ends here