lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'syntax)
  29
  30 (defvar comint-prompt-regexp)
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40 \f
  41 ;;; Switching tooltips on/off
  42
  43 (define-minor-mode tooltip-mode
  44   "Toggle Tooltip mode.
  45 With a prefix argument ARG, enable Tooltip mode if ARG is positive,
  46 and disable it otherwise.  If called from Lisp, enable the mode
  47 if ARG is omitted or nil.
  48
  49 When this global minor mode is enabled, Emacs displays help
  50 text (e.g. for buttons and menu items that you put the mouse on)
  51 in a pop-up window.
  52
  53 When Tooltip mode is disabled, Emacs displays help text in the
  54 echo area, instead of making a pop-up window."
  55   :global t
  56   ;; Even if we start on a text-only terminal, make this non-nil by
  57   ;; default because we can open a graphical frame later (multi-tty).
  58   :init-value t
  59   :initialize 'custom-initialize-delay
  60   :group 'tooltip
  61   (if (and tooltip-mode (fboundp 'x-show-tip))
  62       (progn
  63         (add-hook 'pre-command-hook 'tooltip-hide)
  64         (add-hook 'tooltip-functions 'tooltip-help-tips))
  65     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  66       (remove-hook 'pre-command-hook 'tooltip-hide))
  67     (remove-hook 'tooltip-functions 'tooltip-help-tips))
  68   (setq show-help-function
  69         (if tooltip-mode 'tooltip-show-help 'tooltip-show-help-non-mode)))
  70
  71 \f
  72 ;;; Customizable settings
  73
  74 (defcustom tooltip-delay 0.7
  75   "Seconds to wait before displaying a tooltip the first time."
  76   :type 'number
  77   :group 'tooltip)
  78
  79 (defcustom tooltip-short-delay 0.1
  80   "Seconds to wait between subsequent tooltips on different items."
  81   :type 'number
  82   :group 'tooltip)
  83
  84 (defcustom tooltip-recent-seconds 1
  85   "Display tooltips if changing tip items within this many seconds.
  86 Do so after `tooltip-short-delay'."
  87   :type 'number
  88   :group 'tooltip)
  89
  90 (defcustom tooltip-hide-delay 10
  91   "Hide tooltips automatically after this many seconds."
  92   :type 'number
  93   :group 'tooltip)
  94
  95 (defcustom tooltip-x-offset 5
  96   "X offset, in pixels, for the display of tooltips.
  97 The offset is the distance between the X position of the mouse and
  98 the left border of the tooltip window.  It must be chosen so that the
  99 tooltip window doesn't contain the mouse when it pops up, or it may
 100 interfere with clicking where you wish.
 101
 102 If `tooltip-frame-parameters' includes the `left' parameter,
 103 the value of `tooltip-x-offset' is ignored."
 104   :type 'integer
 105   :group 'tooltip)
 106
 107 (defcustom tooltip-y-offset +20
 108   "Y offset, in pixels, for the display of tooltips.
 109 The offset is the distance between the Y position of the mouse and
 110 the top border of the tooltip window.  It must be chosen so that the
 111 tooltip window doesn't contain the mouse when it pops up, or it may
 112 interfere with clicking where you wish.
 113
 114 If `tooltip-frame-parameters' includes the `top' parameter,
 115 the value of `tooltip-y-offset' is ignored."
 116   :type 'integer
 117   :group 'tooltip)
 118
 119 (defcustom tooltip-frame-parameters
 120   '((name . "tooltip")
 121     (internal-border-width . 2)
 122     (border-width . 1))
 123   "Frame parameters used for tooltips.
 124
 125 If `left' or `top' parameters are included, they specify the absolute
 126 position to pop up the tooltip.
 127
 128 Note that font and color parameters are ignored, and the attributes
 129 of the `tooltip' face are used instead."
 130   :type '(repeat (cons :format "%v"
 131                        (symbol :tag "Parameter")
 132                        (sexp :tag "Value")))
 133   :group 'tooltip)
 134
 135 (defface tooltip
 136   '((((class color))
 137      :background "lightyellow"
 138      :foreground "black"
 139      :inherit variable-pitch)
 140     (t
 141      :inherit variable-pitch))
 142   "Face for tooltips."
 143   :group 'tooltip
 144   :group 'basic-faces)
 145
 146 (defcustom tooltip-use-echo-area nil
 147   "Use the echo area instead of tooltip frames for help and GUD tooltips.
 148 This variable is obsolete; instead of setting it to t, disable
 149 `tooltip-mode' (which has a similar effect)."
 150   :type 'boolean
 151   :group 'tooltip)
 152
 153 (make-obsolete-variable 'tooltip-use-echo-area
 154                         "disable Tooltip mode instead" "24.1" 'set)
 155
 156 \f
 157 ;;; Variables that are not customizable.
 158
 159 (define-obsolete-variable-alias 'tooltip-hook 'tooltip-functions "23.1")
 160
 161 (defvar tooltip-functions nil
 162   "Functions to call to display tooltips.
 163 Each function is called with one argument EVENT which is a copy
 164 of the last mouse movement event that occurred.  If one of these
 165 functions displays the tooltip, it should return non-nil and the
 166 rest are not called.")
 167
 168 (defvar tooltip-timeout-id nil
 169   "The id of the timeout started when Emacs becomes idle.")
 170
 171 (defvar tooltip-last-mouse-motion-event nil
 172   "A copy of the last mouse motion event seen.")
 173
 174 (defvar tooltip-hide-time nil
 175   "Time when the last tooltip was hidden.")
 176
 177 (defvar gud-tooltip-mode) ;; Prevent warning.
 178
 179 ;;; Event accessors
 180
 181 (defun tooltip-event-buffer (event)
 182   "Return the buffer over which event EVENT occurred.
 183 This might return nil if the event did not occur over a buffer."
 184   (let ((window (posn-window (event-end event))))
 185     (and window (window-buffer window))))
 186
 187 \f
 188 ;;; Timeout for tooltip display
 189
 190 (defun tooltip-delay ()
 191   "Return the delay in seconds for the next tooltip."
 192   (if (and tooltip-hide-time
 193            (< (- (float-time) tooltip-hide-time) tooltip-recent-seconds))
 194       tooltip-short-delay
 195     tooltip-delay))
 196
 197 (defun tooltip-cancel-delayed-tip ()
 198   "Disable the tooltip timeout."
 199   (when tooltip-timeout-id
 200     (disable-timeout tooltip-timeout-id)
 201     (setq tooltip-timeout-id nil)))
 202
 203 (defun tooltip-start-delayed-tip ()
 204   "Add a one-shot timeout to call function `tooltip-timeout'."
 205   (setq tooltip-timeout-id
 206         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 207
 208 (defun tooltip-timeout (_object)
 209   "Function called when timer with id `tooltip-timeout-id' fires."
 210   (run-hook-with-args-until-success 'tooltip-functions
 211                                     tooltip-last-mouse-motion-event))
 212
 213 \f
 214 ;;; Displaying tips
 215
 216 (defun tooltip-set-param (alist key value)
 217   "Change the value of KEY in alist ALIST to VALUE.
 218 If there's no association for KEY in ALIST, add one, otherwise
 219 change the existing association.  Value is the resulting alist."
 220   (declare (obsolete "use (setf (alist-get ..) ..) instead" "25.1"))
 221   (setf (alist-get key alist) value)
 222   alist)
 223
 224 (declare-function x-show-tip "xfns.c"
 225                   (string &optional frame parms timeout dx dy))
 226
 227 (defun tooltip-show (text &optional use-echo-area)
 228   "Show a tooltip window displaying TEXT.
 229
 230 Text larger than `x-max-tooltip-size' is clipped.
 231
 232 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 233 parameters, they determine the x and y position where the tooltip
 234 is displayed.  Otherwise, the tooltip pops at offsets specified by
 235 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 236 position.
 237
 238 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 239 in echo area."
 240   (if use-echo-area
 241       (tooltip-show-help-non-mode text)
 242     (condition-case error
 243         (let ((params (copy-sequence tooltip-frame-parameters))
 244               (fg (face-attribute 'tooltip :foreground))
 245               (bg (face-attribute 'tooltip :background)))
 246           (when (stringp fg)
 247             (setf (alist-get 'foreground-color params) fg)
 248             (setf (alist-get 'border-color params) fg))
 249           (when (stringp bg)
 250             (setf (alist-get 'background-color params) bg))
 251           (x-show-tip (propertize text 'face 'tooltip)
 252                       (selected-frame)
 253                       params
 254                       tooltip-hide-delay
 255                       tooltip-x-offset
 256                       tooltip-y-offset))
 257       (error
 258        (message "Error while displaying tooltip: %s" error)
 259        (sit-for 1)
 260        (message "%s" text)))))
 261
 262 (declare-function x-hide-tip "xfns.c" ())
 263
 264 (defun tooltip-hide (&optional _ignored-arg)
 265   "Hide a tooltip, if one is displayed.
 266 Value is non-nil if tooltip was open."
 267   (tooltip-cancel-delayed-tip)
 268   (when (x-hide-tip)
 269     (setq tooltip-hide-time (float-time))))
 270
 271 \f
 272 ;;; Debugger-related functions
 273
 274 (defun tooltip-identifier-from-point (point)
 275   "Extract the identifier at POINT, if any.
 276 Value is nil if no identifier exists at point.  Identifier extraction
 277 is based on the current syntax table."
 278   (save-excursion
 279     (goto-char point)
 280     (let* ((start (progn (skip-syntax-backward "w_") (point)))
 281            (pstate (syntax-ppss)))
 282       (unless (or (looking-at "[0-9]")
 283                   (nth 3 pstate)
 284                   (nth 4 pstate))
 285         (skip-syntax-forward "w_")
 286         (when (> (point) start)
 287           (buffer-substring start (point)))))))
 288
 289 (defun tooltip-expr-to-print (event)
 290   "Return an expression that should be printed for EVENT.
 291 If a region is active and the mouse is inside the region, print
 292 the region.  Otherwise, figure out the identifier around the point
 293 where the mouse is."
 294   (with-current-buffer (tooltip-event-buffer event)
 295     (let ((point (posn-point (event-end event))))
 296       (if (use-region-p)
 297           (when (and (<= (region-beginning) point) (<= point (region-end)))
 298             (buffer-substring (region-beginning) (region-end)))
 299         (tooltip-identifier-from-point point)))))
 300
 301 (defun tooltip-process-prompt-regexp (process)
 302   "Return regexp matching the prompt of PROCESS at the end of a string.
 303 The prompt is taken from the value of `comint-prompt-regexp' in
 304 the buffer of PROCESS."
 305   (let ((prompt-regexp (with-current-buffer (process-buffer process)
 306                          comint-prompt-regexp)))
 307     (concat "\n*"
 308             ;; Most start with `^' but the one for `sdb' cannot be easily
 309             ;; stripped.  Code the prompt for `sdb' fixed here.
 310             (if (= (aref prompt-regexp 0) ?^)
 311                 (substring prompt-regexp 1)
 312               "\\*")
 313             "$")))
 314
 315 (defun tooltip-strip-prompt (process output)
 316   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 317   (save-match-data
 318     (if (string-match (tooltip-process-prompt-regexp process) output)
 319         (substring output 0 (match-beginning 0))
 320       output)))
 321
 322 \f
 323 ;;; Tooltip help.
 324
 325 (defvar tooltip-help-message nil
 326   "The last help message received via `show-help-function'.
 327 This is used by `tooltip-show-help' and
 328 `tooltip-show-help-non-mode'.")
 329
 330 (defvar tooltip-previous-message nil
 331   "The previous content of the echo area.")
 332
 333 (defun tooltip-show-help-non-mode (help)
 334   "Function installed as `show-help-function' when Tooltip mode is off.
 335 It is also called if Tooltip mode is on, for text-only displays."
 336   (when (and (not (window-minibuffer-p)) ;Don't overwrite minibuffer contents.
 337              (not cursor-in-echo-area))  ;Don't overwrite a prompt.
 338     (cond
 339      ((stringp help)
 340       (setq help (replace-regexp-in-string "\n" ", " help))
 341       (unless (or tooltip-previous-message
 342                   (equal-including-properties help (current-message))
 343                   (and (stringp tooltip-help-message)
 344                        (equal-including-properties tooltip-help-message
 345                                                    (current-message))))
 346         (setq tooltip-previous-message (current-message)))
 347       (setq tooltip-help-message help)
 348       (let ((message-truncate-lines t)
 349             (message-log-max nil))
 350         (message "%s" help)))
 351      ((stringp tooltip-previous-message)
 352       (let ((message-log-max nil))
 353         (message "%s" tooltip-previous-message)
 354         (setq tooltip-previous-message nil)))
 355      (t
 356       (message nil)))))
 357
 358 (defun tooltip-show-help (msg)
 359   "Function installed as `show-help-function'.
 360 MSG is either a help string to display, or nil to cancel the display."
 361   (if (display-graphic-p)
 362       (let ((previous-help tooltip-help-message))
 363         (setq tooltip-help-message msg)
 364         (cond ((null msg)
 365                ;; Cancel display.  This also cancels a delayed tip, if
 366                ;; there is one.
 367                (tooltip-hide))
 368               ((equal-including-properties previous-help msg)
 369                ;; Same help as before (but possibly the mouse has moved).
 370                ;; Keep what we have.
 371                )
 372               (t
 373                ;; A different help.  Remove a previous tooltip, and
 374                ;; display a new one, with some delay.
 375                (tooltip-hide)
 376                (tooltip-start-delayed-tip))))
 377     ;; On text-only displays, try `tooltip-show-help-non-mode'.
 378     (tooltip-show-help-non-mode msg)))
 379
 380 (defun tooltip-help-tips (_event)
 381   "Hook function to display a help tooltip.
 382 This is installed on the hook `tooltip-functions', which
 383 is run when the timer with id `tooltip-timeout-id' fires.
 384 Value is non-nil if this function handled the tip."
 385   (when (stringp tooltip-help-message)
 386     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 387     t))
 388
 389 (provide 'tooltip)
 390
 391 ;;; tooltip.el ends here