lisp/ebuff-menu.el

   1 ;;; ebuff-menu.el --- electric-buffer-list mode
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Richard Mlynarik <mly@ai.mit.edu>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Who says one can't have typeout windows in GNU Emacs?   The entry
  26 ;; point, `electric-buffer-list' works like ^r select buffer from the
  27 ;; ITS Emacs lunar or tmacs libraries.
  28
  29 ;;; Code:
  30
  31 (require 'electric)
  32
  33 ;; this depends on the format of list-buffers (from src/buffer.c) and
  34 ;; on stuff in lisp/buff-menu.el
  35
  36 (defvar electric-buffer-menu-mode-map nil)
  37
  38 ;;;###autoload
  39 (defun electric-buffer-list (arg)
  40   "Pops up a buffer describing the set of Emacs buffers.
  41 Vaguely like ITS lunar select buffer; combining typeoutoid buffer
  42 listing with menuoid buffer selection.
  43
  44 If the very next character typed is a space then the buffer list
  45 window disappears.  Otherwise, one may move around in the buffer list
  46 window, marking buffers to be selected, saved or deleted.
  47
  48 To exit and select a new buffer, type a space when the cursor is on
  49 the appropriate line of the buffer-list window.  Other commands are
  50 much like those of buffer-menu-mode.
  51
  52 Calls value of `electric-buffer-menu-mode-hook' on entry if non-nil.
  53
  54 \\{electric-buffer-menu-mode-map}"
  55   (interactive "P")
  56   (let (select buffer)
  57     (save-window-excursion
  58       (save-window-excursion (list-buffers arg))
  59       (setq buffer (window-buffer (Electric-pop-up-window "*Buffer List*")))
  60       (unwind-protect
  61           (progn
  62             (set-buffer buffer)
  63             (Electric-buffer-menu-mode)
  64             (setq select
  65                   (catch 'electric-buffer-menu-select
  66                     (message "<<< Press Return to bury the buffer list >>>")
  67                     (if (eq (setq unread-command-events (list (read-event)))
  68                             ?\ )
  69                         (progn (setq unread-command-events nil)
  70                                (throw 'electric-buffer-menu-select nil)))
  71                     (let ((first (progn (goto-char (point-min))
  72                                         (forward-line 2)
  73                                         (point)))
  74                           (last (progn (goto-char (point-max))
  75                                        (forward-line -1)
  76                                        (point)))
  77                           (goal-column 0))
  78                       (goto-char first)
  79                       (Electric-command-loop 'electric-buffer-menu-select
  80                                              nil
  81                                              t
  82                                              'electric-buffer-menu-looper
  83                                              (cons first last))))))
  84         (set-buffer buffer)
  85         (Buffer-menu-mode)
  86         (bury-buffer buffer)
  87         (message "")))
  88     (if select
  89         (progn (set-buffer buffer)
  90                (let ((opoint (point-marker)))
  91                  (Buffer-menu-execute)
  92                  (goto-char (point-min))
  93                  (if (prog1 (search-forward "\n>" nil t)
  94                        (goto-char opoint) (set-marker opoint nil))
  95                      (Buffer-menu-select)
  96                      (switch-to-buffer (Buffer-menu-buffer t))))))))
  97
  98 (defun electric-buffer-menu-looper (state condition)
  99   (cond ((and condition
 100               (not (memq (car condition) '(buffer-read-only
 101                                            end-of-buffer
 102                                            beginning-of-buffer))))
 103          (signal (car condition) (cdr condition)))
 104         ((< (point) (car state))
 105          (goto-char (point-min))
 106          (forward-line 2))
 107         ((> (point) (cdr state))
 108          (goto-char (point-max))
 109          (forward-line -1)
 110          (if (pos-visible-in-window-p (point-max))
 111              (recenter -1)))))
 112
 113 (put 'Electric-buffer-menu-mode 'mode-class 'special)
 114 (defun Electric-buffer-menu-mode ()
 115   "Major mode for editing a list of buffers.
 116 Each line describes one of the buffers in Emacs.
 117 Letters do not insert themselves; instead, they are commands.
 118 \\<electric-buffer-menu-mode-map>
 119 \\[keyboard-quit] or \\[Electric-buffer-menu-quit] -- exit buffer menu, returning to previous window and buffer
 120   configuration.  If the very first character typed is a space, it
 121   also has this effect.
 122 \\[Electric-buffer-menu-select] -- select buffer of line point is on.
 123   Also show buffers marked with m in other windows,
 124   deletes buffers marked with \"D\", and saves those marked with \"S\".
 125 \\[Buffer-menu-mark] -- mark buffer to be displayed.
 126 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 127 \\[Buffer-menu-save] -- mark that buffer to be saved.
 128 \\[Buffer-menu-delete] or \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted.
 129 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 130 \\[Electric-buffer-menu-mode-view-buffer] -- view buffer, returning when done.
 131 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 132
 133 \\{electric-buffer-menu-mode-map}
 134
 135 Entry to this mode via command electric-buffer-list calls the value of
 136 electric-buffer-menu-mode-hook if it is non-nil."
 137   (kill-all-local-variables)
 138   (use-local-map electric-buffer-menu-mode-map)
 139   (setq mode-name "Electric Buffer Menu")
 140   (setq mode-line-buffer-identification "Electric Buffer List")
 141   (make-local-variable 'Helper-return-blurb)
 142   (setq Helper-return-blurb "return to buffer editing")
 143   (setq truncate-lines t)
 144   (setq buffer-read-only t)
 145   (setq major-mode 'Electric-buffer-menu-mode)
 146   (goto-char (point-min))
 147   (if (search-forward "\n." nil t) (forward-char -1))
 148   (run-hooks 'electric-buffer-menu-mode-hook))
 149
 150 ;; generally the same as Buffer-menu-mode-map
 151 ;;  (except we don't indirect to global-map)
 152 (put 'Electric-buffer-menu-undefined 'suppress-keymap t)
 153 (if electric-buffer-menu-mode-map
 154     nil
 155   (let ((map (make-keymap)) (submap (make-keymap)))
 156     (fillarray (car (cdr map)) 'Electric-buffer-menu-undefined)
 157     (define-key map "\e" submap)
 158     (fillarray (car (cdr submap)) 'Electric-buffer-menu-undefined)
 159     (define-key map "\C-z" 'suspend-emacs)
 160     (define-key map "v" 'Electric-buffer-menu-mode-view-buffer)
 161     (define-key map (char-to-string help-char) 'Helper-help)
 162     (define-key map "?" 'Helper-describe-bindings)
 163     (define-key map "\C-c" nil)
 164     (define-key map "\C-c\C-c" 'Electric-buffer-menu-quit)
 165     (define-key map "\C-]" 'Electric-buffer-menu-quit)
 166     (define-key map "q" 'Electric-buffer-menu-quit)
 167     (define-key map " " 'Electric-buffer-menu-select)
 168     (define-key map "\C-m" 'Electric-buffer-menu-select)
 169     (define-key map "\C-l" 'recenter)
 170     (define-key map "s" 'Buffer-menu-save)
 171     (define-key map "d" 'Buffer-menu-delete)
 172     (define-key map "k" 'Buffer-menu-delete)
 173     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
 174     ;(define-key map "\C-k" 'Buffer-menu-delete)
 175     (define-key map "\177" 'Buffer-menu-backup-unmark)
 176     (define-key map "~" 'Buffer-menu-not-modified)
 177     (define-key map "u" 'Buffer-menu-unmark)
 178     (let ((i ?0))
 179       (while (<= i ?9)
 180         (define-key map (char-to-string i) 'digit-argument)
 181         (define-key map (concat "\e" (char-to-string i)) 'digit-argument)
 182         (setq i (1+ i))))
 183     (define-key map "-" 'negative-argument)
 184     (define-key map "\e-" 'negative-argument)
 185     (define-key map "m" 'Buffer-menu-mark)
 186     (define-key map "\C-u" 'universal-argument)
 187     (define-key map "\C-p" 'previous-line)
 188     (define-key map "\C-n" 'next-line)
 189     (define-key map "p" 'previous-line)
 190     (define-key map "n" 'next-line)
 191     (define-key map "\C-v" 'scroll-up)
 192     (define-key map "\ev" 'scroll-down)
 193     (define-key map ">" 'scroll-right)
 194     (define-key map "<" 'scroll-left)
 195     (define-key map "\e\C-v" 'scroll-other-window)
 196     (define-key map "\e>" 'end-of-buffer)
 197     (define-key map "\e<" 'beginning-of-buffer)
 198     (define-key map "\e\e\e" 'Electric-buffer-menu-quit)
 199     (define-key map [escape escape escape] 'Electric-buffer-menu-quit)
 200     (define-key map [mouse-2] 'Electric-buffer-menu-mouse-select)
 201     (setq electric-buffer-menu-mode-map map)))
 202
 203 (defun Electric-buffer-menu-exit ()
 204   (interactive)
 205   (setq unread-command-events (listify-key-sequence (this-command-keys)))
 206   ;; for robustness
 207   (condition-case ()
 208       (throw 'electric-buffer-menu-select nil)
 209     (error (Buffer-menu-mode)
 210            (other-buffer))))
 211
 212 (defun Electric-buffer-menu-select ()
 213   "Leave Electric Buffer Menu, selecting buffers and executing changes.
 214 Saves buffers marked \"S\".  Deletes buffers marked \"K\".
 215 Selects buffer at point and displays buffers marked \">\" in other windows."
 216   (interactive)
 217   (throw 'electric-buffer-menu-select (point)))
 218
 219 (defun Electric-buffer-menu-mouse-select (event)
 220   (interactive "e")
 221   (select-window (posn-window (event-end event)))
 222   (set-buffer (window-buffer (selected-window)))
 223   (goto-char (posn-point (event-end event)))
 224   (throw 'electric-buffer-menu-select (point)))
 225
 226 (defun Electric-buffer-menu-quit ()
 227   "Leave Electric Buffer Menu, restoring previous window configuration.
 228 Does not execute select, save, or delete commands."
 229   (interactive)
 230   (throw 'electric-buffer-menu-select nil))
 231
 232 (defun Electric-buffer-menu-undefined ()
 233   (interactive)
 234   (ding)
 235   (message (if (and (eq (key-binding "\C-c\C-c") 'Electric-buffer-menu-quit)
 236                     (eq (key-binding " ") 'Electric-buffer-menu-select)
 237                     (eq (key-binding (char-to-string help-char)) 'Helper-help)
 238                     (eq (key-binding "?") 'Helper-describe-bindings))
 239                (substitute-command-keys "Type C-c C-c to exit, Space to select, \\[Helper-help] for help, ? for commands")
 240              (substitute-command-keys "\
 241 Type \\[Electric-buffer-menu-quit] to exit, \
 242 \\[Electric-buffer-menu-select] to select, \
 243 \\[Helper-help] for help, \\[Helper-describe-bindings] for commands.")))
 244   (sit-for 4))
 245
 246 (defun Electric-buffer-menu-mode-view-buffer ()
 247   "View buffer on current line in Electric Buffer Menu.
 248 Returns to Electric Buffer Menu when done."
 249   (interactive)
 250   (let ((bufnam (Buffer-menu-buffer nil)))
 251     (if bufnam
 252         (view-buffer bufnam)
 253       (ding)
 254       (message "Buffer %s does not exist!" bufnam)
 255       (sit-for 4))))
 256
 257 ;;; ebuff-menu.el ends here