lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * working-revision (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       OK
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-revision (file)                          NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-revision (file rev buffer)               OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional revision)          NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (revision)                     OK
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (files)             NEEDED?
  91 ;; - annotate-command (file buf &optional rev)     OK
  92 ;; - annotate-time ()                              OK
  93 ;; - annotate-current-time ()                      NOT NEEDED
  94 ;; - annotate-extract-revision-at-line ()          OK
  95 ;; SNAPSHOT SYSTEM
  96 ;; - create-snapshot (dir name branchp)            OK
  97 ;; - assign-name (file name)                       NOT NEEDED
  98 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
  99 ;; MISCELLANEOUS
 100 ;; - make-version-backups-p (file)                 NOT NEEDED
 101 ;; - repository-hostname (dirname)                 NOT NEEDED
 102 ;; - previous-revision (file rev)                  OK
 103 ;; - next-revision (file rev)                      OK
 104 ;; - check-headers ()                              COULD BE SUPPORTED
 105 ;; - clear-headers ()                              NOT NEEDED
 106 ;; - delete-file (file)                            OK
 107 ;; - rename-file (old new)                         OK
 108 ;; - find-file-hook ()                             NOT NEEDED
 109 ;; - find-file-not-found-hook ()                   NOT NEEDED
 110
 111 (eval-when-compile (require 'cl) (require 'vc))
 112
 113 (defvar git-commits-coding-system 'utf-8
 114   "Default coding system for git commits.")
 115
 116 ;;; BACKEND PROPERTIES
 117
 118 (defun vc-git-revision-granularity ()
 119   'repository)
 120
 121 ;;; STATE-QUERYING FUNCTIONS
 122
 123 ;;;###autoload (defun vc-git-registered (file)
 124 ;;;###autoload   "Return non-nil if FILE is registered with git."
 125 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 126 ;;;###autoload       (progn
 127 ;;;###autoload         (load "vc-git")
 128 ;;;###autoload         (vc-git-registered file))))
 129
 130 (defun vc-git-registered (file)
 131   "Check whether FILE is registered with git."
 132   (when (vc-git-root file)
 133     (with-temp-buffer
 134       (let* ((dir (file-name-directory file))
 135              (name (file-relative-name file dir)))
 136         (and (ignore-errors
 137                (when dir (cd dir))
 138                (vc-git--out-ok "ls-files" "-c" "-z" "--" name))
 139              (let ((str (buffer-string)))
 140                (and (> (length str) (length name))
 141                     (string= (substring str 0 (1+ (length name)))
 142                              (concat name "\0")))))))))
 143
 144 (defun vc-git--state-code (code)
 145   "Convert from a string to a added/deleted/modified state."
 146   (case (string-to-char code)
 147     (?M 'edited)
 148     (?A 'added)
 149     (?D 'removed)
 150     (?U 'edited)     ;; FIXME
 151     (?T 'edited)))   ;; FIXME
 152
 153 (defun vc-git-state (file)
 154   "Git-specific version of `vc-state'."
 155   ;; FIXME: This can't set 'ignored yet
 156   (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 157   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 158     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0"
 159                                 diff))
 160         (vc-git--state-code (match-string 1 diff))
 161       (if (vc-git--empty-db-p) 'added 'up-to-date))))
 162
 163 (defun vc-git--ls-files-state (state &rest args)
 164   "Set state to STATE on all files found with git-ls-files ARGS."
 165   (with-temp-buffer
 166     (apply 'vc-git-command (current-buffer) nil nil "ls-files" "-z" args)
 167     (goto-char (point-min))
 168     (let ((start (point)))
 169       (while (search-forward "\0" nil t)
 170         (let ((file (expand-file-name
 171                      (buffer-substring-no-properties start (1- (point))))))
 172           (vc-file-setprop file 'vc-backend (if state 'Git 'none))
 173           (vc-file-setprop file 'vc-state state))
 174         (setq start (point))))))
 175
 176 (defun vc-git-dir-state (dir)
 177   "Git-specific version of `dir-state'."
 178   (vc-git--ls-files-state 'up-to-date "-c")
 179   (vc-git--ls-files-state 'edited "-m")
 180   (vc-git--ls-files-state 'removed "-d")
 181   (vc-git--ls-files-state 'ignored "-o" "-i" "--exclude-standard")
 182   (vc-git--ls-files-state nil "-o" "--exclude-standard"))
 183
 184 (defun vc-git-working-revision (file)
 185   "Git-specific version of `vc-working-revision'."
 186   (let ((str (with-output-to-string
 187                (with-current-buffer standard-output
 188                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 189     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 190         (match-string 2 str)
 191       str)))
 192
 193 (defun vc-git-checkout-model (file)
 194   'implicit)
 195
 196 (defun vc-git-workfile-unchanged-p (file)
 197   (eq 'up-to-date (vc-git-state file)))
 198
 199 (defun vc-git-mode-line-string (file)
 200   "Return string for placement into the modeline for FILE."
 201   (let* ((branch (vc-git-working-revision file))
 202          (def-ml (vc-default-mode-line-string 'Git file))
 203          (help-echo (get-text-property 0 'help-echo def-ml)))
 204     (if (zerop (length branch))
 205         (propertize
 206          (concat def-ml "!")
 207          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 208       (propertize def-ml
 209                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 210
 211 ;; Variable used to keep the intermediate results for vc-git-status.
 212 (defvar vc-git-status-result nil)
 213
 214 (defun vc-git-after-dir-status-stage2 (update-function status-buffer)
 215   (goto-char (point-min))
 216   (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 217     (push (cons (match-string 1) 'unregistered) vc-git-status-result))
 218   (funcall update-function (nreverse vc-git-status-result) status-buffer)
 219   ;; Remove the temporary buffer.
 220   (kill-buffer (current-buffer)))
 221
 222 (defun vc-git-after-dir-status-stage1 (update-function status-buffer)
 223   (goto-char (point-min))
 224   (while (re-search-forward
 225           ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0\\([^\0]+\\)\0"
 226           nil t 1)
 227     (let ((filename (match-string 2))
 228           (status (vc-git--state-code (match-string 1))))
 229       (push (cons filename status) vc-git-status-result)))
 230   (erase-buffer)
 231   (vc-git-command (current-buffer) 'async nil "ls-files" "-z" "-o"
 232                   "--directory" "--no-empty-directory" "--exclude-standard")
 233   (vc-exec-after
 234    `(vc-git-after-dir-status-stage2 (quote ,update-function) ,status-buffer)))
 235
 236 (defun vc-git-after-dir-status-stage1-empty-db (update-function status-buffer)
 237   (goto-char (point-min))
 238   (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 239     (push (cons (match-string 1) 'added) vc-git-status-result))
 240   (erase-buffer)
 241   (vc-git-command (current-buffer) 'async nil "ls-files" "-z" "-o"
 242                   "--directory" "--no-empty-directory" "--exclude-standard")
 243   (vc-exec-after
 244    `(vc-git-after-dir-status-stage2 (quote ,update-function) ,status-buffer)))
 245
 246 (defun vc-git-dir-status (dir update-function status-buffer)
 247   "Return a list of conses (file . state) for DIR."
 248   ;; Further things that would have to be fixed later:
 249   ;; - how to handle unregistered directories
 250   ;; - how to support vc-status on a subdir of the project tree
 251   (with-current-buffer
 252       (get-buffer-create
 253        (expand-file-name " *VC-Git* tmp status" dir))
 254     (set (make-local-variable 'vc-git-status-result) nil)
 255     (cd dir)
 256     (erase-buffer)
 257     (if (vc-git--empty-db-p)
 258         (progn
 259           (vc-git-command (current-buffer) 'async nil "ls-files" "-z" "-c")
 260           (vc-exec-after
 261            `(vc-git-after-dir-status-stage1-empty-db (quote ,update-function) ,status-buffer)))
 262       (vc-git-command (current-buffer) 'async nil "diff-index" "-z" "HEAD")
 263       (vc-exec-after
 264        `(vc-git-after-dir-status-stage1 (quote ,update-function) ,status-buffer)))
 265     (current-buffer)))
 266
 267 ;;; STATE-CHANGING FUNCTIONS
 268
 269 (defun vc-git-create-repo ()
 270   "Create a new Git repository."
 271   (vc-git-command nil 0 nil "init"))
 272
 273 (defun vc-git-register (files &optional rev comment)
 274   "Register FILE into the git version-control system."
 275   (vc-git-command nil 0 files "update-index" "--add" "--"))
 276
 277 (defalias 'vc-git-responsible-p 'vc-git-root)
 278
 279 (defun vc-git-unregister (file)
 280   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 281
 282
 283 (defun vc-git-checkin (files rev comment)
 284   (let ((coding-system-for-write git-commits-coding-system))
 285     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 286
 287 (defun vc-git-find-revision (file rev buffer)
 288   (let ((coding-system-for-read 'binary)
 289         (coding-system-for-write 'binary)
 290         (fullname (substring
 291                    (vc-git--run-command-string
 292                     file "ls-files" "-z" "--full-name" "--")
 293                    0 -1)))
 294     (vc-git-command
 295      buffer 0
 296      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 297
 298 (defun vc-git-checkout (file &optional editable rev)
 299   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 300
 301 (defun vc-git-revert (file &optional contents-done)
 302   "Revert FILE to the version stored in the git repository."
 303   (if contents-done
 304       (vc-git-command nil 0 file "update-index" "--")
 305     (vc-git-command nil 0 file "checkout" "HEAD")))
 306
 307 ;;; HISTORY FUNCTIONS
 308
 309 (defun vc-git-print-log (files &optional buffer)
 310   "Get change log associated with FILES."
 311   (let ((coding-system-for-read git-commits-coding-system)
 312         ;; Support both the old print-log interface that passes a
 313         ;; single file, and the new one that passes a file list.
 314         (flist (if (listp files) files (list files))))
 315     ;; `vc-do-command' creates the buffer, but we need it before running
 316     ;; the command.
 317     (vc-setup-buffer buffer)
 318     ;; If the buffer exists from a previous invocation it might be
 319     ;; read-only.
 320     (let ((inhibit-read-only t))
 321       ;; XXX `log-view-mode' needs to have something to identify where
 322       ;; the log for each individual file starts. It seems that by
 323       ;; default git does not output this info. So loop here and call
 324       ;; "git rev-list" on each file separately to make sure that each
 325       ;; file gets a "File:" header before the corresponding
 326       ;; log. Maybe there is a way to do this with one command...
 327       (dolist (file flist)
 328         (with-current-buffer
 329             buffer
 330           (insert "File: " (file-name-nondirectory file) "\n"))
 331         (vc-git-command buffer 'async (file-relative-name file)
 332                         "rev-list" "--pretty" "HEAD" "--")))))
 333
 334 (defvar log-view-message-re)
 335 (defvar log-view-file-re)
 336 (defvar log-view-font-lock-keywords)
 337
 338 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 339   (require 'add-log) ;; we need the faces add-log
 340   ;; Don't have file markers, so use impossible regexp.
 341   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 342   (set (make-local-variable 'log-view-message-re)
 343        "^commit *\\([0-9a-z]+\\)")
 344   (set (make-local-variable 'log-view-font-lock-keywords)
 345        (append
 346         `((,log-view-message-re  (1 'change-log-acknowledgement))
 347           (,log-view-file-re (1 'change-log-file-face)))
 348         ;; Handle the case:
 349         ;; user: foo@bar
 350         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 351            (1 'change-log-email))
 352           ;; Handle the case:
 353           ;; user: FirstName LastName <foo@bar>
 354           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 355            (1 'change-log-name)
 356            (2 'change-log-email))
 357           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 358            (1 'change-log-name))
 359           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 360            (1 'change-log-name)
 361            (2 'change-log-email))
 362           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 363            (1 'change-log-acknowledgement)
 364            (2 'change-log-acknowledgement))
 365           ("^Date:   \\(.+\\)" (1 'change-log-date))
 366           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 367
 368 (defun vc-git-show-log-entry (revision)
 369   "Move to the log entry for REVISION.
 370 REVISION may have the form BRANCH, BRANCH~N,
 371 or BRANCH^ (where \"^\" can be repeated)."
 372   (goto-char (point-min))
 373   (search-forward "\ncommit" nil t
 374                   (cond ((string-match "~\\([0-9]\\)$" revision)
 375                          (1+ (string-to-number (match-string 1 revision))))
 376                         ((string-match "\\^+$" revision)
 377                          (1+ (length (match-string 0 revision))))
 378                         (t nil)))
 379   (beginning-of-line))
 380
 381 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 382   (let ((buf (or buffer "*vc-diff*")))
 383     (if (and rev1 rev2)
 384         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 385                         rev1 rev2 "--")
 386       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 387                       (or rev1 "HEAD") "--"))))
 388
 389 (defun vc-git-revision-table (files)
 390   ;; What about `files'?!?  --Stef
 391   (let ((table (list "HEAD")))
 392     (with-temp-buffer
 393       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 394       (goto-char (point-min))
 395       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 396         (push (match-string 2) table)))
 397     table))
 398
 399 (defun vc-git-revision-completion-table (files)
 400   (lexical-let ((files files)
 401                 table)
 402     (setq table (lazy-completion-table
 403                  table (lambda () (vc-git-revision-table files))))
 404     table))
 405
 406 (defun vc-git-annotate-command (file buf &optional rev)
 407   ;; FIXME: rev is ignored
 408   (let ((name (file-relative-name file)))
 409     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 410
 411 (defun vc-git-annotate-time ()
 412   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 413        (vc-annotate-convert-time
 414         (apply #'encode-time (mapcar (lambda (match)
 415                                        (string-to-number (match-string match)))
 416                                      '(6 5 4 3 2 1 7))))))
 417
 418 (defun vc-git-annotate-extract-revision-at-line ()
 419   (save-excursion
 420     (move-beginning-of-line 1)
 421     (and (looking-at "[0-9a-f^][0-9a-f]+")
 422          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 423
 424 ;;; SNAPSHOT SYSTEM
 425
 426 (defun vc-git-create-snapshot (dir name branchp)
 427   (let ((default-directory dir))
 428     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 429          (if branchp
 430              (vc-git-command nil 0 nil "checkout" "-b" name)
 431            (vc-git-command nil 0 nil "tag" name)))))
 432
 433 (defun vc-git-retrieve-snapshot (dir name update)
 434   (let ((default-directory dir))
 435     (vc-git-command nil 0 nil "checkout" name)
 436     ;; FIXME: update buffers if `update' is true
 437     ))
 438
 439
 440 ;;; MISCELLANEOUS
 441
 442 (defun vc-git-previous-revision (file rev)
 443   "Git-specific version of `vc-previous-revision'."
 444   (let ((default-directory (file-name-directory (expand-file-name file)))
 445         (file (file-name-nondirectory file)))
 446     (vc-git-symbolic-commit
 447      (with-temp-buffer
 448        (and
 449         (vc-git--out-ok "rev-list" "-2" rev "--" file)
 450         (goto-char (point-max))
 451         (bolp)
 452         (zerop (forward-line -1))
 453         (not (bobp))
 454         (buffer-substring-no-properties
 455          (point)
 456          (1- (point-max))))))))
 457
 458 (defun vc-git-next-revision (file rev)
 459   "Git-specific version of `vc-next-revision'."
 460   (let* ((default-directory (file-name-directory
 461                              (expand-file-name file)))
 462          (file (file-name-nondirectory file))
 463          (current-rev
 464           (with-temp-buffer
 465             (and
 466              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 467              (goto-char (point-max))
 468              (bolp)
 469              (zerop (forward-line -1))
 470              (bobp)
 471              (buffer-substring-no-properties
 472               (point)
 473               (1- (point-max)))))))
 474     (and current-rev
 475          (vc-git-symbolic-commit
 476           (with-temp-buffer
 477             (and
 478              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 479              (goto-char (point-min))
 480              (search-forward current-rev nil t)
 481              (zerop (forward-line -1))
 482              (buffer-substring-no-properties
 483               (point)
 484               (progn (forward-line 1) (1- (point))))))))))
 485
 486 (defun vc-git-delete-file (file)
 487   (vc-git-command nil 0 file "rm" "-f" "--"))
 488
 489 (defun vc-git-rename-file (old new)
 490   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 491
 492 \f
 493 ;;; Internal commands
 494
 495 (defun vc-git-root (file)
 496   (vc-find-root file ".git"))
 497
 498 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 499   "A wrapper around `vc-do-command' for use in vc-git.el.
 500 The difference to vc-do-command is that this function always invokes `git'."
 501   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 502
 503 (defun vc-git--empty-db-p ()
 504   "Check if the git db is empty (no commit done yet)."
 505   (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD"))))
 506
 507 (defun vc-git--call (buffer command &rest args)
 508   ;; We don't need to care the arguments.  If there is a file name, it
 509   ;; is always a relative one.  This works also for remote
 510   ;; directories.
 511   (apply 'process-file "git" nil buffer nil command args))
 512
 513 (defun vc-git--out-ok (command &rest args)
 514   (zerop (apply 'vc-git--call '(t nil) command args)))
 515
 516 (defun vc-git--run-command-string (file &rest args)
 517   "Run a git command on FILE and return its output as string."
 518   (let* ((ok t)
 519          (str (with-output-to-string
 520                 (with-current-buffer standard-output
 521                   (unless (apply 'vc-git--out-ok
 522                                  (append args (list (file-relative-name
 523                                                      file))))
 524                     (setq ok nil))))))
 525     (and ok str)))
 526
 527 (defun vc-git-symbolic-commit (commit)
 528   "Translate COMMIT string into symbolic form.
 529 Returns nil if not possible."
 530   (and commit
 531        (with-temp-buffer
 532          (and
 533           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 534           (goto-char (point-min))
 535           (= (forward-line 2) 1)
 536           (bolp)
 537           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 538
 539 (provide 'vc-git)
 540
 541 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 542 ;;; vc-git.el ends here