lisp/hl-line.el

   1 ;;; hl-line.el --- highlight the current line
   2
   3 ;; Copyright (C) 1998, 2000-2011  Free Software Foundation, Inc.
   4
   5 ;; Author:  Dave Love <fx@gnu.org>
   6 ;; Maintainer: FSF
   7 ;; Created: 1998-09-13
   8 ;; Keywords: faces, frames, emulations
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Provides a local minor mode (toggled by M-x hl-line-mode) and
  28 ;; a global minor mode (toggled by M-x global-hl-line-mode) to
  29 ;; highlight, on a suitable terminal, the line on which point is.  The
  30 ;; global mode highlights the current line in the selected window only
  31 ;; (except when the minibuffer window is selected).  This was
  32 ;; implemented to satisfy a request for a feature of Lesser Editors.
  33 ;; The local mode is sticky: it highlights the line about the buffer's
  34 ;; point even if the buffer's window is not selected.  Caveat: the
  35 ;; buffer's point might be different from the point of a non-selected
  36 ;; window.  Set the variable `hl-line-sticky-flag' to nil to make the
  37 ;; local mode behave like the global mode.
  38
  39 ;; You probably don't really want to use the global mode; if the
  40 ;; cursor is difficult to spot, try changing its color, relying on
  41 ;; `blink-cursor-mode' or both.  The hookery used might affect
  42 ;; response noticeably on a slow machine.  The local mode may be
  43 ;; useful in non-editing buffers such as Gnus or PCL-CVS though.
  44
  45 ;; An overlay is used.  In the non-sticky cases, this overlay is
  46 ;; active only on the selected window.  A hook is added to
  47 ;; `post-command-hook' to activate the overlay and move it to the line
  48 ;; about point.  To get the non-sticky behavior, `hl-line-unhighlight'
  49 ;; is added to `pre-command-hook' as well.  This function deactivates
  50 ;; the overlay unconditionally in case the command changes the
  51 ;; selected window.  (It does so rather than keeping track of changes
  52 ;; in the selected window).
  53
  54 ;; You could make variable `global-hl-line-mode' buffer-local and set
  55 ;; it to nil to avoid highlighting specific buffers, when the global
  56 ;; mode is used.
  57
  58 ;; By default the whole line is highlighted.  The range of highlighting
  59 ;; can be changed by defining an appropriate function as the
  60 ;; buffer-local value of `hl-line-range-function'.
  61
  62 ;;; Code:
  63
  64 (defvar hl-line-overlay nil
  65   "Overlay used by Hl-Line mode to highlight the current line.")
  66 (make-variable-buffer-local 'hl-line-overlay)
  67
  68 (defvar global-hl-line-overlay nil
  69   "Overlay used by Global-Hl-Line mode to highlight the current line.")
  70
  71 (defgroup hl-line nil
  72   "Highlight the current line."
  73   :version "21.1"
  74   :group 'convenience)
  75
  76 (defface hl-line
  77   '((t :inherit highlight))
  78   "Default face for highlighting the current line in Hl-Line mode."
  79   :version "22.1"
  80   :group 'hl-line)
  81
  82 (defcustom hl-line-face 'hl-line
  83   "Face with which to highlight the current line in Hl-Line mode."
  84   :type 'face
  85   :group 'hl-line
  86   :set (lambda (symbol value)
  87          (set symbol value)
  88          (dolist (buffer (buffer-list))
  89            (with-current-buffer buffer
  90              (when hl-line-overlay
  91                (overlay-put hl-line-overlay 'face hl-line-face))))
  92          (when global-hl-line-overlay
  93            (overlay-put global-hl-line-overlay 'face hl-line-face))))
  94
  95 (defcustom hl-line-sticky-flag t
  96   "Non-nil means highlight the current line in all windows.
  97 Otherwise Hl-Line mode will highlight only in the selected
  98 window.  Setting this variable takes effect the next time you use
  99 the command `hl-line-mode' to turn Hl-Line mode on."
 100   :type 'boolean
 101   :version "22.1"
 102   :group 'hl-line)
 103
 104 (defvar hl-line-range-function nil
 105   "If non-nil, function to call to return highlight range.
 106 The function of no args should return a cons cell; its car value
 107 is the beginning position of highlight and its cdr value is the
 108 end position of highlight in the buffer.
 109 It should return nil if there's no region to be highlighted.
 110
 111 This variable is expected to be made buffer-local by modes.")
 112
 113 ;;;###autoload
 114 (define-minor-mode hl-line-mode
 115   "Buffer-local minor mode to highlight the line about point.
 116 With ARG, turn Hl-Line mode on if ARG is positive, off otherwise.
 117
 118 If `hl-line-sticky-flag' is non-nil, Hl-Line mode highlights the
 119 line about the buffer's point in all windows.  Caveat: the
 120 buffer's point might be different from the point of a
 121 non-selected window.  Hl-Line mode uses the function
 122 `hl-line-highlight' on `post-command-hook' in this case.
 123
 124 When `hl-line-sticky-flag' is nil, Hl-Line mode highlights the
 125 line about point in the selected window only.  In this case, it
 126 uses the function `hl-line-unhighlight' on `pre-command-hook' in
 127 addition to `hl-line-highlight' on `post-command-hook'."
 128   :group 'hl-line
 129   (if hl-line-mode
 130       (progn
 131         ;; In case `kill-all-local-variables' is called.
 132         (add-hook 'change-major-mode-hook #'hl-line-unhighlight nil t)
 133         (if hl-line-sticky-flag
 134             (remove-hook 'pre-command-hook #'hl-line-unhighlight t)
 135           (add-hook 'pre-command-hook #'hl-line-unhighlight nil t))
 136         (hl-line-highlight)
 137         (add-hook 'post-command-hook #'hl-line-highlight nil t))
 138     (remove-hook 'post-command-hook #'hl-line-highlight t)
 139     (hl-line-unhighlight)
 140     (remove-hook 'change-major-mode-hook #'hl-line-unhighlight t)
 141     (remove-hook 'pre-command-hook #'hl-line-unhighlight t)))
 142
 143 (defun hl-line-highlight ()
 144   "Activate the Hl-Line overlay on the current line."
 145   (if hl-line-mode      ; Might be changed outside the mode function.
 146       (progn
 147         (unless hl-line-overlay
 148           (setq hl-line-overlay (make-overlay 1 1)) ; to be moved
 149           (overlay-put hl-line-overlay 'face hl-line-face))
 150         (overlay-put hl-line-overlay
 151                      'window (unless hl-line-sticky-flag (selected-window)))
 152         (hl-line-move hl-line-overlay))
 153     (hl-line-unhighlight)))
 154
 155 (defun hl-line-unhighlight ()
 156   "Deactivate the Hl-Line overlay on the current line."
 157   (when hl-line-overlay
 158     (delete-overlay hl-line-overlay)))
 159
 160 ;;;###autoload
 161 (define-minor-mode global-hl-line-mode
 162   "Global minor mode to highlight the line about point in the current window.
 163 With ARG, turn Global-Hl-Line mode on if ARG is positive, off otherwise.
 164
 165 Global-Hl-Line mode uses the functions `global-hl-line-unhighlight' and
 166 `global-hl-line-highlight' on `pre-command-hook' and `post-command-hook'."
 167   :global t
 168   :group 'hl-line
 169   (if global-hl-line-mode
 170       (progn
 171         (add-hook 'pre-command-hook #'global-hl-line-unhighlight)
 172         (add-hook 'post-command-hook #'global-hl-line-highlight))
 173     (global-hl-line-unhighlight)
 174     (remove-hook 'pre-command-hook #'global-hl-line-unhighlight)
 175     (remove-hook 'post-command-hook #'global-hl-line-highlight)))
 176
 177 (defun global-hl-line-highlight ()
 178   "Highlight the current line in the current window."
 179   (when global-hl-line-mode     ; Might be changed outside the mode function.
 180     (unless (window-minibuffer-p (selected-window))
 181       (unless global-hl-line-overlay
 182         (setq global-hl-line-overlay (make-overlay 1 1)) ; to be moved
 183         (overlay-put global-hl-line-overlay 'face hl-line-face))
 184       (overlay-put global-hl-line-overlay 'window (selected-window))
 185       (hl-line-move global-hl-line-overlay))))
 186
 187 (defun global-hl-line-unhighlight ()
 188   "Deactivate the Global-Hl-Line overlay on the current line."
 189   (when global-hl-line-overlay
 190     (delete-overlay global-hl-line-overlay)))
 191
 192 (defun hl-line-move (overlay)
 193   "Move the Hl-Line overlay.
 194 If `hl-line-range-function' is non-nil, move the OVERLAY to the position
 195 where the function returns.  If `hl-line-range-function' is nil, fill
 196 the line including the point by OVERLAY."
 197   (let (tmp b e)
 198     (if hl-line-range-function
 199         (setq tmp (funcall hl-line-range-function)
 200               b   (car tmp)
 201               e   (cdr tmp))
 202       (setq tmp t
 203             b (line-beginning-position)
 204             e (line-beginning-position 2)))
 205     (if tmp
 206         (move-overlay overlay b e)
 207       (move-overlay overlay 1 1))))
 208
 209 (defun hl-line-unload-function ()
 210   "Unload the Hl-Line library."
 211   (global-hl-line-mode -1)
 212   (save-current-buffer
 213     (dolist (buffer (buffer-list))
 214       (set-buffer buffer)
 215       (when hl-line-mode (hl-line-mode -1))))
 216   ;; continue standard unloading
 217   nil)
 218
 219 (provide 'hl-line)
 220
 221 ;;; hl-line.el ends here