lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support.
   2
   3 ;; Keywords: internal
   4
   5 ;; Copyright (c) 1993, 1994 Free Software Foundation, Inc.
   6 ;; Based partially on earlier release by Lucid.
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 ;; This is for temporary compatibility with pre-release Emacs 19.
  28 (defalias 'x-selection 'x-get-selection)
  29 (defun x-get-selection (&optional type data-type)
  30   "Return the value of an X Windows selection.
  31 The argument TYPE (default `PRIMARY') says which selection,
  32 and the argument DATA-TYPE (default `STRING') says how to convert the data."
  33   (x-get-selection-internal (or type 'PRIMARY) (or data-type 'STRING)))
  34
  35 (defun x-get-clipboard ()
  36   "Return text pasted to the clipboard."
  37   (x-get-selection-internal 'CLIPBOARD 'STRING))
  38
  39 (defun x-set-selection (type data)
  40   "Make an X Windows selection of type TYPE and value DATA.
  41 The argument TYPE (default `PRIMARY') says which selection,
  42 and DATA specifies the contents.  DATA may be a string,
  43 a symbol, an integer (or a cons of two integers or list of two integers).
  44
  45 The selection may also be a cons of two markers pointing to the same buffer,
  46 or an overlay.  In these cases, the selection is considered to be the text
  47 between the markers *at whatever time the selection is examined*.
  48 Thus, editing done in the buffer after you specify the selection
  49 can alter the effective value of the selection.
  50
  51 The data may also be a vector of valid non-vector selection values.
  52
  53 Interactively, the text of the region is used as the selection value."
  54   (interactive (if (not current-prefix-arg)
  55                    (list 'PRIMARY (read-string "Set text for pasting: "))
  56                  (list 'PRIMARY (substring (region-beginning) (region-end)))))
  57   ;; This is for temporary compatibility with pre-release Emacs 19.
  58   (if (stringp type)
  59       (setq type (intern type)))
  60   (or (x-valid-simple-selection-p data)
  61       (and (vectorp data)
  62            (let ((valid t)
  63                  (i (1- (length data))))
  64              (while (>= i 0)
  65                (or (x-valid-simple-selection-p (aref data i))
  66                    (setq valid nil))
  67                (setq i (1- i)))
  68              valid))
  69       (signal 'error (list "invalid selection" data)))
  70   (or type (setq type 'PRIMARY))
  71   (if data
  72       (x-own-selection-internal type data)
  73     (x-disown-selection-internal type))
  74   data)
  75
  76 (defun x-valid-simple-selection-p (data)
  77   (or (stringp data)
  78       (symbolp data)
  79       (integerp data)
  80       (and (consp data)
  81            (integerp (car data))
  82            (or (integerp (cdr data))
  83                (and (consp (cdr data))
  84                     (integerp (car (cdr data))))))
  85       (overlayp data)
  86       (and (consp data)
  87            (markerp (car data))
  88            (markerp (cdr data))
  89            (marker-buffer (car data))
  90            (marker-buffer (cdr data))
  91            (eq (marker-buffer (car data))
  92                (marker-buffer (cdr data)))
  93            (buffer-name (marker-buffer (car data)))
  94            (buffer-name (marker-buffer (cdr data))))))
  95 \f
  96 ;;; Cut Buffer support
  97
  98 (defun x-get-cut-buffer (&optional which-one)
  99   "Returns the value of one of the 8 X server cut-buffers.  Optional arg
 100 WHICH-ONE should be a number from 0 to 7, defaulting to 0.
 101 Cut buffers are considered obsolete; you should use selections instead."
 102   (x-get-cut-buffer-internal
 103    (if which-one
 104        (aref [CUT_BUFFER0 CUT_BUFFER1 CUT_BUFFER2 CUT_BUFFER3
 105               CUT_BUFFER4 CUT_BUFFER5 CUT_BUFFER6 CUT_BUFFER7]
 106              which-one)
 107      'CUT_BUFFER0)))
 108
 109 (defun x-set-cut-buffer (string &optional push)
 110   "Store STRING into the X server's primary cut buffer.
 111 If PUSH is non-nil, also rotate the cut buffers:
 112 this means the previous value of the primary cut buffer moves the second
 113 cut buffer, and the second to the third, and so on (there are 8 buffers.)
 114 Cut buffers are considered obsolete; you should use selections instead."
 115   ;; Check the data type of STRING.
 116   (substring string 0 0)
 117   (if push
 118       (x-rotate-cut-buffers-internal 1))
 119   (x-store-cut-buffer-internal 'CUT_BUFFER0 string))
 120
 121 \f
 122 ;;; Functions to convert the selection into various other selection types.
 123 ;;; Every selection type that Emacs handles is implemented this way, except
 124 ;;; for TIMESTAMP, which is a special case.
 125
 126 (defun xselect-convert-to-string (selection type value)
 127   (cond ((stringp value)
 128          value)
 129         ((overlayp value)
 130          (save-excursion
 131            (or (buffer-name (overlay-buffer value))
 132                (error "selection is in a killed buffer"))
 133            (set-buffer (overlay-buffer value))
 134            (buffer-substring (overlay-start value)
 135                              (overlay-end value))))
 136         ((and (consp value)
 137               (markerp (car value))
 138               (markerp (cdr value)))
 139          (or (eq (marker-buffer (car value)) (marker-buffer (cdr value)))
 140              (signal 'error
 141                      (list "markers must be in the same buffer"
 142                            (car value) (cdr value))))
 143          (save-excursion
 144            (set-buffer (or (marker-buffer (car value))
 145                            (error "selection is in a killed buffer")))
 146            (buffer-substring (car value) (cdr value))))
 147         (t nil)))
 148
 149 (defun xselect-convert-to-length (selection type value)
 150   (let ((value
 151          (cond ((stringp value)
 152                 (length value))
 153                ((overlayp value)
 154                 (abs (- (overlay-end value) (overlay-start value))))
 155                ((and (consp value)
 156                      (markerp (car value))
 157                      (markerp (cdr value)))
 158                 (or (eq (marker-buffer (car value))
 159                         (marker-buffer (cdr value)))
 160                     (signal 'error
 161                             (list "markers must be in the same buffer"
 162                                   (car value) (cdr value))))
 163                 (abs (- (car value) (cdr value)))))))
 164     (if value ; force it to be in 32-bit format.
 165         (cons (ash value -16) (logand value 65535))
 166       nil)))
 167
 168 (defun xselect-convert-to-targets (selection type value)
 169   ;; return a vector of atoms, but remove duplicates first.
 170   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 171          (rest all))
 172     (while rest
 173       (cond ((memq (car rest) (cdr rest))
 174              (setcdr rest (delq (car rest) (cdr rest))))
 175             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 176              (setcdr rest (cdr (cdr rest))))
 177             (t
 178              (setq rest (cdr rest)))))
 179     (apply 'vector all)))
 180
 181 (defun xselect-convert-to-delete (selection type value)
 182   (x-disown-selection-internal selection)
 183   ;; A return value of nil means that we do not know how to do this conversion,
 184   ;; and replies with an "error".  A return value of NULL means that we have
 185   ;; done the conversion (and any side-effects) but have no value to return.
 186   'NULL)
 187
 188 (defun xselect-convert-to-filename (selection type value)
 189   (cond ((overlayp value)
 190          (buffer-file-name (or (overlay-buffer value)
 191                                (error "selection is in a killed buffer"))))
 192         ((and (consp value)
 193               (markerp (car value))
 194               (markerp (cdr value)))
 195          (buffer-file-name (or (marker-buffer (car value))
 196                                (error "selection is in a killed buffer"))))
 197         (t nil)))
 198
 199 (defun xselect-convert-to-charpos (selection type value)
 200   (let (a b tmp)
 201     (cond ((cond ((overlayp value)
 202                   (setq a (overlay-start value)
 203                         b (overlay-end value)))
 204                  ((and (consp value)
 205                        (markerp (car value))
 206                        (markerp (cdr value)))
 207                   (setq a (car value)
 208                         b (cdr value))))
 209            (setq a (1- a) b (1- b)) ; zero-based
 210            (if (< b a) (setq tmp a a b b tmp))
 211            (cons 'SPAN
 212                  (vector (cons (ash a -16) (logand a 65535))
 213                          (cons (ash b -16) (logand b 65535))))))))
 214
 215 (defun xselect-convert-to-lineno (selection type value)
 216   (let (a b buf tmp)
 217     (cond ((cond ((and (consp value)
 218                        (markerp (car value))
 219                        (markerp (cdr value)))
 220                   (setq a (marker-position (car value))
 221                         b (marker-position (cdr value))
 222                         buf (marker-buffer (car value))))
 223                  ((overlayp value)
 224                   (setq buf (overlay-buffer value)
 225                         a (overlay-start value)
 226                         b (overlay-end value)))
 227                  )
 228            (save-excursion
 229              (set-buffer buf)
 230              (setq a (count-lines 1 a)
 231                    b (count-lines 1 b)))
 232            (if (< b a) (setq tmp a a b b tmp))
 233            (cons 'SPAN
 234                  (vector (cons (ash a -16) (logand a 65535))
 235                          (cons (ash b -16) (logand b 65535))))))))
 236
 237 (defun xselect-convert-to-colno (selection type value)
 238   (let (a b buf tmp)
 239     (cond ((cond ((and (consp value)
 240                        (markerp (car value))
 241                        (markerp (cdr value)))
 242                   (setq a (car value)
 243                         b (cdr value)
 244                         buf (marker-buffer a)))
 245                  ((overlayp value)
 246                   (setq buf (overlay-buffer value)
 247                         a (overlay-start value)
 248                         b (overlay-end value)))
 249                  )
 250            (save-excursion
 251              (set-buffer buf)
 252              (goto-char a)
 253              (setq a (current-column))
 254              (goto-char b)
 255              (setq b (current-column)))
 256            (if (< b a) (setq tmp a a b b tmp))
 257            (cons 'SPAN
 258                  (vector (cons (ash a -16) (logand a 65535))
 259                          (cons (ash b -16) (logand b 65535))))))))
 260
 261 (defun xselect-convert-to-os (selection type size)
 262   (symbol-name system-type))
 263
 264 (defun xselect-convert-to-host (selection type size)
 265   (system-name))
 266
 267 (defun xselect-convert-to-user (selection type size)
 268   (user-full-name))
 269
 270 (defun xselect-convert-to-class (selection type size)
 271   "Emacs")
 272
 273 ;; We do not try to determine the name Emacs was invoked with,
 274 ;; because it is not clean for a program's behavior to depend on that.
 275 (defun xselect-convert-to-name (selection type size)
 276   "emacs")
 277
 278 (defun xselect-convert-to-integer (selection type value)
 279   (and (integerp value)
 280        (cons (ash value -16) (logand value 65535))))
 281
 282 (defun xselect-convert-to-atom (selection type value)
 283   (and (symbolp value) value))
 284
 285 (defun xselect-convert-to-identity (selection type value) ; used internally
 286   (vector value))
 287
 288 (setq selection-converter-alist
 289       '((TEXT . xselect-convert-to-string)
 290         (STRING . xselect-convert-to-string)
 291         (TARGETS . xselect-convert-to-targets)
 292         (LENGTH . xselect-convert-to-length)
 293         (DELETE . xselect-convert-to-delete)
 294         (FILE_NAME . xselect-convert-to-filename)
 295         (CHARACTER_POSITION . xselect-convert-to-charpos)
 296         (LINE_NUMBER . xselect-convert-to-lineno)
 297         (COLUMN_NUMBER . xselect-convert-to-colno)
 298         (OWNER_OS . xselect-convert-to-os)
 299         (HOST_NAME . xselect-convert-to-host)
 300         (USER . xselect-convert-to-user)
 301         (CLASS . xselect-convert-to-class)
 302         (NAME . xselect-convert-to-name)
 303         (ATOM . xselect-convert-to-atom)
 304         (INTEGER . xselect-convert-to-integer)
 305         (_EMACS_INTERNAL . xselect-convert-to-identity)
 306         ))
 307
 308 (provide 'select)
 309
 310 ;;; select.el ends here.