lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (c) 1996, 1997, 1998, 1999, 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13 ;;
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 ;; (require 'url)
  29 (eval-when-compile (require 'url-parse))
  30 ;; (require 'url-util)
  31 (eval-when-compile (require 'mm-decode))
  32 ;; (require 'mailcap)
  33 ;; The following functions in the byte compiler's warnings are known not
  34 ;; to cause any real problem for the following reasons:
  35 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  36 ;;   after mm-dissect-buffer and defined in the same file.
  37 ;; The following are autoloaded instead of `require'd to avoid eagerly
  38 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  39 (autoload 'url-retrieve-synchronously "url" "Retrieve url synchronously.")
  40 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  41 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  42 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  43
  44 (eval-when-compile
  45   (require 'cl))
  46
  47 ;; Implementation status
  48 ;; ---------------------
  49 ;; Function                             Status
  50 ;; ------------------------------------------------------------
  51 ;; add-name-to-file                     Needs DAV Bindings
  52 ;; copy-file                            Broken (assumes 1st item is URL)
  53 ;; delete-directory                     Finished (DAV)
  54 ;; delete-file                          Finished (DAV)
  55 ;; diff-latest-backup-file
  56 ;; directory-file-name                  unnecessary (what about VMS)?
  57 ;; directory-files                      Finished (DAV)
  58 ;; dired-call-process
  59 ;; dired-compress-file
  60 ;; dired-uncache
  61 ;; expand-file-name                     Finished
  62 ;; file-accessible-directory-p
  63 ;; file-attributes                      Finished, better with DAV
  64 ;; file-directory-p                     Needs DAV, finished
  65 ;; file-executable-p                    Finished
  66 ;; file-exists-p                        Finished
  67 ;; file-local-copy
  68 ;; file-modes
  69 ;; file-name-all-completions            Finished (DAV)
  70 ;; file-name-as-directory
  71 ;; file-name-completion                 Finished (DAV)
  72 ;; file-name-directory
  73 ;; file-name-nondirectory
  74 ;; file-name-sans-versions              why?
  75 ;; file-newer-than-file-p
  76 ;; file-ownership-preserved-p           No way to know
  77 ;; file-readable-p                      Finished
  78 ;; file-regular-p                       !directory_p
  79 ;; file-symlink-p                       Needs DAV bindings
  80 ;; file-truename                        Needs DAV bindings
  81 ;; file-writable-p                      Check for LOCK?
  82 ;; find-backup-file-name                why?
  83 ;; get-file-buffer                      why?
  84 ;; insert-directory                     Use DAV
  85 ;; insert-file-contents                 Finished
  86 ;; load
  87 ;; make-directory                       Finished (DAV)
  88 ;; make-symbolic-link                   Needs DAV bindings
  89 ;; rename-file                          Finished (DAV)
  90 ;; set-file-modes                       Use mod_dav specific executable flag?
  91 ;; set-visited-file-modtime             Impossible?
  92 ;; shell-command                        Impossible?
  93 ;; unhandled-file-name-directory
  94 ;; vc-registered                        Finished (DAV)
  95 ;; verify-visited-file-modtime
  96 ;; write-region
  97
  98 (defvar url-handler-regexp
  99   "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
 100   "*A regular expression for matching  URLs handled by file-name-handler-alist.
 101 Some valid URL protocols just do not make sense to visit interactively
 102 \(about, data, info, irc, mailto, etc\).  This regular expression
 103 avoids conflicts with local files that look like URLs \(Gnus is
 104 particularly bad at this\).")
 105
 106 ;;;###autoload
 107 (define-minor-mode url-handler-mode
 108   "Use URL to handle URL-like file names."
 109   :global t :group 'url
 110   (if (not (boundp 'file-name-handler-alist))
 111       ;; Can't be turned ON anyway.
 112       (setq url-handler-mode nil)
 113     ;; Remove old entry, if any.
 114     (setq file-name-handler-alist
 115           (delq (rassq 'url-file-handler file-name-handler-alist)
 116                 file-name-handler-alist))
 117     (if url-handler-mode
 118         (push (cons url-handler-regexp 'url-file-handler)
 119               file-name-handler-alist))))
 120
 121 (defun url-run-real-handler (operation args)
 122   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 123                                           (if (eq operation inhibit-file-name-operation)
 124                                               inhibit-file-name-handlers)))
 125         (inhibit-file-name-operation operation))
 126     (apply operation args)))
 127
 128 (defun url-file-handler (operation &rest args)
 129   "Function called from the `file-name-handler-alist' routines.
 130 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 131 the arguments that would have been passed to OPERATION."
 132   (let ((fn (or (get operation 'url-file-handlers)
 133                 (intern-soft (format "url-%s" operation))))
 134         (val nil)
 135         (hooked nil))
 136     (if (and fn (fboundp fn))
 137         (setq hooked t
 138               val (apply fn args))
 139       (setq hooked nil
 140             val (url-run-real-handler operation args)))
 141     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 142                operation args val)
 143     val))
 144
 145 (defun url-file-handler-identity (&rest args)
 146   ;; Identity function
 147   (car args))
 148
 149 ;; These are operations that we can fully support
 150 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 151 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 152 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 153 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 154
 155 ;; These are operations that we do not support yet (DAV!!!)
 156 (put 'file-writable-p 'url-file-handlers 'ignore)
 157 (put 'file-symlink-p 'url-file-handlers 'ignore)
 158
 159 (defun url-handler-expand-file-name (file &optional base)
 160   (if (file-name-absolute-p file)
 161       (expand-file-name file "/")
 162     (url-expand-file-name file base)))
 163
 164 ;; The actual implementation
 165 ;;;###autoload
 166 (defun url-copy-file (url newname &optional ok-if-already-exists keep-time)
 167   "Copy URL to NEWNAME.  Both args must be strings.
 168 Signals a `file-already-exists' error if file NEWNAME already exists,
 169 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 170 A number as third arg means request confirmation if NEWNAME already exists.
 171 This is what happens in interactive use with M-x.
 172 Fourth arg KEEP-TIME non-nil means give the new file the same
 173 last-modified time as the old one.  (This works on only some systems.)
 174 A prefix arg makes KEEP-TIME non-nil."
 175   (if (and (file-exists-p newname)
 176            (not ok-if-already-exists))
 177       (error "Opening output file: File already exists, %s" newname))
 178   (let ((buffer (url-retrieve-synchronously url))
 179         (handle nil))
 180     (if (not buffer)
 181         (error "Opening input file: No such file or directory, %s" url))
 182     (with-current-buffer buffer
 183       (setq handle (mm-dissect-buffer t)))
 184     (mm-save-part-to-file handle newname)
 185     (kill-buffer buffer)
 186     (mm-destroy-parts handle)))
 187
 188 ;;;###autoload
 189 (defun url-file-local-copy (url &rest ignored)
 190   "Copy URL into a temporary file on this machine.
 191 Returns the name of the local copy, or nil, if FILE is directly
 192 accessible."
 193   (let ((filename (make-temp-name "url")))
 194     (url-copy-file url filename)
 195     filename))
 196
 197 ;;;###autoload
 198 (defun url-insert-file-contents (url &optional visit beg end replace)
 199   (let ((buffer (url-retrieve-synchronously url))
 200         (handle nil)
 201         (data nil))
 202     (if (not buffer)
 203         (error "Opening input file: No such file or directory, %s" url))
 204     (if visit (setq buffer-file-name url))
 205     (with-current-buffer buffer
 206       (setq handle (mm-dissect-buffer t))
 207       (set-buffer (mm-handle-buffer handle))
 208       (setq data (if beg (buffer-substring beg end)
 209                    (buffer-string))))
 210     (kill-buffer buffer)
 211     (mm-destroy-parts handle)
 212     (if replace (delete-region (point-min) (point-max)))
 213     (save-excursion
 214       (let ((start (point)))
 215         (insert data)
 216         ;; FIXME: for text/plain data, we sometimes receive a `charset'
 217         ;; annotation which we could use as a hint of the locale in use
 218         ;; at the remote site.  Not sure how/if that should be done.  --Stef
 219         (decode-coding-inserted-region
 220          start (point) url visit beg end replace)))
 221     (list url (length data))))
 222
 223 (defun url-file-name-completion (url directory)
 224   (error "Unimplemented"))
 225
 226 (defun url-file-name-all-completions (file directory)
 227   (error "Unimplemented"))
 228
 229 ;; All other handlers map onto their respective backends.
 230 (defmacro url-handlers-create-wrapper (method args)
 231   `(defun ,(intern (format "url-%s" method)) ,args
 232      ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 233               (or (documentation method t) "No original documentation."))
 234      (setq url (url-generic-parse-url url))
 235      (when (url-type url)
 236        (funcall (url-scheme-get-property (url-type url) (quote ,method))
 237                 ,@(remove '&rest (remove '&optional args))))))
 238
 239 (url-handlers-create-wrapper file-exists-p (url))
 240 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 241 (url-handlers-create-wrapper file-symlink-p (url))
 242 (url-handlers-create-wrapper file-writable-p (url))
 243 (url-handlers-create-wrapper file-directory-p (url))
 244 (url-handlers-create-wrapper file-executable-p (url))
 245
 246 (if (featurep 'xemacs)
 247     (progn
 248       ;; XEmacs specific prototypes
 249       (url-handlers-create-wrapper
 250        directory-files (url &optional full match nosort files-only))
 251       (url-handlers-create-wrapper
 252        file-truename (url &optional default)))
 253   ;; Emacs specific prototypes
 254   (url-handlers-create-wrapper
 255    directory-files (url &optional full match nosort))
 256   (url-handlers-create-wrapper
 257    file-truename (url &optional counter prev-dirs)))
 258
 259 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 260
 261 (defun url-handlers-set-buffer-mode ()
 262   "Set correct modes for the current buffer if visiting a remote file."
 263   (and (stringp buffer-file-name)
 264        (string-match url-handler-regexp buffer-file-name)
 265        (auto-save-mode 0)))
 266
 267 (provide 'url-handlers)
 268
 269 ;; arch-tag: 7300b99c-cc83-42ff-9147-79b2723c62ac
 270 ;;; url-handlers.el ends here