lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 (require 'help-mode)
  37
  38
  39 ;;;###autoload
  40 (defun help-with-tutorial (&optional arg)
  41   "Select the Emacs learn-by-doing tutorial.
  42 If there is a tutorial version written in the language
  43 of the selected language environment, that version is used.
  44 If there's no tutorial in that language, `TUTORIAL' is selected.
  45 With ARG, you are asked to choose which language."
  46   (interactive "P")
  47   (let ((lang (if arg
  48                   (let ((minibuffer-setup-hook minibuffer-setup-hook))
  49                     (add-hook 'minibuffer-setup-hook
  50                               'minibuffer-completion-help)
  51                     (read-language-name 'tutorial "Language: " "English"))
  52                 (if (get-language-info current-language-environment 'tutorial)
  53                     current-language-environment
  54                   "English")))
  55         file filename)
  56     (setq filename (get-language-info lang 'tutorial))
  57     (setq file (expand-file-name (concat "~/" filename)))
  58     (delete-other-windows)
  59     (if (get-file-buffer file)
  60         (switch-to-buffer (get-file-buffer file))
  61       (switch-to-buffer (create-file-buffer file))
  62       (setq buffer-file-name file)
  63       (setq default-directory (expand-file-name "~/"))
  64       (setq buffer-auto-save-file-name nil)
  65       (insert-file-contents (expand-file-name filename data-directory))
  66       (hack-local-variables)
  67       (goto-char (point-min))
  68       (search-forward "\n<<")
  69       (beginning-of-line)
  70       ;; Convert the <<...>> line to the proper [...] line,
  71       ;; or just delete the <<...>> line if a [...] line follows.
  72       (cond ((save-excursion
  73                (forward-line 1)
  74                (looking-at "\\["))
  75              (delete-region (point) (progn (forward-line 1) (point))))
  76             ((looking-at "<<Blank lines inserted.*>>")
  77              (replace-match "[Middle of page left blank for didactic purposes.   Text continues below]"))
  78             (t
  79              (looking-at "<<")
  80              (replace-match "[")
  81              (search-forward ">>")
  82              (replace-match "]")))
  83       (beginning-of-line)
  84       (let ((n (- (window-height (selected-window))
  85                   (count-lines (point-min) (point))
  86                   6)))
  87         (if (< n 8)
  88             (progn
  89               ;; For a short gap, we don't need the [...] line,
  90               ;; so delete it.
  91               (delete-region (point) (progn (end-of-line) (point)))
  92               (newline n))
  93           ;; Some people get confused by the large gap.
  94           (newline (/ n 2))
  95
  96           ;; Skip the [...] line (don't delete it).
  97           (forward-line 1)
  98           (newline (- n (/ n 2)))))
  99       (goto-char (point-min))
 100       (setq buffer-undo-list nil)
 101       (set-buffer-modified-p nil))))
 102
 103 \f
 104 ;; Functions
 105
 106 ;;;###autoload
 107 (defun describe-function (function)
 108   "Display the full documentation of FUNCTION (a symbol)."
 109   (interactive
 110    (let ((fn (function-called-at-point))
 111          (enable-recursive-minibuffers t)
 112          val)
 113      (setq val (completing-read (if fn
 114                                     (format "Describe function (default %s): " fn)
 115                                   "Describe function: ")
 116                                 obarray 'fboundp t nil nil (symbol-name fn)))
 117      (list (if (equal val "")
 118                fn (intern val)))))
 119   (if (null function)
 120       (message "You didn't specify a function")
 121     (help-setup-xref (list #'describe-function function) (interactive-p))
 122     (save-excursion
 123       (with-output-to-temp-buffer (help-buffer)
 124         (prin1 function)
 125         ;; Use " is " instead of a colon so that
 126         ;; it is easier to get out the function name using forward-sexp.
 127         (princ " is ")
 128         (describe-function-1 function)
 129         (print-help-return-message)
 130         (with-current-buffer standard-output
 131           ;; Return the text we displayed.
 132           (buffer-string))))))
 133
 134 (defun help-split-fundoc (docstring def)
 135   "Split a function DOCSTRING into the actual doc and the usage info.
 136 Return (USAGE . DOC) or nil if there's no usage info.
 137 DEF is the function whose usage we're looking for in DOCSTRING."
 138   ;; Functions can get the calling sequence at the end of the doc string.
 139   ;; In cases where `function' has been fset to a subr we can't search for
 140   ;; function's name in the doc string so we use `fn' as the anonymous
 141   ;; function name instead.
 142   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
 143     (cons (format "(%s%s"
 144                   ;; Replace `fn' with the actual function name.
 145                   (if (consp def) "anonymous" def)
 146                   (match-string 1 docstring))
 147           (substring docstring 0 (match-beginning 0)))))
 148
 149 (defun help-add-fundoc-usage (docstring arglist)
 150   "Add the usage info to DOCSTRING.
 151 If DOCSTRING already has a usage info, then just return it unchanged.
 152 The usage info is built from ARGLIST.  DOCSTRING can be nil.
 153 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
 154   (unless (stringp docstring) (setq docstring "Not documented"))
 155   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
 156       docstring
 157     (concat docstring
 158             (if (string-match "\n?\n\\'" docstring)
 159                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
 160               "\n\n")
 161             (if (and (stringp arglist)
 162                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
 163                 (concat "(fn" (match-string 1 arglist) ")")
 164               (format "%S" (help-make-usage 'fn arglist))))))
 165
 166 (defun help-function-arglist (def)
 167   ;; Handle symbols aliased to other symbols.
 168   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 169   ;; If definition is a macro, find the function inside it.
 170   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 171   (cond
 172    ((byte-code-function-p def) (aref def 0))
 173    ((eq (car-safe def) 'lambda) (nth 1 def))
 174    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 175     "[Arg list not available until function definition is loaded.]")
 176    (t t)))
 177
 178 (defun help-make-usage (function arglist)
 179   (cons (if (symbolp function) function 'anonymous)
 180         (mapcar (lambda (arg)
 181                   (if (not (symbolp arg))
 182                       (if (and (consp arg) (symbolp (car arg)))
 183                           ;; CL style default values for optional args.
 184                           (cons (intern (upcase (symbol-name (car arg))))
 185                                 (cdr arg))
 186                         arg)
 187                     (let ((name (symbol-name arg)))
 188                       (if (string-match "\\`&" name) arg
 189                         (intern (upcase name))))))
 190                 arglist)))
 191
 192 ;; Could be this, if we make symbol-file do the work below.
 193 ;; (defun help-C-file-name (subr-or-var kind)
 194 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 195 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 196 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 197 ;;               (subr-name subr-or-var))
 198 ;;             (if (eq kind 'var) 'defvar 'defun)))
 199 ;;;###autoload
 200 (defun help-C-file-name (subr-or-var kind)
 201   "Return the name of the C file where SUBR-OR-VAR is defined.
 202 KIND should be `var' for a variable or `subr' for a subroutine."
 203   (let ((docbuf (get-buffer-create " *DOC*"))
 204         (name (if (eq 'var kind)
 205                   (concat "V" (symbol-name subr-or-var))
 206                 (concat "F" (subr-name subr-or-var)))))
 207     (with-current-buffer docbuf
 208       (goto-char (point-min))
 209       (if (eobp)
 210           (insert-file-contents-literally
 211            (expand-file-name internal-doc-file-name doc-directory)))
 212       (let ((file (catch 'loop
 213                     (while t
 214                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 215                         (re-search-backward "\x1fS\\(.*\\)")
 216                         (let ((file (match-string 1)))
 217                           (if (member file build-files)
 218                               (throw 'loop file)
 219                             (goto-char pnt))))))))
 220         (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 221             (setq file (replace-match ".c" t t file)))
 222         (if (string-match "\\.c\\'" file)
 223             (concat "src/" file)
 224           file)))))
 225
 226 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 227   "Face to highlight argument names in *Help* buffers."
 228   :group 'help)
 229
 230 (defun help-default-arg-highlight (arg)
 231   "Default function to highlight arguments in *Help* buffers.
 232 It returns ARG in face `help-argument-name'; ARG is also
 233 downcased if it displays differently than the default
 234 face (according to `face-differs-from-default-p')."
 235   (propertize (if (face-differs-from-default-p 'help-argument-name)
 236                   (downcase arg)
 237                 arg)
 238               'face 'help-argument-name))
 239
 240 (defun help-do-arg-highlight (doc args)
 241   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 242     (modify-syntax-entry ?\- "w")
 243     (dolist (arg args doc)
 244       (setq doc (replace-regexp-in-string
 245                  ;; This is heuristic, but covers all common cases
 246                  ;; except ARG1-ARG2
 247                  (concat "\\<"                   ; beginning of word
 248                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 249                          "\\("
 250                          (regexp-quote arg)
 251                          "\\)"
 252                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 253                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 254                          "\\>")                  ; end of word
 255                  (help-default-arg-highlight arg)
 256                  doc t t 1)))))
 257
 258 (defun help-highlight-arguments (usage doc &rest args)
 259   (when usage
 260     (with-temp-buffer
 261       (insert usage)
 262       (goto-char (point-min))
 263       (let ((case-fold-search nil)
 264             (next (not (or args (looking-at "\\["))))
 265             (opt nil))
 266         ;; Make a list of all arguments
 267         (skip-chars-forward "^ ")
 268         (while next
 269           (or opt (not (looking-at " &")) (setq opt t))
 270           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 271               (setq next nil)
 272             (setq args (cons (match-string 2) args))
 273             (when (and opt (string= (match-string 1) "("))
 274               ;; A pesky CL-style optional argument with default value,
 275               ;; so let's skip over it
 276               (search-backward "(")
 277               (goto-char (scan-sexps (point) 1)))))
 278         ;; Highlight aguments in the USAGE string
 279         (setq usage (help-do-arg-highlight (buffer-string) args))
 280         ;; Highlight arguments in the DOC string
 281         (setq doc (and doc (help-do-arg-highlight doc args))))))
 282   ;; Return value is like the one from help-split-fundoc, but highlighted
 283   (cons usage doc))
 284
 285 ;;;###autoload
 286 (defun describe-simplify-lib-file-name (file)
 287   "Simplify a library name FILE to a relative name, and make it a source file."
 288   (if file
 289       ;; Try converting the absolute file name to a library name.
 290       (let ((libname (file-name-nondirectory file)))
 291         ;; Now convert that back to a file name and see if we get
 292         ;; the original one.  If so, they are equivalent.
 293         (if (equal file (locate-file libname load-path '("")))
 294             (if (string-match "[.]elc\\'" libname)
 295                 (substring libname 0 -1)
 296               libname)
 297           file))))
 298
 299 ;;;###autoload
 300 (defun describe-function-1 (function)
 301   (let* ((def (if (symbolp function)
 302                   (symbol-function function)
 303                 function))
 304          file-name string
 305          (beg (if (commandp def) "an interactive " "a ")))
 306     (setq string
 307           (cond ((or (stringp def)
 308                      (vectorp def))
 309                  "a keyboard macro")
 310                 ((subrp def)
 311                  (if (eq 'unevalled (cdr (subr-arity def)))
 312                      (concat beg "special form")
 313                    (concat beg "built-in function")))
 314                 ((byte-code-function-p def)
 315                  (concat beg "compiled Lisp function"))
 316                 ((symbolp def)
 317                  (while (symbolp (symbol-function def))
 318                    (setq def (symbol-function def)))
 319                  (format "an alias for `%s'" def))
 320                 ((eq (car-safe def) 'lambda)
 321                  (concat beg "Lisp function"))
 322                 ((eq (car-safe def) 'macro)
 323                  "a Lisp macro")
 324                 ((eq (car-safe def) 'autoload)
 325                  (setq file-name (nth 1 def))
 326                  (format "%s autoloaded %s"
 327                          (if (commandp def) "an interactive" "an")
 328                          (if (eq (nth 4 def) 'keymap) "keymap"
 329                            (if (nth 4 def) "Lisp macro" "Lisp function"))
 330                          ))
 331                 ((keymapp def)
 332                  (let ((is-full nil)
 333                        (elts (cdr-safe def)))
 334                    (while elts
 335                      (if (char-table-p (car-safe elts))
 336                          (setq is-full t
 337                                elts nil))
 338                      (setq elts (cdr-safe elts)))
 339                    (if is-full
 340                        "a full keymap"
 341                      "a sparse keymap")))
 342                 (t "")))
 343     (princ string)
 344     (with-current-buffer standard-output
 345       (save-excursion
 346         (save-match-data
 347           (if (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 348               (help-xref-button 1 'help-function def)))))
 349     (or file-name
 350         (setq file-name (symbol-file function 'defun)))
 351     (setq file-name (describe-simplify-lib-file-name file-name))
 352     (when (equal file-name "loaddefs.el")
 353       ;; Find the real def site of the preloaded function.
 354       ;; This is necessary only for defaliases.
 355       (let ((location
 356              (condition-case nil
 357                  (find-function-search-for-symbol function nil "loaddefs.el")
 358                (error nil))))
 359         (when location
 360           (with-current-buffer (car location)
 361             (goto-char (cdr location))
 362             (when (re-search-backward
 363                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 364               (setq file-name (match-string 1)))))))
 365     (when (and (null file-name) (subrp def))
 366       ;; Find the C source file name.
 367       (setq file-name (if (get-buffer " *DOC*")
 368                           (help-C-file-name def 'subr)
 369                         'C-source)))
 370     (when file-name
 371       (princ " in `")
 372       ;; We used to add .el to the file name,
 373       ;; but that's completely wrong when the user used load-file.
 374       (princ (if (eq file-name 'C-source) "C source code" file-name))
 375       (princ "'")
 376       ;; Make a hyperlink to the library.
 377       (with-current-buffer standard-output
 378         (save-excursion
 379           (re-search-backward "`\\([^`']+\\)'" nil t)
 380           (help-xref-button 1 'help-function-def function file-name))))
 381     (princ ".")
 382     (terpri)
 383     (when (commandp function)
 384       (let* ((remapped (command-remapping function))
 385              (keys (where-is-internal
 386                     (or remapped function) overriding-local-map nil nil))
 387              non-modified-keys)
 388         ;; Which non-control non-meta keys run this command?
 389         (dolist (key keys)
 390           (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 391               (push key non-modified-keys)))
 392         (when remapped
 393           (princ "It is remapped to `")
 394           (princ (symbol-name remapped))
 395           (princ "'"))
 396
 397         (when keys
 398           (princ (if remapped " which is bound to " "It is bound to "))
 399           ;; FIXME: This list can be very long (f.ex. for self-insert-command).
 400           ;; If there are many, remove them from KEYS.
 401           (if (< (length non-modified-keys) 10)
 402               (princ (mapconcat 'key-description keys ", "))
 403             (dolist (key non-modified-keys)
 404               (setq keys (delq key keys)))
 405             (if keys
 406                 (progn
 407                   (princ (mapconcat 'key-description keys ", "))
 408                   (princ ", and many ordinary text characters"))
 409               (princ "many ordinary text characters"))))
 410         (when (or remapped keys non-modified-keys)
 411           (princ ".")
 412           (terpri))))
 413     (let* ((arglist (help-function-arglist def))
 414            (doc (documentation function))
 415            (usage (help-split-fundoc doc function)))
 416       (with-current-buffer standard-output
 417         ;; If definition is a keymap, skip arglist note.
 418         (unless (keymapp def)
 419           (let* ((use (cond
 420                         (usage (setq doc (cdr usage)) (car usage))
 421                         ((listp arglist)
 422                          (format "%S" (help-make-usage function arglist)))
 423                         ((stringp arglist) arglist)
 424                         ;; Maybe the arglist is in the docstring of the alias.
 425                         ((let ((fun function))
 426                            (while (and (symbolp fun)
 427                                        (setq fun (symbol-function fun))
 428                                        (not (setq usage (help-split-fundoc
 429                                                          (documentation fun)
 430                                                          function)))))
 431                            usage)
 432                          (car usage))
 433                         ((or (stringp def)
 434                              (vectorp def))
 435                          (format "\nMacro: %s" (format-kbd-macro def)))
 436                         (t "[Missing arglist.  Please make a bug report.]")))
 437                  (high (help-highlight-arguments use doc)))
 438             (let ((fill-begin (point)))
 439               (insert (car high) "\n")
 440               (fill-region fill-begin (point)))
 441             (setq doc (cdr high))))
 442         (let ((obsolete (and
 443                          ;; function might be a lambda construct.
 444                          (symbolp function)
 445                          (get function 'byte-obsolete-info))))
 446           (when obsolete
 447             (princ "\nThis function is obsolete")
 448             (when (nth 2 obsolete)
 449               (insert (format " since %s" (nth 2 obsolete))))
 450             (insert ";\n"
 451                     (if (stringp (car obsolete)) (car obsolete)
 452                       (format "use `%s' instead." (car obsolete)))
 453                     "\n"))
 454           (insert "\n"
 455                   (or doc "Not documented.")))))))
 456
 457 \f
 458 ;; Variables
 459
 460 ;;;###autoload
 461 (defun variable-at-point (&optional any-symbol)
 462   "Return the bound variable symbol found around point.
 463 Return 0 if there is no such symbol.
 464 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 465   (or (condition-case ()
 466           (with-syntax-table emacs-lisp-mode-syntax-table
 467             (save-excursion
 468               (or (not (zerop (skip-syntax-backward "_w")))
 469                   (eq (char-syntax (following-char)) ?w)
 470                   (eq (char-syntax (following-char)) ?_)
 471                   (forward-sexp -1))
 472               (skip-chars-forward "'")
 473               (let ((obj (read (current-buffer))))
 474                 (and (symbolp obj) (boundp obj) obj))))
 475         (error nil))
 476       (let* ((str (find-tag-default))
 477              (sym (if str (intern-soft str))))
 478         (if (and sym (or any-symbol (boundp sym)))
 479             sym
 480           (save-match-data
 481             (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 482               (setq sym (intern-soft (match-string 1 str)))
 483               (and (or any-symbol (boundp sym)) sym)))))
 484       0))
 485
 486 ;;;###autoload
 487 (defun describe-variable (variable &optional buffer)
 488   "Display the full documentation of VARIABLE (a symbol).
 489 Returns the documentation as a string, also.
 490 If VARIABLE has a buffer-local value in BUFFER (default to the current buffer),
 491 it is displayed along with the global value."
 492   (interactive
 493    (let ((v (variable-at-point))
 494          (enable-recursive-minibuffers t)
 495          val)
 496      (setq val (completing-read (if (symbolp v)
 497                                     (format
 498                                      "Describe variable (default %s): " v)
 499                                   "Describe variable: ")
 500                                 obarray
 501                                 '(lambda (vv)
 502                                    (or (boundp vv)
 503                                        (get vv 'variable-documentation)))
 504                                 t nil nil
 505                                 (if (symbolp v) (symbol-name v))))
 506      (list (if (equal val "")
 507                v (intern val)))))
 508   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 509   (if (not (symbolp variable))
 510       (message "You did not specify a variable")
 511     (save-excursion
 512       (let* ((valvoid (not (with-current-buffer buffer (boundp variable))))
 513              ;; Extract the value before setting up the output buffer,
 514              ;; in case `buffer' *is* the output buffer.
 515              (val (unless valvoid (buffer-local-value variable buffer)))
 516              val-start-pos)
 517         (help-setup-xref (list #'describe-variable variable buffer)
 518                          (interactive-p))
 519         (with-output-to-temp-buffer (help-buffer)
 520           (with-current-buffer buffer
 521             (prin1 variable)
 522             ;; Make a hyperlink to the library if appropriate.  (Don't
 523             ;; change the format of the buffer's initial line in case
 524             ;; anything expects the current format.)
 525             (let ((file-name (symbol-file variable 'defvar)))
 526               (setq file-name (describe-simplify-lib-file-name file-name))
 527               (when (equal file-name "loaddefs.el")
 528                 ;; Find the real def site of the preloaded variable.
 529                 (let ((location
 530                        (condition-case nil
 531                            (find-variable-noselect variable file-name)
 532                          (error nil))))
 533                   (when location
 534                     (with-current-buffer (car location)
 535                       (goto-char (cdr location))
 536                       (when (re-search-backward
 537                              "^;;; Generated autoloads from \\(.*\\)" nil t)
 538                         (setq file-name (match-string 1)))))))
 539               (when (and (null file-name)
 540                          (integerp (get variable 'variable-documentation)))
 541                 ;; It's a variable not defined in Elisp but in C.
 542                 (setq file-name
 543                       (if (get-buffer " *DOC*")
 544                           (help-C-file-name variable 'var)
 545                         'C-source)))
 546               (if file-name
 547                   (progn
 548                     (princ " is a variable defined in `")
 549                     (princ (if (eq file-name 'C-source) "C source code" file-name))
 550                     (princ "'.\n")
 551                     (with-current-buffer standard-output
 552                       (save-excursion
 553                         (re-search-backward "`\\([^`']+\\)'" nil t)
 554                         (help-xref-button 1 'help-variable-def
 555                                           variable file-name)))
 556                     (if valvoid
 557                         (princ "It is void as a variable.\n")
 558                       (princ "Its ")))
 559                 (if valvoid
 560                     (princ " is void as a variable.\n")
 561                   (princ "'s "))))
 562             (if valvoid
 563                 nil
 564               (with-current-buffer standard-output
 565                 (setq val-start-pos (point))
 566                 (princ "value is ")
 567                 (terpri)
 568                 (let ((from (point)))
 569                   (pp val)
 570                   ;; Hyperlinks in variable's value are quite frequently
 571                   ;; inappropriate e.g C-h v <RET> features <RET>
 572                   ;; (help-xref-on-pp from (point))
 573                   (if (< (point) (+ from 20))
 574                       (delete-region (1- from) from)))))
 575             (terpri)
 576
 577             (when (local-variable-p variable)
 578               (princ (format "%socal in buffer %s; "
 579                              (if (get variable 'permanent-local)
 580                                  "Permanently l" "L")
 581                              (buffer-name)))
 582               (if (not (default-boundp variable))
 583                   (princ "globally void")
 584                 (let ((val (default-value variable)))
 585                   (with-current-buffer standard-output
 586                     (princ "global value is ")
 587                     (terpri)
 588                     ;; Fixme: pp can take an age if you happen to
 589                     ;; ask for a very large expression.  We should
 590                     ;; probably print it raw once and check it's a
 591                     ;; sensible size before prettyprinting.  -- fx
 592                     (let ((from (point)))
 593                       (pp val)
 594                       ;; See previous comment for this function.
 595                       ;; (help-xref-on-pp from (point))
 596                       (if (< (point) (+ from 20))
 597                           (delete-region (1- from) from)))))))
 598             ;; Add a note for variables that have been make-var-buffer-local.
 599             (when (and (local-variable-if-set-p variable)
 600                        (or (not (local-variable-p variable))
 601                            (with-temp-buffer
 602                              (local-variable-if-set-p variable))))
 603               (princ "\nAutomatically becomes buffer-local when set in any fashion.\n"))
 604             (terpri)
 605
 606             ;; If the value is large, move it to the end.
 607             (with-current-buffer standard-output
 608               (when (> (count-lines (point-min) (point-max)) 10)
 609                 ;; Note that setting the syntax table like below
 610                 ;; makes forward-sexp move over a `'s' at the end
 611                 ;; of a symbol.
 612                 (set-syntax-table emacs-lisp-mode-syntax-table)
 613                 (goto-char val-start-pos)
 614                 (delete-region (point) (progn (end-of-line) (point)))
 615                 (save-excursion
 616                   (insert "\n\nValue:")
 617                   (set (make-local-variable 'help-button-cache)
 618                        (point-marker)))
 619                 (insert "value is shown ")
 620                 (insert-button "below"
 621                                'action help-button-cache
 622                                'follow-link t
 623                                'help-echo "mouse-2, RET: show value")
 624                 (insert ".\n\n")))
 625
 626             ;; Mention if it's an alias
 627             (let* ((alias (condition-case nil
 628                              (indirect-variable variable)
 629                            (error variable)))
 630                    (obsolete (get variable 'byte-obsolete-variable))
 631                    (doc (or (documentation-property variable 'variable-documentation)
 632                             (documentation-property alias 'variable-documentation))))
 633               (unless (eq alias variable)
 634                 (princ (format "\nThis variable is an alias for `%s'.\n" alias)))
 635               (when obsolete
 636                 (princ "\nThis variable is obsolete")
 637                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 638                 (princ ";") (terpri)
 639                 (princ (if (stringp (car obsolete)) (car obsolete)
 640                          (format "use `%s' instead." (car obsolete))))
 641                 (terpri))
 642               (princ "Documentation:\n")
 643               (princ (or doc "Not documented as a variable.")))
 644             ;; Make a link to customize if this variable can be customized.
 645             (if (custom-variable-p variable)
 646                 (let ((customize-label "customize"))
 647                   (terpri)
 648                   (terpri)
 649                   (princ (concat "You can " customize-label " this variable."))
 650                   (with-current-buffer standard-output
 651                     (save-excursion
 652                       (re-search-backward
 653                        (concat "\\(" customize-label "\\)") nil t)
 654                       (help-xref-button 1 'help-customize-variable variable)))))
 655             (print-help-return-message)
 656             (save-excursion
 657               (set-buffer standard-output)
 658               ;; Return the text we displayed.
 659               (buffer-string))))))))
 660
 661
 662 ;;;###autoload
 663 (defun describe-syntax (&optional buffer)
 664   "Describe the syntax specifications in the syntax table of BUFFER.
 665 The descriptions are inserted in a help buffer, which is then displayed.
 666 BUFFER defaults to the current buffer."
 667   (interactive)
 668   (setq buffer (or buffer (current-buffer)))
 669   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 670   (with-output-to-temp-buffer (help-buffer)
 671     (let ((table (with-current-buffer buffer (syntax-table))))
 672       (with-current-buffer standard-output
 673         (describe-vector table 'internal-describe-syntax-value)
 674         (while (setq table (char-table-parent table))
 675           (insert "\nThe parent syntax table is:")
 676           (describe-vector table 'internal-describe-syntax-value))))))
 677
 678 (defun help-describe-category-set (value)
 679   (insert (cond
 680            ((null value) "default")
 681            ((char-table-p value) "deeper char-table ...")
 682            (t (condition-case err
 683                   (category-set-mnemonics value)
 684                 (error "invalid"))))))
 685
 686 ;;;###autoload
 687 (defun describe-categories (&optional buffer)
 688   "Describe the category specifications in the current category table.
 689 The descriptions are inserted in a buffer, which is then displayed.
 690 If BUFFER is non-nil, then describe BUFFER's category table instead.
 691 BUFFER should be a buffer or a buffer name."
 692   (interactive)
 693   (setq buffer (or buffer (current-buffer)))
 694   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 695   (with-output-to-temp-buffer (help-buffer)
 696     (let ((table (with-current-buffer buffer (category-table))))
 697       (with-current-buffer standard-output
 698         (describe-vector table 'help-describe-category-set)
 699         (let ((docs (char-table-extra-slot table 0)))
 700           (if (or (not (vectorp docs)) (/= (length docs) 95))
 701               (insert "Invalid first extra slot in this char table\n")
 702             (insert "Meanings of mnemonic characters are:\n")
 703             (dotimes (i 95)
 704               (let ((elt (aref docs i)))
 705                 (when elt
 706                   (insert (+ i ?\s) ": " elt "\n"))))
 707             (while (setq table (char-table-parent table))
 708               (insert "\nThe parent category table is:")
 709               (describe-vector table 'help-describe-category-set))))))))
 710
 711 (provide 'help-fns)
 712
 713 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 714 ;;; help-fns.el ends here