lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar comint-prompt-regexp)
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40 \f
  41 ;;; Switching tooltips on/off
  42
  43 ;; We don't set track-mouse globally because this is a big redisplay
  44 ;; problem in buffers having a pre-command-hook or such installed,
  45 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
  46 ;; set-buffer prevents redisplay optimizations, so every mouse motion
  47 ;; would be accompanied by a full redisplay.
  48
  49 (define-minor-mode tooltip-mode
  50   "Toggle Tooltip display.
  51 With ARG, turn tooltip mode on if and only if ARG is positive.
  52 When this minor mode is enabled, Emacs displays help text
  53 in a pop-up window on mouse-over.  When it is disabled,
  54 Emacs displays the help text in the echo area instead."
  55   :global t
  56   :init-value (not (or noninteractive
  57                        emacs-basic-display
  58                        (not (display-graphic-p))
  59                        (not (fboundp 'x-show-tip))))
  60   :initialize 'custom-initialize-safe-default
  61   :group 'tooltip
  62   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
  63     (error "Sorry, tooltips are not yet available on this system"))
  64   (if tooltip-mode
  65       (progn
  66         (add-hook 'pre-command-hook 'tooltip-hide)
  67         (add-hook 'tooltip-hook 'tooltip-help-tips))
  68     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  69       (remove-hook 'pre-command-hook 'tooltip-hide))
  70     (remove-hook 'tooltip-hook 'tooltip-help-tips))
  71   (setq show-help-function
  72         (if tooltip-mode 'tooltip-show-help nil)))
  73
  74 \f
  75 ;;; Customizable settings
  76
  77 (defcustom tooltip-delay 0.7
  78   "Seconds to wait before displaying a tooltip the first time."
  79   :type 'number
  80   :group 'tooltip)
  81
  82 (defcustom tooltip-short-delay 0.1
  83   "Seconds to wait between subsequent tooltips on different items."
  84   :type 'number
  85   :group 'tooltip)
  86
  87 (defcustom tooltip-recent-seconds 1
  88   "Display tooltips if changing tip items within this many seconds.
  89 Do so after `tooltip-short-delay'."
  90   :type 'number
  91   :group 'tooltip)
  92
  93 (defcustom tooltip-hide-delay 10
  94   "Hide tooltips automatically after this many seconds."
  95   :type 'number
  96   :group 'tooltip)
  97
  98 (defcustom tooltip-x-offset 5
  99   "X offset, in pixels, for the display of tooltips.
 100 The offset is the distance between the X position of the mouse and
 101 the left border of the tooltip window.  It must be chosen so that the
 102 tooltip window doesn't contain the mouse when it pops up, or it may
 103 interfere with clicking where you wish.
 104
 105 If `tooltip-frame-parameters' includes the `left' parameter,
 106 the value of `tooltip-x-offset' is ignored."
 107   :type 'integer
 108   :group 'tooltip)
 109
 110 (defcustom tooltip-y-offset +20
 111   "Y offset, in pixels, for the display of tooltips.
 112 The offset is the distance between the Y position of the mouse and
 113 the top border of the tooltip window.  It must be chosen so that the
 114 tooltip window doesn't contain the mouse when it pops up, or it may
 115 interfere with clicking where you wish.
 116
 117 If `tooltip-frame-parameters' includes the `top' parameter,
 118 the value of `tooltip-y-offset' is ignored."
 119   :type 'integer
 120   :group 'tooltip)
 121
 122 (defcustom tooltip-frame-parameters
 123   '((name . "tooltip")
 124     (internal-border-width . 2)
 125     (border-width . 1))
 126   "Frame parameters used for tooltips.
 127
 128 If `left' or `top' parameters are included, they specify the absolute
 129 position to pop up the tooltip."
 130   :type 'sexp
 131   :group 'tooltip)
 132
 133 (defface tooltip
 134   '((((class color))
 135      :background "lightyellow"
 136      :foreground "black"
 137      :inherit variable-pitch)
 138     (t
 139      :inherit variable-pitch))
 140   "Face for tooltips."
 141   :group 'tooltip
 142   :group 'basic-faces)
 143
 144 (defcustom tooltip-use-echo-area nil
 145   "Use the echo area instead of tooltip frames for help and GUD tooltips."
 146   :type 'boolean
 147   :group 'tooltip)
 148
 149 \f
 150 ;;; Variables that are not customizable.
 151
 152 (defvar tooltip-hook nil
 153   "Functions to call to display tooltips.
 154 Each function is called with one argument EVENT which is a copy of
 155 the last mouse movement event that occurred.")
 156
 157 (defvar tooltip-timeout-id nil
 158   "The id of the timeout started when Emacs becomes idle.")
 159
 160 (defvar tooltip-last-mouse-motion-event nil
 161   "A copy of the last mouse motion event seen.")
 162
 163 (defvar tooltip-hide-time nil
 164   "Time when the last tooltip was hidden.")
 165
 166 (defvar gud-tooltip-mode) ;; Prevent warning.
 167
 168 ;;; Event accessors
 169
 170 (defun tooltip-event-buffer (event)
 171   "Return the buffer over which event EVENT occurred.
 172 This might return nil if the event did not occur over a buffer."
 173   (let ((window (posn-window (event-end event))))
 174     (and window (window-buffer window))))
 175
 176 \f
 177 ;;; Timeout for tooltip display
 178
 179 (defun tooltip-delay ()
 180   "Return the delay in seconds for the next tooltip."
 181   (let ((delay tooltip-delay)
 182         (now (float-time)))
 183     (when (and tooltip-hide-time
 184                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 185       (setq delay tooltip-short-delay))
 186     delay))
 187
 188 (defun tooltip-cancel-delayed-tip ()
 189   "Disable the tooltip timeout."
 190   (when tooltip-timeout-id
 191     (disable-timeout tooltip-timeout-id)
 192     (setq tooltip-timeout-id nil)))
 193
 194 (defun tooltip-start-delayed-tip ()
 195   "Add a one-shot timeout to call function `tooltip-timeout'."
 196   (setq tooltip-timeout-id
 197         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 198
 199 (defun tooltip-timeout (object)
 200   "Function called when timer with id `tooltip-timeout-id' fires."
 201   (run-hook-with-args-until-success 'tooltip-hook
 202                                     tooltip-last-mouse-motion-event))
 203
 204 \f
 205 ;;; Displaying tips
 206
 207 (defun tooltip-set-param (alist key value)
 208   "Change the value of KEY in alist ALIST to VALUE.
 209 If there's no association for KEY in ALIST, add one, otherwise
 210 change the existing association.  Value is the resulting alist."
 211   (let ((param (assq key alist)))
 212     (if (consp param)
 213         (setcdr param value)
 214       (push (cons key value) alist))
 215     alist))
 216
 217 (defun tooltip-show (text &optional use-echo-area)
 218   "Show a tooltip window displaying TEXT.
 219
 220 Text larger than `x-max-tooltip-size' is clipped.
 221
 222 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 223 parameters, they determine the x and y position where the tooltip
 224 is displayed.  Otherwise, the tooltip pops at offsets specified by
 225 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 226 position.
 227
 228 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 229 in echo area."
 230   (if use-echo-area
 231       (message "%s" text)
 232     (condition-case error
 233         (let ((params (copy-sequence tooltip-frame-parameters))
 234               (fg (face-attribute 'tooltip :foreground))
 235               (bg (face-attribute 'tooltip :background)))
 236           (when (stringp fg)
 237             (setq params (tooltip-set-param params 'foreground-color fg))
 238             (setq params (tooltip-set-param params 'border-color fg)))
 239           (when (stringp bg)
 240             (setq params (tooltip-set-param params 'background-color bg)))
 241           (x-show-tip (propertize text 'face 'tooltip)
 242                       (selected-frame)
 243                       params
 244                       tooltip-hide-delay
 245                       tooltip-x-offset
 246                       tooltip-y-offset))
 247       (error
 248        (message "Error while displaying tooltip: %s" error)
 249        (sit-for 1)
 250        (message "%s" text)))))
 251
 252 (defun tooltip-hide (&optional ignored-arg)
 253   "Hide a tooltip, if one is displayed.
 254 Value is non-nil if tooltip was open."
 255   (tooltip-cancel-delayed-tip)
 256   (when (x-hide-tip)
 257     (setq tooltip-hide-time (float-time))))
 258
 259 \f
 260 ;;; Debugger-related functions
 261
 262 (defun tooltip-identifier-from-point (point)
 263   "Extract the identifier at POINT, if any.
 264 Value is nil if no identifier exists at point.  Identifier extraction
 265 is based on the current syntax table."
 266   (save-excursion
 267     (goto-char point)
 268     (let ((start (progn (skip-syntax-backward "w_") (point))))
 269       (unless (looking-at "[0-9]")
 270         (skip-syntax-forward "w_")
 271         (when (> (point) start)
 272           (buffer-substring start (point)))))))
 273
 274 (defmacro tooltip-region-active-p ()
 275   "Value is non-nil if the region is currently active."
 276   (if (string-match "^GNU" (emacs-version))
 277       `(and transient-mark-mode mark-active)
 278     `(region-active-p)))
 279
 280 (defun tooltip-expr-to-print (event)
 281   "Return an expression that should be printed for EVENT.
 282 If a region is active and the mouse is inside the region, print
 283 the region.  Otherwise, figure out the identifier around the point
 284 where the mouse is."
 285   (save-excursion
 286     (set-buffer (tooltip-event-buffer event))
 287     (let ((point (posn-point (event-end event))))
 288       (if (tooltip-region-active-p)
 289           (when (and (<= (region-beginning) point) (<= point (region-end)))
 290             (buffer-substring (region-beginning) (region-end)))
 291         (tooltip-identifier-from-point point)))))
 292
 293 (defun tooltip-process-prompt-regexp (process)
 294   "Return regexp matching the prompt of PROCESS at the end of a string.
 295 The prompt is taken from the value of `comint-prompt-regexp' in
 296 the buffer of PROCESS."
 297   (let ((prompt-regexp (save-excursion
 298                          (set-buffer (process-buffer process))
 299                          comint-prompt-regexp)))
 300     ;; Most start with `^' but the one for `sdb' cannot be easily
 301     ;; stripped.  Code the prompt for `sdb' fixed here.
 302     (if (= (aref prompt-regexp 0) ?^)
 303         (setq prompt-regexp (substring prompt-regexp 1))
 304       (setq prompt-regexp "\\*"))
 305     (concat "\n*" prompt-regexp "$")))
 306
 307 (defun tooltip-strip-prompt (process output)
 308   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 309   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 310     (save-match-data
 311       (when (string-match prompt-regexp output)
 312         (setq output (substring output 0 (match-beginning 0)))))
 313     output))
 314
 315 \f
 316 ;;; Tooltip help.
 317
 318 (defvar tooltip-help-message nil
 319   "The last help message received via `tooltip-show-help'.")
 320
 321 (defun tooltip-show-help (msg)
 322   "Function installed as `show-help-function'.
 323 MSG is either a help string to display, or nil to cancel the display."
 324   (let ((previous-help tooltip-help-message))
 325     (setq tooltip-help-message msg)
 326     (cond ((null msg)
 327            ;; Cancel display.  This also cancels a delayed tip, if
 328            ;; there is one.
 329            (tooltip-hide))
 330           ((equal previous-help msg)
 331            ;; Same help as before (but possibly the mouse has moved).
 332            ;; Keep what we have.
 333            )
 334           (t
 335            ;; A different help.  Remove a previous tooltip, and
 336            ;; display a new one, with some delay.
 337            (tooltip-hide)
 338            (tooltip-start-delayed-tip)))))
 339
 340 (defun tooltip-help-tips (event)
 341   "Hook function to display a help tooltip.
 342 This is installed on the hook `tooltip-hook', which is run when
 343 the timer with id `tooltip-timeout-id' fires.
 344 Value is non-nil if this function handled the tip."
 345   (when (stringp tooltip-help-message)
 346     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 347     t))
 348
 349 (provide 'tooltip)
 350
 351 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 352 ;;; tooltip.el ends here