lisp/wdired.el

   1 ;;; wdired.el --- Rename files editing their names in dired buffers
   2
   3 ;; Copyright (C) 2004-2011  Free Software Foundation, Inc.
   4
   5 ;; Filename: wdired.el
   6 ;; Author: Juan León Lahoz García <juanleon1@gmail.com>
   7 ;; Version: 2.0
   8 ;; Keywords: dired, environment, files, renaming
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; wdired.el (the "w" is for writable) provides an alternative way of
  28 ;; renaming files.
  29 ;;
  30 ;; Have you ever wished to use C-x r t (string-rectangle), M-%
  31 ;; (query-replace), M-c (capitalize-word), etc... to change the name of
  32 ;; the files in a "dired" buffer? Now you can do this.  All the power
  33 ;; of Emacs commands are available to renaming files!
  34 ;;
  35 ;; This package provides a function that makes the filenames of a a
  36 ;; dired buffer editable, by changing the buffer mode (which inhibits
  37 ;; all of the commands of dired mode). Here you can edit the names of
  38 ;; one or more files and directories, and when you press C-c C-c, the
  39 ;; renaming takes effect and you are back to dired mode.
  40 ;;
  41 ;; Another things you can do with WDired:
  42 ;;
  43 ;; - To move files to another directory (by typing their path,
  44 ;;   absolute or relative, as a part of the new filename).
  45 ;;
  46 ;; - To change the target of symbolic links.
  47 ;;
  48 ;; - To change the permission bits of the filenames (in systems with a
  49 ;;   working unix-alike `dired-chmod-program'). See and customize the
  50 ;;   variable `wdired-allow-to-change-permissions'.  To change a single
  51 ;;   char (toggling between its two more usual values) you can press
  52 ;;   the space bar over it or left-click the mouse.  To set any char to
  53 ;;   an specific value (this includes the SUID, SGID and STI bits) you
  54 ;;   can use the key labeled as the letter you want.  Please note that
  55 ;;   permissions of the links cannot be changed in that way, because
  56 ;;   the change would affect to their targets, and this would not be
  57 ;;   WYSIWYG :-).
  58 ;;
  59 ;; - To mark files for deletion, by deleting their whole filename.
  60
  61 ;;; Usage:
  62
  63 ;; You can edit the names of the files by typing C-x C-q or by
  64 ;; executing M-x wdired-change-to-wdired-mode.  Use C-c C-c when
  65 ;; finished or C-c C-k to abort.  While editing filenames, a new
  66 ;; submenu "WDired" is available at top level.  You can customize the
  67 ;; behavior of this package from this menu.
  68
  69 ;;; Change Log:
  70
  71 ;; Google is your friend (previous versions with complete changelogs
  72 ;; were posted to gnu.emacs.sources)
  73
  74 ;;; Code:
  75
  76 (defvar dired-backup-overwrite) ; Only in Emacs 20.x this is a custom var
  77
  78 (eval-when-compile (require 'cl))
  79 (require 'dired)
  80 (autoload 'dired-do-create-files-regexp "dired-aux")
  81
  82 (defgroup wdired nil
  83   "Mode to rename files by editing their names in dired buffers."
  84   :group 'dired)
  85
  86 (defcustom wdired-use-interactive-rename nil
  87   "If non-nil, WDired requires confirmation before actually renaming files.
  88 If nil, WDired doesn't require confirmation to change the file names,
  89 and the variable `wdired-confirm-overwrite' controls whether it is ok
  90 to overwrite files without asking."
  91   :type 'boolean
  92   :group 'wdired)
  93
  94 (defcustom wdired-confirm-overwrite t
  95   "If nil the renames can overwrite files without asking.
  96 This variable has no effect at all if `wdired-use-interactive-rename'
  97 is not nil."
  98   :type 'boolean
  99   :group 'wdired)
 100
 101 (defcustom wdired-use-dired-vertical-movement nil
 102   "If t, the \"up\" and \"down\" movement works as in Dired mode.
 103 That is, always move the point to the beginning of the filename at line.
 104
 105 If `sometimes', only move to the beginning of filename if the point is
 106 before it, and `track-eol' is non-nil.  This behavior is very handy
 107 when editing several filenames.
 108
 109 If nil, \"up\" and \"down\" movement is done as in any other buffer."
 110   :type '(choice (const :tag "As in any other mode" nil)
 111                  (const :tag "Smart cursor placement" sometimes)
 112                  (other :tag "As in dired mode" t))
 113   :group 'wdired)
 114
 115 (defcustom wdired-allow-to-redirect-links t
 116   "If non-nil, the target of the symbolic links are editable.
 117 In systems without symbolic links support, this variable has no effect
 118 at all."
 119   :type 'boolean
 120   :group 'wdired)
 121
 122 (defcustom wdired-allow-to-change-permissions nil
 123   "If non-nil, the permissions bits of the files are editable.
 124
 125 If t, to change a single bit, put the cursor over it and press the
 126 space bar, or left click over it.  You can also hit the letter you want
 127 to set: if this value is allowed, the character in the buffer will be
 128 changed.  Anyway, the point is advanced one position, so, for example,
 129 you can keep the <x> key pressed to give execution permissions to
 130 everybody to that file.
 131
 132 If `advanced', the bits are freely editable.  You can use
 133 `string-rectangle', `query-replace', etc.  You can put any value (even
 134 newlines), but if you want your changes to be useful, you better put a
 135 intelligible value.
 136
 137 Anyway, the real change of the permissions is done by the external
 138 program `dired-chmod-program', which must exist."
 139   :type '(choice (const :tag "Not allowed" nil)
 140                  (const :tag "Toggle/set bits" t)
 141                  (other :tag "Bits freely editable" advanced))
 142   :group 'wdired)
 143
 144 (defvar wdired-mode-map
 145   (let ((map (make-sparse-keymap)))
 146     (define-key map "\C-x\C-s" 'wdired-finish-edit)
 147     (define-key map "\C-c\C-c" 'wdired-finish-edit)
 148     (define-key map "\C-c\C-k" 'wdired-abort-changes)
 149     (define-key map "\C-c\C-[" 'wdired-abort-changes)
 150     (define-key map "\C-x\C-q" 'wdired-exit)
 151     (define-key map "\C-m"     'ignore)
 152     (define-key map "\C-j"     'ignore)
 153     (define-key map "\C-o"     'ignore)
 154     (define-key map [up]       'wdired-previous-line)
 155     (define-key map "\C-p"     'wdired-previous-line)
 156     (define-key map [down]     'wdired-next-line)
 157     (define-key map "\C-n"     'wdired-next-line)
 158
 159     (define-key map [menu-bar wdired]
 160       (cons "WDired" (make-sparse-keymap "WDired")))
 161     (define-key map [menu-bar wdired wdired-customize]
 162       '("Options" . wdired-customize))
 163     (define-key map [menu-bar wdired dashes]
 164       '("--"))
 165     (define-key map [menu-bar wdired wdired-abort-changes]
 166       '(menu-item "Abort Changes" wdired-abort-changes
 167                   :help "Abort changes and return to dired mode"))
 168     (define-key map [menu-bar wdired wdired-finish-edit]
 169       '("Commit Changes" . wdired-finish-edit))
 170
 171     (define-key map [remap upcase-word] 'wdired-upcase-word)
 172     (define-key map [remap capitalize-word] 'wdired-capitalize-word)
 173     (define-key map [remap downcase-word] 'wdired-downcase-word)
 174
 175     map))
 176
 177 (defvar wdired-mode-hook nil
 178   "Hooks run when changing to WDired mode.")
 179
 180 ;; Local variables (put here to avoid compilation gripes)
 181 (defvar wdired-col-perm) ;; Column where the permission bits start
 182 (defvar wdired-old-content)
 183 (defvar wdired-old-point)
 184
 185
 186 (defun wdired-mode ()
 187   "\\<wdired-mode-map>File Names Editing mode.
 188
 189 Press \\[wdired-finish-edit] to make the changes to take effect
 190 and exit.  To abort the edit, use \\[wdired-abort-changes].
 191
 192 In this mode you can edit the names of the files, the target of
 193 the links and the permission bits of the files.  You can use
 194 \\[customize-group] RET wdired to customize WDired behavior.
 195
 196 The only editable texts in a WDired buffer are filenames,
 197 symbolic link targets, and filenames permission."
 198   (interactive)
 199   (error "This mode can be enabled only by `wdired-change-to-wdired-mode'"))
 200 (put 'wdired-mode 'mode-class 'special)
 201
 202
 203 ;;;###autoload
 204 (defun wdired-change-to-wdired-mode ()
 205   "Put a dired buffer in a mode in which filenames are editable.
 206 \\<wdired-mode-map>
 207 This mode allows the user to change the names of the files, and after
 208 typing \\[wdired-finish-edit] Emacs renames the files and directories
 209 in disk.
 210
 211 See `wdired-mode'."
 212   (interactive)
 213   (or (eq major-mode 'dired-mode)
 214       (error "Not a Dired buffer"))
 215   (set (make-local-variable 'wdired-old-content)
 216        (buffer-substring (point-min) (point-max)))
 217   (set (make-local-variable 'wdired-old-point) (point))
 218   (set (make-local-variable 'query-replace-skip-read-only) t)
 219   (use-local-map wdired-mode-map)
 220   (force-mode-line-update)
 221   (setq buffer-read-only nil)
 222   (dired-unadvertise default-directory)
 223   (add-hook 'kill-buffer-hook 'wdired-check-kill-buffer nil t)
 224   (setq major-mode 'wdired-mode)
 225   (setq mode-name "Editable Dired")
 226   (setq revert-buffer-function 'wdired-revert)
 227   ;; I temp disable undo for performance: since I'm going to clear the
 228   ;; undo list, it can save more than a 9% of time with big
 229   ;; directories because setting properties modify the undo-list.
 230   (buffer-disable-undo)
 231   (wdired-preprocess-files)
 232   (if wdired-allow-to-change-permissions
 233       (wdired-preprocess-perms))
 234   (if (and wdired-allow-to-redirect-links (fboundp 'make-symbolic-link))
 235       (wdired-preprocess-symlinks))
 236   (buffer-enable-undo) ; Performance hack. See above.
 237   (set-buffer-modified-p nil)
 238   (setq buffer-undo-list nil)
 239   (run-mode-hooks 'wdired-mode-hook)
 240   (message "%s" (substitute-command-keys
 241                  "Press \\[wdired-finish-edit] when finished \
 242 or \\[wdired-abort-changes] to abort changes")))
 243
 244
 245 ;; Protect the buffer so only the filenames can be changed, and put
 246 ;; properties so filenames (old and new) can be easily found.
 247 (defun wdired-preprocess-files ()
 248   (put-text-property (point-min) (1+ (point-min))'front-sticky t)
 249   (save-excursion
 250     (goto-char (point-min))
 251     (let ((b-protection (point))
 252           filename)
 253       (while (not (eobp))
 254         (setq filename (dired-get-filename nil t))
 255         (when (and filename
 256                    (not (member (file-name-nondirectory filename) '("." ".."))))
 257           (dired-move-to-filename)
 258           ;; The rear-nonsticky property below shall ensure that text preceding
 259           ;; the filename can't be modified.
 260           (add-text-properties
 261            (1- (point)) (point) `(old-name ,filename rear-nonsticky (read-only)))
 262           (put-text-property b-protection (point) 'read-only t)
 263           (setq b-protection (dired-move-to-end-of-filename t))
 264           (put-text-property (point) (1+ (point)) 'end-name t))
 265         (forward-line))
 266       (put-text-property b-protection (point-max) 'read-only t))))
 267
 268 ;; This code is a copy of some dired-get-filename lines.
 269 (defsubst wdired-normalize-filename (file)
 270   (setq file
 271         ;; FIXME: shouldn't we check for a `b' argument or somesuch before
 272         ;; doing such unquoting?  --Stef
 273         (read (concat
 274                "\"" (replace-regexp-in-string
 275                      "\\([^\\]\\|\\`\\)\"" "\\1\\\\\"" file)
 276                "\"")))
 277   (and file buffer-file-coding-system
 278        (not file-name-coding-system)
 279        (not default-file-name-coding-system)
 280        (setq file (encode-coding-string file buffer-file-coding-system)))
 281   file)
 282
 283 (defun wdired-get-filename (&optional no-dir old)
 284   "Return the filename at line.
 285 Similar to `dired-get-filename' but it doesn't rely on regexps.  It
 286 relies on WDired buffer's properties.  Optional arg NO-DIR with value
 287 non-nil means don't include directory.  Optional arg OLD with value
 288 non-nil means return old filename."
 289   ;; FIXME: Use dired-get-filename's new properties.
 290   (let (beg end file)
 291     (save-excursion
 292       (setq end (line-end-position))
 293       (beginning-of-line)
 294       (setq beg (next-single-property-change (point) 'old-name nil end))
 295       (unless (eq beg end)
 296         (if old
 297             (setq file (get-text-property beg 'old-name))
 298           ;; In the following form changed `(1+ beg)' to `beg' so that
 299           ;; the filename end is found even when the filename is empty.
 300           ;; Fixes error and spurious newlines when marking files for
 301           ;; deletion.
 302           (setq end (next-single-property-change beg 'end-name))
 303           (setq file (buffer-substring-no-properties (1+ beg) end)))
 304         (and file (setq file (wdired-normalize-filename file))))
 305       (if (or no-dir old)
 306           file
 307         (and file (> (length file) 0)
 308              (concat (dired-current-directory) file))))))
 309
 310
 311 (defun wdired-change-to-dired-mode ()
 312   "Change the mode back to dired."
 313   (or (eq major-mode 'wdired-mode)
 314       (error "Not a Wdired buffer"))
 315   (let ((inhibit-read-only t))
 316     (remove-text-properties
 317      (point-min) (point-max)
 318      '(front-sticky nil rear-nonsticky nil read-only nil keymap nil)))
 319   (use-local-map dired-mode-map)
 320   (force-mode-line-update)
 321   (setq buffer-read-only t)
 322   (setq major-mode 'dired-mode)
 323   (setq mode-name "Dired")
 324   (dired-advertise)
 325   (remove-hook 'kill-buffer-hook 'wdired-check-kill-buffer t)
 326   (set (make-local-variable 'revert-buffer-function) 'dired-revert))
 327
 328
 329 (defun wdired-abort-changes ()
 330   "Abort changes and return to dired mode."
 331   (interactive)
 332   (let ((inhibit-read-only t))
 333     (erase-buffer)
 334     (insert wdired-old-content)
 335     (goto-char wdired-old-point))
 336   (wdired-change-to-dired-mode)
 337   (set-buffer-modified-p nil)
 338   (setq buffer-undo-list nil)
 339   (message "Changes aborted"))
 340
 341 (defun wdired-finish-edit ()
 342   "Actually rename files based on your editing in the Dired buffer."
 343   (interactive)
 344   (wdired-change-to-dired-mode)
 345   (let ((changes nil)
 346         (errors 0)
 347         files-deleted
 348         files-renamed
 349         some-file-names-unchanged
 350         file-old file-new tmp-value)
 351     (save-excursion
 352       (when (and wdired-allow-to-redirect-links
 353                  (fboundp 'make-symbolic-link))
 354         (setq tmp-value (wdired-do-symlink-changes))
 355         (setq errors (cdr tmp-value))
 356         (setq changes (car tmp-value)))
 357       (when (and wdired-allow-to-change-permissions
 358                  (boundp 'wdired-col-perm)) ; could have been changed
 359         (setq tmp-value (wdired-do-perm-changes))
 360         (setq errors (+ errors (cdr tmp-value)))
 361         (setq changes (or changes (car tmp-value))))
 362       (goto-char (point-max))
 363       (while (not (bobp))
 364         (setq file-old (wdired-get-filename nil t))
 365         (when file-old
 366           (setq file-new (wdired-get-filename))
 367           (if (equal file-new file-old)
 368               (setq some-file-names-unchanged t)
 369             (setq changes t)
 370             (if (not file-new)          ;empty filename!
 371                 (push file-old files-deleted)
 372               (push (cons file-old (substitute-in-file-name file-new))
 373                     files-renamed))))
 374         (forward-line -1)))
 375     (when files-renamed
 376       (setq errors (+ errors (wdired-do-renames files-renamed))))
 377     (if changes
 378         (progn
 379           ;; If we are displaying a single file (rather than the
 380           ;; contents of a directory), change dired-directory if that
 381           ;; file was renamed.  (This ought to be generalized to
 382           ;; handle the multiple files case, but that's less trivial).
 383           (when (and (stringp dired-directory)
 384                      (not (file-directory-p dired-directory))
 385                      (null some-file-names-unchanged)
 386                      (= (length files-renamed) 1))
 387             (setq dired-directory (cdr (car files-renamed))))
 388           ;; Re-sort the buffer.
 389           (revert-buffer))
 390       (let ((inhibit-read-only t))
 391         (remove-text-properties (point-min) (point-max)
 392                                 '(old-name nil end-name nil old-link nil
 393                                            end-link nil end-perm nil
 394                                            old-perm nil perm-changed nil))
 395         (message "(No changes to be performed)")))
 396     (when files-deleted
 397       (wdired-flag-for-deletion files-deleted))
 398     (when (> errors 0)
 399       (dired-log-summary (format "%d rename actions failed" errors) nil)))
 400   (set-buffer-modified-p nil)
 401   (setq buffer-undo-list nil))
 402
 403 (defun wdired-do-renames (renames)
 404   "Perform RENAMES in parallel."
 405   (let ((residue ())
 406         (progress nil)
 407         (errors 0)
 408         (overwrite (or (not wdired-confirm-overwrite) 1)))
 409     (while (or renames
 410                ;; We've done one round through the renames, we have found
 411                ;; some residue, but we also made some progress, so maybe
 412                ;; some of the residue were resolved: try again.
 413                (prog1 (setq renames residue)
 414                  (setq progress nil)
 415                  (setq residue nil)))
 416       (let* ((rename (pop renames))
 417              (file-new (cdr rename)))
 418         (cond
 419          ((rassoc file-new renames)
 420           (error "Trying to rename 2 files to the same name"))
 421          ((assoc file-new renames)
 422           ;; Renaming to a file name that already exists but will itself be
 423           ;; renamed as well.  Let's wait until that one gets renamed.
 424           (push rename residue))
 425          ((and (assoc file-new residue)
 426                ;; Make sure the file really exists: if it doesn't it's
 427                ;; not really a conflict.  It might be a temp-file generated
 428                ;; specifically to break a circular renaming.
 429                (file-exists-p file-new))
 430           ;; Renaming to a file name that already exists, needed to be renamed,
 431           ;; but whose renaming could not be performed right away.
 432           (if (or progress renames)
 433               ;; There's still a chance the conflict will be resolved.
 434               (push rename residue)
 435             ;; We have not made any progress and we've reached the end of
 436             ;; the renames, so we really have a circular conflict, and we
 437             ;; have to forcefully break the cycle.
 438             (message "Circular renaming: using temporary file name")
 439             (let ((tmp (make-temp-name file-new)))
 440               (push (cons (car rename) tmp) renames)
 441               (push (cons tmp file-new) residue))))
 442          (t
 443           (setq progress t)
 444           (let ((file-ori (car rename)))
 445             (if wdired-use-interactive-rename
 446                 (wdired-search-and-rename file-ori file-new)
 447               ;; If dired-rename-file autoloads dired-aux while
 448               ;; dired-backup-overwrite is locally bound,
 449               ;; dired-backup-overwrite won't be initialized.
 450               ;; So we must ensure dired-aux is loaded.
 451               (require 'dired-aux)
 452               (condition-case err
 453                   (let ((dired-backup-overwrite nil))
 454                     (dired-rename-file file-ori file-new
 455                                        overwrite))
 456                 (error
 457                  (setq errors (1+ errors))
 458                  (dired-log (concat "Rename `" file-ori "' to `"
 459                                     file-new "' failed:\n%s\n")
 460                             err)))))))))
 461     errors))
 462
 463
 464 (defun wdired-exit ()
 465   "Exit wdired and return to dired mode.
 466 Just return to dired mode if there are no changes.  Otherwise,
 467 ask a yes-or-no question whether to save or cancel changes,
 468 and proceed depending on the answer."
 469   (interactive)
 470   (if (buffer-modified-p)
 471       (if (y-or-n-p (format "Buffer %s modified; save changes? "
 472                             (current-buffer)))
 473           (wdired-finish-edit)
 474         (wdired-abort-changes))
 475     (wdired-change-to-dired-mode)
 476     (set-buffer-modified-p nil)
 477     (setq buffer-undo-list nil)
 478     (message "(No changes need to be saved)")))
 479
 480 ;; Rename a file, searching it in a modified dired buffer, in order
 481 ;; to be able to use `dired-do-create-files-regexp' and get its
 482 ;; "benefits".
 483 (defun wdired-search-and-rename (filename-ori filename-new)
 484   (save-excursion
 485     (goto-char (point-max))
 486     (forward-line -1)
 487     (let ((done nil)
 488           curr-filename)
 489       (while (and (not done) (not (bobp)))
 490         (setq curr-filename (wdired-get-filename nil t))
 491         (if (equal curr-filename filename-ori)
 492             (progn
 493               (setq done t)
 494               (let ((inhibit-read-only t))
 495                 (dired-move-to-filename)
 496                 (search-forward (wdired-get-filename t) nil t)
 497                 (replace-match (file-name-nondirectory filename-ori) t t))
 498               (dired-do-create-files-regexp
 499                (function dired-rename-file)
 500                "Move" 1 ".*" filename-new nil t))
 501           (forward-line -1))))))
 502
 503 ;; marks a list of files for deletion
 504 (defun wdired-flag-for-deletion (filenames-ori)
 505   (save-excursion
 506     (goto-char (point-min))
 507     (while (not (eobp))
 508       (if (member (dired-get-filename nil t) filenames-ori)
 509           (dired-flag-file-deletion 1)
 510         (forward-line)))))
 511
 512 (defun wdired-customize ()
 513   "Customize WDired options."
 514   (interactive)
 515   (customize-apropos "wdired" 'groups))
 516
 517 (defun wdired-revert (&optional _arg _noconfirm)
 518   "Discard changes in the buffer and update it based on changes on disk.
 519 Optional arguments are ignored."
 520   (wdired-change-to-dired-mode)
 521   (revert-buffer)
 522   (wdired-change-to-wdired-mode))
 523
 524 (defun wdired-check-kill-buffer ()
 525   ;; FIXME: Can't we use the normal mechanism for that?  --Stef
 526   (if (and
 527        (buffer-modified-p)
 528        (not (y-or-n-p "Buffer changed. Discard changes and kill buffer? ")))
 529       (error "Error")))
 530
 531 (defun wdired-next-line (arg)
 532   "Move down lines then position at filename or the current column.
 533 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 534 says how many lines to move; default is one line."
 535   (interactive "p")
 536   (with-no-warnings (next-line arg))
 537   (if (or (eq wdired-use-dired-vertical-movement t)
 538           (and wdired-use-dired-vertical-movement
 539                (< (current-column)
 540                   (save-excursion (dired-move-to-filename)
 541                                   (current-column)))))
 542       (dired-move-to-filename)))
 543
 544 (defun wdired-previous-line (arg)
 545   "Move up lines then position at filename or the current column.
 546 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 547 says how many lines to move; default is one line."
 548   (interactive "p")
 549   (with-no-warnings (previous-line arg))
 550   (if (or (eq wdired-use-dired-vertical-movement t)
 551           (and wdired-use-dired-vertical-movement
 552                (< (current-column)
 553                   (save-excursion (dired-move-to-filename)
 554                                   (current-column)))))
 555       (dired-move-to-filename)))
 556
 557 ;; Put the needed properties to allow the user to change links' targets
 558 (defun wdired-preprocess-symlinks ()
 559   (let ((inhibit-read-only t))
 560     (save-excursion
 561       (goto-char (point-min))
 562       (while (not (eobp))
 563         (if (looking-at dired-re-sym)
 564             (progn
 565               (re-search-forward " -> \\(.*\\)$")
 566               (put-text-property (- (match-beginning 1) 2)
 567                                  (1- (match-beginning 1)) 'old-link
 568                                  (match-string-no-properties 1))
 569               (put-text-property (match-end 1) (1+ (match-end 1)) 'end-link t)
 570               (put-text-property (1- (match-beginning 1))
 571                                  (match-beginning 1)
 572                                  'rear-nonsticky '(read-only))
 573               (put-text-property (match-beginning 1)
 574                                  (match-end 1) 'read-only nil)))
 575         (forward-line)
 576         (beginning-of-line)))))
 577
 578
 579 (defun wdired-get-previous-link (&optional old move)
 580   "Return the next symlink target.
 581 If OLD, return the old target.  If MOVE, move point before it."
 582   (let (beg end target)
 583     (setq beg (previous-single-property-change (point) 'old-link nil))
 584     (if beg
 585         (progn
 586           (if old
 587               (setq target (get-text-property (1- beg) 'old-link))
 588             (setq end (next-single-property-change beg 'end-link))
 589             (setq target (buffer-substring-no-properties (1+ beg) end)))
 590           (if move (goto-char (1- beg)))))
 591     (and target (wdired-normalize-filename target))))
 592
 593 (declare-function make-symbolic-link "fileio.c")
 594
 595 ;; Perform the changes in the target of the changed links.
 596 (defun wdired-do-symlink-changes ()
 597   (let ((changes nil)
 598         (errors 0)
 599         link-to-ori link-to-new link-from)
 600     (goto-char (point-max))
 601     (while (setq link-to-new (wdired-get-previous-link))
 602       (setq link-to-ori (wdired-get-previous-link t t))
 603       (setq link-from (wdired-get-filename nil t))
 604       (unless (equal link-to-new link-to-ori)
 605         (setq changes t)
 606         (if (equal link-to-new "") ;empty filename!
 607             (setq link-to-new "/dev/null"))
 608         (condition-case err
 609             (progn
 610               (delete-file link-from)
 611               (make-symbolic-link
 612                (substitute-in-file-name link-to-new) link-from))
 613           (error
 614            (setq errors (1+ errors))
 615            (dired-log (concat "Link `" link-from "' to `"
 616                               link-to-new "' failed:\n%s\n")
 617                       err)))))
 618     (cons changes errors)))
 619
 620 ;; Perform a "case command" skipping read-only words.
 621 (defun wdired-xcase-word (command arg)
 622   (if (< arg 0)
 623       (funcall command arg)
 624     (while (> arg 0)
 625       (condition-case nil
 626           (progn
 627             (funcall command 1)
 628             (setq arg (1- arg)))
 629         (error
 630          (if (forward-word)
 631              ;; Skip any non-word characters to avoid triggering a read-only
 632              ;; error which would cause skipping the next word characters too.
 633              (skip-syntax-forward "^w")
 634            (setq arg 0)))))))
 635
 636 (defun wdired-downcase-word (arg)
 637   "WDired version of `downcase-word'.
 638 Like original function but it skips read-only words."
 639   (interactive "p")
 640   (wdired-xcase-word 'downcase-word arg))
 641
 642 (defun wdired-upcase-word (arg)
 643   "WDired version of `upcase-word'.
 644 Like original function but it skips read-only words."
 645   (interactive "p")
 646   (wdired-xcase-word 'upcase-word arg))
 647
 648 (defun wdired-capitalize-word (arg)
 649   "WDired version of `capitalize-word'.
 650 Like original function but it skips read-only words."
 651   (interactive "p")
 652   (wdired-xcase-word 'capitalize-word arg))
 653
 654
 655 ;; The following code deals with changing the access bits (or
 656 ;; permissions) of the files.
 657
 658 (defvar wdired-perm-mode-map
 659   (let ((map (make-sparse-keymap)))
 660     (define-key map " " 'wdired-toggle-bit)
 661     (define-key map "r" 'wdired-set-bit)
 662     (define-key map "w" 'wdired-set-bit)
 663     (define-key map "x" 'wdired-set-bit)
 664     (define-key map "-" 'wdired-set-bit)
 665     (define-key map "S" 'wdired-set-bit)
 666     (define-key map "s" 'wdired-set-bit)
 667     (define-key map "T" 'wdired-set-bit)
 668     (define-key map "t" 'wdired-set-bit)
 669     (define-key map "s" 'wdired-set-bit)
 670     (define-key map "l" 'wdired-set-bit)
 671     (define-key map [down-mouse-1] 'wdired-mouse-toggle-bit)
 672     map))
 673
 674 ;; Put a keymap property to the permission bits of the files, and store the
 675 ;; original name and permissions as a property
 676 (defun wdired-preprocess-perms ()
 677   (let ((inhibit-read-only t))
 678     (set (make-local-variable 'wdired-col-perm) nil)
 679     (save-excursion
 680       (goto-char (point-min))
 681       (while (not (eobp))
 682         (when (and (not (looking-at dired-re-sym))
 683                    (wdired-get-filename)
 684                    (re-search-forward dired-re-perms (line-end-position) 'eol))
 685           (let ((begin (match-beginning 0))
 686                 (end (match-end 0)))
 687             (unless wdired-col-perm
 688               (setq wdired-col-perm (- (current-column) 9)))
 689             (if (eq wdired-allow-to-change-permissions 'advanced)
 690                 (progn
 691                   (put-text-property begin end 'read-only nil)
 692                   ;; make first permission bit writable
 693                   (put-text-property
 694                    (1- begin) begin 'rear-nonsticky '(read-only)))
 695               ;; avoid that keymap applies to text following permissions
 696               (add-text-properties
 697                (1+ begin) end
 698                `(keymap ,wdired-perm-mode-map rear-nonsticky (keymap))))
 699             (put-text-property end (1+ end) 'end-perm t)
 700             (put-text-property
 701              begin (1+ begin) 'old-perm (match-string-no-properties 0))))
 702         (forward-line)
 703         (beginning-of-line)))))
 704
 705 (defun wdired-perm-allowed-in-pos (char pos)
 706   (cond
 707    ((= char ?-)          t)
 708    ((= char ?r)          (= (% pos 3) 0))
 709    ((= char ?w)          (= (% pos 3) 1))
 710    ((= char ?x)          (= (% pos 3) 2))
 711    ((memq char '(?s ?S)) (memq pos '(2 5)))
 712    ((memq char '(?t ?T)) (= pos 8))
 713    ((= char ?l)          (= pos 5))))
 714
 715 (defun wdired-set-bit ()
 716   "Set a permission bit character."
 717   (interactive)
 718   (if (wdired-perm-allowed-in-pos last-command-event
 719                                   (- (current-column) wdired-col-perm))
 720       (let ((new-bit (char-to-string last-command-event))
 721             (inhibit-read-only t)
 722             (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 723         (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 724         (put-text-property 0 1 'read-only t new-bit)
 725         (insert new-bit)
 726         (delete-char 1)
 727         (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 728         (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap)))
 729     (forward-char 1)))
 730
 731 (defun wdired-toggle-bit ()
 732   "Toggle the permission bit at point."
 733   (interactive)
 734   (let ((inhibit-read-only t)
 735         (new-bit "-")
 736         (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 737     (if (eq (char-after (point)) ?-)
 738         (setq new-bit
 739               (if (= (% (- (current-column) wdired-col-perm) 3) 0) "r"
 740                 (if (= (% (- (current-column) wdired-col-perm) 3) 1) "w"
 741                   "x"))))
 742     (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 743     (put-text-property 0 1 'read-only t new-bit)
 744     (insert new-bit)
 745     (delete-char 1)
 746     (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 747     (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap))))
 748
 749 (defun wdired-mouse-toggle-bit (event)
 750   "Toggle the permission bit that was left clicked."
 751   (interactive "e")
 752   (mouse-set-point event)
 753   (wdired-toggle-bit))
 754
 755 ;; Allowed chars for 4000 bit are Ss  in position 3
 756 ;; Allowed chars for 2000 bit are Ssl in position 6
 757 ;; Allowed chars for 1000 bit are Tt  in position 9
 758 (defun wdired-perms-to-number (perms)
 759   (let ((nperm 0777))
 760     (if (= (elt perms 1) ?-) (setq nperm (- nperm 400)))
 761     (if (= (elt perms 2) ?-) (setq nperm (- nperm 200)))
 762     (let ((p-bit (elt perms 3)))
 763       (if (memq p-bit '(?- ?S)) (setq nperm (- nperm 100)))
 764       (if (memq p-bit '(?s ?S)) (setq nperm (+ nperm 4000))))
 765     (if (= (elt perms 4) ?-) (setq nperm (- nperm 40)))
 766     (if (= (elt perms 5) ?-) (setq nperm (- nperm 20)))
 767     (let ((p-bit (elt perms 6)))
 768       (if (memq p-bit '(?- ?S ?l)) (setq nperm (- nperm 10)))
 769       (if (memq p-bit '(?s ?S ?l)) (setq nperm (+ nperm 2000))))
 770     (if (= (elt perms 7) ?-) (setq nperm (- nperm 4)))
 771     (if (= (elt perms 8) ?-) (setq nperm (- nperm 2)))
 772     (let ((p-bit (elt perms 9)))
 773       (if (memq p-bit '(?- ?T)) (setq nperm (- nperm 1)))
 774       (if (memq p-bit '(?t ?T)) (setq nperm (+ nperm 1000))))
 775     nperm))
 776
 777 ;; Perform the changes in the permissions of the files that have
 778 ;; changed.
 779 (defun wdired-do-perm-changes ()
 780   (let ((changes nil)
 781         (errors 0)
 782         (prop-wanted (if (eq wdired-allow-to-change-permissions 'advanced)
 783                          'old-perm 'perm-changed))
 784         filename perms-ori perms-new perm-tmp)
 785     (goto-char (next-single-property-change (point-min) prop-wanted
 786                                             nil (point-max)))
 787     (while (not (eobp))
 788       (setq perms-ori (get-text-property (point) 'old-perm))
 789       (setq perms-new (buffer-substring-no-properties
 790                        (point) (next-single-property-change (point) 'end-perm)))
 791       (unless (equal perms-ori perms-new)
 792         (setq changes t)
 793         (setq filename (wdired-get-filename nil t))
 794         (if (= (length perms-new) 10)
 795             (progn
 796               (setq perm-tmp
 797                     (int-to-string (wdired-perms-to-number perms-new)))
 798               (unless (equal 0 (process-file dired-chmod-program
 799                                              nil nil nil perm-tmp filename))
 800                 (setq errors (1+ errors))
 801                 (dired-log (concat dired-chmod-program " " perm-tmp
 802                                    " `" filename "' failed\n\n"))))
 803           (setq errors (1+ errors))
 804           (dired-log (concat "Cannot parse permission `" perms-new
 805                              "' for file `" filename "'\n\n"))))
 806       (goto-char (next-single-property-change (1+ (point)) prop-wanted
 807                                               nil (point-max))))
 808     (cons changes errors)))
 809
 810 (provide 'wdired)
 811
 812 ;; Local Variables:
 813 ;; coding: latin-1
 814 ;; byte-compile-dynamic: t
 815 ;; End:
 816
 817 ;;; wdired.el ends here