lisp/reposition.el

   1 ;;; reposition.el --- center a Lisp function or comment on the screen
   2
   3 ;; Copyright (C) 1991, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael D. Ernst <mernst@theory.lcs.mit.edu>
   6 ;; Created: Jan 1991
   7 ;; Maintainer: FSF
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Reposition-window makes an entire function definition or comment visible,
  29 ;; or, if it is already visible, places it at the top of the window;
  30 ;; additional invocations toggle the visibility of comments preceding the
  31 ;; code.  For the gory details, see the documentation for reposition-window;
  32 ;; rather than reading that, you may just want to play with it.
  33
  34 ;; This tries pretty hard to do the recentering correctly; the precise
  35 ;; action depends on what the buffer looks like.  If you find a situation
  36 ;; where it doesn't behave well, let me know.  This function is modeled
  37 ;; after one of the same name in ZMACS, but the code is all-new and the
  38 ;; behavior in some situations differs.
  39
  40 ;;; Code:
  41
  42 ;;;###autoload
  43 (defun reposition-window (&optional arg)
  44   "Make the current definition and/or comment visible.
  45 Further invocations move it to the top of the window or toggle the
  46 visibility of comments that precede it.
  47   Point is left unchanged unless prefix ARG is supplied.
  48   If the definition is fully onscreen, it is moved to the top of the
  49 window.  If it is partly offscreen, the window is scrolled to get the
  50 definition (or as much as will fit) onscreen, unless point is in a comment
  51 which is also partly offscreen, in which case the scrolling attempts to get
  52 as much of the comment onscreen as possible.
  53   Initially `reposition-window' attempts to make both the definition and
  54 preceding comments visible.  Further invocations toggle the visibility of
  55 the comment lines.
  56   If ARG is non-nil, point may move in order to make the whole defun
  57 visible (if only part could otherwise be made so), to make the defun line
  58 visible (if point is in code and it could not be made so, or if only
  59 comments, including the first comment line, are visible), or to make the
  60 first comment line visible (if point is in a comment)."
  61   (interactive "P")
  62   (let* (;; (here (save-excursion (beginning-of-line) (point)))
  63          (here (point))
  64          ;; change this name once I've gotten rid of references to ht.
  65          ;; this is actually the number of the last screen line
  66          (ht (- (window-height (selected-window)) 2))
  67          (line (repos-count-screen-lines (window-start) (point)))
  68          (comment-height
  69           ;; The call to max deals with the case of cursor between defuns.
  70           (max 0
  71                (repos-count-screen-lines-signed
  72                 ;; the beginning of the preceding comment
  73                 (save-excursion
  74                   (if (not (eobp)) (forward-char 1))
  75                   (end-of-defun -1)
  76                   ;; Skip whitespace, newlines, and form feeds.
  77                   (if (re-search-forward "[^ \t\n\f]" nil t)
  78                       (backward-char 1))
  79                   (point))
  80                 here)))
  81          (defun-height
  82            (repos-count-screen-lines-signed
  83             (save-excursion
  84               (end-of-defun 1) ; so comments associate with following defuns
  85               (beginning-of-defun 1)
  86               (point))
  87             here))
  88          ;; This must be positive, so don't use the signed version.
  89          (defun-depth (repos-count-screen-lines here
  90                                                 (save-excursion
  91                                                   (end-of-defun 1)
  92                                                   (point))))
  93          (defun-line-onscreen-p
  94            (and (<= defun-height line)
  95                 (<= (- line defun-height) ht))))
  96     (cond ((or (= comment-height line)
  97                (and (= line ht)
  98                     (> comment-height line)
  99                     ;; if defun line offscreen, we should be in case 4
 100                     defun-line-onscreen-p))
 101            ;; Either first comment line is at top of screen or (point at
 102            ;; bottom of screen, defun line onscreen, and first comment line
 103            ;; off top of screen).  That is, it looks like we just did
 104            ;; recenter-definition, trying to fit as much of the comment
 105            ;; onscreen as possible.  Put defun line at top of screen; that
 106            ;; is, show as much code, and as few comments, as possible.
 107
 108            (if (and arg (> defun-depth (1+ ht)))
 109                ;; Can't fit whole defun onscreen without moving point.
 110                (progn (end-of-defun) (beginning-of-defun) (recenter 0))
 111              (recenter (max defun-height 0)))
 112            ;;(repos-debug-macro "1")
 113            )
 114
 115           ((or (= defun-height line)
 116                (= line 0)
 117                (and (< line comment-height)
 118                     (< defun-height 0)))
 119            ;; Defun line or cursor at top of screen, OR cursor in comment
 120            ;; whose first line is offscreen.
 121            ;; Avoid moving definition up even if defun runs offscreen;
 122            ;; we care more about getting the comment onscreen.
 123
 124            (cond ((= line ht)
 125                   ;; cursor on last screen line (and so in a comment)
 126                   (if arg (progn (end-of-defun) (beginning-of-defun)))
 127                   (recenter 0)
 128                   ;;(repos-debug-macro "2a")
 129                   )
 130
 131                  ;; This condition, copied from case 4, may not be quite right
 132
 133                  ((and arg (< ht comment-height))
 134                   ;; Can't get first comment line onscreen.
 135                   ;; Go there and try again.
 136                   (forward-line (- comment-height))
 137                   (beginning-of-line)
 138                   ;; was (reposition-window)
 139                   (recenter 0)
 140                   ;;(repos-debug-macro "2b")
 141                   )
 142                  (t
 143                   (recenter (min ht comment-height))
 144                   ;;(repos-debug-macro "2c")
 145                   ))
 146            ;; (recenter (min ht comment-height))
 147            )
 148
 149           ((and (> (+ line defun-depth -1) ht)
 150                 defun-line-onscreen-p)
 151            ;; Defun runs off the bottom of the screen and the defun line
 152            ;; is onscreen.
 153            ;; Move the defun up.
 154            (recenter (max 0 (1+ (- ht defun-depth)) defun-height))
 155            ;;(repos-debug-macro "3")
 156            )
 157
 158           (t
 159            ;; If on the bottom line and comment start is offscreen
 160            ;; then just move all comments offscreen, or at least as
 161            ;; far as they'll go.
 162
 163            ;; Try to get as much of the comments onscreen as possible.
 164            (if (and arg (< ht comment-height))
 165                ;; Can't get defun line onscreen; go there and try again.
 166                (progn (forward-line (- defun-height))
 167                       (beginning-of-line)
 168                       (reposition-window))
 169              (recenter (min ht comment-height)))
 170            ;;(repos-debug-macro "4")
 171            ))))
 172
 173 ;;;###autoload (define-key esc-map "\C-l" 'reposition-window)
 174
 175 ;;; Auxiliary functions
 176
 177 ;; Return number of screen lines between START and END.
 178 (defun repos-count-screen-lines (start end)
 179   (save-excursion
 180     (save-restriction
 181       (narrow-to-region start end)
 182       (goto-char (point-min))
 183       (vertical-motion (- (point-max) (point-min))))))
 184
 185 ;; Return number of screen lines between START and END; returns a negative
 186 ;; number if END precedes START.
 187 (defun repos-count-screen-lines-signed (start end)
 188   (let ((lines (repos-count-screen-lines start end)))
 189     (if (< start end)
 190         lines
 191       (- lines))))
 192
 193 ;; (defmacro repos-debug-macro (case-no)
 194 ;;   (` (message
 195 ;;       (concat "Case " (, case-no) ": %s %s %s %s %s")
 196 ;;       ht line comment-height defun-height defun-depth)))
 197
 198 (provide 'reposition)
 199
 200 ;;; reposition.el ends here