lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * working-revision (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       OK
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-revision (file)                          NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-revision (file rev buffer)               OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional revision)          NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (revision)                     OK
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (files)             NEEDED?
  91 ;; - annotate-command (file buf &optional rev)     OK
  92 ;; - annotate-time ()                              OK
  93 ;; - annotate-current-time ()                      NOT NEEDED
  94 ;; - annotate-extract-revision-at-line ()          OK
  95 ;; SNAPSHOT SYSTEM
  96 ;; - create-snapshot (dir name branchp)            OK
  97 ;; - assign-name (file name)                       NOT NEEDED
  98 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
  99 ;; MISCELLANEOUS
 100 ;; - make-version-backups-p (file)                 NOT NEEDED
 101 ;; - repository-hostname (dirname)                 NOT NEEDED
 102 ;; - previous-revision (file rev)                  OK
 103 ;; - next-revision (file rev)                      OK
 104 ;; - check-headers ()                              COULD BE SUPPORTED
 105 ;; - clear-headers ()                              NOT NEEDED
 106 ;; - delete-file (file)                            OK
 107 ;; - rename-file (old new)                         OK
 108 ;; - find-file-hook ()                             NOT NEEDED
 109 ;; - find-file-not-found-hook ()                   NOT NEEDED
 110
 111 (eval-when-compile (require 'cl) (require 'vc))
 112
 113 (defvar git-commits-coding-system 'utf-8
 114   "Default coding system for git commits.")
 115
 116 ;;; BACKEND PROPERTIES
 117
 118 (defun vc-git-revision-granularity ()
 119   'repository)
 120
 121 ;;; STATE-QUERYING FUNCTIONS
 122
 123 ;;;###autoload (defun vc-git-registered (file)
 124 ;;;###autoload   "Return non-nil if FILE is registered with git."
 125 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 126 ;;;###autoload       (progn
 127 ;;;###autoload         (load "vc-git")
 128 ;;;###autoload         (vc-git-registered file))))
 129
 130 (defun vc-git-registered (file)
 131   "Check whether FILE is registered with git."
 132   (when (vc-git-root file)
 133     (with-temp-buffer
 134       (let* ((dir (file-name-directory file))
 135              (name (file-relative-name file dir)))
 136         (and (ignore-errors
 137                (when dir (cd dir))
 138                (vc-git--out-ok "ls-files" "-c" "-z" "--" name))
 139              (let ((str (buffer-string)))
 140                (and (> (length str) (length name))
 141                     (string= (substring str 0 (1+ (length name)))
 142                              (concat name "\0")))))))))
 143
 144 (defun vc-git-state (file)
 145   "Git-specific version of `vc-state'."
 146   ;; FIXME: This can't set 'ignored yet
 147   (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 148   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 149     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0"
 150                                 diff))
 151         'edited
 152       'up-to-date)))
 153
 154 (defun vc-git--ls-files-state (state &rest args)
 155   "Set state to STATE on all files found with git-ls-files ARGS."
 156   (with-temp-buffer
 157     (apply 'vc-git-command (current-buffer) nil nil "ls-files" "-z" args)
 158     (goto-char (point-min))
 159     (let ((start (point)))
 160       (while (search-forward "\0" nil t)
 161         (let ((file (expand-file-name
 162                      (buffer-substring-no-properties start (1- (point))))))
 163           (vc-file-setprop file 'vc-backend (if state 'Git 'none))
 164           (vc-file-setprop file 'vc-state state))
 165         (setq start (point))))))
 166
 167 (defun vc-git-dir-state (dir)
 168   "Git-specific version of `dir-state'."
 169   (vc-git--ls-files-state 'up-to-date "-c")
 170   (vc-git--ls-files-state 'edited "-m")
 171   (vc-git--ls-files-state 'removed "-d")
 172   (vc-git--ls-files-state 'ignored "-o" "-i" "--exclude-standard")
 173   (vc-git--ls-files-state nil "-o" "--exclude-standard"))
 174
 175 (defun vc-git-working-revision (file)
 176   "Git-specific version of `vc-working-revision'."
 177   (let ((str (with-output-to-string
 178                (with-current-buffer standard-output
 179                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 180     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 181         (match-string 2 str)
 182       str)))
 183
 184 (defun vc-git-checkout-model (file)
 185   'implicit)
 186
 187 (defun vc-git-workfile-unchanged-p (file)
 188   (eq 'up-to-date (vc-git-state file)))
 189
 190 (defun vc-git-mode-line-string (file)
 191   "Return string for placement into the modeline for FILE."
 192   (let* ((branch (vc-git-working-revision file))
 193          (def-ml (vc-default-mode-line-string 'Git file))
 194          (help-echo (get-text-property 0 'help-echo def-ml)))
 195     (if (zerop (length branch))
 196         (propertize
 197          (concat def-ml "!")
 198          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 199       (propertize def-ml
 200                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 201
 202 (defun vc-git-dired-state-info (file)
 203   "Git-specific version of `vc-dired-state-info'."
 204   (let ((git-state (vc-state file)))
 205     (if (eq git-state 'edited)
 206         "(modified)"
 207       ;; fall back to the default VC representation
 208       (vc-default-dired-state-info 'Git file))))
 209
 210 ;;; STATE-CHANGING FUNCTIONS
 211
 212 (defun vc-git-create-repo ()
 213   "Create a new Git repository."
 214   (vc-git-command nil 0 nil "init"))
 215
 216 (defun vc-git-register (files &optional rev comment)
 217   "Register FILE into the git version-control system."
 218   (vc-git-command nil 0 files "update-index" "--add" "--"))
 219
 220 (defalias 'vc-git-responsible-p 'vc-git-root)
 221
 222 (defun vc-git-unregister (file)
 223   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 224
 225
 226 (defun vc-git-checkin (files rev comment)
 227   (let ((coding-system-for-write git-commits-coding-system))
 228     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 229
 230 (defun vc-git-find-revision (file rev buffer)
 231   (let ((coding-system-for-read 'binary)
 232         (coding-system-for-write 'binary)
 233         (fullname (substring
 234                    (vc-git--run-command-string
 235                     file "ls-files" "-z" "--full-name" "--")
 236                    0 -1)))
 237     (vc-git-command
 238      buffer 0
 239      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 240
 241 (defun vc-git-checkout (file &optional editable rev)
 242   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 243
 244 (defun vc-git-revert (file &optional contents-done)
 245   "Revert FILE to the version stored in the git repository."
 246   (if contents-done
 247       (vc-git-command nil 0 file "update-index" "--")
 248     (vc-git-command nil 0 file "checkout" "HEAD")))
 249
 250 ;;; HISTORY FUNCTIONS
 251
 252 (defun vc-git-print-log (files &optional buffer)
 253   "Get change log associated with FILES."
 254   (let ((coding-system-for-read git-commits-coding-system)
 255         ;; Support both the old print-log interface that passes a
 256         ;; single file, and the new one that passes a file list.
 257         (flist (if (listp files) files (list files))))
 258     ;; `vc-do-command' creates the buffer, but we need it before running
 259     ;; the command.
 260     (vc-setup-buffer buffer)
 261     ;; If the buffer exists from a previous invocation it might be
 262     ;; read-only.
 263     (let ((inhibit-read-only t))
 264       ;; XXX `log-view-mode' needs to have something to identify where
 265       ;; the log for each individual file starts. It seems that by
 266       ;; default git does not output this info. So loop here and call
 267       ;; "git rev-list" on each file separately to make sure that each
 268       ;; file gets a "File:" header before the corresponding
 269       ;; log. Maybe there is a way to do this with one command...
 270       (dolist (file flist)
 271         (with-current-buffer
 272             buffer
 273           (insert "File: " (file-name-nondirectory file) "\n"))
 274         (vc-git-command buffer 'async (file-relative-name file)
 275                         "rev-list" "--pretty" "HEAD" "--")))))
 276
 277 (defvar log-view-message-re)
 278 (defvar log-view-file-re)
 279 (defvar log-view-font-lock-keywords)
 280
 281 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 282   (require 'add-log) ;; we need the faces add-log
 283   ;; Don't have file markers, so use impossible regexp.
 284   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 285   (set (make-local-variable 'log-view-message-re)
 286        "^commit *\\([0-9a-z]+\\)")
 287   (set (make-local-variable 'log-view-font-lock-keywords)
 288        (append
 289         `((,log-view-message-re  (1 'change-log-acknowledgement))
 290           (,log-view-file-re (1 'change-log-file-face)))
 291         ;; Handle the case:
 292         ;; user: foo@bar
 293         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 294            (1 'change-log-email))
 295           ;; Handle the case:
 296           ;; user: FirstName LastName <foo@bar>
 297           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 298            (1 'change-log-name)
 299            (2 'change-log-email))
 300           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 301            (1 'change-log-name))
 302           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 303            (1 'change-log-name)
 304            (2 'change-log-email))
 305           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 306            (1 'change-log-acknowledgement)
 307            (2 'change-log-acknowledgement))
 308           ("^Date:   \\(.+\\)" (1 'change-log-date))
 309           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 310
 311 (defun vc-git-show-log-entry (revision)
 312   "Move to the log entry for REVISION.
 313 REVISION may have the form BRANCH, BRANCH~N,
 314 or BRANCH^ (where \"^\" can be repeated)."
 315   (goto-char (point-min))
 316   (search-forward "\ncommit" nil t
 317                   (cond ((string-match "~\\([0-9]\\)$" revision)
 318                          (1+ (string-to-number (match-string 1 revision))))
 319                         ((string-match "\\^+$" revision)
 320                          (1+ (length (match-string 0 revision))))
 321                         (t nil)))
 322   (beginning-of-line))
 323
 324 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 325   (let ((buf (or buffer "*vc-diff*")))
 326     (if (and rev1 rev2)
 327         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 328                         rev1 rev2 "--")
 329       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 330                       (or rev1 "HEAD") "--"))))
 331
 332 (defun vc-git-revision-table (files)
 333   ;; What about `files'?!?  --Stef
 334   (let ((table (list "HEAD")))
 335     (with-temp-buffer
 336       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 337       (goto-char (point-min))
 338       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 339         (push (match-string 2) table)))
 340     table))
 341
 342 (defun vc-git-revision-completion-table (files)
 343   (lexical-let ((files files)
 344                 table)
 345     (setq table (lazy-completion-table
 346                  table (lambda () (vc-git-revision-table files))))
 347     table))
 348
 349 (defun vc-git-annotate-command (file buf &optional rev)
 350   ;; FIXME: rev is ignored
 351   (let ((name (file-relative-name file)))
 352     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 353
 354 (defun vc-git-annotate-time ()
 355   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 356        (vc-annotate-convert-time
 357         (apply #'encode-time (mapcar (lambda (match)
 358                                        (string-to-number (match-string match)))
 359                                      '(6 5 4 3 2 1 7))))))
 360
 361 (defun vc-git-annotate-extract-revision-at-line ()
 362   (save-excursion
 363     (move-beginning-of-line 1)
 364     (and (looking-at "[0-9a-f]+")
 365          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 366
 367 ;;; SNAPSHOT SYSTEM
 368
 369 (defun vc-git-create-snapshot (dir name branchp)
 370   (let ((default-directory dir))
 371     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 372          (if branchp
 373              (vc-git-command nil 0 nil "checkout" "-b" name)
 374            (vc-git-command nil 0 nil "tag" name)))))
 375
 376 (defun vc-git-retrieve-snapshot (dir name update)
 377   (let ((default-directory dir))
 378     (vc-git-command nil 0 nil "checkout" name)
 379     ;; FIXME: update buffers if `update' is true
 380     ))
 381
 382
 383 ;;; MISCELLANEOUS
 384
 385 (defun vc-git-previous-revision (file rev)
 386   "Git-specific version of `vc-previous-revision'."
 387   (let ((default-directory (file-name-directory (expand-file-name file)))
 388         (file (file-name-nondirectory file)))
 389     (vc-git-symbolic-commit
 390      (with-temp-buffer
 391        (and
 392         (vc-git--out-ok "rev-list" "-2" rev "--" file)
 393         (goto-char (point-max))
 394         (bolp)
 395         (zerop (forward-line -1))
 396         (not (bobp))
 397         (buffer-substring-no-properties
 398          (point)
 399          (1- (point-max))))))))
 400
 401 (defun vc-git-next-revision (file rev)
 402   "Git-specific version of `vc-next-revision'."
 403   (let* ((default-directory (file-name-directory
 404                              (expand-file-name file)))
 405          (file (file-name-nondirectory file))
 406          (current-rev
 407           (with-temp-buffer
 408             (and
 409              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 410              (goto-char (point-max))
 411              (bolp)
 412              (zerop (forward-line -1))
 413              (bobp)
 414              (buffer-substring-no-properties
 415               (point)
 416               (1- (point-max)))))))
 417     (and current-rev
 418          (vc-git-symbolic-commit
 419           (with-temp-buffer
 420             (and
 421              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 422              (goto-char (point-min))
 423              (search-forward current-rev nil t)
 424              (zerop (forward-line -1))
 425              (buffer-substring-no-properties
 426               (point)
 427               (progn (forward-line 1) (1- (point))))))))))
 428
 429 (defun vc-git-delete-file (file)
 430   (vc-git-command nil 0 file "rm" "-f" "--"))
 431
 432 (defun vc-git-rename-file (old new)
 433   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 434
 435 \f
 436 ;;; Internal commands
 437
 438 (defun vc-git-root (file)
 439   (vc-find-root file ".git"))
 440
 441 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 442   "A wrapper around `vc-do-command' for use in vc-git.el.
 443 The difference to vc-do-command is that this function always invokes `git'."
 444   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 445
 446 (defun vc-git--call (buffer command &rest args)
 447   ;; We don't need to care the arguments.  If there is a file name, it
 448   ;; is always a relative one.  This works also for remote
 449   ;; directories.
 450   (apply 'process-file "git" nil buffer nil command args))
 451
 452 (defun vc-git--out-ok (command &rest args)
 453   (zerop (apply 'vc-git--call '(t nil) command args)))
 454
 455 (defun vc-git--run-command-string (file &rest args)
 456   "Run a git command on FILE and return its output as string."
 457   (let* ((ok t)
 458          (str (with-output-to-string
 459                 (with-current-buffer standard-output
 460                   (unless (apply 'vc-git--out-ok
 461                                  (append args (list (file-relative-name
 462                                                      file))))
 463                     (setq ok nil))))))
 464     (and ok str)))
 465
 466 (defun vc-git-symbolic-commit (commit)
 467   "Translate COMMIT string into symbolic form.
 468 Returns nil if not possible."
 469   (and commit
 470        (with-temp-buffer
 471          (and
 472           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 473           (goto-char (point-min))
 474           (= (forward-line 2) 1)
 475           (bolp)
 476           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 477
 478 (provide 'vc-git)
 479
 480 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 481 ;;; vc-git.el ends here