lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2015 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 (defvar help-fns-describe-function-functions nil
  36   "List of functions to run in help buffer in `describe-function'.
  37 Those functions will be run after the header line and argument
  38 list was inserted, and before the documentation will be inserted.
  39 The functions will receive the function name as argument.")
  40
  41 ;; Functions
  42
  43 ;;;###autoload
  44 (defun describe-function (function)
  45   "Display the full documentation of FUNCTION (a symbol)."
  46   (interactive
  47    (let ((fn (function-called-at-point))
  48          (enable-recursive-minibuffers t)
  49          val)
  50      (setq val (completing-read (if fn
  51                                     (format "Describe function (default %s): " fn)
  52                                   "Describe function: ")
  53                                 obarray 'fboundp t nil nil
  54                                 (and fn (symbol-name fn))))
  55      (list (if (equal val "")
  56                fn (intern val)))))
  57   (if (null function)
  58       (message "You didn't specify a function")
  59     (help-setup-xref (list #'describe-function function)
  60                      (called-interactively-p 'interactive))
  61     (save-excursion
  62       (with-help-window (help-buffer)
  63         (prin1 function)
  64         ;; Use " is " instead of a colon so that
  65         ;; it is easier to get out the function name using forward-sexp.
  66         (princ " is ")
  67         (describe-function-1 function)
  68         (with-current-buffer standard-output
  69           ;; Return the text we displayed.
  70           (buffer-string))))))
  71
  72
  73 ;; Could be this, if we make symbol-file do the work below.
  74 ;; (defun help-C-file-name (subr-or-var kind)
  75 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
  76 ;; KIND should be `var' for a variable or `subr' for a subroutine."
  77 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
  78 ;;               (subr-name subr-or-var))
  79 ;;             (if (eq kind 'var) 'defvar 'defun)))
  80 ;;;###autoload
  81 (defun help-C-file-name (subr-or-var kind)
  82   "Return the name of the C file where SUBR-OR-VAR is defined.
  83 KIND should be `var' for a variable or `subr' for a subroutine."
  84   (let ((docbuf (get-buffer-create " *DOC*"))
  85         (name (if (eq 'var kind)
  86                   (concat "V" (symbol-name subr-or-var))
  87                 (concat "F" (subr-name (advice--cd*r subr-or-var))))))
  88     (with-current-buffer docbuf
  89       (goto-char (point-min))
  90       (if (eobp)
  91           (insert-file-contents-literally
  92            (expand-file-name internal-doc-file-name doc-directory)))
  93       (let ((file (catch 'loop
  94                     (while t
  95                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
  96                         (re-search-backward "\x1fS\\(.*\\)")
  97                         (let ((file (match-string 1)))
  98                           (if (member file build-files)
  99                               (throw 'loop file)
 100                             (goto-char pnt))))))))
 101         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 102             (setq file (replace-match ".m" t t file 1))
 103           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 104               (setq file (replace-match ".c" t t file))))
 105         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 106             (concat "src/" file)
 107           file)))))
 108
 109 (defcustom help-downcase-arguments nil
 110   "If non-nil, argument names in *Help* buffers are downcased."
 111   :type 'boolean
 112   :group 'help
 113   :version "23.2")
 114
 115 (defun help-highlight-arg (arg)
 116   "Highlight ARG as an argument name for a *Help* buffer.
 117 Return ARG in face `help-argument-name'; ARG is also downcased
 118 if the variable `help-downcase-arguments' is non-nil."
 119   (propertize (if help-downcase-arguments (downcase arg) arg)
 120               'face 'help-argument-name))
 121
 122 (defun help-do-arg-highlight (doc args)
 123   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 124     (modify-syntax-entry ?\- "w")
 125     (dolist (arg args)
 126       (setq doc (replace-regexp-in-string
 127                  ;; This is heuristic, but covers all common cases
 128                  ;; except ARG1-ARG2
 129                  (concat "\\<"                   ; beginning of word
 130                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 131                          "\\("
 132                          (regexp-quote arg)
 133                          "\\)"
 134                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 135                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 136                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 137                          "\\>")                  ; end of word
 138                  (help-highlight-arg arg)
 139                  doc t t 1)))
 140     doc))
 141
 142 (defun help-highlight-arguments (usage doc &rest args)
 143   (when (and usage (string-match "^(" usage))
 144     (with-temp-buffer
 145       (insert usage)
 146       (goto-char (point-min))
 147       (let ((case-fold-search nil)
 148             (next (not (or args (looking-at "\\["))))
 149             (opt nil))
 150         ;; Make a list of all arguments
 151         (skip-chars-forward "^ ")
 152         (while next
 153           (or opt (not (looking-at " &")) (setq opt t))
 154           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 155               (setq next nil)
 156             (setq args (cons (match-string 2) args))
 157             (when (and opt (string= (match-string 1) "("))
 158               ;; A pesky CL-style optional argument with default value,
 159               ;; so let's skip over it
 160               (search-backward "(")
 161               (goto-char (scan-sexps (point) 1)))))
 162         ;; Highlight arguments in the USAGE string
 163         (setq usage (help-do-arg-highlight (buffer-string) args))
 164         ;; Highlight arguments in the DOC string
 165         (setq doc (and doc (help-do-arg-highlight doc args))))))
 166   ;; Return value is like the one from help-split-fundoc, but highlighted
 167   (cons usage doc))
 168
 169 ;; The following function was compiled from the former functions
 170 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 171 ;; some excerpts from `describe-function-1' and `describe-variable'.
 172 ;; The only additional twists provided are (1) locate the defining file
 173 ;; for autoloaded functions, and (2) give preference to files in the
 174 ;; "install directory" (directories found via `load-path') rather than
 175 ;; to files in the "compile directory" (directories found by searching
 176 ;; the loaddefs.el file).  We autoload it because it's also used by
 177 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 178
 179 ;;;###autoload
 180 (defun find-lisp-object-file-name (object type)
 181   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 182 OBJECT should be a symbol associated with a function, variable, or face;
 183   alternatively, it can be a function definition.
 184 If TYPE is `defvar', search for a variable definition.
 185 If TYPE is `defface', search for a face definition.
 186 If TYPE is not a symbol, search for a function definition.
 187
 188 The return value is the absolute name of a readable file where OBJECT is
 189 defined.  If several such files exist, preference is given to a file
 190 found via `load-path'.  The return value can also be `C-source', which
 191 means that OBJECT is a function or variable defined in C.  If no
 192 suitable file is found, return nil."
 193   (let* ((autoloaded (autoloadp type))
 194          (file-name (or (and autoloaded (nth 1 type))
 195                         (symbol-file
 196                          ;; FIXME: Why do we have this weird "If TYPE is the
 197                          ;; value returned by `symbol-function' for a function
 198                          ;; symbol" exception?
 199                          object (or (if (symbolp type) type) 'defun)))))
 200     (cond
 201      (autoloaded
 202       ;; An autoloaded function: Locate the file since `symbol-function'
 203       ;; has only returned a bare string here.
 204       (setq file-name
 205             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 206      ((and (stringp file-name)
 207            (string-match "[.]*loaddefs.el\\'" file-name))
 208       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 209       ;; and try to extract the defining file.  The following form is
 210       ;; from `describe-function-1' and `describe-variable'.
 211       (let ((location
 212              (condition-case nil
 213                  (find-function-search-for-symbol object nil file-name)
 214                (error nil))))
 215         (when (cdr location)
 216           (with-current-buffer (car location)
 217             (goto-char (cdr location))
 218             (when (re-search-backward
 219                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 220               (setq file-name
 221                     (locate-file
 222                      (file-name-sans-extension
 223                       (match-string-no-properties 1))
 224                      load-path '(".el" ".elc") 'readable))))))))
 225
 226     (cond
 227      ((and (not file-name) (subrp type))
 228       ;; A built-in function.  The form is from `describe-function-1'.
 229       (if (get-buffer " *DOC*")
 230           (help-C-file-name type 'subr)
 231         'C-source))
 232      ((and (not file-name) (symbolp object)
 233            (integerp (get object 'variable-documentation)))
 234       ;; A variable defined in C.  The form is from `describe-variable'.
 235       (if (get-buffer " *DOC*")
 236           (help-C-file-name object 'var)
 237         'C-source))
 238      ((not (stringp file-name))
 239       ;; If we don't have a file-name string by now, we lost.
 240       nil)
 241      ;; Now, `file-name' should have become an absolute file name.
 242      ;; For files loaded from ~/.foo.elc, try ~/.foo.
 243      ;; This applies to config files like ~/.emacs,
 244      ;; which people sometimes compile.
 245      ((let (fn)
 246         (and (string-match "\\`\\..*\\.elc\\'"
 247                            (file-name-nondirectory file-name))
 248              (string-equal (file-name-directory file-name)
 249                            (file-name-as-directory (expand-file-name "~")))
 250              (file-readable-p (setq fn (file-name-sans-extension file-name)))
 251              fn)))
 252      ;; When the Elisp source file can be found in the install
 253      ;; directory, return the name of that file.
 254      ((let ((lib-name
 255              (if (string-match "[.]elc\\'" file-name)
 256                  (substring-no-properties file-name 0 -1)
 257                file-name)))
 258         (or (and (file-readable-p lib-name) lib-name)
 259             ;; The library might be compressed.
 260             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 261      ((let* ((lib-name (file-name-nondirectory file-name))
 262              ;; The next form is from `describe-simplify-lib-file-name'.
 263              (file-name
 264               ;; Try converting the absolute file name to a library
 265               ;; name, convert that back to a file name and see if we
 266               ;; get the original one.  If so, they are equivalent.
 267               (if (equal file-name (locate-file lib-name load-path '("")))
 268                   (if (string-match "[.]elc\\'" lib-name)
 269                       (substring-no-properties lib-name 0 -1)
 270                     lib-name)
 271                 file-name))
 272              ;; The next three forms are from `find-source-lisp-file'.
 273              (elc-file (locate-file
 274                         (concat file-name
 275                                 (if (string-match "\\.el\\'" file-name)
 276                                     "c"
 277                                   ".elc"))
 278                         load-path nil 'readable))
 279              (str (when elc-file
 280                     (with-temp-buffer
 281                       (insert-file-contents-literally elc-file nil 0 256)
 282                       (buffer-string))))
 283              (src-file (and str
 284                             (string-match ";;; from file \\(.*\\.el\\)" str)
 285                             (match-string 1 str))))
 286         (and src-file (file-readable-p src-file) src-file))))))
 287
 288 (defun help-fns--key-bindings (function)
 289   (when (commandp function)
 290     (let ((pt2 (with-current-buffer standard-output (point)))
 291           (remapped (command-remapping function)))
 292       (unless (memq remapped '(ignore undefined))
 293         (let ((keys (where-is-internal
 294                      (or remapped function) overriding-local-map nil nil))
 295               non-modified-keys)
 296           (if (and (eq function 'self-insert-command)
 297                    (vectorp (car-safe keys))
 298                    (consp (aref (car keys) 0)))
 299               (princ "It is bound to many ordinary text characters.\n")
 300             ;; Which non-control non-meta keys run this command?
 301             (dolist (key keys)
 302               (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 303                   (push key non-modified-keys)))
 304             (when remapped
 305               (princ "Its keys are remapped to ")
 306               (princ (if (symbolp remapped)
 307                          (concat "`" (symbol-name remapped) "'")
 308                        "an anonymous command"))
 309               (princ ".\n"))
 310
 311             (when keys
 312               (princ (if remapped
 313                          "Without this remapping, it would be bound to "
 314                        "It is bound to "))
 315               ;; If lots of ordinary text characters run this command,
 316               ;; don't mention them one by one.
 317               (if (< (length non-modified-keys) 10)
 318                   (princ (mapconcat 'key-description keys ", "))
 319                 (dolist (key non-modified-keys)
 320                   (setq keys (delq key keys)))
 321                 (if keys
 322                     (progn
 323                       (princ (mapconcat 'key-description keys ", "))
 324                       (princ ", and many ordinary text characters"))
 325                   (princ "many ordinary text characters"))))
 326             (when (or remapped keys non-modified-keys)
 327               (princ ".")
 328               (terpri)))))
 329
 330       (with-current-buffer standard-output
 331         (fill-region-as-paragraph pt2 (point))
 332         (unless (looking-back "\n\n")
 333           (terpri))))))
 334
 335 (defun help-fns--compiler-macro (function)
 336   (let ((handler (function-get function 'compiler-macro)))
 337     (when handler
 338       (insert "\nThis function has a compiler macro")
 339       (if (symbolp handler)
 340           (progn
 341             (insert (format " `%s'" handler))
 342             (save-excursion
 343               (re-search-backward "`\\([^`']+\\)'" nil t)
 344               (help-xref-button 1 'help-function handler)))
 345         ;; FIXME: Obsolete since 24.4.
 346         (let ((lib (get function 'compiler-macro-file)))
 347           (when (stringp lib)
 348             (insert (format " in `%s'" lib))
 349             (save-excursion
 350               (re-search-backward "`\\([^`']+\\)'" nil t)
 351               (help-xref-button 1 'help-function-cmacro function lib)))))
 352       (insert ".\n"))))
 353
 354 (defun help-fns--signature (function doc real-def real-function)
 355   (unless (keymapp function)    ; If definition is a keymap, skip arglist note.
 356     (let* ((advertised (gethash real-def advertised-signature-table t))
 357            (arglist (if (listp advertised)
 358                         advertised (help-function-arglist real-def)))
 359            (usage (help-split-fundoc doc function)))
 360       (if usage (setq doc (cdr usage)))
 361       (let* ((use (cond
 362                    ((and usage (not (listp advertised))) (car usage))
 363                    ((listp arglist)
 364                     (format "%S" (help-make-usage function arglist)))
 365                    ((stringp arglist) arglist)
 366                    ;; Maybe the arglist is in the docstring of a symbol
 367                    ;; this one is aliased to.
 368                    ((let ((fun real-function))
 369                       (while (and (symbolp fun)
 370                                   (setq fun (symbol-function fun))
 371                                   (not (setq usage (help-split-fundoc
 372                                                     (documentation fun)
 373                                                     function)))))
 374                       usage)
 375                     (car usage))
 376                    ((or (stringp real-def)
 377                         (vectorp real-def))
 378                     (format "\nMacro: %s" (format-kbd-macro real-def)))
 379                    (t "[Missing arglist.  Please make a bug report.]")))
 380              (high (help-highlight-arguments use doc)))
 381         (let ((fill-begin (point)))
 382           (insert (car high) "\n")
 383           (fill-region fill-begin (point)))
 384         (cdr high)))))
 385
 386 (defun help-fns--parent-mode (function)
 387   ;; If this is a derived mode, link to the parent.
 388   (let ((parent-mode (and (symbolp function)
 389                           (get function
 390                                'derived-mode-parent))))
 391     (when parent-mode
 392       (insert "\nParent mode: `")
 393       (let ((beg (point)))
 394         (insert (format "%s" parent-mode))
 395         (make-text-button beg (point)
 396                           'type 'help-function
 397                           'help-args (list parent-mode)))
 398       (insert "'.\n"))))
 399
 400 (defun help-fns--obsolete (function)
 401   ;; Ignore lambda constructs, keyboard macros, etc.
 402   (let* ((obsolete (and (symbolp function)
 403                         (get function 'byte-obsolete-info)))
 404          (use (car obsolete)))
 405     (when obsolete
 406       (insert "\nThis "
 407               (if (eq (car-safe (symbol-function function)) 'macro)
 408                   "macro"
 409                 "function")
 410               " is obsolete")
 411       (when (nth 2 obsolete)
 412         (insert (format " since %s" (nth 2 obsolete))))
 413       (insert (cond ((stringp use) (concat ";\n" use))
 414                     (use (format ";\nuse `%s' instead." use))
 415                     (t "."))
 416               "\n"))))
 417
 418 ;; We could use `symbol-file' but this is a wee bit more efficient.
 419 (defun help-fns--autoloaded-p (function file)
 420   "Return non-nil if FUNCTION has previously been autoloaded.
 421 FILE is the file where FUNCTION was probably defined."
 422   (let* ((file (file-name-sans-extension (file-truename file)))
 423          (load-hist load-history)
 424          (target (cons t function))
 425          found)
 426     (while (and load-hist (not found))
 427       (and (caar load-hist)
 428            (equal (file-name-sans-extension (caar load-hist)) file)
 429            (setq found (member target (cdar load-hist))))
 430       (setq load-hist (cdr load-hist)))
 431     found))
 432
 433 (defun help-fns--interactive-only (function)
 434   "Insert some help blurb if FUNCTION should only be used interactively."
 435   ;; Ignore lambda constructs, keyboard macros, etc.
 436   (and (symbolp function)
 437        (not (eq (car-safe (symbol-function function)) 'macro))
 438        (let* ((interactive-only
 439                (or (get function 'interactive-only)
 440                    (if (boundp 'byte-compile-interactive-only-functions)
 441                        (memq function
 442                              byte-compile-interactive-only-functions)))))
 443          (when interactive-only
 444            (insert "\nThis function is for interactive use only"
 445                    ;; Cf byte-compile-form.
 446                    (cond ((stringp interactive-only)
 447                           (format ";\nin Lisp code %s" interactive-only))
 448                          ((and (symbolp 'interactive-only)
 449                                (not (eq interactive-only t)))
 450                           (format ";\nin Lisp code use `%s' instead."
 451                                   interactive-only))
 452                          (t "."))
 453                    "\n")))))
 454
 455 (defun help-fns-short-filename (filename)
 456   (let* ((abbrev (abbreviate-file-name filename))
 457          (short abbrev))
 458     (dolist (dir load-path)
 459       (let ((rel (file-relative-name filename dir)))
 460         (if (< (length rel) (length short))
 461             (setq short rel)))
 462       (let ((rel (file-relative-name abbrev dir)))
 463         (if (< (length rel) (length short))
 464             (setq short rel))))
 465     short))
 466
 467 ;;;###autoload
 468 (defun describe-function-1 (function)
 469   (let* ((advised (and (symbolp function)
 470                        (featurep 'nadvice)
 471                        (advice--p (advice--symbol-function function))))
 472          ;; If the function is advised, use the symbol that has the
 473          ;; real definition, if that symbol is already set up.
 474          (real-function
 475           (or (and advised
 476                    (advice--cd*r (advice--symbol-function function)))
 477               function))
 478          ;; Get the real definition.
 479          (def (if (symbolp real-function)
 480                   (symbol-function real-function)
 481                 real-function))
 482          (aliased (or (symbolp def)
 483                       ;; Advised & aliased function.
 484                       (and advised (symbolp real-function))))
 485          (real-def (cond
 486                     (aliased (let ((f real-function))
 487                                (while (and (fboundp f)
 488                                            (symbolp (symbol-function f)))
 489                                  (setq f (symbol-function f)))
 490                                f))
 491                     ((subrp def) (intern (subr-name def)))
 492                     (t def)))
 493          (file-name (find-lisp-object-file-name function def))
 494          (pt1 (with-current-buffer (help-buffer) (point)))
 495          (beg (if (and (or (byte-code-function-p def)
 496                            (keymapp def)
 497                            (memq (car-safe def) '(macro lambda closure)))
 498                        (stringp file-name)
 499                        (help-fns--autoloaded-p function file-name))
 500                   (if (commandp def)
 501                       "an interactive autoloaded "
 502                     "an autoloaded ")
 503                 (if (commandp def) "an interactive " "a "))))
 504
 505     ;; Print what kind of function-like object FUNCTION is.
 506     (princ (cond ((or (stringp def) (vectorp def))
 507                   "a keyboard macro")
 508                  ((subrp def)
 509                   (if (eq 'unevalled (cdr (subr-arity def)))
 510                       (concat beg "special form")
 511                     (concat beg "built-in function")))
 512                  ;; Aliases are Lisp functions, so we need to check
 513                  ;; aliases before functions.
 514                  (aliased
 515                   (format "an alias for `%s'" real-def))
 516                  ((autoloadp def)
 517                   (format "%s autoloaded %s"
 518                           (if (commandp def) "an interactive" "an")
 519                           (if (eq (nth 4 def) 'keymap) "keymap"
 520                             (if (nth 4 def) "Lisp macro" "Lisp function"))))
 521                  ((or (eq (car-safe def) 'macro)
 522                       ;; For advised macros, def is a lambda
 523                       ;; expression or a byte-code-function-p, so we
 524                       ;; need to check macros before functions.
 525                       (macrop function))
 526                   (concat beg "Lisp macro"))
 527                  ((byte-code-function-p def)
 528                   (concat beg "compiled Lisp function"))
 529                  ((eq (car-safe def) 'lambda)
 530                   (concat beg "Lisp function"))
 531                  ((eq (car-safe def) 'closure)
 532                   (concat beg "Lisp closure"))
 533                  ((keymapp def)
 534                   (let ((is-full nil)
 535                         (elts (cdr-safe def)))
 536                     (while elts
 537                       (if (char-table-p (car-safe elts))
 538                           (setq is-full t
 539                                 elts nil))
 540                       (setq elts (cdr-safe elts)))
 541                     (concat beg (if is-full "keymap" "sparse keymap"))))
 542                  (t "")))
 543
 544     (if (and aliased (not (fboundp real-def)))
 545         (princ ",\nwhich is not defined.  Please make a bug report.")
 546       (with-current-buffer standard-output
 547         (save-excursion
 548           (save-match-data
 549             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 550               (help-xref-button 1 'help-function real-def)))))
 551
 552       (when file-name
 553         (princ " in `")
 554         ;; We used to add .el to the file name,
 555         ;; but that's completely wrong when the user used load-file.
 556         (princ (if (eq file-name 'C-source)
 557                    "C source code"
 558                  (help-fns-short-filename file-name)))
 559         (princ "'")
 560         ;; Make a hyperlink to the library.
 561         (with-current-buffer standard-output
 562           (save-excursion
 563             (re-search-backward "`\\([^`']+\\)'" nil t)
 564             (help-xref-button 1 'help-function-def function file-name))))
 565       (princ ".")
 566       (with-current-buffer (help-buffer)
 567         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 568                                   (point)))
 569       (terpri)(terpri)
 570
 571       (let* ((doc-raw (documentation function t))
 572              ;; If the function is autoloaded, and its docstring has
 573              ;; key substitution constructs, load the library.
 574              (doc (progn
 575                     (and (autoloadp real-def) doc-raw
 576                          help-enable-auto-load
 577                          (string-match "\\([^\\]=\\|[^=]\\|\\`\\)\\\\[[{<]"
 578                                        doc-raw)
 579                          (autoload-do-load real-def))
 580                     (substitute-command-keys doc-raw))))
 581
 582         (help-fns--key-bindings function)
 583         (with-current-buffer standard-output
 584           (setq doc (help-fns--signature function doc real-def real-function))
 585           (run-hook-with-args 'help-fns-describe-function-functions function)
 586           (insert "\n"
 587                   (or doc "Not documented.")))))))
 588
 589 ;; Add defaults to `help-fns-describe-function-functions'.
 590 (add-hook 'help-fns-describe-function-functions #'help-fns--obsolete)
 591 (add-hook 'help-fns-describe-function-functions #'help-fns--interactive-only)
 592 (add-hook 'help-fns-describe-function-functions #'help-fns--parent-mode)
 593 (add-hook 'help-fns-describe-function-functions #'help-fns--compiler-macro)
 594
 595 \f
 596 ;; Variables
 597
 598 ;;;###autoload
 599 (defun variable-at-point (&optional any-symbol)
 600   "Return the bound variable symbol found at or before point.
 601 Return 0 if there is no such symbol.
 602 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 603   (with-syntax-table emacs-lisp-mode-syntax-table
 604     (or (condition-case ()
 605             (save-excursion
 606               (skip-chars-forward "'")
 607               (or (not (zerop (skip-syntax-backward "_w")))
 608                   (eq (char-syntax (following-char)) ?w)
 609                   (eq (char-syntax (following-char)) ?_)
 610                   (forward-sexp -1))
 611               (skip-chars-forward "'")
 612               (let ((obj (read (current-buffer))))
 613                 (and (symbolp obj) (boundp obj) obj)))
 614           (error nil))
 615         (let* ((str (find-tag-default))
 616                (sym (if str (intern-soft str))))
 617           (if (and sym (or any-symbol (boundp sym)))
 618               sym
 619             (save-match-data
 620               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 621                 (setq sym (intern-soft (match-string 1 str)))
 622                 (and (or any-symbol (boundp sym)) sym)))))
 623         0)))
 624
 625 (defun describe-variable-custom-version-info (variable)
 626   (let ((custom-version (get variable 'custom-version))
 627         (cpv (get variable 'custom-package-version))
 628         (output nil))
 629     (if custom-version
 630         (setq output
 631               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 632                       custom-version))
 633       (when cpv
 634         (let* ((package (car-safe cpv))
 635                (version (if (listp (cdr-safe cpv))
 636                             (car (cdr-safe cpv))
 637                           (cdr-safe cpv)))
 638                (pkg-versions (assq package customize-package-emacs-version-alist))
 639                (emacsv (cdr (assoc version pkg-versions))))
 640           (if (and package version)
 641               (setq output
 642                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 643                                     (if emacsv
 644                                         (format " that is part of Emacs %s" emacsv))
 645                                     ".\n")
 646                             version package))))))
 647     output))
 648
 649 ;;;###autoload
 650 (defun describe-variable (variable &optional buffer frame)
 651   "Display the full documentation of VARIABLE (a symbol).
 652 Returns the documentation as a string, also.
 653 If VARIABLE has a buffer-local value in BUFFER or FRAME
 654 \(default to the current buffer and current frame),
 655 it is displayed along with the global value."
 656   (interactive
 657    (let ((v (variable-at-point))
 658          (enable-recursive-minibuffers t)
 659          val)
 660      (setq val (completing-read (if (symbolp v)
 661                                     (format
 662                                      "Describe variable (default %s): " v)
 663                                   "Describe variable: ")
 664                                 obarray
 665                                 (lambda (vv)
 666                                   (or (get vv 'variable-documentation)
 667                                       (and (boundp vv) (not (keywordp vv)))))
 668                                 t nil nil
 669                                 (if (symbolp v) (symbol-name v))))
 670      (list (if (equal val "")
 671                v (intern val)))))
 672   (let (file-name)
 673     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 674     (unless (frame-live-p frame) (setq frame (selected-frame)))
 675     (if (not (symbolp variable))
 676         (message "You did not specify a variable")
 677       (save-excursion
 678         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 679               (permanent-local (get variable 'permanent-local))
 680               val val-start-pos locus)
 681           ;; Extract the value before setting up the output buffer,
 682           ;; in case `buffer' *is* the output buffer.
 683           (unless valvoid
 684             (with-selected-frame frame
 685               (with-current-buffer buffer
 686                 (setq val (symbol-value variable)
 687                       locus (variable-binding-locus variable)))))
 688           (help-setup-xref (list #'describe-variable variable buffer)
 689                            (called-interactively-p 'interactive))
 690           (with-help-window (help-buffer)
 691             (with-current-buffer buffer
 692               (prin1 variable)
 693               (setq file-name (find-lisp-object-file-name variable 'defvar))
 694
 695               (if file-name
 696                   (progn
 697                     (princ " is a variable defined in `")
 698                     (princ (if (eq file-name 'C-source)
 699                                "C source code"
 700                              (file-name-nondirectory file-name)))
 701                     (princ "'.\n")
 702                     (with-current-buffer standard-output
 703                       (save-excursion
 704                         (re-search-backward "`\\([^`']+\\)'" nil t)
 705                         (help-xref-button 1 'help-variable-def
 706                                           variable file-name)))
 707                     (if valvoid
 708                         (princ "It is void as a variable.")
 709                       (princ "Its ")))
 710                 (if valvoid
 711                     (princ " is void as a variable.")
 712                   (princ "'s "))))
 713             (unless valvoid
 714               (with-current-buffer standard-output
 715                 (setq val-start-pos (point))
 716                 (princ "value is ")
 717                 (let ((from (point))
 718                       (line-beg (line-beginning-position))
 719                       (print-rep
 720                        (let ((print-quoted t))
 721                          (prin1-to-string val))))
 722                   (if (< (+ (length print-rep) (point) (- line-beg)) 68)
 723                       (insert print-rep)
 724                     (terpri)
 725                     (pp val)
 726                     (if (< (point) (+ 68 (line-beginning-position 0)))
 727                         (delete-region from (1+ from))
 728                       (delete-region (1- from) from)))
 729                   (let* ((sv (get variable 'standard-value))
 730                          (origval (and (consp sv)
 731                                        (condition-case nil
 732                                            (eval (car sv))
 733                                          (error :help-eval-error)))))
 734                     (when (and (consp sv)
 735                                (not (equal origval val))
 736                                (not (equal origval :help-eval-error)))
 737                       (princ "\nOriginal value was \n")
 738                       (setq from (point))
 739                       (pp origval)
 740                       (if (< (point) (+ from 20))
 741                           (delete-region (1- from) from)))))))
 742             (terpri)
 743             (when locus
 744               (cond
 745                ((bufferp locus)
 746                 (princ (format "Local in buffer %s; "
 747                                (buffer-name buffer))))
 748                ((framep locus)
 749                 (princ (format "It is a frame-local variable; ")))
 750                ((terminal-live-p locus)
 751                 (princ (format "It is a terminal-local variable; ")))
 752                (t
 753                 (princ (format "It is local to %S" locus))))
 754               (if (not (default-boundp variable))
 755                   (princ "globally void")
 756                 (let ((global-val (default-value variable)))
 757                   (with-current-buffer standard-output
 758                     (princ "global value is ")
 759                     (if (eq val global-val)
 760                         (princ "the same.")
 761                       (terpri)
 762                       ;; Fixme: pp can take an age if you happen to
 763                       ;; ask for a very large expression.  We should
 764                       ;; probably print it raw once and check it's a
 765                       ;; sensible size before prettyprinting.  -- fx
 766                       (let ((from (point)))
 767                         (pp global-val)
 768                         ;; See previous comment for this function.
 769                         ;; (help-xref-on-pp from (point))
 770                         (if (< (point) (+ from 20))
 771                             (delete-region (1- from) from)))))))
 772               (terpri))
 773
 774             ;; If the value is large, move it to the end.
 775             (with-current-buffer standard-output
 776               (when (> (count-lines (point-min) (point-max)) 10)
 777                 ;; Note that setting the syntax table like below
 778                 ;; makes forward-sexp move over a `'s' at the end
 779                 ;; of a symbol.
 780                 (set-syntax-table emacs-lisp-mode-syntax-table)
 781                 (goto-char val-start-pos)
 782                 ;; The line below previously read as
 783                 ;; (delete-region (point) (progn (end-of-line) (point)))
 784                 ;; which suppressed display of the buffer local value for
 785                 ;; large values.
 786                 (when (looking-at "value is") (replace-match ""))
 787                 (save-excursion
 788                   (insert "\n\nValue:")
 789                   (set (make-local-variable 'help-button-cache)
 790                        (point-marker)))
 791                 (insert "value is shown ")
 792                 (insert-button "below"
 793                                'action help-button-cache
 794                                'follow-link t
 795                                'help-echo "mouse-2, RET: show value")
 796                 (insert ".\n")))
 797             (terpri)
 798
 799             (let* ((alias (condition-case nil
 800                               (indirect-variable variable)
 801                             (error variable)))
 802                    (obsolete (get variable 'byte-obsolete-variable))
 803                    (use (car obsolete))
 804                    (safe-var (get variable 'safe-local-variable))
 805                    (doc (or (documentation-property
 806                              variable 'variable-documentation)
 807                             (documentation-property
 808                              alias 'variable-documentation)))
 809                    (extra-line nil))
 810
 811               ;; Mention if it's a local variable.
 812               (cond
 813                ((and (local-variable-if-set-p variable)
 814                      (or (not (local-variable-p variable))
 815                          (with-temp-buffer
 816                            (local-variable-if-set-p variable))))
 817                 (setq extra-line t)
 818                 (princ "  Automatically becomes ")
 819                 (if permanent-local
 820                     (princ "permanently "))
 821                 (princ "buffer-local when set.\n"))
 822                ((not permanent-local))
 823                ((bufferp locus)
 824                 (setq extra-line t)
 825                 (princ "  This variable's buffer-local value is permanent.\n"))
 826                (t
 827                 (setq extra-line t)
 828                 (princ "  This variable's value is permanent \
 829 if it is given a local binding.\n")))
 830
 831               ;; Mention if it's an alias.
 832               (unless (eq alias variable)
 833                 (setq extra-line t)
 834                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 835
 836               (when obsolete
 837                 (setq extra-line t)
 838                 (princ "  This variable is obsolete")
 839                 (if (nth 2 obsolete)
 840                     (princ (format " since %s" (nth 2 obsolete))))
 841                 (princ (cond ((stringp use) (concat ";\n  " use))
 842                              (use (format ";\n  use `%s' instead." (car obsolete)))
 843                              (t ".")))
 844                 (terpri))
 845
 846               (when (member (cons variable val)
 847                             (with-current-buffer buffer
 848                               file-local-variables-alist))
 849                 (setq extra-line t)
 850                 (if (member (cons variable val)
 851                              (with-current-buffer buffer
 852                                dir-local-variables-alist))
 853                     (let ((file (and (buffer-file-name buffer)
 854                                       (not (file-remote-p
 855                                             (buffer-file-name buffer)))
 856                                       (dir-locals-find-file
 857                                        (buffer-file-name buffer))))
 858                           (dir-file t))
 859                       (princ "  This variable's value is directory-local")
 860                       (if (null file)
 861                           (princ ".\n")
 862                         (princ ", set ")
 863                         (if (consp file) ; result from cache
 864                             ;; If the cache element has an mtime, we
 865                             ;; assume it came from a file.
 866                             (if (nth 2 file)
 867                                 (setq file (expand-file-name
 868                                             dir-locals-file (car file)))
 869                               ;; Otherwise, assume it was set directly.
 870                               (setq file (car file)
 871                                     dir-file nil)))
 872                         (princ (if dir-file
 873                                    "by the file\n  `"
 874                                  "for the directory\n  `"))
 875                         (with-current-buffer standard-output
 876                           (insert-text-button
 877                            file 'type 'help-dir-local-var-def
 878                            'help-args (list variable file)))
 879                         (princ "'.\n")))
 880                   (princ "  This variable's value is file-local.\n")))
 881
 882               (when (memq variable ignored-local-variables)
 883                 (setq extra-line t)
 884                 (princ "  This variable is ignored as a file-local \
 885 variable.\n"))
 886
 887               ;; Can be both risky and safe, eg auto-fill-function.
 888               (when (risky-local-variable-p variable)
 889                 (setq extra-line t)
 890                 (princ "  This variable may be risky if used as a \
 891 file-local variable.\n")
 892                 (when (assq variable safe-local-variable-values)
 893                   (princ "  However, you have added it to \
 894 `safe-local-variable-values'.\n")))
 895
 896               (when safe-var
 897                 (setq extra-line t)
 898                 (princ "  This variable is safe as a file local variable ")
 899                 (princ "if its value\n  satisfies the predicate ")
 900                 (princ (if (byte-code-function-p safe-var)
 901                            "which is a byte-compiled expression.\n"
 902                          (format "`%s'.\n" safe-var))))
 903
 904               (if extra-line (terpri))
 905               (princ "Documentation:\n")
 906               (with-current-buffer standard-output
 907                 (insert (or doc "Not documented as a variable."))))
 908
 909             ;; Make a link to customize if this variable can be customized.
 910             (when (custom-variable-p variable)
 911               (let ((customize-label "customize"))
 912                 (terpri)
 913                 (terpri)
 914                 (princ (concat "You can " customize-label " this variable."))
 915                 (with-current-buffer standard-output
 916                   (save-excursion
 917                     (re-search-backward
 918                      (concat "\\(" customize-label "\\)") nil t)
 919                     (help-xref-button 1 'help-customize-variable variable))))
 920               ;; Note variable's version or package version
 921               (let ((output (describe-variable-custom-version-info variable)))
 922                 (when output
 923                   (terpri)
 924                   (terpri)
 925                   (princ output))))
 926
 927             (with-current-buffer standard-output
 928               ;; Return the text we displayed.
 929               (buffer-string))))))))
 930
 931
 932 ;;;###autoload
 933 (defun describe-function-or-variable (symbol &optional buffer frame)
 934   "Display the full documentation of the function or variable SYMBOL.
 935 If SYMBOL is a variable and has a buffer-local value in BUFFER or FRAME
 936 \(default to the current buffer and current frame), it is displayed along
 937 with the global value."
 938   (interactive
 939    (let* ((v-or-f (variable-at-point))
 940           (found (symbolp v-or-f))
 941           (v-or-f (if found v-or-f (function-called-at-point)))
 942           (found (or found v-or-f))
 943           (enable-recursive-minibuffers t)
 944           val)
 945      (setq val (completing-read (if found
 946                                     (format
 947                                         "Describe function or variable (default %s): " v-or-f)
 948                                   "Describe function or variable: ")
 949                                 obarray
 950                                 (lambda (vv)
 951                                   (or (fboundp vv)
 952                                       (get vv 'variable-documentation)
 953                                       (and (boundp vv) (not (keywordp vv)))))
 954                                 t nil nil
 955                                 (if found (symbol-name v-or-f))))
 956      (list (if (equal val "")
 957                v-or-f (intern val)))))
 958   (if (not (symbolp symbol)) (message "You didn't specify a function or variable")
 959     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 960     (unless (frame-live-p frame) (setq frame (selected-frame)))
 961     (help-xref-interned symbol buffer frame)))
 962
 963 ;;;###autoload
 964 (defun describe-syntax (&optional buffer)
 965   "Describe the syntax specifications in the syntax table of BUFFER.
 966 The descriptions are inserted in a help buffer, which is then displayed.
 967 BUFFER defaults to the current buffer."
 968   (interactive)
 969   (setq buffer (or buffer (current-buffer)))
 970   (help-setup-xref (list #'describe-syntax buffer)
 971                    (called-interactively-p 'interactive))
 972   (with-help-window (help-buffer)
 973     (let ((table (with-current-buffer buffer (syntax-table))))
 974       (with-current-buffer standard-output
 975         (describe-vector table 'internal-describe-syntax-value)
 976         (while (setq table (char-table-parent table))
 977           (insert "\nThe parent syntax table is:")
 978           (describe-vector table 'internal-describe-syntax-value))))))
 979
 980 (defun help-describe-category-set (value)
 981   (insert (cond
 982            ((null value) "default")
 983            ((char-table-p value) "deeper char-table ...")
 984            (t (condition-case nil
 985                   (category-set-mnemonics value)
 986                 (error "invalid"))))))
 987
 988 ;;;###autoload
 989 (defun describe-categories (&optional buffer)
 990   "Describe the category specifications in the current category table.
 991 The descriptions are inserted in a buffer, which is then displayed.
 992 If BUFFER is non-nil, then describe BUFFER's category table instead.
 993 BUFFER should be a buffer or a buffer name."
 994   (interactive)
 995   (setq buffer (or buffer (current-buffer)))
 996   (help-setup-xref (list #'describe-categories buffer)
 997                    (called-interactively-p 'interactive))
 998   (with-help-window (help-buffer)
 999     (let* ((table (with-current-buffer buffer (category-table)))
1000            (docs (char-table-extra-slot table 0)))
1001       (if (or (not (vectorp docs)) (/= (length docs) 95))
1002           (error "Invalid first extra slot in this category table\n"))
1003       (with-current-buffer standard-output
1004         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
1005         (let ((pos (point)) (items 0) lines n)
1006           (dotimes (i 95)
1007             (if (aref docs i) (setq items (1+ items))))
1008           (setq lines (1+ (/ (1- items) 4)))
1009           (setq n 0)
1010           (dotimes (i 95)
1011             (let ((elt (aref docs i)))
1012               (when elt
1013                 (string-match ".*" elt)
1014                 (setq elt (match-string 0 elt))
1015                 (if (>= (length elt) 17)
1016                     (setq elt (concat (substring elt 0 14) "...")))
1017                 (if (< (point) (point-max))
1018                     (move-to-column (* 20 (/ n lines)) t))
1019                 (insert (+ i ?\s) ?: elt)
1020                 (if (< (point) (point-max))
1021                     (forward-line 1)
1022                   (insert "\n"))
1023                 (setq n (1+ n))
1024                 (if (= (% n lines) 0)
1025                     (goto-char pos))))))
1026         (goto-char (point-max))
1027         (insert "\n"
1028                 "character(s)\tcategory mnemonics\n"
1029                 "------------\t------------------")
1030         (describe-vector table 'help-describe-category-set)
1031         (insert "Legend of category mnemonics:\n")
1032         (dotimes (i 95)
1033           (let ((elt (aref docs i)))
1034             (when elt
1035               (if (string-match "\n" elt)
1036                   (setq elt (substring elt (match-end 0))))
1037               (insert (+ i ?\s) ": " elt "\n"))))
1038         (while (setq table (char-table-parent table))
1039           (insert "\nThe parent category table is:")
1040           (describe-vector table 'help-describe-category-set))))))
1041
1042 \f
1043 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
1044
1045 ;; Replaces lib-src/digest-doc.c.
1046 ;;;###autoload
1047 (defun doc-file-to-man (file)
1048   "Produce an nroff buffer containing the doc-strings from the DOC file."
1049   (interactive (list (read-file-name "Name of DOC file: " doc-directory
1050                                      internal-doc-file-name t)))
1051   (or (file-readable-p file)
1052       (error "Cannot read file `%s'" file))
1053   (pop-to-buffer (generate-new-buffer "*man-doc*"))
1054   (setq buffer-undo-list t)
1055   (insert ".TH \"Command Summary for GNU Emacs\"\n"
1056           ".AU Richard M. Stallman\n")
1057   (insert-file-contents file)
1058   (let (notfirst)
1059     (while (search-forward "\x1f" nil 'move)
1060       (if (looking-at "S")
1061           (delete-region (1- (point)) (line-end-position))
1062         (delete-char -1)
1063         (if notfirst
1064             (insert "\n.DE\n")
1065           (setq notfirst t))
1066         (insert "\n.SH ")
1067         (insert (if (looking-at "F") "Function " "Variable "))
1068         (delete-char 1)
1069         (forward-line 1)
1070         (insert ".DS L\n"))))
1071   (insert "\n.DE\n")
1072   (setq buffer-undo-list nil)
1073   (nroff-mode))
1074
1075 ;; Replaces lib-src/sorted-doc.c.
1076 ;;;###autoload
1077 (defun doc-file-to-info (file)
1078   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
1079   (interactive (list (read-file-name "Name of DOC file: " doc-directory
1080                                      internal-doc-file-name t)))
1081   (or (file-readable-p file)
1082       (error "Cannot read file `%s'" file))
1083   (let ((i 0) type name doc alist)
1084     (with-temp-buffer
1085       (insert-file-contents file)
1086       ;; The characters "@{}" need special treatment.
1087       (while (re-search-forward "[@{}]" nil t)
1088         (backward-char)
1089         (insert "@")
1090         (forward-char 1))
1091       (goto-char (point-min))
1092       (while (search-forward "\x1f" nil t)
1093         (unless (looking-at "S")
1094           (setq type (char-after)
1095                 name (buffer-substring (1+ (point)) (line-end-position))
1096                 doc (buffer-substring (line-beginning-position 2)
1097                                       (if (search-forward  "\x1f" nil 'move)
1098                                           (1- (point))
1099                                         (point)))
1100                 alist (cons (list name type doc) alist))
1101           (backward-char 1))))
1102     (pop-to-buffer (generate-new-buffer "*info-doc*"))
1103     (setq buffer-undo-list t)
1104     ;; Write the output header.
1105     (insert "\\input texinfo  @c -*-texinfo-*-\n"
1106             "@setfilename emacsdoc.info\n"
1107             "@settitle Command Summary for GNU Emacs\n"
1108             "@finalout\n"
1109             "\n@node Top\n"
1110             "@unnumbered Command Summary for GNU Emacs\n\n"
1111             "@table @asis\n\n"
1112             "@iftex\n"
1113             "@global@let@ITEM@item\n"
1114             "@def@item{@filbreak@vskip5pt@ITEM}\n"
1115             "@font@tensy cmsy10 scaled @magstephalf\n"
1116             "@font@teni cmmi10 scaled @magstephalf\n"
1117             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
1118             "@def|{{@tensy@char106}}\n"
1119             "@def@{{{@tensy@char102}}\n"
1120             "@def@}{{@tensy@char103}}\n"
1121             "@def<{{@teni@char62}}\n"
1122             "@def>{{@teni@char60}}\n"
1123             "@chardef@@64\n"
1124             "@catcode43=12\n"
1125             "@tableindent-0.2in\n"
1126             "@end iftex\n")
1127     ;; Sort the array by name; within each name, by type (functions first).
1128     (setq alist (sort alist (lambda (e1 e2)
1129                               (if (string-equal (car e1) (car e2))
1130                                   (<= (cadr e1) (cadr e2))
1131                                 (string-lessp (car e1) (car e2))))))
1132     ;; Print each function.
1133     (dolist (e alist)
1134       (insert "\n@item "
1135               (if (char-equal (cadr e) ?\F) "Function" "Variable")
1136               " @code{" (car e) "}\n@display\n"
1137               (nth 2 e)
1138               "\n@end display\n")
1139       ;; Try to avoid a save size overflow in the TeX output routine.
1140       (if (zerop (setq i (% (1+ i) 100)))
1141           (insert "\n@end table\n@table @asis\n")))
1142     (insert "@end table\n"
1143             "@bye\n")
1144     (setq buffer-undo-list nil)
1145     (texinfo-mode)))
1146
1147 (provide 'help-fns)
1148
1149 ;;; help-fns.el ends here