lisp/format-spec.el

   1 ;;; format-spec.el --- functions for formatting arbitrary formatting strings
   2
   3 ;; Copyright (C) 1999-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (defun format-spec (format specification)
  30   "Return a string based on FORMAT and SPECIFICATION.
  31 FORMAT is a string containing `format'-like specs like \"bash %u %k\",
  32 while SPECIFICATION is an alist mapping from format spec characters
  33 to values.  Any text properties on a %-spec itself are propagated to
  34 the text that it generates."
  35   (with-temp-buffer
  36     (insert format)
  37     (goto-char (point-min))
  38     (while (search-forward "%" nil t)
  39       (cond
  40        ;; Quoted percent sign.
  41        ((eq (char-after) ?%)
  42         (delete-char 1))
  43        ;; Valid format spec.
  44        ((looking-at "\\([-0-9.]*\\)\\([a-zA-Z]\\)")
  45         (let* ((num (match-string 1))
  46                (spec (string-to-char (match-string 2)))
  47                (val (cdr (assq spec specification))))
  48           (unless val
  49             (error "Invalid format character: `%%%c'" spec))
  50           ;; Pad result to desired length.
  51           (let ((text (format (concat "%" num "s") val)))
  52             ;; Insert first, to preserve text properties.
  53             (insert-and-inherit text)
  54             ;; Delete the specifier body.
  55             (delete-region (+ (match-beginning 0) (length text))
  56                            (+ (match-end 0) (length text)))
  57             ;; Delete the percent sign.
  58             (delete-region (1- (match-beginning 0)) (match-beginning 0)))))
  59        ;; Signal an error on bogus format strings.
  60        (t
  61         (error "Invalid format string"))))
  62     (buffer-string)))
  63
  64 (defun format-spec-make (&rest pairs)
  65   "Return an alist suitable for use in `format-spec' based on PAIRS.
  66 PAIRS is a list where every other element is a character and a value,
  67 starting with a character."
  68   (let (alist)
  69     (while pairs
  70       (unless (cdr pairs)
  71         (error "Invalid list of pairs"))
  72       (push (cons (car pairs) (cadr pairs)) alist)
  73       (setq pairs (cddr pairs)))
  74     (nreverse alist)))
  75
  76 (provide 'format-spec)
  77
  78 ;;; format-spec.el ends here