lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998-2012 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: multimedia
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28
  29 (defgroup image ()
  30   "Image support."
  31   :group 'multimedia)
  32
  33 (defalias 'image-refresh 'image-flush)
  34
  35 (defconst image-type-header-regexps
  36   `(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  37     ("\\`P[1-6][[:space:]]+\\(?:#.*[[:space:]]+\\)*[0-9]+[[:space:]]+[0-9]+" . pbm)
  38     ("\\`GIF8[79]a" . gif)
  39     ("\\`\x89PNG\r\n\x1a\n" . png)
  40     ("\\`[\t\n\r ]*#define \\([a-z0-9_]+\\)_width [0-9]+\n\
  41 #define \\1_height [0-9]+\n\\(\
  42 #define \\1_x_hot [0-9]+\n\
  43 #define \\1_y_hot [0-9]+\n\\)?\
  44 static \\(unsigned \\)?char \\1_bits" . xbm)
  45     ("\\`\\(?:MM\0\\*\\|II\\*\0\\)" . tiff)
  46     ("\\`[\t\n\r ]*%!PS" . postscript)
  47     ("\\`\xff\xd8" . jpeg)    ; used to be (image-jpeg-p . jpeg)
  48     (,(let* ((incomment-re "\\(?:[^-]\\|-[^-]\\)")
  49              (comment-re (concat "\\(?:!--" incomment-re "*-->[ \t\r\n]*<\\)")))
  50         (concat "\\(?:<\\?xml[ \t\r\n]+[^>]*>\\)?[ \t\r\n]*<"
  51                 comment-re "*"
  52                 "\\(?:!DOCTYPE[ \t\r\n]+[^>]*>[ \t\r\n]*<[ \t\r\n]*" comment-re "*\\)?"
  53                 "[Ss][Vv][Gg]"))
  54      . svg)
  55     )
  56   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  57 When the first bytes of an image file match REGEXP, it is assumed to
  58 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  59 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  60 with one argument, a string containing the image data.  If PREDICATE returns
  61 a non-nil value, TYPE is the image's type.")
  62
  63 (defvar image-type-file-name-regexps
  64   '(("\\.png\\'" . png)
  65     ("\\.gif\\'" . gif)
  66     ("\\.jpe?g\\'" . jpeg)
  67     ("\\.bmp\\'" . bmp)
  68     ("\\.xpm\\'" . xpm)
  69     ("\\.pbm\\'" . pbm)
  70     ("\\.xbm\\'" . xbm)
  71     ("\\.ps\\'" . postscript)
  72     ("\\.tiff?\\'" . tiff)
  73     ("\\.svgz?\\'" . svg)
  74     )
  75   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  76 When the name of an image file match REGEXP, it is assumed to
  77 be of image type IMAGE-TYPE.")
  78
  79 ;; We rely on `auto-mode-alist' to detect xbm and xpm files, instead
  80 ;; of content autodetection.  Their contents are just C code, so it is
  81 ;; easy to generate false matches.
  82 (defvar image-type-auto-detectable
  83   '((pbm . t)
  84     (xbm . nil)
  85     (bmp . maybe)
  86     (gif . maybe)
  87     (png . maybe)
  88     (xpm . nil)
  89     (jpeg . maybe)
  90     (tiff . maybe)
  91     (svg . maybe)
  92     (postscript . nil))
  93   "Alist of (IMAGE-TYPE . AUTODETECT) pairs used to auto-detect image files.
  94 \(See `image-type-auto-detected-p').
  95
  96 AUTODETECT can be
  97  - t      always auto-detect.
  98  - nil    never auto-detect.
  99  - maybe  auto-detect only if the image type is available
 100             (see `image-type-available-p').")
 101
 102 (defcustom image-load-path
 103   (list (file-name-as-directory (expand-file-name "images" data-directory))
 104         'data-directory 'load-path)
 105   "List of locations in which to search for image files.
 106 If an element is a string, it defines a directory to search.
 107 If an element is a variable symbol whose value is a string, that
 108 value defines a directory to search.
 109 If an element is a variable symbol whose value is a list, the
 110 value is used as a list of directories to search."
 111   :type '(repeat (choice directory variable))
 112   :initialize 'custom-initialize-delay)
 113
 114
 115 (defun image-load-path-for-library (library image &optional path no-error)
 116   "Return a suitable search path for images used by LIBRARY.
 117
 118 It searches for IMAGE in `image-load-path' (excluding
 119 \"`data-directory'/images\") and `load-path', followed by a path
 120 suitable for LIBRARY, which includes \"../../etc/images\" and
 121 \"../etc/images\" relative to the library file itself, and then
 122 in \"`data-directory'/images\".
 123
 124 Then this function returns a list of directories which contains
 125 first the directory in which IMAGE was found, followed by the
 126 value of `load-path'.  If PATH is given, it is used instead of
 127 `load-path'.
 128
 129 If NO-ERROR is non-nil and a suitable path can't be found, don't
 130 signal an error.  Instead, return a list of directories as before,
 131 except that nil appears in place of the image directory.
 132
 133 Here is an example that uses a common idiom to provide
 134 compatibility with versions of Emacs that lack the variable
 135 `image-load-path':
 136
 137     ;; Shush compiler.
 138     (defvar image-load-path)
 139
 140     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 141            (image-load-path (cons (car load-path)
 142                                   (when (boundp 'image-load-path)
 143                                     image-load-path))))
 144       (mh-tool-bar-folder-buttons-init))"
 145   (unless library (error "No library specified"))
 146   (unless image   (error "No image specified"))
 147   (let (image-directory image-directory-load-path)
 148     ;; Check for images in image-load-path or load-path.
 149     (let ((img image)
 150           (dir (or
 151                 ;; Images in image-load-path.
 152                 (image-search-load-path image)
 153                 ;; Images in load-path.
 154                 (locate-library image)))
 155           parent)
 156       ;; Since the image might be in a nested directory (for
 157       ;; example, mail/attach.pbm), adjust `image-directory'
 158       ;; accordingly.
 159       (when dir
 160         (setq dir (file-name-directory dir))
 161         (while (setq parent (file-name-directory img))
 162           (setq img (directory-file-name parent)
 163                 dir (expand-file-name "../" dir))))
 164       (setq image-directory-load-path dir))
 165
 166     ;; If `image-directory-load-path' isn't Emacs's image directory,
 167     ;; it's probably a user preference, so use it. Then use a
 168     ;; relative setting if possible; otherwise, use
 169     ;; `image-directory-load-path'.
 170     (cond
 171      ;; User-modified image-load-path?
 172      ((and image-directory-load-path
 173            (not (equal image-directory-load-path
 174                        (file-name-as-directory
 175                         (expand-file-name "images" data-directory)))))
 176       (setq image-directory image-directory-load-path))
 177      ;; Try relative setting.
 178      ((let (library-name d1ei d2ei)
 179         ;; First, find library in the load-path.
 180         (setq library-name (locate-library library))
 181         (if (not library-name)
 182             (error "Cannot find library %s in load-path" library))
 183         ;; And then set image-directory relative to that.
 184         (setq
 185          ;; Go down 2 levels.
 186          d2ei (file-name-as-directory
 187                (expand-file-name
 188                 (concat (file-name-directory library-name) "../../etc/images")))
 189          ;; Go down 1 level.
 190          d1ei (file-name-as-directory
 191                (expand-file-name
 192                 (concat (file-name-directory library-name) "../etc/images"))))
 193         (setq image-directory
 194               ;; Set it to nil if image is not found.
 195               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 196                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 197      ;; Use Emacs's image directory.
 198      (image-directory-load-path
 199       (setq image-directory image-directory-load-path))
 200      (no-error
 201       (message "Could not find image %s for library %s" image library))
 202      (t
 203       (error "Could not find image %s for library %s" image library)))
 204
 205     ;; Return an augmented `path' or `load-path'.
 206     (nconc (list image-directory)
 207            (delete image-directory (copy-sequence (or path load-path))))))
 208
 209
 210 ;; Used to be in image-type-header-regexps, but now not used anywhere
 211 ;; (since 2009-08-28).
 212 (defun image-jpeg-p (data)
 213   "Value is non-nil if DATA, a string, consists of JFIF image data.
 214 We accept the tag Exif because that is the same format."
 215   (setq data (ignore-errors (string-to-unibyte data)))
 216   (when (and data (string-match-p "\\`\xff\xd8" data))
 217     (catch 'jfif
 218       (let ((len (length data)) (i 2))
 219         (while (< i len)
 220           (when (/= (aref data i) #xff)
 221             (throw 'jfif nil))
 222           (setq i (1+ i))
 223           (when (>= (+ i 2) len)
 224             (throw 'jfif nil))
 225           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 226                            (aref data (+ i 2))))
 227                 (code (aref data i)))
 228             (when (and (>= code #xe0) (<= code #xef))
 229               ;; APP0 LEN1 LEN2 "JFIF\0"
 230               (throw 'jfif
 231                      (string-match-p "JFIF\\|Exif"
 232                                      (substring data i (min (+ i nbytes) len)))))
 233             (setq i (+ i 1 nbytes))))))))
 234
 235
 236 ;;;###autoload
 237 (defun image-type-from-data (data)
 238   "Determine the image type from image data DATA.
 239 Value is a symbol specifying the image type or nil if type cannot
 240 be determined."
 241   (let ((types image-type-header-regexps)
 242         type)
 243     (while types
 244       (let ((regexp (car (car types)))
 245             (image-type (cdr (car types))))
 246         (if (or (and (symbolp image-type)
 247                      (string-match-p regexp data))
 248                 (and (consp image-type)
 249                      (funcall (car image-type) data)
 250                      (setq image-type (cdr image-type))))
 251             (setq type image-type
 252                   types nil)
 253           (setq types (cdr types)))))
 254     type))
 255
 256
 257 ;;;###autoload
 258 (defun image-type-from-buffer ()
 259   "Determine the image type from data in the current buffer.
 260 Value is a symbol specifying the image type or nil if type cannot
 261 be determined."
 262   (let ((types image-type-header-regexps)
 263         type
 264         (opoint (point)))
 265     (goto-char (point-min))
 266     (while types
 267       (let ((regexp (car (car types)))
 268             (image-type (cdr (car types)))
 269             data)
 270         (if (or (and (symbolp image-type)
 271                      (looking-at-p regexp))
 272                 (and (consp image-type)
 273                      (funcall (car image-type)
 274                               (or data
 275                                   (setq data
 276                                         (buffer-substring
 277                                          (point-min)
 278                                          (min (point-max)
 279                                               (+ (point-min) 256))))))
 280                      (setq image-type (cdr image-type))))
 281             (setq type image-type
 282                   types nil)
 283           (setq types (cdr types)))))
 284     (goto-char opoint)
 285     (and type
 286          (memq type image-types)
 287          type)))
 288
 289
 290 ;;;###autoload
 291 (defun image-type-from-file-header (file)
 292   "Determine the type of image file FILE from its first few bytes.
 293 Value is a symbol specifying the image type, or nil if type cannot
 294 be determined."
 295   (unless (or (file-readable-p file)
 296               (file-name-absolute-p file))
 297     (setq file (image-search-load-path file)))
 298   (and file
 299        (file-readable-p file)
 300        (with-temp-buffer
 301          (set-buffer-multibyte nil)
 302          (insert-file-contents-literally file nil 0 256)
 303          (image-type-from-buffer))))
 304
 305
 306 ;;;###autoload
 307 (defun image-type-from-file-name (file)
 308   "Determine the type of image file FILE from its name.
 309 Value is a symbol specifying the image type, or nil if type cannot
 310 be determined."
 311   (assoc-default file image-type-file-name-regexps 'string-match-p))
 312
 313
 314 ;;;###autoload
 315 (defun image-type (source &optional type data-p)
 316   "Determine and return image type.
 317 SOURCE is an image file name or image data.
 318 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 319 or nil, try to determine the image type from its first few bytes
 320 of image data.  If that doesn't work, and SOURCE is a file name,
 321 use its file extension as image type.
 322 Optional DATA-P non-nil means SOURCE is a string containing image data."
 323   (when (and (not data-p) (not (stringp source)))
 324     (error "Invalid image file name `%s'" source))
 325   (unless type
 326     (setq type (if data-p
 327                    (image-type-from-data source)
 328                  (or (image-type-from-file-header source)
 329                      (image-type-from-file-name source))))
 330     (or type (error "Cannot determine image type")))
 331   (or (memq type (and (boundp 'image-types) image-types))
 332       (error "Invalid image type `%s'" type))
 333   type)
 334
 335
 336 (if (fboundp 'image-metadata)           ; eg not --without-x
 337     (define-obsolete-function-alias 'image-extension-data
 338       'image-metadata' "24.1"))
 339
 340 (define-obsolete-variable-alias
 341     'image-library-alist
 342     'dynamic-library-alist "24.1")
 343
 344 ;;;###autoload
 345 (defun image-type-available-p (type)
 346   "Return non-nil if image type TYPE is available.
 347 Image types are symbols like `xbm' or `jpeg'."
 348   (and (fboundp 'init-image-library)
 349        (init-image-library type dynamic-library-alist)))
 350
 351
 352 ;;;###autoload
 353 (defun image-type-auto-detected-p ()
 354   "Return t if the current buffer contains an auto-detectable image.
 355 This function is intended to be used from `magic-fallback-mode-alist'.
 356
 357 The buffer is considered to contain an auto-detectable image if
 358 its beginning matches an image type in `image-type-header-regexps',
 359 and that image type is present in `image-type-auto-detectable' with a
 360 non-nil value.  If that value is non-nil, but not t, then the image type
 361 must be available."
 362   (let* ((type (image-type-from-buffer))
 363          (auto (and type (cdr (assq type image-type-auto-detectable)))))
 364     (and auto
 365          (or (eq auto t) (image-type-available-p type)))))
 366
 367
 368 ;;;###autoload
 369 (defun create-image (file-or-data &optional type data-p &rest props)
 370   "Create an image.
 371 FILE-OR-DATA is an image file name or image data.
 372 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 373 or nil, try to determine the image type from its first few bytes
 374 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 375 use its file extension as image type.
 376 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 377 Optional PROPS are additional image attributes to assign to the image,
 378 like, e.g. `:mask MASK'.
 379 Value is the image created, or nil if images of type TYPE are not supported.
 380
 381 Images should not be larger than specified by `max-image-size'.
 382
 383 Image file names that are not absolute are searched for in the
 384 \"images\" sub-directory of `data-directory' and
 385 `x-bitmap-file-path' (in that order)."
 386   ;; It is x_find_image_file in image.c that sets the search path.
 387   (setq type (image-type file-or-data type data-p))
 388   (when (image-type-available-p type)
 389     (append (list 'image :type type (if data-p :data :file) file-or-data)
 390             props)))
 391
 392
 393 ;;;###autoload
 394 (defun put-image (image pos &optional string area)
 395   "Put image IMAGE in front of POS in the current buffer.
 396 IMAGE must be an image created with `create-image' or `defimage'.
 397 IMAGE is displayed by putting an overlay into the current buffer with a
 398 `before-string' STRING that has a `display' property whose value is the
 399 image.  STRING is defaulted if you omit it.
 400 The overlay created will have the `put-image' property set to t.
 401 POS may be an integer or marker.
 402 AREA is where to display the image.  AREA nil or omitted means
 403 display it in the text area, a value of `left-margin' means
 404 display it in the left marginal area, a value of `right-margin'
 405 means display it in the right marginal area."
 406   (unless string (setq string "x"))
 407   (let ((buffer (current-buffer)))
 408     (unless (eq (car-safe image) 'image)
 409       (error "Not an image: %s" image))
 410     (unless (or (null area) (memq area '(left-margin right-margin)))
 411       (error "Invalid area %s" area))
 412     (setq string (copy-sequence string))
 413     (let ((overlay (make-overlay pos pos buffer))
 414           (prop (if (null area) image (list (list 'margin area) image))))
 415       (put-text-property 0 (length string) 'display prop string)
 416       (overlay-put overlay 'put-image t)
 417       (overlay-put overlay 'before-string string)
 418       overlay)))
 419
 420
 421 ;;;###autoload
 422 (defun insert-image (image &optional string area slice)
 423   "Insert IMAGE into current buffer at point.
 424 IMAGE is displayed by inserting STRING into the current buffer
 425 with a `display' property whose value is the image.  STRING
 426 defaults to the empty string if you omit it.
 427 AREA is where to display the image.  AREA nil or omitted means
 428 display it in the text area, a value of `left-margin' means
 429 display it in the left marginal area, a value of `right-margin'
 430 means display it in the right marginal area.
 431 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 432 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 433 specifying the X and Y positions and WIDTH and HEIGHT of image area
 434 to insert.  A float value 0.0 - 1.0 means relative to the width or
 435 height of the image; integer values are taken as pixel values."
 436   ;; Use a space as least likely to cause trouble when it's a hidden
 437   ;; character in the buffer.
 438   (unless string (setq string " "))
 439   (unless (eq (car-safe image) 'image)
 440     (error "Not an image: %s" image))
 441   (unless (or (null area) (memq area '(left-margin right-margin)))
 442     (error "Invalid area %s" area))
 443   (if area
 444       (setq image (list (list 'margin area) image))
 445     ;; Cons up a new spec equal but not eq to `image' so that
 446     ;; inserting it twice in a row (adjacently) displays two copies of
 447     ;; the image.  Don't try to avoid this by looking at the display
 448     ;; properties on either side so that we DTRT more often with
 449     ;; cut-and-paste.  (Yanking killed image text next to another copy
 450     ;; of it loses anyway.)
 451     (setq image (cons 'image (cdr image))))
 452   (let ((start (point)))
 453     (insert string)
 454     (add-text-properties start (point)
 455                          `(display ,(if slice
 456                                         (list (cons 'slice slice) image)
 457                                       image) rear-nonsticky (display)))))
 458
 459
 460 ;;;###autoload
 461 (defun insert-sliced-image (image &optional string area rows cols)
 462   "Insert IMAGE into current buffer at point.
 463 IMAGE is displayed by inserting STRING into the current buffer
 464 with a `display' property whose value is the image.  STRING is
 465 defaulted if you omit it.
 466 AREA is where to display the image.  AREA nil or omitted means
 467 display it in the text area, a value of `left-margin' means
 468 display it in the left marginal area, a value of `right-margin'
 469 means display it in the right marginal area.
 470 The image is automatically split into ROWS x COLS slices."
 471   (unless string (setq string " "))
 472   (unless (eq (car-safe image) 'image)
 473     (error "Not an image: %s" image))
 474   (unless (or (null area) (memq area '(left-margin right-margin)))
 475     (error "Invalid area %s" area))
 476   (if area
 477       (setq image (list (list 'margin area) image))
 478     ;; Cons up a new spec equal but not eq to `image' so that
 479     ;; inserting it twice in a row (adjacently) displays two copies of
 480     ;; the image.  Don't try to avoid this by looking at the display
 481     ;; properties on either side so that we DTRT more often with
 482     ;; cut-and-paste.  (Yanking killed image text next to another copy
 483     ;; of it loses anyway.)
 484     (setq image (cons 'image (cdr image))))
 485   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 486          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 487     (while (< y 1.0)
 488       (while (< x 1.0)
 489         (let ((start (point)))
 490           (insert string)
 491           (add-text-properties start (point)
 492                                `(display ,(list (list 'slice x y dx dy) image)
 493                                          rear-nonsticky (display)))
 494           (setq x (+ x dx))))
 495       (setq x 0.0
 496             y (+ y dy))
 497       (insert (propertize "\n" 'line-height t)))))
 498
 499
 500
 501 ;;;###autoload
 502 (defun remove-images (start end &optional buffer)
 503   "Remove images between START and END in BUFFER.
 504 Remove only images that were put in BUFFER with calls to `put-image'.
 505 BUFFER nil or omitted means use the current buffer."
 506   (unless buffer
 507     (setq buffer (current-buffer)))
 508   (let ((overlays (overlays-in start end)))
 509     (while overlays
 510       (let ((overlay (car overlays)))
 511         (when (overlay-get overlay 'put-image)
 512           (delete-overlay overlay)))
 513       (setq overlays (cdr overlays)))))
 514
 515 (defun image-search-load-path (file &optional path)
 516   (unless path
 517     (setq path image-load-path))
 518   (let (element found filename)
 519     (while (and (not found) (consp path))
 520       (setq element (car path))
 521       (cond
 522        ((stringp element)
 523         (setq found
 524               (file-readable-p
 525                (setq filename (expand-file-name file element)))))
 526        ((and (symbolp element) (boundp element))
 527         (setq element (symbol-value element))
 528         (cond
 529          ((stringp element)
 530           (setq found
 531                 (file-readable-p
 532                  (setq filename (expand-file-name file element)))))
 533          ((consp element)
 534           (if (setq filename (image-search-load-path file element))
 535               (setq found t))))))
 536       (setq path (cdr path)))
 537     (if found filename)))
 538
 539 ;;;###autoload
 540 (defun find-image (specs)
 541   "Find an image, choosing one of a list of image specifications.
 542
 543 SPECS is a list of image specifications.
 544
 545 Each image specification in SPECS is a property list.  The contents of
 546 a specification are image type dependent.  All specifications must at
 547 least contain the properties `:type TYPE' and either `:file FILE' or
 548 `:data DATA', where TYPE is a symbol specifying the image type,
 549 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 550 string containing the actual image data.  The specification whose TYPE
 551 is supported, and FILE exists, is used to construct the image
 552 specification to be returned.  Return nil if no specification is
 553 satisfied.
 554
 555 The image is looked for in `image-load-path'.
 556
 557 Image files should not be larger than specified by `max-image-size'."
 558   (let (image)
 559     (while (and specs (null image))
 560       (let* ((spec (car specs))
 561              (type (plist-get spec :type))
 562              (data (plist-get spec :data))
 563              (file (plist-get spec :file))
 564              found)
 565         (when (image-type-available-p type)
 566           (cond ((stringp file)
 567                  (if (setq found (image-search-load-path file))
 568                      (setq image
 569                            (cons 'image (plist-put (copy-sequence spec)
 570                                                    :file found)))))
 571                 ((not (null data))
 572                  (setq image (cons 'image spec)))))
 573         (setq specs (cdr specs))))
 574     image))
 575
 576
 577 ;;;###autoload
 578 (defmacro defimage (symbol specs &optional doc)
 579   "Define SYMBOL as an image.
 580
 581 SPECS is a list of image specifications.  DOC is an optional
 582 documentation string.
 583
 584 Each image specification in SPECS is a property list.  The contents of
 585 a specification are image type dependent.  All specifications must at
 586 least contain the properties `:type TYPE' and either `:file FILE' or
 587 `:data DATA', where TYPE is a symbol specifying the image type,
 588 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 589 string containing the actual image data.  The first image
 590 specification whose TYPE is supported, and FILE exists, is used to
 591 define SYMBOL.
 592
 593 Example:
 594
 595    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 596                          (:type xbm :file \"~/test1.xbm\")))"
 597   (declare (doc-string 3))
 598   `(defvar ,symbol (find-image ',specs) ,doc))
 599
 600 \f
 601 ;;; Animated image API
 602
 603 (defconst image-animated-types '(gif)
 604   "List of supported animated image types.")
 605
 606 (defun image-animated-p (image)
 607   "Return non-nil if IMAGE can be animated.
 608 To be capable of being animated, an image must be of a type
 609 listed in `image-animated-types', and contain more than one
 610 sub-image, with a specified animation delay.  The actual return
 611 value is a cons (NIMAGES . DELAY), where NIMAGES is the number
 612 of sub-images in the animated image and DELAY is the delay in
 613 seconds until the next sub-image should be displayed."
 614   (cond
 615    ((memq (plist-get (cdr image) :type) image-animated-types)
 616     (let* ((metadata (image-metadata image))
 617            (images (plist-get metadata 'count))
 618            (delay (plist-get metadata 'delay)))
 619       (when (and images (> images 1) (numberp delay))
 620         (if (< delay 0) (setq delay 0.1))
 621         (cons images delay))))))
 622
 623 ;; "Destructively"?
 624 (defun image-animate (image &optional index limit)
 625   "Start animating IMAGE.
 626 Animation occurs by destructively altering the IMAGE spec list.
 627
 628 With optional INDEX, begin animating from that animation frame.
 629 LIMIT specifies how long to animate the image.  If omitted or
 630 nil, play the animation until the end.  If t, loop forever.  If a
 631 number, play until that number of seconds has elapsed."
 632   (let ((animation (image-animated-p image))
 633         timer)
 634     (when animation
 635       (if (setq timer (image-animate-timer image))
 636           (cancel-timer timer))
 637       (run-with-timer 0.2 nil 'image-animate-timeout
 638                       image (or index 0) (car animation)
 639                       0 limit))))
 640
 641 (defun image-animate-timer (image)
 642   "Return the animation timer for image IMAGE."
 643   ;; See cancel-function-timers
 644   (let ((tail timer-list) timer)
 645     (while tail
 646       (setq timer (car tail)
 647             tail (cdr tail))
 648       (if (and (eq (aref timer 5) 'image-animate-timeout)
 649                (eq (car-safe (aref timer 6)) image))
 650           (setq tail nil)
 651         (setq timer nil)))
 652     timer))
 653
 654 ;; FIXME? The delay may not be the same for different sub-images,
 655 ;; hence we need to call image-animated-p to return it.
 656 ;; But it also returns count, so why do we bother passing that as an
 657 ;; argument?
 658 (defun image-animate-timeout (image n count time-elapsed limit)
 659   "Display animation frame N of IMAGE.
 660 N=0 refers to the initial animation frame.
 661 COUNT is the total number of frames in the animation.
 662 TIME-ELAPSED is the total time that has elapsed since
 663 `image-animate-start' was called.
 664 LIMIT determines when to stop.  If t, loop forever.  If nil, stop
 665  after displaying the last animation frame.  Otherwise, stop
 666  after LIMIT seconds have elapsed.
 667 The minimum delay between successive frames is 0.01s."
 668   (plist-put (cdr image) :index n)
 669   (force-window-update)
 670   (setq n (1+ n))
 671   (let* ((time (float-time))
 672          (animation (image-animated-p image))
 673          ;; Subtract off the time we took to load the image from the
 674          ;; stated delay time.
 675          (delay (max (+ (cdr animation) time (- (float-time)))
 676                      0.01))
 677          done)
 678     (if (>= n count)
 679         (if limit
 680             (setq n 0)
 681           (setq done t)))
 682     (setq time-elapsed (+ delay time-elapsed))
 683     (if (numberp limit)
 684         (setq done (>= time-elapsed limit)))
 685     (unless done
 686       (run-with-timer delay nil 'image-animate-timeout
 687                       image n count time-elapsed limit))))
 688
 689 \f
 690 (defvar imagemagick--file-regexp nil
 691   "File extension regexp for ImageMagick files, if any.
 692 This is the extension installed into `auto-mode-alist' and
 693 `image-type-file-name-regexps' by `imagemagick-register-types'.")
 694
 695 (defvar imagemagick-types-inhibit)
 696 (defvar imagemagick-types-enable)
 697
 698 ;;;###autoload
 699 (defun imagemagick-register-types ()
 700   "Register file types that can be handled by ImageMagick.
 701 This function is called at startup, after loading the init file.
 702 It registers the ImageMagick types returned by `imagemagick-types',
 703 including only those from `imagemagick-types-enable', and excluding
 704 those from `imagemagick-types-inhibit'.
 705
 706 Registered image types are added to `auto-mode-alist', so that
 707 Emacs visits them in Image mode.  They are also added to
 708 `image-type-file-name-regexps', so that the `image-type' function
 709 recognizes these files as having image type `imagemagick'.
 710
 711 If Emacs is compiled without ImageMagick support, this does nothing."
 712   (when (fboundp 'imagemagick-types)
 713     (let* ((include
 714             (cond ((null imagemagick-types-enable) nil)
 715                   ((eq imagemagick-types-inhibit t) nil)
 716                   ((eq imagemagick-types-enable t) (imagemagick-types))
 717                   (t
 718                    (delq nil
 719                          (mapcar
 720                           (lambda (type)
 721                             (catch 'found
 722                               (dolist (enable imagemagick-types-enable nil)
 723                                 (if (cond ((symbolp enable) (eq enable type))
 724                                           ((stringp enable)
 725                                            (string-match enable
 726                                                          (symbol-name type))))
 727                                     (throw 'found type)))))
 728                           (imagemagick-types))))))
 729            (re (let (types)
 730                  (dolist (type include)
 731                    (unless (memq type imagemagick-types-inhibit)
 732                      (push (downcase (symbol-name type)) types)))
 733                  (if types (concat "\\." (regexp-opt types) "\\'"))))
 734            (ama-elt (car (member (cons imagemagick--file-regexp 'image-mode)
 735                                  auto-mode-alist)))
 736            (itfnr-elt (car (member (cons imagemagick--file-regexp 'imagemagick)
 737                                    image-type-file-name-regexps))))
 738       (if (not re)
 739           (setq auto-mode-alist (delete ama-elt auto-mode-alist)
 740                 image-type-file-name-regexps
 741                 (delete itfnr-elt image-type-file-name-regexps))
 742         (if ama-elt
 743             (setcar ama-elt re)
 744           (push (cons re 'image-mode) auto-mode-alist))
 745         (if itfnr-elt
 746             (setcar itfnr-elt re)
 747           (push (cons re 'imagemagick) image-type-file-name-regexps)))
 748       (setq imagemagick--file-regexp re))))
 749
 750 (defcustom imagemagick-types-inhibit
 751   '(C HTML HTM TXT PDF)
 752   "List of ImageMagick types that should not be treated as images.
 753 This should be a list of symbols, each of which should be one of
 754 the ImageMagick types listed in `imagemagick-types'.  The listed
 755 image types are not registered by `imagemagick-register-types'.
 756
 757 If the value is t, inhibit the use of ImageMagick for images.
 758
 759 If you change this without using customize, you must call
 760 `imagemagick-register-types' afterwards.
 761
 762 If Emacs is compiled without ImageMagick support, this variable
 763 has no effect."
 764   :type '(choice (const :tag "Support all ImageMagick types" nil)
 765                  (const :tag "Disable all ImageMagick types" t)
 766                  (repeat symbol))
 767   :initialize 'custom-initialize-default
 768   :set (lambda (symbol value)
 769          (set-default symbol value)
 770          (imagemagick-register-types))
 771   :version "24.1"
 772   :group 'image)
 773
 774 (defcustom imagemagick-types-enable
 775   '("\\`BMP" DJVU "\\`GIF" "\\`ICO" "P?JPE?G" "P[BNP]M"
 776     "\\`[MP]NG" "\\`TIFF")
 777   "List of ImageMagick types to treat as images.
 778 The list elements are either strings or symbols, and represent
 779 types returned by `imagemagick-types'.  A string is a regexp that
 780 selects all types matching the regexp.
 781
 782 The value may also be t, meaning all the types that ImageMagick
 783 supports; or nil, meaning no types.
 784
 785 The variable `imagemagick-types-inhibit' overrides this variable.
 786
 787 If you change this without using customize, you must call
 788 `imagemagick-register-types' afterwards.
 789
 790 If Emacs is compiled without ImageMagick support, this variable
 791 has no effect."
 792   :type '(choice (const :tag "Support all ImageMagick types" t)
 793                  (const :tag "Disable all ImageMagick types" nil)
 794                  (repeat :tag "List of types"
 795                          (choice (symbol :tag "type")
 796                                  (regexp :tag "regexp"))))
 797   :initialize 'custom-initialize-default
 798   :set (lambda (symbol value)
 799          (set-default symbol value)
 800          (imagemagick-register-types))
 801   :version "24.2"
 802   :group 'image)
 803
 804 (imagemagick-register-types)
 805
 806 (provide 'image)
 807
 808 ;;; image.el ends here