lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter
   2
   3 ;; Copyright (C) 1989, 1994, 1998, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: data
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This package implements a major mode for editing binary files.  It uses
  30 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  31 ;; can filter a binary into an editable format or from the format back into
  32 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  33 ;; do M-x `describe-mode'.
  34 ;;
  35 ;; NOTE: Remember to change `hexl-program' or `hexl-options' if needed.
  36 ;;
  37 ;; Currently hexl only supports big endian hex output with 16 bit
  38 ;; grouping.
  39 ;;
  40 ;; -iso in `hexl-options' will allow iso characters to display in the
  41 ;; ASCII region of the screen (if your Emacs supports this) instead of
  42 ;; changing them to dots.
  43
  44 ;;; Code:
  45
  46 (require 'eldoc)
  47
  48 ;;
  49 ;; vars here
  50 ;;
  51
  52 (defgroup hexl nil
  53   "Edit a file in a hex dump format using the hexl filter."
  54   :group 'data)
  55
  56
  57 (defcustom hexl-program "hexl"
  58   "The program that will hexlify and dehexlify its stdin.
  59 `hexl-program' will always be concatenated with `hexl-options'
  60 and \"-de\" when dehexlifying a buffer."
  61   :type 'string
  62   :group 'hexl)
  63
  64 (defcustom hexl-iso ""
  65   "If your Emacs can handle ISO characters, this should be set to
  66 \"-iso\" otherwise it should be \"\"."
  67   :type 'string
  68   :group 'hexl)
  69
  70 (defcustom hexl-options (format "-hex %s" hexl-iso)
  71   "Space separated options to `hexl-program' that suit your needs.
  72 Quoting cannot be used, so the arguments cannot themselves contain spaces."
  73   :type 'string
  74   :group 'hexl)
  75
  76 (defcustom hexl-follow-ascii t
  77   "If non-nil then highlight the ASCII character corresponding to point."
  78   :type 'boolean
  79   :group 'hexl
  80   :version "20.3")
  81
  82 (defcustom hexl-mode-hook '(hexl-follow-line hexl-activate-ruler)
  83   "Normal hook run when entering Hexl mode."
  84   :type 'hook
  85   :options '(hexl-follow-line hexl-activate-ruler turn-on-eldoc-mode)
  86   :group 'hexl)
  87
  88 (defface hexl-address-region
  89   '((t (:inherit header-line)))
  90   "Face used in address are of hexl-mode buffer."
  91   :group 'hexl)
  92
  93 (defface hexl-ascii-region
  94   '((t (:inherit header-line)))
  95   "Face used in ascii are of hexl-mode buffer."
  96   :group 'hexl)
  97
  98 (defvar hexl-max-address 0
  99   "Maximum offset into hexl buffer.")
 100
 101 (defvar hexl-mode-map nil)
 102
 103 (defvar ruler-mode)
 104 (defvar ruler-mode-ruler-function)
 105 (defvar hl-line-mode)
 106
 107 (defvar hexl-mode-old-hl-line-mode)
 108 (defvar hexl-mode-old-local-map)
 109 (defvar hexl-mode-old-mode-name)
 110 (defvar hexl-mode-old-major-mode)
 111 (defvar hexl-mode-old-ruler-mode)
 112 (defvar hexl-mode-old-isearch-search-fun-function)
 113 (defvar hexl-mode-old-require-final-newline)
 114 (defvar hexl-mode-old-syntax-table)
 115 (defvar hexl-mode-old-font-lock-keywords)
 116
 117 (defvar hexl-ascii-overlay nil
 118   "Overlay used to highlight ASCII element corresponding to current point.")
 119 (make-variable-buffer-local 'hexl-ascii-overlay)
 120
 121 (defvar hexl-font-lock-keywords
 122   '(("^\\([0-9a-f]+:\\).\\{40\\}  \\(.+$\\)"
 123      ;; "^\\([0-9a-f]+:\\).+  \\(.+$\\)"
 124      (1 'hexl-address-region t t)
 125      (2 'hexl-ascii-region t t)))
 126   "Font lock keywords used in `hexl-mode'.")
 127
 128 ;; routines
 129
 130 (put 'hexl-mode 'mode-class 'special)
 131
 132 ;;;###autoload
 133 (defun hexl-mode (&optional arg)
 134   "\\<hexl-mode-map>A mode for editing binary files in hex dump format.
 135 This is not an ordinary major mode; it alters some aspects
 136 of the current mode's behavior, but not all; also, you can exit
 137 Hexl mode and return to the previous mode using `hexl-mode-exit'.
 138
 139 This function automatically converts a buffer into the hexl format
 140 using the function `hexlify-buffer'.
 141
 142 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 143 representing the offset into the file that the characters on this line
 144 are at and 16 characters from the file (displayed as hexadecimal
 145 values grouped every 16 bits) and as their ASCII values.
 146
 147 If any of the characters (displayed as ASCII characters) are
 148 unprintable (control or meta characters) they will be replaced as
 149 periods.
 150
 151 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 152 in hexl format.
 153
 154 A sample format:
 155
 156   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 157   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 158   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 159   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 160   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 161   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 162   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 163   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 164   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 165   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 166   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 167   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 168   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 169   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 170   000000c0: 7265 6769 6f6e 2e0a                      region..
 171
 172 Movement is as simple as movement in a normal emacs text buffer.  Most
 173 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 174 to move the cursor left, right, down, and up).
 175
 176 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 177 also supported.
 178
 179 There are several ways to change text in hexl mode:
 180
 181 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 182 bound to self-insert so you can simply type the character and it will
 183 insert itself (actually overstrike) into the buffer.
 184
 185 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 186 it isn't bound to self-insert.  An octal number can be supplied in place
 187 of another key to insert the octal number's ASCII representation.
 188
 189 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 190 into the buffer at the current point.
 191
 192 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 193 into the buffer at the current point.
 194
 195 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 196 into the buffer at the current point.
 197
 198 \\[hexl-mode-exit] will exit hexl-mode.
 199
 200 Note: saving the file with any of the usual Emacs commands
 201 will actually convert it back to binary format while saving.
 202
 203 You can use \\[hexl-find-file] to visit a file in Hexl mode.
 204
 205 \\[describe-bindings] for advanced commands."
 206   (interactive "p")
 207   (unless (eq major-mode 'hexl-mode)
 208     (let ((modified (buffer-modified-p))
 209           (inhibit-read-only t)
 210           (original-point (- (point) (point-min)))
 211           max-address)
 212       (and (eobp) (not (bobp))
 213            (setq original-point (1- original-point)))
 214       (if (not (or (eq arg 1) (not arg)))
 215           ;; if no argument then we guess at hexl-max-address
 216           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 217         (setq max-address (1- (buffer-size)))
 218         ;; If the buffer's EOL type is -dos, we need to account for
 219         ;; extra CR characters added when hexlify-buffer writes the
 220         ;; buffer to a file.
 221         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 222           (setq max-address (+ (count-lines (point-min) (point-max))
 223                                max-address))
 224           ;; But if there's no newline at the last line, we are off by
 225           ;; one; adjust.
 226           (or (eq (char-before (point-max)) ?\n)
 227               (setq max-address (1- max-address)))
 228           (setq original-point (+ (count-lines (point-min) (point))
 229                                   original-point))
 230           (or (bolp) (setq original-point (1- original-point))))
 231         (hexlify-buffer)
 232         (restore-buffer-modified-p modified))
 233       (make-local-variable 'hexl-max-address)
 234       (setq hexl-max-address max-address)
 235       (condition-case nil
 236           (hexl-goto-address original-point)
 237         (error nil)))
 238
 239     ;; We do not turn off the old major mode; instead we just
 240     ;; override most of it.  That way, we can restore it perfectly.
 241     (make-local-variable 'hexl-mode-old-local-map)
 242     (setq hexl-mode-old-local-map (current-local-map))
 243     (use-local-map hexl-mode-map)
 244
 245     (make-local-variable 'hexl-mode-old-mode-name)
 246     (setq hexl-mode-old-mode-name mode-name)
 247     (setq mode-name "Hexl")
 248
 249     (set (make-local-variable 'hexl-mode-old-isearch-search-fun-function)
 250          isearch-search-fun-function)
 251     (set (make-local-variable 'isearch-search-fun-function)
 252          'hexl-isearch-search-function)
 253
 254     (make-local-variable 'hexl-mode-old-major-mode)
 255     (setq hexl-mode-old-major-mode major-mode)
 256     (setq major-mode 'hexl-mode)
 257
 258     (make-local-variable 'hexl-mode-old-ruler-mode)
 259     (setq hexl-mode-old-ruler-mode
 260           (and (boundp 'ruler-mode) ruler-mode))
 261
 262     (make-local-variable 'hexl-mode-old-hl-line-mode)
 263     (setq hexl-mode-old-hl-line-mode
 264           (and (boundp 'hl-line-mode) hl-line-mode))
 265
 266     (make-local-variable 'hexl-mode-old-syntax-table)
 267     (setq hexl-mode-old-syntax-table (syntax-table))
 268     (set-syntax-table (standard-syntax-table))
 269
 270     (add-hook 'write-contents-functions 'hexl-save-buffer nil t)
 271
 272     (make-local-variable 'hexl-mode-old-require-final-newline)
 273     (setq hexl-mode-old-require-final-newline require-final-newline)
 274     (make-local-variable 'require-final-newline)
 275     (setq require-final-newline nil)
 276
 277     (make-local-variable 'hexl-mode-old-font-lock-keywords)
 278     (setq hexl-mode-old-font-lock-keywords font-lock-defaults)
 279     (make-local-variable 'font-lock-defaults)
 280     (setq font-lock-defaults '(hexl-font-lock-keywords t))
 281
 282     ;; Add hooks to rehexlify or dehexlify on various events.
 283     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 284
 285     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 286
 287     ;; Set a callback function for eldoc.
 288     (set (make-local-variable 'eldoc-documentation-function)
 289          'hexl-print-current-point-info)
 290     (eldoc-add-command-completions "hexl-")
 291     (eldoc-remove-command "hexl-save-buffer"
 292                           "hexl-current-address")
 293
 294     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 295   (run-mode-hooks 'hexl-mode-hook))
 296
 297
 298 (defun hexl-isearch-search-function ()
 299   (if (and (not isearch-regexp) (not isearch-word))
 300       (lambda (string &optional bound noerror count)
 301         (funcall
 302          (if isearch-forward 're-search-forward 're-search-backward)
 303          (let ((textre
 304                 (if (> (length string) 80)
 305                     (regexp-quote string)
 306                   (mapconcat (lambda (c) (regexp-quote (string c))) string
 307                              "\\(?:\n\\(?:[:a-f0-9]+ \\)+ \\)?"))))
 308            (if (string-match "\\` ?\\([a-f0-9]+ \\)*[a-f0-9]+ ?\\'" string)
 309                (concat textre "\\|"
 310                        (mapconcat 'regexp-quote (split-string string " ")
 311                                   " \\(?: .+\n[a-f0-9]+: \\)?"))
 312              textre))
 313          bound noerror count))
 314     (let ((isearch-search-fun-function nil))
 315       (isearch-search-fun))))
 316
 317 (defun hexl-after-revert-hook ()
 318   (setq hexl-max-address (1- (buffer-size)))
 319   (hexlify-buffer)
 320   (set-buffer-modified-p nil))
 321
 322 (defvar hexl-in-save-buffer nil)
 323
 324 (defun hexl-save-buffer ()
 325   "Save a hexl format buffer as binary in visited file if modified."
 326   (interactive)
 327   (if hexl-in-save-buffer nil
 328     (restore-buffer-modified-p
 329      (if (buffer-modified-p)
 330          (let ((buf (generate-new-buffer " hexl"))
 331                (name (buffer-name))
 332                (start (point-min))
 333                (end (point-max))
 334                modified)
 335            (with-current-buffer buf
 336              (insert-buffer-substring name start end)
 337              (set-buffer name)
 338              (dehexlify-buffer)
 339              ;; Prevent infinite recursion.
 340              (let ((hexl-in-save-buffer t))
 341                (save-buffer))
 342              (setq modified (buffer-modified-p))
 343              (delete-region (point-min) (point-max))
 344              (insert-buffer-substring buf start end)
 345              (kill-buffer buf)
 346              modified))
 347        (message "(No changes need to be saved)")
 348        nil))
 349     ;; Return t to indicate we have saved t
 350     t))
 351
 352 ;;;###autoload
 353 (defun hexl-find-file (filename)
 354   "Edit file FILENAME in `hexl-mode'.
 355 Switch to a buffer visiting file FILENAME, creating one in none exists."
 356   (interactive
 357    (list
 358     (let ((completion-ignored-extensions nil))
 359       (read-file-name "Filename: " nil nil 'ret-must-match))))
 360   ;; Ignore the user's setting of default-major-mode.
 361   (let ((default-major-mode 'fundamental-mode))
 362     (find-file-literally filename))
 363   (if (not (eq major-mode 'hexl-mode))
 364       (hexl-mode)))
 365
 366 (defun hexl-mode-exit (&optional arg)
 367   "Exit Hexl mode, returning to previous mode.
 368 With arg, don't unhexlify buffer."
 369   (interactive "p")
 370   (if (or (eq arg 1) (not arg))
 371       (let ((modified (buffer-modified-p))
 372             (inhibit-read-only t)
 373             (original-point (1+ (hexl-current-address))))
 374         (dehexlify-buffer)
 375         (remove-hook 'write-contents-functions 'hexl-save-buffer t)
 376         (restore-buffer-modified-p modified)
 377         (goto-char original-point)
 378         ;; Maybe adjust point for the removed CR characters.
 379         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 380           (setq original-point (- original-point
 381                                   (count-lines (point-min) (point))))
 382           (or (bobp) (setq original-point (1+ original-point))))
 383         (goto-char original-point)))
 384
 385   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 386   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 387   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 388   (setq hexl-ascii-overlay nil)
 389
 390   (if (and (boundp 'ruler-mode) ruler-mode (not hexl-mode-old-ruler-mode))
 391       (ruler-mode 0))
 392   (if (and (boundp 'hl-line-mode) hl-line-mode (not hexl-mode-old-hl-line-mode))
 393       (hl-line-mode 0))
 394   (setq require-final-newline hexl-mode-old-require-final-newline)
 395   (setq mode-name hexl-mode-old-mode-name)
 396   (setq isearch-search-fun-function hexl-mode-old-isearch-search-fun-function)
 397   (use-local-map hexl-mode-old-local-map)
 398   (set-syntax-table hexl-mode-old-syntax-table)
 399   (setq font-lock-defaults hexl-mode-old-font-lock-keywords)
 400   (setq major-mode hexl-mode-old-major-mode)
 401   (force-mode-line-update))
 402
 403 (defun hexl-maybe-dehexlify-buffer ()
 404   "Convert a hexl format buffer to binary.
 405 Ask the user for confirmation."
 406   (if (y-or-n-p "Convert contents back to binary format? ")
 407       (let ((modified (buffer-modified-p))
 408             (inhibit-read-only t)
 409             (original-point (1+ (hexl-current-address))))
 410         (dehexlify-buffer)
 411         (remove-hook 'write-contents-functions 'hexl-save-buffer t)
 412         (restore-buffer-modified-p modified)
 413         (goto-char original-point))))
 414
 415 (defun hexl-current-address (&optional validate)
 416   "Return current hexl-address."
 417   (interactive)
 418   (let ((current-column (- (% (- (point) (point-min) -1) 68) 11))
 419         (hexl-address 0))
 420     (if (< current-column 0)
 421         (if validate
 422             (error "Point is not on a character in the file")
 423           (setq current-column 0)))
 424     (setq hexl-address
 425           (+ (* (/ (- (point) (point-min) -1) 68) 16)
 426              (if (>= current-column 41)
 427                  (- current-column 41)
 428                (/ (- current-column  (/ current-column 5)) 2))))
 429     (when (interactive-p)
 430       (message "Current address is %d/0x%08x" hexl-address hexl-address))
 431     hexl-address))
 432
 433 (defun hexl-print-current-point-info ()
 434   "Return current hexl-address in string.
 435 This function is intended to be used as eldoc callback."
 436   (let ((addr (hexl-current-address)))
 437     (format "Current address is %d/0x%08x" addr addr)))
 438
 439 (defun hexl-address-to-marker (address)
 440   "Return buffer position for ADDRESS."
 441   (interactive "nAddress: ")
 442   (+ (* (/ address 16) 68) 10 (point-min) (/ (* (% address 16) 5) 2)))
 443
 444 (defun hexl-goto-address (address)
 445   "Goto hexl-mode (decimal) address ADDRESS.
 446 Signal error if ADDRESS out of range."
 447   (interactive "nAddress: ")
 448   (if (or (< address 0) (> address hexl-max-address))
 449       (error "Out of hexl region"))
 450   (goto-char (hexl-address-to-marker address)))
 451
 452 (defun hexl-goto-hex-address (hex-address)
 453   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 454 Signal error if HEX-ADDRESS is out of range."
 455   (interactive "sHex Address: ")
 456   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 457
 458 (defun hexl-hex-string-to-integer (hex-string)
 459   "Return decimal integer for HEX-STRING."
 460   (interactive "sHex number: ")
 461   (let ((hex-num 0))
 462     (while (not (equal hex-string ""))
 463       (setq hex-num (+ (* hex-num 16)
 464                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 465       (setq hex-string (substring hex-string 1)))
 466     hex-num))
 467
 468 (defun hexl-octal-string-to-integer (octal-string)
 469   "Return decimal integer for OCTAL-STRING."
 470   (interactive "sOctal number: ")
 471   (let ((oct-num 0))
 472     (while (not (equal octal-string ""))
 473       (setq oct-num (+ (* oct-num 8)
 474                        (hexl-oct-char-to-integer
 475                         (string-to-char octal-string))))
 476       (setq octal-string (substring octal-string 1)))
 477     oct-num))
 478
 479 ;; move point functions
 480
 481 (defun hexl-backward-char (arg)
 482   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 483   (interactive "p")
 484   (hexl-goto-address (- (hexl-current-address) arg)))
 485
 486 (defun hexl-forward-char (arg)
 487   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 488   (interactive "p")
 489   (hexl-goto-address (+ (hexl-current-address) arg)))
 490
 491 (defun hexl-backward-short (arg)
 492   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 493   (interactive "p")
 494   (hexl-goto-address (let ((address (hexl-current-address)))
 495                        (if (< arg 0)
 496                            (progn
 497                              (setq arg (- arg))
 498                              (while (> arg 0)
 499                                (if (not (equal address (logior address 3)))
 500                                    (if (> address hexl-max-address)
 501                                        (progn
 502                                          (message "End of buffer.")
 503                                          (setq address hexl-max-address))
 504                                      (setq address (logior address 3)))
 505                                  (if (> address hexl-max-address)
 506                                      (progn
 507                                        (message "End of buffer.")
 508                                        (setq address hexl-max-address))
 509                                    (setq address (+ address 4))))
 510                                (setq arg (1- arg)))
 511                              (if (> address hexl-max-address)
 512                                  (progn
 513                                    (message "End of buffer.")
 514                                    (setq address hexl-max-address))
 515                                (setq address (logior address 3))))
 516                          (while (> arg 0)
 517                            (if (not (equal address (logand address -4)))
 518                                (setq address (logand address -4))
 519                              (if (not (equal address 0))
 520                                  (setq address (- address 4))
 521                                (message "Beginning of buffer.")))
 522                            (setq arg (1- arg))))
 523                        address)))
 524
 525 (defun hexl-forward-short (arg)
 526   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 527   (interactive "p")
 528   (hexl-backward-short (- arg)))
 529
 530 (defun hexl-backward-word (arg)
 531   "Move to left ARG words (right if ARG negative) in hexl-mode."
 532   (interactive "p")
 533   (hexl-goto-address (let ((address (hexl-current-address)))
 534                        (if (< arg 0)
 535                            (progn
 536                              (setq arg (- arg))
 537                              (while (> arg 0)
 538                                (if (not (equal address (logior address 7)))
 539                                    (if (> address hexl-max-address)
 540                                        (progn
 541                                          (message "End of buffer.")
 542                                          (setq address hexl-max-address))
 543                                      (setq address (logior address 7)))
 544                                  (if (> address hexl-max-address)
 545                                      (progn
 546                                        (message "End of buffer.")
 547                                        (setq address hexl-max-address))
 548                                    (setq address (+ address 8))))
 549                                (setq arg (1- arg)))
 550                              (if (> address hexl-max-address)
 551                                  (progn
 552                                    (message "End of buffer.")
 553                                    (setq address hexl-max-address))
 554                                (setq address (logior address 7))))
 555                          (while (> arg 0)
 556                            (if (not (equal address (logand address -8)))
 557                                (setq address (logand address -8))
 558                              (if (not (equal address 0))
 559                                  (setq address (- address 8))
 560                                (message "Beginning of buffer.")))
 561                            (setq arg (1- arg))))
 562                        address)))
 563
 564 (defun hexl-forward-word (arg)
 565   "Move right ARG words (left if ARG negative) in hexl-mode."
 566   (interactive "p")
 567   (hexl-backward-word (- arg)))
 568
 569 (defun hexl-previous-line (arg)
 570   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 571 If there is byte at the target address move to the last byte in that line."
 572   (interactive "p")
 573   (hexl-next-line (- arg)))
 574
 575 (defun hexl-next-line (arg)
 576   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 577 If there is no byte at the target address move to the last byte in that line."
 578   (interactive "p")
 579   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 580                        (if (and (< arg 0) (< address 0))
 581                                 (progn (message "Out of hexl region.")
 582                                        (setq address
 583                                              (% (hexl-current-address) 16)))
 584                          (if (and (> address hexl-max-address)
 585                                   (< (% hexl-max-address 16) (% address 16)))
 586                              (setq address hexl-max-address)
 587                            (if (> address hexl-max-address)
 588                                (progn (message "Out of hexl region.")
 589                                       (setq
 590                                        address
 591                                        (+ (logand hexl-max-address -16)
 592                                           (% (hexl-current-address) 16)))))))
 593                        address)))
 594
 595 (defun hexl-beginning-of-buffer (arg)
 596   "Move to the beginning of the hexl buffer.
 597 Leaves `hexl-mark' at previous position.
 598 With prefix arg N, puts point N bytes of the way from the true beginning."
 599   (interactive "p")
 600   (push-mark (point))
 601   (hexl-goto-address (+ 0 (1- arg))))
 602
 603 (defun hexl-end-of-buffer (arg)
 604   "Go to `hexl-max-address' minus ARG."
 605   (interactive "p")
 606   (push-mark (point))
 607   (hexl-goto-address (- hexl-max-address (1- arg))))
 608
 609 (defun hexl-beginning-of-line ()
 610   "Goto beginning of line in hexl mode."
 611   (interactive)
 612   (goto-char (+ (* (/ (point) 68) 68) 11)))
 613
 614 (defun hexl-end-of-line ()
 615   "Goto end of line in hexl mode."
 616   (interactive)
 617   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 618                        (if (> address hexl-max-address)
 619                            (setq address hexl-max-address))
 620                        address)))
 621
 622 (defun hexl-scroll-down (arg)
 623   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 624   (interactive "P")
 625   (if (null arg)
 626       (setq arg (1- (window-height)))
 627     (setq arg (prefix-numeric-value arg)))
 628   (hexl-scroll-up (- arg)))
 629
 630 (defun hexl-scroll-up (arg)
 631   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG.
 632 If there's no byte at the target address, move to the first or last line."
 633   (interactive "P")
 634   (if (null arg)
 635       (setq arg (1- (window-height)))
 636     (setq arg (prefix-numeric-value arg)))
 637   (let* ((movement (* arg 16))
 638          (address (hexl-current-address))
 639          (dest (+ address movement)))
 640     (cond
 641      ;; If possible, try to stay at the same offset from the beginning
 642      ;; of the 16-byte group, even if we move to the first or last
 643      ;; group.
 644      ((and (> dest hexl-max-address)
 645            (>= (% hexl-max-address 16) (% address 16)))
 646       (setq dest (+ (logand hexl-max-address -16) (% address 16))))
 647      ((> dest hexl-max-address)
 648       (setq dest hexl-max-address))
 649      ((< dest 0)
 650       (setq dest (% address 16))))
 651     (if (/= dest (+ address movement))
 652         (message "Out of hexl region."))
 653     (hexl-goto-address dest)
 654     (recenter 0)))
 655
 656 (defun hexl-beginning-of-1k-page ()
 657   "Go to beginning of 1k boundary."
 658   (interactive)
 659   (hexl-goto-address (logand (hexl-current-address) -1024)))
 660
 661 (defun hexl-end-of-1k-page ()
 662   "Go to end of 1k boundary."
 663   (interactive)
 664   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 665                        (if (> address hexl-max-address)
 666                            (setq address hexl-max-address))
 667                        address)))
 668
 669 (defun hexl-beginning-of-512b-page ()
 670   "Go to beginning of 512 byte boundary."
 671   (interactive)
 672   (hexl-goto-address (logand (hexl-current-address) -512)))
 673
 674 (defun hexl-end-of-512b-page ()
 675   "Go to end of 512 byte boundary."
 676   (interactive)
 677   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 678                        (if (> address hexl-max-address)
 679                            (setq address hexl-max-address))
 680                        address)))
 681
 682 (defun hexl-quoted-insert (arg)
 683   "Read next input character and insert it.
 684 Useful for inserting control characters and non-ASCII characters given their
 685 numerical code.
 686 You may also type octal digits, to insert a character with that code."
 687   (interactive "p")
 688   (hexl-insert-multibyte-char (read-quoted-char) arg))
 689
 690 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 691
 692 ;;;###autoload
 693 (defun hexlify-buffer ()
 694   "Convert a binary buffer to hexl format.
 695 This discards the buffer's undo information."
 696   (interactive)
 697   (and buffer-undo-list
 698        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 699            (error "Aborted")))
 700   (setq buffer-undo-list nil)
 701   ;; Don't decode text in the ASCII part of `hexl' program output.
 702   (let ((coding-system-for-read 'raw-text)
 703         (coding-system-for-write buffer-file-coding-system)
 704         (buffer-undo-list t))
 705     (apply 'call-process-region (point-min) (point-max)
 706            (expand-file-name hexl-program exec-directory)
 707            t t nil (split-string hexl-options))
 708     (if (> (point) (hexl-address-to-marker hexl-max-address))
 709         (hexl-goto-address hexl-max-address))))
 710
 711 (defun dehexlify-buffer ()
 712   "Convert a hexl format buffer to binary.
 713 This discards the buffer's undo information."
 714   (interactive)
 715   (and buffer-undo-list
 716        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 717            (error "Aborted")))
 718   (setq buffer-undo-list nil)
 719   (let ((coding-system-for-write 'raw-text)
 720         (coding-system-for-read buffer-file-coding-system)
 721         (buffer-undo-list t))
 722     (apply 'call-process-region (point-min) (point-max)
 723            (expand-file-name hexl-program exec-directory)
 724            t t nil "-de" (split-string hexl-options))))
 725
 726 (defun hexl-char-after-point ()
 727   "Return char for ASCII hex digits at point."
 728   (hexl-htoi (char-after (point))
 729              (char-after (1+ (point)))))
 730
 731 (defun hexl-htoi (lh rh)
 732   "Hex (char) LH (char) RH to integer."
 733     (+ (* (hexl-hex-char-to-integer lh) 16)
 734        (hexl-hex-char-to-integer rh)))
 735
 736 (defun hexl-hex-char-to-integer (character)
 737   "Take a char and return its value as if it was a hex digit."
 738   (if (and (>= character ?0) (<= character ?9))
 739       (- character ?0)
 740     (let ((ch (logior character 32)))
 741       (if (and (>= ch ?a) (<= ch ?f))
 742           (- ch (- ?a 10))
 743         (error "Invalid hex digit `%c'" ch)))))
 744
 745 (defun hexl-oct-char-to-integer (character)
 746   "Take a char and return its value as if it was a octal digit."
 747   (if (and (>= character ?0) (<= character ?7))
 748       (- character ?0)
 749     (error "Invalid octal digit `%c'" character)))
 750
 751 (defun hexl-printable-character (ch)
 752   "Return a displayable string for character CH."
 753   (format "%c" (if hexl-iso
 754                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 755                        46
 756                      ch)
 757                  (if (or (< ch 32) (>= ch 127))
 758                      46
 759                    ch))))
 760
 761 (defun hexl-insert-multibyte-char (ch num)
 762   "Insert a possibly multibyte character CH NUM times.
 763
 764 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 765 and their encoded form is inserted byte by byte."
 766   (let ((charset (char-charset ch))
 767         (coding (if (or (null buffer-file-coding-system)
 768                         ;; coding-system-type equals t means undecided.
 769                         (eq (coding-system-type buffer-file-coding-system) t))
 770                     default-buffer-file-coding-system
 771                   buffer-file-coding-system)))
 772     (cond ((and (> ch 0) (< ch 256))
 773            (hexl-insert-char ch num))
 774           ((eq charset 'unknown)
 775            (error
 776             "0x%x -- invalid character code; use \\[hexl-insert-hex-string]"
 777             ch))
 778           (t
 779            (let ((encoded (encode-coding-char ch coding))
 780                  (internal (string-as-unibyte (char-to-string ch)))
 781                  internal-hex)
 782              ;; If encode-coding-char returns nil, it means our character
 783              ;; cannot be safely encoded with buffer-file-coding-system.
 784              ;; In that case, we offer to insert the internal representation
 785              ;; of that character, byte by byte.
 786              (when (null encoded)
 787                (setq internal-hex
 788                      (mapconcat (function (lambda (c) (format "%x" c)))
 789                                 internal " "))
 790                (if (yes-or-no-p
 791                     (format
 792                      "Insert char 0x%x's internal representation \"%s\"? "
 793                      ch internal-hex))
 794                    (setq encoded internal)
 795                  (error
 796                   "Can't encode `0x%x' with this buffer's coding system; try \\[hexl-insert-hex-string]"
 797                   ch)))
 798              (while (> num 0)
 799                (mapc
 800                 (function (lambda (c) (hexl-insert-char c 1))) encoded)
 801                (setq num (1- num))))))))
 802
 803 (defun hexl-self-insert-command (arg)
 804   "Insert this character.
 805 Interactively, with a numeric argument, insert this character that many times.
 806
 807 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 808 and their encoded form is inserted byte by byte."
 809   (interactive "p")
 810   (hexl-insert-multibyte-char last-command-char arg))
 811
 812 (defun hexl-insert-char (ch num)
 813   "Insert the character CH NUM times in a hexl buffer.
 814
 815 CH must be a unibyte character whose value is between 0 and 255."
 816   (if (or (< ch 0) (> ch 255))
 817       (error "Invalid character 0x%x -- must be in the range [0..255]" ch))
 818   (let ((address (hexl-current-address t)))
 819     (while (> num 0)
 820       (let ((hex-position
 821              (+ (* (/ address 16) 68)
 822                 10 (point-min)
 823                 (* 2 (% address 16))
 824                 (/ (% address 16) 2)))
 825             (ascii-position
 826              (+ (* (/ address 16) 68) 51 (point-min) (% address 16)))
 827             at-ascii-position)
 828         (if (= (point) ascii-position)
 829             (setq at-ascii-position t))
 830         (goto-char hex-position)
 831         (delete-char 2)
 832         (insert (format "%02x" ch))
 833         (goto-char ascii-position)
 834         (delete-char 1)
 835         (insert (hexl-printable-character ch))
 836         (or (eq address hexl-max-address)
 837             (setq address (1+ address)))
 838         (hexl-goto-address address)
 839         (if at-ascii-position
 840             (progn
 841               (beginning-of-line)
 842               (forward-char 51)
 843               (forward-char (% address 16)))))
 844       (setq num (1- num)))))
 845
 846 ;; hex conversion
 847
 848 (defun hexl-insert-hex-char (arg)
 849   "Insert a character given by its hexadecimal code ARG times at point."
 850   (interactive "p")
 851   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 852     (if (< num 0)
 853         (error "Hex number out of range")
 854       (hexl-insert-multibyte-char num arg))))
 855
 856 (defun hexl-insert-hex-string (str arg)
 857   "Insert hexadecimal string STR at point ARG times.
 858 Embedded whitespace, dashes, and periods in the string are ignored."
 859   (interactive "sHex string: \np")
 860   (setq str (replace-regexp-in-string "[- \t.]" "" str))
 861   (let ((chars '()))
 862     (let ((len (length str))
 863           (idx 0))
 864       (if (eq (logand len 1) 1)
 865           (let ((num (hexl-hex-string-to-integer (substring str 0 1))))
 866             (setq chars (cons num chars))
 867             (setq idx 1)))
 868       (while (< idx len)
 869         (let* ((nidx (+ idx 2))
 870                (num (hexl-hex-string-to-integer (substring str idx nidx))))
 871           (setq chars (cons num chars))
 872           (setq idx nidx))))
 873     (setq chars (nreverse chars))
 874     (while (> arg 0)
 875       (let ((chars chars))
 876         (while chars
 877           (hexl-insert-char (car chars) 1)
 878           (setq chars (cdr chars))))
 879       (setq arg (- arg 1)))))
 880
 881 (defun hexl-insert-decimal-char (arg)
 882   "Insert a character given by its decimal code ARG times at point."
 883   (interactive "p")
 884   (let ((num (string-to-number (read-string "Decimal Number: "))))
 885     (if (< num 0)
 886         (error "Decimal number out of range")
 887       (hexl-insert-multibyte-char num arg))))
 888
 889 (defun hexl-insert-octal-char (arg)
 890   "Insert a character given by its octal code ARG times at point."
 891   (interactive "p")
 892   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 893     (if (< num 0)
 894         (error "Decimal number out of range")
 895       (hexl-insert-multibyte-char num arg))))
 896
 897 (defun hexl-follow-ascii (&optional arg)
 898   "Toggle following ASCII in Hexl buffers.
 899 With prefix ARG, turn on following if and only if ARG is positive.
 900 When following is enabled, the ASCII character corresponding to the
 901 element under the point is highlighted.
 902 Customize the variable `hexl-follow-ascii' to disable this feature."
 903   (interactive "P")
 904   (let ((on-p (if arg
 905                   (> (prefix-numeric-value arg) 0)
 906                (not hexl-ascii-overlay))))
 907
 908     (if on-p
 909       ;; turn it on
 910       (if (not hexl-ascii-overlay)
 911           (progn
 912             (setq hexl-ascii-overlay (make-overlay 1 1)
 913                   hexl-follow-ascii t)
 914             (overlay-put hexl-ascii-overlay 'face 'highlight)
 915             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
 916       ;; turn it off
 917       (if hexl-ascii-overlay
 918           (progn
 919             (delete-overlay hexl-ascii-overlay)
 920             (setq hexl-ascii-overlay nil
 921                   hexl-follow-ascii nil)
 922             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 923             )))))
 924
 925 (defun hexl-activate-ruler ()
 926   "Activate `ruler-mode'."
 927   (require 'ruler-mode)
 928   (set (make-local-variable 'ruler-mode-ruler-function)
 929        'hexl-mode-ruler)
 930   (ruler-mode 1))
 931
 932 (defun hexl-follow-line ()
 933   "Activate `hl-line-mode'."
 934   (require 'frame)
 935   (require 'hl-line)
 936   (with-no-warnings
 937     (set (make-local-variable 'hl-line-range-function)
 938          'hexl-highlight-line-range)
 939     (set (make-local-variable 'hl-line-face)
 940          'highlight))
 941   (hl-line-mode 1))
 942
 943 (defun hexl-highlight-line-range ()
 944   "Return the range of address region for the point.
 945 This function is assumed to be used as call back function for `hl-line-mode'."
 946   (cons
 947    (line-beginning-position)
 948    ;; 9 stands for (length "87654321:")
 949    (+ (line-beginning-position) 9)))
 950
 951 (defun hexl-follow-ascii-find ()
 952   "Find and highlight the ASCII element corresponding to current point."
 953   (let ((pos (+ 51
 954                 (- (point) (current-column))
 955                 (mod (hexl-current-address) 16))))
 956     (move-overlay hexl-ascii-overlay pos (1+ pos))
 957     ))
 958
 959 (defun hexl-mode-ruler ()
 960   "Return a string ruler for hexl mode."
 961   (let* ((highlight (mod (hexl-current-address) 16))
 962          (s " 87654321  0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789abcdef")
 963          (pos 0))
 964     (set-text-properties 0 (length s) nil s)
 965     ;; Turn spaces in the header into stretch specs so they work
 966     ;; regardless of the header-line face.
 967     (while (string-match "[ \t]+" s pos)
 968       (setq pos (match-end 0))
 969       (put-text-property (match-beginning 0) pos 'display
 970                          ;; Assume fixed-size chars
 971                          `(space :align-to ,(1- pos))
 972                          s))
 973     ;; Highlight the current column.
 974     (put-text-property (+ 11 (/ (* 5 highlight) 2))
 975                        (+ 13 (/ (* 5 highlight) 2))
 976                        'face 'highlight s)
 977     ;; Highlight the current ascii column
 978     (put-text-property (+ 13 39 highlight) (+ 13 40 highlight)
 979                        'face 'highlight s)
 980     s))
 981
 982 ;; startup stuff.
 983
 984 (if hexl-mode-map
 985     nil
 986   (setq hexl-mode-map (make-keymap))
 987   ;; Make all self-inserting keys go through hexl-self-insert-command,
 988   ;; because we need to convert them to unibyte characters before
 989   ;; inserting them into the buffer.
 990   (define-key hexl-mode-map [remap self-insert-command] 'hexl-self-insert-command)
 991
 992   (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 993   (define-key hexl-mode-map [left] 'hexl-backward-char)
 994   (define-key hexl-mode-map [right] 'hexl-forward-char)
 995   (define-key hexl-mode-map [up] 'hexl-previous-line)
 996   (define-key hexl-mode-map [down] 'hexl-next-line)
 997   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 998   (define-key hexl-mode-map [?\e left] 'hexl-backward-short)
 999   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
1000   (define-key hexl-mode-map [?\e right] 'hexl-forward-short)
1001   (define-key hexl-mode-map [next] 'hexl-scroll-up)
1002   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
1003   (define-key hexl-mode-map [home] 'hexl-beginning-of-line)
1004   (define-key hexl-mode-map [end] 'hexl-end-of-line)
1005   (define-key hexl-mode-map [C-home] 'hexl-beginning-of-buffer)
1006   (define-key hexl-mode-map [C-end] 'hexl-end-of-buffer)
1007   (define-key hexl-mode-map [deletechar] 'undefined)
1008   (define-key hexl-mode-map [deleteline] 'undefined)
1009   (define-key hexl-mode-map [insertline] 'undefined)
1010   (define-key hexl-mode-map [S-delete] 'undefined)
1011   (define-key hexl-mode-map "\177" 'undefined)
1012
1013   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
1014   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
1015   (define-key hexl-mode-map "\C-d" 'undefined)
1016   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
1017   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
1018
1019   (if (not (memq (key-binding (char-to-string help-char))
1020                  '(help-command ehelp-command)))
1021       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
1022
1023   (define-key hexl-mode-map "\C-k" 'undefined)
1024   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
1025   (define-key hexl-mode-map "\C-o" 'undefined)
1026   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
1027   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
1028   (define-key hexl-mode-map "\C-t" 'undefined)
1029   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
1030   (define-key hexl-mode-map "\C-w" 'undefined)
1031   (define-key hexl-mode-map "\C-y" 'undefined)
1032
1033   (fset 'hexl-ESC-prefix (copy-keymap 'ESC-prefix))
1034   (define-key hexl-mode-map "\e" 'hexl-ESC-prefix)
1035   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
1036   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
1037   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
1038   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
1039   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
1040   (define-key hexl-mode-map "\e\C-i" 'undefined)
1041   (define-key hexl-mode-map "\e\C-j" 'undefined)
1042   (define-key hexl-mode-map "\e\C-k" 'undefined)
1043   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
1044   (define-key hexl-mode-map "\e\C-q" 'undefined)
1045   (define-key hexl-mode-map "\e\C-t" 'undefined)
1046   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
1047   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
1048   (define-key hexl-mode-map "\ec" 'undefined)
1049   (define-key hexl-mode-map "\ed" 'undefined)
1050   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
1051   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
1052   (define-key hexl-mode-map "\ei" 'undefined)
1053   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
1054   (define-key hexl-mode-map "\ek" 'undefined)
1055   (define-key hexl-mode-map "\el" 'undefined)
1056   (define-key hexl-mode-map "\eq" 'undefined)
1057   (define-key hexl-mode-map "\es" 'undefined)
1058   (define-key hexl-mode-map "\et" 'undefined)
1059   (define-key hexl-mode-map "\eu" 'undefined)
1060   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
1061   (define-key hexl-mode-map "\ey" 'undefined)
1062   (define-key hexl-mode-map "\ez" 'undefined)
1063   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
1064   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
1065
1066   (fset 'hexl-C-c-prefix (copy-keymap mode-specific-map))
1067   (define-key hexl-mode-map "\C-c" 'hexl-C-c-prefix)
1068   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
1069
1070   (fset 'hexl-C-x-prefix (copy-keymap 'Control-X-prefix))
1071   (define-key hexl-mode-map "\C-x" 'hexl-C-x-prefix)
1072   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
1073   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
1074   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
1075   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
1076   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
1077
1078 (provide 'hexl)
1079
1080 ;; arch-tag: d5a7aa8a-9bce-480b-bcff-6c4c7ca5ea4a
1081 ;;; hexl.el ends here