lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2016 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  30 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  31
  32 ;; USAGE: In your ~/.emacs,
  33 ;;
  34 ;; (add-hook 'dired-load-hook
  35 ;;           (lambda ()
  36 ;;                       (load "dired-x")
  37 ;;                       ;; Set global variables here.  For example:
  38 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  39 ;;                       ))
  40 ;; (add-hook 'dired-mode-hook
  41 ;;           (lambda ()
  42 ;;                       ;; Set buffer-local variables here.  For example:
  43 ;;                       ;; (dired-omit-mode 1)
  44 ;;                       ))
  45 ;;
  46 ;; At load time dired-x.el will install itself and bind some dired keys.
  47 ;; Some dired.el and dired-aux.el functions have extra features if
  48 ;; dired-x is loaded.
  49
  50 ;; User customization: M-x customize-group RET dired-x RET.
  51
  52 ;; *Please* see the `dired-x' info pages for more details.
  53
  54 \f
  55 ;;; Code:
  56
  57 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  58 ;; but maybe not if a dired-x function is being autoloaded.
  59 (require 'dired)
  60
  61 ;;; User-defined variables.
  62
  63 (defgroup dired-x nil
  64   "Extended directory editing (dired-x)."
  65   :group 'dired)
  66
  67 (defgroup dired-keys nil
  68   "Dired keys customizations."
  69   :prefix "dired-"
  70   :group 'dired-x)
  71
  72 (defcustom dired-bind-vm nil
  73   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  74 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  75 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  76 will run `rmail' on these files.  New RMAIL files use the standard
  77 mbox format, and so cannot be distinguished in this way."
  78   :type 'boolean
  79   :group 'dired-keys)
  80
  81 (defcustom dired-bind-jump t
  82   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  83 Setting this variable directly after dired-x is loaded has no effect -
  84 use \\[customize]."
  85   :type 'boolean
  86   :set (lambda (sym val)
  87          (if (set sym val)
  88              (progn
  89                (define-key ctl-x-map "\C-j" 'dired-jump)
  90                (define-key ctl-x-4-map "\C-j" 'dired-jump-other-window))
  91            (if (eq 'dired-jump (lookup-key ctl-x-map "\C-j"))
  92                (define-key ctl-x-map "\C-j" nil))
  93            (if (eq 'dired-jump-other-window (lookup-key ctl-x-4-map "\C-j"))
  94                (define-key ctl-x-4-map "\C-j" nil))))
  95   :group 'dired-keys)
  96
  97 (defcustom dired-bind-man t
  98   "Non-nil means bind `dired-man' to \"N\" in Dired, otherwise do not.
  99 Setting this variable directly after dired-x is loaded has no effect -
 100 use \\[customize]."
 101   :type 'boolean
 102   :set (lambda (sym val)
 103          (if (set sym val)
 104              (define-key dired-mode-map "N" 'dired-man)
 105            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
 106                (define-key dired-mode-map "N" nil))))
 107   :group 'dired-keys)
 108
 109 (defcustom dired-bind-info t
 110   "Non-nil means bind `dired-info' to \"I\" in Dired, otherwise do not.
 111 Setting this variable directly after dired-x is loaded has no effect -
 112 use \\[customize]."
 113   :type 'boolean
 114   :set (lambda (sym val)
 115          (if (set sym val)
 116              (define-key dired-mode-map "I" 'dired-info)
 117            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 118                (define-key dired-mode-map "I" nil))))
 119   :group 'dired-keys)
 120
 121 (defcustom dired-vm-read-only-folders nil
 122   "If non-nil, \\[dired-vm] will visit all folders read-only.
 123 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 124 files not writable by you are visited read-only."
 125   :type '(choice (const :tag "off" nil)
 126                  (const :tag "on" t)
 127                  (other :tag "non-writable only" if-file-read-only))
 128   :group 'dired-x)
 129
 130 (defcustom dired-omit-size-limit 30000
 131   "Maximum size for the \"omitting\" feature.
 132 If nil, there is no maximum size."
 133   :type '(choice (const :tag "no maximum" nil) integer)
 134   :group 'dired-x)
 135
 136 ;; For backward compatibility
 137 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 138 (define-minor-mode dired-omit-mode
 139   "Toggle omission of uninteresting files in Dired (Dired-Omit mode).
 140 With a prefix argument ARG, enable Dired-Omit mode if ARG is
 141 positive, and disable it otherwise.  If called from Lisp, enable
 142 the mode if ARG is omitted or nil.
 143
 144 Dired-Omit mode is a buffer-local minor mode.  When enabled in a
 145 Dired buffer, Dired does not list files whose filenames match
 146 regexp `dired-omit-files', nor files ending with extensions in
 147 `dired-omit-extensions'.
 148
 149 To enable omitting in every Dired buffer, you can put this in
 150 your init file:
 151
 152   (add-hook \\='dired-mode-hook (lambda () (dired-omit-mode)))
 153
 154 See Info node `(dired-x) Omitting Variables' for more information."
 155   :group 'dired-x
 156   (if dired-omit-mode
 157       ;; This will mention how many lines were omitted:
 158       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 159     (revert-buffer)))
 160
 161 (put 'dired-omit-mode 'safe-local-variable 'booleanp)
 162
 163 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 164   "Filenames matching this regexp will not be displayed.
 165 This only has effect when `dired-omit-mode' is t.  See interactive function
 166 `dired-omit-mode' (\\[dired-omit-mode]) and variable
 167 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 168 files and lock files."
 169   :type 'regexp
 170   :group 'dired-x)
 171
 172 (defcustom dired-omit-verbose t
 173   "When non-nil, show messages when omitting files.
 174 When nil, don't show messages."
 175   :version "24.1"
 176   :type 'boolean
 177   :group 'dired-x)
 178
 179 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 180   "If non-nil, Dired always finds a directory in a buffer of its own.
 181 If nil, Dired finds the directory as a subdirectory in some other buffer
 182 if it is present as one.
 183
 184 If there are several Dired buffers for a directory, the most recently
 185 used is chosen.
 186
 187 Dired avoids switching to the current buffer, so that if you have
 188 a normal and a wildcard buffer for the same directory, \\[dired] will
 189 toggle between those two."
 190   :type 'boolean
 191   :group 'dired-x)
 192
 193 (defcustom dired-enable-local-variables t
 194   "Control use of local-variables lists in Dired.
 195 This temporarily overrides the value of `enable-local-variables' when
 196 listing a directory.  See also `dired-local-variables-file'."
 197   :risky t
 198   :type '(choice (const :tag "Query Unsafe" t)
 199                  (const :tag "Safe Only" :safe)
 200                  (const :tag "Do all" :all)
 201                  (const :tag "Ignore" nil)
 202                  (other :tag "Query" other))
 203   :group 'dired-x)
 204
 205 (make-obsolete-variable 'dired-enable-local-variables
 206                         "use a standard `dir-locals-file' instead." "24.1")
 207
 208 (defcustom dired-guess-shell-gnutar
 209   (catch 'found
 210     (dolist (exe '("tar" "gtar"))
 211       (if (with-temp-buffer
 212             (ignore-errors (call-process exe nil t nil "--version"))
 213             (and (re-search-backward "GNU tar" nil t) t))
 214           (throw 'found exe))))
 215   "If non-nil, name of GNU tar executable.
 216 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 217 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 218 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 219   ;; Changed from system-type test to testing --version output.
 220   ;; Maybe test --help for -z instead?
 221   :version "24.1"
 222   :type '(choice (const :tag "Not GNU tar" nil)
 223                  (string :tag "Command name"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-gzip-quiet t
 227   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 (defcustom dired-guess-shell-znew-switches nil
 232   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 233   :type '(choice (const :tag "None" nil)
 234                  (string :tag "Switches"))
 235   :group 'dired-x)
 236
 237 (defcustom dired-clean-up-buffers-too t
 238   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 239   :type 'boolean
 240   :group 'dired-x)
 241
 242 ;;; KEY BINDINGS.
 243
 244 (define-key dired-mode-map "\C-x\M-o" 'dired-omit-mode)
 245 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 246 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 248 (define-key dired-mode-map "*." 'dired-mark-extension)
 249 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 250 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 251 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 252 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 253 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 254 (define-key dired-mode-map "V" 'dired-do-run-mail)
 255
 256 ;;; MENU BINDINGS
 257
 258 (require 'easymenu)
 259
 260 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 261   (easy-menu-add-item menu '("Operate")
 262                       ["Find Files" dired-do-find-marked-files
 263                        :help "Find current or marked files"]
 264                       "Shell Command...")
 265   (easy-menu-add-item menu '("Operate")
 266                       ["Relative Symlink to..." dired-do-relsymlink
 267                        :visible (fboundp 'make-symbolic-link)
 268                        :help "Make relative symbolic links for current or \
 269 marked files"]
 270                       "Hardlink to...")
 271   (easy-menu-add-item menu '("Mark")
 272                       ["Flag Extension..." dired-flag-extension
 273                        :help "Flag files with a certain extension for deletion"]
 274                       "Mark Executables")
 275   (easy-menu-add-item menu '("Mark")
 276                       ["Mark Extension..." dired-mark-extension
 277                        :help "Mark files with a certain extension"]
 278                       "Unmark All")
 279   (easy-menu-add-item menu '("Mark")
 280                       ["Mark Omitted" dired-mark-omitted
 281                        :help "Mark files matching `dired-omit-files' \
 282 and `dired-omit-extensions'"]
 283                       "Unmark All")
 284   (easy-menu-add-item menu '("Regexp")
 285                       ["Relative Symlink..." dired-do-relsymlink-regexp
 286                        :visible (fboundp 'make-symbolic-link)
 287                        :help "Make relative symbolic links for files \
 288 matching regexp"]
 289                       "Hardlink...")
 290   (easy-menu-add-item menu '("Immediate")
 291                       ["Omit Mode" dired-omit-mode
 292                        :style toggle :selected dired-omit-mode
 293                        :help "Enable or disable omitting \"uninteresting\" \
 294 files"]
 295                       "Refresh"))
 296
 297 \f
 298 ;; Install into appropriate hooks.
 299
 300 (add-hook 'dired-mode-hook 'dired-extra-startup)
 301 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 302
 303 (defun dired-extra-startup ()
 304   "Automatically put on `dired-mode-hook' to get extra Dired features:
 305 \\<dired-mode-map>
 306   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 307   \\[dired-info]\t-- run info on file
 308   \\[dired-man]\t-- run man on file
 309   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 310   \\[dired-omit-mode]\t-- toggle omitting of files
 311   \\[dired-mark-sexp]\t-- mark by Lisp expression
 312
 313 To see the options you can set, use M-x customize-group RET dired-x RET.
 314 See also the functions:
 315   `dired-flag-extension'
 316   `dired-virtual'
 317   `dired-jump'
 318   `dired-man'
 319   `dired-vm'
 320   `dired-rmail'
 321   `dired-info'
 322   `dired-do-find-marked-files'"
 323   (interactive)
 324   ;; These must be done in each new dired buffer.
 325   (dired-hack-local-variables)
 326   (dired-omit-startup))
 327
 328 \f
 329 ;;; EXTENSION MARKING FUNCTIONS.
 330
 331 ;; Mark files with some extension.
 332 (defun dired-mark-extension (extension &optional marker-char)
 333   "Mark all files with a certain EXTENSION for use in later commands.
 334 A `.' is *not* automatically prepended to the string entered.
 335 EXTENSION may also be a list of extensions instead of a single one.
 336 Optional MARKER-CHAR is marker to use."
 337   (interactive "sMarking extension: \nP")
 338   (or (listp extension)
 339       (setq extension (list extension)))
 340   (dired-mark-files-regexp
 341    (concat ".";; don't match names with nothing but an extension
 342            "\\("
 343            (mapconcat 'regexp-quote extension "\\|")
 344            "\\)$")
 345    marker-char))
 346
 347 (defun dired-flag-extension (extension)
 348   "In Dired, flag all files with a certain EXTENSION for deletion.
 349 A `.' is *not* automatically prepended to the string entered."
 350   (interactive "sFlagging extension: ")
 351   (dired-mark-extension extension dired-del-marker))
 352
 353 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 354
 355 (defvar dired-patch-unclean-extensions
 356   '(".rej" ".orig")
 357   "List of extensions of dispensable files created by the `patch' program.")
 358
 359 (defvar dired-tex-unclean-extensions
 360   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 361   "List of extensions of dispensable files created by TeX.")
 362
 363 (defvar dired-latex-unclean-extensions
 364   '(".idx" ".lof" ".lot" ".glo")
 365   "List of extensions of dispensable files created by LaTeX.")
 366
 367 (defvar dired-bibtex-unclean-extensions
 368   '(".blg" ".bbl")
 369   "List of extensions of dispensable files created by BibTeX.")
 370
 371 (defvar dired-texinfo-unclean-extensions
 372   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 373     ".tp" ".tps" ".vr" ".vrs")
 374   "List of extensions of dispensable files created by texinfo.")
 375
 376 (defun dired-clean-patch ()
 377   "Flag dispensable files created by patch for deletion.
 378 See variable `dired-patch-unclean-extensions'."
 379   (interactive)
 380   (dired-flag-extension dired-patch-unclean-extensions))
 381
 382 (defun dired-clean-tex ()
 383   "Flag dispensable files created by [La]TeX etc. for deletion.
 384 See variables `dired-tex-unclean-extensions',
 385 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 386 `dired-texinfo-unclean-extensions'."
 387   (interactive)
 388   (dired-flag-extension (append dired-texinfo-unclean-extensions
 389                                 dired-latex-unclean-extensions
 390                                 dired-bibtex-unclean-extensions
 391                                 dired-tex-unclean-extensions)))
 392
 393 (defun dired-very-clean-tex ()
 394   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 395 See variables `dired-texinfo-unclean-extensions',
 396 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 397 `dired-texinfo-unclean-extensions'."
 398   (interactive)
 399   (dired-flag-extension (append dired-texinfo-unclean-extensions
 400                                 dired-latex-unclean-extensions
 401                                 dired-bibtex-unclean-extensions
 402                                 dired-tex-unclean-extensions
 403                                 (list ".dvi"))))
 404 \f
 405 (defvar tar-superior-buffer)
 406 ;;; JUMP.
 407
 408 ;;;###autoload
 409 (defun dired-jump (&optional other-window file-name)
 410   "Jump to Dired buffer corresponding to current buffer.
 411 If in a file, Dired the current directory and move to file's line.
 412 If in Dired already, pop up a level and goto old directory's line.
 413 In case the proper Dired file line cannot be found, refresh the dired
 414 buffer and try again.
 415 When OTHER-WINDOW is non-nil, jump to Dired buffer in other window.
 416 When FILE-NAME is non-nil, jump to its line in Dired.
 417 Interactively with prefix argument, read FILE-NAME."
 418   (interactive
 419    (list nil (and current-prefix-arg
 420                   (read-file-name "Jump to Dired file: "))))
 421   (if (bound-and-true-p tar-subfile-mode)
 422       (switch-to-buffer tar-superior-buffer)
 423     ;; Expand file-name before `dired-goto-file' call:
 424     ;; `dired-goto-file' requires its argument to be an absolute
 425     ;; file name; the result of `read-file-name' could be
 426     ;; an abbreviated file name (Bug#24409).
 427     (let* ((file (or (and file-name (expand-file-name file-name))
 428                      buffer-file-name))
 429            (dir (if file (file-name-directory file) default-directory)))
 430       (if (and (eq major-mode 'dired-mode) (null file-name))
 431           (progn
 432             (setq dir (dired-current-directory))
 433             (dired-up-directory other-window)
 434             (unless (dired-goto-file dir)
 435               ;; refresh and try again
 436               (dired-insert-subdir (file-name-directory dir))
 437               (dired-goto-file dir)))
 438         (if other-window
 439             (dired-other-window dir)
 440           (dired dir))
 441         (if file
 442             (or (dired-goto-file file)
 443                 ;; refresh and try again
 444                 (progn
 445                   (dired-insert-subdir (file-name-directory file))
 446                   (dired-goto-file file))
 447                 ;; Toggle omitting, if it is on, and try again.
 448                 (when dired-omit-mode
 449                   (dired-omit-mode)
 450                   (dired-goto-file file))))))))
 451
 452 ;;;###autoload
 453 (defun dired-jump-other-window (&optional file-name)
 454   "Like \\[dired-jump] (`dired-jump') but in other window."
 455   (interactive
 456    (list (and current-prefix-arg
 457               (read-file-name "Jump to Dired file: "))))
 458   (dired-jump t file-name))
 459 \f
 460 ;;; OMITTING.
 461
 462 ;; Enhanced omitting of lines from directory listings.
 463 ;; Marked files are never omitted.
 464
 465 ;; should probably get rid of this and always use 'no-dir.
 466 ;; sk 28-Aug-1991 09:37
 467 (defvar dired-omit-localp 'no-dir
 468   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 469 If it is `no-dir', omitting is much faster, but you can only match
 470 against the non-directory part of the file name.  Set it to nil if you
 471 need to match the entire file name.")
 472
 473 ;; \017=^O for Omit - other packages can chose other control characters.
 474 (defvar dired-omit-marker-char ?\017
 475   "Temporary marker used by Dired-Omit.
 476 Should never be used as marker by the user or other packages.")
 477
 478 (defun dired-omit-startup ()
 479   (or (assq 'dired-omit-mode minor-mode-alist)
 480       (setq minor-mode-alist
 481             (append '((dired-omit-mode
 482                        (:eval (if (eq major-mode 'dired-mode)
 483                                   " Omit" ""))))
 484                     minor-mode-alist))))
 485
 486 (defun dired-mark-omitted ()
 487   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 488   (interactive)
 489   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 490   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 491
 492 (defcustom dired-omit-extensions
 493   (append completion-ignored-extensions
 494           dired-latex-unclean-extensions
 495           dired-bibtex-unclean-extensions
 496           dired-texinfo-unclean-extensions)
 497   "If non-nil, a list of extensions (strings) to omit from Dired listings.
 498 Defaults to elements of `completion-ignored-extensions',
 499 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 500 `dired-texinfo-unclean-extensions'.
 501
 502 See interactive function `dired-omit-mode' (\\[dired-omit-mode]) and
 503 variables `dired-omit-mode' and `dired-omit-files'."
 504   :type '(repeat string)
 505   :group 'dired-x)
 506
 507 (defun dired-omit-expunge (&optional regexp)
 508   "Erases all unmarked files matching REGEXP.
 509 Does nothing if global variable `dired-omit-mode' is nil, or if called
 510   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 511 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 512   filenames ending in `dired-omit-extensions'.
 513 If REGEXP is the empty string, this function is a no-op.
 514
 515 This functions works by temporarily binding `dired-marker-char' to
 516 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 517   (interactive "sOmit files (regexp): ")
 518   (if (and dired-omit-mode
 519            (or (called-interactively-p 'interactive)
 520                (not dired-omit-size-limit)
 521                (< (buffer-size) dired-omit-size-limit)
 522                (progn
 523                  (when dired-omit-verbose
 524                    (message "Not omitting: directory larger than %d characters."
 525                             dired-omit-size-limit))
 526                  (setq dired-omit-mode nil)
 527                  nil)))
 528       (let ((omit-re (or regexp (dired-omit-regexp)))
 529             (old-modified-p (buffer-modified-p))
 530             count)
 531         (or (string= omit-re "")
 532             (let ((dired-marker-char dired-omit-marker-char))
 533               (when dired-omit-verbose (message "Omitting..."))
 534               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 535                   (progn
 536                     (setq count (dired-do-kill-lines
 537                                  nil
 538                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 539                     (force-mode-line-update))
 540                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 541         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 542         ;; in mode-line of omitted buffers.
 543         (set-buffer-modified-p (and old-modified-p
 544                                     (save-excursion
 545                                       (goto-char (point-min))
 546                                       (re-search-forward dired-re-mark nil t))))
 547         count)))
 548
 549 (defun dired-omit-regexp ()
 550   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 551           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 552           (if dired-omit-extensions
 553               (concat ".";; a non-extension part should exist
 554                       "\\("
 555                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 556                       "\\)$")
 557             "")))
 558
 559 ;; Returns t if any work was done, nil otherwise.
 560 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 561   "Mark unmarked files matching REGEXP, displaying MSG.
 562 REGEXP is matched against the entire file name.  When called
 563 interactively, prompt for REGEXP.
 564 With prefix argument, unflag all those files.
 565 Optional fourth argument LOCALP is as in `dired-get-filename'."
 566   (interactive
 567    (list (read-regexp
 568           "Mark unmarked files matching regexp (default all): "
 569           nil 'dired-regexp-history)
 570          nil current-prefix-arg nil))
 571   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 572     (dired-mark-if
 573      (and
 574       ;; not already marked
 575       (looking-at-p " ")
 576       ;; uninteresting
 577       (let ((fn (dired-get-filename localp t)))
 578         (and fn (string-match-p regexp fn))))
 579      msg)))
 580
 581 \f
 582 ;;; VIRTUAL DIRED MODE.
 583
 584 ;; For browsing `ls -lR' listings in a dired-like fashion.
 585
 586 (defalias 'virtual-dired 'dired-virtual)
 587 (defun dired-virtual (dirname &optional switches)
 588   "Put this buffer into Virtual Dired mode.
 589
 590 In Virtual Dired mode, all commands that do not actually consult the
 591 filesystem will work.
 592
 593 This is useful if you want to peruse and move around in an ls -lR
 594 output file, for example one you got from an ftp server.  With
 595 ange-ftp, you can even Dired a directory containing an ls-lR file,
 596 visit that file and turn on Virtual Dired mode.  But don't try to save
 597 this file, as dired-virtual indents the listing and thus changes the
 598 buffer.
 599
 600 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 601 resume it in a later session.
 602
 603 Type \\<dired-mode-map>\\[revert-buffer] \
 604 in the Virtual Dired buffer and answer `y' to convert
 605 the virtual to a real Dired buffer again.  You don't have to do this, though:
 606 you can relist single subdirs using \\[dired-do-redisplay]."
 607
 608   ;; DIRNAME is the top level directory of the buffer.  It will become
 609   ;; its `default-directory'.  If nil, the old value of
 610   ;; default-directory is used.
 611
 612   ;; Optional SWITCHES are the ls switches to use.
 613
 614   ;; Shell wildcards will be used if there already is a `wildcard'
 615   ;; line in the buffer (thus it is a saved Dired buffer), but there
 616   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 617   ;; hand if you want them.
 618
 619   (interactive
 620    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 621   (goto-char (point-min))
 622   (or (looking-at-p "  ")
 623       ;; if not already indented, do it now:
 624       (indent-region (point-min) (point-max) 2))
 625   (or dirname (setq dirname default-directory))
 626   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 627   (setq default-directory dirname)      ; contains no wildcards
 628   (let ((wildcard (save-excursion
 629                     (goto-char (point-min))
 630                     (forward-line 1)
 631                     (and (looking-at "^  wildcard ")
 632                          (buffer-substring (match-end 0)
 633                                            (line-end-position))))))
 634   (if wildcard
 635         (setq dirname (expand-file-name wildcard default-directory))))
 636   ;; If raw ls listing (not a saved old dired buffer), give it a
 637   ;; decent subdir headerline:
 638   (goto-char (point-min))
 639   (or (looking-at-p dired-subdir-regexp)
 640       (insert "  "
 641               (directory-file-name (file-name-directory default-directory))
 642               ":\n"))
 643   (dired-mode dirname (or switches dired-listing-switches))
 644   (setq mode-name "Virtual Dired"
 645         revert-buffer-function 'dired-virtual-revert)
 646   (set (make-local-variable 'dired-subdir-alist) nil)
 647   (dired-build-subdir-alist)
 648   (goto-char (point-min))
 649   (dired-initial-position dirname))
 650
 651 (defun dired-virtual-guess-dir ()
 652   "Guess and return appropriate working directory of this buffer.
 653 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 654 based upon buffer contents.  If nothing could be guessed, returns
 655 nil."
 656
 657   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 658         (subexpr 2))
 659     (goto-char (point-min))
 660     (cond ((looking-at regexp)
 661            ;; If a saved dired buffer, look to which dir and
 662            ;; perhaps wildcard it belongs:
 663            (let ((dir (buffer-substring (match-beginning subexpr)
 664                                         (match-end subexpr))))
 665              (file-name-as-directory dir)))
 666           ;; Else no match for headerline found.  It's a raw ls listing.
 667           ;; In raw ls listings the directory does not have a headerline
 668           ;; try parent of first subdir, if any
 669           ((re-search-forward regexp nil t)
 670            (file-name-directory
 671             (directory-file-name
 672              (file-name-as-directory
 673               (buffer-substring (match-beginning subexpr)
 674                                 (match-end subexpr))))))
 675           (t                            ; if all else fails
 676            nil))))
 677
 678
 679 (defun dired-virtual-revert (&optional _arg _noconfirm)
 680   (if (not
 681        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 682       (error "Cannot revert a Virtual Dired buffer")
 683     (setq mode-name "Dired"
 684           revert-buffer-function 'dired-revert)
 685     (revert-buffer)))
 686
 687 ;; A zero-arg version of dired-virtual.
 688 (defun dired-virtual-mode ()
 689   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 690 Useful on `magic-mode-alist' with the regexp
 691
 692   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 693
 694 to put saved Dired buffers automatically into Virtual Dired mode.
 695
 696 Also useful for `auto-mode-alist' like this:
 697
 698   (add-to-list \\='auto-mode-alist
 699                \\='(\"[^/]\\\\.dired\\\\\\='\" . dired-virtual-mode))"
 700   (interactive)
 701   (dired-virtual (dired-virtual-guess-dir)))
 702
 703 \f
 704 ;;; SMART SHELL.
 705
 706 ;; An Emacs buffer can have but one working directory, stored in the
 707 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 708 ;; several subdirectories inserted, but still has but one working directory:
 709 ;; that of the top level Dired directory in that buffer.  For some commands
 710 ;; it is appropriate that they use the current Dired directory instead of
 711 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 712 ;; mechanism is provided for special handling of the working directory in
 713 ;; special major modes.
 714
 715 (define-obsolete-variable-alias 'default-directory-alist
 716   'dired-default-directory-alist "24.1")
 717
 718 ;; It's easier to add to this alist than redefine function
 719 ;; default-directory while keeping the old information.
 720 (defconst dired-default-directory-alist
 721   '((dired-mode . (if (fboundp 'dired-current-directory)
 722                       (dired-current-directory)
 723                     default-directory)))
 724   "Alist of major modes and their opinion on `default-directory'.
 725 Each element has the form (MAJOR . EXPRESSION).
 726 The function `dired-default-directory' evaluates EXPRESSION to
 727 determine a default directory.")
 728
 729 (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd
 730 (make-obsolete-variable 'dired-default-directory-alist
 731                         "this feature is due to be removed." "24.1")
 732
 733 (defun dired-default-directory ()
 734   "Return the `dired-default-directory-alist' entry for the current major-mode.
 735 If none, return `default-directory'."
 736   ;; It looks like this was intended to be something of a "general"
 737   ;; feature, but it only ever seems to have been used in
 738   ;; dired-smart-shell-command, and doesn't seem worth keeping around.
 739   (declare (obsolete nil "24.1"))
 740   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 741       default-directory))
 742
 743 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 744   "Like function `shell-command', but in the current Virtual Dired directory."
 745   (interactive
 746    (list
 747     (read-shell-command "Shell command: " nil nil
 748                         (cond
 749                          (buffer-file-name (file-relative-name buffer-file-name))
 750                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 751     current-prefix-arg
 752     shell-command-default-error-buffer))
 753   (let ((default-directory (or (and (eq major-mode 'dired-mode)
 754                                     (dired-current-directory))
 755                                default-directory)))
 756     (shell-command command output-buffer error-buffer)))
 757
 758 \f
 759 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 760
 761 ;; Brief Description  (This feature is obsolete as of Emacs 24.1)
 762 ;;
 763 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 764 ;;
 765 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 766 ;;
 767 ;; * `dired-hack-local-variables' checks the value of
 768 ;;   `dired-local-variables-file'
 769 ;;
 770 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 771 ;;   filename found in the directory of the Dired Buffer being created.
 772 ;;
 773 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 774 ;;   include it in the Dired Buffer at the bottom.
 775 ;;
 776 ;; * Set `enable-local-variables' temporarily to the user variable
 777 ;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 778 ;;   Dired Buffer.
 779
 780 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 781   "Filename, as string, containing local Dired buffer variables to be hacked.
 782 If this file found in current directory, then it will be inserted into dired
 783 buffer and `hack-local-variables' will be run.  See Info node
 784 `(emacs)File Variables' for more information on local variables.
 785 See also `dired-enable-local-variables'."
 786   :type 'file
 787   :group 'dired)
 788
 789 (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1")
 790
 791 (defun dired-hack-local-variables ()
 792   "Evaluate local variables in `dired-local-variables-file' for Dired buffer."
 793   (declare (obsolete hack-dir-local-variables-non-file-buffer "24.1"))
 794   (and (stringp dired-local-variables-file)
 795        (file-exists-p dired-local-variables-file)
 796        (let ((opoint (point-max))
 797              (inhibit-read-only t)
 798              ;; In case user has `enable-local-variables' set to nil we
 799              ;; override it locally with dired's variable.
 800              (enable-local-variables dired-enable-local-variables))
 801          ;; Insert 'em.
 802          (save-excursion
 803            (goto-char opoint)
 804            (insert "\^L\n")
 805            (insert-file-contents dired-local-variables-file))
 806          ;; Hack 'em.
 807          (unwind-protect
 808              (let ((buffer-file-name dired-local-variables-file))
 809                (hack-local-variables))
 810            ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 811            (delete-region opoint (point-max)))
 812          ;; Make sure that the mode line shows the proper information.
 813          (dired-sort-set-mode-line))))
 814
 815 ;; Does not seem worth a dedicated command.
 816 ;; See the more general features in files-x.el.
 817 (defun dired-omit-here-always ()
 818   "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'.
 819 If in a Dired buffer, reverts it."
 820   (declare (obsolete add-dir-local-variable "24.1"))
 821   (interactive)
 822   (if (file-exists-p dired-local-variables-file)
 823       (error "Old-style dired-local-variables-file `./%s' found;
 824 replace it with a dir-locals-file `./%s'"
 825              dired-local-variables-file
 826              dir-locals-file))
 827   (if (file-exists-p dir-locals-file)
 828       (message "File `./%s' already exists." dir-locals-file)
 829     (add-dir-local-variable 'dired-mode 'subdirs nil)
 830     (add-dir-local-variable 'dired-mode 'dired-omit-mode t)
 831     ;; Run extra-hooks and revert directory.
 832     (when (derived-mode-p 'dired-mode)
 833       (hack-dir-local-variables-non-file-buffer)
 834       (dired-extra-startup)
 835       (dired-revert))))
 836
 837 \f
 838 ;;; GUESS SHELL COMMAND.
 839
 840 ;; Brief Description:
 841 ;;;
 842 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 843 ;;;
 844 ;; * `dired-guess-shell-command' provides smarter defaults for
 845 ;;;    dired-aux.el's `dired-read-shell-command'.
 846 ;;;
 847 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 848 ;;;    marked files.
 849 ;;;
 850 ;; * Parse `dired-guess-shell-alist-user' and
 851 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 852 ;;;   that matches the first file in the file list.
 853 ;;;
 854 ;; * If the REGEXP matches all the entries of the file list then evaluate
 855 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 856 ;;;   string.  COMMAND may be a list of commands.
 857 ;;;
 858 ;; * Return this command to `dired-guess-shell-command' which prompts user
 859 ;;;   with it.  The list of commands is put into the list of default values.
 860 ;;;   If a command is used successfully then it is stored permanently in
 861 ;;;   `dired-shell-command-history'.
 862
 863 ;; Guess what shell command to apply to a file.
 864 (defvar dired-shell-command-history nil
 865   "History list for commands that read dired-shell commands.")
 866
 867 ;; Default list of shell commands.
 868
 869 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 870 ;; install GNU zip's version of zcat.
 871
 872 (autoload 'Man-support-local-filenames "man")
 873
 874 (defvar dired-guess-shell-alist-default
 875   (list
 876    (list "\\.tar\\'"
 877          '(if dired-guess-shell-gnutar
 878               (concat dired-guess-shell-gnutar " xvf")
 879             "tar xvf")
 880          ;; Extract files into a separate subdirectory
 881          '(if dired-guess-shell-gnutar
 882               (concat "mkdir " (file-name-sans-extension file)
 883                       "; " dired-guess-shell-gnutar " -C "
 884                       (file-name-sans-extension file) " -xvf")
 885             (concat "mkdir " (file-name-sans-extension file)
 886                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 887          ;; List archive contents.
 888          '(if dired-guess-shell-gnutar
 889               (concat dired-guess-shell-gnutar " tvf")
 890             "tar tvf"))
 891
 892    ;; REGEXPS for compressed archives must come before the .Z rule to
 893    ;; be recognized:
 894    (list "\\.tar\\.Z\\'"
 895          ;; Untar it.
 896          '(if dired-guess-shell-gnutar
 897               (concat dired-guess-shell-gnutar " zxvf")
 898             (concat "zcat * | tar xvf -"))
 899          ;; Optional conversion to gzip format.
 900          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 901                   " " dired-guess-shell-znew-switches))
 902
 903    ;; gzip'ed archives
 904    (list "\\.t\\(ar\\.\\)?gz\\'"
 905          '(if dired-guess-shell-gnutar
 906               (concat dired-guess-shell-gnutar " zxvf")
 907             (concat "gunzip -qc * | tar xvf -"))
 908          ;; Extract files into a separate subdirectory
 909          '(if dired-guess-shell-gnutar
 910               (concat "mkdir " (file-name-sans-extension file)
 911                       "; " dired-guess-shell-gnutar " -C "
 912                       (file-name-sans-extension file) " -zxvf")
 913             (concat "mkdir " (file-name-sans-extension file)
 914                     "; gunzip -qc * | tar -C "
 915                     (file-name-sans-extension file) " -xvf -"))
 916          ;; Optional decompression.
 917          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 918          ;; List archive contents.
 919          '(if dired-guess-shell-gnutar
 920               (concat dired-guess-shell-gnutar " ztvf")
 921             (concat "gunzip -qc * | tar tvf -")))
 922
 923    ;; bzip2'ed archives
 924    (list "\\.t\\(ar\\.bz2\\|bz\\)\\'"
 925          "bunzip2 -c * | tar xvf -"
 926          ;; Extract files into a separate subdirectory
 927          '(concat "mkdir " (file-name-sans-extension file)
 928                   "; bunzip2 -c * | tar -C "
 929                   (file-name-sans-extension file) " -xvf -")
 930          ;; Optional decompression.
 931          "bunzip2")
 932
 933    ;; xz'ed archives
 934    (list "\\.t\\(ar\\.\\)?xz\\'"
 935          "unxz -c * | tar xvf -"
 936          ;; Extract files into a separate subdirectory
 937          '(concat "mkdir " (file-name-sans-extension file)
 938                   "; unxz -c * | tar -C "
 939                   (file-name-sans-extension file) " -xvf -")
 940          ;; Optional decompression.
 941          "unxz")
 942
 943    '("\\.shar\\.Z\\'" "zcat * | unshar")
 944    '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar")
 945
 946    '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr")
 947    (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -"
 948          ;; Optional decompression.
 949          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 950    (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -"
 951          ;; Optional conversion to gzip format.
 952          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 953                   " " dired-guess-shell-znew-switches))
 954
 955    '("\\.patch\\'" "cat * | patch")
 956    (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch"
 957          ;; Optional decompression.
 958          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 959    (list "\\.patch\\.Z\\'" "zcat * | patch"
 960          ;; Optional conversion to gzip format.
 961          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 962                   " " dired-guess-shell-znew-switches))
 963
 964    ;; The following four extensions are useful with dired-man ("N" key)
 965    ;; FIXME "man ./" does not work with dired-do-shell-command,
 966    ;; because there seems to be no way for us to modify the filename,
 967    ;; only the command.  Hmph.  `dired-man' works though.
 968    (list "\\.\\(?:[0-9]\\|man\\)\\'"
 969          '(let ((loc (Man-support-local-filenames)))
 970             (cond ((eq loc 'man-db) "man -l")
 971                   ((eq loc 'man) "man ./")
 972                   (t
 973                    "cat * | tbl | nroff -man -h | col -b"))))
 974    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'"
 975          '(let ((loc (Man-support-local-filenames)))
 976             (cond ((eq loc 'man-db)
 977                    "man -l")
 978                   ((eq loc 'man)
 979                    "man ./")
 980                   (t "gunzip -qc * | tbl | nroff -man -h | col -b")))
 981          ;; Optional decompression.
 982          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 983    (list "\\.[0-9]\\.Z\\'"
 984          '(let ((loc (Man-support-local-filenames)))
 985             (cond ((eq loc 'man-db) "man -l")
 986                   ((eq loc 'man) "man ./")
 987                   (t "zcat * | tbl | nroff -man -h | col -b")))
 988          ;; Optional conversion to gzip format.
 989          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 990                   " " dired-guess-shell-znew-switches))
 991    '("\\.pod\\'" "perldoc" "pod2man * | nroff -man")
 992
 993    '("\\.dvi\\'" "xdvi" "dvips")        ; preview and printing
 994    '("\\.au\\'" "play")                 ; play Sun audiofiles
 995    '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p")
 996    '("\\.ogg\\'" "ogg123")
 997    '("\\.mp3\\'" "mpg123")
 998    '("\\.wav\\'" "play")
 999    '("\\.uu\\'" "uudecode")             ; for uudecoded files
1000    '("\\.hqx\\'" "mcvert")
1001    '("\\.sh\\'" "sh")                   ; execute shell scripts
1002    '("\\.xbm\\'" "bitmap")              ; view X11 bitmaps
1003    '("\\.gp\\'" "gnuplot")
1004    '("\\.p[bgpn]m\\'" "xloadimage")
1005    '("\\.gif\\'" "xloadimage")          ; view gif pictures
1006    '("\\.tif\\'" "xloadimage")
1007    '("\\.png\\'" "display")             ; xloadimage 4.1 doesn't grok PNG
1008    '("\\.jpe?g\\'" "xloadimage")
1009    '("\\.fig\\'" "xfig")                ; edit fig pictures
1010    '("\\.out\\'" "xgraph")              ; for plotting purposes.
1011    '("\\.tex\\'" "latex" "tex")
1012    '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi")
1013    '("\\.pdf\\'" "xpdf")
1014    '("\\.doc\\'" "antiword" "strings")
1015    '("\\.rpm\\'" "rpm -qilp" "rpm -ivh")
1016    '("\\.dia\\'" "dia")
1017    '("\\.mgp\\'" "mgp")
1018
1019    ;; Some other popular archivers.
1020    (list "\\.zip\\'" "unzip" "unzip -l"
1021          ;; Extract files into a separate subdirectory
1022          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1023                   " -d " (file-name-sans-extension file)))
1024    '("\\.zoo\\'" "zoo x//")
1025    '("\\.lzh\\'" "lharc x")
1026    '("\\.arc\\'" "arc x")
1027    '("\\.shar\\'" "unshar")
1028    '("\\.rar\\'" "unrar x")
1029    '("\\.7z\\'" "7z x")
1030
1031    ;; Compression.
1032    (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1033    (list "\\.dz\\'" "dictunzip")
1034    (list "\\.bz2\\'" "bunzip2")
1035    (list "\\.xz\\'" "unxz")
1036    (list "\\.Z\\'" "uncompress"
1037          ;; Optional conversion to gzip format.
1038          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1039                   " " dired-guess-shell-znew-switches))
1040
1041    '("\\.sign?\\'" "gpg --verify"))
1042
1043   "Default alist used for shell command guessing.
1044 See `dired-guess-shell-alist-user'.")
1045
1046 (defcustom dired-guess-shell-alist-user nil
1047   "User-defined alist of rules for suggested commands.
1048 These rules take precedence over the predefined rules in the variable
1049 `dired-guess-shell-alist-default' (to which they are prepended).
1050
1051 Each element of this list looks like
1052
1053     (REGEXP COMMAND...)
1054
1055 where each COMMAND can either be a string or a Lisp expression that evaluates
1056 to a string.  This expression can access the file name as the variable `file'.
1057 If several COMMANDs are given, the first one will be the default
1058 and the rest will be added temporarily to the history and can be retrieved
1059 with \\[previous-history-element] (M-p) .
1060
1061 The variable `dired-guess-shell-case-fold-search' controls whether
1062 REGEXP is matched case-sensitively.
1063
1064 You can set this variable in your ~/.emacs.  For example, to add rules for
1065 `.foo' and `.bar' files, write
1066
1067  (setq dired-guess-shell-alist-user
1068         '((\"\\\\.foo\\\\'\" \"FOO-COMMAND\")
1069           (\"\\\\.bar\\\\'\"
1070            (if condition
1071               \"BAR-COMMAND-1\"
1072             \"BAR-COMMAND-2\"))))"
1073   :group 'dired-x
1074   :type '(alist :key-type regexp :value-type (repeat sexp)))
1075
1076 (defcustom dired-guess-shell-case-fold-search t
1077   "If non-nil, `dired-guess-shell-alist-default' and
1078 `dired-guess-shell-alist-user' are matched case-insensitively."
1079   :group 'dired-x
1080   :type 'boolean)
1081
1082 (defun dired-guess-default (files)
1083   "Return a shell command, or a list of commands, appropriate for FILES.
1084 See `dired-guess-shell-alist-user'."
1085
1086   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1087          ;; Prepend the user's alist to the default alist.
1088          (alist (append dired-guess-shell-alist-user
1089                         dired-guess-shell-alist-default))
1090          (file (car files))
1091          (flist (cdr files))
1092          elt regexp cmds)
1093
1094     ;; Find the first match in the alist for first file in FILES.
1095     (while alist
1096       (setq elt (car alist)
1097             regexp (car elt)
1098             alist (cdr alist))
1099       (if (string-match-p regexp file)
1100           (setq cmds (cdr elt)
1101                 alist nil)))
1102
1103     ;; If more than one file, see if all of FILES match regular expression.
1104     (while (and flist
1105                 (string-match-p regexp (car flist)))
1106       (setq flist (cdr flist)))
1107
1108     ;; If flist is still non-nil, then do not guess since this means that not
1109     ;; all the files in FILES were matched by the regexp.
1110     (setq cmds (and (not flist) cmds))
1111
1112     ;; Return commands or nil if flist is still non-nil.
1113     ;; Evaluate the commands in order that any logical testing will be done.
1114     (if (cdr cmds)
1115         (delete-dups (mapcar (lambda (cmd) (eval cmd `((file . ,file)))) cmds))
1116       (eval (car cmds) `((file . ,file))))))            ; single command
1117
1118 (defun dired-guess-shell-command (prompt files)
1119   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1120   (let ((default (dired-guess-default files))
1121         default-list val)
1122     (if (null default)
1123         ;; Nothing to guess
1124         (read-shell-command prompt nil 'dired-shell-command-history)
1125       (setq prompt (replace-regexp-in-string ": $" " " prompt))
1126       (if (listp default)
1127           ;; More than one guess
1128           (setq default-list default
1129                 default (car default)
1130                 prompt (concat
1131                         prompt
1132                         (format "{%d guesses} " (length default-list))))
1133         ;; Just one guess
1134         (setq default-list (list default)))
1135       ;; Put the first guess in the prompt but not in the initial value.
1136       (setq prompt (concat prompt (format "[%s]: " default)))
1137       ;; All guesses can be retrieved with M-n
1138       (setq val (read-shell-command prompt nil
1139                                     'dired-shell-command-history
1140                                     default-list))
1141       ;; If we got a return, then return default.
1142       (if (equal val "") default val))))
1143
1144 \f
1145 ;;; RELATIVE SYMBOLIC LINKS.
1146
1147 (declare-function make-symbolic-link "fileio.c")
1148
1149 (defvar dired-keep-marker-relsymlink ?S
1150   "See variable `dired-keep-marker-move'.")
1151
1152 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1153   "Make a symbolic link (pointing to FILE1) in FILE2.
1154 The link is relative (if possible), for example
1155
1156     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1157
1158 results in
1159
1160     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1161   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1162   (let (name1 name2 len1 len2 (index 0) sub)
1163     (setq file1 (expand-file-name file1)
1164           file2 (expand-file-name file2)
1165           len1 (length file1)
1166           len2 (length file2))
1167     ;; Find common initial file name components:
1168     (let (next)
1169       (while (and (setq next (string-match "/" file1 index))
1170                   (< (setq next (1+ next)) (min len1 len2))
1171                   ;; For the comparison, both substrings must end in
1172                   ;; `/', so NEXT is *one plus* the result of the
1173                   ;; string-match.
1174                   ;; E.g., consider the case of linking "/tmp/a/abc"
1175                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1176                   ;; of "/tmp/" as common initial component
1177                   (string-equal (substring file1 0 next)
1178                                 (substring file2 0 next)))
1179         (setq index next))
1180       (setq name2 file2
1181             sub (substring file1 0 index)
1182             name1 (substring file1 index)))
1183     (if (string-equal sub "/")
1184         ;; No common initial file name found
1185         (setq name1 file1)
1186       ;; Else they have a common parent directory
1187       (let ((tem (substring file2 index))
1188             (start 0)
1189             (count 0))
1190         ;; Count number of slashes we must compensate for ...
1191         (while (setq start (string-match "/" tem start))
1192           (setq count (1+ count)
1193                 start (1+ start)))
1194         ;; ... and prepend a "../" for each slash found:
1195         (dotimes (_ count)
1196           (setq name1 (concat "../" name1)))))
1197     (make-symbolic-link
1198      (directory-file-name name1)        ; must not link to foo/
1199                                         ; (trailing slash!)
1200      name2 ok-if-already-exists)))
1201
1202 (autoload 'dired-do-create-files "dired-aux")
1203
1204 ;;;###autoload
1205 (defun dired-do-relsymlink (&optional arg)
1206    "Relative symlink all marked (or next ARG) files into a directory.
1207 Otherwise make a relative symbolic link to the current file.
1208 This creates relative symbolic links like
1209
1210     foo -> ../bar/foo
1211
1212 not absolute ones like
1213
1214     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1215
1216 For absolute symlinks, use \\[dired-do-symlink]."
1217   (interactive "P")
1218   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1219                            "RelSymLink" arg dired-keep-marker-relsymlink))
1220
1221 (autoload 'dired-mark-read-regexp "dired-aux")
1222 (autoload 'dired-do-create-files-regexp "dired-aux")
1223
1224 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1225   "RelSymlink all marked files containing REGEXP to NEWNAME.
1226 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1227 for more info."
1228   (interactive (dired-mark-read-regexp "RelSymLink"))
1229   (dired-do-create-files-regexp
1230    #'dired-make-relative-symlink
1231    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1232
1233 \f
1234 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1235
1236 ;; Brief Description:
1237 ;;;
1238 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1239 ;;;
1240 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1241 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1242 ;;;
1243 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1244 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1245 ;;;
1246 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1247 ;;;   list each time.
1248 ;;;
1249 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1250 ;;;   element of FILE-LIST.
1251 ;;;
1252 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1253 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1254 ;;;   cognizant of the window-configuration.
1255 ;;;
1256 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1257 ;;;   of FILE-LIST giving each a window of height `size'.
1258
1259 (defun dired-do-find-marked-files (&optional noselect)
1260   "Find all marked files displaying all of them simultaneously.
1261 With optional NOSELECT just find files but do not select them.
1262
1263 The current window is split across all files marked, as evenly as possible.
1264 Remaining lines go to bottom-most window.  The number of files that can be
1265 displayed this way is restricted by the height of the current window and
1266 `window-min-height'.
1267
1268 To keep Dired buffer displayed, type \\[split-window-below] first.
1269 To display just marked files, type \\[delete-other-windows] first."
1270   (interactive "P")
1271   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1272
1273 (defun dired-simultaneous-find-file (file-list noselect)
1274   "Visit all files in FILE-LIST and display them simultaneously.
1275 The current window is split across all files in FILE-LIST, as evenly as
1276 possible.  Remaining lines go to the bottom-most window.  The number of
1277 files that can be displayed this way is restricted by the height of the
1278 current window and the variable `window-min-height'.  With non-nil
1279 NOSELECT the files are merely found but not selected."
1280   ;; We don't make this function interactive because it is usually too clumsy
1281   ;; to specify FILE-LIST interactively unless via dired.
1282   (let (size)
1283     (if noselect
1284         ;; Do not select the buffer.
1285         (find-file-noselect (car file-list))
1286       ;; We will have to select the buffer.  Calculate and check window size.
1287       (setq size (/ (window-height) (length file-list)))
1288       (or (<= window-min-height size)
1289           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1290       (find-file (car file-list)))
1291     ;; Decrement.
1292     (dolist (file (cdr file-list))
1293       (if noselect
1294           ;; Do not select the buffer.
1295           (find-file-noselect file)
1296         ;; Vertically split off a window of desired size.  Upper window will
1297         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1298         (select-window (split-window nil size))
1299         (find-file file)))))
1300
1301 \f
1302 ;;; MISCELLANEOUS COMMANDS.
1303
1304 ;; Run man on files.
1305
1306 (declare-function Man-getpage-in-background "man" (topic))
1307
1308 (defvar manual-program) ; from man.el
1309
1310 (defun dired-man ()
1311   "Run `man' on this file."
1312 ;; Used also to say: "Display old buffer if buffer name matches filename."
1313 ;; but I have no idea what that means.
1314   (interactive)
1315   (require 'man)
1316   (let* ((file (dired-get-filename))
1317          (manual-program (replace-regexp-in-string "\\*" "%s"
1318                           (dired-guess-shell-command
1319                            "Man command: " (list file)))))
1320     (Man-getpage-in-background file)))
1321
1322 ;; Run Info on files.
1323
1324 (defun dired-info ()
1325   "Run `info' on this file."
1326   (interactive)
1327   (info (dired-get-filename)))
1328
1329 ;; Run mail on mail folders.
1330
1331 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1332 (defvar vm-folder-directory)
1333
1334 (defun dired-vm (&optional read-only)
1335   "Run VM on this file.
1336 With optional prefix argument, visits the folder read-only.
1337 Otherwise obeys the value of `dired-vm-read-only-folders'."
1338   (interactive "P")
1339   (let ((dir (dired-current-directory))
1340         (fil (dired-get-filename)))
1341     (vm-visit-folder fil (or read-only
1342                              (eq t dired-vm-read-only-folders)
1343                              (and dired-vm-read-only-folders
1344                                   (not (file-writable-p fil)))))
1345     ;; So that pressing `v' inside VM does prompt within current directory:
1346     (set (make-local-variable 'vm-folder-directory) dir)))
1347
1348 (defun dired-rmail ()
1349   "Run RMAIL on this file."
1350   (interactive)
1351   (rmail (dired-get-filename)))
1352
1353 (defun dired-do-run-mail ()
1354   "Visit the current file as a mailbox, using VM or RMAIL.
1355 Prompt for confirmation first; if the user says yes, call
1356 `dired-vm' if `dired-bind-vm' is non-nil, `dired-rmail'
1357 otherwise."
1358   (interactive)
1359   (let ((file (dired-get-filename t)))
1360     (if dired-bind-vm
1361         (if (y-or-n-p (format-message
1362                        "Visit `%s' as a mail folder with VM?" file))
1363             (dired-vm))
1364       ;; Read mail folder using rmail.
1365       (if (y-or-n-p (format-message
1366                      "Visit `%s' as a mailbox with RMAIL?" file))
1367           (dired-rmail)))))
1368
1369 \f
1370 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1371
1372 ;; This should be a builtin
1373 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1374   "Return t if BUFFER1 is more recently used than BUFFER2.
1375 Considers buffers closer to the car of `buffer-list' to be more recent."
1376   (and (not (equal buffer1 buffer2))
1377        (memq buffer1 (buffer-list))
1378        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1379
1380 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1381 ;; (defun dired-buffers-for-dir-exact (dir)
1382 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1383 ;; ;; at top level, or as subdirectory.
1384 ;; ;; Top level matches must match the wildcard part too, if any.
1385 ;; ;; The list is in reverse order of buffer creation, most recent last.
1386 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1387 ;; ;; dired-buffers.
1388 ;;   (let ((alist dired-buffers) result elt)
1389 ;;     (while alist
1390 ;;       (setq elt (car alist)
1391 ;;             alist (cdr alist))
1392 ;;       (let ((buf (cdr elt)))
1393 ;;         (if (buffer-name buf)
1394 ;;             ;; Top level must match exactly against dired-directory in
1395 ;;             ;; case one of them is a wildcard.
1396 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1397 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1398 ;;                 (setq result (cons buf result)))
1399 ;;           ;; else buffer is killed - clean up:
1400 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1401 ;;     result))
1402
1403 \f
1404 ;; Needed if ls -lh is supported and also for GNU ls -ls.
1405 (defun dired-x--string-to-number (str)
1406   "Like `string-to-number' but recognize a trailing unit prefix.
1407 For example, 2K is expanded to 2048.0.  The caller should make
1408 sure that a trailing letter in STR is one of BKkMGTPEZY."
1409   (let* ((val (string-to-number str))
1410          (u (unless (zerop val)
1411               (aref str (1- (length str))))))
1412     (when (and u (> u ?9))
1413       (when (= u ?k)
1414         (setq u ?K))
1415       (let ((units '(?B ?K ?M ?G ?T ?P ?E ?Z ?Y)))
1416         (while (and units (/= (pop units) u))
1417           (setq val (* 1024.0 val)))))
1418     val))
1419
1420 ;; Does anyone use this? - lrd 6/29/93.
1421 ;; Apparently people do use it. - lrd 12/22/97.
1422
1423 (defun dired-mark-sexp (predicate &optional unflag-p)
1424   "Mark files for which PREDICATE returns non-nil.
1425 With a prefix arg, unmark or unflag those files instead.
1426
1427 PREDICATE is a lisp expression that can refer to the following symbols:
1428
1429     inode  [integer] the inode of the file (only for ls -i output)
1430     s      [integer] the size of the file for ls -s output
1431                      (usually in blocks or, with -k, in KByte)
1432     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1433     nlink  [integer] number of links to file
1434     uid    [string]  owner
1435     gid    [string]  group  (If the gid is not displayed by ls,
1436                      this will still be set (to the same as uid))
1437     size   [integer] file size in bytes
1438     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1439     name   [string]  the name of the file
1440     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1441
1442 For example, use
1443
1444         (equal 0 size)
1445
1446 to mark all zero length files.
1447
1448 There's an ambiguity when a single integer not followed by a unit
1449 prefix precedes the file mode: It is then parsed as inode number
1450 and not as block size (this always works for GNU coreutils ls).
1451
1452 Another limitation is that the uid field is needed for the
1453 function to work correctly.  In particular, the field is not
1454 present for some values of `ls-lisp-emulation'.
1455
1456 This function operates only on the buffer content and does not
1457 refer at all to the underlying file system.  Contrast this with
1458 `find-dired', which might be preferable for the task at hand."
1459   ;; Using sym="" instead of nil avoids the trap of
1460   ;; (string-match "foo" sym) into which a user would soon fall.
1461   ;; Give `equal' instead of `=' in the example, as this works on
1462   ;; integers and strings.
1463   (interactive "xMark if (lisp expr): \nP")
1464   (message "%s" predicate)
1465   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1466         inode s mode nlink uid gid size time name sym)
1467     (dired-mark-if
1468      (save-excursion
1469        (and
1470         ;; Sets vars
1471         ;;                inode s mode nlink uid gid size time name sym
1472
1473         ;; according to current file line.  Returns t for success, nil if
1474         ;; there is no file line.  Upon success, all variables are set, either
1475         ;; to nil or the appropriate value, so they need not be initialized.
1476         ;; Moves point within the current line.
1477         (dired-move-to-filename)
1478         (let ((mode-len 10) ; length of mode string
1479               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1480               ;; GNU ls -hs suffixes the block count with a unit and
1481               ;; prints it as a float, FreeBSD does neither.
1482               (dired-re-inode-size "\\=\\s *\\([0-9]+\\s +\\)?\
1483 \\(?:\\([0-9]+\\(?:\\.[0-9]*\\)?[BkKMGTPEZY]?\\)? ?\\)"))
1484           (beginning-of-line)
1485           (forward-char 2)
1486           (search-forward-regexp dired-re-inode-size nil t)
1487           ;; XXX Might be a size not followed by a unit prefix.
1488           ;; We could set s to inode if it were otherwise nil,
1489           ;; with a similar reasoning as below for setting gid to uid,
1490           ;; but it would be even more whimsical.
1491           (setq inode (when (match-string 1)
1492                         (string-to-number (match-string 1))))
1493           (setq s (when (match-string 2)
1494                     (dired-x--string-to-number (match-string 2))))
1495           (setq mode (buffer-substring (point) (+ mode-len (point))))
1496           (forward-char mode-len)
1497           ;; Skip any extended attributes marker ("." or "+").
1498           (or (looking-at " ")
1499               (forward-char 1))
1500           (setq nlink (read (current-buffer)))
1501           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1502           ;; Another issue is that GNU ls -n right-justifies numerical
1503           ;; UIDs and GIDs, while FreeBSD left-justifies them, so
1504           ;; don't rely on a specific whitespace layout.  Both of them
1505           ;; right-justify all other numbers, though.
1506           ;; XXX Return a number if the uid or gid seems to be
1507           ;; numerical?
1508           (setq uid (buffer-substring (progn
1509                                         (skip-chars-forward " \t")
1510                                         (point))
1511                                       (progn
1512                                         (skip-chars-forward "^ \t")
1513                                         (point))))
1514           (dired-move-to-filename)
1515           (save-excursion
1516             (setq time
1517                   ;; The regexp below tries to match from the last
1518                   ;; digit of the size field through a space after the
1519                   ;; date.  Also, dates may have different formats
1520                   ;; depending on file age, so the date column need
1521                   ;; not be aligned to the right.
1522                   (buffer-substring (save-excursion
1523                                       (skip-chars-backward " \t")
1524                                       (point))
1525                                     (progn
1526                                       (re-search-backward
1527                                        directory-listing-before-filename-regexp)
1528                                       (skip-chars-forward "^ \t")
1529                                       (1+ (point))))
1530                   size (dired-x--string-to-number
1531                         ;; We know that there's some kind of number
1532                         ;; before point because the regexp search
1533                         ;; above succeeded.  I don't think it's worth
1534                         ;; doing an extra check for leading garbage.
1535                         (buffer-substring (point)
1536                                           (progn
1537                                             (skip-chars-backward "^ \t")
1538                                             (point))))
1539                   ;; If no gid is displayed, gid will be set to uid
1540                   ;; but the user will then not reference it anyway in
1541                   ;; PREDICATE.
1542                   gid (buffer-substring (progn
1543                                           (skip-chars-backward " \t")
1544                                           (point))
1545                                         (progn
1546                                           (skip-chars-backward "^ \t")
1547                                           (point)))))
1548           (setq name (buffer-substring (point)
1549                                        (or
1550                                         (dired-move-to-end-of-filename t)
1551                                         (point)))
1552                 sym (if (looking-at " -> ")
1553                         (buffer-substring (progn (forward-char 4) (point))
1554                                           (line-end-position))
1555                       ""))
1556           t)
1557         (eval predicate
1558               `((inode . ,inode)
1559                 (s . ,s)
1560                 (mode . ,mode)
1561                 (nlink . ,nlink)
1562                 (uid . ,uid)
1563                 (gid . ,gid)
1564                 (size . ,size)
1565                 (time . ,time)
1566                 (name . ,name)
1567                 (sym . ,sym)))))
1568      (format "'%s file" predicate))))
1569
1570 \f
1571 ;;; FIND FILE AT POINT.
1572
1573 (defcustom dired-x-hands-off-my-keys t
1574   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1575 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1576 If you change this variable without using \\[customize] after `dired-x.el'
1577 is loaded then call \\[dired-x-bind-find-file]."
1578   :type 'boolean
1579   :initialize 'custom-initialize-default
1580   :set (lambda (symbol value)
1581          (set symbol value)
1582          (dired-x-bind-find-file))
1583   :group 'dired-x)
1584
1585 (defun dired-x-bind-find-file ()
1586   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1587 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1588 Binding direction based on `dired-x-hands-off-my-keys'."
1589   (interactive)
1590   (if (called-interactively-p 'interactive)
1591       (setq dired-x-hands-off-my-keys
1592             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1593   (define-key (current-global-map) [remap find-file]
1594     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file))
1595   (define-key (current-global-map) [remap find-file-other-window]
1596     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window)))
1597
1598 ;; Now call it so binding is correct.  This could go in the :initialize
1599 ;; slot, but then dired-x-bind-find-file has to be defined before the
1600 ;; defcustom, and we get free variable warnings.
1601 (dired-x-bind-find-file)
1602
1603 (defun dired-x-find-file (filename)
1604   "Edit file FILENAME.
1605 Like `find-file', except that when called interactively with a
1606 prefix argument, it offers the filename near point as a default."
1607   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1608   (find-file filename))
1609
1610 (defun dired-x-find-file-other-window (filename)
1611   "Edit file FILENAME, in another window.
1612 Like `find-file-other-window', except that when called interactively with
1613 a prefix argument, when it offers the filename near point as a default."
1614   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1615   (find-file-other-window filename))
1616
1617 ;;; Internal functions.
1618
1619 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1620 (defun dired-filename-at-point ()
1621   "Return the filename closest to point, expanded.
1622 Point should be in or after a filename."
1623   (save-excursion
1624     ;; First see if just past a filename.
1625     (or (eobp)                             ; why?
1626         (when (looking-at-p "[] \t\n[{}()]") ; whitespace or some parens
1627           (skip-chars-backward " \n\t\r({[]})")
1628           (or (bobp) (backward-char 1))))
1629     (let ((filename-chars "-.[:alnum:]_/:$+@")
1630           start prefix)
1631       (if (looking-at-p (format "[%s]" filename-chars))
1632           (progn
1633             (skip-chars-backward filename-chars)
1634             (setq start (point)
1635                   prefix
1636                   ;; This is something to do with ange-ftp filenames.
1637                   ;; It convert foo@bar to /foo@bar.
1638                   ;; But when does the former occur in dired buffers?
1639                   (and (string-match-p
1640                         "^\\w+@"
1641                         (buffer-substring start (line-end-position)))
1642                        "/"))
1643             (if (string-match-p "[/~]" (char-to-string (preceding-char)))
1644                 (setq start (1- start)))
1645             (skip-chars-forward filename-chars))
1646         (error "No file found around point!"))
1647       ;; Return string.
1648       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1649
1650 (defun dired-x-read-filename-at-point (prompt)
1651   "Return filename prompting with PROMPT with completion.
1652 If `current-prefix-arg' is non-nil, uses name at point as guess."
1653   (if current-prefix-arg
1654       (let ((guess (dired-filename-at-point)))
1655         (read-file-name prompt
1656                         (file-name-directory guess)
1657                         guess
1658                         nil (file-name-nondirectory guess)))
1659     (read-file-name prompt default-directory)))
1660
1661 (define-obsolete-function-alias 'read-filename-at-point
1662   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1663 \f
1664 ;;; BUG REPORTS
1665
1666 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1667
1668 \f
1669 ;; As Barry Warsaw would say: "This might be useful..."
1670 (provide 'dired-x)
1671
1672 ;; Local Variables:
1673 ;; byte-compile-dynamic: t
1674 ;; generated-autoload-file: "dired-loaddefs.el"
1675 ;; End:
1676
1677 ;;; dired-x.el ends here