lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Boris Goldowsky <boris@gnu.org>
   7 ;; Maintainer: FSF
   8 ;; Keywords: faces, i18n, Unicode, multilingual
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Describe-Text Mode.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'quail))
  32 (require 'help-fns)
  33
  34 ;;; Describe-Text Utilities.
  35
  36 (defun describe-text-widget (widget)
  37   "Insert text to describe WIDGET in the current buffer."
  38   (insert-text-button
  39    (symbol-name (if (symbolp widget) widget (car widget)))
  40    'action `(lambda (&rest ignore)
  41               (widget-browse ',widget))
  42    'help-echo "mouse-2, RET: browse this widget")
  43   (insert " ")
  44   (insert-text-button
  45    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  46
  47 (defun describe-text-sexp (sexp)
  48   "Insert a short description of SEXP in the current buffer."
  49   (let ((pp (condition-case signal
  50                 (pp-to-string sexp)
  51               (error (prin1-to-string signal)))))
  52     (when (string-match-p "\n\\'" pp)
  53       (setq pp (substring pp 0 (1- (length pp)))))
  54
  55     (if (and (not (string-match-p "\n" pp))
  56              (<= (length pp) (- (window-width) (current-column))))
  57         (insert pp)
  58       (insert-text-button
  59        "[Show]" 'action `(lambda (&rest ignore)
  60                            (with-output-to-temp-buffer
  61                                "*Pp Eval Output*"
  62                              (princ ',pp)))
  63        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  64
  65 (defun describe-property-list (properties)
  66   "Insert a description of PROPERTIES in the current buffer.
  67 PROPERTIES should be a list of overlay or text properties.
  68 The `category', `face' and `font-lock-face' properties are made
  69 into help buttons that call `describe-text-category' or
  70 `describe-face' when pushed."
  71   ;; Sort the properties by the size of their value.
  72   (dolist (elt (sort (let (ret)
  73                        (while properties
  74                          (push (list (pop properties) (pop properties)) ret))
  75                        ret)
  76                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  77                                             (prin1-to-string (nth 0 b) t)))))
  78     (let ((key (nth 0 elt))
  79           (value (nth 1 elt)))
  80       (insert (propertize (format "  %-20s " key)
  81                           'face 'help-argument-name))
  82       (cond ((eq key 'category)
  83              (insert-text-button
  84               (symbol-name value)
  85               'action `(lambda (&rest ignore)
  86                          (describe-text-category ',value))
  87               'help-echo "mouse-2, RET: describe this category"))
  88             ((memq key '(face font-lock-face mouse-face))
  89              (insert-text-button
  90               (format "%S" value)
  91               'type 'help-face 'help-args (list value)))
  92             ((widgetp value)
  93              (describe-text-widget value))
  94             (t
  95              (describe-text-sexp value))))
  96     (insert "\n")))
  97 \f
  98 ;;; Describe-Text Commands.
  99
 100 (defun describe-text-category (category)
 101   "Describe a text property category."
 102   (interactive "SCategory: ")
 103   (help-setup-xref (list #'describe-text-category category) (interactive-p))
 104   (save-excursion
 105     (with-output-to-temp-buffer "*Help*"
 106       (set-buffer standard-output)
 107       (insert "Category " (format "%S" category) ":\n\n")
 108       (describe-property-list (symbol-plist category))
 109       (goto-char (point-min)))))
 110
 111 ;;;###autoload
 112 (defun describe-text-properties (pos &optional output-buffer)
 113   "Describe widgets, buttons, overlays and text properties at POS.
 114 Interactively, describe them for the character after point.
 115 If optional second argument OUTPUT-BUFFER is non-nil,
 116 insert the output into that buffer, and don't initialize or clear it
 117 otherwise."
 118   (interactive "d")
 119   (if (>= pos (point-max))
 120       (error "No character follows specified position"))
 121   (if output-buffer
 122       (describe-text-properties-1 pos output-buffer)
 123     (if (not (or (text-properties-at pos) (overlays-at pos)))
 124         (message "This is plain text.")
 125       (let ((buffer (current-buffer))
 126             (target-buffer "*Help*"))
 127         (when (eq buffer (get-buffer target-buffer))
 128           (setq target-buffer "*Help*<2>"))
 129         (save-excursion
 130           (with-output-to-temp-buffer target-buffer
 131             (set-buffer standard-output)
 132             (setq output-buffer (current-buffer))
 133             (insert "Text content at position " (format "%d" pos) ":\n\n")
 134             (with-current-buffer buffer
 135               (describe-text-properties-1 pos output-buffer))
 136             (goto-char (point-min))))))))
 137
 138 (defun describe-text-properties-1 (pos output-buffer)
 139   (let* ((properties (text-properties-at pos))
 140          (overlays (overlays-at pos))
 141          (wid-field (get-char-property pos 'field))
 142          (wid-button (get-char-property pos 'button))
 143          (wid-doc (get-char-property pos 'widget-doc))
 144          ;; If button.el is not loaded, we have no buttons in the text.
 145          (button (and (fboundp 'button-at) (button-at pos)))
 146          (button-type (and button (button-type button)))
 147          (button-label (and button (button-label button)))
 148          (widget (or wid-field wid-button wid-doc)))
 149     (with-current-buffer output-buffer
 150       ;; Widgets
 151       (when (widgetp widget)
 152         (newline)
 153         (insert (cond (wid-field "This is an editable text area")
 154                       (wid-button "This is an active area")
 155                       (wid-doc "This is documentation text")))
 156         (insert " of a ")
 157         (describe-text-widget widget)
 158         (insert ".\n\n"))
 159       ;; Buttons
 160       (when (and button (not (widgetp wid-button)))
 161         (newline)
 162         (insert "Here is a `" (format "%S" button-type)
 163                 "' button labeled `" button-label "'.\n\n"))
 164       ;; Overlays
 165       (when overlays
 166         (newline)
 167         (if (eq (length overlays) 1)
 168             (insert "There is an overlay here:\n")
 169           (insert "There are " (format "%d" (length overlays))
 170                          " overlays here:\n"))
 171         (dolist (overlay overlays)
 172           (insert " From " (format "%d" (overlay-start overlay))
 173                          " to " (format "%d" (overlay-end overlay)) "\n")
 174           (describe-property-list (overlay-properties overlay)))
 175         (insert "\n"))
 176       ;; Text properties
 177       (when properties
 178         (newline)
 179         (insert "There are text properties here:\n")
 180         (describe-property-list properties)))))
 181 \f
 182 (defcustom describe-char-unidata-list
 183   '(name old-name general-category decomposition)
 184   "List of Unicode-based character property names shown by `describe-char'."
 185   :group 'mule
 186   :version "23.1"
 187   :type '(choice (const :tag "All properties" t)
 188           (set
 189            (const :tag "Unicode Name" name)
 190            (const :tag "Unicode old name" old-name)
 191            (const :tag "Unicode general category " general-category)
 192            (const :tag "Unicode canonical combining class"
 193                   canonical-combining-class)
 194            (const :tag "Unicode bidi class" bidi-class)
 195            (const :tag "Unicode decomposition mapping" decomposition)
 196            (const :tag "Unicode decimal digit value" decimal-digit-value)
 197            (const :tag "Unicode digit value" digit-value)
 198            (const :tag "Unicode numeric value" numeric-value)
 199            (const :tag "Unicode mirrored" mirrored)
 200            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 201            (const :tag "Unicode simple uppercase mapping" uppercase)
 202            (const :tag "Unicode simple lowercase mapping" lowercase)
 203            (const :tag "Unicode simple titlecase mapping" titlecase))))
 204
 205 (defcustom describe-char-unicodedata-file nil
 206   "Location of Unicode data file.
 207 This is the UnicodeData.txt file from the Unicode Consortium, used for
 208 diagnostics.  If it is non-nil `describe-char' will print data
 209 looked up from it.  This facility is mostly of use to people doing
 210 multilingual development.
 211
 212 This is a fairly large file, not typically present on GNU systems.
 213 At the time of writing it is at the URL
 214 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 215   :group 'mule
 216   :version "22.1"
 217   :type '(choice (const :tag "None" nil)
 218                  file))
 219
 220 (defun describe-char-unicode-data (char)
 221   "Return a list of Unicode data for unicode CHAR.
 222 Each element is a list of a property description and the property value.
 223 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 224 This function is semi-obsolete.  Use `get-char-code-property'."
 225   (when describe-char-unicodedata-file
 226     (unless (file-exists-p describe-char-unicodedata-file)
 227       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 228     (with-current-buffer (get-buffer-create " *Unicode Data*")
 229       (when (zerop (buffer-size))
 230         ;; Don't use -literally in case of DOS line endings.
 231         (insert-file-contents describe-char-unicodedata-file))
 232       (goto-char (point-min))
 233       (let ((hex (format "%04X" char))
 234             found first last)
 235         (if (re-search-forward (concat "^" hex) nil t)
 236             (setq found t)
 237           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 238           ;; ideographs, and check whether it's in one of them.
 239           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 240                       (>= char (setq first
 241                                      (string-to-number (match-string 1) 16)))
 242                       (progn
 243                         (forward-line 1)
 244                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 245                         (> char
 246                            (setq last
 247                                  (string-to-number (match-string 1) 16))))))
 248           (if (and (>= char first)
 249                    (<= char last))
 250               (setq found t)))
 251         (if found
 252             (let ((fields (mapcar (lambda (elt)
 253                                     (if (> (length elt) 0)
 254                                         elt))
 255                                   (cdr (split-string
 256                                         (buffer-substring
 257                                          (line-beginning-position)
 258                                          (line-end-position))
 259                                         ";")))))
 260               ;; The length depends on whether the last field was empty.
 261               (unless (or (= 13 (length fields))
 262                           (= 14 (length fields)))
 263                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 264               ;; The field names and values lists are slightly
 265               ;; modified from Mule-UCS unidata.el.
 266               (list
 267                (list "Name" (let ((name (nth 0 fields)))
 268                               ;; Check for <..., First>, <..., Last>
 269                               (if (string-match "\\`\\(<[^,]+\\)," name)
 270                                   (concat (match-string 1 name) ">")
 271                                 name)))
 272                (list "Category"
 273                      (let ((val (nth 1 fields)))
 274                        (or (char-code-property-description
 275                             'general-category (intern val))
 276                            val)))
 277                (list "Combining class"
 278                      (let ((val (nth 1 fields)))
 279                        (or (char-code-property-description
 280                             'canonical-combining-class (intern val))
 281                            val)))
 282                (list "Bidi category"
 283                      (let ((val (nth 1 fields)))
 284                        (or (char-code-property-description
 285                             'bidi-class (intern val))
 286                            val)))
 287                (list
 288                 "Decomposition"
 289                 (if (nth 4 fields)
 290                     (let* ((parts (split-string (nth 4 fields)))
 291                            (info (car parts)))
 292                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 293                           (setq info (match-string 1 info))
 294                         (setq info nil))
 295                       (if info (setq parts (cdr parts)))
 296                       (setq parts (mapconcat
 297                                    (lambda (arg)
 298                                      (string (string-to-number arg 16)))
 299                                    parts " "))
 300                       (concat info parts))))
 301                (list "Decimal digit value"
 302                      (nth 5 fields))
 303                (list "Digit value"
 304                      (nth 6 fields))
 305                (list "Numeric value"
 306                      (nth 7 fields))
 307                (list "Mirrored"
 308                      (if (equal "Y" (nth 8 fields))
 309                          "yes"))
 310                (list "Old name" (nth 9 fields))
 311                (list "ISO 10646 comment" (nth 10 fields))
 312                (list "Uppercase" (and (nth 11 fields)
 313                                       (string (string-to-number
 314                                                (nth 11 fields) 16))))
 315                (list "Lowercase" (and (nth 12 fields)
 316                                       (string (string-to-number
 317                                                (nth 12 fields) 16))))
 318                (list "Titlecase" (and (nth 13 fields)
 319                                       (string (string-to-number
 320                                                (nth 13 fields) 16)))))))))))
 321
 322 ;; Not defined on builds without X, but behind display-graphic-p.
 323 (declare-function internal-char-font "fontset.c" (position &optional ch))
 324
 325 ;; Return information about how CHAR is displayed at the buffer
 326 ;; position POS.  If the selected frame is on a graphic display,
 327 ;; return a string "FONT-DRIVER:FONT-NAME (GLYPH-CODE)" where:
 328 ;;   FONT-DRIVER is the font-driver name,
 329 ;;   FONT-NAME is the font name,
 330 ;;   GLYPH-CODE is a hexadigit string representing the glyph-ID.
 331 ;; Otherwise, return a string describing the terminal codes for the
 332 ;; character.
 333 (defun describe-char-display (pos char)
 334   (if (display-graphic-p (selected-frame))
 335       (let ((char-font-info (internal-char-font pos char)))
 336         (if char-font-info
 337             (let ((type (font-get (car char-font-info) :type))
 338                   (name (font-xlfd-name (car char-font-info)))
 339                   (code (cdr char-font-info)))
 340                (if (integerp code)
 341                    (format "%s:%s (#x%02X)" type name code)
 342                  (format "%s:%s (#x%04X%04X)"
 343                          type name (car code) (cdr code))))))
 344     (let* ((charset (get-text-property pos 'charset))
 345            (coding (terminal-coding-system))
 346            (encoded (encode-coding-char char coding charset)))
 347       (if encoded
 348           (encoded-string-description encoded coding)))))
 349
 350 \f
 351 ;; Return a string of CH with composition for padding on both sides.
 352 ;; It is displayed without overlapping with the left/right columns.
 353 (defsubst describe-char-padded-string (ch)
 354   (compose-string (string ch) 0 1 (format "\t%c\t" ch)))
 355
 356 ;;;###autoload
 357 (defun describe-char (pos)
 358   "Describe the character after POS (interactively, the character after point).
 359 The information includes character code, charset and code points in it,
 360 syntax, category, how the character is encoded in a file,
 361 character composition information (if relevant),
 362 as well as widgets, buttons, overlays, and text properties."
 363   (interactive "d")
 364   (if (>= pos (point-max))
 365       (error "No character follows specified position"))
 366   (let* ((char (char-after pos))
 367          (charset (or (get-text-property pos 'charset) (char-charset char)))
 368          (composition (find-composition pos nil nil t))
 369          (component-chars nil)
 370          (display-table (or (window-display-table)
 371                             buffer-display-table
 372                             standard-display-table))
 373          (disp-vector (and display-table (aref display-table char)))
 374          (multibyte-p enable-multibyte-characters)
 375          (overlays (mapcar #'(lambda (o) (overlay-properties o))
 376                            (overlays-at pos)))
 377          (char-description (if (not multibyte-p)
 378                                (single-key-description char)
 379                              (if (< char 128)
 380                                  (single-key-description char)
 381                                (string-to-multibyte
 382                                 (char-to-string char)))))
 383          (text-props-desc
 384           (let ((tmp-buf (generate-new-buffer " *text-props*")))
 385             (unwind-protect
 386                 (progn
 387                   (describe-text-properties pos tmp-buf)
 388                   (with-current-buffer tmp-buf (buffer-string)))
 389               (kill-buffer tmp-buf))))
 390          item-list max-width code)
 391
 392     (or (setq code (encode-char char charset))
 393         (setq charset (char-charset char)
 394               code (encode-char char charset)))
 395     (setq item-list
 396           `(("character"
 397              ,(format "%s (%d, #o%o, #x%x)"
 398                       (apply 'propertize char-description
 399                              (text-properties-at pos))
 400                       char char char))
 401             ("preferred charset"
 402              ,`(insert-text-button
 403                 ,(symbol-name charset)
 404                 'type 'help-character-set 'help-args '(,charset))
 405              ,(format "(%s)" (charset-description charset)))
 406             ("code point"
 407              ,(let ((str (if (integerp code)
 408                              (format (if (< code 256) "0x%02X" "0x%04X") code)
 409                            (format "0x%04X%04X" (car code) (cdr code)))))
 410                 (if (<= (charset-dimension charset) 2)
 411                     `(insert-text-button
 412                       ,str
 413                       'action (lambda (&rest ignore)
 414                                 (list-charset-chars ',charset)
 415                                 (with-selected-window
 416                                     (get-buffer-window "*Character List*" 0)
 417                                   (goto-char (point-min))
 418                                   (forward-line 2) ;Skip the header.
 419                                   (let ((case-fold-search nil))
 420                                     (if (search-forward ,(char-to-string char)
 421                                                         nil t)
 422                                         (goto-char (match-beginning 0))))))
 423                       'help-echo
 424                       "mouse-2, RET: show this character in its character set")
 425                   str)))
 426             ("syntax"
 427              ,(let ((syntax (syntax-after pos)))
 428                 (with-temp-buffer
 429                   (internal-describe-syntax-value syntax)
 430                   (buffer-string))))
 431             ("category"
 432              ,@(let ((category-set (char-category-set char)))
 433                  (if (not category-set)
 434                      '("-- none --")
 435                    (mapcar #'(lambda (x) (format "%c:%s"
 436                                                  x (category-docstring x)))
 437                            (category-set-mnemonics category-set)))))
 438             ("to input"
 439              ,@(let ((key-list (and (eq input-method-function
 440                                         'quail-input-method)
 441                                     (quail-find-key char))))
 442                  (if (consp key-list)
 443                      (list "type"
 444                            (mapconcat #'(lambda (x) (concat "\"" x "\""))
 445                                       key-list " or ")
 446                            "with"
 447                            `(insert-text-button
 448                              ,current-input-method
 449                              'type 'help-input-method
 450                              'help-args '(,current-input-method))))))
 451             ("buffer code"
 452              ,(encoded-string-description
 453                (string-as-unibyte (char-to-string char)) nil))
 454             ("file code"
 455              ,@(let* ((coding buffer-file-coding-system)
 456                       (encoded (encode-coding-char char coding charset)))
 457                  (if encoded
 458                      (list (encoded-string-description encoded coding)
 459                            (format "(encoded by coding system %S)" coding))
 460                    (list "not encodable by coding system"
 461                          (symbol-name coding)))))
 462             ("display"
 463              ,(cond
 464                (disp-vector
 465                 (setq disp-vector (copy-sequence disp-vector))
 466                 (dotimes (i (length disp-vector))
 467                   (aset disp-vector i
 468                         (cons (aref disp-vector i)
 469                               (describe-char-display
 470                                pos (glyph-char (aref disp-vector i))))))
 471                 (format "by display table entry [%s] (see below)"
 472                         (mapconcat
 473                          #'(lambda (x)
 474                              (format "?%c" (glyph-char (car x))))
 475                          disp-vector " ")))
 476                (composition
 477                 (let ((from (car composition))
 478                       (to (nth 1 composition))
 479                       (next (1+ pos))
 480                       (components (nth 2 composition))
 481                       ch)
 482                   (setcar composition
 483                           (and (< from pos) (buffer-substring from pos)))
 484                   (setcar (cdr composition)
 485                           (and (< next to) (buffer-substring next to)))
 486                   (dotimes (i (length components))
 487                     (if (integerp (setq ch (aref components i)))
 488                         (push (cons ch (describe-char-display pos ch))
 489                               component-chars)))
 490                   (setq component-chars (nreverse component-chars))
 491                   (format "composed to form \"%s\" (see below)"
 492                           (buffer-substring from to))))
 493                (t
 494                 (let ((display (describe-char-display pos char)))
 495                   (if (display-graphic-p (selected-frame))
 496                       (if display
 497                           (concat "by this font (glyph code)\n    " display)
 498                         "no font available")
 499                     (if display
 500                         (format "terminal code %s" display)
 501                       "not encodable for terminal"))))))
 502             ,@(let ((face
 503                      (if (not (or disp-vector composition))
 504                          (cond
 505                           ((and show-trailing-whitespace
 506                                 (save-excursion (goto-char pos)
 507                                                 (looking-at-p "[ \t]+$")))
 508                            'trailing-whitespace)
 509                           ((and nobreak-char-display char (eq char '#xa0))
 510                            'nobreak-space)
 511                           ((and nobreak-char-display char (eq char '#xad))
 512                            'escape-glyph)
 513                           ((and (< char 32) (not (memq char '(9 10))))
 514                            'escape-glyph)))))
 515                 (if face (list (list "hardcoded face"
 516                                      `(insert-text-button
 517                                        ,(symbol-name face)
 518                                        'type 'help-face 'help-args '(,face))))))
 519             ,@(let ((unicodedata (describe-char-unicode-data char)))
 520                 (if unicodedata
 521                     (cons (list "Unicode data" " ") unicodedata)))))
 522     (setq max-width (apply #'max (mapcar #'(lambda (x)
 523                                              (if (cadr x) (length (car x)) 0))
 524                                          item-list)))
 525     (help-setup-xref nil (interactive-p))
 526     (with-help-window (help-buffer)
 527       (with-current-buffer standard-output
 528         (set-buffer-multibyte multibyte-p)
 529         (let ((formatter (format "%%%ds:" max-width)))
 530           (dolist (elt item-list)
 531             (when (cadr elt)
 532               (insert (format formatter (car elt)))
 533               (dolist (clm (cdr elt))
 534                 (if (eq (car-safe clm) 'insert-text-button)
 535                     (progn (insert " ") (eval clm))
 536                   (when (>= (+ (current-column)
 537                                (or (string-match-p "\n" clm)
 538                                    (string-width clm))
 539                                1)
 540                             (window-width))
 541                     (insert "\n")
 542                     (indent-to (1+ max-width)))
 543                   (insert " " clm)))
 544               (insert "\n"))))
 545
 546         (when overlays
 547           (save-excursion
 548             (goto-char (point-min))
 549             (re-search-forward "character:[ \t\n]+")
 550             (let ((end (+ (point) (length char-description))))
 551               (mapc #'(lambda (props)
 552                         (let ((o (make-overlay (point) end)))
 553                           (while props
 554                             (overlay-put o (car props) (nth 1 props))
 555                             (setq props (cddr props)))))
 556                     overlays))))
 557
 558         (when disp-vector
 559           (insert
 560            "\nThe display table entry is displayed by ")
 561           (if (display-graphic-p (selected-frame))
 562               (progn
 563                 (insert "these fonts (glyph codes):\n")
 564                 (dotimes (i (length disp-vector))
 565                   (insert (glyph-char (car (aref disp-vector i))) ?:
 566                           (propertize " " 'display '(space :align-to 5))
 567                           (or (cdr (aref disp-vector i)) "-- no font --")
 568                           "\n")
 569                   (let ((face (glyph-face (car (aref disp-vector i)))))
 570                     (when face
 571                       (insert (propertize " " 'display '(space :align-to 5))
 572                               "face: ")
 573                       (insert (concat "`" (symbol-name face) "'"))
 574                       (insert "\n")))))
 575             (insert "these terminal codes:\n")
 576             (dotimes (i (length disp-vector))
 577               (insert (car (aref disp-vector i))
 578                       (propertize " " 'display '(space :align-to 5))
 579                       (or (cdr (aref disp-vector i)) "-- not encodable --")
 580                       "\n"))))
 581
 582         (when composition
 583           (insert "\nComposed")
 584           (if (car composition)
 585               (if (cadr composition)
 586                   (insert " with the surrounding characters \""
 587                           (mapconcat 'describe-char-padded-string
 588                                      (car composition) "")
 589                           "\" and \""
 590                           (mapconcat 'describe-char-padded-string
 591                                      (cadr composition) "")
 592                           "\"")
 593                 (insert " with the preceding character(s) \""
 594                         (mapconcat 'describe-char-padded-string
 595                                    (car composition) "")
 596                         "\""))
 597             (if (cadr composition)
 598                 (insert " with the following character(s) \""
 599                         (mapconcat 'describe-char-padded-string
 600                                    (cadr composition) "")
 601                         "\"")))
 602           (if (and (vectorp (nth 2 composition))
 603                    (vectorp (aref (nth 2 composition) 0)))
 604               (let* ((gstring (nth 2 composition))
 605                      (font (lgstring-font gstring))
 606                      (nglyphs (lgstring-glyph-len gstring))
 607                      (i 0)
 608                      glyph)
 609                 (if font
 610                     (progn
 611                       (insert " using this font:\n  "
 612                               (symbol-name (font-get font :type))
 613                               ?:
 614                               (aref (query-font font) 0)
 615                               "\nby these glyphs:\n")
 616                       (while (and (< i nglyphs)
 617                                   (setq glyph (lgstring-glyph gstring i)))
 618                         (insert (format "  %S\n" glyph))
 619                         (setq i (1+ i))))
 620                   (insert " by these characters:\n")
 621                   (while (and (< i nglyphs)
 622                               (setq glyph (lgstring-glyph gstring i)))
 623                     (insert (format " %c (#x%d)\n"
 624                                     (lglyph-char glyph) (lglyph-char glyph)))
 625                     (setq i (1+ i)))))
 626             (insert " by the rule:\n\t(")
 627             (let ((first t))
 628               (mapc (lambda (x)
 629                       (if first (setq first nil)
 630                         (insert " "))
 631                       (if (consp x) (insert (format "%S" x))
 632                         (if (= x ?\t) (insert (single-key-description x))
 633                           (insert ??)
 634                           (insert (describe-char-padded-string x)))))
 635                     (nth 2 composition)))
 636             (insert  ")\nThe component character(s) are displayed by ")
 637             (if (display-graphic-p (selected-frame))
 638                 (progn
 639                   (insert "these fonts (glyph codes):")
 640                   (dolist (elt component-chars)
 641                     (if (/= (car elt) ?\t)
 642                         (insert "\n "
 643                                 (describe-char-padded-string (car elt))
 644                                 ?:
 645                                 (propertize " " 'display '(space :align-to 5))
 646                                 (or (cdr elt) "-- no font --")))))
 647               (insert "these terminal codes:")
 648               (dolist (elt component-chars)
 649                 (insert "\n  " (car elt) ":"
 650                         (propertize " " 'display '(space :align-to 4))
 651                         (or (cdr elt) "-- not encodable --"))))
 652             (insert "\nSee the variable `reference-point-alist' for "
 653                     "the meaning of the rule.\n")))
 654
 655         (insert (if (not describe-char-unidata-list)
 656                     "\nCharacter code properties are not shown: "
 657                   "\nCharacter code properties: "))
 658         (insert-text-button
 659          "customize what to show"
 660          'action (lambda (&rest ignore)
 661                    (customize-variable
 662                     'describe-char-unidata-list)))
 663         (insert "\n")
 664         (dolist (elt (if (eq describe-char-unidata-list t)
 665                          (nreverse (mapcar 'car char-code-property-alist))
 666                        describe-char-unidata-list))
 667           (let ((val (get-char-code-property char elt))
 668                 description)
 669             (when val
 670               (setq description (char-code-property-description elt val))
 671               (insert (if description
 672                           (format "  %s: %s (%s)\n" elt val description)
 673                         (format "  %s: %s\n" elt val))))))
 674
 675         (if text-props-desc (insert text-props-desc))
 676         (setq help-xref-stack-item (list 'help-insert-string (buffer-string)))
 677         (toggle-read-only 1)))))
 678
 679 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 680
 681 (provide 'descr-text)
 682
 683 ;; arch-tag: fc55a498-f3e9-4312-b5bd-98cc02480af1
 684 ;;; descr-text.el ends here