lisp/calendar/cal-mayan.el

   1 ;;; cal-mayan.el --- calendar functions for the Mayan calendars
   2
   3 ;; Copyright (C) 1992, 1993, 1995, 1997, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007  Free Software Foundation, Inc.
   5
   6 ;; Author: Stewart M. Clamen <clamen@cs.cmu.edu>
   7 ;;      Edward M. Reingold <reingold@cs.uiuc.edu>
   8 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   9 ;; Keywords: calendar
  10 ;; Human-Keywords: Mayan calendar, Maya, calendar, diary
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  27 ;; Boston, MA 02110-1301, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; This collection of functions implements the features of calendar.el and
  32 ;; diary.el that deal with the Mayan calendar.  It was written jointly by
  33
  34 ;;  Stewart M. Clamen                School of Computer Science
  35 ;;  clamen@cs.cmu.edu                Carnegie Mellon University
  36 ;;                                   5000 Forbes Avenue
  37 ;;                                   Pittsburgh, PA 15213
  38
  39 ;; and
  40
  41 ;;  Edward M. Reingold               Department of Computer Science
  42 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  43 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  44 ;;                                   Urbana, Illinois 61801
  45
  46 ;; Comments, improvements, and bug reports should be sent to Reingold.
  47
  48 ;; Technical details of the Mayan calendrical calculations can be found in
  49 ;; ``Calendrical Calculations: The Millennium Edition'' by Edward M. Reingold
  50 ;; and Nachum Dershowitz, Cambridge University Press (2001), and in
  51 ;; ``Calendrical Calculations, Part II: Three Historical Calendars''
  52 ;; by E. M. Reingold,  N. Dershowitz, and S. M. Clamen,
  53 ;; Software--Practice and Experience, Volume 23, Number 4 (April, 1993),
  54 ;; pages 383-404.
  55
  56 ;;; Code:
  57
  58 (defvar date)
  59
  60 (require 'calendar)
  61
  62 (defconst calendar-mayan-days-before-absolute-zero 1137142
  63   "Number of days of the Mayan calendar epoch before absolute day 0.
  64 This is the Goodman-Martinez-Thompson correlation used by almost all experts,
  65 but some use 1137140.  Using 1232041 gives you Spinden's correlation; using
  66 1142840 gives you Hochleitner's correlation.")
  67
  68 (defconst calendar-mayan-haab-at-epoch '(8 . 18)
  69   "Mayan haab date at the epoch.")
  70
  71 (defconst calendar-mayan-haab-month-name-array
  72   ["Pop" "Uo" "Zip" "Zotz" "Tzec" "Xul" "Yaxkin" "Mol" "Chen" "Yax"
  73    "Zac" "Ceh" "Mac" "Kankin" "Muan" "Pax" "Kayab" "Cumku"])
  74
  75 (defconst calendar-mayan-tzolkin-at-epoch '(4 . 20)
  76   "Mayan tzolkin date at the epoch.")
  77
  78 (defconst calendar-mayan-tzolkin-names-array
  79   ["Imix" "Ik" "Akbal" "Kan" "Chicchan" "Cimi" "Manik" "Lamat" "Muluc" "Oc"
  80    "Chuen" "Eb" "Ben" "Ix" "Men" "Cib" "Caban" "Etznab" "Cauac" "Ahau"])
  81
  82 (defun calendar-mayan-long-count-from-absolute (date)
  83   "Compute the Mayan long count corresponding to the absolute DATE."
  84   (let ((long-count (+ date calendar-mayan-days-before-absolute-zero)))
  85     (let* ((baktun (/ long-count 144000))
  86            (remainder (% long-count 144000))
  87            (katun (/ remainder 7200))
  88            (remainder (% remainder 7200))
  89            (tun (/ remainder 360))
  90            (remainder (% remainder 360))
  91            (uinal (/ remainder 20))
  92            (kin (% remainder 20)))
  93       (list baktun katun tun uinal kin))))
  94
  95 (defun calendar-mayan-long-count-to-string (mayan-long-count)
  96   "Convert MAYAN-LONG-COUNT into traditional written form."
  97   (apply 'format (cons "%s.%s.%s.%s.%s" mayan-long-count)))
  98
  99 (defun calendar-string-to-mayan-long-count (str)
 100   "Given STR, a string of format \"%d.%d.%d.%d.%d\", return list of nums."
 101   (let ((rlc nil)
 102         (c (length str))
 103         (cc 0))
 104     (condition-case condition
 105         (progn
 106           (while (< cc c)
 107             (let* ((start (string-match "[0-9]+" str cc))
 108                    (end (match-end 0))
 109                    datum)
 110               (setq datum (read (substring str start end)))
 111               (setq rlc (cons datum rlc))
 112               (setq cc end)))
 113           (if (not (= (length rlc) 5)) (signal 'invalid-read-syntax nil)))
 114       (invalid-read-syntax nil))
 115     (reverse rlc)))
 116
 117 (defun calendar-mayan-haab-from-absolute (date)
 118   "Convert absolute DATE into a Mayan haab date (a pair)."
 119   (let* ((long-count (+ date calendar-mayan-days-before-absolute-zero))
 120          (day-of-haab
 121           (% (+ long-count
 122                 (car calendar-mayan-haab-at-epoch)
 123                 (* 20 (1- (cdr calendar-mayan-haab-at-epoch))))
 124              365))
 125          (day (% day-of-haab 20))
 126          (month (1+ (/ day-of-haab 20))))
 127     (cons day month)))
 128
 129 (defun calendar-mayan-haab-difference (date1 date2)
 130   "Number of days from Mayan haab DATE1 to next occurrence of haab date DATE2."
 131   (mod (+ (* 20 (- (cdr date2) (cdr date1)))
 132           (- (car date2) (car date1)))
 133        365))
 134
 135 (defun calendar-mayan-haab-on-or-before (haab-date date)
 136   "Absolute date of latest HAAB-DATE on or before absolute DATE."
 137   (- date
 138      (% (- date
 139            (calendar-mayan-haab-difference
 140             (calendar-mayan-haab-from-absolute 0) haab-date))
 141         365)))
 142
 143 (defun calendar-next-haab-date (haab-date &optional noecho)
 144   "Move cursor to next instance of Mayan HAAB-DATE.
 145 Echo Mayan date if NOECHO is t."
 146   (interactive (list (calendar-read-mayan-haab-date)))
 147   (calendar-goto-date
 148    (calendar-gregorian-from-absolute
 149     (calendar-mayan-haab-on-or-before
 150      haab-date
 151      (+ 365
 152         (calendar-absolute-from-gregorian (calendar-cursor-to-date))))))
 153   (or noecho (calendar-print-mayan-date)))
 154
 155 (defun calendar-previous-haab-date (haab-date &optional noecho)
 156   "Move cursor to previous instance of Mayan HAAB-DATE.
 157 Echo Mayan date if NOECHO is t."
 158   (interactive (list (calendar-read-mayan-haab-date)))
 159   (calendar-goto-date
 160    (calendar-gregorian-from-absolute
 161     (calendar-mayan-haab-on-or-before
 162      haab-date
 163      (1- (calendar-absolute-from-gregorian (calendar-cursor-to-date))))))
 164   (or noecho (calendar-print-mayan-date)))
 165
 166 (defun calendar-mayan-haab-to-string (haab)
 167   "Convert Mayan haab date (a pair) into its traditional written form."
 168   (let ((month (cdr haab))
 169         (day (car haab)))
 170   ;; 19th month consists of 5 special days
 171   (if (= month 19)
 172       (format "%d Uayeb" day)
 173     (format "%d %s"
 174             day
 175             (aref calendar-mayan-haab-month-name-array (1- month))))))
 176
 177 (defun calendar-mayan-tzolkin-from-absolute (date)
 178   "Convert absolute DATE into a Mayan tzolkin date (a pair)."
 179   (let* ((long-count (+ date calendar-mayan-days-before-absolute-zero))
 180          (day (calendar-mod
 181                (+ long-count (car calendar-mayan-tzolkin-at-epoch))
 182                13))
 183          (name (calendar-mod
 184                 (+ long-count (cdr calendar-mayan-tzolkin-at-epoch))
 185                 20)))
 186     (cons day name)))
 187
 188 (defun calendar-mayan-tzolkin-difference (date1 date2)
 189   "Number of days from Mayan tzolkin DATE1 to next occurrence of tzolkin DATE2."
 190   (let ((number-difference (- (car date2) (car date1)))
 191         (name-difference (- (cdr date2) (cdr date1))))
 192     (mod (+ number-difference
 193             (* 13 (mod (* 3 (- number-difference name-difference))
 194                        20)))
 195          260)))
 196
 197 (defun calendar-mayan-tzolkin-on-or-before (tzolkin-date date)
 198   "Absolute date of latest TZOLKIN-DATE on or before absolute DATE."
 199   (- date
 200      (% (- date (calendar-mayan-tzolkin-difference
 201                  (calendar-mayan-tzolkin-from-absolute 0)
 202                  tzolkin-date))
 203         260)))
 204
 205 (defun calendar-next-tzolkin-date (tzolkin-date &optional noecho)
 206   "Move cursor to next instance of Mayan TZOLKIN-DATE.
 207 Echo Mayan date if NOECHO is t."
 208   (interactive (list (calendar-read-mayan-tzolkin-date)))
 209   (calendar-goto-date
 210    (calendar-gregorian-from-absolute
 211     (calendar-mayan-tzolkin-on-or-before
 212      tzolkin-date
 213      (+ 260
 214         (calendar-absolute-from-gregorian (calendar-cursor-to-date))))))
 215   (or noecho (calendar-print-mayan-date)))
 216
 217 (defun calendar-previous-tzolkin-date (tzolkin-date &optional noecho)
 218   "Move cursor to previous instance of Mayan TZOLKIN-DATE.
 219 Echo Mayan date if NOECHO is t."
 220   (interactive (list (calendar-read-mayan-tzolkin-date)))
 221   (calendar-goto-date
 222    (calendar-gregorian-from-absolute
 223     (calendar-mayan-tzolkin-on-or-before
 224      tzolkin-date
 225      (1- (calendar-absolute-from-gregorian (calendar-cursor-to-date))))))
 226   (or noecho (calendar-print-mayan-date)))
 227
 228 (defun calendar-mayan-tzolkin-to-string (tzolkin)
 229   "Convert Mayan tzolkin date (a pair) into its traditional written form."
 230   (format "%d %s"
 231           (car tzolkin)
 232           (aref calendar-mayan-tzolkin-names-array (1- (cdr tzolkin)))))
 233
 234 (defun calendar-mayan-tzolkin-haab-on-or-before (tzolkin-date haab-date date)
 235   "Absolute date that is Mayan TZOLKIN-DATE and HAAB-DATE.
 236 Latest such date on or before DATE.
 237 Returns nil if such a tzolkin-haab combination is impossible."
 238   (let* ((haab-difference
 239           (calendar-mayan-haab-difference
 240            (calendar-mayan-haab-from-absolute 0)
 241            haab-date))
 242          (tzolkin-difference
 243           (calendar-mayan-tzolkin-difference
 244            (calendar-mayan-tzolkin-from-absolute 0)
 245            tzolkin-date))
 246          (difference (- tzolkin-difference haab-difference)))
 247     (if (= (% difference 5) 0)
 248         (- date
 249            (mod (- date
 250                    (+ haab-difference (* 365 difference)))
 251                 18980))
 252       nil)))
 253
 254 (defun calendar-read-mayan-haab-date ()
 255   "Prompt for a Mayan haab date"
 256   (let* ((completion-ignore-case t)
 257          (haab-day (calendar-read
 258                     "Haab kin (0-19): "
 259                     '(lambda (x) (and (>= x 0) (< x 20)))))
 260          (haab-month-list (append calendar-mayan-haab-month-name-array
 261                                   (and (< haab-day 5) '("Uayeb"))))
 262          (haab-month (cdr
 263                       (assoc-string
 264                        (completing-read "Haab uinal: "
 265                                         (mapcar 'list haab-month-list)
 266                                         nil t)
 267                        (calendar-make-alist haab-month-list 1) t))))
 268     (cons haab-day haab-month)))
 269
 270 (defun calendar-read-mayan-tzolkin-date ()
 271   "Prompt for a Mayan tzolkin date"
 272   (let* ((completion-ignore-case t)
 273          (tzolkin-count (calendar-read
 274                          "Tzolkin kin (1-13): "
 275                          '(lambda (x) (and (> x 0) (< x 14)))))
 276          (tzolkin-name-list (append calendar-mayan-tzolkin-names-array nil))
 277          (tzolkin-name (cdr
 278                         (assoc-string
 279                           (completing-read "Tzolkin uinal: "
 280                                            (mapcar 'list tzolkin-name-list)
 281                                            nil t)
 282                          (calendar-make-alist tzolkin-name-list 1) t))))
 283     (cons tzolkin-count tzolkin-name)))
 284
 285 (defun calendar-next-calendar-round-date
 286   (tzolkin-date haab-date &optional noecho)
 287   "Move cursor to next instance of Mayan HAAB-DATE TZOLKIN-DATE combination.
 288 Echo Mayan date if NOECHO is t."
 289   (interactive (list (calendar-read-mayan-tzolkin-date)
 290                      (calendar-read-mayan-haab-date)))
 291   (let ((date (calendar-mayan-tzolkin-haab-on-or-before
 292                tzolkin-date haab-date
 293                (+ 18980 (calendar-absolute-from-gregorian
 294                          (calendar-cursor-to-date))))))
 295     (if (not date)
 296         (error "%s, %s does not exist in the Mayan calendar round"
 297                (calendar-mayan-tzolkin-to-string tzolkin-date)
 298                (calendar-mayan-haab-to-string haab-date))
 299       (calendar-goto-date (calendar-gregorian-from-absolute date))
 300       (or noecho (calendar-print-mayan-date)))))
 301
 302 (defun calendar-previous-calendar-round-date
 303   (tzolkin-date haab-date &optional noecho)
 304   "Move to previous instance of Mayan TZOLKIN-DATE HAAB-DATE combination.
 305 Echo Mayan date if NOECHO is t."
 306   (interactive (list (calendar-read-mayan-tzolkin-date)
 307                      (calendar-read-mayan-haab-date)))
 308   (let ((date (calendar-mayan-tzolkin-haab-on-or-before
 309                tzolkin-date haab-date
 310                (1- (calendar-absolute-from-gregorian
 311                     (calendar-cursor-to-date))))))
 312     (if (not date)
 313         (error "%s, %s does not exist in the Mayan calendar round"
 314                (calendar-mayan-tzolkin-to-string tzolkin-date)
 315                (calendar-mayan-haab-to-string haab-date))
 316       (calendar-goto-date (calendar-gregorian-from-absolute date))
 317       (or noecho (calendar-print-mayan-date)))))
 318
 319 (defun calendar-absolute-from-mayan-long-count (c)
 320   "Compute the absolute date corresponding to the Mayan Long Count C.
 321 Long count is a list (baktun katun tun uinal kin)"
 322   (+ (* (nth 0 c) 144000)        ; baktun
 323      (* (nth 1 c) 7200)          ; katun
 324      (* (nth 2 c) 360)           ; tun
 325      (* (nth 3 c) 20)            ; uinal
 326      (nth 4 c)                   ; kin (days)
 327      (-                          ; days before absolute date 0
 328       calendar-mayan-days-before-absolute-zero)))
 329
 330 (defun calendar-mayan-date-string (&optional date)
 331   "String of Mayan date of Gregorian DATE.
 332 Defaults to today's date if DATE is not given."
 333   (let* ((d (calendar-absolute-from-gregorian
 334              (or date (calendar-current-date))))
 335          (tzolkin (calendar-mayan-tzolkin-from-absolute d))
 336          (haab (calendar-mayan-haab-from-absolute d))
 337          (long-count (calendar-mayan-long-count-from-absolute d)))
 338       (format "Long count = %s; tzolkin = %s; haab = %s"
 339               (calendar-mayan-long-count-to-string long-count)
 340               (calendar-mayan-tzolkin-to-string tzolkin)
 341               (calendar-mayan-haab-to-string haab))))
 342
 343 (defun calendar-print-mayan-date ()
 344   "Show the Mayan long count, tzolkin, and haab equivalents of date."
 345   (interactive)
 346   (message "Mayan date: %s"
 347            (calendar-mayan-date-string (calendar-cursor-to-date t))))
 348
 349 (defun calendar-goto-mayan-long-count-date (date &optional noecho)
 350   "Move cursor to Mayan long count DATE.  Echo Mayan date unless NOECHO is t."
 351   (interactive
 352    (let (lc)
 353      (while (not lc)
 354        (let ((datum
 355               (calendar-string-to-mayan-long-count
 356                (read-string "Mayan long count (baktun.katun.tun.uinal.kin): "
 357                             (calendar-mayan-long-count-to-string
 358                              (calendar-mayan-long-count-from-absolute
 359                                (calendar-absolute-from-gregorian
 360                                 (calendar-current-date))))))))
 361          (if (calendar-mayan-long-count-common-era datum)
 362              (setq lc datum))))
 363      (list lc)))
 364   (calendar-goto-date
 365    (calendar-gregorian-from-absolute
 366     (calendar-absolute-from-mayan-long-count date)))
 367   (or noecho (calendar-print-mayan-date)))
 368
 369 (defun calendar-mayan-long-count-common-era (lc)
 370   "T if long count represents date in the Common Era."
 371   (let ((base (calendar-mayan-long-count-from-absolute 1)))
 372     (while (and (not (null base)) (= (car lc) (car base)))
 373       (setq lc (cdr lc)
 374             base (cdr base)))
 375     (or (null lc) (> (car lc) (car base)))))
 376
 377 (defun diary-mayan-date ()
 378   "Show the Mayan long count, haab, and tzolkin dates as a diary entry."
 379   (format "Mayan date: %s" (calendar-mayan-date-string date)))
 380
 381 (provide 'cal-mayan)
 382
 383 ;;; arch-tag: 54f35144-cd0f-4873-935a-a60129de07df
 384 ;;; cal-mayan.el ends here