lisp/compare-w.el

   1 ;;; compare-w.el --- compare text between windows for Emacs
   2
   3 ;; Copyright (C) 1986, 1989, 1993, 1997 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package provides one entry point, compare-windows.  It compares
  27 ;; text starting from point in two adjacent windows, advancing point
  28 ;; until it finds a difference.  Option variables permit you to ignore
  29 ;; whitespace differences, or case differences, or both.
  30
  31 ;;; Code:
  32
  33 (defgroup compare-w nil
  34   "Compare text between windows."
  35   :prefix "compare-"
  36   :group 'tools)
  37
  38 (defcustom compare-windows-whitespace "[ \t\n]+"
  39   "*Regexp that defines whitespace sequences for \\[compare-windows].
  40 Changes in whitespace are optionally ignored.
  41
  42 The value of `compare-windows-whitespace' may instead be a function; this
  43 function is called in each buffer, with point at the current scanning point.
  44 The function's job is to categorize any whitespace around (including before)
  45 point; it should also advance past any whitespace.
  46
  47 The function is passed one argument, the point where `compare-windows'
  48 was originally called; it should not consider any text before that point.
  49 If the function returns the same value for both buffers, then the
  50 whitespace is considered to match, and is skipped."
  51   :type '(choice regexp function)
  52   :group 'compare-w)
  53
  54 (defcustom compare-ignore-case nil
  55   "*Non-nil means \\[compare-windows] ignores case differences."
  56   :type 'boolean
  57   :group 'compare-w)
  58
  59 ;;;###autoload
  60 (defun compare-windows (ignore-whitespace)
  61   "Compare text in current window with text in next window.
  62 Compares the text starting at point in each window,
  63 moving over text in each one as far as they match.
  64
  65 This command pushes the mark in each window
  66 at the prior location of point in that window.
  67 If both windows display the same buffer,
  68 the mark is pushed twice in that buffer:
  69 first in the other window, then in the selected window.
  70
  71 A prefix arg means ignore changes in whitespace.
  72 The variable `compare-windows-whitespace' controls how whitespace is skipped.
  73 If `compare-ignore-case' is non-nil, changes in case are also ignored."
  74   (interactive "P")
  75   (let* (p1 p2 maxp1 maxp2 b1 b2 w2
  76             (progress 1)
  77             (opoint1 (point))
  78             opoint2
  79             (skip-func (if ignore-whitespace
  80                          (if (stringp compare-windows-whitespace)
  81                              'compare-windows-skip-whitespace
  82                            compare-windows-whitespace))))
  83     (setq p1 (point) b1 (current-buffer))
  84     (setq w2 (next-window (selected-window)))
  85     (if (eq w2 (selected-window))
  86         (setq w2 (next-window (selected-window) nil 'visible)))
  87     (if (eq w2 (selected-window))
  88         (error "No other window"))
  89     (setq p2 (window-point w2)
  90           b2 (window-buffer w2))
  91     (setq opoint2 p2)
  92     (setq maxp1 (point-max))
  93     (save-excursion
  94       (set-buffer b2)
  95       (push-mark p2 t)
  96       (setq maxp2 (point-max)))
  97     (push-mark)
  98
  99     (while (> progress 0)
 100       ;; If both buffers have whitespace next to point,
 101       ;; optionally skip over it.
 102
 103       (and skip-func
 104            (save-excursion
 105              (let (p1a p2a w1 w2 result1 result2)
 106                (setq result1 (funcall skip-func opoint1))
 107                (setq p1a (point))
 108                (set-buffer b2)
 109                (goto-char p2)
 110                (setq result2 (funcall skip-func opoint2))
 111                (setq p2a (point))
 112                (if (or (stringp compare-windows-whitespace)
 113                        (and result1 result2 (eq result1 result2)))
 114                    (setq p1 p1a
 115                          p2 p2a)))))
 116
 117       (let ((size (min (- maxp1 p1) (- maxp2 p2)))
 118             (case-fold-search compare-ignore-case))
 119         (setq progress (compare-buffer-substrings b2 p2 (+ size p2)
 120                                                   b1 p1 (+ size p1)))
 121         (setq progress (if (zerop progress) size (1- (abs progress))))
 122         (setq p1 (+ p1 progress) p2 (+ p2 progress)))
 123       ;; Advance point now rather than later, in case we're interrupted.
 124       (goto-char p1)
 125       (set-window-point w2 p2))
 126
 127     (if (= (point) opoint1)
 128         (ding))))
 129
 130 ;; Move forward over whatever might be called whitespace.
 131 ;; compare-windows-whitespace is a regexp that matches whitespace.
 132 ;; Match it at various starting points before the original point
 133 ;; and find the latest point at which a match ends.
 134 ;; Don't try starting points before START, though.
 135 ;; Value is non-nil if whitespace is found.
 136
 137 ;; If there is whitespace before point, but none after,
 138 ;; then return t, but don't advance point.
 139 (defun compare-windows-skip-whitespace (start)
 140   (let ((end (point))
 141         (beg (point))
 142         (opoint (point)))
 143     (while (or (and (looking-at compare-windows-whitespace)
 144                     (<= end (match-end 0))
 145                     ;; This match goes past END, so advance END.
 146                     (progn (setq end (match-end 0))
 147                            (> (point) start)))
 148                (and (/= (point) start)
 149                     ;; Consider at least the char before point,
 150                     ;; unless it is also before START.
 151                     (= (point) opoint)))
 152       ;; keep going back until whitespace
 153       ;; doesn't extend to or past end
 154       (forward-char -1))
 155     (setq beg (point))
 156     (goto-char end)
 157     (or (/= beg opoint)
 158         (/= end opoint))))
 159
 160 (provide 'compare-w)
 161
 162 ;;; compare-w.el ends here