lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing
   2
   3 ;; Copyright (C) 1985, 1989, 1994, 1995, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: Inge Frick <inge@nada.kth.se>
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This package provides the `view' minor mode documented in the Emacs
  30 ;; user's manual.
  31 ;; View mode entry and exit is done through the functions view-mode-enter
  32 ;; and view-mode-exit.  Use these functions to enter or exit view-mode from
  33 ;; emacs lisp programs.
  34 ;; We use both view- and View- as prefix for symbols.  View- is used as
  35 ;; prefix for commands that have a key binding.  view- is used for commands
  36 ;; without key binding.  The purpose of this is to make it easier for a
  37 ;; user to use command name completion.
  38
  39 ;;; Suggested key bindings:
  40 ;;
  41 ;; (define-key ctl-x-4-map "v" 'view-file-other-window)  ; ^x4v
  42 ;; (define-key ctl-x-5-map "v" 'view-file-other-frame)  ; ^x5v
  43 ;;
  44 ;; You could also bind view-file, view-buffer, view-buffer-other-window and
  45 ;; view-buffer-other-frame to keys.
  46 \f
  47 ;;; Code:
  48
  49 (defgroup view nil
  50   "Peruse file or buffer without editing."
  51   :link '(function-link view-mode)
  52   :link '(custom-manual "(emacs)Misc File Ops")
  53   :group 'wp
  54   :group 'editing)
  55
  56 (defcustom view-highlight-face 'highlight
  57    "*The face used for highlighting the match found by View mode search."
  58    :type 'face
  59    :group 'view)
  60
  61 ;; `view-mode-auto-exit' is replaced by the following option variable which
  62 ;; only says if scrolling past buffer end should leave view mode or not, it
  63 ;; doesn't say if leaving view mode should restore windows or not.  The latter
  64 ;; is now controlled by the presence of a value in `view-return-to-alist'.
  65 (defcustom view-scroll-auto-exit nil
  66   "*Non-nil means scrolling past the end of buffer exits View mode.
  67 A value of nil means attempting to scroll past the end of the buffer,
  68 only rings the bell and gives a message on how to leave."
  69   :type 'boolean
  70   :group 'view)
  71
  72 (defcustom view-try-extend-at-buffer-end nil
  73  "*Non-nil means try to load more of file when reaching end of buffer.
  74 This variable is mainly intended to be temporarily set to non-nil by
  75 the F command in view-mode, but you can set it to t if you want the action
  76 for all scroll commands in view mode."
  77   :type 'boolean
  78   :group 'view)
  79
  80 (defcustom view-remove-frame-by-deleting nil
  81   "*Determine how View mode removes a frame no longer needed.
  82 If nil, make an icon of the frame.  If non-nil, delete the frame."
  83   :type 'boolean
  84   :group 'view)
  85
  86 (defcustom view-exits-all-viewing-windows nil
  87   "*Non-nil means restore all windows used to view buffer.
  88 Commands that restore windows when finished viewing a buffer, apply to all
  89 windows that display the buffer and have restore information in
  90 `view-return-to-alist'.
  91 If `view-exits-all-viewing-windows' is nil, only the selected window is
  92 considered for restoring."
  93   :type 'boolean
  94   :group 'view)
  95
  96 (defcustom view-inhibit-help-message nil
  97   "*Non-nil inhibits the help message shown upon entering View mode."
  98   :type 'boolean
  99   :group 'view
 100   :version "22.1")
 101
 102 ;;;###autoload
 103 (defvar view-mode nil
 104   "Non-nil if View mode is enabled.
 105 Don't change this variable directly, you must change it by one of the
 106 functions that enable or disable view mode.")
 107 ;;;###autoload
 108 (make-variable-buffer-local 'view-mode)
 109
 110 (defcustom view-mode-hook nil
 111   "Normal hook run when starting to view a buffer or file."
 112   :type 'hook
 113   :group 'view)
 114 \f
 115 (defvar view-old-buffer-read-only nil)
 116 (make-variable-buffer-local 'view-old-buffer-read-only)
 117
 118 (defvar view-old-Helper-return-blurb)
 119 (make-variable-buffer-local 'view-old-Helper-return-blurb)
 120
 121 ;; Just to avoid warnings.
 122 (defvar Helper-return-blurb)
 123
 124 (defvar view-page-size nil
 125   "Default number of lines to scroll by View page commands.
 126 If nil that means use the window size.")
 127 (make-variable-buffer-local 'view-page-size)
 128
 129 (defvar view-half-page-size nil
 130   "Default number of lines to scroll by View half page commands.
 131 If nil that means use half the window size.")
 132 (make-variable-buffer-local 'view-half-page-size)
 133
 134 (defvar view-last-regexp nil)
 135 (make-variable-buffer-local 'view-last-regexp) ; Global is better???
 136
 137 (defvar view-return-to-alist nil
 138   "What to do with used windows and where to go when finished viewing buffer.
 139 This is local in each buffer being viewed.
 140 It is added to by `view-mode-enter' when starting to view a buffer and
 141 subtracted from by `view-mode-exit' when finished viewing the buffer.
 142
 143 See RETURN-TO-ALIST argument of function `view-mode-exit' for the format of
 144 `view-return-to-alist'.")
 145 (make-variable-buffer-local 'view-return-to-alist)
 146 (put 'view-return-to-alist 'permanent-local t)
 147
 148 (defvar view-exit-action nil
 149   "nil or a function with one argument (a buffer) called when finished viewing.
 150 This is local in each buffer being viewed.
 151 The \\[view-file] and \\[view-file-other-window] commands may set this to
 152 `kill-buffer'.")
 153 (make-variable-buffer-local 'view-exit-action)
 154
 155 (defvar view-no-disable-on-exit nil
 156   "If non-nil, View mode \"exit\" commands don't actually disable View mode.
 157 Instead, these commands just switch buffers or windows.
 158 This is set in certain buffers by specialized features such as help commands
 159 that use View mode automatically.")
 160
 161 (defvar view-overlay nil
 162   "Overlay used to display where a search operation found its match.
 163 This is local in each buffer, once it is used.")
 164 (make-variable-buffer-local 'view-overlay)
 165
 166 (unless (assq 'view-mode minor-mode-alist)
 167   (setq minor-mode-alist
 168         (cons (list 'view-mode
 169                     (propertize " View"
 170                                 'local-map mode-line-minor-mode-keymap
 171                                 'help-echo "mouse-3: minor mode menu"))
 172               minor-mode-alist)))
 173 \f
 174 ;; Define keymap inside defvar to make it easier to load changes.
 175 ;; Some redundant "less"-like key bindings below have been commented out.
 176 (defvar view-mode-map
 177   (let ((map (make-sparse-keymap)))
 178     (define-key map "C" 'View-kill-and-leave)
 179     (define-key map "c" 'View-leave)
 180     (define-key map "Q" 'View-quit-all)
 181     (define-key map "E" 'View-exit-and-edit)
 182 ;    (define-key map "v" 'View-exit)
 183     (define-key map "e" 'View-exit)
 184     (define-key map "q" 'View-quit)
 185 ;    (define-key map "N" 'View-search-last-regexp-backward)
 186     (define-key map "p" 'View-search-last-regexp-backward)
 187     (define-key map "n" 'View-search-last-regexp-forward)
 188 ;    (define-key map "?" 'View-search-regexp-backward) ; Less does this.
 189     (define-key map "\\" 'View-search-regexp-backward)
 190     (define-key map "/" 'View-search-regexp-forward)
 191     (define-key map "r" 'isearch-backward)
 192     (define-key map "s" 'isearch-forward)
 193     (define-key map "m" 'point-to-register)
 194     (define-key map "'" 'register-to-point)
 195     (define-key map "x" 'exchange-point-and-mark)
 196     (define-key map "@" 'View-back-to-mark)
 197     (define-key map "." 'set-mark-command)
 198     (define-key map "%" 'View-goto-percent)
 199 ;    (define-key map "G" 'View-goto-line-last)
 200     (define-key map "g" 'View-goto-line)
 201     (define-key map "=" 'what-line)
 202     (define-key map "F" 'View-revert-buffer-scroll-page-forward)
 203 ;    (define-key map "k" 'View-scroll-line-backward)
 204     (define-key map "y" 'View-scroll-line-backward)
 205 ;    (define-key map "j" 'View-scroll-line-forward)
 206     (define-key map "\n" 'View-scroll-line-forward)
 207     (define-key map "\r" 'View-scroll-line-forward)
 208     (define-key map "u" 'View-scroll-half-page-backward)
 209     (define-key map "d" 'View-scroll-half-page-forward)
 210     (define-key map "z" 'View-scroll-page-forward-set-page-size)
 211     (define-key map "w" 'View-scroll-page-backward-set-page-size)
 212 ;    (define-key map "b" 'View-scroll-page-backward)
 213     (define-key map "\C-?" 'View-scroll-page-backward)
 214 ;    (define-key map "f" 'View-scroll-page-forward)
 215     (define-key map " " 'View-scroll-page-forward)
 216     (define-key map "o" 'View-scroll-to-buffer-end)
 217     (define-key map ">" 'end-of-buffer)
 218     (define-key map "<" 'beginning-of-buffer)
 219     (define-key map "-" 'negative-argument)
 220     (define-key map "9" 'digit-argument)
 221     (define-key map "8" 'digit-argument)
 222     (define-key map "7" 'digit-argument)
 223     (define-key map "6" 'digit-argument)
 224     (define-key map "5" 'digit-argument)
 225     (define-key map "4" 'digit-argument)
 226     (define-key map "3" 'digit-argument)
 227     (define-key map "2" 'digit-argument)
 228     (define-key map "1" 'digit-argument)
 229     (define-key map "0" 'digit-argument)
 230     (define-key map "H" 'describe-mode)
 231     (define-key map "?" 'describe-mode) ; Maybe do as less instead? See above.
 232     (define-key map "h" 'describe-mode)
 233     map))
 234
 235 (or (assq 'view-mode minor-mode-map-alist)
 236     (setq minor-mode-map-alist
 237           (cons (cons 'view-mode view-mode-map) minor-mode-map-alist)))
 238 \f
 239 ;;; Commands that enter or exit view mode.
 240
 241 ;;;###autoload
 242 (defun view-file (file)
 243   "View FILE in View mode, returning to previous buffer when done.
 244 Emacs commands editing the buffer contents are not available; instead,
 245 a special set of commands (mostly letters and punctuation)
 246 are defined for moving around in the buffer.
 247 Space scrolls forward, Delete scrolls backward.
 248 For list of all View commands, type H or h while viewing.
 249
 250 This command runs the normal hook `view-mode-hook'."
 251   (interactive "fView file: ")
 252   (unless (file-exists-p file) (error "%s does not exist" file))
 253   (let ((had-a-buf (get-file-buffer file))
 254         (buffer (find-file-noselect file)))
 255     (if (eq (with-current-buffer buffer
 256               (get major-mode 'mode-class))
 257             'special)
 258         (progn
 259           (switch-to-buffer buffer)
 260           (message "Not using View mode because the major mode is special"))
 261       (view-buffer buffer (and (not had-a-buf) 'kill-buffer)))))
 262
 263 ;;;###autoload
 264 (defun view-file-other-window (file)
 265   "View FILE in View mode in another window.
 266 Return that window to its previous buffer when done.
 267 Emacs commands editing the buffer contents are not available; instead,
 268 a special set of commands (mostly letters and punctuation)
 269 are defined for moving around in the buffer.
 270 Space scrolls forward, Delete scrolls backward.
 271 For list of all View commands, type H or h while viewing.
 272
 273 This command runs the normal hook `view-mode-hook'."
 274   (interactive "fIn other window view file: ")
 275   (unless (file-exists-p file) (error "%s does not exist" file))
 276   (let ((had-a-buf (get-file-buffer file)))
 277     (view-buffer-other-window (find-file-noselect file) nil
 278                               (and (not had-a-buf) 'kill-buffer))))
 279
 280 ;;;###autoload
 281 (defun view-file-other-frame (file)
 282   "View FILE in View mode in another frame.
 283 Maybe delete other frame and/or return to previous buffer when done.
 284 Emacs commands editing the buffer contents are not available; instead,
 285 a special set of commands (mostly letters and punctuation)
 286 are defined for moving around in the buffer.
 287 Space scrolls forward, Delete scrolls backward.
 288 For list of all View commands, type H or h while viewing.
 289
 290 This command runs the normal hook `view-mode-hook'."
 291   (interactive "fIn other frame view file: ")
 292   (unless (file-exists-p file) (error "%s does not exist" file))
 293   (let ((had-a-buf (get-file-buffer file)))
 294     (view-buffer-other-frame (find-file-noselect file) nil
 295                              (and (not had-a-buf) 'kill-buffer))))
 296
 297
 298 ;;;###autoload
 299 (defun view-buffer (buffer &optional exit-action)
 300   "View BUFFER in View mode, returning to previous buffer when done.
 301 Emacs commands editing the buffer contents are not available; instead,
 302 a special set of commands (mostly letters and punctuation)
 303 are defined for moving around in the buffer.
 304 Space scrolls forward, Delete scrolls backward.
 305 For list of all View commands, type H or h while viewing.
 306
 307 This command runs the normal hook `view-mode-hook'.
 308
 309 Optional argument EXIT-ACTION is either nil or a function with buffer as
 310 argument.  This function is called when finished viewing buffer.
 311 Use this argument instead of explicitly setting `view-exit-action'."
 312
 313   (interactive "bView buffer: ")
 314   (let ((undo-window (list (window-buffer) (window-start) (window-point))))
 315     (switch-to-buffer buffer)
 316     (view-mode-enter (cons (selected-window) (cons nil undo-window))
 317                      exit-action)))
 318
 319 ;;;###autoload
 320 (defun view-buffer-other-window (buffer &optional not-return exit-action)
 321   "View BUFFER in View mode in another window.
 322 Return to previous buffer when done, unless optional NOT-RETURN is non-nil.
 323 Emacs commands editing the buffer contents are not available; instead,
 324 a special set of commands (mostly letters and punctuation)
 325 are defined for moving around in the buffer.
 326 Space scrolls forward, Delete scrolls backward.
 327 For list of all View commands, type H or h while viewing.
 328
 329 This command runs the normal hook `view-mode-hook'.
 330
 331 Optional argument EXIT-ACTION is either nil or a function with buffer as
 332 argument.  This function is called when finished viewing buffer.
 333 Use this argument instead of explicitly setting `view-exit-action'."
 334   (interactive "bIn other window view buffer:\nP")
 335   (let* ((win                           ; This window will be selected by
 336           (get-lru-window))             ; switch-to-buffer-other-window below.
 337          (return-to
 338           (and (not not-return)
 339                (cons (selected-window)
 340                      (if (eq win (selected-window))
 341                          t                      ; Has to make new window.
 342                        (list
 343                         (window-buffer win)     ; Other windows old buffer.
 344                         (window-start win)
 345                         (window-point win)))))))
 346     (switch-to-buffer-other-window buffer)
 347     (view-mode-enter (and return-to (cons (selected-window) return-to))
 348                      exit-action)))
 349
 350 ;;;###autoload
 351 (defun view-buffer-other-frame (buffer &optional not-return exit-action)
 352   "View BUFFER in View mode in another frame.
 353 Return to previous buffer when done, unless optional NOT-RETURN is non-nil.
 354 Emacs commands editing the buffer contents are not available; instead,
 355 a special set of commands (mostly letters and punctuation)
 356 are defined for moving around in the buffer.
 357 Space scrolls forward, Delete scrolls backward.
 358 For list of all View commands, type H or h while viewing.
 359
 360 This command runs the normal hook `view-mode-hook'.
 361
 362 Optional argument EXIT-ACTION is either nil or a function with buffer as
 363 argument.  This function is called when finished viewing buffer.
 364 Use this argument instead of explicitly setting `view-exit-action'."
 365   (interactive "bView buffer in other frame: \nP")
 366   (let ((return-to
 367          (and (not not-return) (cons (selected-window) t)))) ; Old window.
 368     (switch-to-buffer-other-frame buffer)
 369     (view-mode-enter (and return-to (cons (selected-window) return-to))
 370                      exit-action)))
 371 \f
 372 ;;;###autoload
 373 (defun view-mode (&optional arg)
 374   ;; In the following documentation string we have to use some explicit key
 375   ;; bindings instead of using the \\[] construction.  The reason for this
 376   ;; is that most commands have more than one key binding.
 377   "Toggle View mode, a minor mode for viewing text but not editing it.
 378 With ARG, turn View mode on iff ARG is positive.
 379
 380 Emacs commands that do not change the buffer contents are available as usual.
 381 Kill commands insert text in kill buffers but do not delete.  Other commands
 382 \(among them most letters and punctuation) beep and tell that the buffer is
 383 read-only.
 384 \\<view-mode-map>
 385 The following additional commands are provided.  Most commands take prefix
 386 arguments.  Page commands default to \"page size\" lines which is almost a whole
 387 window full, or number of lines set by \\[View-scroll-page-forward-set-page-size] or \\[View-scroll-page-backward-set-page-size].  Half page commands default to
 388 and set \"half page size\" lines which initially is half a window full.  Search
 389 commands default to a repeat count of one.
 390
 391 H, h, ?  This message.
 392 Digits  provide prefix arguments.
 393 \\[negative-argument]   negative prefix argument.
 394 \\[beginning-of-buffer] move to the beginning of buffer.
 395 >       move to the end of buffer.
 396 \\[View-scroll-to-buffer-end]   scroll so that buffer end is at last line of window.
 397 SPC     scroll forward \"page size\" lines.
 398           With prefix scroll forward prefix lines.
 399 DEL     scroll backward \"page size\" lines.
 400           With prefix scroll backward prefix lines.
 401 \\[View-scroll-page-forward-set-page-size]      like  \\[View-scroll-page-forward]  but with prefix sets \"page size\" to prefix.
 402 \\[View-scroll-page-backward-set-page-size]     like  \\[View-scroll-page-backward]  but with prefix sets \"page size\" to prefix.
 403 \\[View-scroll-half-page-forward]       scroll forward \"half page size\" lines.  With prefix, sets
 404           \"half page size\" to prefix lines and scrolls forward that much.
 405 \\[View-scroll-half-page-backward]      scroll backward \"half page size\" lines.  With prefix, sets
 406           \"half page size\" to prefix lines and scrolls backward that much.
 407 RET, LFD  scroll forward one line.  With prefix scroll forward prefix line(s).
 408 y       scroll backward one line.  With prefix scroll backward prefix line(s).
 409 \\[View-revert-buffer-scroll-page-forward]      revert-buffer if necessary and scroll forward.
 410           Use this to view a changing file.
 411 \\[what-line]   prints the current line number.
 412 \\[View-goto-percent]   goes prefix argument (default 100) percent into buffer.
 413 \\[View-goto-line]      goes to line given by prefix argument (default first line).
 414 .       set the mark.
 415 x       exchanges point and mark.
 416 \\[View-back-to-mark]   return to mark and pops mark ring.
 417           Mark ring is pushed at start of every successful search and when
 418           jump to line occurs.  The mark is set on jump to buffer start or end.
 419 \\[point-to-register]   save current position in character register.
 420 '       go to position saved in character register.
 421 s       do forward incremental search.
 422 r       do reverse incremental search.
 423 \\[View-search-regexp-forward]  searches forward for regular expression, starting after current page.
 424           ! and @ have a special meaning at the beginning of the regexp.
 425           ! means search for a line with no match for regexp.  @ means start
 426           search at beginning (end for backward search) of buffer.
 427 \\      searches backward for regular expression, starting before current page.
 428 \\[View-search-last-regexp-forward]     searches forward for last regular expression.
 429 p       searches backward for last regular expression.
 430 \\[View-quit]   quit View mode, restoring this window and buffer to previous state.
 431           \\[View-quit] is the normal way to leave view mode.
 432 \\[View-exit]   exit View mode but stay in current buffer.  Use this if you started
 433           viewing a buffer (file) and find out you want to edit it.
 434           This command restores the previous read-only status of the buffer.
 435 \\[View-exit-and-edit]  exit View mode, and make the current buffer editable
 436           even if it was not editable before entry to View mode.
 437 \\[View-quit-all]       quit View mode, restoring all windows to previous state.
 438 \\[View-leave]  quit View mode and maybe switch buffers, but don't kill this buffer.
 439 \\[View-kill-and-leave] quit View mode, kill current buffer and go back to other buffer.
 440
 441 The effect of \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] depends on how view-mode was entered.  If it was
 442 entered by view-file, view-file-other-window, view-file-other-frame, or
 443 \\[dired-view-file] \(\\[view-file], \\[view-file-other-window],
 444 \\[view-file-other-frame], or the Dired mode v command),
 445 then \\[View-quit] will try to kill the current buffer.
 446 If view-mode was entered from another buffer, by \\[view-buffer],
 447 \\[view-buffer-other-window], \\[view-buffer-other frame], \\[view-file],
 448 \\[view-file-other-window], or \\[view-file-other-frame],
 449 then \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] will return to that buffer.
 450
 451 Entry to view-mode runs the normal hook `view-mode-hook'."
 452   (interactive "P")
 453   (unless (and arg                      ; Do nothing if already OK.
 454                (if (> (prefix-numeric-value arg) 0) view-mode (not view-mode)))
 455     (if view-mode (view-mode-disable)
 456       (view-mode-enable))))
 457 \f
 458 (defun view-mode-enable ()
 459   "Turn on View mode."
 460   ;; Always leave view mode before changing major mode.
 461   ;; This is to guarantee that the buffer-read-only variable is restored.
 462   (add-hook 'change-major-mode-hook 'view-mode-disable nil t)
 463   (setq view-mode t
 464         view-page-size nil
 465         view-half-page-size nil
 466         view-old-buffer-read-only buffer-read-only
 467         buffer-read-only t
 468         view-old-Helper-return-blurb (and (boundp 'Helper-return-blurb)
 469                                           Helper-return-blurb)
 470         Helper-return-blurb
 471         (format "continue viewing %s"
 472                 (if (buffer-file-name)
 473                     (file-name-nondirectory (buffer-file-name))
 474                   (buffer-name))))
 475   (force-mode-line-update)
 476   (run-hooks 'view-mode-hook))
 477
 478 (defun view-mode-disable ()
 479   "Turn off View mode."
 480   (remove-hook 'change-major-mode-hook 'view-mode-disable t)
 481   (and view-overlay (delete-overlay view-overlay))
 482   (force-mode-line-update)
 483   ;; Calling toggle-read-only while View mode is enabled
 484   ;; sets view-read-only to t as a buffer-local variable
 485   ;; after exiting View mode.  That arranges that the next toggle-read-only
 486   ;; will reenable View mode.
 487   ;; Cancelling View mode in any other way should cancel that, too,
 488   ;; so that View mode stays off if toggle-read-only is called.
 489   (if (local-variable-p 'view-read-only)
 490       (kill-local-variable 'view-read-only))
 491   (setq view-mode nil
 492         Helper-return-blurb view-old-Helper-return-blurb)
 493   (if buffer-read-only
 494       (setq buffer-read-only view-old-buffer-read-only)))
 495
 496 ;;;###autoload
 497 (defun view-mode-enter (&optional return-to exit-action) "\
 498 Enter View mode and set up exit from view mode depending on optional arguments.
 499 If RETURN-TO is non-nil it is added as an element to the buffer local alist
 500 `view-return-to-alist'.
 501 Save EXIT-ACTION in buffer local variable `view-exit-action'.
 502 It should be either nil or a function that takes a buffer as argument.
 503 This function will be called by `view-mode-exit'.
 504
 505 RETURN-TO is either nil, meaning do nothing when exiting view mode, or
 506 it has the format (WINDOW OLD-WINDOW . OLD-BUF-INFO).
 507 WINDOW is a window used for viewing.
 508 OLD-WINDOW is nil or the window to select after viewing.
 509 OLD-BUF-INFO tells what to do with WINDOW when exiting.  It is one of:
 510 1) nil       Do nothing.
 511 2) t         Delete WINDOW or, if it is the only window, its frame.
 512 3) (OLD-BUFF START POINT)  Display buffer OLD-BUFF with displayed text
 513                            starting at START and point at POINT in WINDOW.
 514 4) quit-window   Do `quit-window' in WINDOW.
 515
 516 For list of all View commands, type H or h while viewing.
 517
 518 This function runs the normal hook `view-mode-hook'."
 519   (if return-to
 520       (let ((entry (assq (car return-to) view-return-to-alist)))
 521         (if entry (setcdr entry (cdr return-to))
 522           (setq view-return-to-alist (cons return-to view-return-to-alist)))))
 523   (if exit-action (setq view-exit-action exit-action))
 524   (unless view-mode                     ; Do nothing if already in view mode.
 525     (view-mode-enable)
 526     (force-mode-line-update)
 527     (unless view-inhibit-help-message
 528       (message "%s"
 529                (substitute-command-keys "\
 530 View mode: type \\[help-command] for help, \\[describe-mode] for commands, \\[View-quit] to quit.")))))
 531 \f
 532 (defun view-mode-exit (&optional return-to-alist exit-action all-win)
 533   "Exit View mode in various ways, depending on optional arguments.
 534 RETURN-TO-ALIST, EXIT-ACTION and ALL-WIN determine what to do after exit.
 535 EXIT-ACTION is nil or a function that is called with current buffer as
 536 argument.
 537 RETURN-TO-ALIST is an alist that for some of the windows displaying the
 538 current buffer, associate information on what to do with those windows.
 539 If ALL-WIN or the variable `view-exits-all-viewing-windows' is non-nil,
 540 then all windows on RETURN-TO-ALIST are restored to their old state.
 541 Otherwise only the selected window is affected (if it is on RETURN-TO-ALIST).
 542
 543 Elements of RETURN-TO-ALIST have the format (WINDOW OLD-WINDOW . OLD-BUF-INFO).
 544 WINDOW is a window displaying the current buffer.
 545 OLD-WINDOW is nil or a window to select after viewing.
 546 OLD-BUF-INFO is information on what to do with WINDOW and is one of:
 547 1) nil       Do nothing.
 548 2) t         Delete WINDOW and, if it is the only window, its frame.
 549 3) (OLD-BUF START POINT)  Display buffer OLD-BUF with displayed text
 550                           starting at START and point at POINT in WINDOW.
 551 4) quit-window   Do `quit-window' in WINDOW.
 552
 553 If one of the WINDOW in RETURN-TO-ALIST is the selected window and the
 554 corresponding OLD-WINDOW is a live window, then select OLD-WINDOW."
 555   (setq all-win
 556         (and return-to-alist (or all-win view-exits-all-viewing-windows)))
 557   (if view-mode         ; Only do something if in view mode.
 558       (let* ((buffer (current-buffer))
 559              window notlost
 560              (sel-old (assq (selected-window) return-to-alist))
 561              (alist (cond
 562                      (all-win           ; Try to restore all windows.
 563                       (append return-to-alist nil)) ; Copy.
 564                      (sel-old           ; Only selected window.
 565                       (list sel-old))))
 566              (old-window (if sel-old (car (cdr sel-old)))))
 567         (if all-win                     ; Follow chains of old-windows.
 568             (let ((c (length alist)) a)
 569               (while (and (> c 0)       ; Safety if mutually refering windows.
 570                           (or (not (window-live-p old-window))
 571                               (eq buffer (window-buffer old-window)))
 572                           (setq a (assq old-window alist)))
 573                 (setq c (1- c))
 574                 (setq old-window (car (cdr a))))
 575               (if (or (zerop c) (not (window-live-p old-window)))
 576                   (setq old-window (selected-window)))))
 577         (or view-no-disable-on-exit
 578             (view-mode-disable))
 579         (while alist                    ; Restore windows with info.
 580           (setq notlost nil)
 581           (if (and (window-live-p (setq window (car (car alist))))
 582                    (eq buffer (window-buffer window)))
 583               (let ((frame (window-frame window))
 584                     (old-buf-info (cdr (cdr (car alist)))))
 585                 (if all-win (select-window window))
 586                 (cond
 587                  ((and (consp old-buf-info) ; Case 3.
 588                        (buffer-live-p (car old-buf-info)))
 589                   (set-window-buffer window (car old-buf-info)) ; old-buf
 590                   (set-window-start window (car (cdr old-buf-info)))
 591                   (set-window-point window (car (cdr (cdr old-buf-info)))))
 592                  ((eq old-buf-info 'quit-window)
 593                   (quit-window))        ; Case 4.
 594                  ((not (eq old-buf-info t)) nil) ; Not case 2, do nothing.
 595                  ((not (one-window-p t)) (delete-window))
 596                  ((not (eq frame (next-frame)))
 597                   ;; Not the only frame, so can safely be removed.
 598                   (if view-remove-frame-by-deleting
 599                       (delete-frame frame)
 600                     (setq notlost t)    ; Keep the window. See below.
 601                     (iconify-frame frame))))))
 602           ;; If a frame is removed by iconifying it, then the window is not
 603           ;; really lost.  In this case we keep the entry in
 604           ;; view-return-to-alist so that if the user deiconifies the frame
 605           ;; and then press q, then the frame is iconified again.
 606           (unless notlost
 607             (setq view-return-to-alist
 608                   (delete (car alist) view-return-to-alist)))
 609           (setq alist (cdr alist)))
 610         (if (window-live-p old-window)  ; still existing window
 611             (select-window old-window))
 612         (when exit-action
 613           (setq view-exit-action nil)
 614           (funcall exit-action buffer))
 615         (force-mode-line-update))))
 616 \f
 617 (defun View-exit ()
 618   "Exit View mode but stay in current buffer."
 619   (interactive)
 620   (view-mode-exit))
 621
 622 ;;;###autoload
 623 (defun View-exit-and-edit ()
 624   "Exit View mode and make the current buffer editable."
 625   (interactive)
 626   (let ((view-old-buffer-read-only nil)
 627         (view-no-disable-on-exit nil))
 628     (view-mode-exit)))
 629
 630 (defun View-leave ()
 631   "Quit View mode and maybe switch buffers, but don't kill this buffer."
 632   (interactive)
 633   (view-mode-exit view-return-to-alist))
 634
 635 (defun View-quit ()
 636   "Quit View mode, trying to restore window and buffer to previous state.
 637 Maybe kill this buffer.  Try to restore selected window to previous state
 638 and go to previous buffer or window."
 639   (interactive)
 640   (view-mode-exit view-return-to-alist view-exit-action))
 641
 642 (defun View-quit-all ()
 643   "Quit View mode, trying to restore windows and buffers to previous state.
 644 Maybe kill current buffer.  Try to restore all windows viewing buffer to
 645 previous state and go to previous buffer or window."
 646   (interactive)
 647   (view-mode-exit view-return-to-alist view-exit-action t))
 648
 649 (defun View-kill-and-leave ()
 650   "Quit View mode, kill current buffer and return to previous buffer."
 651   (interactive)
 652   (view-mode-exit view-return-to-alist (or view-exit-action 'kill-buffer) t))
 653 \f
 654
 655 ;;; Some help routines.
 656
 657 (defun view-window-size ()
 658   ;; Window height excluding mode line.
 659   (1- (window-height)))
 660
 661 ;(defun view-last-command (&optional who what)
 662 ;  (setq view-last-command-entry this-command)
 663 ;  (setq view-last-command who)
 664 ;  (setq view-last-command-argument what))
 665
 666 ;(defun View-repeat-last-command ()
 667 ;  "Repeat last command issued in View mode."
 668 ;  (interactive)
 669 ;  (if (and view-last-command
 670 ;          (eq view-last-command-entry last-command))
 671 ;      (funcall view-last-command view-last-command-argument))
 672 ;  (setq this-command view-last-command-entry))
 673
 674 (defun view-recenter ()
 675   ;; Center point in window.
 676   (recenter (/ (view-window-size) 2)))
 677
 678 (defun view-page-size-default (lines)
 679   ;; Get page size.
 680   (let ((default (- (view-window-size) next-screen-context-lines)))
 681     (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 682         default
 683       (min (abs lines) default))))
 684
 685 (defun view-set-half-page-size-default (lines)
 686   ;; Get and maybe set half page size.
 687   (if (not lines) (or view-half-page-size
 688                       (/ (view-window-size) 2))
 689     (setq view-half-page-size
 690           (if (zerop (setq lines (prefix-numeric-value lines)))
 691               (/ (view-window-size) 2)
 692             (view-page-size-default lines)))))
 693
 694
 695 ;;; Commands for moving around in the buffer.
 696
 697 (defun View-goto-percent (&optional percent)
 698   "Move to end (or prefix PERCENT) of buffer in View mode.
 699 Display is centered at point.
 700 Also set the mark at the position where point was."
 701   (interactive "P")
 702   (push-mark)
 703   (goto-char
 704    (if percent
 705        (+ (point-min)
 706           (floor (* (- (point-max) (point-min)) 0.01
 707                     (max 0 (min 100 (prefix-numeric-value percent))))))
 708      (point-max)))
 709   (view-recenter))
 710
 711 ;(defun View-goto-line-last (&optional line)
 712 ;"Move to last (or prefix LINE) line in View mode.
 713 ;Display is centered at LINE.
 714 ;Sets mark at starting position and pushes mark ring."
 715 ;  (interactive "P")
 716 ;  (push-mark)
 717 ;  (if line (goto-line (prefix-numeric-value line))
 718 ;    (goto-char (point-max))
 719 ;    (beginning-of-line))
 720 ;  (view-recenter))
 721
 722 (defun View-goto-line (&optional line)
 723   "Move to first (or prefix LINE) line in View mode.
 724 Display is centered at LINE.
 725 Also set the mark at the position where point was."
 726   (interactive "p")
 727   (push-mark)
 728   (goto-line line)
 729   (view-recenter))
 730
 731 (defun View-back-to-mark (&optional ignore)
 732   "Return to last mark set in View mode, else beginning of file.
 733 Display that line at the center of the window.
 734 This command pops the mark ring, so that successive
 735 invocations return to earlier marks."
 736   (interactive)
 737   (goto-char (or (mark t) (point-min)))
 738   (pop-mark)
 739   (view-recenter))
 740 \f
 741 (defun view-scroll-lines (lines backward default maxdefault)
 742   ;; This function does the job for all the scrolling commands.
 743   ;; Scroll forward LINES lines.  If BACKWARD is true scroll backwards.
 744   ;; If LINES is negative scroll in the other direction.  If LINES is 0 or nil,
 745   ;; scroll DEFAULT lines.  If MAXDEFAULT is true then scroll no more than a
 746   ;; window full.
 747   (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 748       (setq lines default))
 749   (when (< lines 0)
 750     (setq backward (not backward)) (setq lines (- lines)))
 751   (setq default (view-page-size-default nil)) ; Max scrolled at a time.
 752   (if maxdefault (setq lines (min lines default)))
 753   (cond
 754    (backward (scroll-down lines))
 755    ((view-really-at-end)
 756     (if view-scroll-auto-exit (View-quit)
 757       (ding)
 758       (view-end-message)))
 759    (t (while (> lines default)
 760         (scroll-up default)
 761         (setq lines (- lines default))
 762         (if (view-really-at-end) (setq lines 0)))
 763       (scroll-up lines)
 764       (if (view-really-at-end) (view-end-message))
 765       (move-to-window-line -1)
 766       (beginning-of-line))))
 767
 768 (defun view-really-at-end ()
 769   ;; Return true if buffer end visible.  Maybe revert buffer and test.
 770   (and (pos-visible-in-window-p (point-max))
 771        (let ((buf (current-buffer))
 772              (bufname (buffer-name))
 773              (file (buffer-file-name)))
 774          (or (not view-try-extend-at-buffer-end)
 775              (null file)
 776              (verify-visited-file-modtime buf)
 777              (not (file-exists-p file))
 778              (when (buffer-modified-p buf)
 779                (setq file (file-name-nondirectory file))
 780                (not (yes-or-no-p
 781                      (format
 782                       "File %s changed on disk.  Discard your edits%s? "
 783                       file
 784                       (if (string= bufname file) ""
 785                         (concat " in " bufname))))))
 786              (progn
 787                (revert-buffer t t t)
 788                (pos-visible-in-window-p (point-max)))))))
 789
 790 (defun view-end-message ()
 791   ;; Tell that we are at end of buffer.
 792   (goto-char (point-max))
 793   (if view-return-to-alist
 794       (message "End of buffer.  Type %s to quit viewing."
 795                (substitute-command-keys
 796                 (if view-scroll-auto-exit "\\[View-scroll-page-forward]"
 797                   "\\[View-quit]")))
 798     (message "End of buffer")))
 799 \f
 800 (defun View-scroll-to-buffer-end ()
 801   "Scroll backward or forward so that buffer end is at last line of window."
 802   (interactive)
 803   (let ((p (if (pos-visible-in-window-p (point-max)) (point))))
 804     (goto-char (point-max))
 805     (recenter -1)
 806     (and p (goto-char p))))
 807
 808 (defun View-scroll-page-forward (&optional lines)
 809   "Scroll \"page size\" or prefix LINES lines forward in View mode.
 810 Exit if end of text is visible and `view-scroll-auto-exit' is non-nil.
 811 \"page size\" is whole window full, or number of lines set by
 812 \\[View-scroll-page-forward-set-page-size] or
 813 \\[View-scroll-page-backward-set-page-size].
 814 If LINES is more than a window-full, only the last window-full is shown."
 815   (interactive "P")
 816   (view-scroll-lines lines nil (view-page-size-default view-page-size) nil))
 817
 818 (defun View-scroll-page-backward (&optional lines)
 819   "Scroll \"page size\" or prefix LINES lines backward in View mode.
 820 See also `View-scroll-page-forward'."
 821   (interactive "P")
 822   (view-scroll-lines lines t (view-page-size-default view-page-size) nil))
 823
 824 (defun View-scroll-page-forward-set-page-size (&optional lines)
 825   "Scroll forward LINES lines in View mode, setting the \"page size\".
 826 This is the number of lines which \\[View-scroll-page-forward] and
 827 \\[View-scroll-page-backward] scroll by default.
 828 If LINES is omitted or = 0, sets \"page size\" to window height and
 829 scrolls forward that much, otherwise scrolls forward LINES lines and sets
 830 \"page size\" to the minimum of window height and the absolute value of LINES.
 831 See also `View-scroll-page-forward'."
 832   (interactive "P")
 833   (view-scroll-lines lines nil
 834                      (setq view-page-size (view-page-size-default lines))
 835                      nil))
 836
 837 (defun View-scroll-page-backward-set-page-size (&optional lines)
 838   "Scroll backward prefix LINES lines in View mode, setting the \"page size\".
 839 See also `View-scroll-page-forward-set-page-size'."
 840   (interactive "P")
 841   (view-scroll-lines lines t
 842                      (setq view-page-size (view-page-size-default lines))
 843                      nil))
 844
 845 (defun View-scroll-line-forward (&optional lines)
 846   "Scroll forward one line (or prefix LINES lines) in View mode.
 847 See also `View-scroll-page-forward,' but note that scrolling is limited
 848 to minimum of LINES and one window-full."
 849   (interactive "P")
 850   (view-scroll-lines lines nil 1 t))
 851
 852 (defun View-scroll-line-backward (&optional lines)
 853   "Scroll backward one line (or prefix LINES lines) in View mode.
 854 See also `View-scroll-line-forward'."
 855   (interactive "P")
 856   (view-scroll-lines lines t 1 t))
 857
 858 (defun View-scroll-half-page-forward (&optional lines)
 859   "Scroll forward a \"half page\" (or prefix LINES) lines in View mode.
 860 If LINES is not omitted, the \"half page size\" is set to the minimum of
 861 window height and the absolute value of LINES.
 862 LINES=0 resets \"half page size\" to half window height."
 863   (interactive "P")
 864   (view-scroll-lines lines nil (view-set-half-page-size-default lines) t))
 865
 866 (defun View-scroll-half-page-backward (&optional lines)
 867   "Scroll backward a \"half page\" (or prefix LINES) lines in View mode.
 868 See also `View-scroll-half-page-forward'."
 869   (interactive "P")
 870   (view-scroll-lines lines t (view-set-half-page-size-default lines) t))
 871
 872 (defun View-revert-buffer-scroll-page-forward (&optional lines)
 873   "Scroll forward, reverting buffer if needed, in View mode.
 874 If buffer has not been changed and the corresponding file is newer, first
 875 revert the buffer, then scroll.
 876 This command is useful if you are viewing a changing file.
 877
 878 The prefix argument LINES says how many lines to scroll.
 879 If you don't specify a prefix argument, it uses the number of lines set by
 880 \\[View-scroll-page-forward-set-page-size] or
 881 \\[View-scroll-page-backward-set-page-size].
 882 If LINES is more than a window-full, only the last window-full is shown."
 883   (interactive "P")
 884   (let ((view-scroll-auto-exit nil)
 885         (view-try-extend-at-buffer-end t))
 886     (view-scroll-lines lines nil (view-page-size-default view-page-size) nil)))
 887 \f
 888 (defun View-search-regexp-forward (n regexp)
 889   "Search forward for first (or prefix Nth) occurrence of REGEXP in View mode.
 890
 891 Displays line found at center of window.  Sets mark at starting position and
 892 pushes mark ring.
 893
 894 Characters @ and ! are special at the beginning of REGEXP.  They modify
 895 the search rather than become part of the pattern searched for.
 896 @ means search all the buffer i.e. start search at the beginning of buffer.
 897 ! means search for a line that contains no match for the pattern.
 898 If REGEXP is empty or only consist of these control characters, then
 899 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 900 for use by later search commands.
 901
 902 The variable `view-highlight-face' controls the face that is used
 903 for highlighting the match that is found."
 904   (interactive "p\nsSearch forward (regexp): ")
 905   (view-search n regexp))
 906
 907 (defun View-search-regexp-backward (n regexp)
 908   "Search backward for first (or prefix Nth) occurrence of REGEXP in View mode.
 909
 910 Displays line found at center of window.  Sets mark at starting position and
 911 pushes mark ring.
 912
 913 Characters @ and ! are special at the beginning of REGEXP.  They modify
 914 the search rather than become part of the pattern searched for.
 915 @ means search all the buffer i.e. start search at the end of buffer.
 916 ! means search for a line that contains no match for the pattern.
 917 If REGEXP is empty or only consist of these control characters, then
 918 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 919 for use by later search commands.
 920
 921 The variable `view-highlight-face' controls the face that is used
 922 for highlighting the match that is found."
 923   (interactive "p\nsSearch backward (regexp): ")
 924   (view-search (- n) regexp))
 925
 926 (defun View-search-last-regexp-forward (n) "\
 927 Search forward for first (or prefix Nth) instance of last regexp in View mode.
 928 Displays line found at center of window.  Sets mark at starting position and
 929 pushes mark ring.
 930
 931 The variable `view-highlight-face' controls the face that is used
 932 for highlighting the match that is found."
 933   (interactive "p")
 934   (view-search n nil))
 935
 936 (defun View-search-last-regexp-backward (n) "\
 937 Search backward for first (or prefix Nth) instance of last regexp in View mode.
 938 Displays line found at center of window.  Sets mark at starting position and
 939 pushes mark ring.
 940
 941 The variable `view-highlight-face' controls the face that is used
 942 for highlighting the match that is found."
 943   (interactive "p")
 944   (view-search (- n) nil))
 945
 946 (defun view-search (times regexp)
 947   ;; This function does the job for all the View-search- commands.
 948   ;; Search for the TIMESt match for REGEXP. If TIMES is negative
 949   ;; search backwards. If REGEXP is nil use `view-last-regexp'.
 950   ;; Charcters "!" and "@" have a special meaning at the beginning of
 951   ;; REGEXP and are removed from REGEXP before the search "!" means
 952   ;; search for lines with no match for REGEXP.  "@" means search in
 953   ;; the whole buffer, don't start searching from the present point.
 954   (let (where no end ln)
 955     (cond
 956      ((and regexp (> (length regexp) 0)
 957            (or (not (memq (string-to-char regexp) '(?! ?@)))
 958                (progn
 959                  (if (member (substring regexp 0 2) '("!@" "@!"))
 960                      (setq end t no t ln 2)
 961                    (setq no (not (setq end (eq ?@ (string-to-char regexp))))
 962                          ln 1))
 963                  (> (length (setq regexp (substring regexp ln))) 0))))
 964       (setq view-last-regexp (if no (list regexp) regexp)))
 965      ((consp view-last-regexp)
 966       (setq regexp (car view-last-regexp))
 967       (unless (setq no (not no)) (setq view-last-regexp regexp)))
 968      (view-last-regexp (setq regexp view-last-regexp)
 969                        (if no (setq view-last-regexp (list regexp))))
 970      (t (error "No previous View-mode search")))
 971     (save-excursion
 972       (if end (goto-char (if (< times 0) (point-max) (point-min)))
 973         (move-to-window-line (if (< times 0) 0 -1)))
 974       (if (if no (view-search-no-match-lines times regexp)
 975             (re-search-forward regexp nil t times))
 976           (setq where (point))))
 977     (if where
 978         (progn
 979           (push-mark)
 980           (goto-char where)
 981           (if view-overlay
 982               (move-overlay view-overlay (match-beginning 0) (match-end 0))
 983             (setq view-overlay
 984                   (make-overlay (match-beginning 0) (match-end 0))))
 985           (overlay-put view-overlay 'face view-highlight-face)
 986           (beginning-of-line)
 987           (view-recenter))
 988       (message "Can't find occurrence %d of %s%s"
 989                times (if no "no " "") regexp)
 990       (sit-for 4))))
 991
 992 (defun view-search-no-match-lines (times regexp)
 993   ;; Search for the TIMESt occurrence of line with no match for REGEXP.
 994   (let ((back (and (< times 0) (setq times (- times)) -1))
 995         n)
 996     (while (> times 0)
 997       (save-excursion (beginning-of-line (if back (- times) (1+ times)))
 998                       (setq n (point)))
 999       (setq times
1000             (cond
1001              ((< (count-lines (point) n) times) -1) ; Not enough lines.
1002              ((or (null (re-search-forward regexp nil t back))
1003                   (if back (and (< (match-end 0) n)
1004                                 (> (count-lines (match-end 0) n) 1))
1005                     (and (< n (match-beginning 0))
1006                          (> (count-lines n (match-beginning 0)) 1))))
1007               0)                        ; No match within lines.
1008              (back (count-lines (max n (match-beginning 0)) (match-end 0)))
1009              (t (count-lines (match-beginning 0) (min n (match-end 0))))))
1010       (goto-char n))
1011     (and (zerop times) (looking-at "^.*$"))))
1012
1013
1014 (provide 'view)
1015
1016 ;;; arch-tag: 6d0ace36-1d12-4de3-8de3-1fa3231636d7
1017 ;;; view.el ends here