lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do `M-x describe-mode'.
  33 ;;
  34 ;; This may be useful in your .emacs:
  35 ;;
  36 ;;      (autoload 'hexl-find-file "hexl"
  37 ;;        "Edit file FILENAME in hexl-mode." t)
  38 ;;
  39 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40 ;;
  41 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42 ;;
  43 ;; Currently hexl only supports big endian hex output with 16 bit
  44 ;; grouping.
  45 ;;
  46 ;; -iso in `hexl-options' will allow iso characters to display in the
  47 ;; ASCII region of the screen (if your emacs supports this) instead of
  48 ;; changing them to dots.
  49
  50 ;;; Code:
  51
  52 ;;
  53 ;; vars here
  54 ;;
  55
  56 (defgroup hexl nil
  57   "Edit a file in a hex dump format using the hexl filter."
  58   :group 'data)
  59
  60
  61 (defcustom hexl-program "hexl"
  62   "The program that will hexlify and dehexlify its stdin.
  63 `hexl-program' will always be concatenated with `hexl-options'
  64 and \"-de\" when dehexlifying a buffer."
  65   :type 'string
  66   :group 'hexl)
  67
  68 (defcustom hexl-iso ""
  69   "If your emacs can handle ISO characters, this should be set to
  70 \"-iso\" otherwise it should be \"\"."
  71   :type 'string
  72   :group 'hexl)
  73
  74 (defcustom hexl-options (format "-hex %s" hexl-iso)
  75   "Options to hexl-program that suit your needs."
  76   :type 'string
  77   :group 'hexl)
  78
  79 (defcustom hexlify-command
  80   (format "%s%s %s" exec-directory hexl-program hexl-options)
  81   "The command to use to hexlify a buffer."
  82   :type 'string
  83   :group 'hexl)
  84
  85 (defcustom dehexlify-command
  86   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  87   "The command to use to unhexlify a buffer."
  88   :type 'string
  89   :group 'hexl)
  90
  91 (defvar hexl-max-address 0
  92   "Maximum offset into hexl buffer.")
  93
  94 (defvar hexl-mode-map nil)
  95
  96 (defvar hexl-mode-old-local-map)
  97 (defvar hexl-mode-old-mode-name)
  98 (defvar hexl-mode-old-major-mode)
  99 (defvar hexl-mode-old-write-contents-hooks)
 100 (defvar hexl-mode-old-require-final-newline)
 101 (defvar hexl-mode-old-syntax-table)
 102
 103 ;; routines
 104
 105 (put 'hexl-mode 'mode-class 'special)
 106
 107 ;;;###autoload
 108 (defun hexl-mode (&optional arg)
 109   "\\<hexl-mode-map>
 110 A major mode for editing binary files in hex dump format.
 111
 112 This function automatically converts a buffer into the hexl format
 113 using the function `hexlify-buffer'.
 114
 115 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 116 representing the offset into the file that the characters on this line
 117 are at and 16 characters from the file (displayed as hexadecimal
 118 values grouped every 16 bits) and as their ASCII values.
 119
 120 If any of the characters (displayed as ASCII characters) are
 121 unprintable (control or meta characters) they will be replaced as
 122 periods.
 123
 124 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 125 in hexl format.
 126
 127 A sample format:
 128
 129   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 130   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 131   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 132   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 133   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 134   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 135   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 136   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 137   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 138   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 139   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 140   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 141   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 142   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 143   000000c0: 7265 6769 6f6e 2e0a                      region..
 144
 145 Movement is as simple as movement in a normal emacs text buffer.  Most
 146 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 147 to move the cursor left, right, down, and up).
 148
 149 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 150 also supported.
 151
 152 There are several ways to change text in hexl mode:
 153
 154 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 155 bound to self-insert so you can simply type the character and it will
 156 insert itself (actually overstrike) into the buffer.
 157
 158 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 159 it isn't bound to self-insert.  An octal number can be supplied in place
 160 of another key to insert the octal number's ASCII representation.
 161
 162 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 163 into the buffer at the current point.
 164
 165 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 166 into the buffer at the current point.
 167
 168 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 169 into the buffer at the current point.
 170
 171 \\[hexl-mode-exit] will exit hexl-mode.
 172
 173 Note: saving the file with any of the usual Emacs commands
 174 will actually convert it back to binary format while saving.
 175
 176 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 177
 178 \\[describe-bindings] for advanced commands."
 179   (interactive "p")
 180   (if (eq major-mode 'hexl-mode)
 181       (error "You are already in hexl mode")
 182
 183     (let ((modified (buffer-modified-p))
 184           (inhibit-read-only t)
 185           (original-point (1- (point)))
 186           max-address)
 187       (and (eobp) (not (bobp))
 188            (setq original-point (1- original-point)))
 189       (if (not (or (eq arg 1) (not arg)))
 190           ;; if no argument then we guess at hexl-max-address
 191           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 192         (setq max-address (1- (buffer-size)))
 193         (hexlify-buffer)
 194         (set-buffer-modified-p modified))
 195       (make-local-variable 'hexl-max-address)
 196       (setq hexl-max-address max-address)
 197       (hexl-goto-address original-point))
 198
 199     ;; We do not turn off the old major mode; instead we just
 200     ;; override most of it.  That way, we can restore it perfectly.
 201     (make-local-variable 'hexl-mode-old-local-map)
 202     (setq hexl-mode-old-local-map (current-local-map))
 203     (use-local-map hexl-mode-map)
 204
 205     (make-local-variable 'hexl-mode-old-mode-name)
 206     (setq hexl-mode-old-mode-name mode-name)
 207     (setq mode-name "Hexl")
 208
 209     (make-local-variable 'hexl-mode-old-major-mode)
 210     (setq hexl-mode-old-major-mode major-mode)
 211     (setq major-mode 'hexl-mode)
 212
 213     (make-local-variable 'hexl-mode-old-syntax-table)
 214     (setq hexl-mode-old-syntax-table (syntax-table))
 215     (set-syntax-table (standard-syntax-table))
 216
 217     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 218     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 219     (make-local-variable 'write-contents-hooks)
 220     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 221
 222     (make-local-variable 'hexl-mode-old-require-final-newline)
 223     (setq hexl-mode-old-require-final-newline require-final-newline)
 224     (make-local-variable 'require-final-newline)
 225     (setq require-final-newline nil)
 226
 227     ;; Add hooks to rehexlify or dehexlify on various events.
 228     (make-local-hook 'after-revert-hook)
 229     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 230
 231     (make-local-hook 'change-major-mode-hook)
 232     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t))
 233   (run-hooks 'hexl-mode-hook))
 234
 235 (defun hexl-after-revert-hook ()
 236   (hexlify-buffer)
 237   (set-buffer-modified-p nil))
 238
 239 (defvar hexl-in-save-buffer nil)
 240
 241 (defun hexl-save-buffer ()
 242   "Save a hexl format buffer as binary in visited file if modified."
 243   (interactive)
 244   (if hexl-in-save-buffer nil
 245     (set-buffer-modified-p (if (buffer-modified-p)
 246                                (save-excursion
 247                                  (let ((buf (generate-new-buffer " hexl"))
 248                                        (name (buffer-name))
 249                                        (file-name (buffer-file-name))
 250                                        (start (point-min))
 251                                        (end (point-max))
 252                                        modified)
 253                                    (set-buffer buf)
 254                                    (insert-buffer-substring name start end)
 255                                    (set-buffer name)
 256                                    (dehexlify-buffer)
 257                                    ;; Prevent infinite recursion.
 258                                    (let ((hexl-in-save-buffer t)
 259                                          (buffer-file-type t)) ; for ms-dos
 260                                      (save-buffer))
 261                                    (setq modified (buffer-modified-p))
 262                                    (delete-region (point-min) (point-max))
 263                                    (insert-buffer-substring buf start end)
 264                                    (kill-buffer buf)
 265                                    modified))
 266                              (message "(No changes need to be saved)")
 267                              nil))
 268     ;; Return t to indicate we have saved t
 269     t))
 270
 271 ;;;###autoload
 272 (defun hexl-find-file (filename)
 273   "Edit file FILENAME in hexl-mode.
 274 Switch to a buffer visiting file FILENAME, creating one in none exists."
 275   (interactive "fFilename: ")
 276   (if (or (eq system-type 'ms-dos) (eq system-type 'windows-nt))
 277       (find-file-binary filename)
 278     (find-file filename))
 279   (if (not (eq major-mode 'hexl-mode))
 280       (hexl-mode)))
 281
 282 (defun hexl-mode-exit (&optional arg)
 283   "Exit Hexl mode, returning to previous mode.
 284 With arg, don't unhexlify buffer."
 285   (interactive "p")
 286   (if (or (eq arg 1) (not arg))
 287       (let ((modified (buffer-modified-p))
 288             (inhibit-read-only t)
 289             (original-point (1+ (hexl-current-address))))
 290         (dehexlify-buffer)
 291         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 292         (set-buffer-modified-p modified)
 293         (goto-char original-point)))
 294
 295   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 296   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 297
 298   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 299   (setq require-final-newline hexl-mode-old-require-final-newline)
 300   (setq mode-name hexl-mode-old-mode-name)
 301   (use-local-map hexl-mode-old-local-map)
 302   (set-syntax-table hexl-mode-old-syntax-table)
 303   (setq major-mode hexl-mode-old-major-mode)
 304   (force-mode-line-update))
 305
 306 (defun hexl-maybe-dehexlify-buffer ()
 307   "Convert a hexl format buffer to binary.
 308 Ask the user for confirmation."
 309   (if (y-or-n-p "Convert contents back to binary format? ")
 310       (let ((modified (buffer-modified-p))
 311             (inhibit-read-only t)
 312             (original-point (1+ (hexl-current-address))))
 313         (dehexlify-buffer)
 314         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 315         (set-buffer-modified-p modified)
 316         (goto-char original-point))))
 317
 318 (defun hexl-current-address (&optional validate)
 319   "Return current hexl-address."
 320   (interactive)
 321   (let ((current-column (- (% (point) 68) 11))
 322         (hexl-address 0))
 323     (if (< current-column 0)
 324         (if validate
 325             (error "Point is not on a character in the file")
 326           (setq current-column 0)))
 327     (setq hexl-address
 328           (+ (* (/ (point) 68) 16)
 329              (if (>= current-column 41)
 330                  (- current-column 41)
 331                (/ (- current-column  (/ current-column 5)) 2))))
 332     hexl-address))
 333
 334 (defun hexl-address-to-marker (address)
 335   "Return marker for ADDRESS."
 336   (interactive "nAddress: ")
 337   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 338
 339 (defun hexl-goto-address (address)
 340   "Goto hexl-mode (decimal) address ADDRESS.
 341 Signal error if ADDRESS out of range."
 342   (interactive "nAddress: ")
 343   (if (or (< address 0) (> address hexl-max-address))
 344           (error "Out of hexl region"))
 345   (goto-char (hexl-address-to-marker address)))
 346
 347 (defun hexl-goto-hex-address (hex-address)
 348   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 349 Signal error if HEX-ADDRESS is out of range."
 350   (interactive "sHex Address: ")
 351   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 352
 353 (defun hexl-hex-string-to-integer (hex-string)
 354   "Return decimal integer for HEX-STRING."
 355   (interactive "sHex number: ")
 356   (let ((hex-num 0))
 357     (while (not (equal hex-string ""))
 358       (setq hex-num (+ (* hex-num 16)
 359                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 360       (setq hex-string (substring hex-string 1)))
 361     hex-num))
 362
 363 (defun hexl-octal-string-to-integer (octal-string)
 364   "Return decimal integer for OCTAL-STRING."
 365   (interactive "sOctal number: ")
 366   (let ((oct-num 0))
 367     (while (not (equal octal-string ""))
 368       (setq oct-num (+ (* oct-num 8)
 369                        (hexl-oct-char-to-integer
 370                         (string-to-char octal-string))))
 371       (setq octal-string (substring octal-string 1)))
 372     oct-num))
 373
 374 ;; move point functions
 375
 376 (defun hexl-backward-char (arg)
 377   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 378   (interactive "p")
 379   (hexl-goto-address (- (hexl-current-address) arg)))
 380
 381 (defun hexl-forward-char (arg)
 382   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 383   (interactive "p")
 384   (hexl-goto-address (+ (hexl-current-address) arg)))
 385
 386 (defun hexl-backward-short (arg)
 387   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 388   (interactive "p")
 389   (hexl-goto-address (let ((address (hexl-current-address)))
 390                        (if (< arg 0)
 391                            (progn
 392                              (setq arg (- arg))
 393                              (while (> arg 0)
 394                                (if (not (equal address (logior address 3)))
 395                                    (if (> address hexl-max-address)
 396                                        (progn
 397                                          (message "End of buffer.")
 398                                          (setq address hexl-max-address))
 399                                      (setq address (logior address 3)))
 400                                  (if (> address hexl-max-address)
 401                                      (progn
 402                                        (message "End of buffer.")
 403                                        (setq address hexl-max-address))
 404                                    (setq address (+ address 4))))
 405                                (setq arg (1- arg)))
 406                              (if (> address hexl-max-address)
 407                                  (progn
 408                                    (message "End of buffer.")
 409                                    (setq address hexl-max-address))
 410                                (setq address (logior address 3))))
 411                          (while (> arg 0)
 412                            (if (not (equal address (logand address -4)))
 413                                (setq address (logand address -4))
 414                              (if (not (equal address 0))
 415                                  (setq address (- address 4))
 416                                (message "Beginning of buffer.")))
 417                            (setq arg (1- arg))))
 418                        address)))
 419
 420 (defun hexl-forward-short (arg)
 421   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 422   (interactive "p")
 423   (hexl-backward-short (- arg)))
 424
 425 (defun hexl-backward-word (arg)
 426   "Move to left ARG words (right if ARG negative) in hexl-mode."
 427   (interactive "p")
 428   (hexl-goto-address (let ((address (hexl-current-address)))
 429                        (if (< arg 0)
 430                            (progn
 431                              (setq arg (- arg))
 432                              (while (> arg 0)
 433                                (if (not (equal address (logior address 7)))
 434                                    (if (> address hexl-max-address)
 435                                        (progn
 436                                          (message "End of buffer.")
 437                                          (setq address hexl-max-address))
 438                                      (setq address (logior address 7)))
 439                                  (if (> address hexl-max-address)
 440                                      (progn
 441                                        (message "End of buffer.")
 442                                        (setq address hexl-max-address))
 443                                    (setq address (+ address 8))))
 444                                (setq arg (1- arg)))
 445                              (if (> address hexl-max-address)
 446                                  (progn
 447                                    (message "End of buffer.")
 448                                    (setq address hexl-max-address))
 449                                (setq address (logior address 7))))
 450                          (while (> arg 0)
 451                            (if (not (equal address (logand address -8)))
 452                                (setq address (logand address -8))
 453                              (if (not (equal address 0))
 454                                  (setq address (- address 8))
 455                                (message "Beginning of buffer.")))
 456                            (setq arg (1- arg))))
 457                        address)))
 458
 459 (defun hexl-forward-word (arg)
 460   "Move right ARG words (left if ARG negative) in hexl-mode."
 461   (interactive "p")
 462   (hexl-backward-word (- arg)))
 463
 464 (defun hexl-previous-line (arg)
 465   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 466 If there is byte at the target address move to the last byte in that line."
 467   (interactive "p")
 468   (hexl-next-line (- arg)))
 469
 470 (defun hexl-next-line (arg)
 471   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 472 If there is no byte at the target address move to the last byte in that line."
 473   (interactive "p")
 474   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 475                        (if (and (< arg 0) (< address 0))
 476                                 (progn (message "Out of hexl region.")
 477                                        (setq address
 478                                              (% (hexl-current-address) 16)))
 479                          (if (and (> address hexl-max-address)
 480                                   (< (% hexl-max-address 16) (% address 16)))
 481                              (setq address hexl-max-address)
 482                            (if (> address hexl-max-address)
 483                                (progn (message "Out of hexl region.")
 484                                       (setq
 485                                        address
 486                                        (+ (logand hexl-max-address -16)
 487                                           (% (hexl-current-address) 16)))))))
 488                        address)))
 489
 490 (defun hexl-beginning-of-buffer (arg)
 491   "Move to the beginning of the hexl buffer.
 492 Leaves `hexl-mark' at previous position.
 493 With prefix arg N, puts point N bytes of the way from the true beginning."
 494   (interactive "p")
 495   (push-mark (point))
 496   (hexl-goto-address (+ 0 (1- arg))))
 497
 498 (defun hexl-end-of-buffer (arg)
 499   "Go to `hexl-max-address' minus ARG."
 500   (interactive "p")
 501   (push-mark (point))
 502   (hexl-goto-address (- hexl-max-address (1- arg))))
 503
 504 (defun hexl-beginning-of-line ()
 505   "Goto beginning of line in hexl mode."
 506   (interactive)
 507   (goto-char (+ (* (/ (point) 68) 68) 11)))
 508
 509 (defun hexl-end-of-line ()
 510   "Goto end of line in hexl mode."
 511   (interactive)
 512   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 513                        (if (> address hexl-max-address)
 514                            (setq address hexl-max-address))
 515                        address)))
 516
 517 (defun hexl-scroll-down (arg)
 518   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 519   (interactive "P")
 520   (if (null arg)
 521       (setq arg (1- (window-height)))
 522     (setq arg (prefix-numeric-value arg)))
 523   (hexl-scroll-up (- arg)))
 524
 525 (defun hexl-scroll-up (arg)
 526   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 527   (interactive "P")
 528   (if (null arg)
 529       (setq arg (1- (window-height)))
 530     (setq arg (prefix-numeric-value arg)))
 531   (let ((movement (* arg 16))
 532         (address (hexl-current-address)))
 533     (if (or (> (+ address movement) hexl-max-address)
 534             (< (+ address movement) 0))
 535         (message "Out of hexl region.")
 536       (hexl-goto-address (+ address movement))
 537       (recenter 0))))
 538
 539 (defun hexl-beginning-of-1k-page ()
 540   "Go to beginning of 1k boundary."
 541   (interactive)
 542   (hexl-goto-address (logand (hexl-current-address) -1024)))
 543
 544 (defun hexl-end-of-1k-page ()
 545   "Go to end of 1k boundary."
 546   (interactive)
 547   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 548                        (if (> address hexl-max-address)
 549                            (setq address hexl-max-address))
 550                        address)))
 551
 552 (defun hexl-beginning-of-512b-page ()
 553   "Go to beginning of 512 byte boundary."
 554   (interactive)
 555   (hexl-goto-address (logand (hexl-current-address) -512)))
 556
 557 (defun hexl-end-of-512b-page ()
 558   "Go to end of 512 byte boundary."
 559   (interactive)
 560   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 561                        (if (> address hexl-max-address)
 562                            (setq address hexl-max-address))
 563                        address)))
 564
 565 (defun hexl-quoted-insert (arg)
 566   "Read next input character and insert it.
 567 Useful for inserting control characters.
 568 You may also type up to 3 octal digits, to insert a character with that code"
 569   (interactive "p")
 570   (hexl-insert-char (read-quoted-char) arg))
 571
 572 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 573
 574 ;;;###autoload
 575 (defun hexlify-buffer ()
 576   "Convert a binary buffer to hexl format.
 577 This discards the buffer's undo information."
 578   (interactive)
 579   (and buffer-undo-list
 580        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 581            (error "Aborted")))
 582   (setq buffer-undo-list nil)
 583   (let ((binary-process-output nil) ; for Ms-Dos
 584         (binary-process-input t)
 585         (buffer-undo-list t))
 586     (shell-command-on-region (point-min) (point-max) hexlify-command t)))
 587
 588 (defun dehexlify-buffer ()
 589   "Convert a hexl format buffer to binary.
 590 This discards the buffer's undo information."
 591   (interactive)
 592   (and buffer-undo-list
 593        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 594            (error "Aborted")))
 595   (setq buffer-undo-list nil)
 596   (let ((binary-process-output t) ; for Ms-Dos
 597         (binary-process-input nil)
 598         (buffer-undo-list t))
 599     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 600
 601 (defun hexl-char-after-point ()
 602   "Return char for ASCII hex digits at point."
 603   (hexl-htoi (char-after (point))
 604              (char-after (1+ (point)))))
 605
 606 (defun hexl-htoi (lh rh)
 607   "Hex (char) LH (char) RH to integer."
 608     (+ (* (hexl-hex-char-to-integer lh) 16)
 609        (hexl-hex-char-to-integer rh)))
 610
 611 (defun hexl-hex-char-to-integer (character)
 612   "Take a char and return its value as if it was a hex digit."
 613   (if (and (>= character ?0) (<= character ?9))
 614       (- character ?0)
 615     (let ((ch (logior character 32)))
 616       (if (and (>= ch ?a) (<= ch ?f))
 617           (- ch (- ?a 10))
 618         (error "Invalid hex digit `%c'" ch)))))
 619
 620 (defun hexl-oct-char-to-integer (character)
 621   "Take a char and return its value as if it was a octal digit."
 622   (if (and (>= character ?0) (<= character ?7))
 623       (- character ?0)
 624     (error "Invalid octal digit `%c'" character)))
 625
 626 (defun hexl-printable-character (ch)
 627   "Return a displayable string for character CH."
 628   (format "%c" (if hexl-iso
 629                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 630                        46
 631                      ch)
 632                  (if (or (< ch 32) (>= ch 127))
 633                      46
 634                    ch))))
 635
 636 (defun hexl-self-insert-command (arg)
 637   "Insert this character."
 638   (interactive "p")
 639   (hexl-insert-char last-command-char arg))
 640
 641 (defun hexl-insert-char (ch num)
 642   "Insert a character in a hexl buffer."
 643   (let ((address (hexl-current-address t)))
 644     (while (> num 0)
 645       (let ((hex-position
 646              (+ (* (/ address 16) 68)
 647                 11
 648                 (* 2 (% address 16))
 649                 (/ (% address 16) 2)))
 650             (ascii-position
 651              (+ (* (/ address 16) 68) 52 (% address 16)))
 652             at-ascii-position)
 653         (if (= (point) ascii-position)
 654             (setq at-ascii-position t))
 655         (goto-char hex-position)
 656         (delete-char 2)
 657         (insert (format "%02x" ch))
 658         (goto-char ascii-position)
 659         (delete-char 1)
 660         (insert (hexl-printable-character ch))
 661         (or (eq address hexl-max-address)
 662             (setq address (1+ address)))
 663         (hexl-goto-address address)
 664         (if at-ascii-position
 665             (progn
 666               (beginning-of-line)
 667               (forward-char 51)
 668               (forward-char (% address 16)))))
 669       (setq num (1- num)))))
 670
 671 ;; hex conversion
 672
 673 (defun hexl-insert-hex-char (arg)
 674   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 675   (interactive "p")
 676   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 677     (if (or (> num 255) (< num 0))
 678         (error "Hex number out of range")
 679       (hexl-insert-char num arg))))
 680
 681 (defun hexl-insert-decimal-char (arg)
 682   "Insert a ASCII char ARG times at point for a given decimal number."
 683   (interactive "p")
 684   (let ((num (string-to-int (read-string "Decimal Number: "))))
 685     (if (or (> num 255) (< num 0))
 686         (error "Decimal number out of range")
 687       (hexl-insert-char num arg))))
 688
 689 (defun hexl-insert-octal-char (arg)
 690   "Insert a ASCII char ARG times at point for a given octal number."
 691   (interactive "p")
 692   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 693     (if (or (> num 255) (< num 0))
 694         (error "Decimal number out of range")
 695       (hexl-insert-char num arg))))
 696
 697 ;; startup stuff.
 698
 699 (if hexl-mode-map
 700     nil
 701   (setq hexl-mode-map (make-sparse-keymap))
 702
 703   (define-key hexl-mode-map [left] 'hexl-backward-char)
 704   (define-key hexl-mode-map [right] 'hexl-forward-char)
 705   (define-key hexl-mode-map [up] 'hexl-previous-line)
 706   (define-key hexl-mode-map [down] 'hexl-next-line)
 707   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 708   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 709   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 710   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 711   (define-key hexl-mode-map [home] 'hexl-beginning-of-buffer)
 712   (define-key hexl-mode-map [deletechar] 'undefined)
 713   (define-key hexl-mode-map [deleteline] 'undefined)
 714   (define-key hexl-mode-map [insertline] 'undefined)
 715   (define-key hexl-mode-map [S-delete] 'undefined)
 716   (define-key hexl-mode-map "\177" 'undefined)
 717
 718   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 719   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 720   (define-key hexl-mode-map "\C-d" 'undefined)
 721   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 722   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 723
 724   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 725       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 726
 727   (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 728   (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 729   (define-key hexl-mode-map "\C-k" 'undefined)
 730   (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 731   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 732   (define-key hexl-mode-map "\C-o" 'undefined)
 733   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 734   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 735   (define-key hexl-mode-map "\C-t" 'undefined)
 736   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 737   (define-key hexl-mode-map "\C-w" 'undefined)
 738   (define-key hexl-mode-map "\C-y" 'undefined)
 739
 740   (let ((ch 32))
 741     (while (< ch 127)
 742       (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 743       (setq ch (1+ ch))))
 744
 745   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 746   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 747   (define-key hexl-mode-map "\e\C-c" 'undefined)
 748   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 749   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 750   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 751   (define-key hexl-mode-map "\e\C-g" 'undefined)
 752   (define-key hexl-mode-map "\e\C-h" 'undefined)
 753   (define-key hexl-mode-map "\e\C-i" 'undefined)
 754   (define-key hexl-mode-map "\e\C-j" 'undefined)
 755   (define-key hexl-mode-map "\e\C-k" 'undefined)
 756   (define-key hexl-mode-map "\e\C-l" 'undefined)
 757   (define-key hexl-mode-map "\e\C-m" 'undefined)
 758   (define-key hexl-mode-map "\e\C-n" 'undefined)
 759   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 760   (define-key hexl-mode-map "\e\C-p" 'undefined)
 761   (define-key hexl-mode-map "\e\C-q" 'undefined)
 762   (define-key hexl-mode-map "\e\C-r" 'undefined)
 763   (define-key hexl-mode-map "\e\C-s" 'undefined)
 764   (define-key hexl-mode-map "\e\C-t" 'undefined)
 765   (define-key hexl-mode-map "\e\C-u" 'undefined)
 766
 767   (define-key hexl-mode-map "\e\C-w" 'undefined)
 768   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 769   (define-key hexl-mode-map "\e\C-y" 'undefined)
 770
 771   (define-key hexl-mode-map "\ea" 'undefined)
 772   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 773   (define-key hexl-mode-map "\ec" 'undefined)
 774   (define-key hexl-mode-map "\ed" 'undefined)
 775   (define-key hexl-mode-map "\ee" 'undefined)
 776   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 777   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 778   (define-key hexl-mode-map "\eh" 'undefined)
 779   (define-key hexl-mode-map "\ei" 'undefined)
 780   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 781   (define-key hexl-mode-map "\ek" 'undefined)
 782   (define-key hexl-mode-map "\el" 'undefined)
 783   (define-key hexl-mode-map "\em" 'undefined)
 784   (define-key hexl-mode-map "\en" 'undefined)
 785   (define-key hexl-mode-map "\eo" 'undefined)
 786   (define-key hexl-mode-map "\ep" 'undefined)
 787   (define-key hexl-mode-map "\eq" 'undefined)
 788   (define-key hexl-mode-map "\er" 'undefined)
 789   (define-key hexl-mode-map "\es" 'undefined)
 790   (define-key hexl-mode-map "\et" 'undefined)
 791   (define-key hexl-mode-map "\eu" 'undefined)
 792   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 793   (define-key hexl-mode-map "\ey" 'undefined)
 794   (define-key hexl-mode-map "\ez" 'undefined)
 795   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 796   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 797
 798   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 799
 800   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 801   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 802   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 803   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 804   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 805
 806 (provide 'hexl)
 807
 808 ;;; hexl.el ends here