lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing
   2
   3 ;; Copyright (C) 1985, 1989, 1994-1995, 1997, 2000-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: Inge Frick <inge@nada.kth.se>
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the `view' minor mode documented in the Emacs
  28 ;; user's manual.
  29 ;; View mode entry and exit is done through the functions view-mode-enter
  30 ;; and view-mode-exit.  Use these functions to enter or exit view-mode from
  31 ;; emacs lisp programs.
  32 ;; We use both view- and View- as prefix for symbols.  View- is used as
  33 ;; prefix for commands that have a key binding.  view- is used for commands
  34 ;; without key binding.  The purpose of this is to make it easier for a
  35 ;; user to use command name completion.
  36
  37 ;;; Suggested key bindings:
  38 ;;
  39 ;; (define-key ctl-x-4-map "v" 'view-file-other-window)  ; ^x4v
  40 ;; (define-key ctl-x-5-map "v" 'view-file-other-frame)  ; ^x5v
  41 ;;
  42 ;; You could also bind view-file, view-buffer, view-buffer-other-window and
  43 ;; view-buffer-other-frame to keys.
  44 \f
  45 ;;; Code:
  46
  47 (defgroup view nil
  48   "Peruse file or buffer without editing."
  49   :link '(function-link view-mode)
  50   :link '(custom-manual "(emacs)Misc File Ops")
  51   :group 'wp)
  52
  53 (defcustom view-highlight-face 'highlight
  54    "The face used for highlighting the match found by View mode search."
  55    :type 'face
  56    :group 'view)
  57
  58 (defcustom view-scroll-auto-exit nil
  59   "Non-nil means scrolling past the end of buffer exits View mode.
  60 A value of nil means attempting to scroll past the end of the buffer,
  61 only rings the bell and gives a message on how to leave."
  62   :type 'boolean
  63   :group 'view)
  64
  65 (defcustom view-try-extend-at-buffer-end nil
  66  "Non-nil means try to load more of file when reaching end of buffer.
  67 This variable is mainly intended to be temporarily set to non-nil by
  68 the F command in view-mode, but you can set it to t if you want the action
  69 for all scroll commands in view mode."
  70   :type 'boolean
  71   :group 'view)
  72
  73 ;;;###autoload
  74 (defcustom view-remove-frame-by-deleting t
  75   "Determine how View mode removes a frame no longer needed.
  76 If nil, make an icon of the frame.  If non-nil, delete the frame."
  77   :type 'boolean
  78   :group 'view
  79   :version "23.1")
  80
  81 (defcustom view-exits-all-viewing-windows nil
  82   "Non-nil means restore all windows used to view buffer.
  83 Commands that restore windows when finished viewing a buffer,
  84 apply to all windows that display the buffer and have restore
  85 information.  If `view-exits-all-viewing-windows' is nil, only
  86 the selected window is considered for restoring."
  87   :type 'boolean
  88   :group 'view)
  89
  90 (defcustom view-inhibit-help-message nil
  91   "Non-nil inhibits the help message shown upon entering View mode."
  92   :type 'boolean
  93   :group 'view
  94   :version "22.1")
  95
  96 ;;;###autoload
  97 (defvar view-mode nil
  98   "Non-nil if View mode is enabled.
  99 Don't change this variable directly, you must change it by one of the
 100 functions that enable or disable view mode.")
 101 ;;;###autoload
 102 (make-variable-buffer-local 'view-mode)
 103
 104 (defcustom view-mode-hook nil
 105   "Normal hook run when starting to view a buffer or file."
 106   :type 'hook
 107   :group 'view)
 108 \f
 109 (defvar view-old-buffer-read-only nil)
 110 (make-variable-buffer-local 'view-old-buffer-read-only)
 111
 112 (defvar view-old-Helper-return-blurb)
 113 (make-variable-buffer-local 'view-old-Helper-return-blurb)
 114
 115 (defvar view-page-size nil
 116   "Default number of lines to scroll by View page commands.
 117 If nil that means use the window size.")
 118 (make-variable-buffer-local 'view-page-size)
 119
 120 (defvar view-half-page-size nil
 121   "Default number of lines to scroll by View half page commands.
 122 If nil that means use half the window size.")
 123 (make-variable-buffer-local 'view-half-page-size)
 124
 125 (defvar view-last-regexp nil)
 126 (make-variable-buffer-local 'view-last-regexp) ; Global is better???
 127
 128 (defvar view-return-to-alist nil
 129   "What to do with used windows and where to go when finished viewing buffer.
 130 This is local in each buffer being viewed.
 131 It is added to by `view-mode-enter' when starting to view a buffer and
 132 subtracted from by `view-mode-exit' when finished viewing the buffer.
 133
 134 See RETURN-TO-ALIST argument of function `view-mode-exit' for the format of
 135 `view-return-to-alist'.")
 136 (make-obsolete-variable
 137  'view-return-to-alist "this variable is no more used." "24.1")
 138 (make-variable-buffer-local 'view-return-to-alist)
 139 (put 'view-return-to-alist 'permanent-local t)
 140
 141 (defvar view-exit-action nil
 142   "If non-nil, a function with one argument (a buffer) called when finished viewing.
 143 Commands like \\[view-file] and \\[view-file-other-window] may
 144 set this to bury or kill the viewed buffer.
 145 Observe that the buffer viewed might not appear in any window at
 146 the time this function is called.")
 147 (make-variable-buffer-local 'view-exit-action)
 148
 149 (defvar view-no-disable-on-exit nil
 150   "If non-nil, View mode \"exit\" commands don't actually disable View mode.
 151 Instead, these commands just switch buffers or windows.
 152 This is set in certain buffers by specialized features such as help commands
 153 that use View mode automatically.")
 154
 155 (defvar view-overlay nil
 156   "Overlay used to display where a search operation found its match.
 157 This is local in each buffer, once it is used.")
 158 (make-variable-buffer-local 'view-overlay)
 159 \f
 160 ;; Define keymap inside defvar to make it easier to load changes.
 161 ;; Some redundant "less"-like key bindings below have been commented out.
 162 (defvar view-mode-map
 163   (let ((map (make-sparse-keymap)))
 164     (define-key map "C" 'View-kill-and-leave)
 165     (define-key map "c" 'View-leave)
 166     (define-key map "Q" 'View-quit-all)
 167     (define-key map "E" 'View-exit-and-edit)
 168     ;; (define-key map "v" 'View-exit)
 169     (define-key map "e" 'View-exit)
 170     (define-key map "q" 'View-quit)
 171     ;; (define-key map "N" 'View-search-last-regexp-backward)
 172     (define-key map "p" 'View-search-last-regexp-backward)
 173     (define-key map "n" 'View-search-last-regexp-forward)
 174     ;; (define-key map "?" 'View-search-regexp-backward) ; Less does this.
 175     (define-key map "\\" 'View-search-regexp-backward)
 176     (define-key map "/" 'View-search-regexp-forward)
 177     (define-key map "r" 'isearch-backward)
 178     (define-key map "s" 'isearch-forward)
 179     (define-key map "m" 'point-to-register)
 180     (define-key map "'" 'register-to-point)
 181     (define-key map "x" 'exchange-point-and-mark)
 182     (define-key map "@" 'View-back-to-mark)
 183     (define-key map "." 'set-mark-command)
 184     (define-key map "%" 'View-goto-percent)
 185     ;; (define-key map "G" 'View-goto-line-last)
 186     (define-key map "g" 'View-goto-line)
 187     (define-key map "=" 'what-line)
 188     (define-key map "F" 'View-revert-buffer-scroll-page-forward)
 189     ;; (define-key map "k" 'View-scroll-line-backward)
 190     (define-key map "y" 'View-scroll-line-backward)
 191     ;; (define-key map "j" 'View-scroll-line-forward)
 192     (define-key map "\n" 'View-scroll-line-forward)
 193     (define-key map "\r" 'View-scroll-line-forward)
 194     (define-key map "u" 'View-scroll-half-page-backward)
 195     (define-key map "d" 'View-scroll-half-page-forward)
 196     (define-key map "z" 'View-scroll-page-forward-set-page-size)
 197     (define-key map "w" 'View-scroll-page-backward-set-page-size)
 198     ;; (define-key map "b" 'View-scroll-page-backward)
 199     (define-key map "\C-?" 'View-scroll-page-backward)
 200     ;; (define-key map "f" 'View-scroll-page-forward)
 201     (define-key map " " 'View-scroll-page-forward)
 202     (define-key map "o" 'View-scroll-to-buffer-end)
 203     (define-key map ">" 'end-of-buffer)
 204     (define-key map "<" 'beginning-of-buffer)
 205     (define-key map "-" 'negative-argument)
 206     (define-key map "9" 'digit-argument)
 207     (define-key map "8" 'digit-argument)
 208     (define-key map "7" 'digit-argument)
 209     (define-key map "6" 'digit-argument)
 210     (define-key map "5" 'digit-argument)
 211     (define-key map "4" 'digit-argument)
 212     (define-key map "3" 'digit-argument)
 213     (define-key map "2" 'digit-argument)
 214     (define-key map "1" 'digit-argument)
 215     (define-key map "0" 'digit-argument)
 216     (define-key map "H" 'describe-mode)
 217     (define-key map "?" 'describe-mode) ; Maybe do as less instead? See above.
 218     (define-key map "h" 'describe-mode)
 219     map))
 220 \f
 221 ;;; Commands that enter or exit view mode.
 222
 223 ;; This is used when view mode is exited, to make sure we don't try to
 224 ;; kill a buffer modified by the user.  A buffer in view mode can
 225 ;; become modified if the user types C-x C-q, edits the buffer, then
 226 ;; types C-x C-q again to return to view mode.
 227 ;;;###autoload
 228 (defun kill-buffer-if-not-modified (buf)
 229   "Like `kill-buffer', but does nothing if the buffer is modified."
 230   (let ((buf (get-buffer buf)))
 231     (and buf (not (buffer-modified-p buf))
 232          (kill-buffer buf))))
 233
 234 ;;;###autoload
 235 (defun view-file (file)
 236   "View FILE in View mode, returning to previous buffer when done.
 237 Emacs commands editing the buffer contents are not available; instead, a
 238 special set of commands (mostly letters and punctuation) are defined for
 239 moving around in the buffer.
 240 Space scrolls forward, Delete scrolls backward.
 241 For a list of all View commands, type H or h while viewing.
 242
 243 This command runs the normal hook `view-mode-hook'."
 244   (interactive "fView file: ")
 245   (unless (file-exists-p file) (error "%s does not exist" file))
 246   (let ((had-a-buf (get-file-buffer file))
 247         (buffer (find-file-noselect file)))
 248     (view-buffer buffer (and (not had-a-buf) 'kill-buffer-if-not-modified))))
 249
 250 ;;;###autoload
 251 (defun view-file-other-window (file)
 252   "View FILE in View mode in another window.
 253 When done, return that window to its previous buffer, and kill the
 254 buffer visiting FILE if unmodified and if it wasn't visited before.
 255
 256 Emacs commands editing the buffer contents are not available; instead,
 257 a special set of commands (mostly letters and punctuation)
 258 are defined for moving around in the buffer.
 259 Space scrolls forward, Delete scrolls backward.
 260 For a list of all View commands, type H or h while viewing.
 261
 262 This command runs the normal hook `view-mode-hook'."
 263   (interactive "fIn other window view file: ")
 264   (unless (file-exists-p file) (error "%s does not exist" file))
 265   (let ((had-a-buf (get-file-buffer file))
 266         (buf-to-view (find-file-noselect file)))
 267     (view-buffer-other-window buf-to-view nil
 268                               (and (not had-a-buf)
 269                                    'kill-buffer-if-not-modified))))
 270
 271 ;;;###autoload
 272 (defun view-file-other-frame (file)
 273   "View FILE in View mode in another frame.
 274 When done, kill the buffer visiting FILE if unmodified and if it wasn't
 275 visited before; also, maybe delete other frame and/or return to previous
 276 buffer.
 277
 278 Emacs commands editing the buffer contents are not available; instead,
 279 a special set of commands (mostly letters and punctuation)
 280 are defined for moving around in the buffer.
 281 Space scrolls forward, Delete scrolls backward.
 282 For a list of all View commands, type H or h while viewing.
 283
 284 This command runs the normal hook `view-mode-hook'."
 285   (interactive "fIn other frame view file: ")
 286   (unless (file-exists-p file) (error "%s does not exist" file))
 287   (let ((had-a-buf (get-file-buffer file))
 288         (buf-to-view (find-file-noselect file)))
 289     (view-buffer-other-frame buf-to-view nil
 290                              (and (not had-a-buf)
 291                                   'kill-buffer-if-not-modified))))
 292
 293
 294 ;;;###autoload
 295 (defun view-buffer (buffer &optional exit-action)
 296   "View BUFFER in View mode, returning to previous buffer when done.
 297 Emacs commands editing the buffer contents are not available; instead, a
 298 special set of commands (mostly letters and punctuation) are defined for
 299 moving around in the buffer.
 300 Space scrolls forward, Delete scrolls backward.
 301 For a list of all View commands, type H or h while viewing.
 302
 303 This command runs the normal hook `view-mode-hook'.
 304
 305 Optional argument EXIT-ACTION is either nil or a function with buffer as
 306 argument.  This function is called when finished viewing buffer.  Use
 307 this argument instead of explicitly setting `view-exit-action'.
 308
 309 Do not set EXIT-ACTION to `kill-buffer' when BUFFER visits a
 310 file: Users may suspend viewing in order to modify the buffer.
 311 Exiting View mode will then discard the user's edits.  Setting
 312 EXIT-ACTION to `kill-buffer-if-not-modified' avoids this."
 313   (interactive "bView buffer: ")
 314   (switch-to-buffer buffer)
 315   (if (eq (get major-mode 'mode-class) 'special)
 316       (message "Not using View mode because the major mode is special")
 317     (view-mode-enter nil exit-action)))
 318
 319 ;;;###autoload
 320 (defun view-buffer-other-window (buffer &optional not-return exit-action)
 321   "View BUFFER in View mode in another window.
 322 Emacs commands editing the buffer contents are not available;
 323 instead, a special set of commands (mostly letters and
 324 punctuation) are defined for moving around in the buffer.
 325 Space scrolls forward, Delete scrolls backward.
 326 For a list of all View commands, type H or h while viewing.
 327
 328 This command runs the normal hook `view-mode-hook'.
 329
 330 Optional argument NOT-RETURN is ignored.
 331
 332 Optional argument EXIT-ACTION is either nil or a function with buffer as
 333 argument.  This function is called when finished viewing buffer.  Use
 334 this argument instead of explicitly setting `view-exit-action'."
 335   (interactive "bIn other window view buffer:\nP")
 336   (let ((pop-up-windows t))
 337     (pop-to-buffer buffer t))
 338   (if (eq (get major-mode 'mode-class) 'special)
 339       (message "Not using View mode because the major mode is special")
 340     (view-mode-enter nil exit-action)))
 341
 342 ;;;###autoload
 343 (defun view-buffer-other-frame (buffer &optional not-return exit-action)
 344   "View BUFFER in View mode in another frame.
 345 Emacs commands editing the buffer contents are not available;
 346 instead, a special set of commands (mostly letters and
 347 punctuation) are defined for moving around in the buffer.
 348 Space scrolls forward, Delete scrolls backward.
 349 For a list of all View commands, type H or h while viewing.
 350
 351 This command runs the normal hook `view-mode-hook'.
 352
 353 Optional argument NOT-RETURN is ignored.
 354
 355 Optional argument EXIT-ACTION is either nil or a function with buffer as
 356 argument.  This function is called when finished viewing buffer.  Use
 357 this argument instead of explicitly setting `view-exit-action'."
 358   (interactive "bView buffer in other frame: \nP")
 359   (let ((pop-up-frames t))
 360     (pop-to-buffer buffer t))
 361   (if (eq (get major-mode 'mode-class) 'special)
 362       (message "Not using View mode because the major mode is special")
 363     (view-mode-enter nil exit-action)))
 364 \f
 365 ;;;###autoload
 366 (define-minor-mode view-mode
 367   ;; In the following documentation string we have to use some explicit key
 368   ;; bindings instead of using the \\[] construction.  The reason for this
 369   ;; is that most commands have more than one key binding.
 370   "Toggle View mode, a minor mode for viewing text but not editing it.
 371 With a prefix argument ARG, enable View mode if ARG is positive,
 372 and disable it otherwise.  If called from Lisp, enable View mode
 373 if ARG is omitted or nil.
 374
 375 When View mode is enabled, commands that do not change the buffer
 376 contents are available as usual.  Kill commands insert text in
 377 kill buffers but do not delete.  Most other commands beep and
 378 tell the user that the buffer is read-only.
 379
 380 \\<view-mode-map>
 381
 382 The following additional commands are provided.  Most commands
 383 take prefix arguments.  Page commands default to \"page size\"
 384 lines which is almost a whole window, or number of lines set by
 385 \\[View-scroll-page-forward-set-page-size] or \\[View-scroll-page-backward-set-page-size].
 386 Half page commands default to and set \"half page size\" lines
 387 which initially is half a window full.  Search commands default
 388 to a repeat count of one.
 389
 390 H, h, ?  This message.
 391 Digits  provide prefix arguments.
 392 \\[negative-argument]   negative prefix argument.
 393 \\[beginning-of-buffer] move to the beginning of buffer.
 394 >       move to the end of buffer.
 395 \\[View-scroll-to-buffer-end]   scroll so that buffer end is at last line of window.
 396 SPC     scroll forward \"page size\" lines.
 397           With prefix scroll forward prefix lines.
 398 DEL     scroll backward \"page size\" lines.
 399           With prefix scroll backward prefix lines.
 400 \\[View-scroll-page-forward-set-page-size]      like  \\[View-scroll-page-forward]  but with prefix sets \"page size\" to prefix.
 401 \\[View-scroll-page-backward-set-page-size]     like  \\[View-scroll-page-backward]  but with prefix sets \"page size\" to prefix.
 402 \\[View-scroll-half-page-forward]       scroll forward \"half page size\" lines.  With prefix, sets
 403           \"half page size\" to prefix lines and scrolls forward that much.
 404 \\[View-scroll-half-page-backward]      scroll backward \"half page size\" lines.  With prefix, sets
 405           \"half page size\" to prefix lines and scrolls backward that much.
 406 RET, LFD  scroll forward one line.  With prefix scroll forward prefix line(s).
 407 y       scroll backward one line.  With prefix scroll backward prefix line(s).
 408 \\[View-revert-buffer-scroll-page-forward]      revert-buffer if necessary and scroll forward.
 409           Use this to view a changing file.
 410 \\[what-line]   prints the current line number.
 411 \\[View-goto-percent]   goes prefix argument (default 100) percent into buffer.
 412 \\[View-goto-line]      goes to line given by prefix argument (default first line).
 413 .       set the mark.
 414 x       exchanges point and mark.
 415 \\[View-back-to-mark]   return to mark and pops mark ring.
 416           Mark ring is pushed at start of every successful search and when
 417           jump to line occurs.  The mark is set on jump to buffer start or end.
 418 \\[point-to-register]   save current position in character register.
 419 '       go to position saved in character register.
 420 s       do forward incremental search.
 421 r       do reverse incremental search.
 422 \\[View-search-regexp-forward]  searches forward for regular expression, starting after current page.
 423           ! and @ have a special meaning at the beginning of the regexp.
 424           ! means search for a line with no match for regexp.  @ means start
 425           search at beginning (end for backward search) of buffer.
 426 \\      searches backward for regular expression, starting before current page.
 427 \\[View-search-last-regexp-forward]     searches forward for last regular expression.
 428 p       searches backward for last regular expression.
 429 \\[View-quit]   quit View mode, restoring this window and buffer to previous state.
 430           \\[View-quit] is the normal way to leave view mode.
 431 \\[View-exit]   exit View mode but stay in current buffer.  Use this if you started
 432           viewing a buffer (file) and find out you want to edit it.
 433           This command restores the previous read-only status of the buffer.
 434 \\[View-exit-and-edit]  exit View mode, and make the current buffer editable
 435           even if it was not editable before entry to View mode.
 436 \\[View-quit-all]       quit View mode, restoring all windows to previous state.
 437 \\[View-leave]  quit View mode and maybe switch buffers, but don't kill this buffer.
 438 \\[View-kill-and-leave] quit View mode, kill current buffer and go back to other buffer.
 439
 440 The effect of \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] depends on how view-mode was entered.  If it was
 441 entered by view-file, view-file-other-window, view-file-other-frame, or
 442 \\[dired-view-file] \(\\[view-file], \\[view-file-other-window],
 443 \\[view-file-other-frame], or the Dired mode v command),
 444 then \\[View-quit] will try to kill the current buffer.
 445 If view-mode was entered from another buffer, by \\[view-buffer],
 446 \\[view-buffer-other-window], \\[view-buffer-other frame], \\[view-file],
 447 \\[view-file-other-window], or \\[view-file-other-frame],
 448 then \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] will return to that buffer.
 449
 450 Entry to view-mode runs the normal hook `view-mode-hook'."
 451   :lighter " View" :keymap view-mode-map
 452   (if view-mode (view-mode-enable) (view-mode-disable)))
 453 \f
 454 (defun view-mode-enable ()
 455   "Turn on View mode."
 456   ;; Always leave view mode before changing major mode.
 457   ;; This is to guarantee that the buffer-read-only variable is restored.
 458   (add-hook 'change-major-mode-hook 'view-mode-disable nil t)
 459   (setq view-mode t
 460         view-page-size nil
 461         view-half-page-size nil
 462         view-old-buffer-read-only buffer-read-only
 463         buffer-read-only t)
 464   (if (boundp 'Helper-return-blurb)
 465       (setq view-old-Helper-return-blurb (and (boundp 'Helper-return-blurb)
 466                                               Helper-return-blurb)
 467             Helper-return-blurb
 468             (format "continue viewing %s"
 469                     (if (buffer-file-name)
 470                         (file-name-nondirectory (buffer-file-name))
 471                       (buffer-name)))))
 472   (force-mode-line-update)
 473   (run-hooks 'view-mode-hook))
 474
 475 (defun view-mode-disable ()
 476   "Turn off View mode."
 477   (remove-hook 'change-major-mode-hook 'view-mode-disable t)
 478   (and view-overlay (delete-overlay view-overlay))
 479   (force-mode-line-update)
 480   ;; Calling toggle-read-only while View mode is enabled
 481   ;; sets view-read-only to t as a buffer-local variable
 482   ;; after exiting View mode.  That arranges that the next toggle-read-only
 483   ;; will reenable View mode.
 484   ;; Canceling View mode in any other way should cancel that, too,
 485   ;; so that View mode stays off if toggle-read-only is called.
 486   (if (local-variable-p 'view-read-only)
 487       (kill-local-variable 'view-read-only))
 488   (setq view-mode nil)
 489   (if (boundp 'Helper-return-blurb)
 490       (setq Helper-return-blurb view-old-Helper-return-blurb))
 491   (if buffer-read-only
 492       (setq buffer-read-only view-old-buffer-read-only)))
 493
 494 ;;;###autoload
 495 (defun view-return-to-alist-update (buffer &optional item)
 496   "Update `view-return-to-alist' of buffer BUFFER.
 497 Remove from `view-return-to-alist' all entries referencing dead
 498 windows.  Optional argument ITEM non-nil means add ITEM to
 499 `view-return-to-alist' after purging.  For a description of items
 500 that can be added see the RETURN-TO-ALIST argument of the
 501 function `view-mode-exit'.  If `view-return-to-alist' contains an
 502 entry for the selected window, purge that entry from
 503 `view-return-to-alist' before adding ITEM."
 504   (with-current-buffer buffer
 505     (when view-return-to-alist
 506       (let* ((list view-return-to-alist)
 507              entry entry-window last)
 508         (while list
 509           (setq entry (car list))
 510           (setq entry-window (car entry))
 511           (if (and (windowp entry-window)
 512                    (or (and item (eq entry-window (selected-window)))
 513                        (not (window-live-p entry-window))))
 514               ;; Remove that entry.
 515               (if last
 516                   (setcdr last (cdr list))
 517                 (setq view-return-to-alist
 518                       (cdr view-return-to-alist)))
 519             ;; Leave entry alone.
 520             (setq last entry))
 521           (setq list (cdr list)))))
 522     ;; Add ITEM.
 523     (when item
 524       (setq view-return-to-alist
 525             (cons item view-return-to-alist)))))
 526 (make-obsolete 'view-return-to-alist-update "this function has no effect." "24.1")
 527
 528 ;;;###autoload
 529 (defun view-mode-enter (&optional quit-restore exit-action)
 530   "Enter View mode and set up exit from view mode depending on optional arguments.
 531 Optional argument QUIT-RESTORE if non-nil must specify a valid
 532 entry for quitting and restoring any window showing the current
 533 buffer.  This entry replaces any parameter installed by
 534 `display-buffer' and is used by `view-mode-exit'.
 535
 536 Optional argument EXIT-ACTION, if non-nil, must specify a
 537 function that takes a buffer as argument.  This function will be
 538 called by `view-mode-exit'.
 539
 540 For a list of all View commands, type H or h while viewing.
 541
 542 This function runs the normal hook `view-mode-hook'."
 543   (when quit-restore
 544     (dolist (window (get-buffer-window-list nil nil t))
 545       (set-window-parameter window 'quit-restore quit-restore)))
 546
 547   (when exit-action
 548     (setq view-exit-action exit-action))
 549
 550   (unless view-mode
 551     (view-mode-enable)
 552     (force-mode-line-update)
 553     (unless view-inhibit-help-message
 554       (message "%s"
 555                (substitute-command-keys "\
 556 View mode: type \\[help-command] for help, \\[describe-mode] for commands, \\[View-quit] to quit.")))))
 557 \f
 558 ;; This is awful because it assumes that the selected window shows the
 559 ;; current buffer when this is called.
 560 (defun view-mode-exit (&optional exit-only exit-action all-windows)
 561   "Exit View mode in various ways.
 562 If all arguments are nil, remove the current buffer from the
 563 selected window using the `quit-restore' information associated
 564 with the selected window.  If optional argument ALL-WINDOWS or
 565 `view-exits-all-viewing-windows' are non-nil, remove the current
 566 buffer from all windows showing it.
 567
 568 Optional argument EXIT-ONLY non-nil means just exit `view-mode'
 569 \(unless `view-no-disable-on-exit' is non-nil) but do not change
 570 the associations of any windows with the current buffer.
 571
 572 EXIT-ACTION, if non-nil, must specify a function that is called
 573 with the current buffer as argument and is called after disabling
 574 `view-mode' and removing any associations of windows with the
 575 current buffer. "
 576   (when view-mode
 577     (let ((buffer (window-buffer)))
 578       (unless view-no-disable-on-exit
 579         (view-mode-disable))
 580
 581       (unless exit-only
 582         (cond
 583          ((or all-windows view-exits-all-viewing-windows)
 584           (dolist (window (get-buffer-window-list))
 585             (quit-window nil window)))
 586          ((eq (window-buffer) (current-buffer))
 587           (quit-window)))
 588
 589         (when exit-action
 590           (funcall exit-action buffer))
 591         (force-mode-line-update)))))
 592 \f
 593 (defun View-exit ()
 594   "Exit View mode but stay in current buffer."
 595   (interactive)
 596   (view-mode-exit t))
 597
 598 ;;;###autoload
 599 (defun View-exit-and-edit ()
 600   "Exit View mode and make the current buffer editable."
 601   (interactive)
 602   (let ((view-old-buffer-read-only nil)
 603         (view-no-disable-on-exit nil))
 604     (view-mode-exit t)))
 605
 606 (defun View-leave ()
 607   "Quit View mode and maybe switch buffers, but don't kill this buffer."
 608   (interactive)
 609   (view-mode-exit))
 610
 611 (defun View-quit ()
 612   "Quit View mode, trying to restore window and buffer to previous state.
 613 Maybe kill this buffer.  Try to restore selected window to previous state
 614 and go to previous buffer or window."
 615   (interactive)
 616   (view-mode-exit nil view-exit-action))
 617
 618 (defun View-quit-all ()
 619   "Quit View mode, trying to restore windows and buffers to previous state.
 620 Maybe kill current buffer.  Try to restore all windows viewing buffer to
 621 previous state and go to previous buffer or window."
 622   (interactive)
 623   (view-mode-exit nil view-exit-action t))
 624
 625 (defun View-kill-and-leave ()
 626   "Quit View mode, kill current buffer and return to previous buffer."
 627   (interactive)
 628   (view-mode-exit nil (or view-exit-action 'kill-buffer) t))
 629 \f
 630
 631 ;;; Some help routines.
 632
 633 (defun view-window-size ()
 634   ;; Return the height of the current window, excluding the mode line.
 635   ;; Using `window-line-height' accounts for variable-height fonts.
 636   (let ((h (window-line-height -1)))
 637     (if h
 638         (1+ (nth 1 h))
 639       ;; This should not happen, but if `window-line-height' returns
 640       ;; nil, fall back on `window-height'.
 641       (1- (window-height)))))
 642
 643 ;; (defun view-last-command (&optional who what)
 644 ;;  (setq view-last-command-entry this-command)
 645 ;;  (setq view-last-command who)
 646 ;;  (setq view-last-command-argument what))
 647
 648 ;; (defun View-repeat-last-command ()
 649 ;;  "Repeat last command issued in View mode."
 650 ;;  (interactive)
 651 ;;  (if (and view-last-command
 652 ;;         (eq view-last-command-entry last-command))
 653 ;;      (funcall view-last-command view-last-command-argument))
 654 ;;  (setq this-command view-last-command-entry))
 655
 656 (defun view-recenter ()
 657   ;; Recenter point in window and redisplay normally.
 658   (recenter '(1)))
 659
 660 (defun view-page-size-default (lines)
 661   ;; If LINES is nil, 0, or larger than `view-window-size', return nil.
 662   ;; Otherwise, return LINES.
 663   (and lines
 664        (not (zerop (setq lines (prefix-numeric-value lines))))
 665        (<= (abs lines)
 666            (abs (- (view-window-size) next-screen-context-lines)))
 667        (abs lines)))
 668
 669 (defun view-set-half-page-size-default (lines)
 670   ;; Get and maybe set half page size.
 671   (if (not lines) (or view-half-page-size
 672                       (/ (view-window-size) 2))
 673     (setq view-half-page-size
 674           (if (zerop (setq lines (prefix-numeric-value lines)))
 675               (/ (view-window-size) 2)
 676             (view-page-size-default lines)))))
 677
 678
 679 ;;; Commands for moving around in the buffer.
 680
 681 (defun View-goto-percent (&optional percent)
 682   "Move to end (or prefix PERCENT) of buffer in View mode.
 683 Display is centered at point.
 684 Also set the mark at the position where point was."
 685   (interactive "P")
 686   (push-mark)
 687   (goto-char
 688    (if percent
 689        (+ (point-min)
 690           (floor (* (- (point-max) (point-min)) 0.01
 691                     (max 0 (min 100 (prefix-numeric-value percent))))))
 692      (point-max)))
 693   (view-recenter))
 694
 695 ;; (defun View-goto-line-last (&optional line)
 696 ;; "Move to last (or prefix LINE) line in View mode.
 697 ;; Display is centered at LINE.
 698 ;; Sets mark at starting position and pushes mark ring."
 699 ;;  (interactive "P")
 700 ;;  (push-mark)
 701 ;;  (if line (goto-line (prefix-numeric-value line))
 702 ;;    (goto-char (point-max))
 703 ;;    (beginning-of-line))
 704 ;;  (view-recenter))
 705
 706 (defun View-goto-line (&optional line)
 707   "Move to first (or prefix LINE) line in View mode.
 708 Display is centered at LINE.
 709 Also set the mark at the position where point was."
 710   (interactive "p")
 711   (push-mark)
 712   (goto-char (point-min))
 713   (forward-line (1- line))
 714   (view-recenter))
 715
 716 (defun View-back-to-mark (&optional _ignore)
 717   "Return to last mark set in View mode, else beginning of file.
 718 Display that line at the center of the window.
 719 This command pops the mark ring, so that successive
 720 invocations return to earlier marks."
 721   (interactive)
 722   (goto-char (or (mark t) (point-min)))
 723   (pop-mark)
 724   (view-recenter))
 725 \f
 726 (defun view-scroll-lines (lines backward default maxdefault)
 727   ;; This function does the job for all the scrolling commands.
 728   ;; Scroll forward LINES lines.  If BACKWARD is non-nil, scroll backwards.
 729   ;; If LINES is negative scroll in the other direction.
 730   ;; If LINES is 0 or nil, scroll DEFAULT lines (if DEFAULT is nil, scroll
 731   ;; by one page).  If MAXDEFAULT is non-nil, scroll no more than a window.
 732   (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 733       (setq lines default))
 734   (when (and lines (< lines 0))
 735     (setq backward (not backward) lines (- lines)))
 736   (when (and maxdefault lines (> lines (view-window-size)))
 737     (setq lines nil))
 738   (cond (backward (scroll-down lines))
 739         ((view-really-at-end)
 740          (if view-scroll-auto-exit
 741              (View-quit)
 742            (ding)
 743            (view-end-message)))
 744         (t (scroll-up lines)
 745            (if (view-really-at-end) (view-end-message)))))
 746
 747 (defun view-really-at-end ()
 748   ;; Return true if buffer end visible.  Maybe revert buffer and test.
 749   (and (pos-visible-in-window-p (point-max))
 750        (let ((buf (current-buffer))
 751              (bufname (buffer-name))
 752              (file (buffer-file-name)))
 753          (or (not view-try-extend-at-buffer-end)
 754              (null file)
 755              (verify-visited-file-modtime buf)
 756              (not (file-exists-p file))
 757              (when (buffer-modified-p buf)
 758                (setq file (file-name-nondirectory file))
 759                (not (yes-or-no-p
 760                      (format
 761                       "File %s changed on disk.  Discard your edits%s? "
 762                       file
 763                       (if (string= bufname file) ""
 764                         (concat " in " bufname))))))
 765              (progn
 766                (revert-buffer t t t)
 767                (pos-visible-in-window-p (point-max)))))))
 768
 769 (defun view-end-message ()
 770   ;; Tell that we are at end of buffer.
 771   (goto-char (point-max))
 772   (if (window-parameter nil 'quit-restore)
 773       (message "End of buffer.  Type %s to quit viewing."
 774                (substitute-command-keys
 775                 (if view-scroll-auto-exit "\\[View-scroll-page-forward]"
 776                   "\\[View-quit]")))
 777     (message "End of buffer")))
 778 \f
 779 (defun View-scroll-to-buffer-end ()
 780   "Scroll backward or forward so that buffer end is at last line of window."
 781   (interactive)
 782   (let ((p (if (pos-visible-in-window-p (point-max)) (point))))
 783     (goto-char (point-max))
 784     (recenter -1)
 785     (and p (goto-char p))))
 786
 787 (defun View-scroll-page-forward (&optional lines)
 788   "Scroll \"page size\" or prefix LINES lines forward in View mode.
 789 Exit if end of text is visible and `view-scroll-auto-exit' is non-nil.
 790 \"page size\" is whole window full, or number of lines set by
 791 \\[View-scroll-page-forward-set-page-size] or
 792 \\[View-scroll-page-backward-set-page-size].
 793 If LINES is more than a window-full, only the last window-full is shown."
 794   (interactive "P")
 795   (view-scroll-lines lines nil (view-page-size-default view-page-size) nil))
 796
 797 (defun View-scroll-page-backward (&optional lines)
 798   "Scroll \"page size\" or prefix LINES lines backward in View mode.
 799 See also `View-scroll-page-forward'."
 800   (interactive "P")
 801   (view-scroll-lines lines t (view-page-size-default view-page-size) nil))
 802
 803 (defun View-scroll-page-forward-set-page-size (&optional lines)
 804   "Scroll forward LINES lines in View mode, setting the \"page size\".
 805 This is the number of lines which \\[View-scroll-page-forward] and
 806 \\[View-scroll-page-backward] scroll by default.
 807 If LINES is omitted or = 0, sets \"page size\" to window height and
 808 scrolls forward that much, otherwise scrolls forward LINES lines and sets
 809 \"page size\" to the minimum of window height and the absolute value of LINES.
 810 See also `View-scroll-page-forward'."
 811   (interactive "P")
 812   (view-scroll-lines lines nil
 813                      (setq view-page-size (view-page-size-default lines))
 814                      nil))
 815
 816 (defun View-scroll-page-backward-set-page-size (&optional lines)
 817   "Scroll backward prefix LINES lines in View mode, setting the \"page size\".
 818 See also `View-scroll-page-forward-set-page-size'."
 819   (interactive "P")
 820   (view-scroll-lines lines t
 821                      (setq view-page-size (view-page-size-default lines))
 822                      nil))
 823
 824 (defun View-scroll-line-forward (&optional lines)
 825   "Scroll forward one line (or prefix LINES lines) in View mode.
 826 See also `View-scroll-page-forward', but note that scrolling is limited
 827 to minimum of LINES and one window-full."
 828   (interactive "P")
 829   (view-scroll-lines lines nil 1 t))
 830
 831 (defun View-scroll-line-backward (&optional lines)
 832   "Scroll backward one line (or prefix LINES lines) in View mode.
 833 See also `View-scroll-line-forward'."
 834   (interactive "P")
 835   (view-scroll-lines lines t 1 t))
 836
 837 (defun View-scroll-half-page-forward (&optional lines)
 838   "Scroll forward a \"half page\" (or prefix LINES) lines in View mode.
 839 If LINES is not omitted, the \"half page size\" is set to the minimum of
 840 window height and the absolute value of LINES.
 841 LINES=0 resets \"half page size\" to half window height."
 842   (interactive "P")
 843   (view-scroll-lines lines nil (view-set-half-page-size-default lines) t))
 844
 845 (defun View-scroll-half-page-backward (&optional lines)
 846   "Scroll backward a \"half page\" (or prefix LINES) lines in View mode.
 847 See also `View-scroll-half-page-forward'."
 848   (interactive "P")
 849   (view-scroll-lines lines t (view-set-half-page-size-default lines) t))
 850
 851 (defun View-revert-buffer-scroll-page-forward (&optional lines)
 852   "Scroll forward, reverting buffer if needed, in View mode.
 853 If buffer has not been changed and the corresponding file is newer, first
 854 revert the buffer, then scroll.
 855 This command is useful if you are viewing a changing file.
 856
 857 The prefix argument LINES says how many lines to scroll.
 858 If you don't specify a prefix argument, it uses the number of lines set by
 859 \\[View-scroll-page-forward-set-page-size] or
 860 \\[View-scroll-page-backward-set-page-size].
 861 If LINES is more than a window-full, only the last window-full is shown."
 862   (interactive "P")
 863   (let ((view-scroll-auto-exit nil)
 864         (view-try-extend-at-buffer-end t))
 865     (view-scroll-lines lines nil (view-page-size-default view-page-size) nil)))
 866 \f
 867 (defun View-search-regexp-forward (n regexp)
 868   "Search forward for first (or prefix Nth) occurrence of REGEXP in View mode.
 869
 870 Displays line found at center of window.  Sets mark at starting position and
 871 pushes mark ring.
 872
 873 Characters @ and ! are special at the beginning of REGEXP.  They modify
 874 the search rather than become part of the pattern searched for.
 875 @ means search all the buffer i.e. start search at the beginning of buffer.
 876 ! means search for a line that contains no match for the pattern.
 877 If REGEXP is empty or only consist of these control characters, then
 878 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 879 for use by later search commands.
 880
 881 The variable `view-highlight-face' controls the face that is used
 882 for highlighting the match that is found."
 883   (interactive "p\nsSearch forward (regexp): ")
 884   (view-search n regexp))
 885
 886 (defun View-search-regexp-backward (n regexp)
 887   "Search backward for first (or prefix Nth) occurrence of REGEXP in View mode.
 888
 889 Displays line found at center of window.  Sets mark at starting position and
 890 pushes mark ring.
 891
 892 Characters @ and ! are special at the beginning of REGEXP.  They modify
 893 the search rather than become part of the pattern searched for.
 894 @ means search all the buffer i.e. start search at the end of buffer.
 895 ! means search for a line that contains no match for the pattern.
 896 If REGEXP is empty or only consist of these control characters, then
 897 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 898 for use by later search commands.
 899
 900 The variable `view-highlight-face' controls the face that is used
 901 for highlighting the match that is found."
 902   (interactive "p\nsSearch backward (regexp): ")
 903   (view-search (- n) regexp))
 904
 905 (defun View-search-last-regexp-forward (n) "\
 906 Search forward for first (or prefix Nth) instance of last regexp in View mode.
 907 Displays line found at center of window.  Sets mark at starting position and
 908 pushes mark ring.
 909
 910 The variable `view-highlight-face' controls the face that is used
 911 for highlighting the match that is found."
 912   (interactive "p")
 913   (view-search n nil))
 914
 915 (defun View-search-last-regexp-backward (n) "\
 916 Search backward for first (or prefix Nth) instance of last regexp in View mode.
 917 Displays line found at center of window.  Sets mark at starting position and
 918 pushes mark ring.
 919
 920 The variable `view-highlight-face' controls the face that is used
 921 for highlighting the match that is found."
 922   (interactive "p")
 923   (view-search (- n) nil))
 924
 925 (defun view-search (times regexp)
 926   ;; This function does the job for all the View-search- commands.
 927   ;; Search for the TIMESth match for REGEXP.  If TIMES is negative
 928   ;; search backwards.  If REGEXP is nil use `view-last-regexp'.
 929   ;; Characters "!" and "@" have a special meaning at the beginning of
 930   ;; REGEXP and are removed from REGEXP before the search "!" means
 931   ;; search for lines with no match for REGEXP.  "@" means search in
 932   ;; the whole buffer, don't start searching from the present point.
 933   (let (where no end ln)
 934     (cond
 935      ((and regexp (> (length regexp) 0)
 936            (or (not (memq (string-to-char regexp) '(?! ?@)))
 937                (progn
 938                  (if (member (substring regexp 0 2) '("!@" "@!"))
 939                      (setq end t no t ln 2)
 940                    (setq no (not (setq end (eq ?@ (string-to-char regexp))))
 941                          ln 1))
 942                  (> (length (setq regexp (substring regexp ln))) 0))))
 943       (setq view-last-regexp (if no (list regexp) regexp)))
 944      ((consp view-last-regexp)
 945       (setq regexp (car view-last-regexp))
 946       (unless (setq no (not no)) (setq view-last-regexp regexp)))
 947      (view-last-regexp (setq regexp view-last-regexp)
 948                        (if no (setq view-last-regexp (list regexp))))
 949      (t (error "No previous View-mode search")))
 950     (save-excursion
 951       (if end (goto-char (if (< times 0) (point-max) (point-min)))
 952         (move-to-window-line (if (< times 0) 0 -1)))
 953       (if (if no (view-search-no-match-lines times regexp)
 954             (re-search-forward regexp nil t times))
 955           (setq where (point))))
 956     (if where
 957         (progn
 958           (push-mark)
 959           (goto-char where)
 960           (if view-overlay
 961               (move-overlay view-overlay (match-beginning 0) (match-end 0))
 962             (setq view-overlay
 963                   (make-overlay (match-beginning 0) (match-end 0))))
 964           (overlay-put view-overlay 'face view-highlight-face)
 965           (beginning-of-line)
 966           (view-recenter))
 967       (message "Can't find occurrence %d of %s%s"
 968                times (if no "no " "") regexp)
 969       (sit-for 4))))
 970
 971 ;; This is the dumb approach, looking at each line.  The original
 972 ;; version of this function looked like it might have been trying to
 973 ;; do something clever, but not succeeding:
 974 ;; http://lists.gnu.org/archive/html/bug-gnu-emacs/2007-09/msg00073.html
 975 (defun view-search-no-match-lines (times regexp)
 976   "Search for the TIMESth occurrence of a line with no match for REGEXP.
 977 If such a line is found, return non-nil and set the match-data to that line.
 978 If TIMES is negative, search backwards."
 979   (let ((step (if (>= times 0) 1
 980                 (setq times (- times))
 981                 -1)))
 982     ;; Note that we do not check the current line.
 983     (while (and (> times 0)
 984                 (zerop (forward-line step)))
 985       ;; (forward-line 1) returns 0 on moving within the last line.
 986       (if (eobp)
 987           (setq times -1)
 988         (or (re-search-forward regexp (line-end-position) t)
 989             (setq times (1- times))))))
 990   (and (zerop times)
 991        (looking-at ".*")))
 992
 993 (provide 'view)
 994
 995 ;;; view.el ends here