lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: help, internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 (defvar help-map (make-sparse-keymap)
  27   "Keymap for characters following the Help key.")
  28
  29 (define-key global-map "\C-h" 'help-command)
  30 (fset 'help-command help-map)
  31
  32 (define-key help-map "\C-h" 'help-for-help)
  33 (define-key help-map "?" 'help-for-help)
  34
  35 (define-key help-map "\C-c" 'describe-copying)
  36 (define-key help-map "\C-d" 'describe-distribution)
  37 (define-key help-map "\C-w" 'describe-no-warranty)
  38 (define-key help-map "a" 'command-apropos)
  39
  40 (define-key help-map "b" 'describe-bindings)
  41
  42 (define-key help-map "c" 'describe-key-briefly)
  43 (define-key help-map "k" 'describe-key)
  44
  45 (define-key help-map "d" 'describe-function)
  46 (define-key help-map "f" 'describe-function)
  47
  48 (define-key help-map "i" 'info)
  49 (define-key help-map "\C-f" 'Info-goto-emacs-command-node)
  50 (define-key help-map "\C-k" 'Info-goto-emacs-key-command-node)
  51
  52 (define-key help-map "l" 'view-lossage)
  53
  54 (define-key help-map "m" 'describe-mode)
  55
  56 (define-key help-map "\C-n" 'view-emacs-news)
  57 (define-key help-map "n" 'view-emacs-news)
  58
  59 (define-key help-map "s" 'describe-syntax)
  60
  61 (define-key help-map "t" 'help-with-tutorial)
  62
  63 (define-key help-map "w" 'where-is)
  64
  65 (define-key help-map "v" 'describe-variable)
  66
  67 (defun help-with-tutorial ()
  68   "Select the Emacs learn-by-doing tutorial."
  69   (interactive)
  70   (let ((file (expand-file-name "~/TUTORIAL")))
  71     (delete-other-windows)
  72     (if (get-file-buffer file)
  73         (switch-to-buffer (get-file-buffer file))
  74       (switch-to-buffer (create-file-buffer file))
  75       (setq buffer-file-name file)
  76       (setq default-directory (expand-file-name "~/"))
  77       (setq buffer-auto-save-file-name nil)
  78       (insert-file-contents (expand-file-name "TUTORIAL" data-directory))
  79       (goto-char (point-min))
  80       (search-forward "\n<<")
  81       (beginning-of-line)
  82       (delete-region (point) (progn (end-of-line) (point)))
  83       (newline (- (window-height (selected-window))
  84                   (count-lines (point-min) (point))
  85                   6))
  86       (goto-char (point-min))
  87       (set-buffer-modified-p nil))))
  88
  89 (defun describe-key-briefly (key)
  90   "Print the name of the function KEY invokes.  KEY is a string."
  91   (interactive "kDescribe key briefly: ")
  92   (let ((defn (key-binding key)))
  93     (if (or (null defn) (integerp defn))
  94         (message "%s is undefined" (key-description key))
  95       (message "%s runs the command %s"
  96                (key-description key)
  97                (if (symbolp defn) defn (prin1-to-string defn))))))
  98
  99 (defun print-help-return-message (&optional function)
 100   "Display or return message saying how to restore windows after help command.
 101 Computes a message and applies the optional argument FUNCTION to it.
 102 If FUNCTION is nil, applies `message' to it, thus printing it."
 103   (and (not (get-buffer-window standard-output))
 104        (funcall (or function 'message)
 105                 (concat
 106                  (substitute-command-keys
 107                   (if (one-window-p t)
 108                       (if pop-up-windows
 109                           "Type \\[delete-other-windows] to remove help window."
 110                         "Type \\[switch-to-buffer] RET to remove help window.")
 111                     "Type \\[switch-to-buffer-other-window] RET to restore the other window."))
 112                  (substitute-command-keys
 113                   "  \\[scroll-other-window] to scroll the help.")))))
 114
 115 (defun describe-key (key)
 116   "Display documentation of the function invoked by KEY.  KEY is a string."
 117   (interactive "kDescribe key: ")
 118   (let ((defn (key-binding key)))
 119     (if (or (null defn) (integerp defn))
 120         (message "%s is undefined" (key-description key))
 121       (with-output-to-temp-buffer "*Help*"
 122         (prin1 defn)
 123         (princ ":\n")
 124         (if (documentation defn)
 125             (princ (documentation defn))
 126           (princ "not documented"))
 127         (print-help-return-message)))))
 128
 129 (defun describe-mode (&optional minor)
 130   "Display documentation of current major mode.
 131 If optional MINOR is non-nil (or prefix argument is given if interactive),
 132 display documentation of active minor modes as well.
 133 For this to work correctly for a minor mode, the mode's indicator variable
 134 (listed in `minor-mode-alist') must also be a function whose documentation
 135 describes the minor mode."
 136   (interactive)
 137   (with-output-to-temp-buffer "*Help*"
 138     (princ mode-name)
 139     (princ " Mode:\n")
 140     (princ (documentation major-mode))
 141     (let ((minor-modes minor-mode-alist)
 142           (locals (buffer-local-variables)))
 143       (while minor-modes
 144         (let* ((minor-mode (car (car minor-modes)))
 145                (indicator (car (cdr (car minor-modes))))
 146                (local-binding (assq minor-mode locals)))
 147           ;; Document a minor mode if it is listed in minor-mode-alist,
 148           ;; bound locally in this buffer, non-nil, and has a function
 149           ;; definition.
 150           (if (and local-binding
 151                    (cdr local-binding)
 152                    (fboundp minor-mode))
 153               (progn
 154                 (princ (format "\n\n\n%s minor mode (indicator%s):\n"
 155                                minor-mode indicator))
 156                 (princ (documentation minor-mode)))))
 157         (setq minor-modes (cdr minor-modes))))
 158     (print-help-return-message)))
 159
 160 ;; So keyboard macro definitions are documented correctly
 161 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 162
 163 (defun describe-distribution ()
 164   "Display info on how to obtain the latest version of GNU Emacs."
 165   (interactive)
 166   (find-file-read-only
 167    (expand-file-name "DISTRIB" data-directory)))
 168
 169 (defun describe-copying ()
 170   "Display info on how you may redistribute copies of GNU Emacs."
 171   (interactive)
 172   (find-file-read-only
 173    (expand-file-name "COPYING" data-directory))
 174   (goto-char (point-min)))
 175
 176 (defun describe-no-warranty ()
 177   "Display info on all the kinds of warranty Emacs does NOT have."
 178   (interactive)
 179   (describe-copying)
 180   (let (case-fold-search)
 181     (search-forward "NO WARRANTY")
 182     (recenter 0)))
 183
 184 (defun view-emacs-news ()
 185   "Display info on recent changes to Emacs."
 186   (interactive)
 187   (find-file-read-only (expand-file-name "NEWS" data-directory)))
 188
 189 (defun view-lossage ()
 190   "Display last 100 input keystrokes."
 191   (interactive)
 192   (with-output-to-temp-buffer "*Help*"
 193     (princ (key-description (recent-keys)))
 194     (save-excursion
 195       (set-buffer standard-output)
 196       (goto-char (point-min))
 197       (while (progn (move-to-column 50) (not (eobp)))
 198         (search-forward " " nil t)
 199         (insert "\n")))
 200     (print-help-return-message)))
 201
 202 (defun help-for-help ()
 203   "You have typed C-h, the help character.  Type a Help option:
 204
 205 A  command-apropos.   Give a substring, and see a list of commands
 206               (functions interactively callable) that contain
 207               that substring.  See also the  apropos  command.
 208 B  describe-bindings.  Display table of all key bindings.
 209 C  describe-key-briefly.  Type a command key sequence;
 210               it prints the function name that sequence runs.
 211 F  describe-function.  Type a function name and get documentation of it.
 212 I  info. The  info  documentation reader.
 213 K  describe-key.  Type a command key sequence;
 214               it displays the full documentation.
 215 L  view-lossage.  Shows last 100 characters you typed.
 216 M  describe-mode.  Print documentation of current major mode,
 217               which describes the commands peculiar to it.
 218 N  view-emacs-news.  Shows emacs news file.
 219 S  describe-syntax.  Display contents of syntax table, plus explanations
 220 T  help-with-tutorial.  Select the Emacs learn-by-doing tutorial.
 221 V  describe-variable.  Type name of a variable;
 222               it displays the variable's documentation and value.
 223 W  where-is.  Type command name; it prints which keystrokes
 224               invoke that command.
 225 C-c print Emacs copying permission (General Public License).
 226 C-d print Emacs ordering information.
 227 C-n print news of recent Emacs changes.
 228 C-w print information on absence of warranty for GNU Emacs."
 229   (interactive)
 230   (message
 231  "A B C F I K L M N S T V W C-c C-d C-n C-w.  Type C-h again for more help: ")
 232   (let ((char (read-char)))
 233     (if (or (= char ?\C-h) (= char ??))
 234         (save-window-excursion
 235           (switch-to-buffer "*Help*")
 236           (delete-other-windows)
 237           (erase-buffer)
 238           (insert (documentation 'help-for-help))
 239           (goto-char (point-min))
 240           (while (memq char '(?\C-h ?? ?\C-v ?\  ?\177 ?\M-v))
 241             (if (memq char '(?\C-v ?\ ))
 242                 (scroll-up))
 243             (if (memq char '(?\177 ?\M-v))
 244                 (scroll-down))
 245             (message "A B C F I K L M N S T V W C-c C-d C-n C-w%s: "
 246                      (if (pos-visible-in-window-p (point-max))
 247                          "" " or Space to scroll"))
 248             (let ((cursor-in-echo-area t))
 249               (setq char (read-char))))))
 250     (let ((defn (cdr (assq (downcase char) (cdr help-map)))))
 251       (if defn (call-interactively defn) (ding)))))
 252
 253
 254 ;; Return a function which is called by the list containing point.
 255 ;; If that gives no function, return a function whose name is around point.
 256 ;; If that doesn't give a function, return nil.
 257 (defun function-called-at-point ()
 258   (or (condition-case ()
 259           (save-excursion
 260             (save-restriction
 261               (narrow-to-region (max (point-min) (- (point) 1000)) (point-max))
 262               (backward-up-list 1)
 263               (forward-char 1)
 264               (let (obj)
 265                 (setq obj (read (current-buffer)))
 266                 (and (symbolp obj) (fboundp obj) obj))))
 267         (error nil))
 268       (condition-case ()
 269           (save-excursion
 270             (forward-sexp -1)
 271             (skip-chars-forward "'")
 272             (let ((obj (read (current-buffer))))
 273               (and (symbolp obj) (fboundp obj) obj)))
 274         (error nil))))
 275
 276 (defun describe-function (function)
 277   "Display the full documentation of FUNCTION (a symbol)."
 278   (interactive
 279    (let ((fn (function-called-at-point))
 280          (enable-recursive-minibuffers t)
 281          val)
 282      (setq val (completing-read (if fn
 283                                     (format "Describe function (default %s): " fn)
 284                                   "Describe function: ")
 285                                 obarray 'fboundp t))
 286      (list (if (equal val "")
 287                fn (intern val)))))
 288   (with-output-to-temp-buffer "*Help*"
 289     (prin1 function)
 290     (princ ": ")
 291     (let* ((def (symbol-function function))
 292            (beg (if (commandp def) "an interactive " "a ")))
 293       (princ (cond ((stringp def) "a keyboard macro.")
 294                    ((subrp def)
 295                     (concat beg "built-in function."))
 296                    ((compiled-function-p def)
 297                     (concat beg "compiled Lisp function."))
 298                    ((symbolp def)
 299                     (format "alias for `%s'." def))
 300                    ((eq (car-safe def) 'lambda)
 301                     (concat beg "Lisp function."))
 302                    ((eq (car-safe def) 'macro)
 303                     "a Lisp macro.")
 304                    ((eq (car-safe def) 'mocklisp)
 305                     "a mocklisp function.")
 306                    ((eq (car-safe def) 'autoload)
 307                     (format "%sLisp %s to autoload from `%s'."
 308                             beg
 309                             (if (nth 4 def) "macro" "function")
 310                             (nth 1 def)))
 311                    (t "")))
 312       (terpri))
 313     (if (documentation function)
 314         (princ (documentation function))
 315       (princ "not documented"))
 316     (print-help-return-message)
 317     ;; Return the text we displayed.
 318     (save-excursion (set-buffer standard-output) (buffer-string))))
 319
 320 (defun variable-at-point ()
 321   (condition-case ()
 322       (save-excursion
 323         (forward-sexp -1)
 324         (skip-chars-forward "'")
 325         (let ((obj (read (current-buffer))))
 326           (and (symbolp obj) (boundp obj) obj)))
 327     (error nil)))
 328
 329 (defun describe-variable (variable)
 330   "Display the full documentation of VARIABLE (a symbol).
 331 Returns the documentation as a string, also."
 332   (interactive
 333    (let ((v (variable-at-point))
 334          (enable-recursive-minibuffers t)
 335          val)
 336      (setq val (completing-read (if v
 337                                     (format "Describe variable (default %s): " v)
 338                                   "Describe variable: ")
 339                                 obarray 'boundp t))
 340      (list (if (equal val "")
 341                v (intern val)))))
 342   (with-output-to-temp-buffer "*Help*"
 343     (prin1 variable)
 344     (princ "'s value is ")
 345     (if (not (boundp variable))
 346         (princ "void.")
 347       (prin1 (symbol-value variable)))
 348     (terpri) (terpri)
 349     (princ "Documentation:")
 350     (terpri)
 351     (let ((doc (documentation-property variable 'variable-documentation)))
 352       (if doc
 353           (princ (substitute-command-keys doc))
 354         (princ "not documented as a variable.")))
 355     (print-help-return-message)
 356     ;; Return the text we displayed.
 357     (save-excursion (set-buffer standard-output) (buffer-string))))
 358
 359 (defun command-apropos (string)
 360   "Like apropos but lists only symbols that are names of commands
 361 \(interactively callable functions).  Argument REGEXP is a regular expression
 362 that is matched against command symbol names.  Returns list of symbols and
 363 documentation found."
 364   (interactive "sCommand apropos (regexp): ")
 365   (let ((message
 366          (let ((standard-output (get-buffer-create "*Help*")))
 367            (print-help-return-message 'identity))))
 368     (apropos string 'commandp)
 369     (and message (message message))))
 370
 371 (defun locate-library (library &optional nosuffix)
 372   "Show the full path name of Emacs library LIBRARY.
 373 This command searches the directories in `load-path' like `M-x load-library'
 374 to find the file that `M-x load-library RET LIBRARY RET' would load.
 375 Optional second arg NOSUFFIX non-nil means don't add suffixes `.elc' or `.el'
 376 to the specified name LIBRARY (a la calling `load' instead of `load-library')."
 377   (interactive "sLocate library: ")
 378   (catch 'answer
 379     (mapcar
 380      '(lambda (dir)
 381         (mapcar
 382          '(lambda (suf)
 383             (let ((try (expand-file-name (concat library suf) dir)))
 384               (and (file-readable-p try)
 385                    (null (file-directory-p try))
 386                    (progn
 387                      (message "Library is file %s" try)
 388                      (throw 'answer try)))))
 389          (if nosuffix '("") '(".elc" ".el" ""))))
 390      load-path)
 391     (message "No library %s in search path" library)
 392     nil))
 393
 394 ;;; help.el ends here