lisp/ediff-merg.el

   1 ;;; ediff-merg.el --- merging utilities
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Kifer <kifer@cs.sunysb.edu>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (provide 'ediff-merg)
  29
  30 ;; compiler pacifier
  31 (defvar ediff-window-A)
  32 (defvar ediff-window-B)
  33 (defvar ediff-window-C)
  34 (defvar ediff-merge-window-share)
  35 (defvar ediff-window-config-saved)
  36
  37 (eval-when-compile
  38   (let ((load-path (cons (expand-file-name ".") load-path)))
  39     (or (featurep 'ediff-init)
  40         (load "ediff-init.el" nil nil 'nosuffix))
  41     (or (featurep 'ediff-util)
  42         (load "ediff-util.el" nil nil 'nosuffix))
  43     ))
  44 ;; end pacifier
  45
  46 (require 'ediff-init)
  47
  48 (defcustom ediff-quit-merge-hook 'ediff-maybe-save-and-delete-merge
  49   "*Hooks to run before quitting a merge job.
  50 The most common use is to save and delete the merge buffer."
  51   :type 'hook
  52   :group 'ediff-merge)
  53
  54
  55 (defcustom ediff-default-variant 'combined
  56   "*The variant to be used as a default for buffer C in merging.
  57 Valid values are the symbols `default-A', `default-B', and `combined'."
  58   :type '(radio (const default-A) (const default-B) (const combined))
  59   :group 'ediff-merge)
  60
  61 (defcustom ediff-combination-pattern
  62   '("<<<<<<< variant A" A ">>>>>>> variant B" B  "####### Ancestor" Ancestor "======= end")
  63   "*Pattern to be used for combining difference regions in buffers A and B.
  64 The value must be a list of the form
  65 (STRING1 bufspec1  STRING2 bufspec2 STRING3 bufspec3 STRING4)
  66 where bufspec is the symbol A, B, or Ancestor. For instance, if the value is
  67 '(STRING1 A  STRING2 Ancestor STRING3 B STRING4) then the
  68 combined text will look like this:
  69
  70 STRING1
  71 diff region from variant A
  72 STRING2
  73 diff region from the ancestor
  74 STRING3
  75 diff region from variant B
  76 STRING4
  77 "
  78   :type '(choice (list string symbol string symbol string)
  79                  (list string symbol string symbol string symbol string))
  80   :group 'ediff-merge)
  81
  82 (defcustom ediff-show-clashes-only nil
  83   "*If t, show only those diff regions where both buffers disagree with the ancestor.
  84 This means that regions that have status prefer-A or prefer-B will be
  85 skipped over.  Nil means show all regions."
  86   :type 'boolean
  87   :group 'ediff-merge
  88   )
  89 (make-variable-buffer-local 'ediff-show-clashes-only)
  90
  91 (defcustom ediff-skip-merge-regions-that-differ-from-default nil
  92   "*If t, show only the regions that have not been changed by the user.
  93 A region is considered to have been changed if it is different from the current
  94 default (`default-A', `default-B', `combined') and it hasn't been marked as
  95 `prefer-A' or `prefer-B'.
  96 A region is considered to have been changed also when it is marked as
  97 as `prefer-A', but is different from the corresponding difference region in
  98 Buffer A or if it is marked as `prefer-B' and is different from the region in
  99 Buffer B."
 100   :type 'boolean
 101   :group 'ediff-merge
 102   )
 103 (make-variable-buffer-local 'ediff-skip-merge-regions-that-differ-from-default)
 104
 105 ;; If ediff-show-clashes-only, check if there is no clash between the ancestor
 106 ;; and one of the variants.
 107 (defsubst ediff-merge-region-is-non-clash (n)
 108   (and ediff-show-clashes-only
 109        (string-match "prefer" (or (ediff-get-state-of-merge n) ""))))
 110
 111 ;; If ediff-skip-changed-regions, check if the merge region differs from
 112 ;; the current default. If a region is different from the default, it means
 113 ;; that the user has made determination as to how to merge for this particular
 114 ;; region.
 115 (defsubst ediff-skip-merge-region-if-changed-from-default-p (n)
 116   (and ediff-skip-merge-regions-that-differ-from-default
 117        (ediff-merge-changed-from-default-p n 'prefers-too)))
 118
 119
 120 (defun ediff-get-combined-region (n)
 121   (let ((pattern-list ediff-combination-pattern)
 122         (combo-region "")
 123         (err-msg
 124          "ediff-combination-pattern: Invalid format. Please consult the documentation")
 125         diff-region region-delim region-spec)
 126
 127     (if (< (length pattern-list) 5)
 128         (error err-msg))
 129
 130     (while (> (length pattern-list) 2)
 131       (setq region-delim (nth 0 pattern-list)
 132             region-spec (nth 1 pattern-list))
 133       (or (and (stringp region-delim) (memq region-spec '(A B Ancestor)))
 134           (error err-msg))
 135
 136       (condition-case err
 137           (setq combo-region
 138                 (concat combo-region
 139                         region-delim "\n"
 140                         (ediff-get-region-contents
 141                          n region-spec ediff-control-buffer)))
 142         (error ""))
 143       (setq pattern-list (cdr (cdr pattern-list)))
 144       )
 145
 146     (setq region-delim (nth 0 pattern-list))
 147     (or (stringp region-delim)
 148         (error err-msg))
 149     (setq combo-region (concat combo-region region-delim "\n"))
 150   ))
 151
 152 ;;(defsubst ediff-make-combined-diff (regA regB)
 153 ;;  (concat (nth 0 ediff-combination-pattern) "\n"
 154 ;;        regA
 155 ;;        (nth 1 ediff-combination-pattern) "\n"
 156 ;;        regB
 157 ;;        (nth 2 ediff-combination-pattern) "\n"))
 158
 159 (defsubst ediff-set-state-of-all-diffs-in-all-buffers (ctl-buf)
 160   (let ((n 0))
 161     (while (< n ediff-number-of-differences)
 162       (ediff-set-state-of-diff-in-all-buffers n ctl-buf)
 163       (setq n (1+ n)))))
 164
 165 (defun ediff-set-state-of-diff-in-all-buffers (n ctl-buf)
 166   (let ((regA (ediff-get-region-contents n 'A ctl-buf))
 167         (regB (ediff-get-region-contents n 'B ctl-buf))
 168         (regC (ediff-get-region-contents n 'C ctl-buf)))
 169     (cond ((and (string= regA regB) (string= regA  regC))
 170            (ediff-set-state-of-diff n 'A "=diff(B)")
 171            (ediff-set-state-of-diff n 'B "=diff(C)")
 172            (ediff-set-state-of-diff n 'C "=diff(A)"))
 173           ((string= regA regB)
 174            (ediff-set-state-of-diff n 'A "=diff(B)")
 175            (ediff-set-state-of-diff n 'B "=diff(A)")
 176            (ediff-set-state-of-diff n 'C nil))
 177           ((string= regA regC)
 178            (ediff-set-state-of-diff n 'A "=diff(C)")
 179            (ediff-set-state-of-diff n 'C "=diff(A)")
 180            (ediff-set-state-of-diff n 'B nil))
 181           ((string= regB regC)
 182            (ediff-set-state-of-diff n 'C "=diff(B)")
 183            (ediff-set-state-of-diff n 'B "=diff(C)")
 184            (ediff-set-state-of-diff n 'A nil))
 185           ((string= regC (ediff-get-combined-region n))
 186            (ediff-set-state-of-diff n 'A nil)
 187              (ediff-set-state-of-diff n 'B nil)
 188              (ediff-set-state-of-diff n 'C "=diff(A+B)"))
 189           (t (ediff-set-state-of-diff n 'A nil)
 190              (ediff-set-state-of-diff n 'B nil)
 191              (ediff-set-state-of-diff n 'C nil)))
 192     ))
 193
 194 (defun ediff-set-merge-mode ()
 195   (normal-mode t)
 196   (remove-hook 'local-write-file-hooks 'ediff-set-merge-mode))
 197
 198
 199 ;; Go over all diffs starting with DIFF-NUM and copy regions into buffer C
 200 ;; according to the state of the difference.
 201 ;; Since ediff-copy-diff refuses to copy identical diff regions, there is
 202 ;; no need to optimize ediff-do-merge any further.
 203 ;;
 204 ;; If re-merging, change state of merge in all diffs starting with
 205 ;; DIFF-NUM, except those where the state is prefer-* or where it is
 206 ;; `default-*' or `combined' but the buf C region appears to be modified
 207 ;; since last set by default.
 208 (defun ediff-do-merge (diff-num &optional remerging)
 209   (if (< diff-num 0) (setq diff-num 0))
 210   (let ((n diff-num)
 211         ;;(default-state-of-merge (format "%S" ediff-default-variant))
 212         do-not-copy state-of-merge)
 213     (while (< n ediff-number-of-differences)
 214       (setq do-not-copy nil) ; reset after each cycle
 215       (if (= (mod n 10) 0)
 216           (message "%s buffers A & B into C ... region %d of %d"
 217                    (if remerging "Re-merging" "Merging")
 218                    n
 219                    ediff-number-of-differences))
 220
 221       (setq state-of-merge (ediff-get-state-of-merge n))
 222
 223       (if remerging
 224           (let ((reg-A (ediff-get-region-contents n 'A ediff-control-buffer))
 225                 (reg-B (ediff-get-region-contents n 'B ediff-control-buffer))
 226                 (reg-C (ediff-get-region-contents n 'C ediff-control-buffer)))
 227
 228             ;; if region was edited since it was first set by default
 229             (if (or (ediff-merge-changed-from-default-p n)
 230                     ;; was preferred
 231                     (string-match "prefer" state-of-merge))
 232                 ;; then ignore
 233                 (setq do-not-copy t))
 234
 235             ;; change state of merge for this diff, if necessary
 236             (if (and (string-match "\\(default\\|combined\\)" state-of-merge)
 237                      (not do-not-copy))
 238                 (ediff-set-state-of-merge
 239                  n (format "%S" ediff-default-variant)))
 240             ))
 241
 242       ;; state-of-merge may have changed via ediff-set-state-of-merge, so
 243       ;; check it once again
 244       (setq state-of-merge (ediff-get-state-of-merge n))
 245
 246       (or do-not-copy
 247           (if (string= state-of-merge "combined")
 248               ;; use n+1 because ediff-combine-diffs works via user numbering
 249               ;; of diffs, which is 1+ to what ediff uses internally
 250               (ediff-combine-diffs (1+ n) 'batch)
 251             (ediff-copy-diff
 252              n (if (string-match "-A" state-of-merge) 'A 'B) 'C 'batch)))
 253       (setq n (1+ n)))
 254     (message "Merging buffers A & B into C ... Done")
 255     ))
 256
 257
 258 (defun ediff-re-merge ()
 259   "Remerge unmodified diff regions using a new default.  Start with the current region."
 260   (interactive)
 261   (let* ((default-variant-alist
 262            (list '("default-A") '("default-B") '("combined")))
 263          (actual-alist
 264           (delete (list (symbol-name ediff-default-variant))
 265                   default-variant-alist)))
 266     (setq ediff-default-variant
 267           (intern
 268            (completing-read
 269             (format "Current merge default is `%S'.  New default: "
 270                     ediff-default-variant)
 271             actual-alist nil 'must-match)))
 272     (ediff-do-merge ediff-current-difference 'remerge)
 273     (ediff-recenter)
 274   ))
 275
 276 (defun ediff-shrink-window-C (arg)
 277   "Shrink window C to just one line.
 278 With a prefix argument, returns window C to its normal size.
 279 Used only for merging jobs."
 280   (interactive "P")
 281   (if (not ediff-merge-job)
 282       (error "ediff-shrink-window-C can be used only for merging jobs"))
 283   (cond ((eq arg '-) (setq arg -1))
 284         ((not (numberp arg)) (setq arg nil)))
 285   (cond ((null arg)
 286          (let ((ediff-merge-window-share
 287                 (if (< (window-height ediff-window-C) 3)
 288                     ediff-merge-window-share 0)))
 289            (setq ediff-window-config-saved "") ; force redisplay
 290            (ediff-recenter 'no-rehighlight)))
 291         ((and (< arg 0) (> (window-height ediff-window-C) 2))
 292          (setq ediff-merge-window-share (* ediff-merge-window-share 0.9))
 293          (setq ediff-window-config-saved "") ; force redisplay
 294          (ediff-recenter 'no-rehighlight))
 295         ((and (> arg 0) (> (window-height ediff-window-A) 2))
 296          (setq ediff-merge-window-share (* ediff-merge-window-share 1.1))
 297          (setq ediff-window-config-saved "") ; force redisplay
 298          (ediff-recenter 'no-rehighlight))))
 299
 300
 301 ;; N here is the user's region number.  It is 1+ what Ediff uses internally.
 302 (defun ediff-combine-diffs (n &optional batch-invocation)
 303   "Combine Nth diff regions of buffers A and B and place the combination in C.
 304 N is a prefix argument.  If nil, combine the current difference regions.
 305 Combining is done according to the specifications in variable
 306 `ediff-combination-pattern'."
 307   (interactive "P")
 308   (setq n (if (numberp n) (1- n) ediff-current-difference))
 309
 310   (let (regA regB reg-combined)
 311     ;;(setq regA (ediff-get-region-contents n 'A ediff-control-buffer)
 312     ;;    regB (ediff-get-region-contents n 'B ediff-control-buffer))
 313     ;;(setq reg-combined (ediff-make-combined-diff regA regB))
 314     (setq reg-combined (ediff-get-combined-region n))
 315
 316     (ediff-copy-diff n nil 'C batch-invocation reg-combined))
 317     (or batch-invocation (ediff-jump-to-difference (1+ n))))
 318
 319
 320 ;; Checks if the region in buff C looks like a combination of the regions
 321 ;; in buffers A and B.  Return a list (reg-a-beg reg-a-end reg-b-beg reg-b-end)
 322 ;; These refer to where the delimiters for region A, B, Ancestor start and end
 323 ;; in buffer C
 324 (defun ediff-looks-like-combined-merge (region-num)
 325   (if ediff-merge-job
 326       (let ((combined (string-match (regexp-quote "(A+B)")
 327                                     (or (ediff-get-state-of-diff region-num 'C)
 328                                         "")))
 329             (mrgreg-beg (ediff-get-diff-posn 'C 'beg region-num))
 330             (mrgreg-end (ediff-get-diff-posn 'C 'end region-num))
 331             (pattern-list ediff-combination-pattern)
 332             delim reg-beg reg-end delim-regs-list)
 333
 334         (if combined
 335             (ediff-with-current-buffer ediff-buffer-C
 336               (while pattern-list
 337                 (goto-char mrgreg-beg)
 338                 (setq delim (nth 0 pattern-list))
 339                 (search-forward delim mrgreg-end 'noerror)
 340                 (setq reg-beg (match-beginning 0))
 341                 (setq reg-end (match-end 0))
 342                 (if (and reg-beg reg-end)
 343                     (setq delim-regs-list
 344                           ;; in reverse
 345                           (cons reg-end (cons reg-beg delim-regs-list))))
 346                 (if (> (length pattern-list) 1)
 347                     (setq pattern-list (cdr (cdr pattern-list)))
 348                   (setq pattern-list nil))
 349                 )))
 350
 351         (reverse delim-regs-list)
 352         )))
 353
 354 (eval-when-compile (defvar state-of-merge)) ; dynamic var
 355
 356 ;; Check if the non-preferred merge has been modified since originally set.
 357 ;; This affects only the regions that are marked as default-A/B or combined.
 358 ;; If PREFERS-TOO is non-nil, then look at the regions marked as prefers-A/B as
 359 ;; well.
 360 (defun ediff-merge-changed-from-default-p (diff-num &optional prefers-too)
 361   (let ((reg-A (ediff-get-region-contents diff-num 'A ediff-control-buffer))
 362         (reg-B (ediff-get-region-contents diff-num 'B ediff-control-buffer))
 363         (reg-C (ediff-get-region-contents diff-num 'C ediff-control-buffer)))
 364
 365     (setq state-of-merge (ediff-get-state-of-merge diff-num))
 366
 367     ;; if region was edited since it was first set by default
 368     (or (and (string= state-of-merge "default-A")
 369              (not (string= reg-A reg-C)))
 370         (and (string= state-of-merge "default-B")
 371              (not (string= reg-B reg-C)))
 372         (and (string= state-of-merge "combined")
 373              ;;(not (string= (ediff-make-combined-diff reg-A reg-B) reg-C)))
 374              (not (string= (ediff-get-combined-region diff-num) reg-C)))
 375         (and prefers-too
 376              (string= state-of-merge "prefer-A")
 377              (not (string= reg-A reg-C)))
 378         (and prefers-too
 379              (string= state-of-merge "prefer-B")
 380              (not (string= reg-B reg-C)))
 381         )))
 382
 383
 384 ;;; Local Variables:
 385 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
 386 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
 387 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
 388 ;;; End:
 389
 390 ;;; ediff-merg.el ends here