lisp/calculator.el

   1 ;;; calculator.el --- a [not so] simple calculator for Emacs
   2
   3 ;; Copyright (C) 1998, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Eli Barzilay <eli@barzilay.org>
   7 ;; Keywords: tools, convenience
   8 ;; Time-stamp: <2005-07-18 17:45:34 juri>
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by the
  14 ;; Free Software Foundation; either version 2, or (at your option) any
  15 ;; later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  25 ;; MA 02110-1301, USA.
  26
  27 ;;;=====================================================================
  28 ;;; Commentary:
  29 ;;
  30 ;; A calculator for Emacs.
  31 ;; Why should you reach for your mouse to get xcalc (calc.exe, gcalc or
  32 ;; whatever), when you have Emacs running already?
  33 ;;
  34 ;; If this is not part of your Emacs distribution, then simply bind
  35 ;; `calculator' to a key and make it an autoloaded function, e.g.:
  36 ;;   (autoload 'calculator "calculator"
  37 ;;     "Run the Emacs calculator." t)
  38 ;;   (global-set-key [(control return)] 'calculator)
  39 ;;
  40 ;; Written by Eli Barzilay: Maze is Life!  eli@barzilay.org
  41 ;;                                         http://www.barzilay.org/
  42 ;;
  43 ;; For latest version, check
  44 ;;     http://www.barzilay.org/misc/calculator.el
  45 ;;
  46
  47 ;;; History:
  48 ;; I hate history.
  49
  50 (eval-and-compile
  51   (if (fboundp 'defgroup) nil
  52     (defmacro defgroup (&rest forms) nil)
  53     (defmacro defcustom (s v d &rest r) (list 'defvar s v d))))
  54
  55 ;;;=====================================================================
  56 ;;; Customization:
  57
  58 (defgroup calculator nil
  59   "Simple Emacs calculator."
  60   :prefix "calculator"
  61   :version "21.1"
  62   :group 'tools
  63   :group 'convenience)
  64
  65 (defcustom calculator-electric-mode nil
  66   "*Run `calculator' electrically, in the echo area.
  67 Electric mode saves some place but changes the way you interact with the
  68 calculator."
  69   :type  'boolean
  70   :group 'calculator)
  71
  72 (defcustom calculator-use-menu t
  73   "*Make `calculator' create a menu.
  74 Note that this requires easymenu.  Must be set before loading."
  75   :type  'boolean
  76   :group 'calculator)
  77
  78 (defcustom calculator-bind-escape nil
  79   "*If non-nil, set escape to exit the calculator."
  80   :type  'boolean
  81   :group 'calculator)
  82
  83 (defcustom calculator-unary-style 'postfix
  84   "*Value is either 'prefix or 'postfix.
  85 This determines the default behavior of unary operators."
  86   :type    '(choice (const prefix) (const postfix))
  87   :group   'calculator)
  88
  89 (defcustom calculator-prompt "Calc=%s> "
  90   "*The prompt used by the Emacs calculator.
  91 It should contain a \"%s\" somewhere that will indicate the i/o radixes,
  92 this string will be a two-character string as described in the
  93 documentation for `calculator-mode'."
  94   :type  'string
  95   :group 'calculator)
  96
  97 (defcustom calculator-number-digits 3
  98   "*The calculator's number of digits used for standard display.
  99 Used by the `calculator-standard-display' function - it will use the
 100 format string \"%.NC\" where this number is N and C is a character given
 101 at runtime."
 102   :type  'integer
 103   :group 'calculator)
 104
 105 (defcustom calculator-radix-grouping-mode t
 106   "*Use digit grouping in radix output mode.
 107 If this is set, chunks of `calculator-radix-grouping-digits' characters
 108 will be separated by `calculator-radix-grouping-separator' when in radix
 109 output mode is active (determined by `calculator-output-radix')."
 110   :type  'boolean
 111   :group 'calculator)
 112
 113 (defcustom calculator-radix-grouping-digits 4
 114   "*The number of digits used for grouping display in radix modes.
 115 See `calculator-radix-grouping-mode'."
 116   :type  'integer
 117   :group 'calculator)
 118
 119 (defcustom calculator-radix-grouping-separator "'"
 120   "*The separator used in radix grouping display.
 121 See `calculator-radix-grouping-mode'."
 122   :type  'string
 123   :group 'calculator)
 124
 125 (defcustom calculator-remove-zeros t
 126   "*Non-nil value means delete all redundant zero decimal digits.
 127 If this value is not t, and not nil, redundant zeros are removed except
 128 for one and if it is nil, nothing is removed.
 129 Used by the `calculator-remove-zeros' function."
 130   :type  '(choice (const t) (const leave-decimal) (const nil))
 131   :group 'calculator)
 132
 133 (defcustom calculator-displayer '(std ?n)
 134   "*A displayer specification for numerical values.
 135 This is the displayer used to show all numbers in an expression.  Result
 136 values will be displayed according to the first element of
 137 `calculator-displayers'.
 138
 139 The displayer is a symbol, a string or an expression.  A symbol should
 140 be the name of a one-argument function, a string is used with a single
 141 argument and an expression will be evaluated with the variable `num'
 142 bound to whatever should be displayed.  If it is a function symbol, it
 143 should be able to handle special symbol arguments, currently 'left and
 144 'right which will be sent by special keys to modify display parameters
 145 associated with the displayer function (for example to change the number
 146 of digits displayed).
 147
 148 An exception to the above is the case of the list (std C) where C is a
 149 character, in this case the `calculator-standard-displayer' function
 150 will be used with this character for a format string."
 151   :group 'calculator)
 152
 153 (defcustom calculator-displayers
 154   '(((std ?n) "Standard display, decimal point or scientific")
 155     (calculator-eng-display "Eng display")
 156     ((std ?f) "Standard display, decimal point")
 157     ((std ?e) "Standard display, scientific")
 158     ("%S"     "Emacs printer"))
 159   "*A list of displayers.
 160 Each element is a list of a displayer and a description string.  The
 161 first element is the one which is currently used, this is for the display
 162 of result values not values in expressions.  A displayer specification
 163 is the same as the values that can be stored in `calculator-displayer'.
 164
 165 `calculator-rotate-displayer' rotates this list."
 166   :type  'sexp
 167   :group 'calculator)
 168
 169 (defcustom calculator-paste-decimals t
 170   "*If non-nil, convert pasted integers so they have a decimal point.
 171 This makes it possible to paste big integers since they will be read as
 172 floats, otherwise the Emacs reader will fail on them."
 173   :type  'boolean
 174   :group 'calculator)
 175
 176 (defcustom calculator-copy-displayer nil
 177   "*If non-nil, this is any value that can be used for
 178 `calculator-displayer', to format a string before copying it with
 179 `calculator-copy'.  If nil, then `calculator-displayer's normal value is
 180 used."
 181   :type  'boolean
 182   :group 'calculator)
 183
 184 (defcustom calculator-2s-complement nil
 185   "*If non-nil, show negative numbers in 2s complement in radix modes.
 186 Otherwise show as a negative number."
 187   :type  'boolean
 188   :group 'calculator)
 189
 190 (defcustom calculator-mode-hook nil
 191   "*List of hook functions for `calculator-mode' to run.
 192 Note: if `calculator-electric-mode' is on, then this hook will get
 193 activated in the minibuffer - in that case it should not do much more
 194 than local key settings and other effects that will change things
 195 outside the scope of calculator related code."
 196   :type  'hook
 197   :group 'calculator)
 198
 199 (defcustom calculator-user-registers nil
 200   "*An association list of user-defined register bindings.
 201 Each element in this list is a list of a character and a number that
 202 will be stored in that character's register.
 203
 204 For example, use this to define the golden ratio number:
 205   (setq calculator-user-registers '((?g .  1.61803398875)))
 206 before you load calculator."
 207   :type  '(repeat (cons character number))
 208   :set   '(lambda (_ val)
 209             (and (boundp 'calculator-registers)
 210                  (setq calculator-registers
 211                        (append val calculator-registers)))
 212             (setq calculator-user-registers val))
 213   :group 'calculator)
 214
 215 (defcustom calculator-user-operators nil
 216   "*A list of additional operators.
 217 This is a list in the same format as specified in the documentation for
 218 `calculator-operators', that you can use to bind additional calculator
 219 operators.  It is probably not a good idea to modify this value with
 220 `customize' since it is too complex...
 221
 222 Examples:
 223
 224 * A very simple one, adding a postfix \"x-to-y\" conversion keys, using
 225   t as a prefix key:
 226
 227   (setq calculator-user-operators
 228         '((\"tf\" cl-to-fr (+ 32 (/ (* X 9) 5)) 1)
 229           (\"tc\" fr-to-cl (/ (* (- X 32) 5) 9) 1)
 230           (\"tp\" kg-to-lb (/ X 0.453592)       1)
 231           (\"tk\" lb-to-kg (* X 0.453592)       1)
 232           (\"tF\" mt-to-ft (/ X 0.3048)         1)
 233           (\"tM\" ft-to-mt (* X 0.3048)         1)))
 234
 235 * Using a function-like form is very simple, X for an argument (Y the
 236   second in case of a binary operator), TX is a truncated version of X
 237   and F does a recursive call, Here is a [very inefficient] Fibonacci
 238   number calculation:
 239
 240   (add-to-list 'calculator-user-operators
 241                '(\"F\" fib (if (<= TX 1)
 242                          1
 243                          (+ (F (- TX 1)) (F (- TX 2)))) 0))
 244
 245   Note that this will be either postfix or prefix, according to
 246   `calculator-unary-style'."
 247   :type  '(repeat (list string symbol sexp integer integer))
 248   :group 'calculator)
 249
 250 ;;;=====================================================================
 251 ;;; Code:
 252
 253 ;;;---------------------------------------------------------------------
 254 ;;; Variables
 255
 256 (defvar calculator-initial-operators
 257   '(;; "+"/"-" have keybindings of themselves, not calculator-ops
 258     ("=" =     identity        1 -1)
 259     (nobind "+" +  +           2  4)
 260     (nobind "-" -  -           2  4)
 261     (nobind "+" +  +          -1  9)
 262     (nobind "-" -  -          -1  9)
 263     ("(" \(    identity       -1 -1)
 264     (")" \)    identity       +1 10)
 265     ;; normal keys
 266     ("|"  or   (logior TX TY)  2  2)
 267     ("#"  xor  (logxor TX TY)  2  2)
 268     ("&"  and  (logand TX TY)  2  3)
 269     ("*"  *    *               2  5)
 270     ("/"  /    /               2  5)
 271     ("\\" div  (/ TX TY)       2  5)
 272     ("%"  rem  (% TX TY)       2  5)
 273     ("L"  log  log             2  6)
 274     ("S"  sin  (sin DX)        x  6)
 275     ("C"  cos  (cos DX)        x  6)
 276     ("T"  tan  (tan DX)        x  6)
 277     ("IS" asin (D (asin X))    x  6)
 278     ("IC" acos (D (acos X))    x  6)
 279     ("IT" atan (D (atan X))    x  6)
 280     ("Q"  sqrt sqrt            x  7)
 281     ("^"  ^    expt            2  7)
 282     ("!"  !    calculator-fact x  7)
 283     (";"  1/   (/ 1 X)         1  7)
 284     ("_"  -    -               1  8)
 285     ("~"  ~    (lognot TX)     x  8)
 286     (">"  repR calculator-repR 1  8)
 287     ("<"  repL calculator-repL 1  8)
 288     ("v"  avg  (/ (apply '+ L) (length L)) 0 8)
 289     ("l"  tot  (apply '+ L)    0 8)
 290     )
 291   "A list of initial operators.
 292 This is a list in the same format as `calculator-operators'.  Whenever
 293 `calculator' starts, it looks at the value of this variable, and if it
 294 is not empty, its contents is prepended to `calculator-operators' and
 295 the appropriate key bindings are made.
 296
 297 This variable is then reset to nil.  Don't use this if you want to add
 298 user-defined operators, use `calculator-user-operators' instead.")
 299
 300 (defvar calculator-operators nil
 301   "The calculator operators, each a list with:
 302
 303 1. The key that is bound to for this operation (usually a string);
 304
 305 2. The displayed symbol for this function;
 306
 307 3. The function symbol, or a form that uses the variables `X' and `Y',
 308    (if it is a binary operator), `TX' and `TY' (truncated integer
 309    versions), `DX' (converted to radians if degrees mode is on), `D'
 310    (function for converting radians to degrees if deg mode is on), `L'
 311    (list of saved values), `F' (function for recursive iteration calls)
 312    and evaluates to the function value - these variables are capital;
 313
 314 4. The function's arity, optional, one of: 2 => binary, -1 => prefix
 315    unary, +1 => postfix unary, 0 => a 0-arg operator func, non-number =>
 316    postfix/prefix as determined by `calculator-unary-style' (the
 317    default);
 318
 319 5. The function's precedence - should be in the range of 1 (lowest) to
 320    9 (highest) (optional, defaults to 1);
 321
 322 It it possible have a unary prefix version of a binary operator if it
 323 comes later in this list.  If the list begins with the symbol 'nobind,
 324 then no key binding will take place - this is only useful for predefined
 325 keys.
 326
 327 Use `calculator-user-operators' to add operators to this list, see its
 328 documentation for an example.")
 329
 330 (defvar calculator-stack nil
 331   "Stack contents - operations and operands.")
 332
 333 (defvar calculator-curnum nil
 334   "Current number being entered (as a string).")
 335
 336 (defvar calculator-stack-display nil
 337   "Cons of the stack and its string representation.")
 338
 339 (defvar calculator-char-radix
 340   '((?D . nil) (?B . bin) (?O . oct) (?H . hex) (?X . hex))
 341   "A table to convert input characters to corresponding radix symbols.")
 342
 343 (defvar calculator-output-radix nil
 344   "The mode for display, one of: nil (decimal), 'bin, 'oct or 'hex.")
 345
 346 (defvar calculator-input-radix nil
 347   "The mode for input, one of: nil (decimal), 'bin, 'oct or 'hex.")
 348
 349 (defvar calculator-deg nil
 350   "Non-nil if trig functions operate on degrees instead of radians.")
 351
 352 (defvar calculator-saved-list nil
 353   "A list of saved values collected.")
 354
 355 (defvar calculator-saved-ptr 0
 356   "The pointer to the current saved number.")
 357
 358 (defvar calculator-add-saved nil
 359   "Bound to t when a value should be added to the saved-list.")
 360
 361 (defvar calculator-display-fragile nil
 362   "When non-nil, we see something that the next digit should replace.")
 363
 364 (defvar calculator-buffer nil
 365   "The current calculator buffer.")
 366
 367 (defvar calculator-eng-extra nil
 368   "Internal value used by `calculator-eng-display'.")
 369
 370 (defvar calculator-eng-tmp-show nil
 371   "Internal value used by `calculator-eng-display'.")
 372
 373 (defvar calculator-last-opXY nil
 374   "The last binary operation and its arguments.
 375 Used for repeating operations in calculator-repR/L.")
 376
 377 (defvar calculator-registers ; use user-bindings first
 378   (append calculator-user-registers (list (cons ?e e) (cons ?p pi)))
 379   "The association list of calculator register values.")
 380
 381 (defvar calculator-saved-global-map nil
 382   "Saved global key map.")
 383
 384 (defvar calculator-restart-other-mode nil
 385   "Used to hack restarting with the electric mode changed.")
 386
 387 ;;;---------------------------------------------------------------------
 388 ;;; Key bindings
 389
 390 (defvar calculator-mode-map nil
 391   "The calculator key map.")
 392
 393 (or calculator-mode-map
 394   (let ((map (make-sparse-keymap)))
 395     (suppress-keymap map t)
 396     (define-key map "i" nil)
 397     (define-key map "o" nil)
 398     (let ((p
 399            '((calculator-open-paren  "[")
 400              (calculator-close-paren "]")
 401              (calculator-op-or-exp   "+" "-" [kp-add] [kp-subtract])
 402              (calculator-digit       "0" "1" "2" "3" "4" "5" "6" "7" "8"
 403                                      "9" "a" "b" "c" "d" "f"
 404                                      [kp-0] [kp-1] [kp-2] [kp-3] [kp-4]
 405                                      [kp-5] [kp-6] [kp-7] [kp-8] [kp-9])
 406              (calculator-op          [kp-divide] [kp-multiply])
 407              (calculator-decimal     "." [kp-decimal])
 408              (calculator-exp         "e")
 409              (calculator-dec/deg-mode "D")
 410              (calculator-set-register "s")
 411              (calculator-get-register "g")
 412              (calculator-radix-mode        "H" "X" "O" "B")
 413              (calculator-radix-input-mode  "id" "ih" "ix" "io" "ib"
 414                                            "iD" "iH" "iX" "iO" "iB")
 415              (calculator-radix-output-mode "od" "oh" "ox" "oo" "ob"
 416                                            "oD" "oH" "oX" "oO" "oB")
 417              (calculator-rotate-displayer      "'")
 418              (calculator-rotate-displayer-back "\"")
 419              (calculator-displayer-prev        "{")
 420              (calculator-displayer-next        "}")
 421              (calculator-saved-up      [up] [?\C-p])
 422              (calculator-saved-down    [down] [?\C-n])
 423              (calculator-quit          "q" [?\C-g])
 424              (calculator-enter         [enter] [linefeed] [kp-enter]
 425                                        [return] [?\r] [?\n])
 426              (calculator-save-on-list  " " [space])
 427              (calculator-clear-saved   [?\C-c] [(control delete)])
 428              (calculator-save-and-quit [(control return)]
 429                                        [(control kp-enter)])
 430              (calculator-paste         [insert] [(shift insert)]
 431                                        [paste] [mouse-2] [?\C-y])
 432              (calculator-clear         [delete] [?\C-?] [?\C-d])
 433              (calculator-help          [?h] [??] [f1] [help])
 434              (calculator-copy          [(control insert)] [copy])
 435              (calculator-backspace     [backspace])
 436              )))
 437       (while p
 438         ;; reverse the keys so first defs come last - makes the more
 439         ;; sensible bindings visible in the menu
 440         (let ((func (car (car p))) (keys (reverse (cdr (car p)))))
 441           (while keys
 442             (define-key map (car keys) func)
 443             (setq keys (cdr keys))))
 444         (setq p (cdr p))))
 445     (if calculator-bind-escape
 446       (progn (define-key map [?\e] 'calculator-quit)
 447              (define-key map [escape] 'calculator-quit))
 448       (define-key map [?\e ?\e ?\e] 'calculator-quit))
 449     ;; make C-h work in text-mode
 450     (or window-system (define-key map [?\C-h] 'calculator-backspace))
 451     ;; set up a menu
 452     (if (and calculator-use-menu (not (boundp 'calculator-menu)))
 453       (let ((radix-selectors
 454              (mapcar (lambda (x)
 455                        `([,(nth 0 x)
 456                           (calculator-radix-mode ,(nth 2 x))
 457                           :style radio
 458                           :keys ,(nth 2 x)
 459                           :selected
 460                           (and
 461                            (eq calculator-input-radix ',(nth 1 x))
 462                            (eq calculator-output-radix ',(nth 1 x)))]
 463                          [,(concat (nth 0 x) " Input")
 464                           (calculator-radix-input-mode ,(nth 2 x))
 465                           :keys ,(concat "i" (downcase (nth 2 x)))
 466                           :style radio
 467                           :selected
 468                           (eq calculator-input-radix ',(nth 1 x))]
 469                          [,(concat (nth 0 x) " Output")
 470                           (calculator-radix-output-mode ,(nth 2 x))
 471                           :keys ,(concat "o" (downcase (nth 2 x)))
 472                           :style radio
 473                           :selected
 474                           (eq calculator-output-radix ',(nth 1 x))]))
 475                      '(("Decimal"     nil "D")
 476                        ("Binary"      bin "B")
 477                        ("Octal"       oct "O")
 478                        ("Hexadecimal" hex "H"))))
 479             (op '(lambda (name key)
 480                         `[,name (calculator-op ,key) :keys ,key])))
 481         (easy-menu-define
 482          calculator-menu map "Calculator menu."
 483          `("Calculator"
 484            ["Help"
 485             (let ((last-command 'calculator-help)) (calculator-help))
 486             :keys "?"]
 487            "---"
 488            ["Copy"  calculator-copy]
 489            ["Paste" calculator-paste]
 490            "---"
 491            ["Electric mode"
 492             (progn (calculator-quit)
 493                    (setq calculator-restart-other-mode t)
 494                    (run-with-timer 0.1 nil '(lambda () (message nil)))
 495                    ;; the message from the menu will be visible,
 496                    ;; couldn't make it go away...
 497                    (calculator))
 498             :active (not calculator-electric-mode)]
 499            ["Normal mode"
 500             (progn (setq calculator-restart-other-mode t)
 501                    (calculator-quit))
 502             :active calculator-electric-mode]
 503            "---"
 504            ("Functions"
 505             ,(funcall op "Repeat-right" ">")
 506             ,(funcall op "Repeat-left"  "<")
 507             "------General------"
 508             ,(funcall op "Reciprocal"   ";")
 509             ,(funcall op "Log"          "L")
 510             ,(funcall op "Square-root"  "Q")
 511             ,(funcall op "Factorial"    "!")
 512             "------Trigonometric------"
 513             ,(funcall op "Sinus"        "S")
 514             ,(funcall op "Cosine"       "C")
 515             ,(funcall op "Tangent"      "T")
 516             ,(funcall op "Inv-Sinus"    "IS")
 517             ,(funcall op "Inv-Cosine"   "IC")
 518             ,(funcall op "Inv-Tangent"  "IT")
 519             "------Bitwise------"
 520             ,(funcall op "Or"           "|")
 521             ,(funcall op "Xor"          "#")
 522             ,(funcall op "And"          "&")
 523             ,(funcall op "Not"          "~"))
 524            ("Saved List"
 525             ["Eval+Save"      calculator-save-on-list]
 526             ["Prev number"    calculator-saved-up]
 527             ["Next number"    calculator-saved-down]
 528             ["Delete current" calculator-clear
 529              :active (and calculator-display-fragile
 530                           calculator-saved-list
 531                           (= (car calculator-stack)
 532                              (nth calculator-saved-ptr
 533                                   calculator-saved-list)))]
 534             ["Delete all" calculator-clear-saved]
 535             "---"
 536             ,(funcall op "List-total"   "l")
 537             ,(funcall op "List-average" "v"))
 538            ("Registers"
 539             ["Get register" calculator-get-register]
 540             ["Set register" calculator-set-register])
 541            ("Modes"
 542             ["Radians"
 543              (progn
 544                (and (or calculator-input-radix calculator-output-radix)
 545                     (calculator-radix-mode "D"))
 546                (and calculator-deg (calculator-dec/deg-mode)))
 547              :keys "D"
 548              :style radio
 549              :selected (not (or calculator-input-radix
 550                                 calculator-output-radix
 551                                 calculator-deg))]
 552             ["Degrees"
 553              (progn
 554                (and (or calculator-input-radix calculator-output-radix)
 555                     (calculator-radix-mode "D"))
 556                (or calculator-deg (calculator-dec/deg-mode)))
 557              :keys "D"
 558              :style radio
 559              :selected (and calculator-deg
 560                             (not (or calculator-input-radix
 561                                      calculator-output-radix)))]
 562             "---"
 563             ,@(mapcar 'car radix-selectors)
 564             ("Seperate I/O"
 565              ,@(mapcar (lambda (x) (nth 1 x)) radix-selectors)
 566              "---"
 567              ,@(mapcar (lambda (x) (nth 2 x)) radix-selectors)))
 568            ("Decimal Display"
 569             ,@(mapcar (lambda (d)
 570                         (vector (cadr d)
 571                                 ;; Note: inserts actual object here
 572                                 `(calculator-rotate-displayer ',d)))
 573                       calculator-displayers)
 574             "---"
 575             ["Change Prev Display" calculator-displayer-prev]
 576             ["Change Next Display" calculator-displayer-next])
 577            "---"
 578            ["Copy+Quit" calculator-save-and-quit]
 579            ["Quit"      calculator-quit]))))
 580     (setq calculator-mode-map map)))
 581
 582 ;;;---------------------------------------------------------------------
 583 ;;; Startup and mode stuff
 584
 585 (defun calculator-mode ()
 586   ;; this help is also used as the major help screen
 587   "A [not so] simple calculator for Emacs.
 588
 589 This calculator is used in the same way as other popular calculators
 590 like xcalc or calc.exe - but using an Emacs interface.
 591
 592 Expressions are entered using normal infix notation, parens are used as
 593 normal.  Unary functions are usually postfix, but some depends on the
 594 value of `calculator-unary-style' (if the style for an operator below is
 595 specified, then it is fixed, otherwise it depends on this variable).
 596 `+' and `-' can be used as either binary operators or prefix unary
 597 operators.  Numbers can be entered with exponential notation using `e',
 598 except when using a non-decimal radix mode for input (in this case `e'
 599 will be the hexadecimal digit).
 600
 601 Here are the editing keys:
 602 * `RET' `='      evaluate the current expression
 603 * `C-insert'     copy the whole current expression to the `kill-ring'
 604 * `C-return'     evaluate, save result the `kill-ring' and exit
 605 * `insert'       paste a number if the one was copied (normally)
 606 * `delete' `C-d' clear last argument or whole expression (hit twice)
 607 * `backspace'    delete a digit or a previous expression element
 608 * `h' `?'        pop-up a quick reference help
 609 * `ESC' `q'      exit (`ESC' can be used if `calculator-bind-escape' is
 610                  non-nil, otherwise use three consecutive `ESC's)
 611
 612 These operators are pre-defined:
 613 * `+' `-' `*' `/' the common binary operators
 614 * `\\' `%'         integer division and reminder
 615 * `_' `;'         postfix unary negation and reciprocal
 616 * `^' `L'         binary operators for x^y and log(x) in base y
 617 * `Q' `!'         unary square root and factorial
 618 * `S' `C' `T'     unary trigonometric operators - sin, cos and tan
 619 * `|' `#' `&' `~' bitwise operators - or, xor, and, not
 620
 621 The trigonometric functions can be inverted if prefixed with an `I', see
 622 below for the way to use degrees instead of the default radians.
 623
 624 Two special postfix unary operators are `>' and `<': whenever a binary
 625 operator is performed, it is remembered along with its arguments; then
 626 `>' (`<') will apply the same operator with the same right (left)
 627 argument.
 628
 629 hex/oct/bin modes can be set for input and for display separately.
 630 Another toggle-able mode is for using degrees instead of radians for
 631 trigonometric functions.
 632 The keys to switch modes are (`X' is shortcut for `H'):
 633 * `D'             switch to all-decimal mode, or toggle degrees/radians
 634 * `B' `O' `H' `X' binary/octal/hexadecimal modes for input & display
 635 * `i' `o'         followed by one of `D' `B' `O' `H' `X' (case
 636                   insensitive) sets only the input or display radix mode
 637 The prompt indicates the current modes:
 638 * \"D=\": degrees mode;
 639 * \"?=\": (? is B/O/H) this is the radix for both input and output;
 640 * \"=?\": (? is B/O/H) the display radix (when input is decimal);
 641 * \"??\": (? is D/B/O/H) 1st char for input radix, 2nd for display.
 642
 643 Also, the quote key can be used to switch display modes for decimal
 644 numbers (double-quote rotates back), and the two brace characters
 645 \(\"{\" and \"}\" change display parameters that these displayers use (if
 646 they handle such).  If output is using any radix mode, then these keys
 647 toggle digit grouping mode and the chunk size.
 648
 649 Values can be saved for future reference in either a list of saved
 650 values, or in registers.
 651
 652 The list of saved values is useful for statistics operations on some
 653 collected data.  It is possible to navigate in this list, and if the
 654 value shown is the current one on the list, an indication is displayed
 655 as \"[N]\" if this is the last number and there are N numbers, or
 656 \"[M/N]\" if the M-th value is shown.
 657 * `SPC'            evaluate the current value as usual, but also adds
 658                    the result to the list of saved values
 659 * `l' `v'          computes total / average of saved values
 660 * `up' `C-p'       browse to the previous value in the list
 661 * `down' `C-n'     browse to the next value in the list
 662 * `delete' `C-d'   remove current value from the list (if it is on it)
 663 * `C-delete' `C-c' delete the whole list
 664
 665 Registers are variable-like place-holders for values:
 666 * `s' followed by a character attach the current value to that character
 667 * `g' followed by a character fetches the attached value
 668
 669 There are many variables that can be used to customize the calculator.
 670 Some interesting customization variables are:
 671 * `calculator-electric-mode'  use only the echo-area electrically.
 672 * `calculator-unary-style'    set most unary ops to pre/postfix style.
 673 * `calculator-user-registers' to define user-preset registers.
 674 * `calculator-user-operators' to add user-defined operators.
 675 See the documentation for these variables, and \"calculator.el\" for
 676 more information.
 677
 678 \\{calculator-mode-map}"
 679   (interactive)
 680   (kill-all-local-variables)
 681   (setq major-mode 'calculator-mode)
 682   (setq mode-name "Calculator")
 683   (use-local-map calculator-mode-map)
 684   (run-mode-hooks 'calculator-mode-hook))
 685
 686 (eval-when-compile (require 'electric) (require 'ehelp))
 687
 688 ;;;###autoload
 689 (defun calculator ()
 690   "Run the Emacs calculator.
 691 See the documentation for `calculator-mode' for more information."
 692   (interactive)
 693   (if calculator-restart-other-mode
 694     (setq calculator-electric-mode (not calculator-electric-mode)))
 695   (if calculator-initial-operators
 696     (progn (calculator-add-operators calculator-initial-operators)
 697            (setq calculator-initial-operators nil)
 698            ;; don't change this since it is a customization variable,
 699            ;; its set function will add any new operators
 700            (calculator-add-operators calculator-user-operators)))
 701   (setq calculator-buffer (get-buffer-create "*calculator*"))
 702   (if calculator-electric-mode
 703     (save-window-excursion
 704       (progn (require 'electric) (message nil)) ; hide load message
 705       (let (old-g-map old-l-map (echo-keystrokes 0)
 706             (garbage-collection-messages nil)) ; no gc msg when electric
 707         (set-window-buffer (minibuffer-window) calculator-buffer)
 708         (select-window (minibuffer-window))
 709         (calculator-reset)
 710         (calculator-update-display)
 711         (setq old-l-map (current-local-map))
 712         (setq old-g-map (current-global-map))
 713         (setq calculator-saved-global-map (current-global-map))
 714         (use-local-map nil)
 715         (use-global-map calculator-mode-map)
 716         (run-hooks 'calculator-mode-hook)
 717         (unwind-protect
 718             (catch 'calculator-done
 719               (Electric-command-loop
 720                'calculator-done
 721                ;; can't use 'noprompt, bug in electric.el
 722                '(lambda () 'noprompt)
 723                nil
 724                (lambda (x y) (calculator-update-display))))
 725           (and calculator-buffer
 726                (catch 'calculator-done (calculator-quit)))
 727           (use-local-map old-l-map)
 728           (use-global-map old-g-map))))
 729     (progn
 730       (cond
 731         ((not (get-buffer-window calculator-buffer))
 732          (let ((split-window-keep-point nil)
 733                (window-min-height 2))
 734            ;; maybe leave two lines for our window because of the normal
 735            ;; `raised' modeline in Emacs 21
 736            (select-window
 737             (split-window-vertically
 738              (if (and (fboundp 'face-attr-construct)
 739                       (plist-get (face-attr-construct 'modeline) :box))
 740                -3 -2)))
 741            (switch-to-buffer calculator-buffer)))
 742         ((not (eq (current-buffer) calculator-buffer))
 743          (select-window (get-buffer-window calculator-buffer))))
 744       (calculator-mode)
 745       (setq buffer-read-only t)
 746       (calculator-reset)
 747       (message "Hit `?' For a quick help screen.")))
 748   (if (and calculator-restart-other-mode calculator-electric-mode)
 749     (calculator)))
 750
 751 (defun calculator-message (string &rest arguments)
 752   "Same as `message', but special handle of electric mode."
 753   (apply 'message string arguments)
 754   (if calculator-electric-mode
 755     (progn (sit-for 1) (message nil))))
 756
 757 ;;;---------------------------------------------------------------------
 758 ;;; Operators
 759
 760 (defun calculator-op-arity (op)
 761   "Return OP's arity, 2, +1 or -1."
 762   (let ((arity (or (nth 3 op) 'x)))
 763     (if (numberp arity)
 764       arity
 765       (if (eq calculator-unary-style 'postfix) +1 -1))))
 766
 767 (defun calculator-op-prec (op)
 768   "Return OP's precedence for reducing when inserting into the stack.
 769 Defaults to 1."
 770   (or (nth 4 op) 1))
 771
 772 (defun calculator-add-operators (more-ops)
 773   "This function handles operator addition.
 774 Adds MORE-OPS to `calculator-operator', called initially to handle
 775 `calculator-initial-operators' and `calculator-user-operators'."
 776   (let ((added-ops nil))
 777     (while more-ops
 778       (or (eq (car (car more-ops)) 'nobind)
 779           (let ((i -1) (key (car (car more-ops))))
 780             ;; make sure the key is undefined, so it's easy to define
 781             ;; prefix keys
 782             (while (< (setq i (1+ i)) (length key))
 783               (or (keymapp
 784                    (lookup-key calculator-mode-map
 785                                (substring key 0 (1+ i))))
 786                   (progn
 787                     (define-key
 788                       calculator-mode-map (substring key 0 (1+ i)) nil)
 789                     (setq i (length key)))))
 790             (define-key calculator-mode-map key 'calculator-op)))
 791       (setq added-ops (cons (if (eq (car (car more-ops)) 'nobind)
 792                               (cdr (car more-ops))
 793                               (car more-ops))
 794                             added-ops))
 795       (setq more-ops (cdr more-ops)))
 796     ;; added-ops come first, but in correct order
 797     (setq calculator-operators
 798           (append (nreverse added-ops) calculator-operators))))
 799
 800 ;;;---------------------------------------------------------------------
 801 ;;; Display stuff
 802
 803 (defun calculator-reset ()
 804   "Reset calculator variables."
 805   (or calculator-restart-other-mode
 806       (setq calculator-stack           nil
 807             calculator-curnum          nil
 808             calculator-stack-display   nil
 809             calculator-display-fragile nil))
 810   (setq calculator-restart-other-mode nil)
 811   (calculator-update-display))
 812
 813 (defun calculator-get-prompt ()
 814   "Return a string to display.
 815 The string is set not to exceed the screen width."
 816   (let* ((calculator-prompt
 817           (format calculator-prompt
 818                   (cond
 819                     ((or calculator-output-radix calculator-input-radix)
 820                      (if (eq calculator-output-radix
 821                              calculator-input-radix)
 822                        (concat
 823                         (char-to-string
 824                          (car (rassq calculator-output-radix
 825                                      calculator-char-radix)))
 826                         "=")
 827                        (concat
 828                         (if calculator-input-radix
 829                           (char-to-string
 830                            (car (rassq calculator-input-radix
 831                                        calculator-char-radix)))
 832                           "=")
 833                         (char-to-string
 834                          (car (rassq calculator-output-radix
 835                                      calculator-char-radix))))))
 836                     (calculator-deg "D=")
 837                     (t "=="))))
 838          (prompt
 839           (concat calculator-prompt
 840                   (cdr calculator-stack-display)
 841                   (cond (calculator-curnum
 842                          ;; number being typed
 843                          (concat calculator-curnum "_"))
 844                         ((and (= 1 (length calculator-stack))
 845                               calculator-display-fragile)
 846                          ;; only the result is shown, next number will
 847                          ;; restart
 848                          nil)
 849                         (t
 850                          ;; waiting for a number or an operator
 851                          "?"))))
 852          (trim (- (length prompt) (1- (window-width)))))
 853     (if (<= trim 0)
 854       prompt
 855       (concat calculator-prompt
 856               (substring prompt (+ trim (length calculator-prompt)))))))
 857
 858 (defun calculator-string-to-number (str)
 859   "Convert the given STR to a number, according to the value of
 860 `calculator-input-radix'."
 861   (if calculator-input-radix
 862     (let ((radix
 863            (cdr (assq calculator-input-radix
 864                       '((bin . 2) (oct . 8) (hex . 16)))))
 865           (i -1) (value 0) (new-value 0))
 866       ;; assume mostly valid input (e.g., characters in range)
 867       (while (< (setq i (1+ i)) (length str))
 868         (setq new-value
 869               (let* ((ch (upcase (aref str i)))
 870                      (n (cond ((< ch ?0)  nil)
 871                               ((<= ch ?9) (- ch ?0))
 872                               ((< ch ?A)  nil)
 873                               ((<= ch ?Z) (- ch (- ?A 10)))
 874                               (t          nil))))
 875                 (if (and n (<= 0 n) (< n radix))
 876                   (+ n (* radix value))
 877                   (progn
 878                     (calculator-message
 879                      "Warning: Ignoring bad input character `%c'." ch)
 880                     (sit-for 1)
 881                     value))))
 882         (if (if (< new-value 0) (> value 0) (< value 0))
 883           (calculator-message "Warning: Overflow in input."))
 884         (setq value new-value))
 885       value)
 886     (car (read-from-string
 887           (cond ((equal "." str) "0.0")
 888                 ((string-match "[eE][+-]?$" str) (concat str "0"))
 889                 ((string-match "\\.[0-9]\\|[eE]" str) str)
 890                 ((string-match "\\." str)
 891                  ;; do this because Emacs reads "23." as an integer
 892                  (concat str "0"))
 893                 ((stringp str) (concat str ".0"))
 894                 (t "0.0"))))))
 895
 896 (defun calculator-curnum-value ()
 897   "Get the numeric value of the displayed number string as a float."
 898   (calculator-string-to-number calculator-curnum))
 899
 900 (defun calculator-rotate-displayer (&optional new-disp)
 901   "Switch to the next displayer on the `calculator-displayers' list.
 902 Can be called with an optional argument NEW-DISP to force rotation to
 903 that argument.
 904 If radix output mode is active, toggle digit grouping."
 905   (interactive)
 906   (cond
 907     (calculator-output-radix
 908      (setq calculator-radix-grouping-mode
 909            (not calculator-radix-grouping-mode))
 910      (calculator-message
 911       "Digit grouping mode %s."
 912       (if calculator-radix-grouping-mode "ON" "OFF")))
 913     (t
 914      (setq calculator-displayers
 915            (if (and new-disp (memq new-disp calculator-displayers))
 916              (let ((tmp nil))
 917                (while (not (eq (car calculator-displayers) new-disp))
 918                  (setq tmp (cons (car calculator-displayers) tmp))
 919                  (setq calculator-displayers
 920                        (cdr calculator-displayers)))
 921                (setq calculator-displayers
 922                      (nconc calculator-displayers (nreverse tmp))))
 923              (nconc (cdr calculator-displayers)
 924                     (list (car calculator-displayers)))))
 925      (calculator-message
 926       "Using %s." (cadr (car calculator-displayers)))))
 927   (calculator-enter))
 928
 929 (defun calculator-rotate-displayer-back ()
 930   "Like `calculator-rotate-displayer', but rotates modes back.
 931 If radix output mode is active, toggle digit grouping."
 932   (interactive)
 933   (calculator-rotate-displayer (car (last calculator-displayers))))
 934
 935 (defun calculator-displayer-prev ()
 936   "Send the current displayer function a 'left argument.
 937 This is used to modify display arguments (if the current displayer
 938 function supports this).
 939 If radix output mode is active, increase the grouping size."
 940   (interactive)
 941   (if calculator-output-radix
 942     (progn (setq calculator-radix-grouping-digits
 943                  (1+ calculator-radix-grouping-digits))
 944            (calculator-enter))
 945     (and (car calculator-displayers)
 946          (let ((disp (caar calculator-displayers)))
 947            (cond
 948              ((symbolp disp) (funcall disp 'left))
 949              ((and (consp disp) (eq 'std (car disp)))
 950               (calculator-standard-displayer 'left (cadr disp))))))))
 951
 952 (defun calculator-displayer-next ()
 953   "Send the current displayer function a 'right argument.
 954 This is used to modify display arguments (if the current displayer
 955 function supports this).
 956 If radix output mode is active, decrease the grouping size."
 957   (interactive)
 958   (if calculator-output-radix
 959     (progn (setq calculator-radix-grouping-digits
 960                  (max 2 (1- calculator-radix-grouping-digits)))
 961            (calculator-enter))
 962     (and (car calculator-displayers)
 963          (let ((disp (caar calculator-displayers)))
 964            (cond
 965              ((symbolp disp) (funcall disp 'right))
 966              ((and (consp disp) (eq 'std (car disp)))
 967               (calculator-standard-displayer 'right (cadr disp))))))))
 968
 969 (defun calculator-remove-zeros (numstr)
 970   "Get a number string NUMSTR and remove unnecessary zeroes.
 971 the behavior of this function is controlled by
 972 `calculator-remove-zeros'."
 973   (cond ((and (eq calculator-remove-zeros t)
 974               (string-match "\\.0+\\([eE][+-]?[0-9]*\\)?$" numstr))
 975          ;; remove all redundant zeros leaving an integer
 976          (if (match-beginning 1)
 977            (concat (substring numstr 0 (match-beginning 0))
 978                    (match-string 1 numstr))
 979            (substring numstr 0 (match-beginning 0))))
 980         ((and calculator-remove-zeros
 981               (string-match
 982                "\\..\\([0-9]*[1-9]\\)?\\(0+\\)\\([eE][+-]?[0-9]*\\)?$"
 983                numstr))
 984          ;; remove zeros, except for first after the "."
 985          (if (match-beginning 3)
 986            (concat (substring numstr 0 (match-beginning 2))
 987                    (match-string 3 numstr))
 988            (substring numstr 0 (match-beginning 2))))
 989         (t numstr)))
 990
 991 (defun calculator-standard-displayer (num char)
 992   "Standard display function, used to display NUM.
 993 Its behavior is determined by `calculator-number-digits' and the given
 994 CHAR argument (both will be used to compose a format string).  If the
 995 char is \"n\" then this function will choose one between %f or %e, this
 996 is a work around %g jumping to exponential notation too fast.
 997
 998 The special 'left and 'right symbols will make it change the current
 999 number of digits displayed (`calculator-number-digits').
1000
1001 It will also remove redundant zeros from the result."
1002   (if (symbolp num)
1003     (cond ((eq num 'left)
1004            (and (> calculator-number-digits 0)
1005                 (setq calculator-number-digits
1006                       (1- calculator-number-digits))
1007                 (calculator-enter)))
1008           ((eq num 'right)
1009            (setq calculator-number-digits
1010                  (1+ calculator-number-digits))
1011            (calculator-enter)))
1012     (let ((str (if (zerop num)
1013                  "0"
1014                  (format
1015                   (concat "%."
1016                           (number-to-string calculator-number-digits)
1017                           (if (eq char ?n)
1018                             (let ((n (abs num)))
1019                               (if (or (< n 0.001) (> n 1e8)) "e" "f"))
1020                             (string char)))
1021                   num))))
1022       (calculator-remove-zeros str))))
1023
1024 (defun calculator-eng-display (num)
1025   "Display NUM in engineering notation.
1026 The number of decimal digits used is controlled by
1027 `calculator-number-digits', so to change it at runtime you have to use
1028 the 'left or 'right when one of the standard modes is used."
1029   (if (symbolp num)
1030     (cond ((eq num 'left)
1031            (setq calculator-eng-extra
1032                  (if calculator-eng-extra
1033                    (1+ calculator-eng-extra)
1034                    1))
1035            (let ((calculator-eng-tmp-show t)) (calculator-enter)))
1036           ((eq num 'right)
1037            (setq calculator-eng-extra
1038                  (if calculator-eng-extra
1039                    (1- calculator-eng-extra)
1040                    -1))
1041            (let ((calculator-eng-tmp-show t)) (calculator-enter))))
1042     (let ((exp 0))
1043       (and (not (= 0 num))
1044            (progn
1045              (while (< (abs num) 1.0)
1046                (setq num (* num 1000.0)) (setq exp (- exp 3)))
1047              (while (> (abs num) 999.0)
1048                (setq num (/ num 1000.0)) (setq exp (+ exp 3)))
1049              (and calculator-eng-tmp-show
1050                   (not (= 0 calculator-eng-extra))
1051                   (let ((i calculator-eng-extra))
1052                     (while (> i 0)
1053                       (setq num (* num 1000.0)) (setq exp (- exp 3))
1054                       (setq i (1- i)))
1055                     (while (< i 0)
1056                       (setq num (/ num 1000.0)) (setq exp (+ exp 3))
1057                       (setq i (1+ i)))))))
1058       (or calculator-eng-tmp-show (setq calculator-eng-extra nil))
1059       (let ((str (format (concat "%." (number-to-string
1060                                        calculator-number-digits)
1061                                  "f")
1062                          num)))
1063         (concat (let ((calculator-remove-zeros
1064                        ;; make sure we don't leave integers
1065                        (and calculator-remove-zeros 'x)))
1066                   (calculator-remove-zeros str))
1067                 "e" (number-to-string exp))))))
1068
1069 (defun calculator-number-to-string (num)
1070   "Convert NUM to a displayable string."
1071   (cond
1072     ((and (numberp num) calculator-output-radix)
1073      ;; print with radix - for binary I convert the octal number
1074      (let ((str (format (if (eq calculator-output-radix 'hex) "%x" "%o")
1075                         (calculator-truncate
1076                          (if calculator-2s-complement num (abs num))))))
1077        (if (eq calculator-output-radix 'bin)
1078          (let ((i -1) (s ""))
1079            (while (< (setq i (1+ i)) (length str))
1080              (setq s
1081                    (concat s
1082                            (cdr (assq (aref str i)
1083                                       '((?0 . "000") (?1 . "001")
1084                                         (?2 . "010") (?3 . "011")
1085                                         (?4 . "100") (?5 . "101")
1086                                         (?6 . "110") (?7 . "111")))))))
1087            (string-match "^0*\\(.+\\)" s)
1088            (setq str (match-string 1 s))))
1089        (if calculator-radix-grouping-mode
1090          (let ((d (/ (length str) calculator-radix-grouping-digits))
1091                (r (% (length str) calculator-radix-grouping-digits)))
1092            (while (>= (setq d (1- d)) (if (zerop r) 1 0))
1093              (let ((i (+ r (* d calculator-radix-grouping-digits))))
1094                (setq str (concat (substring str 0 i)
1095                                  calculator-radix-grouping-separator
1096                                  (substring str i)))))))
1097        (upcase
1098         (if (and (not calculator-2s-complement) (< num 0))
1099           (concat "-" str)
1100           str))))
1101     ((and (numberp num) calculator-displayer)
1102      (cond
1103        ((stringp calculator-displayer)
1104         (format calculator-displayer num))
1105        ((symbolp calculator-displayer)
1106         (funcall calculator-displayer num))
1107        ((and (consp calculator-displayer)
1108              (eq 'std (car calculator-displayer)))
1109         (calculator-standard-displayer num (cadr calculator-displayer)))
1110        ((listp calculator-displayer)
1111         (eval calculator-displayer))
1112        (t (prin1-to-string num t))))
1113     ;; operators are printed here
1114     (t (prin1-to-string (nth 1 num) t))))
1115
1116 (defun calculator-update-display (&optional force)
1117   "Update the display.
1118 If optional argument FORCE is non-nil, don't use the cached string."
1119   (set-buffer calculator-buffer)
1120   ;; update calculator-stack-display
1121   (if (or force
1122           (not (eq (car calculator-stack-display) calculator-stack)))
1123     (setq calculator-stack-display
1124           (cons calculator-stack
1125                 (if calculator-stack
1126                   (concat
1127                    (let ((calculator-displayer
1128                           (if (and calculator-displayers
1129                                    (= 1 (length calculator-stack)))
1130                             ;; customizable display for a single value
1131                             (caar calculator-displayers)
1132                             calculator-displayer)))
1133                      (mapconcat 'calculator-number-to-string
1134                                 (reverse calculator-stack)
1135                                 " "))
1136                    " "
1137                    (and calculator-display-fragile
1138                         calculator-saved-list
1139                         (= (car calculator-stack)
1140                            (nth calculator-saved-ptr
1141                                 calculator-saved-list))
1142                         (if (= 0 calculator-saved-ptr)
1143                           (format "[%s]" (length calculator-saved-list))
1144                           (format "[%s/%s]"
1145                                   (- (length calculator-saved-list)
1146                                      calculator-saved-ptr)
1147                                   (length calculator-saved-list)))))
1148                   ""))))
1149   (let ((inhibit-read-only t))
1150     (erase-buffer)
1151     (insert (calculator-get-prompt)))
1152   (set-buffer-modified-p nil)
1153   (if calculator-display-fragile
1154     (goto-char (1+ (length calculator-prompt)))
1155     (goto-char (1- (point)))))
1156
1157 ;;;---------------------------------------------------------------------
1158 ;;; Stack computations
1159
1160 (defun calculator-reduce-stack (prec)
1161   "Reduce the stack using top operator.
1162 PREC is a precedence - reduce everything with higher precedence."
1163   (while
1164       (cond
1165         ((and (cdr (cdr calculator-stack))         ; have three values
1166               (consp   (nth 0 calculator-stack))   ; two operators & num
1167               (numberp (nth 1 calculator-stack))
1168               (consp   (nth 2 calculator-stack))
1169               (eq '\) (nth 1 (nth 0 calculator-stack)))
1170               (eq '\( (nth 1 (nth 2 calculator-stack))))
1171          ;; reduce "... ( x )" --> "... x"
1172          (setq calculator-stack
1173                (cons (nth 1 calculator-stack)
1174                      (nthcdr 3 calculator-stack)))
1175          ;; another iteration
1176          t)
1177         ((and (cdr (cdr calculator-stack))         ; have three values
1178               (numberp (nth 0 calculator-stack))   ; two nums & operator
1179               (consp   (nth 1 calculator-stack))
1180               (numberp (nth 2 calculator-stack))
1181               (= 2 (calculator-op-arity            ; binary operator
1182                     (nth 1 calculator-stack)))
1183               (<= prec                             ; with higher prec.
1184                   (calculator-op-prec (nth 1 calculator-stack))))
1185          ;; reduce "... x op y" --> "... r", r is the result
1186          (setq calculator-stack
1187                (cons (calculator-funcall
1188                       (nth 2 (nth 1 calculator-stack))
1189                       (nth 2 calculator-stack)
1190                       (nth 0 calculator-stack))
1191                      (nthcdr 3 calculator-stack)))
1192          ;; another iteration
1193          t)
1194         ((and (>= (length calculator-stack) 2)     ; have two values
1195               (numberp (nth 0 calculator-stack))   ; number & operator
1196               (consp   (nth 1 calculator-stack))
1197               (= -1 (calculator-op-arity           ; prefix-unary op
1198                      (nth 1 calculator-stack)))
1199               (<= prec                             ; with higher prec.
1200                   (calculator-op-prec (nth 1 calculator-stack))))
1201          ;; reduce "... op x" --> "... r" for prefix op
1202          (setq calculator-stack
1203                (cons (calculator-funcall
1204                       (nth 2 (nth 1 calculator-stack))
1205                       (nth 0 calculator-stack))
1206                      (nthcdr 2 calculator-stack)))
1207          ;; another iteration
1208          t)
1209         ((and (cdr calculator-stack)               ; have two values
1210               (consp   (nth 0 calculator-stack))   ; operator & number
1211               (numberp (nth 1 calculator-stack))
1212               (= +1 (calculator-op-arity           ; postfix-unary op
1213                      (nth 0 calculator-stack)))
1214               (<= prec                             ; with higher prec.
1215                   (calculator-op-prec (nth 0 calculator-stack))))
1216          ;; reduce "... x op" --> "... r" for postfix op
1217          (setq calculator-stack
1218                (cons (calculator-funcall
1219                       (nth 2 (nth 0 calculator-stack))
1220                       (nth 1 calculator-stack))
1221                      (nthcdr 2 calculator-stack)))
1222          ;; another iteration
1223          t)
1224         ((and calculator-stack                     ; have one value
1225               (consp (nth 0 calculator-stack))     ; an operator
1226               (= 0 (calculator-op-arity            ; 0-ary op
1227                     (nth 0 calculator-stack))))
1228          ;; reduce "... op" --> "... r" for 0-ary op
1229          (setq calculator-stack
1230                (cons (calculator-funcall
1231                       (nth 2 (nth 0 calculator-stack)))
1232                      (nthcdr 1 calculator-stack)))
1233          ;; another iteration
1234          t)
1235         ((and (cdr calculator-stack)               ; have two values
1236               (numberp (nth 0 calculator-stack))   ; both numbers
1237               (numberp (nth 1 calculator-stack)))
1238          ;; get rid of redundant numbers:
1239          ;;   reduce "... y x" --> "... x"
1240          ;; needed for 0-ary ops that puts more values
1241          (setcdr calculator-stack (cdr (cdr calculator-stack))))
1242         (t ;; no more iterations
1243            nil))))
1244
1245 (defun calculator-funcall (f &optional X Y)
1246   "If F is a symbol, evaluate (F X Y).
1247 Otherwise, it should be a list, evaluate it with X, Y bound to the
1248 arguments."
1249   ;; remember binary ops for calculator-repR/L
1250   (if Y (setq calculator-last-opXY (list f X Y)))
1251   (condition-case nil
1252       ;; there used to be code here that returns 0 if the result was
1253       ;; smaller than calculator-epsilon (1e-15).  I don't think this is
1254       ;; necessary now.
1255       (if (symbolp f)
1256         (cond ((and X Y) (funcall f X Y))
1257               (X         (funcall f X))
1258               (t         (funcall f)))
1259         ;; f is an expression
1260         (let* ((__f__ f) ; so we can get this value below...
1261                (TX (calculator-truncate X))
1262                (TY (and Y (calculator-truncate Y)))
1263                (DX (if calculator-deg (/ (* X pi) 180) X))
1264                (L  calculator-saved-list)
1265                (Fbound (fboundp 'F))
1266                (Fsave  (and Fbound (symbol-function 'F)))
1267                (Dbound (fboundp 'D))
1268                (Dsave  (and Dbound (symbol-function 'D))))
1269           ;; a shortened version of flet
1270           (fset 'F (function
1271                     (lambda (&optional x y)
1272                       (calculator-funcall __f__ x y))))
1273           (fset 'D (function
1274                     (lambda (x)
1275                       (if calculator-deg (/ (* x 180) pi) x))))
1276           (unwind-protect (eval f)
1277             (if Fbound (fset 'F Fsave) (fmakunbound 'F))
1278             (if Dbound (fset 'D Dsave) (fmakunbound 'D)))))
1279     (error 0)))
1280
1281 ;;;---------------------------------------------------------------------
1282 ;;; Input interaction
1283
1284 (defun calculator-last-input (&optional keys)
1285   "Last char (or event or event sequence) that was read.
1286 Optional string argument KEYS will force using it as the keys entered."
1287   (let ((inp (or keys (this-command-keys))))
1288     (if (or (stringp inp) (not (arrayp inp)))
1289       inp
1290       ;; this translates kp-x to x and [tries to] create a string to
1291       ;; lookup operators
1292       (let* ((i -1) (converted-str (make-string (length inp) ? )) k)
1293         ;; converts an array to a string the ops lookup with keypad
1294         ;; input
1295         (while (< (setq i (1+ i)) (length inp))
1296           (setq k (aref inp i))
1297           ;; if Emacs will someday have a event-key, then this would
1298           ;; probably be modified anyway
1299           (and (if (fboundp 'key-press-event-p) (key-press-event-p k))
1300                (if (fboundp 'event-key)
1301                    (and (event-key k) (setq k (event-key k)))))
1302           ;; assume all symbols are translatable with an ascii-character
1303           (and (symbolp k)
1304                (setq k (or (get k 'ascii-character) ? )))
1305           (aset converted-str i k))
1306         converted-str))))
1307
1308 (defun calculator-clear-fragile (&optional op)
1309   "Clear the fragile flag if it was set, then maybe reset all.
1310 OP is the operator (if any) that caused this call."
1311   (if (and calculator-display-fragile
1312            (or (not op)
1313                (= -1 (calculator-op-arity op))
1314                (= 0 (calculator-op-arity op))))
1315     ;; reset if last calc finished, and now get a num or prefix or 0-ary
1316     ;; op
1317     (calculator-reset))
1318   (setq calculator-display-fragile nil))
1319
1320 (defun calculator-digit ()
1321   "Enter a single digit."
1322   (interactive)
1323   (let ((inp (aref (calculator-last-input) 0)))
1324     (if (and (or calculator-display-fragile
1325                  (not (numberp (car calculator-stack))))
1326              (cond
1327                ((not calculator-input-radix)     (<= inp ?9))
1328                ((eq calculator-input-radix 'bin) (<= inp ?1))
1329                ((eq calculator-input-radix 'oct) (<= inp ?7))
1330                (t t)))
1331       ;; enter digit if starting a new computation or have an op on the
1332       ;; stack
1333       (progn
1334         (calculator-clear-fragile)
1335         (let ((digit (upcase (char-to-string inp))))
1336           (if (equal calculator-curnum "0")
1337             (setq calculator-curnum nil))
1338           (setq calculator-curnum
1339                 (concat (or calculator-curnum "") digit)))
1340         (calculator-update-display)))))
1341
1342 (defun calculator-decimal ()
1343   "Enter a decimal period."
1344   (interactive)
1345   (if (and (not calculator-input-radix)
1346            (or calculator-display-fragile
1347                (not (numberp (car calculator-stack))))
1348            (not (and calculator-curnum
1349                      (string-match "[.eE]" calculator-curnum))))
1350     ;; enter the period on the same condition as a digit, only if no
1351     ;; period or exponent entered yet
1352     (progn
1353       (calculator-clear-fragile)
1354       (setq calculator-curnum (concat (or calculator-curnum "0") "."))
1355       (calculator-update-display))))
1356
1357 (defun calculator-exp ()
1358   "Enter an `E' exponent character, or a digit in hex input mode."
1359   (interactive)
1360   (if calculator-input-radix
1361     (calculator-digit)
1362     (if (and (or calculator-display-fragile
1363                  (not (numberp (car calculator-stack))))
1364              (not (and calculator-curnum
1365                        (string-match "[eE]" calculator-curnum))))
1366       ;; same condition as above, also no E so far
1367       (progn
1368         (calculator-clear-fragile)
1369         (setq calculator-curnum (concat (or calculator-curnum "1") "e"))
1370         (calculator-update-display)))))
1371
1372 (defun calculator-op (&optional keys)
1373   "Enter an operator on the stack, doing all necessary reductions.
1374 Optional string argument KEYS will force using it as the keys entered."
1375   (interactive)
1376   (catch 'op-error
1377     (let* ((last-inp (calculator-last-input keys))
1378            (op (assoc last-inp calculator-operators)))
1379       (calculator-clear-fragile op)
1380       (if (and calculator-curnum (/= (calculator-op-arity op) 0))
1381         (setq calculator-stack
1382               (cons (calculator-curnum-value) calculator-stack)))
1383       (setq calculator-curnum nil)
1384       (if (and (= 2 (calculator-op-arity op))
1385                (not (and calculator-stack
1386                          (numberp (nth 0 calculator-stack)))))
1387         ;; we have a binary operator but no number - search for a prefix
1388         ;; version
1389         (let ((rest-ops calculator-operators))
1390           (while (not (equal last-inp (car (car rest-ops))))
1391             (setq rest-ops (cdr rest-ops)))
1392           (setq op (assoc last-inp (cdr rest-ops)))
1393           (if (not (and op (= -1 (calculator-op-arity op))))
1394             ;;(error "Binary operator without a first operand")
1395             (progn
1396               (calculator-message
1397                "Binary operator without a first operand")
1398               (throw 'op-error nil)))))
1399       (calculator-reduce-stack
1400        (cond ((eq (nth 1 op) '\() 10)
1401              ((eq (nth 1 op) '\)) 0)
1402              (t (calculator-op-prec op))))
1403       (if (or (and (= -1 (calculator-op-arity op))
1404                    (numberp (car calculator-stack)))
1405               (and (/= (calculator-op-arity op) -1)
1406                    (/= (calculator-op-arity op) 0)
1407                    (not (numberp (car calculator-stack)))))
1408         ;;(error "Unterminated expression")
1409         (progn
1410           (calculator-message "Unterminated expression")
1411           (throw 'op-error nil)))
1412       (setq calculator-stack (cons op calculator-stack))
1413       (calculator-reduce-stack (calculator-op-prec op))
1414       (and (= (length calculator-stack) 1)
1415            (numberp (nth 0 calculator-stack))
1416            ;; the display is fragile if it contains only one number
1417            (setq calculator-display-fragile t)
1418            ;; add number to the saved-list
1419            calculator-add-saved
1420            (if (= 0 calculator-saved-ptr)
1421              (setq calculator-saved-list
1422                    (cons (car calculator-stack) calculator-saved-list))
1423              (let ((p (nthcdr (1- calculator-saved-ptr)
1424                               calculator-saved-list)))
1425                (setcdr p (cons (car calculator-stack) (cdr p))))))
1426       (calculator-update-display))))
1427
1428 (defun calculator-op-or-exp ()
1429   "Either enter an operator or a digit.
1430 Used with +/- for entering them as digits in numbers like 1e-3 (there is
1431 no need for negative numbers since these are handled by unary
1432 operators)."
1433   (interactive)
1434   (if (and (not calculator-display-fragile)
1435            calculator-curnum
1436            (string-match "[eE]$" calculator-curnum))
1437     (calculator-digit)
1438     (calculator-op)))
1439
1440 ;;;---------------------------------------------------------------------
1441 ;;; Input/output modes (not display)
1442
1443 (defun calculator-dec/deg-mode ()
1444   "Set decimal mode for display & input, if decimal, toggle deg mode."
1445   (interactive)
1446   (if calculator-curnum
1447     (setq calculator-stack
1448           (cons (calculator-curnum-value) calculator-stack)))
1449   (setq calculator-curnum nil)
1450   (if (or calculator-input-radix calculator-output-radix)
1451     (progn (setq calculator-input-radix nil)
1452            (setq calculator-output-radix nil))
1453     ;; already decimal - toggle degrees mode
1454     (setq calculator-deg (not calculator-deg)))
1455   (calculator-update-display t))
1456
1457 (defun calculator-radix-mode (&optional keys)
1458   "Set input and display radix modes.
1459 Optional string argument KEYS will force using it as the keys entered."
1460   (interactive)
1461   (calculator-radix-input-mode keys)
1462   (calculator-radix-output-mode keys))
1463
1464 (defun calculator-radix-input-mode (&optional keys)
1465   "Set input radix modes.
1466 Optional string argument KEYS will force using it as the keys entered."
1467   (interactive)
1468   (if calculator-curnum
1469     (setq calculator-stack
1470           (cons (calculator-curnum-value) calculator-stack)))
1471   (setq calculator-curnum nil)
1472   (setq calculator-input-radix
1473         (let ((inp (calculator-last-input keys)))
1474           (cdr (assq (upcase (aref inp (1- (length inp))))
1475                      calculator-char-radix))))
1476   (calculator-update-display))
1477
1478 (defun calculator-radix-output-mode (&optional keys)
1479   "Set display radix modes.
1480 Optional string argument KEYS will force using it as the keys entered."
1481   (interactive)
1482   (if calculator-curnum
1483     (setq calculator-stack
1484           (cons (calculator-curnum-value) calculator-stack)))
1485   (setq calculator-curnum nil)
1486   (setq calculator-output-radix
1487         (let ((inp (calculator-last-input keys)))
1488           (cdr (assq (upcase (aref inp (1- (length inp))))
1489                      calculator-char-radix))))
1490   (calculator-update-display t))
1491
1492 ;;;---------------------------------------------------------------------
1493 ;;; Saved values list
1494
1495 (defun calculator-save-on-list ()
1496   "Evaluate current expression, put result on the saved values list."
1497   (interactive)
1498   (let ((calculator-add-saved t)) ; marks the result to be added
1499     (calculator-enter)))
1500
1501 (defun calculator-clear-saved ()
1502   "Clear the list of saved values in `calculator-saved-list'."
1503   (interactive)
1504   (setq calculator-saved-list nil)
1505   (setq calculator-saved-ptr 0)
1506   (calculator-update-display t))
1507
1508 (defun calculator-saved-move (n)
1509   "Go N elements up the list of saved values."
1510   (interactive)
1511   (and calculator-saved-list
1512        (or (null calculator-stack) calculator-display-fragile)
1513        (progn
1514          (setq calculator-saved-ptr
1515                (max (min (+ n calculator-saved-ptr)
1516                          (length calculator-saved-list))
1517                     0))
1518          (if (nth calculator-saved-ptr calculator-saved-list)
1519            (setq calculator-stack
1520                  (list (nth calculator-saved-ptr calculator-saved-list))
1521                  calculator-display-fragile t)
1522            (calculator-reset))
1523          (calculator-update-display))))
1524
1525 (defun calculator-saved-up ()
1526   "Go up the list of saved values."
1527   (interactive)
1528   (calculator-saved-move +1))
1529
1530 (defun calculator-saved-down ()
1531   "Go down the list of saved values."
1532   (interactive)
1533   (calculator-saved-move -1))
1534
1535 ;;;---------------------------------------------------------------------
1536 ;;; Misc functions
1537
1538 (defun calculator-open-paren ()
1539   "Equivalents of `(' use this."
1540   (interactive)
1541   (calculator-op "("))
1542
1543 (defun calculator-close-paren ()
1544   "Equivalents of `)' use this."
1545   (interactive)
1546   (calculator-op ")"))
1547
1548 (defun calculator-enter ()
1549   "Evaluate current expression."
1550   (interactive)
1551   (calculator-op "="))
1552
1553 (defun calculator-backspace ()
1554   "Backward delete a single digit or a stack element."
1555   (interactive)
1556   (if calculator-curnum
1557     (setq calculator-curnum
1558           (if (> (length calculator-curnum) 1)
1559             (substring calculator-curnum
1560                        0 (1- (length calculator-curnum)))
1561             nil))
1562     (setq calculator-stack (cdr calculator-stack)))
1563   (calculator-update-display))
1564
1565 (defun calculator-clear ()
1566   "Clear current number."
1567   (interactive)
1568   (setq calculator-curnum nil)
1569   (cond
1570     ;; if the current number is from the saved-list - remove it
1571     ((and calculator-display-fragile
1572           calculator-saved-list
1573           (= (car calculator-stack)
1574              (nth calculator-saved-ptr calculator-saved-list)))
1575      (if (= 0 calculator-saved-ptr)
1576        (setq calculator-saved-list (cdr calculator-saved-list))
1577        (let ((p (nthcdr (1- calculator-saved-ptr)
1578                         calculator-saved-list)))
1579          (setcdr p (cdr (cdr p)))
1580          (setq calculator-saved-ptr (1- calculator-saved-ptr))))
1581      (if calculator-saved-list
1582        (setq calculator-stack
1583              (list (nth calculator-saved-ptr calculator-saved-list)))
1584        (calculator-reset)))
1585     ;; reset if fragile or double clear
1586     ((or calculator-display-fragile (eq last-command this-command))
1587      (calculator-reset)))
1588   (calculator-update-display))
1589
1590 (defun calculator-copy ()
1591   "Copy current number to the `kill-ring'."
1592   (interactive)
1593   (let ((calculator-displayer
1594          (or calculator-copy-displayer calculator-displayer))
1595         (calculator-displayers
1596          (if calculator-copy-displayer nil calculator-displayers)))
1597     (calculator-enter)
1598     ;; remove trailing spaces and an index
1599     (let ((s (cdr calculator-stack-display)))
1600       (and s
1601            (if (string-match "^\\([^ ]+\\) *\\(\\[[0-9/]+\\]\\)? *$" s)
1602              (setq s (match-string 1 s)))
1603            (kill-new s)))))
1604
1605 (defun calculator-set-register (reg)
1606   "Set a register value for REG."
1607   (interactive "cRegister to store into: ")
1608   (let* ((as  (assq reg calculator-registers))
1609          (val (progn (calculator-enter) (car calculator-stack))))
1610     (if as
1611       (setcdr as val)
1612       (setq calculator-registers
1613             (cons (cons reg val) calculator-registers)))
1614     (calculator-message "[%c] := %S" reg val)))
1615
1616 (defun calculator-put-value (val)
1617   "Paste VAL as if entered.
1618 Used by `calculator-paste' and `get-register'."
1619   (if (and (numberp val)
1620            ;; (not calculator-curnum)
1621            (or calculator-display-fragile
1622                (not (numberp (car calculator-stack)))))
1623     (progn
1624       (calculator-clear-fragile)
1625       (setq calculator-curnum (let ((calculator-displayer "%S"))
1626                                 (calculator-number-to-string val)))
1627       (calculator-update-display))))
1628
1629 (defun calculator-paste ()
1630   "Paste a value from the `kill-ring'."
1631   (interactive)
1632   (calculator-put-value
1633    (let ((str (replace-regexp-in-string
1634                "^ *\\(.+[^ ]\\) *$" "\\1" (current-kill 0))))
1635      (and (not calculator-input-radix)
1636           calculator-paste-decimals
1637           (string-match "\\([0-9]+\\)\\(\\.[0-9]+\\)?\\(e[0-9]+\\)?"
1638                         str)
1639           (or (match-string 1 str)
1640               (match-string 2 str)
1641               (match-string 3 str))
1642           (setq str (concat (or (match-string 1 str) "0")
1643                             (or (match-string 2 str) ".0")
1644                             (or (match-string 3 str) ""))))
1645      (condition-case nil (calculator-string-to-number str)
1646        (error nil)))))
1647
1648 (defun calculator-get-register (reg)
1649   "Get a value from a register REG."
1650   (interactive "cRegister to get value from: ")
1651   (calculator-put-value (cdr (assq reg calculator-registers))))
1652
1653 (defun calculator-help ()
1654   ;; this is used as the quick reference screen you get with `h'
1655   "Quick reference:
1656 * numbers/operators/parens/./e - enter expressions
1657   + - * / \\(div) %(rem) _(-X,postfix) ;(1/X,postfix) ^(exp) L(og)
1658   Q(sqrt) !(fact) S(in) C(os) T(an) |(or) #(xor) &(and) ~(not)
1659 * >/< repeats last binary operation with its 2nd (1st) arg as postfix op
1660 * I inverses next trig function        * '/\"/{} - display/display args
1661 * D         - switch to all-decimal, or toggle deg/rad mode
1662 * B/O/H/X   - binary/octal/hex mode for i/o (X is a shortcut for H)
1663 * i/o       - prefix for d/b/o/x - set only input/output modes
1664 * enter/=   - evaluate current expr.   * s/g      - set/get a register
1665 * space     - evaluate & save on list  * l/v      - list total/average
1666 * up/down/C-p/C-n - browse saved       * C-delete - clear all saved
1667 * C-insert  - copy whole expr.         * C-return - evaluate, copy, exit
1668 * insert    - paste a number           * backspace- delete backwards
1669 * delete    - clear argument or list value or whole expression (twice)
1670 * escape/q  - exit."
1671   (interactive)
1672   (if (eq last-command 'calculator-help)
1673     (let ((mode-name "Calculator")
1674           (major-mode 'calculator-mode)
1675           (g-map (current-global-map))
1676           (win (selected-window)))
1677       (require 'ehelp)
1678       (if calculator-electric-mode
1679         (use-global-map calculator-saved-global-map))
1680       (if (or (not calculator-electric-mode)
1681               ;; XEmacs has a problem with electric-describe-mode
1682               (string-match "XEmacs" (emacs-version)))
1683         (describe-mode)
1684         (electric-describe-mode))
1685       (if calculator-electric-mode
1686         (use-global-map g-map))
1687       (select-window win) ; these are for XEmacs (also below)
1688       (message nil))
1689     (let ((one (one-window-p t))
1690           (win (selected-window))
1691           (help-buf (get-buffer-create "*Help*")))
1692       (save-window-excursion
1693         (with-output-to-temp-buffer "*Help*"
1694           (princ (documentation 'calculator-help)))
1695         (if one
1696           (shrink-window-if-larger-than-buffer
1697            (get-buffer-window help-buf)))
1698         (message
1699          "`%s' again for more help, any other key continues normally."
1700          (calculator-last-input))
1701         (select-window win)
1702         (sit-for 360))
1703       (select-window win))))
1704
1705 (defun calculator-quit ()
1706   "Quit calculator."
1707   (interactive)
1708   (set-buffer calculator-buffer)
1709   (let ((inhibit-read-only t)) (erase-buffer))
1710   (if (not calculator-electric-mode)
1711     (progn
1712       (condition-case nil
1713           (while (get-buffer-window calculator-buffer)
1714             (delete-window (get-buffer-window calculator-buffer)))
1715         (error nil))
1716       (kill-buffer calculator-buffer)))
1717   (setq calculator-buffer nil)
1718   (message "Calculator done.")
1719   (if calculator-electric-mode (throw 'calculator-done nil)))
1720
1721 (defun calculator-save-and-quit ()
1722   "Quit the calculator, saving the result on the `kill-ring'."
1723   (interactive)
1724   (calculator-enter)
1725   (calculator-copy)
1726   (calculator-quit))
1727
1728 (defun calculator-repR (x)
1729   "Repeats the last binary operation with its second argument and X.
1730 To use this, apply a binary operator (evaluate it), then call this."
1731   (if calculator-last-opXY
1732     ;; avoid rebinding calculator-last-opXY
1733     (let ((calculator-last-opXY calculator-last-opXY))
1734       (calculator-funcall
1735        (car calculator-last-opXY) x (nth 2 calculator-last-opXY)))
1736     x))
1737
1738 (defun calculator-repL (x)
1739   "Repeats the last binary operation with its first argument and X.
1740 To use this, apply a binary operator (evaluate it), then call this."
1741   (if calculator-last-opXY
1742     ;; avoid rebinding calculator-last-opXY
1743     (let ((calculator-last-opXY calculator-last-opXY))
1744       (calculator-funcall
1745        (car calculator-last-opXY) (nth 1 calculator-last-opXY) x))
1746     x))
1747
1748 (defun calculator-fact (x)
1749   "Simple factorial of X."
1750   (let ((r (if (<= x 10) 1 1.0)))
1751     (while (> x 0)
1752       (setq r (* r (truncate x)))
1753       (setq x (1- x)))
1754     (+ 0.0 r)))
1755
1756 (defun calculator-truncate (n)
1757   "Truncate N, return 0 in case of overflow."
1758   (condition-case nil (truncate n) (error 0)))
1759
1760
1761 (provide 'calculator)
1762
1763 ;;; arch-tag: a1b9766c-af8a-4a74-b466-65ad8eeb0c73
1764 ;;; calculator.el ends here