lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  29 ;; associated support machinery, such as adding hyperlinks, etc.,
  30
  31 ;;; Code:
  32
  33 (require 'button)
  34 (require 'view)
  35
  36 (defvar help-mode-map (make-sparse-keymap)
  37   "Keymap for help mode.")
  38
  39 (set-keymap-parent help-mode-map button-buffer-map)
  40
  41 (define-key help-mode-map [mouse-2] 'help-follow-mouse)
  42 (define-key help-mode-map "\C-c\C-b" 'help-go-back)
  43 (define-key help-mode-map "\C-c\C-c" 'help-follow)
  44 ;; Documentation only, since we use minor-mode-overriding-map-alist.
  45 (define-key help-mode-map "\r" 'help-follow)
  46
  47 (defvar help-xref-stack nil
  48   "A stack of ways by which to return to help buffers after following xrefs.
  49 Used by `help-follow' and `help-xref-go-back'.
  50 An element looks like (POSITION FUNCTION ARGS...).
  51 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  52 (put 'help-xref-stack 'permanent-local t)
  53 (make-variable-buffer-local 'help-xref-stack)
  54
  55 (defvar help-xref-stack-item nil
  56   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  57 The format is (FUNCTION ARGS...).")
  58 (put 'help-xref-stack-item 'permanent-local t)
  59 (make-variable-buffer-local 'help-xref-stack-item)
  60
  61 (setq-default help-xref-stack nil help-xref-stack-item nil)
  62
  63 (defcustom help-mode-hook nil
  64   "Hook run by `help-mode'."
  65   :type 'hook
  66   :group 'help)
  67 \f
  68 ;; Button types used by help
  69
  70 (define-button-type 'help-xref
  71   'follow-link t
  72   'action #'help-button-action)
  73
  74 (defun help-button-action (button)
  75   "Call BUTTON's help function."
  76   (help-do-xref (button-start button)
  77                 (button-get button 'help-function)
  78                 (button-get button 'help-args)))
  79
  80 ;; These 6 calls to define-button-type were generated in a dolist
  81 ;; loop, but that is bad because it means these button types don't
  82 ;; have an easily found definition.
  83
  84 (define-button-type 'help-function
  85   :supertype 'help-xref
  86   'help-function 'describe-function
  87   'help-echo (purecopy "mouse-2, RET: describe this function"))
  88
  89 (define-button-type 'help-variable
  90   :supertype 'help-xref
  91   'help-function 'describe-variable
  92   'help-echo (purecopy "mouse-2, RET: describe this variable"))
  93
  94 (define-button-type 'help-face
  95   :supertype 'help-xref
  96   'help-function 'describe-face
  97   'help-echo (purecopy "mouse-2, RET: describe this face"))
  98
  99 (define-button-type 'help-coding-system
 100   :supertype 'help-xref
 101   'help-function 'describe-coding-system
 102   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 103
 104 (define-button-type 'help-input-method
 105   :supertype 'help-xref
 106   'help-function 'describe-input-method
 107   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 108
 109 (define-button-type 'help-character-set
 110   :supertype 'help-xref
 111   'help-function 'describe-character-set
 112   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 113
 114 ;; make some more ideosyncratic button types
 115
 116 (define-button-type 'help-symbol
 117   :supertype 'help-xref
 118   'help-function #'help-xref-interned
 119   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 120
 121 (define-button-type 'help-back
 122   :supertype 'help-xref
 123   'help-function #'help-xref-go-back
 124   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 125
 126 (define-button-type 'help-info
 127   :supertype 'help-xref
 128   'help-function #'info
 129   'help-echo (purecopy"mouse-2, RET: read this Info node"))
 130
 131 (define-button-type 'help-customize-variable
 132   :supertype 'help-xref
 133   'help-function (lambda (v)
 134                    (if help-xref-stack
 135                        (pop help-xref-stack))
 136                    (customize-variable v))
 137   'help-echo (purecopy "mouse-2, RET: customize variable"))
 138
 139 (define-button-type 'help-customize-face
 140   :supertype 'help-xref
 141   'help-function (lambda (v)
 142                    (if help-xref-stack
 143                        (pop help-xref-stack))
 144                    (customize-face v))
 145   'help-echo (purecopy "mouse-2, RET: customize face"))
 146
 147 (define-button-type 'help-function-def
 148   :supertype 'help-xref
 149   'help-function (lambda (fun file)
 150                    (require 'find-func)
 151                    (when (eq file 'C-source)
 152                      (setq file
 153                            (help-C-file-name (indirect-function fun) 'fun)))
 154                    ;; Don't use find-function-noselect because it follows
 155                    ;; aliases (which fails for built-in functions).
 156                    (let ((location
 157                           (find-function-search-for-symbol fun nil file)))
 158                      (pop-to-buffer (car location))
 159                      (goto-char (cdr location))))
 160   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 161
 162 (define-button-type 'help-variable-def
 163   :supertype 'help-xref
 164   'help-function (lambda (var &optional file)
 165                    (when (eq file 'C-source)
 166                      (setq file (help-C-file-name var 'var)))
 167                    (let ((location (find-variable-noselect var file)))
 168                      (pop-to-buffer (car location))
 169                      (goto-char (cdr location))))
 170   'help-echo (purecopy"mouse-2, RET: find variable's definition"))
 171
 172 (define-button-type 'help-face-def
 173   :supertype 'help-xref
 174   'help-function (lambda (fun file)
 175                    (require 'find-func)
 176                    ;; Don't use find-function-noselect because it follows
 177                    ;; aliases (which fails for built-in functions).
 178                    (let ((location
 179                           (find-function-search-for-symbol fun 'defface file)))
 180                      (pop-to-buffer (car location))
 181                      (goto-char (cdr location))))
 182   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 183
 184 \f
 185 ;;;###autoload
 186 (defun help-mode ()
 187   "Major mode for viewing help text and navigating references in it.
 188 Entry to this mode runs the normal hook `help-mode-hook'.
 189 Commands:
 190 \\{help-mode-map}"
 191   (interactive)
 192   (kill-all-local-variables)
 193   (use-local-map help-mode-map)
 194   (setq mode-name "Help")
 195   (setq major-mode 'help-mode)
 196   (view-mode)
 197   (make-local-variable 'view-no-disable-on-exit)
 198   (setq view-no-disable-on-exit t)
 199   (run-mode-hooks 'help-mode-hook))
 200
 201 ;;;###autoload
 202 (defun help-mode-setup ()
 203   (help-mode)
 204   (setq buffer-read-only nil))
 205
 206 ;;;###autoload
 207 (defun help-mode-finish ()
 208   (let ((entry (assq (selected-window) view-return-to-alist)))
 209         (if entry
 210             ;; When entering Help mode from the Help window,
 211             ;; such as by following a link, preserve the same
 212             ;; meaning for the q command.
 213             ;; (setcdr entry (cons (selected-window) help-return-method))
 214             nil
 215           (setq view-return-to-alist
 216                 (cons (cons (selected-window) help-return-method)
 217                       view-return-to-alist))))
 218   (when (eq major-mode 'help-mode)
 219     ;; View mode's read-only status of existing *Help* buffer is lost
 220     ;; by with-output-to-temp-buffer.
 221     (toggle-read-only 1)
 222     (help-make-xrefs (current-buffer))))
 223 \f
 224 ;; Grokking cross-reference information in doc strings and
 225 ;; hyperlinking it.
 226
 227 ;; This may have some scope for extension and the same or something
 228 ;; similar should be done for widget doc strings, which currently use
 229 ;; another mechanism.
 230
 231 (defvar help-back-label (purecopy "[back]")
 232   "Label to use by `help-make-xrefs' for the go-back reference.")
 233
 234 (defconst help-xref-symbol-regexp
 235   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"
 236                     "\\(function\\|command\\)\\|"
 237                     "\\(face\\)\\|"
 238                     "\\(symbol\\)\\|"
 239                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 240                     "[ \t\n]+\\)?"
 241                     ;; Note starting with word-syntax character:
 242                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 243   "Regexp matching doc string references to symbols.
 244
 245 The words preceding the quoted symbol can be used in doc strings to
 246 distinguish references to variables, functions and symbols.")
 247
 248 (defvar help-xref-mule-regexp nil
 249   "Regexp matching doc string references to MULE-related keywords.
 250
 251 It is usually nil, and is temporarily bound to an appropriate regexp
 252 when help commands related to multilingual environment (e.g.,
 253 `describe-coding-system') are invoked.")
 254
 255
 256 (defconst help-xref-info-regexp
 257   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 258   "Regexp matching doc string references to an Info node.")
 259
 260 ;;;###autoload
 261 (defun help-setup-xref (item interactive-p)
 262   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 263
 264 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 265 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 266 calling command was invoked interactively.  In this case the stack of
 267 items for help buffer \"back\" buttons is cleared.
 268
 269 This should be called very early, before the output buffer is cleared,
 270 because we want to record the \"previous\" position of point so we can
 271 restore it properly when going back."
 272   (with-current-buffer (help-buffer)
 273     (when help-xref-stack-item
 274       (push (cons (point) help-xref-stack-item) help-xref-stack))
 275     (when interactive-p
 276       (let ((tail (nthcdr 10 help-xref-stack)))
 277         ;; Truncate the stack.
 278         (if tail (setcdr tail nil))))
 279     (setq help-xref-stack-item item)))
 280
 281 (defvar help-xref-following nil
 282   "Non-nil when following a help cross-reference.")
 283
 284 (defun help-buffer ()
 285   (buffer-name                          ;for with-output-to-temp-buffer
 286    (if help-xref-following
 287        (current-buffer)
 288      (get-buffer-create "*Help*"))))
 289
 290 (defvar help-xref-override-view-map
 291   (let ((map (make-sparse-keymap)))
 292     (set-keymap-parent map view-mode-map)
 293     (define-key map "\r" nil)
 294     map)
 295   "Replacement keymap for `view-mode' in help buffers.")
 296
 297 ;;;###autoload
 298 (defun help-make-xrefs (&optional buffer)
 299   "Parse and hyperlink documentation cross-references in the given BUFFER.
 300
 301 Find cross-reference information in a buffer and activate such cross
 302 references for selection with `help-follow'.  Cross-references have
 303 the canonical form `...'  and the type of reference may be
 304 disambiguated by the preceding word(s) used in
 305 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 306 preceded or followed by the word `face'.  Variables without
 307 variable documentation do not get cross-referenced, unless
 308 preceded by the word `variable' or `option'.
 309
 310 If the variable `help-xref-mule-regexp' is non-nil, find also
 311 cross-reference information related to multilingual environment
 312 \(e.g., coding-systems).  This variable is also used to disambiguate
 313 the type of reference as the same way as `help-xref-symbol-regexp'.
 314
 315 A special reference `back' is made to return back through a stack of
 316 help buffers.  Variable `help-back-label' specifies the text for
 317 that."
 318   (interactive "b")
 319   (save-excursion
 320     (set-buffer (or buffer (current-buffer)))
 321     (goto-char (point-min))
 322     ;; Skip the header-type info, though it might be useful to parse
 323     ;; it at some stage (e.g. "function in `library'").
 324     (forward-paragraph)
 325     (let ((old-modified (buffer-modified-p)))
 326       (let ((stab (syntax-table))
 327             (case-fold-search t)
 328             (inhibit-read-only t))
 329         (set-syntax-table emacs-lisp-mode-syntax-table)
 330         ;; The following should probably be abstracted out.
 331         (unwind-protect
 332             (progn
 333               ;; Info references
 334               (save-excursion
 335                 (while (re-search-forward help-xref-info-regexp nil t)
 336                   (let ((data (match-string 2)))
 337                     (save-match-data
 338                       (unless (string-match "^([^)]+)" data)
 339                         (setq data (concat "(emacs)" data))))
 340                     (help-xref-button 2 'help-info data))))
 341               ;; Mule related keywords.  Do this before trying
 342               ;; `help-xref-symbol-regexp' because some of Mule
 343               ;; keywords have variable or function definitions.
 344               (if help-xref-mule-regexp
 345                   (save-excursion
 346                     (while (re-search-forward help-xref-mule-regexp nil t)
 347                       (let* ((data (match-string 7))
 348                              (sym (intern-soft data)))
 349                         (cond
 350                          ((match-string 3) ; coding system
 351                           (and sym (coding-system-p sym)
 352                                (help-xref-button 6 'help-coding-system sym)))
 353                          ((match-string 4) ; input method
 354                           (and (assoc data input-method-alist)
 355                                (help-xref-button 7 'help-input-method data)))
 356                          ((or (match-string 5) (match-string 6)) ; charset
 357                           (and sym (charsetp sym)
 358                                (help-xref-button 7 'help-character-set sym)))
 359                          ((assoc data input-method-alist)
 360                           (help-xref-button 7 'help-character-set data))
 361                          ((and sym (coding-system-p sym))
 362                           (help-xref-button 7 'help-coding-system sym))
 363                          ((and sym (charsetp sym))
 364                           (help-xref-button 7 'help-character-set sym)))))))
 365               ;; Quoted symbols
 366               (save-excursion
 367                 (while (re-search-forward help-xref-symbol-regexp nil t)
 368                   (let* ((data (match-string 8))
 369                          (sym (intern-soft data)))
 370                     (if sym
 371                         (cond
 372                          ((match-string 3)  ; `variable' &c
 373                           (and (boundp sym) ; `variable' doesn't ensure
 374                                         ; it's actually bound
 375                                (help-xref-button 8 'help-variable sym)))
 376                          ((match-string 4)   ; `function' &c
 377                           (and (fboundp sym) ; similarly
 378                                (help-xref-button 8 'help-function sym)))
 379                          ((match-string 5) ; `face'
 380                           (and (facep sym)
 381                                (help-xref-button 8 'help-face sym)))
 382                          ((match-string 6)) ; nothing for `symbol'
 383                          ((match-string 7)
 384 ;;;  this used:
 385 ;;;                       #'(lambda (arg)
 386 ;;;                           (let ((location
 387 ;;;                                  (find-function-noselect arg)))
 388 ;;;                             (pop-to-buffer (car location))
 389 ;;;                             (goto-char (cdr location))))
 390                           (help-xref-button 8 'help-function-def sym))
 391                          ((and
 392                            (facep sym)
 393                            (save-match-data (looking-at "[ \t\n]+face\\W")))
 394                           (help-xref-button 8 'help-face sym))
 395                          ((and (boundp sym) (fboundp sym))
 396                           ;; We can't intuit whether to use the
 397                           ;; variable or function doc -- supply both.
 398                           (help-xref-button 8 'help-symbol sym))
 399                          ((and
 400                            (boundp sym)
 401                            (or
 402                             (documentation-property
 403                              sym 'variable-documentation)
 404                             (condition-case nil
 405                                 (documentation-property
 406                                  (indirect-variable sym)
 407                                  'variable-documentation)
 408                               (cyclic-variable-indirection nil))))
 409                           (help-xref-button 8 'help-variable sym))
 410                          ((fboundp sym)
 411                           (help-xref-button 8 'help-function sym)))))))
 412               ;; An obvious case of a key substitution:
 413               (save-excursion
 414                 (while (re-search-forward
 415                         ;; Assume command name is only word characters
 416                         ;; and dashes to get things like `use M-x foo.'.
 417                         "\\<M-x\\s-+\\(\\sw\\(\\sw\\|-\\)+\\)" nil t)
 418                   (let ((sym (intern-soft (match-string 1))))
 419                     (if (fboundp sym)
 420                         (help-xref-button 1 'help-function sym)))))
 421               ;; Look for commands in whole keymap substitutions:
 422               (save-excursion
 423                 ;; Make sure to find the first keymap.
 424                 (goto-char (point-min))
 425                 ;; Find a header and the column at which the command
 426                 ;; name will be found.
 427
 428                 ;; If the keymap substitution isn't the last thing in
 429                 ;; the doc string, and if there is anything on the
 430                 ;; same line after it, this code won't recognize the end of it.
 431                 (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 432                                           nil t)
 433                   (let ((col (- (match-end 1) (match-beginning 1))))
 434                     (while
 435                         (and (not (eobp))
 436                              ;; Stop at a pair of blank lines.
 437                              (not (looking-at "\n\\s-*\n")))
 438                       ;; Skip a single blank line.
 439                       (and (eolp) (forward-line))
 440                       (end-of-line)
 441                       (skip-chars-backward "^\t\n")
 442                       (if (and (>= (current-column) col)
 443                                (looking-at "\\(\\sw\\|-\\)+$"))
 444                           (let ((sym (intern-soft (match-string 0))))
 445                             (if (fboundp sym)
 446                                 (help-xref-button 0 'help-function sym))))
 447                       (forward-line))))))
 448           (set-syntax-table stab))
 449         ;; Delete extraneous newlines at the end of the docstring
 450         (goto-char (point-max))
 451         (while (and (not (bobp)) (bolp))
 452           (delete-char -1))
 453         (insert "\n")
 454         ;; Make a back-reference in this buffer if appropriate.
 455         (when help-xref-stack
 456           (insert "\n")
 457           (help-insert-xref-button help-back-label 'help-back
 458                                    (current-buffer))
 459           (insert "\n")))
 460       ;; View mode steals RET from us.
 461       (set (make-local-variable 'minor-mode-overriding-map-alist)
 462            (list (cons 'view-mode help-xref-override-view-map)))
 463       (set-buffer-modified-p old-modified))))
 464
 465 ;;;###autoload
 466 (defun help-xref-button (match-number type &rest args)
 467   "Make a hyperlink for cross-reference text previously matched.
 468 MATCH-NUMBER is the subexpression of interest in the last matched
 469 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 470 passed to the button's help-function when it is invoked.
 471 See `help-make-xrefs'."
 472   ;; Don't mung properties we've added specially in some instances.
 473   (unless (button-at (match-beginning match-number))
 474     (make-text-button (match-beginning match-number)
 475                       (match-end match-number)
 476                       'type type 'help-args args)))
 477
 478 ;;;###autoload
 479 (defun help-insert-xref-button (string type &rest args)
 480   "Insert STRING and make a hyperlink from cross-reference text on it.
 481 TYPE is the type of button to use.  Any remaining arguments are passed
 482 to the button's help-function when it is invoked.
 483 See `help-make-xrefs'."
 484   (unless (button-at (point))
 485     (insert-text-button string 'type type 'help-args args)))
 486
 487 ;;;###autoload
 488 (defun help-xref-on-pp (from to)
 489   "Add xrefs for symbols in `pp's output between FROM and TO."
 490   (if (> (- to from) 5000) nil
 491     (with-syntax-table emacs-lisp-mode-syntax-table
 492       (save-excursion
 493         (save-restriction
 494           (narrow-to-region from to)
 495           (goto-char (point-min))
 496           (condition-case nil
 497               (while (not (eobp))
 498                 (cond
 499                  ((looking-at "\"") (forward-sexp 1))
 500                  ((looking-at "#<") (search-forward ">" nil 'move))
 501                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 502                   (let* ((sym (intern-soft (match-string 1)))
 503                          (type (cond ((fboundp sym) 'help-function)
 504                                      ((or (memq sym '(t nil))
 505                                           (keywordp sym))
 506                                       nil)
 507                                      ((and sym (boundp sym))
 508                                       'help-variable))))
 509                     (when type (help-xref-button 1 type sym)))
 510                   (goto-char (match-end 1)))
 511                  (t (forward-char 1))))
 512             (error nil)))))))
 513
 514 \f
 515 ;; Additional functions for (re-)creating types of help buffers.
 516 (defun help-xref-interned (symbol)
 517   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 518 Both variable, function and face documentation are extracted into a single
 519 help buffer."
 520   (with-current-buffer (help-buffer)
 521     ;; Push the previous item on the stack before clobbering the output buffer.
 522     (help-setup-xref nil nil)
 523     (let ((facedoc (when (facep symbol)
 524                      ;; Don't record the current entry in the stack.
 525                      (setq help-xref-stack-item nil)
 526                      (describe-face symbol)))
 527           (fdoc (when (fboundp symbol)
 528                   ;; Don't record the current entry in the stack.
 529                   (setq help-xref-stack-item nil)
 530                   (describe-function symbol)))
 531           (sdoc (when (boundp symbol)
 532                   ;; Don't record the current entry in the stack.
 533                   (setq help-xref-stack-item nil)
 534                   (describe-variable symbol))))
 535       (cond
 536        (sdoc
 537         ;; We now have a help buffer on the variable.
 538         ;; Insert the function and face text before it.
 539         (when (or fdoc facedoc)
 540           (goto-char (point-min))
 541           (let ((inhibit-read-only t))
 542             (when fdoc
 543               (insert fdoc "\n\n")
 544               (when facedoc
 545                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 546                         " is also a " "face." "\n\n")))
 547             (when facedoc
 548               (insert facedoc "\n\n"))
 549             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 550                     " is also a " "variable." "\n\n"))
 551           ;; Don't record the `describe-variable' item in the stack.
 552           (setq help-xref-stack-item nil)
 553           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 554        (fdoc
 555         ;; We now have a help buffer on the function.
 556         ;; Insert face text before it.
 557         (when facedoc
 558           (goto-char (point-max))
 559           (let ((inhibit-read-only t))
 560             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 561                     " is also a " "face." "\n\n" facedoc))
 562           ;; Don't record the `describe-function' item in the stack.
 563           (setq help-xref-stack-item nil)
 564           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 565
 566 \f
 567 ;; Navigation/hyperlinking with xrefs
 568
 569 (defun help-follow-mouse (click)
 570   "Follow the cross-reference that you CLICK on."
 571   (interactive "e")
 572   (let* ((start (event-start click))
 573          (window (car start))
 574          (pos (car (cdr start))))
 575     (with-current-buffer (window-buffer window)
 576       (help-follow pos))))
 577
 578 (defun help-xref-go-back (buffer)
 579   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 580   (let (item position method args)
 581     (with-current-buffer buffer
 582       (when help-xref-stack
 583         (setq item (pop help-xref-stack)
 584               ;; Clear the current item so that it won't get pushed
 585               ;; by the function we're about to call.  TODO: We could also
 586               ;; push it onto a "forward" stack and add a `forw' button.
 587               help-xref-stack-item nil
 588               position (car item)
 589               method (cadr item)
 590               args (cddr item))))
 591     (apply method args)
 592     (with-current-buffer buffer
 593       (if (get-buffer-window buffer)
 594           (set-window-point (get-buffer-window buffer) position)
 595         (goto-char position)))))
 596
 597 (defun help-go-back ()
 598   "Go back to previous topic in this help buffer."
 599   (interactive)
 600   (if help-xref-stack
 601       (help-xref-go-back (current-buffer))
 602     (error "No previous help buffer")))
 603
 604 (defun help-do-xref (pos function args)
 605   "Call the help cross-reference function FUNCTION with args ARGS.
 606 Things are set up properly so that the resulting help-buffer has
 607 a proper [back] button."
 608   ;; There is a reference at point.  Follow it.
 609   (let ((help-xref-following t))
 610     (apply function args)))
 611
 612 (defun help-follow (&optional pos)
 613   "Follow cross-reference at POS, defaulting to point.
 614
 615 For the cross-reference format, see `help-make-xrefs'."
 616   (interactive "d")
 617   (unless pos
 618     (setq pos (point)))
 619   (unless (push-button pos)
 620     ;; check if the symbol under point is a function or variable
 621     (let ((sym
 622            (intern
 623             (save-excursion
 624               (goto-char pos) (skip-syntax-backward "w_")
 625               (buffer-substring (point)
 626                                 (progn (skip-syntax-forward "w_")
 627                                        (point)))))))
 628       (when (or (boundp sym) (fboundp sym) (facep sym))
 629         (help-do-xref pos #'help-xref-interned (list sym))))))
 630
 631
 632 (provide 'help-mode)
 633
 634 ;; arch-tag: 850954ae-3725-4cb4-8e91-0bf6d52d6b0b
 635 ;;; help-mode.el ends here