lisp/midnight.el

   1 ;;; midnight.el --- run something every midnight, e.g., kill old buffers  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1998, 2001-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Sam Steingold <sds@gnu.org>
   6 ;; Maintainer: Sam Steingold <sds@gnu.org>
   7 ;; Created: 1998-05-18
   8 ;; Keywords: utilities
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; To use the file, put (require 'midnight) into your .emacs.  Then, at
  28 ;; midnight, Emacs will run the normal hook `midnight-hook'.  You can
  29 ;; put whatever you like there, say, `calendar'; by default there is
  30 ;; only one function there - `clean-buffer-list'. It will kill the
  31 ;; buffers matching `clean-buffer-list-kill-buffer-names' and
  32 ;; `clean-buffer-list-kill-regexps' and the buffers which where last
  33 ;; displayed more than `clean-buffer-list-delay-general' days ago,
  34 ;; keeping `clean-buffer-list-kill-never-buffer-names' and
  35 ;; `clean-buffer-list-kill-never-regexps'.
  36
  37 ;;; Code:
  38
  39 (require 'cl-lib)
  40
  41 (defgroup midnight nil
  42   "Run something every day at midnight."
  43   :group 'calendar
  44   :version "20.3")
  45
  46 (defvar midnight-timer nil
  47   "Timer running the `midnight-hook' `midnight-delay' seconds after midnight.
  48 Use `cancel-timer' to stop it and `midnight-delay-set' to change
  49 the time when it is run.")
  50
  51 ;;;###autoload
  52 (define-minor-mode midnight-mode
  53   "Non-nil means run `midnight-hook' at midnight."
  54   :global t
  55   :initialize #'custom-initialize-default
  56   (if midnight-mode (timer-activate midnight-timer)
  57     (cancel-timer midnight-timer)))
  58
  59 ;;; time conversion
  60
  61 (defun midnight-buffer-display-time (buffer)
  62   "Return the time-stamp of BUFFER, or current buffer, as float."
  63   (with-current-buffer buffer
  64     (when buffer-display-time (float-time buffer-display-time))))
  65
  66 ;;; clean-buffer-list stuff
  67
  68 (defcustom clean-buffer-list-delay-general 3
  69   "The number of days before any buffer becomes eligible for autokilling.
  70 The autokilling is done by `clean-buffer-list' when is it in `midnight-hook'.
  71 Currently displayed and/or modified (unsaved) buffers, as well as buffers
  72 matching `clean-buffer-list-kill-never-buffer-names' and
  73 `clean-buffer-list-kill-never-regexps' are excluded."
  74   :type 'integer)
  75
  76 (defcustom clean-buffer-list-delay-special 3600
  77   "The number of seconds before some buffers become eligible for autokilling.
  78 Buffers matched by `clean-buffer-list-kill-regexps' and
  79 `clean-buffer-list-kill-buffer-names' are killed if they were last
  80 displayed more than this many seconds ago."
  81   :type 'integer)
  82
  83 (defcustom clean-buffer-list-kill-regexps '("\\`\\*Man ")
  84   "List of regexps saying which buffers will be killed at midnight.
  85 If buffer name matches a regexp in the list and the buffer was not displayed
  86 in the last `clean-buffer-list-delay-special' seconds, it is killed by
  87 `clean-buffer-list' when is it in `midnight-hook'.
  88 If a member of the list is a cons, its `car' is the regexp and its `cdr' is
  89 the number of seconds to use instead of `clean-buffer-list-delay-special'.
  90 See also `clean-buffer-list-kill-buffer-names',
  91 `clean-buffer-list-kill-never-regexps' and
  92 `clean-buffer-list-kill-never-buffer-names'.
  93
  94 Each element can also be a function instead of a regexp, in which case
  95 it takes a single argument (a buffer name) and should return non-nil
  96 if the buffer should be killed by `clean-buffer-list'."
  97   :type '(repeat
  98           (choice (regexp :tag "Regexp matching Buffer Name")
  99                   (function :tag "Predicate function"))))
 100
 101 (defcustom clean-buffer-list-kill-buffer-names
 102     '("*Help*" "*Apropos*" "*Buffer List*" "*Compile-Log*" "*info*"
 103       "*vc*" "*vc-diff*" "*diff*")
 104   "List of strings saying which buffers will be killed at midnight.
 105 Buffers with names in this list, which were not displayed in the last
 106 `clean-buffer-list-delay-special' seconds, are killed by `clean-buffer-list'
 107 when is it in `midnight-hook'.
 108 If a member of the list is a cons, its `car' is the name and its `cdr' is
 109 the number of seconds to use instead of `clean-buffer-list-delay-special'.
 110 See also `clean-buffer-list-kill-regexps',
 111 `clean-buffer-list-kill-never-regexps' and
 112 `clean-buffer-list-kill-never-buffer-names'."
 113   :type '(repeat (string :tag "Buffer Name")))
 114
 115 (defcustom clean-buffer-list-kill-never-buffer-names
 116     '("*scratch*" "*Messages*")
 117   "List of buffer names which will never be killed by `clean-buffer-list'.
 118 See also `clean-buffer-list-kill-never-regexps'.
 119 Note that this does override `clean-buffer-list-kill-regexps' and
 120 `clean-buffer-list-kill-buffer-names' so a buffer matching any of these
 121 two lists will NOT be killed if it is also present in this list."
 122   :type '(repeat (string :tag "Buffer Name")))
 123
 124 (defcustom clean-buffer-list-kill-never-regexps '("\\` \\*Minibuf-.*\\*\\'")
 125   "List of regexp saying which buffers will never be killed at midnight.
 126 See also `clean-buffer-list-kill-never-buffer-names'.
 127 Killing is done by `clean-buffer-list'.
 128 Note that this does override `clean-buffer-list-kill-regexps' and
 129 `clean-buffer-list-kill-buffer-names' so a buffer matching any of these
 130 two lists will NOT be killed if it also matches anything in this list.
 131
 132 Each element can also be a function instead of a regexp, in which case
 133 it takes a single argument (a buffer name) and should return non-nil
 134 if the buffer should never be killed by `clean-buffer-list'."
 135   :type '(repeat
 136           (choice (regexp :tag "Regexp matching Buffer Name")
 137                   (function :tag "Predicate function"))))
 138
 139 (defun clean-buffer-list-delay (name)
 140   "Return the delay, in seconds, before killing a buffer named NAME.
 141 Uses `clean-buffer-list-kill-buffer-names', `clean-buffer-list-kill-regexps'
 142 `clean-buffer-list-delay-general' and `clean-buffer-list-delay-special'.
 143 Autokilling is done by `clean-buffer-list'."
 144   (or (assoc-default name clean-buffer-list-kill-buffer-names #'string=
 145                      clean-buffer-list-delay-special)
 146       (assoc-default name clean-buffer-list-kill-regexps
 147                      (lambda (re str)
 148                        (if (functionp re)
 149                            (funcall re str) (string-match re str)))
 150                      clean-buffer-list-delay-special)
 151       (* clean-buffer-list-delay-general 24 60 60)))
 152
 153 ;;;###autoload
 154 (defun clean-buffer-list ()
 155   "Kill old buffers that have not been displayed recently.
 156 The relevant variables are `clean-buffer-list-delay-general',
 157 `clean-buffer-list-delay-special', `clean-buffer-list-kill-buffer-names',
 158 `clean-buffer-list-kill-never-buffer-names',
 159 `clean-buffer-list-kill-regexps' and
 160 `clean-buffer-list-kill-never-regexps'.
 161 While processing buffers, this procedure displays messages containing
 162 the current date/time, buffer name, how many seconds ago it was
 163 displayed (can be nil if the buffer was never displayed) and its
 164 lifetime, i.e., its \"age\" when it will be purged."
 165   (interactive)
 166   (let ((tm (float-time)) bts (ts (format-time-string "%Y-%m-%d %T"))
 167         delay cbld bn)
 168     (dolist (buf (buffer-list))
 169       (when (buffer-live-p buf)
 170         (setq bts (midnight-buffer-display-time buf) bn (buffer-name buf)
 171               delay (if bts (- tm bts) 0) cbld (clean-buffer-list-delay bn))
 172         (message "[%s] `%s' [%s %d]" ts bn (if bts (round delay)) cbld)
 173         (unless (or (cl-find bn clean-buffer-list-kill-never-regexps
 174                              :test (lambda (bn re)
 175                                      (if (functionp re)
 176                                          (funcall re bn)
 177                                        (string-match re bn))))
 178                     (cl-find bn clean-buffer-list-kill-never-buffer-names
 179                              :test #'string-equal)
 180                     (get-buffer-process buf)
 181                     (and (buffer-file-name buf) (buffer-modified-p buf))
 182                     (get-buffer-window buf 'visible) (< delay cbld))
 183           (message "[%s] killing `%s'" ts bn)
 184           (kill-buffer buf))))))
 185
 186 ;;; midnight hook
 187
 188 (defvar midnight-period (* 24 60 60)
 189   "The number of seconds in a day--the delta for `midnight-timer'.")
 190
 191 (defcustom midnight-hook '(clean-buffer-list)
 192   "The hook run `midnight-delay' seconds after midnight every day.
 193 The default value is `clean-buffer-list'."
 194   :type 'hook)
 195
 196 (defun midnight-next ()
 197   "Return the number of seconds till the next midnight."
 198   (pcase-let ((`(,sec ,min ,hrs) (decode-time)))
 199     (- (* 24 60 60) (* 60 60 hrs) (* 60 min) sec)))
 200
 201 ;;;###autoload
 202 (defun midnight-delay-set (symb tm)
 203   "Modify `midnight-timer' according to `midnight-delay'.
 204 Sets the first argument SYMB (which must be symbol `midnight-delay')
 205 to its second argument TM."
 206   (cl-assert (eq symb 'midnight-delay) t
 207              "Invalid argument to `midnight-delay-set': `%s'")
 208   (set symb tm)
 209   (when (timerp midnight-timer) (cancel-timer midnight-timer))
 210   (setq midnight-timer
 211         (run-at-time (if (numberp tm) (+ (midnight-next) tm) tm)
 212                      midnight-period #'run-hooks 'midnight-hook)))
 213
 214 (defcustom midnight-delay 3600
 215   "The number of seconds after the midnight when the `midnight-timer' is run.
 216 You should set this variable before loading midnight.el, or
 217 set it by calling `midnight-delay-set', or use `custom'.
 218 If you wish, you can use a string instead, it will be passed as the
 219 first argument to `run-at-time'."
 220   :type 'sexp
 221   :set #'midnight-delay-set)
 222
 223 (provide 'midnight)
 224
 225 ;;; midnight.el ends here