lisp/url/url-cookie.el

   1 ;;; url-cookie.el --- Netscape Cookie support
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'timezone)
  30 (require 'url-util)
  31 (require 'url-parse)
  32 (eval-when-compile (require 'cl))
  33
  34 ;; See http://home.netscape.com/newsref/std/cookie_spec.html for the
  35 ;; 'open standard' defining this crap.
  36 ;;
  37 ;; A cookie is stored internally as a vector of 7 slots
  38 ;; [ cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE ]
  39
  40 (defsubst url-cookie-name    (cookie) (aref cookie 1))
  41 (defsubst url-cookie-value   (cookie) (aref cookie 2))
  42 (defsubst url-cookie-expires (cookie) (aref cookie 3))
  43 (defsubst url-cookie-localpart    (cookie) (aref cookie 4))
  44 (defsubst url-cookie-domain  (cookie) (aref cookie 5))
  45 (defsubst url-cookie-secure  (cookie) (aref cookie 6))
  46
  47 (defsubst url-cookie-set-name    (cookie val) (aset cookie 1 val))
  48 (defsubst url-cookie-set-value   (cookie val) (aset cookie 2 val))
  49 (defsubst url-cookie-set-expires (cookie val) (aset cookie 3 val))
  50 (defsubst url-cookie-set-localpart (cookie val) (aset cookie 4 val))
  51 (defsubst url-cookie-set-domain  (cookie val) (aset cookie 5 val))
  52 (defsubst url-cookie-set-secure  (cookie val) (aset cookie 6 val))
  53 (defsubst url-cookie-retrieve-arg (key args) (nth 1 (memq key args)))
  54
  55 (defsubst url-cookie-create (&rest args)
  56   "Create a cookie vector object from keyword-value pairs ARGS.
  57 The keywords allowed are
  58   :name NAME
  59   :value VALUE
  60   :expires TIME
  61   :localpart LOCALPAR
  62   :domain DOMAIN
  63   :secure ???
  64 Could someone fill in more information?"
  65   (let ((retval (make-vector 7 nil)))
  66     (aset retval 0 'cookie)
  67     (url-cookie-set-name retval (url-cookie-retrieve-arg :name args))
  68     (url-cookie-set-value retval (url-cookie-retrieve-arg :value args))
  69     (url-cookie-set-expires retval (url-cookie-retrieve-arg :expires args))
  70     (url-cookie-set-localpart retval (url-cookie-retrieve-arg :localpart args))
  71     (url-cookie-set-domain retval (url-cookie-retrieve-arg :domain args))
  72     (url-cookie-set-secure retval (url-cookie-retrieve-arg :secure args))
  73     retval))
  74
  75 (defun url-cookie-p (obj)
  76   "Return non-nil if OBJ is a cookie vector object.
  77 These objects represent cookies in the URL package.
  78 A cookie vector object is a vector of 7 slots:
  79  [cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE]."
  80   (and (vectorp obj) (= (length obj) 7) (eq (aref obj 0) 'cookie)))
  81
  82 (defgroup url-cookie nil
  83   "URL cookies."
  84   :prefix "url-"
  85   :prefix "url-cookie-"
  86   :group 'url)
  87
  88 (defvar url-cookie-storage nil         "Where cookies are stored.")
  89 (defvar url-cookie-secure-storage nil  "Where secure cookies are stored.")
  90 (defcustom url-cookie-file nil
  91   "*File where cookies are stored on disk."
  92   :type '(choice (const :tag "Default" :value nil) file)
  93   :group 'url-file
  94   :group 'url-cookie)
  95
  96 (defcustom url-cookie-confirmation nil
  97   "*If non-nil, confirmation by the user is required to accept HTTP cookies."
  98   :type 'boolean
  99   :group 'url-cookie)
 100
 101 (defcustom url-cookie-multiple-line nil
 102   "*If nil, HTTP requests put all cookies for the server on one line.
 103 Some web servers, such as http://www.hotmail.com/, only accept cookies
 104 when they are on one line.  This is broken behavior, but just try
 105 telling Microsoft that."
 106   :type 'boolean
 107   :group 'url-cookie)
 108
 109 (defvar url-cookies-changed-since-last-save nil
 110   "Whether the cookies list has changed since the last save operation.")
 111
 112 ;;;###autoload
 113 (defun url-cookie-parse-file (&optional fname)
 114   (setq fname (or fname url-cookie-file))
 115   (condition-case ()
 116       (load fname nil t)
 117     (error (message "Could not load cookie file %s" fname))))
 118
 119 (defun url-cookie-clean-up (&optional secure)
 120   (let* (
 121          (var (if secure 'url-cookie-secure-storage 'url-cookie-storage))
 122          (val (symbol-value var))
 123          (cur nil)
 124          (new nil)
 125          (cookies nil)
 126          (cur-cookie nil)
 127          (new-cookies nil)
 128          )
 129     (while val
 130       (setq cur (car val)
 131             val (cdr val)
 132             new-cookies nil
 133             cookies (cdr cur))
 134       (while cookies
 135         (setq cur-cookie (car cookies)
 136               cookies (cdr cookies))
 137         (if (or (not (url-cookie-p cur-cookie))
 138                 (url-cookie-expired-p cur-cookie)
 139                 (null (url-cookie-expires cur-cookie)))
 140             nil
 141           (setq new-cookies (cons cur-cookie new-cookies))))
 142       (if (not new-cookies)
 143           nil
 144         (setcdr cur new-cookies)
 145         (setq new (cons cur new))))
 146     (set var new)))
 147
 148 ;;;###autoload
 149 (defun url-cookie-write-file (&optional fname)
 150   (setq fname (or fname url-cookie-file))
 151   (unless (file-directory-p (file-name-directory fname))
 152     (ignore-errors (make-directory (file-name-directory fname))))
 153   (cond
 154    ((not url-cookies-changed-since-last-save) nil)
 155    ((not (file-writable-p fname))
 156     (message "Cookies file %s (see variable `url-cookie-file') is unwritable." fname))
 157    (t
 158     (url-cookie-clean-up)
 159     (url-cookie-clean-up t)
 160     (with-current-buffer (get-buffer-create " *cookies*")
 161       (erase-buffer)
 162       (fundamental-mode)
 163       (insert ";; Emacs-W3 HTTP cookies file\n"
 164               ";; Automatically generated file!!! DO NOT EDIT!!!\n\n"
 165               "(setq url-cookie-storage\n '")
 166       (pp url-cookie-storage (current-buffer))
 167       (insert ")\n(setq url-cookie-secure-storage\n '")
 168       (pp url-cookie-secure-storage (current-buffer))
 169       (insert ")\n")
 170       (write-file fname)
 171       (kill-buffer (current-buffer))))))
 172
 173 (defun url-cookie-store (name value &optional expires domain localpart secure)
 174   "Store a netscape-style cookie."
 175   (let* ((storage (if secure url-cookie-secure-storage url-cookie-storage))
 176          (tmp storage)
 177          (cur nil)
 178          (found-domain nil))
 179
 180     ;; First, look for a matching domain
 181     (setq found-domain (assoc domain storage))
 182
 183     (if found-domain
 184         ;; Need to either stick the new cookie in existing domain storage
 185         ;; or possibly replace an existing cookie if the names match.
 186         (progn
 187           (setq storage (cdr found-domain)
 188                 tmp nil)
 189           (while storage
 190             (setq cur (car storage)
 191                   storage (cdr storage))
 192             (if (and (equal localpart (url-cookie-localpart cur))
 193                      (equal name (url-cookie-name cur)))
 194                 (progn
 195                   (url-cookie-set-expires cur expires)
 196                   (url-cookie-set-value cur value)
 197                   (setq tmp t))))
 198           (if (not tmp)
 199               ;; New cookie
 200               (setcdr found-domain (cons
 201                                     (url-cookie-create :name name
 202                                                        :value value
 203                                                        :expires expires
 204                                                        :domain domain
 205                                                        :localpart localpart
 206                                                        :secure secure)
 207                                     (cdr found-domain)))))
 208       ;; Need to add a new top-level domain
 209       (setq tmp (url-cookie-create :name name
 210                                    :value value
 211                                    :expires expires
 212                                    :domain domain
 213                                    :localpart localpart
 214                                    :secure secure))
 215       (cond
 216        (storage
 217         (setcdr storage (cons (list domain tmp) (cdr storage))))
 218        (secure
 219         (setq url-cookie-secure-storage (list (list domain tmp))))
 220        (t
 221         (setq url-cookie-storage (list (list domain tmp))))))))
 222
 223 (defun url-cookie-expired-p (cookie)
 224   (let* (
 225          (exp (url-cookie-expires cookie))
 226          (cur-date (and exp (timezone-parse-date (current-time-string))))
 227          (exp-date (and exp (timezone-parse-date exp)))
 228          (cur-greg (and cur-date (timezone-absolute-from-gregorian
 229                                   (string-to-number (aref cur-date 1))
 230                                   (string-to-number (aref cur-date 2))
 231                                   (string-to-number (aref cur-date 0)))))
 232          (exp-greg (and exp (timezone-absolute-from-gregorian
 233                              (string-to-number (aref exp-date 1))
 234                              (string-to-number (aref exp-date 2))
 235                              (string-to-number (aref exp-date 0)))))
 236          (diff-in-days (and exp (- cur-greg exp-greg)))
 237          )
 238     (cond
 239      ((not exp) nil)                    ; No expiry == expires at browser quit
 240      ((< diff-in-days 0) nil)           ; Expires sometime after today
 241      ((> diff-in-days 0) t)             ; Expired before today
 242      (t                                 ; Expires sometime today, check times
 243       (let* ((cur-time (timezone-parse-time (aref cur-date 3)))
 244              (exp-time (timezone-parse-time (aref exp-date 3)))
 245              (cur-norm (+ (* 360 (string-to-number (aref cur-time 2)))
 246                           (*  60 (string-to-number (aref cur-time 1)))
 247                           (*   1 (string-to-number (aref cur-time 0)))))
 248              (exp-norm (+ (* 360 (string-to-number (aref exp-time 2)))
 249                           (*  60 (string-to-number (aref exp-time 1)))
 250                           (*   1 (string-to-number (aref exp-time 0))))))
 251         (> (- cur-norm exp-norm) 1))))))
 252
 253 ;;;###autoload
 254 (defun url-cookie-retrieve (host localpart &optional secure)
 255   "Retrieve all the netscape-style cookies for a specified HOST and LOCALPART."
 256   (let ((storage (if secure
 257                      (append url-cookie-secure-storage url-cookie-storage)
 258                    url-cookie-storage))
 259         (case-fold-search t)
 260         (cookies nil)
 261         (cur nil)
 262         (retval nil)
 263         (localpart-regexp nil))
 264     (while storage
 265       (setq cur (car storage)
 266             storage (cdr storage)
 267             cookies (cdr cur))
 268       (if (and (car cur)
 269                (string-match (concat "^.*" (regexp-quote (car cur)) "$") host))
 270           ;; The domains match - a possible hit!
 271           (while cookies
 272             (setq cur (car cookies)
 273                   cookies (cdr cookies)
 274                   localpart-regexp (concat "^" (regexp-quote
 275                                                 (url-cookie-localpart cur))))
 276             (if (and (string-match localpart-regexp localpart)
 277                      (not (url-cookie-expired-p cur)))
 278                 (setq retval (cons cur retval))))))
 279     retval))
 280
 281 ;;;###autoload
 282 (defun url-cookie-generate-header-lines (host localpart secure)
 283   (let* ((cookies (url-cookie-retrieve host localpart secure))
 284          (retval nil)
 285          (cur nil)
 286          (chunk nil))
 287     ;; Have to sort this for sending most specific cookies first
 288     (setq cookies (and cookies
 289                        (sort cookies
 290                              (function
 291                               (lambda (x y)
 292                                 (> (length (url-cookie-localpart x))
 293                                    (length (url-cookie-localpart y))))))))
 294     (while cookies
 295       (setq cur (car cookies)
 296             cookies (cdr cookies)
 297             chunk (format "%s=%s" (url-cookie-name cur) (url-cookie-value cur))
 298             retval (if (and url-cookie-multiple-line
 299                             (< 80 (+ (length retval) (length chunk) 4)))
 300                        (concat retval "\r\nCookie: " chunk)
 301                      (if retval
 302                          (concat retval "; " chunk)
 303                        (concat "Cookie: " chunk)))))
 304     (if retval
 305         (concat retval "\r\n")
 306       "")))
 307
 308 (defvar url-cookie-two-dot-domains
 309   (concat "\\.\\("
 310    (mapconcat 'identity (list "com" "edu" "net" "org" "gov" "mil" "int")
 311               "\\|")
 312    "\\)$")
 313   "A regexp of top level domains that only require two matching
 314 '.'s in the domain name in order to set a cookie.")
 315
 316 (defcustom url-cookie-trusted-urls nil
 317   "*A list of regular expressions matching URLs to always accept cookies from."
 318   :type '(repeat regexp)
 319   :group 'url-cookie)
 320
 321 (defcustom url-cookie-untrusted-urls nil
 322   "*A list of regular expressions matching URLs to never accept cookies from."
 323   :type '(repeat regexp)
 324   :group 'url-cookie)
 325
 326 (defun url-cookie-host-can-set-p (host domain)
 327   (let ((numdots 0)
 328         (tmp domain)
 329         (last nil)
 330         (case-fold-search t)
 331         (mindots 3))
 332     (while (setq last (string-match "\\." domain last))
 333       (setq numdots (1+ numdots)
 334             last (1+ last)))
 335     (if (string-match url-cookie-two-dot-domains domain)
 336         (setq mindots 2))
 337     (cond
 338      ((string= host domain)             ; Apparently netscape lets you do this
 339       t)
 340      ((>= numdots mindots)              ; We have enough dots in domain name
 341       ;; Need to check and make sure the host is actually _in_ the
 342       ;; domain it wants to set a cookie for though.
 343       (string-match (concat (regexp-quote domain) "$") host))
 344      (t
 345       nil))))
 346
 347 ;;;###autoload
 348 (defun url-cookie-handle-set-cookie (str)
 349   (setq url-cookies-changed-since-last-save t)
 350   (let* ((args (url-parse-args str t))
 351          (case-fold-search t)
 352          (secure (and (assoc-string "secure" args t) t))
 353          (domain (or (cdr-safe (assoc-string "domain" args t))
 354                      (url-host url-current-object)))
 355          (current-url (url-view-url t))
 356          (trusted url-cookie-trusted-urls)
 357          (untrusted url-cookie-untrusted-urls)
 358          (expires (cdr-safe (assoc-string "expires" args t)))
 359          (localpart (or (cdr-safe (assoc-string "path" args t))
 360                         (file-name-directory
 361                          (url-filename url-current-object))))
 362          (rest nil))
 363     (while args
 364       (if (not (member (downcase (car (car args)))
 365                        '("secure" "domain" "expires" "path")))
 366           (setq rest (cons (car args) rest)))
 367       (setq args (cdr args)))
 368
 369     ;; Sometimes we get dates that the timezone package cannot handle very
 370     ;; gracefully - take care of this here, instead of in url-cookie-expired-p
 371     ;; to speed things up.
 372     (if (and expires
 373              (string-match
 374               (concat "^[^,]+, +\\(..\\)-\\(...\\)-\\(..\\) +"
 375                       "\\(..:..:..\\) +\\[*\\([^\]]+\\)\\]*$")
 376               expires))
 377         (setq expires (concat (match-string 1 expires) " "
 378                               (match-string 2 expires) " "
 379                               (match-string 3 expires) " "
 380                               (match-string 4 expires) " ["
 381                               (match-string 5 expires) "]")))
 382
 383     ;; This one is for older Emacs/XEmacs variants that don't
 384     ;; understand this format without tenths of a second in it.
 385     ;; Wednesday, 30-Dec-2037 16:00:00 GMT
 386     ;;       - vs -
 387     ;; Wednesday, 30-Dec-2037 16:00:00.00 GMT
 388     (if (and expires
 389              (string-match
 390               "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)*[ \t]+\\([-+a-zA-Z0-9]+\\)"
 391               expires))
 392         (setq expires (concat (match-string 1 expires) "-"      ; day
 393                               (match-string 2 expires) "-"      ; month
 394                               (match-string 3 expires) " "      ; year
 395                               (match-string 4 expires) ".00 " ; hour:minutes:seconds
 396                               (match-string 6 expires)))) ":" ; timezone
 397
 398     (while (consp trusted)
 399       (if (string-match (car trusted) current-url)
 400           (setq trusted (- (match-end 0) (match-beginning 0)))
 401         (pop trusted)))
 402     (while (consp untrusted)
 403       (if (string-match (car untrusted) current-url)
 404           (setq untrusted (- (match-end 0) (match-beginning 0)))
 405         (pop untrusted)))
 406     (if (and trusted untrusted)
 407         ;; Choose the more specific match
 408         (if (> trusted untrusted)
 409             (setq untrusted nil)
 410           (setq trusted nil)))
 411     (cond
 412      (untrusted
 413       ;; The site was explicity marked as untrusted by the user
 414       nil)
 415      ((or (eq url-privacy-level 'paranoid)
 416           (and (listp url-privacy-level) (memq 'cookies url-privacy-level)))
 417       ;; user never wants cookies
 418       nil)
 419      ((and url-cookie-confirmation
 420            (not trusted)
 421            (save-window-excursion
 422              (with-output-to-temp-buffer "*Cookie Warning*"
 423                (mapcar
 424                 (function
 425                  (lambda (x)
 426                    (princ (format "%s - %s" (car x) (cdr x))))) rest))
 427              (prog1
 428                  (not (funcall url-confirmation-func
 429                                (format "Allow %s to set these cookies? "
 430                                        (url-host url-current-object))))
 431                (if (get-buffer "*Cookie Warning*")
 432                    (kill-buffer "*Cookie Warning*")))))
 433       ;; user wants to be asked, and declined.
 434       nil)
 435      ((url-cookie-host-can-set-p (url-host url-current-object) domain)
 436       ;; Cookie is accepted by the user, and passes our security checks
 437       (let ((cur nil))
 438         (while rest
 439           (setq cur (pop rest))
 440           (url-cookie-store (car cur) (cdr cur)
 441                             expires domain localpart secure))))
 442      (t
 443       (message "%s tried to set a cookie for domain %s - rejected."
 444                (url-host url-current-object) domain)))))
 445
 446 (defvar url-cookie-timer nil)
 447
 448 (defcustom url-cookie-save-interval 3600
 449   "*The number of seconds between automatic saves of cookies.
 450 Default is 1 hour.  Note that if you change this variable outside of
 451 the `customize' interface after `url-do-setup' has been run, you need
 452 to run the `url-cookie-setup-save-timer' function manually."
 453   :set #'(lambda (var val)
 454            (set-default var val)
 455            (if (bound-and-true-p url-setup-done)
 456                (url-cookie-setup-save-timer)))
 457   :type 'integer
 458   :group 'url)
 459
 460 ;;;###autoload
 461 (defun url-cookie-setup-save-timer ()
 462   "Reset the cookie saver timer."
 463   (interactive)
 464   (ignore-errors (cancel-timer url-cookie-timer))
 465   (setq url-cookie-timer nil)
 466   (if url-cookie-save-interval
 467       (setq url-cookie-timer (run-at-time url-cookie-save-interval
 468                                           url-cookie-save-interval
 469                                           #'url-cookie-write-file))))
 470
 471 (provide 'url-cookie)
 472
 473 ;; arch-tag: 2568751b-6452-4398-aa2d-303edadb54d7
 474 ;;; url-cookie.el ends here