lisp/ediff-vers.el

   1 ;;; ediff-vers.el --- version control interface to Ediff
   2
   3 ;;; Copyright (C) 1995, 96, 97, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 ;; Compiler pacifier
  29 (defvar rcs-default-co-switches)
  30 (defvar sc-mode)
  31 (defvar cvs-shell)
  32 (defvar cvs-program)
  33 (defvar cvs-cookie-handle)
  34 (defvar ediff-temp-file-prefix)
  35
  36 (and noninteractive
  37      (eval-when-compile
  38        (let ((load-path (cons (expand-file-name ".") load-path)))
  39          (load "pcl-cvs" 'noerror)
  40          (load "rcs" 'noerror)
  41          ;; On 8+3 MS-DOS filesystems, generic-x.el is loaded
  42          ;; instead of (the missing) generic-sc.el.  Since the
  43          ;; version of Emacs which supports MS-DOS doesn't have
  44          ;; generic-sc, we simply avoid loading it.
  45          (or (and (fboundp 'msdos-long-file-names)
  46                   (not (msdos-long-file-names)))
  47              (load "generic-sc" 'noerror))
  48          ;; (load "vc" 'noerror) ; this sometimes causes compiler error
  49          (or (featurep 'ediff-init)
  50              (load "ediff-init.el" nil nil 'nosuffix))
  51          )))
  52 ;; end pacifier
  53
  54 ;; VC.el support
  55 (defun ediff-vc-internal (rev1 rev2 &optional startup-hooks)
  56 ;; Run Ediff on versions of the current buffer.
  57 ;; If REV2 is "" then compare current buffer with REV1.
  58 ;; If the current buffer is named `F', the version is named `F.~REV~'.
  59 ;; If `F.~REV~' already exists, it is used instead of being re-created.
  60   (let (file1 file2 rev1buf rev2buf)
  61     (save-window-excursion
  62       (save-excursion
  63         (vc-version-other-window rev1)
  64         (setq rev1buf (current-buffer)
  65               file1 (buffer-file-name)))
  66       (save-excursion
  67         (or (string= rev2 "")           ; use current buffer
  68             (vc-version-other-window rev2))
  69         (setq rev2buf (current-buffer)
  70               file2 (buffer-file-name)))
  71       (setq startup-hooks
  72             (cons `(lambda ()
  73                      (delete-file ,file1)
  74                      (or ,(string= rev2 "") (delete-file ,file2)))
  75                   startup-hooks)))
  76     (ediff-buffers
  77      rev1buf rev2buf
  78      startup-hooks
  79      'ediff-revision)))
  80
  81 ;; RCS.el support
  82 (defun rcs-ediff-view-revision (&optional rev)
  83 ;; View previous RCS revision of current file.
  84 ;; With prefix argument, prompts for a revision name.
  85   (interactive (list (if current-prefix-arg
  86                          (read-string "Revision: "))))
  87   (let* ((filename (buffer-file-name (current-buffer)))
  88          (switches (append '("-p")
  89                            (if rev (list (concat "-r" rev)) nil)))
  90          (buff (concat (file-name-nondirectory filename) ".~" rev "~")))
  91     (message "Working ...")
  92     (setq filename (expand-file-name filename))
  93     (with-output-to-temp-buffer buff
  94       (ediff-with-current-buffer standard-output
  95         (fundamental-mode))
  96       (let ((output-buffer (ediff-rcs-get-output-buffer filename buff)))
  97         (delete-windows-on output-buffer)
  98         (save-excursion
  99           (set-buffer output-buffer)
 100           (apply 'call-process "co" nil t nil
 101                  ;; -q: quiet (no diagnostics)
 102                  (append switches rcs-default-co-switches
 103                          (list "-q" filename)))))
 104       (message "")
 105       buff)))
 106
 107 (defun ediff-rcs-get-output-buffer (file name)
 108   ;; Get a buffer for RCS output for FILE, make it writable and clean it up.
 109   ;; Optional NAME is name to use instead of `*RCS-output*'.
 110   ;; This is a modified version from rcs.el v1.1.  I use it here to make
 111   ;; Ediff immune to changes in rcs.el
 112   (let* ((default-major-mode 'fundamental-mode) ; no frills!
 113          (buf (get-buffer-create name)))
 114     (save-excursion
 115       (set-buffer buf)
 116       (setq buffer-read-only nil
 117             default-directory (file-name-directory (expand-file-name file)))
 118       (erase-buffer))
 119     buf))
 120
 121 (defun ediff-rcs-internal (rev1 rev2 &optional startup-hooks)
 122 ;; Run Ediff on versions of the current buffer.
 123 ;; If REV2 is "" then use current buffer.
 124   (let (rev2buf rev1buf)
 125     (save-window-excursion
 126       (setq rev2buf (if (string= rev2 "")
 127                         (current-buffer)
 128                       (rcs-ediff-view-revision rev2))
 129             rev1buf (rcs-ediff-view-revision rev1)))
 130
 131     ;; rcs.el doesn't create temp version files, so we don't have to delete
 132     ;; anything in startup hooks to ediff-buffers
 133     (ediff-buffers rev1buf rev2buf startup-hooks 'ediff-revision)
 134     ))
 135
 136
 137 ;; GENERIC-SC.el support
 138
 139 (defun generic-sc-get-latest-rev ()
 140   (cond ((eq sc-mode 'CCASE)
 141          (eval "main/LATEST"))
 142         (t (eval ""))))
 143
 144 (defun ediff-generic-sc-internal (rev1 rev2 &optional startup-hooks)
 145 ;; Run Ediff on versions of the current buffer.
 146 ;; If REV2 is "" then compare current buffer with REV1.
 147 ;; If the current buffer is named `F', the version is named `F.~REV~'.
 148 ;; If `F.~REV~' already exists, it is used instead of being re-created.
 149   (let (rev1buf rev2buf)
 150     (save-excursion
 151       (if (or (not rev1) (string= rev1 ""))
 152           (setq rev1 (generic-sc-get-latest-rev)))
 153       (sc-visit-previous-revision rev1)
 154       (setq rev1buf (current-buffer)))
 155     (save-excursion
 156       (or (string= rev2 "")             ; use current buffer
 157           (sc-visit-previous-revision rev2))
 158       (setq rev2buf (current-buffer)))
 159     (ediff-buffers rev1buf rev2buf startup-hooks 'ediff-revision)))
 160
 161
 162 ;;; Merge with Version Control
 163
 164 (defun ediff-vc-merge-internal (rev1 rev2 ancestor-rev
 165                                      &optional startup-hooks merge-buffer-file)
 166 ;; If ANCESTOR-REV non-nil, merge with ancestor
 167   (let (buf1 buf2 ancestor-buf)
 168     (save-window-excursion
 169       (save-excursion
 170         (vc-version-other-window rev1)
 171         (setq buf1 (current-buffer)))
 172       (save-excursion
 173         (or (string= rev2 "")
 174             (vc-version-other-window rev2))
 175         (setq buf2 (current-buffer)))
 176       (if ancestor-rev
 177           (save-excursion
 178             (if (string= ancestor-rev "")
 179                 (setq ancestor-rev (vc-workfile-version buffer-file-name)))
 180             (vc-version-other-window ancestor-rev)
 181             (setq ancestor-buf (current-buffer))))
 182       (setq startup-hooks
 183             (cons
 184              `(lambda ()
 185                 (delete-file ,(buffer-file-name buf1))
 186                 (or ,(string= rev2 "")
 187                     (delete-file ,(buffer-file-name buf2)))
 188                 (or ,(string= ancestor-rev "")
 189                     ,(not ancestor-rev)
 190                     (delete-file ,(buffer-file-name ancestor-buf)))
 191                 )
 192              startup-hooks)))
 193     (if ancestor-rev
 194         (ediff-merge-buffers-with-ancestor
 195          buf1 buf2 ancestor-buf
 196          startup-hooks 'ediff-merge-revisions-with-ancestor merge-buffer-file)
 197       (ediff-merge-buffers
 198        buf1 buf2 startup-hooks 'ediff-merge-revisions merge-buffer-file))
 199     ))
 200
 201 (defun ediff-rcs-merge-internal (rev1 rev2 ancestor-rev
 202                                       &optional
 203                                       startup-hooks merge-buffer-file)
 204   ;; If ANCESTOR-REV non-nil, merge with ancestor
 205   (let (buf1 buf2 ancestor-buf)
 206     (save-window-excursion
 207       (setq buf1 (rcs-ediff-view-revision rev1)
 208             buf2 (if (string= rev2 "")
 209                      (current-buffer)
 210                    (rcs-ediff-view-revision rev2))
 211             ancestor-buf (if ancestor-rev
 212                              (if (string= ancestor-rev "")
 213                                  (current-buffer)
 214                                (rcs-ediff-view-revision ancestor-rev)))))
 215     ;; rcs.el doesn't create temp version files, so we don't have to delete
 216     ;; anything in startup hooks to ediff-buffers
 217     (if ancestor-rev
 218         (ediff-merge-buffers-with-ancestor
 219          buf1 buf2 ancestor-buf
 220          startup-hooks 'ediff-merge-revisions-with-ancestor merge-buffer-file)
 221       (ediff-merge-buffers
 222        buf1 buf2 startup-hooks 'ediff-merge-revisions merge-buffer-file))))
 223
 224 (defun ediff-generic-sc-merge-internal (rev1 rev2 ancestor-rev
 225                                              &optional
 226                                              startup-hooks merge-buffer-file)
 227   ;; If ANCESTOR-REV non-nil, merge with ancestor
 228   (let (buf1 buf2 ancestor-buf)
 229     (save-excursion
 230       (if (string= rev1 "")
 231           (setq rev1 (generic-sc-get-latest-rev)))
 232       (sc-visit-previous-revision rev1)
 233       (setq buf1 (current-buffer)))
 234     (save-excursion
 235       (or (string= rev2 "")
 236           (sc-visit-previous-revision rev2))
 237       (setq buf2 (current-buffer)))
 238     (if ancestor-rev
 239         (save-excursion
 240           (or (string= ancestor-rev "")
 241               (sc-visit-previous-revision ancestor-rev))
 242           (setq ancestor-buf (current-buffer))))
 243     (if ancestor-rev
 244         (ediff-merge-buffers-with-ancestor
 245          buf1 buf2 ancestor-buf
 246          startup-hooks 'ediff-merge-revisions-with-ancestor merge-buffer-file)
 247       (ediff-merge-buffers
 248        buf1 buf2 startup-hooks 'ediff-merge-revisions merge-buffer-file))))
 249
 250
 251 ;; PCL-CVS.el support
 252
 253 ;; MK: Check. This function doesn't seem to be used any more by pcvs or pcl-cvs
 254 (defun cvs-run-ediff-on-file-descriptor (tin)
 255 ;; This is a replacement for cvs-emerge-mode
 256 ;; Runs after cvs-update.
 257 ;; Ediff-merge appropriate revisions of the selected file.
 258   (let* ((fileinfo (tin-cookie cvs-cookie-handle tin))
 259          (type (cvs-fileinfo->type fileinfo))
 260          (tmp-file
 261           (cvs-retrieve-revision-to-tmpfile fileinfo))
 262          (default-directory
 263            (file-name-as-directory (cvs-fileinfo->dir fileinfo)))
 264          ancestor-file)
 265
 266     (or (memq type '(MERGED CONFLICT MODIFIED))
 267         (error
 268          "Can only merge `Modified', `Merged' or `Conflict' files"))
 269
 270     (cond ((memq type '(MERGED CONFLICT))
 271            (setq ancestor-file
 272                  (cvs-retrieve-revision-to-tmpfile
 273                   fileinfo
 274                   ;; revision
 275                   (cvs-fileinfo->base-revision fileinfo)))
 276            (ediff-merge-buffers-with-ancestor
 277             (find-file-noselect tmp-file)
 278             (find-file-noselect (cvs-fileinfo->backup-file fileinfo))
 279             (find-file-noselect ancestor-file)
 280             nil ; startup-hooks
 281             'ediff-merge-revisions-with-ancestor))
 282           ((eq type 'MODIFIED)
 283            (ediff-buffers
 284             (find-file-noselect tmp-file)
 285             (find-file-noselect (cvs-fileinfo->full-path fileinfo))
 286             nil ; startup-hooks
 287             'ediff-revisions)))
 288     (if (stringp tmp-file) (delete-file tmp-file))
 289     (if (stringp ancestor-file) (delete-file ancestor-file))))
 290
 291 ;;; Local Variables:
 292 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
 293 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
 294 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
 295 ;;; End:
 296
 297 (provide 'ediff-vers)
 298
 299 ;;; ediff-vers.el ends here