lisp/calendar/cal-iso.el

   1 ;;; cal-iso.el --- calendar functions for the ISO calendar
   2
   3 ;; Copyright (C) 1995, 1997, 2001-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   7 ;; Keywords: calendar
   8 ;; Human-Keywords: ISO calendar, calendar, diary
   9 ;; Package: calendar
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; See calendar.el.
  29
  30 ;;; Code:
  31
  32 (require 'calendar)
  33
  34 (defun calendar-iso-to-absolute (date)
  35   "The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
  36 The `ISO year' corresponds approximately to the Gregorian year, but
  37 weeks start on Monday and end on Sunday.  The first week of the ISO year is
  38 the first such week in which at least 4 days are in a year.  The ISO
  39 commercial DATE has the form (week day year) in which week is in the range
  40 1..52 and day is in the range 0..6 (1 = Monday, 2 = Tuesday, ..., 0 =
  41 Sunday).  The Gregorian date Sunday, December 31, 1 BC is imaginary."
  42   (let ((day (calendar-extract-day date)))
  43     (+ (calendar-dayname-on-or-before
  44         1 (+ 3 (calendar-absolute-from-gregorian
  45                 (list 1 1 (calendar-extract-year date)))))
  46        ;; ISO date is (week day year); normally (month day year).
  47        (* 7 (1- (calendar-extract-month date)))
  48        (if (zerop day) 6 (1- day)))))
  49
  50 (define-obsolete-function-alias 'calendar-absolute-from-iso
  51   'calendar-iso-to-absolute "23.1")
  52
  53 ;;;###cal-autoload
  54 (defun calendar-iso-from-absolute (date)
  55   "Compute the `ISO commercial date' corresponding to the absolute DATE.
  56 The ISO year corresponds approximately to the Gregorian year, but weeks
  57 start on Monday and end on Sunday.  The first week of the ISO year is the
  58 first such week in which at least 4 days are in a year.  The ISO commercial
  59 date has the form (week day year) in which week is in the range 1..52 and
  60 day is in the range 0..6 (1 = Monday, 2 = Tuesday, ..., 0 = Sunday).  The
  61 absolute date is the number of days elapsed since the (imaginary) Gregorian
  62 date Sunday, December 31, 1 BC."
  63   (let* ((approx (calendar-extract-year
  64                   (calendar-gregorian-from-absolute (- date 3))))
  65          (year (+ approx
  66                   (calendar-sum y approx
  67                                 (>= date (calendar-iso-to-absolute
  68                                           (list 1 1 (1+ y))))
  69                                 1))))
  70     (list
  71      (1+ (/ (- date (calendar-iso-to-absolute (list 1 1 year))) 7))
  72      (% date 7)
  73      year)))
  74
  75 ;;;###cal-autoload
  76 (defun calendar-iso-date-string (&optional date)
  77   "String of ISO date of Gregorian DATE, default today."
  78   (let* ((d (calendar-absolute-from-gregorian
  79              (or date (calendar-current-date))))
  80          (day (% d 7))
  81          (iso-date (calendar-iso-from-absolute d)))
  82     (format "Day %s of week %d of %d"
  83             (if (zerop day) 7 day)
  84             (calendar-extract-month iso-date)
  85             (calendar-extract-year iso-date))))
  86
  87 ;;;###cal-autoload
  88 (defun calendar-iso-print-date ()
  89   "Show equivalent ISO date for the date under the cursor."
  90   (interactive)
  91   (message "ISO date: %s"
  92            (calendar-iso-date-string (calendar-cursor-to-date t))))
  93
  94 (define-obsolete-function-alias 'calendar-print-iso-date
  95   'calendar-iso-print-date "23.1")
  96
  97 (defun calendar-iso-read-date (&optional dayflag)
  98   "Interactively read the arguments for an ISO date command.
  99 Reads a year and week, and if DAYFLAG is non-nil a day (otherwise
 100 taken to be 1)."
 101   (let* ((year (calendar-read
 102                 "ISO calendar year (>0): "
 103                 (lambda (x) (> x 0))
 104                 (number-to-string (calendar-extract-year
 105                                 (calendar-current-date)))))
 106          (no-weeks (calendar-extract-month
 107                     (calendar-iso-from-absolute
 108                      (1-
 109                       (calendar-dayname-on-or-before
 110                        1 (calendar-absolute-from-gregorian
 111                           (list 1 4 (1+ year))))))))
 112          (week (calendar-read
 113                 (format "ISO calendar week (1-%d): " no-weeks)
 114                 (lambda (x) (and (> x 0) (<= x no-weeks)))))
 115          (day (if dayflag (calendar-read
 116                            "ISO day (1-7): "
 117                            (lambda (x) (and (<= 1 x) (<= x 7))))
 118                 1)))
 119     (list (list week day year))))
 120
 121 (define-obsolete-function-alias 'calendar-iso-read-args
 122   'calendar-iso-read-date "23.1")
 123
 124 ;;;###cal-autoload
 125 (defun calendar-iso-goto-date (date &optional noecho)
 126   "Move cursor to ISO DATE; echo ISO date unless NOECHO is non-nil."
 127   (interactive (calendar-iso-read-date t))
 128   (calendar-goto-date (calendar-gregorian-from-absolute
 129                        (calendar-iso-to-absolute date)))
 130   (or noecho (calendar-iso-print-date)))
 131
 132 (define-obsolete-function-alias 'calendar-goto-iso-date
 133   'calendar-iso-goto-date "23.1")
 134
 135 ;;;###cal-autoload
 136 (defun calendar-iso-goto-week (date &optional noecho)
 137   "Move cursor to ISO DATE; echo ISO date unless NOECHO is non-nil.
 138 Interactively, goes to the first day of the specified week."
 139   (interactive (calendar-iso-read-date))
 140   (calendar-goto-date (calendar-gregorian-from-absolute
 141                        (calendar-iso-to-absolute date)))
 142   (or noecho (calendar-iso-print-date)))
 143
 144 (define-obsolete-function-alias 'calendar-goto-iso-week
 145   'calendar-iso-goto-week "23.1")
 146
 147 (defvar date)
 148
 149 ;; To be called from diary-list-sexp-entries, where DATE is bound.
 150 ;;;###diary-autoload
 151 (defun diary-iso-date ()
 152   "ISO calendar equivalent of date diary entry."
 153   (format "ISO date: %s" (calendar-iso-date-string date)))
 154
 155 (provide 'cal-iso)
 156
 157 ;;; cal-iso.el ends here