lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Howie Kaye
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This package provides the sorting facilities documented in the Emacs
  30 ;; user's manual.
  31
  32 ;;; Code:
  33
  34 (defgroup sort nil
  35   "Commands to sort text in an Emacs buffer."
  36   :group 'data)
  37
  38 (defcustom sort-fold-case nil
  39   "*Non-nil if the buffer sort functions should ignore case."
  40   :group 'sort
  41   :type 'boolean)
  42 ;;;###autoload(put 'sort-fold-case 'safe-local-variable 'booleanp)
  43
  44 ;;;###autoload
  45 (defun sort-subr (reverse nextrecfun endrecfun
  46                           &optional startkeyfun endkeyfun predicate)
  47   "General text sorting routine to divide buffer into records and sort them.
  48
  49 We divide the accessible portion of the buffer into disjoint pieces
  50 called sort records.  A portion of each sort record (perhaps all of
  51 it) is designated as the sort key.  The records are rearranged in the
  52 buffer in order by their sort keys.  The records may or may not be
  53 contiguous.
  54
  55 Usually the records are rearranged in order of ascending sort key.
  56 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  57 The variable `sort-fold-case' determines whether alphabetic case affects
  58 the sort order.
  59
  60 The next four arguments are functions to be called to move point
  61 across a sort record.  They will be called many times from within sort-subr.
  62
  63 NEXTRECFUN is called with point at the end of the previous record.
  64 It moves point to the start of the next record.
  65 It should move point to the end of the buffer if there are no more records.
  66 The first record is assumed to start at the position of point when sort-subr
  67 is called.
  68
  69 ENDRECFUN is called with point within the record.
  70 It should move point to the end of the record.
  71
  72 STARTKEYFUN moves from the start of the record to the start of the key.
  73 It may return either a non-nil value to be used as the key, or
  74 else the key is the substring between the values of point after
  75 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  76 starts at the beginning of the record.
  77
  78 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  79 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  80 same as ENDRECFUN.
  81
  82 PREDICATE is the function to use to compare keys.  If keys are numbers,
  83 it defaults to `<', otherwise it defaults to `string<'."
  84   ;; Heuristically try to avoid messages if sorting a small amt of text.
  85   (let ((messages (> (- (point-max) (point-min)) 50000)))
  86     (save-excursion
  87       (if messages (message "Finding sort keys..."))
  88       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  89                                            startkeyfun endkeyfun))
  90              (old (reverse sort-lists))
  91              (case-fold-search sort-fold-case))
  92         (if (null sort-lists)
  93             ()
  94           (or reverse (setq sort-lists (nreverse sort-lists)))
  95           (if messages (message "Sorting records..."))
  96           (setq sort-lists
  97                 (sort sort-lists
  98                       (cond (predicate
  99                              `(lambda (a b) (,predicate (car a) (car b))))
 100                             ((numberp (car (car sort-lists)))
 101                              'car-less-than-car)
 102                             ((consp (car (car sort-lists)))
 103                              (lambda (a b)
 104                                (> 0 (compare-buffer-substrings
 105                                      nil (car (car a)) (cdr (car a))
 106                                      nil (car (car b)) (cdr (car b))))))
 107                             (t
 108                              (lambda (a b) (string< (car a) (car b)))))))
 109           (if reverse (setq sort-lists (nreverse sort-lists)))
 110           (if messages (message "Reordering buffer..."))
 111           (sort-reorder-buffer sort-lists old)))
 112       (if messages (message "Reordering buffer... Done"))))
 113   nil)
 114
 115 ;; Parse buffer into records using the arguments as Lisp expressions;
 116 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 117 ;; where KEY is the sort key (a number or string),
 118 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 119
 120 ;; The records appear in the list lastmost first!
 121
 122 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 123   (let ((sort-lists ())
 124         (start-rec nil)
 125         done key)
 126     ;; Loop over sort records.
 127     ;(goto-char (point-min)) -- it is the caller's responsibility to
 128     ;arrange this if necessary
 129     (while (not (eobp))
 130       (setq start-rec (point))          ;save record start
 131       (setq done nil)
 132       ;; Get key value, or move to start of key.
 133       (setq key (catch 'key
 134                   (or (and startkeyfun (funcall startkeyfun))
 135                       ;; If key was not returned as value,
 136                       ;; move to end of key and get key from the buffer.
 137                       (let ((start (point)))
 138                         (funcall (or endkeyfun
 139                                      (prog1 endrecfun (setq done t))))
 140                         (cons start (point))))))
 141       ;; Move to end of this record (start of next one, or end of buffer).
 142       (cond ((prog1 done (setq done nil)))
 143             (endrecfun (funcall endrecfun))
 144             (nextrecfun (funcall nextrecfun) (setq done t)))
 145       (if key (push
 146                ;; consing optimization in case in which key is same as record.
 147                (if (and (consp key)
 148                         (equal (car key) start-rec)
 149                         (equal (cdr key) (point)))
 150                    (cons key key)
 151                  (cons key (cons start-rec (point))))
 152                sort-lists))
 153       (and (not done) nextrecfun (funcall nextrecfun)))
 154     sort-lists))
 155
 156 (defun sort-reorder-buffer (sort-lists old)
 157   (let ((last (point-min))
 158         (min (point-min)) (max (point-max))
 159         (old-buffer (current-buffer))
 160         (mb enable-multibyte-characters)
 161         temp-buffer)
 162     (with-temp-buffer
 163       (set-buffer-multibyte mb)
 164       ;; Record the temporary buffer.
 165       (setq temp-buffer (current-buffer))
 166
 167       ;; Copy the sorted text into the temporary buffer.
 168       (while sort-lists
 169         (goto-char (point-max))
 170         (insert-buffer-substring old-buffer
 171                                  last
 172                                  (nth 1 (car old)))
 173         (goto-char (point-max))
 174         (insert-buffer-substring old-buffer
 175                                  (nth 1 (car sort-lists))
 176                                  (cdr (cdr (car sort-lists))))
 177         (setq last (cdr (cdr (car old)))
 178               sort-lists (cdr sort-lists)
 179               old (cdr old)))
 180       (goto-char (point-max))
 181       (insert-buffer-substring old-buffer last max)
 182
 183       ;; Copy the reordered text from the temporary buffer
 184       ;; to the buffer we sorted (OLD-BUFFER).
 185       (set-buffer old-buffer)
 186       (let ((inhibit-quit t))
 187         ;; Make sure insertions done for reordering
 188         ;; saves any markers at the end of the sorted region,
 189         ;; by leaving the last character of the region.
 190         (delete-region min (1- max))
 191         ;; Now replace the one remaining old character with the sorted text.
 192         (goto-char (point-min))
 193         (insert-buffer-substring temp-buffer)
 194         (delete-region max (1+ max))))))
 195
 196 ;;;###autoload
 197 (defun sort-lines (reverse beg end)
 198   "Sort lines in region alphabetically; argument means descending order.
 199 Called from a program, there are three arguments:
 200 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 201 The variable `sort-fold-case' determines whether alphabetic case affects
 202 the sort order."
 203   (interactive "P\nr")
 204   (save-excursion
 205     (save-restriction
 206       (narrow-to-region beg end)
 207       (goto-char (point-min))
 208       (let ;; To make `end-of-line' and etc. to ignore fields.
 209           ((inhibit-field-text-motion t))
 210         (sort-subr reverse 'forward-line 'end-of-line)))))
 211
 212 ;;;###autoload
 213 (defun sort-paragraphs (reverse beg end)
 214   "Sort paragraphs in region alphabetically; argument means descending order.
 215 Called from a program, there are three arguments:
 216 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 217 The variable `sort-fold-case' determines whether alphabetic case affects
 218 the sort order."
 219   (interactive "P\nr")
 220   (save-excursion
 221     (save-restriction
 222       (narrow-to-region beg end)
 223       (goto-char (point-min))
 224       (sort-subr reverse
 225                  (function
 226                   (lambda ()
 227                     (while (and (not (eobp)) (looking-at paragraph-separate))
 228                       (forward-line 1))))
 229                  'forward-paragraph))))
 230
 231 ;;;###autoload
 232 (defun sort-pages (reverse beg end)
 233   "Sort pages in region alphabetically; argument means descending order.
 234 Called from a program, there are three arguments:
 235 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 236 The variable `sort-fold-case' determines whether alphabetic case affects
 237 the sort order."
 238   (interactive "P\nr")
 239   (save-excursion
 240     (save-restriction
 241       (narrow-to-region beg end)
 242       (goto-char (point-min))
 243       (sort-subr reverse
 244                  (function (lambda () (skip-chars-forward "\n")))
 245                  'forward-page))))
 246 \f
 247 (defvar sort-fields-syntax-table nil)
 248 (if sort-fields-syntax-table nil
 249   (let ((table (make-syntax-table))
 250         (i 0))
 251     (while (< i 256)
 252       (modify-syntax-entry i "w" table)
 253       (setq i (1+ i)))
 254     (modify-syntax-entry ?\s " " table)
 255     (modify-syntax-entry ?\t " " table)
 256     (modify-syntax-entry ?\n " " table)
 257     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 258     (setq sort-fields-syntax-table table)))
 259
 260 (defcustom sort-numeric-base 10
 261   "*The default base used by `sort-numeric-fields'."
 262   :group 'sort
 263   :type 'integer)
 264 ;;;###autoload(put 'sort-numeric-base 'safe-local-variable 'integerp)
 265
 266 ;;;###autoload
 267 (defun sort-numeric-fields (field beg end)
 268   "Sort lines in region numerically by the ARGth field of each line.
 269 Fields are separated by whitespace and numbered from 1 up.
 270 Specified field must contain a number in each line of the region,
 271 which may begin with \"0x\" or \"0\" for hexadecimal and octal values.
 272 Otherwise, the number is interpreted according to sort-numeric-base.
 273 With a negative arg, sorts by the ARGth field counted from the right.
 274 Called from a program, there are three arguments:
 275 FIELD, BEG and END.  BEG and END specify region to sort."
 276   (interactive "p\nr")
 277   (let ;; To make `end-of-line' and etc. to ignore fields.
 278       ((inhibit-field-text-motion t))
 279     (sort-fields-1 field beg end
 280                    (lambda ()
 281                      (sort-skip-fields field)
 282                      (let* ((case-fold-search t)
 283                             (base
 284                              (if (looking-at "\\(0x\\)[0-9a-f]\\|\\(0\\)[0-7]")
 285                                  (cond ((match-beginning 1)
 286                                         (goto-char (match-end 1))
 287                                         16)
 288                                        ((match-beginning 2)
 289                                         (goto-char (match-end 2))
 290                                         8)
 291                                        (t nil)))))
 292                        (string-to-number (buffer-substring (point)
 293                                                            (save-excursion
 294                                                              (forward-sexp 1)
 295                                                              (point)))
 296                                          (or base sort-numeric-base))))
 297                    nil)))
 298
 299 ;;;;;###autoload
 300 ;;(defun sort-float-fields (field beg end)
 301 ;;  "Sort lines in region numerically by the ARGth field of each line.
 302 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 303 ;;must contain a floating point number in each line of the region.  With a
 304 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 305 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 306 ;;region to sort."
 307 ;;  (interactive "p\nr")
 308 ;;  (sort-fields-1 field beg end
 309 ;;               (function (lambda ()
 310 ;;                           (sort-skip-fields field)
 311 ;;                           (string-to-number
 312 ;;                            (buffer-substring
 313 ;;                             (point)
 314 ;;                             (save-excursion
 315 ;;                               (re-search-forward
 316 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 317 ;;                               (point))))))
 318 ;;               nil))
 319
 320 ;;;###autoload
 321 (defun sort-fields (field beg end)
 322   "Sort lines in region lexicographically by the ARGth field of each line.
 323 Fields are separated by whitespace and numbered from 1 up.
 324 With a negative arg, sorts by the ARGth field counted from the right.
 325 Called from a program, there are three arguments:
 326 FIELD, BEG and END.  BEG and END specify region to sort.
 327 The variable `sort-fold-case' determines whether alphabetic case affects
 328 the sort order."
 329   (interactive "p\nr")
 330   (let ;; To make `end-of-line' and etc. to ignore fields.
 331       ((inhibit-field-text-motion t))
 332     (sort-fields-1 field beg end
 333                    (function (lambda ()
 334                                (sort-skip-fields field)
 335                                nil))
 336                    (function (lambda () (skip-chars-forward "^ \t\n"))))))
 337
 338 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 339   (let ((tbl (syntax-table)))
 340     (if (zerop field) (setq field 1))
 341     (unwind-protect
 342         (save-excursion
 343           (save-restriction
 344             (narrow-to-region beg end)
 345             (goto-char (point-min))
 346             (set-syntax-table sort-fields-syntax-table)
 347             (sort-subr nil
 348                        'forward-line 'end-of-line
 349                        startkeyfun endkeyfun)))
 350       (set-syntax-table tbl))))
 351
 352 ;; Position at the beginning of field N on the current line,
 353 ;; assuming point is initially at the beginning of the line.
 354 (defun sort-skip-fields (n)
 355   (if (> n 0)
 356       ;; Skip across N - 1 fields.
 357       (let ((i (1- n)))
 358         (while (> i 0)
 359           (skip-chars-forward " \t")
 360           (skip-chars-forward "^ \t\n")
 361           (setq i (1- i)))
 362         (skip-chars-forward " \t")
 363         (if (eolp)
 364             (error "Line has too few fields: %s"
 365                    (buffer-substring
 366                     (save-excursion (beginning-of-line) (point))
 367                     (save-excursion (end-of-line) (point))))))
 368     (end-of-line)
 369     ;; Skip back across - N - 1 fields.
 370     (let ((i (1- (- n))))
 371       (while (> i 0)
 372         (skip-chars-backward " \t")
 373         (skip-chars-backward "^ \t\n")
 374         (setq i (1- i)))
 375       (skip-chars-backward " \t"))
 376     (if (bolp)
 377         (error "Line has too few fields: %s"
 378                (buffer-substring
 379                 (save-excursion (beginning-of-line) (point))
 380                 (save-excursion (end-of-line) (point)))))
 381     ;; Position at the front of the field
 382     ;; even if moving backwards.
 383     (skip-chars-backward "^ \t\n")))
 384 \f
 385 (defvar sort-regexp-fields-regexp)
 386 (defvar sort-regexp-record-end)
 387
 388 ;; Move to the beginning of the next match for record-regexp,
 389 ;; and set sort-regexp-record-end to the end of that match.
 390 ;; If the next match is empty and does not advance point,
 391 ;; skip one character and try again.
 392 (defun sort-regexp-fields-next-record ()
 393   (let ((oldpos (point)))
 394     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 395          (setq sort-regexp-record-end (match-end 0))
 396          (if (= sort-regexp-record-end oldpos)
 397              (progn
 398                (forward-char 1)
 399                (re-search-forward sort-regexp-fields-regexp nil 'move)
 400                (setq sort-regexp-record-end (match-end 0)))
 401            t)
 402          (goto-char (match-beginning 0)))))
 403
 404 ;;;###autoload
 405 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 406   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 407 RECORD-REGEXP specifies the textual units which should be sorted.
 408   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 409 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 410   is to be used for sorting.
 411   If it is \"\\\\digit\" then the digit'th \"\\\\(...\\\\)\" match field from
 412   RECORD-REGEXP is used.
 413   If it is \"\\\\&\" then the whole record is used.
 414   Otherwise, it is a regular-expression for which to search within the record.
 415 If a match for KEY is not found within a record then that record is ignored.
 416
 417 With a negative prefix arg sorts in reverse order.
 418
 419 The variable `sort-fold-case' determines whether alphabetic case affects
 420 the sort order.
 421
 422 For example: to sort lines in the region by the first word on each line
 423  starting with the letter \"f\",
 424  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\\\=\\<f\\\\w*\\\\>\""
 425   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 426   ;; other sort-.*fields functions but then again this was before, since it
 427   ;; didn't use the magnitude of the arg to specify anything.
 428   (interactive "P\nsRegexp specifying records to sort:
 429 sRegexp specifying key within record: \nr")
 430   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 431          (setq key-regexp 0))
 432         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 433          (setq key-regexp (- (aref key-regexp 1) ?0))))
 434   (save-excursion
 435     (save-restriction
 436       (narrow-to-region beg end)
 437       (goto-char (point-min))
 438       (let (sort-regexp-record-end
 439             (sort-regexp-fields-regexp record-regexp))
 440         (re-search-forward sort-regexp-fields-regexp nil t)
 441         (setq sort-regexp-record-end (point))
 442         (goto-char (match-beginning 0))
 443         (sort-subr reverse
 444                    'sort-regexp-fields-next-record
 445                    (function (lambda ()
 446                                (goto-char sort-regexp-record-end)))
 447                    (function (lambda ()
 448                                (let ((n 0))
 449                                  (cond ((numberp key-regexp)
 450                                         (setq n key-regexp))
 451                                        ((re-search-forward
 452                                           key-regexp sort-regexp-record-end t)
 453                                         (setq n 0))
 454                                        (t (throw 'key nil)))
 455                                  (condition-case ()
 456                                      (cons (match-beginning n)
 457                                            (match-end n))
 458                                    ;; if there was no such register
 459                                    (error (throw 'key nil)))))))))))
 460
 461 \f
 462 (defvar sort-columns-subprocess t)
 463
 464 ;;;###autoload
 465 (defun sort-columns (reverse &optional beg end)
 466   "Sort lines in region alphabetically by a certain range of columns.
 467 For the purpose of this command, the region BEG...END includes
 468 the entire line that point is in and the entire line the mark is in.
 469 The column positions of point and mark bound the range of columns to sort on.
 470 A prefix argument means sort into REVERSE order.
 471 The variable `sort-fold-case' determines whether alphabetic case affects
 472 the sort order.
 473
 474 Note that `sort-columns' rejects text that contains tabs,
 475 because tabs could be split across the specified columns
 476 and it doesn't know how to handle that.  Also, when possible,
 477 it uses the `sort' utility program, which doesn't understand tabs.
 478 Use \\[untabify] to convert tabs to spaces before sorting."
 479   (interactive "P\nr")
 480   (save-excursion
 481     (let ;; To make `end-of-line' and etc. to ignore fields.
 482         ((inhibit-field-text-motion t)
 483          beg1 end1 col-beg1 col-end1 col-start col-end)
 484       (goto-char (min beg end))
 485       (setq col-beg1 (current-column))
 486       (beginning-of-line)
 487       (setq beg1 (point))
 488       (goto-char (max beg end))
 489       (setq col-end1 (current-column))
 490       (forward-line)
 491       (setq end1 (point))
 492       (setq col-start (min col-beg1 col-end1))
 493       (setq col-end (max col-beg1 col-end1))
 494       (if (search-backward "\t" beg1 t)
 495           (error "sort-columns does not work with tabs -- use M-x untabify"))
 496       (if (not (or (memq system-type '(vax-vms windows-nt))
 497                    (let ((pos beg1) plist fontified)
 498                      (catch 'found
 499                        (while (< pos end1)
 500                          (setq plist (text-properties-at pos))
 501                          (setq fontified (plist-get plist 'fontified))
 502                          (while (consp plist)
 503                            (unless (or (eq (car plist) 'fontified)
 504                                        (and (eq (car plist) 'face)
 505                                             fontified))
 506                              (throw 'found t))
 507                            (setq plist (cddr plist)))
 508                          (setq pos (next-property-change pos nil end1)))))))
 509           ;; Use the sort utility if we can; it is 4 times as fast.
 510           ;; Do not use it if there are any non-font-lock properties
 511           ;; in the region, since the sort utility would lose the
 512           ;; properties.  Tabs are used as field separator; on NetBSD,
 513           ;; sort complains if "\n" is used as field separator.
 514           (let ((sort-args (list (if reverse "-rt\t" "-t\t")
 515                                  (format "-k1.%d,1.%d"
 516                                          (1+ col-start)
 517                                          (1+ col-end)))))
 518             (when sort-fold-case
 519               (push "-f" sort-args))
 520             (apply #'call-process-region beg1 end1 "sort" t t nil sort-args))
 521         ;; On VMS and ms-windows, use Emacs's own facilities.
 522         (save-excursion
 523           (save-restriction
 524             (narrow-to-region beg1 end1)
 525             (goto-char beg1)
 526             (sort-subr reverse 'forward-line 'end-of-line
 527                        #'(lambda () (move-to-column col-start) nil)
 528                        #'(lambda () (move-to-column col-end) nil))))))))
 529
 530 ;;;###autoload
 531 (defun reverse-region (beg end)
 532   "Reverse the order of lines in a region.
 533 From a program takes two point or marker arguments, BEG and END."
 534   (interactive "r")
 535   (if (> beg end)
 536       (let (mid) (setq mid end end beg beg mid)))
 537   (save-excursion
 538     ;; put beg at the start of a line and end and the end of one --
 539     ;; the largest possible region which fits this criteria
 540     (goto-char beg)
 541     (or (bolp) (forward-line 1))
 542     (setq beg (point))
 543     (goto-char end)
 544     ;; the test for bolp is for those times when end is on an empty line;
 545     ;; it is probably not the case that the line should be included in the
 546     ;; reversal; it isn't difficult to add it afterward.
 547     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 548     (setq end (point-marker))
 549     ;; the real work.  this thing cranks through memory on large regions.
 550     (let (ll (do t))
 551       (while do
 552         (goto-char beg)
 553         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 554                        ll))
 555         (setq do (/= (point) end))
 556         (delete-region beg (if do (1+ (point)) (point))))
 557       (while (cdr ll)
 558         (insert (car ll) "\n")
 559         (setq ll (cdr ll)))
 560       (insert (car ll)))))
 561
 562 (provide 'sort)
 563
 564 ;;; arch-tag: fbac12be-2a7b-4c8a-9665-264d61f70bd9
 565 ;;; sort.el ends here