lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: help, internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 (defvar help-map (make-sparse-keymap)
  27   "Keymap for characters following the Help key.")
  28
  29 (define-key global-map (char-to-string help-char) 'help-command)
  30 (fset 'help-command help-map)
  31
  32 (define-key help-map (char-to-string help-char) 'help-for-help)
  33 (define-key help-map "?" 'help-for-help)
  34
  35 (define-key help-map "\C-c" 'describe-copying)
  36 (define-key help-map "\C-d" 'describe-distribution)
  37 (define-key help-map "\C-w" 'describe-no-warranty)
  38 (define-key help-map "a" 'command-apropos)
  39
  40 (define-key help-map "b" 'describe-bindings)
  41
  42 (define-key help-map "c" 'describe-key-briefly)
  43 (define-key help-map "k" 'describe-key)
  44
  45 (define-key help-map "d" 'describe-function)
  46 (define-key help-map "f" 'describe-function)
  47
  48 (define-key help-map "i" 'info)
  49 (define-key help-map "\C-f" 'Info-goto-emacs-command-node)
  50 (define-key help-map "\C-k" 'Info-goto-emacs-key-command-node)
  51
  52 (define-key help-map "l" 'view-lossage)
  53
  54 (define-key help-map "m" 'describe-mode)
  55
  56 (define-key help-map "\C-n" 'view-emacs-news)
  57 (define-key help-map "n" 'view-emacs-news)
  58
  59 (define-key help-map "p" 'finder-by-keyword)
  60 (autoload 'finder-by-keyword "finder.el")
  61
  62 (define-key help-map "s" 'describe-syntax)
  63
  64 (define-key help-map "t" 'help-with-tutorial)
  65
  66 (define-key help-map "w" 'where-is)
  67
  68 (define-key help-map "v" 'describe-variable)
  69
  70 (defun help-with-tutorial ()
  71   "Select the Emacs learn-by-doing tutorial."
  72   (interactive)
  73   (let ((file (expand-file-name "~/TUTORIAL")))
  74     (delete-other-windows)
  75     (if (get-file-buffer file)
  76         (switch-to-buffer (get-file-buffer file))
  77       (switch-to-buffer (create-file-buffer file))
  78       (setq buffer-file-name file)
  79       (setq default-directory (expand-file-name "~/"))
  80       (setq buffer-auto-save-file-name nil)
  81       (insert-file-contents (expand-file-name "TUTORIAL" data-directory))
  82       (goto-char (point-min))
  83       (search-forward "\n<<")
  84       (beginning-of-line)
  85       (delete-region (point) (progn (end-of-line) (point)))
  86       (newline (- (window-height (selected-window))
  87                   (count-lines (point-min) (point))
  88                   6))
  89       (goto-char (point-min))
  90       (set-buffer-modified-p nil))))
  91
  92 (defun describe-key-briefly (key)
  93   "Print the name of the function KEY invokes.  KEY is a string."
  94   (interactive "kDescribe key briefly: ")
  95   (let ((defn (key-binding key)))
  96     (if (or (null defn) (integerp defn))
  97         (message "%s is undefined" (key-description key))
  98       (message "%s runs the command %s"
  99                (key-description key)
 100                (if (symbolp defn) defn (prin1-to-string defn))))))
 101
 102 (defun print-help-return-message (&optional function)
 103   "Display or return message saying how to restore windows after help command.
 104 Computes a message and applies the optional argument FUNCTION to it.
 105 If FUNCTION is nil, applies `message' to it, thus printing it."
 106   (and (not (get-buffer-window standard-output))
 107        (funcall (or function 'message)
 108                 (concat
 109                  (substitute-command-keys
 110                   (if (one-window-p t)
 111                       (if pop-up-windows
 112                           "Type \\[delete-other-windows] to remove help window."
 113                         "Type \\[switch-to-buffer] RET to remove help window.")
 114                     "Type \\[switch-to-buffer-other-window] RET to restore the other window."))
 115                  (substitute-command-keys
 116                   "  \\[scroll-other-window] to scroll the help.")))))
 117
 118 (defun describe-key (key)
 119   "Display documentation of the function invoked by KEY.  KEY is a string."
 120   (interactive "kDescribe key: ")
 121   (let ((defn (key-binding key)))
 122     (if (or (null defn) (integerp defn))
 123         (message "%s is undefined" (key-description key))
 124       (with-output-to-temp-buffer "*Help*"
 125         (prin1 defn)
 126         (princ ":\n")
 127         (if (documentation defn)
 128             (princ (documentation defn))
 129           (princ "not documented"))
 130         (print-help-return-message)))))
 131
 132 (defun describe-mode (&optional minor)
 133   "Display documentation of current major mode.
 134 If optional MINOR is non-nil (or prefix argument is given if interactive),
 135 display documentation of active minor modes as well.
 136 For this to work correctly for a minor mode, the mode's indicator variable
 137 (listed in `minor-mode-alist') must also be a function whose documentation
 138 describes the minor mode."
 139   (interactive)
 140   (with-output-to-temp-buffer "*Help*"
 141     (princ mode-name)
 142     (princ " Mode:\n")
 143     (princ (documentation major-mode))
 144     (let ((minor-modes minor-mode-alist)
 145           (locals (buffer-local-variables)))
 146       (while minor-modes
 147         (let* ((minor-mode (car (car minor-modes)))
 148                (indicator (car (cdr (car minor-modes))))
 149                (local-binding (assq minor-mode locals)))
 150           ;; Document a minor mode if it is listed in minor-mode-alist,
 151           ;; bound locally in this buffer, non-nil, and has a function
 152           ;; definition.
 153           (if (and local-binding
 154                    (cdr local-binding)
 155                    (fboundp minor-mode))
 156               (progn
 157                 (princ (format "\n\n\n%s minor mode (indicator%s):\n"
 158                                minor-mode indicator))
 159                 (princ (documentation minor-mode)))))
 160         (setq minor-modes (cdr minor-modes))))
 161     (print-help-return-message)))
 162
 163 ;; So keyboard macro definitions are documented correctly
 164 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 165
 166 (defun describe-distribution ()
 167   "Display info on how to obtain the latest version of GNU Emacs."
 168   (interactive)
 169   (find-file-read-only
 170    (expand-file-name "DISTRIB" data-directory)))
 171
 172 (defun describe-copying ()
 173   "Display info on how you may redistribute copies of GNU Emacs."
 174   (interactive)
 175   (find-file-read-only
 176    (expand-file-name "COPYING" data-directory))
 177   (goto-char (point-min)))
 178
 179 (defun describe-no-warranty ()
 180   "Display info on all the kinds of warranty Emacs does NOT have."
 181   (interactive)
 182   (describe-copying)
 183   (let (case-fold-search)
 184     (search-forward "NO WARRANTY")
 185     (recenter 0)))
 186
 187 (defun view-emacs-news ()
 188   "Display info on recent changes to Emacs."
 189   (interactive)
 190   (find-file-read-only (expand-file-name "NEWS" data-directory)))
 191
 192 (defun view-lossage ()
 193   "Display last 100 input keystrokes."
 194   (interactive)
 195   (with-output-to-temp-buffer "*Help*"
 196     (princ (key-description (recent-keys)))
 197     (save-excursion
 198       (set-buffer standard-output)
 199       (goto-char (point-min))
 200       (while (progn (move-to-column 50) (not (eobp)))
 201         (search-forward " " nil t)
 202         (insert "\n")))
 203     (print-help-return-message)))
 204
 205 (defun help-for-help ()
 206   "You have typed \\[help-for-help], the help character.  Type a Help option:
 207
 208 A  command-apropos.   Give a substring, and see a list of commands
 209               (functions interactively callable) that contain
 210               that substring.  See also the  apropos  command.
 211 B  describe-bindings.  Display table of all key bindings.
 212 C  describe-key-briefly.  Type a command key sequence;
 213               it prints the function name that sequence runs.
 214 F  describe-function.  Type a function name and get documentation of it.
 215 I  info. The  info  documentation reader.
 216 K  describe-key.  Type a command key sequence;
 217               it displays the full documentation.
 218 L  view-lossage.  Shows last 100 characters you typed.
 219 M  describe-mode.  Print documentation of current major mode,
 220               which describes the commands peculiar to it.
 221 N  view-emacs-news.  Shows emacs news file.
 222 P  finder-by-keyword. Find packages matching a given topic keyword.
 223 S  describe-syntax.  Display contents of syntax table, plus explanations
 224 T  help-with-tutorial.  Select the Emacs learn-by-doing tutorial.
 225 V  describe-variable.  Type name of a variable;
 226               it displays the variable's documentation and value.
 227 W  where-is.  Type command name; it prints which keystrokes
 228               invoke that command.
 229 C-c print Emacs copying permission (General Public License).
 230 C-d print Emacs ordering information.
 231 C-n print news of recent Emacs changes.
 232 C-w print information on absence of warranty for GNU Emacs."
 233   (interactive)
 234   (message (substitute-command-keys
 235  "A B C F I K L M N P S T V W C-c C-d C-n C-w.  Type \\[help-for-help] again for more help: "))
 236   (let ((char (read-char)))
 237     (if (or (= char help-char) (= char ??))
 238         (save-window-excursion
 239           (switch-to-buffer "*Help*")
 240           (delete-other-windows)
 241           (erase-buffer)
 242           (insert (documentation 'help-for-help))
 243           (goto-char (point-min))
 244           (while (memq char (cons help-char '(?? ?\C-v ?\  ?\177 ?\M-v)))
 245             (if (memq char '(?\C-v ?\ ))
 246                 (scroll-up))
 247             (if (memq char '(?\177 ?\M-v))
 248                 (scroll-down))
 249             (message "A B C F I K L M N P S T V W C-c C-d C-n C-w%s: "
 250                      (if (pos-visible-in-window-p (point-max))
 251                          "" " or Space to scroll"))
 252             (let ((cursor-in-echo-area t))
 253               (setq char (read-char))))))
 254     (let ((defn (cdr (assq (downcase char) (cdr help-map)))))
 255       (if defn (call-interactively defn) (ding)))))
 256
 257
 258 ;; Return a function which is called by the list containing point.
 259 ;; If that gives no function, return a function whose name is around point.
 260 ;; If that doesn't give a function, return nil.
 261 (defun function-called-at-point ()
 262   (or (condition-case ()
 263           (save-excursion
 264             (save-restriction
 265               (narrow-to-region (max (point-min) (- (point) 1000)) (point-max))
 266               (backward-up-list 1)
 267               (forward-char 1)
 268               (let (obj)
 269                 (setq obj (read (current-buffer)))
 270                 (and (symbolp obj) (fboundp obj) obj))))
 271         (error nil))
 272       (condition-case ()
 273           (save-excursion
 274             (forward-sexp -1)
 275             (skip-chars-forward "'")
 276             (let ((obj (read (current-buffer))))
 277               (and (symbolp obj) (fboundp obj) obj)))
 278         (error nil))))
 279
 280 (defun describe-function (function)
 281   "Display the full documentation of FUNCTION (a symbol)."
 282   (interactive
 283    (let ((fn (function-called-at-point))
 284          (enable-recursive-minibuffers t)
 285          val)
 286      (setq val (completing-read (if fn
 287                                     (format "Describe function (default %s): " fn)
 288                                   "Describe function: ")
 289                                 obarray 'fboundp t))
 290      (list (if (equal val "")
 291                fn (intern val)))))
 292   (with-output-to-temp-buffer "*Help*"
 293     (prin1 function)
 294     (princ ": ")
 295     (let* ((def (symbol-function function))
 296            (beg (if (commandp def) "an interactive " "a ")))
 297       (princ (cond ((stringp def) "a keyboard macro.")
 298                    ((subrp def)
 299                     (concat beg "built-in function."))
 300                    ((byte-code-function-p def)
 301                     (concat beg "compiled Lisp function."))
 302                    ((symbolp def)
 303                     (format "alias for `%s'." def))
 304                    ((eq (car-safe def) 'lambda)
 305                     (concat beg "Lisp function."))
 306                    ((eq (car-safe def) 'macro)
 307                     "a Lisp macro.")
 308                    ((eq (car-safe def) 'mocklisp)
 309                     "a mocklisp function.")
 310                    ((eq (car-safe def) 'autoload)
 311                     (format "%s autoloaded Lisp %s."
 312                             (if (commandp def) "an interactive" "an")
 313                             (if (nth 4 def) "macro" "function")
 314 ;;; Including the file name made this line too long.
 315 ;;;                         (nth 1 def)
 316                             ))
 317                    (t "")))
 318       (terpri)
 319       (if (documentation function)
 320           (princ (documentation function))
 321         (princ "not documented"))
 322       (cond ((byte-code-function-p def)
 323              (save-excursion
 324                (set-buffer standard-output)
 325                (or (eq (char-after (1- (point-max))) ?\n)
 326                    (terpri)))
 327              (terpri)
 328              (princ (car (append def nil))))
 329             ((eq (car-safe def) 'lambda)
 330              (save-excursion
 331                (set-buffer standard-output)
 332                (or (eq (char-after (1- (point-max))) ?\n)
 333                    (terpri)))
 334              (terpri)
 335              (princ (nth 1 def)))))
 336     (print-help-return-message)
 337     ;; Return the text we displayed.
 338     (save-excursion (set-buffer standard-output) (buffer-string))))
 339
 340 (defun variable-at-point ()
 341   (condition-case ()
 342       (save-excursion
 343         (forward-sexp -1)
 344         (skip-chars-forward "'")
 345         (let ((obj (read (current-buffer))))
 346           (and (symbolp obj) (boundp obj) obj)))
 347     (error nil)))
 348
 349 (defun describe-variable (variable)
 350   "Display the full documentation of VARIABLE (a symbol).
 351 Returns the documentation as a string, also."
 352   (interactive
 353    (let ((v (variable-at-point))
 354          (enable-recursive-minibuffers t)
 355          val)
 356      (setq val (completing-read (if v
 357                                     (format "Describe variable (default %s): " v)
 358                                   "Describe variable: ")
 359                                 obarray 'boundp t))
 360      (list (if (equal val "")
 361                v (intern val)))))
 362   (with-output-to-temp-buffer "*Help*"
 363     (prin1 variable)
 364     (princ "'s value is ")
 365     (if (not (boundp variable))
 366         (princ "void.")
 367       (prin1 (symbol-value variable)))
 368     (terpri) (terpri)
 369     (princ "Documentation:")
 370     (terpri)
 371     (let ((doc (documentation-property variable 'variable-documentation)))
 372       (if doc
 373           (princ (substitute-command-keys doc))
 374         (princ "not documented as a variable.")))
 375     (print-help-return-message)
 376     ;; Return the text we displayed.
 377     (save-excursion (set-buffer standard-output) (buffer-string))))
 378
 379 (defun command-apropos (string)
 380   "Like apropos but lists only symbols that are names of commands
 381 \(interactively callable functions).  Argument REGEXP is a regular expression
 382 that is matched against command symbol names.  Returns list of symbols and
 383 documentation found."
 384   (interactive "sCommand apropos (regexp): ")
 385   (let ((message
 386          (let ((standard-output (get-buffer-create "*Help*")))
 387            (print-help-return-message 'identity))))
 388     (if (apropos string t 'commandp)
 389         (and message (message message)))))
 390
 391 (defun locate-library (library &optional nosuffix)
 392   "Show the full path name of Emacs library LIBRARY.
 393 This command searches the directories in `load-path' like `M-x load-library'
 394 to find the file that `M-x load-library RET LIBRARY RET' would load.
 395 Optional second arg NOSUFFIX non-nil means don't add suffixes `.elc' or `.el'
 396 to the specified name LIBRARY (a la calling `load' instead of `load-library')."
 397   (interactive "sLocate library: ")
 398   (catch 'answer
 399     (mapcar
 400      '(lambda (dir)
 401         (mapcar
 402          '(lambda (suf)
 403             (let ((try (expand-file-name (concat library suf) dir)))
 404               (and (file-readable-p try)
 405                    (null (file-directory-p try))
 406                    (progn
 407                      (message "Library is file %s" try)
 408                      (throw 'answer try)))))
 409          (if nosuffix '("") '(".elc" ".el" ""))))
 410      load-path)
 411     (message "No library %s in search path" library)
 412     nil))
 413
 414 ;;; help.el ends here