configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.62)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" != no; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" != no; then
  88   if test "${with_kerberos}" = no; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 dnl FIXME hesiod support may not be present, so it seems like an error
  97 dnl to define, or at least use, this unconditionally.
  98 if test "$with_hesiod" != no; then
  99   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 100 fi
 101
 102 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 103 if test "$with_mmdf" != no; then
 104    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 105 fi
 106
 107 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 108 if test "$with_mail_unlink" != no; then
 109    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 110 fi
 111
 112 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 113     [string giving default POP mail host])],
 114     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 115
 116 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 117
 118 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 119 if test "$with_sync_input" = yes; then
 120    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 121 fi
 122
 123 dnl FIXME currently it is not the last.
 124 dnl This should be the last --with option, because --with-x is
 125 dnl added later on when we find the path of X, and it's best to
 126 dnl keep them together visually.
 127 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 128  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 129 [         case "${withval}" in
 130             y | ye | yes )      val=gtk ;;
 131             n | no )            val=no  ;;
 132             l | lu | luc | luci | lucid )       val=lucid ;;
 133             a | at | ath | athe | athen | athena )      val=athena ;;
 134             m | mo | mot | moti | motif )       val=motif ;;
 135             g | gt | gtk  )     val=gtk ;;
 136             * )
 137 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 138 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 139 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 140             ;;
 141           esac
 142           with_x_toolkit=$val
 143 ])
 144
 145 dnl _ON results in a '--without' option in the --help output, so
 146 dnl the help text should refer to "don't compile", etc.
 147 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 148 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 149 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 150 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 151 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 152 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 153
 154 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 155 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 156 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 157
 158 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 159 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 160 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 161 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 162
 163 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 164 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 165 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 166 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 167
 168 ## For the times when you want to build Emacs but don't have
 169 ## a suitable makeinfo, and can live without the manuals.
 170 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 171 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 172
 173 AC_ARG_WITH([pkg-config-prog],dnl
 174 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 175                   [path to pkg-config for finding GTK and librsvg])])
 176 if test "X${with_pkg_config_prog}" != X; then
 177    if test "${with_pkg_config_prog}" != yes; then
 178       PKG_CONFIG="${with_pkg_config_prog}"
 179    fi
 180 fi
 181
 182 CRT_DIR=
 183 AC_ARG_WITH([crt-dir],dnl
 184 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 185 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 186 CRT_DIR="${with_crt_dir}"
 187
 188 AC_ARG_WITH([gnustep-conf],dnl
 189 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 190 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 191   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 192 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 193      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 194
 195 AC_ARG_ENABLE(ns-self-contained,
 196 [AS_HELP_STRING([--disable-ns-self-contained],
 197                 [disable self contained build under NeXTstep])],
 198    EN_NS_SELF_CONTAINED=$enableval,
 199    EN_NS_SELF_CONTAINED=yes)
 200
 201 AC_ARG_ENABLE(asserts,
 202 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 203       USE_XASSERTS=$enableval,
 204       USE_XASSERTS=no)
 205
 206 AC_ARG_ENABLE(maintainer-mode,
 207 [AS_HELP_STRING([--enable-maintainer-mode],
 208                 [enable make rules and dependencies not useful (and sometimes
 209                  confusing) to the casual installer])],
 210       USE_MAINTAINER_MODE=$enableval,
 211       USE_MAINTAINER_MODE=no)
 212 if test $USE_MAINTAINER_MODE = yes; then
 213   MAINT=
 214 else
 215   MAINT=#
 216 fi
 217 AC_SUBST(MAINT)
 218
 219 AC_ARG_ENABLE(locallisppath,
 220 [AS_HELP_STRING([--enable-locallisppath=PATH],
 221                 [directories Emacs should search for lisp files specific
 222                  to this site])],
 223 if test "${enableval}" = "no"; then
 224   locallisppath=
 225 elif test "${enableval}" != "yes"; then
 226   locallisppath=${enableval}
 227 fi)
 228
 229 AC_ARG_ENABLE(checking,
 230 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 231                 [enable expensive run-time checks.  With LIST,
 232                  enable only specific categories of checks.
 233                  Categories are: all,yes,no.
 234                  Flags are: stringbytes, stringoverrun, stringfreelist,
 235                  xmallocoverrun, conslist])],
 236 [ac_checking_flags="${enableval}"],[])
 237 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 238 for check in $ac_checking_flags
 239 do
 240         case $check in
 241         # these set all the flags to specific states
 242         yes)            ac_enable_checking=1 ;;
 243         no)             ac_enable_checking= ;
 244                         ac_gc_check_stringbytes= ;
 245                         ac_gc_check_string_overrun= ;
 246                         ac_gc_check_string_free_list= ;
 247                         ac_xmalloc_overrun= ;
 248                         ac_gc_check_cons_list= ;;
 249         all)            ac_enable_checking=1 ;
 250                         ac_gc_check_stringbytes=1 ;
 251                         ac_gc_check_string_overrun=1 ;
 252                         ac_gc_check_string_free_list=1 ;
 253                         ac_xmalloc_overrun=1 ;
 254                         ac_gc_check_cons_list=1 ;;
 255         # these enable particular checks
 256         stringbytes)    ac_gc_check_stringbytes=1 ;;
 257         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 258         stringfreelist) ac_gc_check_string_free_list=1 ;;
 259         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 260         conslist)       ac_gc_check_cons_list=1 ;;
 261         *)      AC_MSG_ERROR(unknown check category $check) ;;
 262         esac
 263 done
 264 IFS="$ac_save_IFS"
 265
 266 if test x$ac_enable_checking != x ; then
 267   AC_DEFINE(ENABLE_CHECKING, 1,
 268 [Enable expensive run-time checking of data types?])
 269 fi
 270 if test x$ac_gc_check_stringbytes != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 272 [Define this temporarily to hunt a bug.  If defined, the size of
 273    strings is redundantly recorded in sdata structures so that it can
 274    be compared to the sizes recorded in Lisp strings.])
 275 fi
 276 if test x$ac_gc_check_stringoverrun != x ; then
 277   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 278 [Define this to check for short string overrun.])
 279 fi
 280 if test x$ac_gc_check_string_free_list != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 282 [Define this to check the string free list.])
 283 fi
 284 if test x$ac_xmalloc_overrun != x ; then
 285   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 286 [Define this to check for malloc buffer overrun.])
 287 fi
 288 if test x$ac_gc_check_cons_list != x ; then
 289   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 290 [Define this to check for errors in cons list.])
 291 fi
 292
 293 AC_ARG_ENABLE(profiling,
 294 [AS_HELP_STRING([--enable-profiling],
 295                 [build emacs with profiling support.
 296                  This might not work on all platforms])],
 297 [ac_enable_profiling="${enableval}"],[])
 298 if test x$ac_enable_profiling != x ; then
 299    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 300    PROFILING_LDFLAGS="-pg"
 301 else
 302    PROFILING_CFLAGS=
 303    PROFILING_LDFLAGS=
 304 fi
 305
 306 AC_ARG_ENABLE(autodepend,
 307 [AS_HELP_STRING([--enable-autodepend],
 308                 [automatically generate dependencies to .h-files.
 309                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 310                  found])],
 311 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 312
 313 #### Make srcdir absolute, if it isn't already.  It's important to
 314 #### avoid running the path through pwd unnecessarily, since pwd can
 315 #### give you automounter prefixes, which can go away.  We do all this
 316 #### so Emacs can find its files when run uninstalled.
 317 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 318 unset CDPATH
 319 case "${srcdir}" in
 320   /* ) ;;
 321   . )
 322     ## We may be able to use the $PWD environment variable to make this
 323     ## absolute.  But sometimes PWD is inaccurate.
 324     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 325     ## but that tested only for a well-formed and valid PWD,
 326     ## it did not object when PWD was well-formed and valid but just wrong.
 327     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 328     then
 329       srcdir="$PWD"
 330     else
 331       srcdir="`(cd ${srcdir}; pwd)`"
 332     fi
 333   ;;
 334   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 335 esac
 336
 337 #### Check if the source directory already has a configured system in it.
 338 if test `pwd` != `(cd ${srcdir} && pwd)` \
 339    && test -f "${srcdir}/src/config.h" ; then
 340   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 341    as a build directory right now; it has been configured in its own
 342    right.  To configure in another directory as well, you MUST
 343    use GNU make.  If you do not have GNU make, then you must
 344    now do `make distclean' in ${srcdir},
 345    and then run $0 again.]])
 346 fi
 347
 348 #### Given the configuration name, set machfile and opsysfile to the
 349 #### names of the m/*.h and s/*.h files we should use.
 350
 351 ### Canonicalize the configuration name.
 352
 353 AC_CANONICAL_HOST
 354 canonical=$host
 355 configuration=${host_alias-${build_alias-$host}}
 356
 357 dnl This used to use changequote, but, apart from `changequote is evil'
 358 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 359 dnl the great gob of text.  Thus it's not processed for possible expansion.
 360 dnl Just make sure the brackets remain balanced.
 361 dnl
 362 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 363 dnl indicated by comments.
 364 dnl quotation begins
 365 [
 366
 367 ### If you add support for a new configuration, add code to this
 368 ### switch statement to recognize your configuration name and select
 369 ### the appropriate operating system and machine description files.
 370
 371 ### You would hope that you could choose an m/*.h file pretty much
 372 ### based on the machine portion of the configuration name, and an s-
 373 ### file based on the operating system portion.  However, it turns out
 374 ### that each m/*.h file is pretty manufacturer-specific - for
 375 ### example mips.h is MIPS
 376 ### So we basically have to have a special case for each
 377 ### configuration name.
 378 ###
 379 ### As far as handling version numbers on operating systems is
 380 ### concerned, make sure things will fail in a fixable way.  If
 381 ### /etc/MACHINES doesn't say anything about version numbers, be
 382 ### prepared to handle anything reasonably.  If version numbers
 383 ### matter, be sure /etc/MACHINES says something about it.
 384 ###
 385 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 386 ### "System V Release 4"; he writes, "The old convention encouraged
 387 ### confusion between `system' and `release' levels'."
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*-*-freebsd*)        machine=alpha ;;
 397       arm*-*-freebsd*)          machine=arm ;;
 398       ia64-*-freebsd*)          machine=ia64 ;;
 399       sparc-*-freebsd*)         machine=sparc ;;
 400       sparc64-*-freebsd*)       machine=sparc ;;
 401       powerpc-*-freebsd*)       machine=macppc ;;
 402       i[3456]86-*-freebsd*)     machine=intel386 ;;
 403       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*-*-kfreebsd*)       machine=alpha ;;
 412       ia64-*-kfreebsd*)         machine=ia64 ;;
 413       sparc-*-kfreebsd*)        machine=sparc ;;
 414       sparc64-*-kfreebsd*)      machine=sparc ;;
 415       powerpc-*-kfreebsd*)      machine=macppc ;;
 416       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 417       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     case "${canonical}" in
 425       alpha*-*-netbsd*) machine=alpha ;;
 426       i[3456]86-*-netbsd*) machine=intel386 ;;
 427       mips-*-netbsd*)   machine=mips ;;
 428       mipsel-*-netbsd*) machine=mips ;;
 429       mipseb-*-netbsd*) machine=mips ;;
 430       powerpc-*-netbsd*) machine=macppc ;;
 431       sparc*-*-netbsd*) machine=sparc ;;
 432       vax-*-netbsd*)    machine=vax ;;
 433       arm-*-netbsd*)    machine=arm ;;
 434       x86_64-*-netbsd*) machine=amdx86-64 ;;
 435       hppa-*-netbsd*)   machine=hp800 ;;
 436       m68k-*-netbsd*)   machine=m68k ;;
 437     esac
 438   ;;
 439
 440   ## OpenBSD ports
 441   *-*-openbsd* )
 442     opsys=openbsd
 443     case "${canonical}" in
 444       alpha*-*-openbsd*)        machine=alpha ;;
 445       arm-*-openbsd*)          machine=arm ;;
 446       i386-*-openbsd*)         machine=intel386 ;;
 447       powerpc-*-openbsd*)      machine=macppc ;;
 448       sparc*-*-openbsd*)       machine=sparc ;;
 449       vax-*-openbsd*)          machine=vax ;;
 450       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 451       hppa-*-openbsd*)         machine=hp800 ;;
 452     esac
 453   ;;
 454
 455   alpha*-*-linux-gnu* )
 456     machine=alpha opsys=gnu-linux
 457   ;;
 458
 459   arm*-*-linux-gnu* )
 460     machine=arm opsys=gnu-linux
 461   ;;
 462
 463   ## Apple Darwin / Mac OS X
 464   *-apple-darwin* )
 465     case "${canonical}" in
 466       i[3456]86-* )  machine=intel386 ;;
 467       powerpc-* )    machine=macppc ;;
 468       x86_64-* )     machine=amdx86-64 ;;
 469       * )            unported=yes ;;
 470     esac
 471     opsys=darwin
 472     # Define CPP as follows to make autoconf work correctly.
 473     CPP="${CC-cc} -E -no-cpp-precomp"
 474     # Use fink packages if available.
 475     if test -d /sw/include && test -d /sw/lib; then
 476       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 477       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 478       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 479     fi
 480   ;;
 481
 482   ## HP 9000 series 700 and 800, running HP/UX
 483   hppa*-hp-hpux10.2* )
 484     machine=hp800 opsys=hpux10-20
 485   ;;
 486   hppa*-hp-hpux1[1-9]* )
 487     machine=hp800 opsys=hpux11
 488     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 489   ;;
 490
 491   hppa*-*-linux-gnu* )
 492     machine=hp800 opsys=gnu-linux
 493   ;;
 494
 495   ## IBM machines
 496   s390-*-linux-gnu* )
 497     machine=ibms390 opsys=gnu-linux
 498   ;;
 499   s390x-*-linux-gnu* )
 500     machine=ibms390x opsys=gnu-linux
 501   ;;
 502   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 503     machine=ibmrs6000 opsys=aix4-2
 504   ;;
 505   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 506     machine=ibmrs6000 opsys=aix4-2
 507   ;;
 508   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514
 515   ## Macintosh PowerPC
 516   powerpc*-*-linux-gnu* )
 517     machine=macppc opsys=gnu-linux
 518   ;;
 519
 520   ## Silicon Graphics machines
 521   ## Iris 4D
 522   mips-sgi-irix6.5 )
 523     machine=iris4d opsys=irix6-5
 524     # Without defining _LANGUAGE_C, things get masked out in the headers
 525     # so that, for instance, grepping for `free' in stdlib.h fails and
 526     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 527     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 528     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 529   ;;
 530
 531   ## Suns
 532   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 533     machine=sparc opsys=gnu-linux
 534   ;;
 535
 536   *-sun-solaris* \
 537     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 538     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 539     case "${canonical}" in
 540       i[3456]86-*-* )     machine=intel386 ;;
 541       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 542       sparc* )          machine=sparc ;;
 543       * )               unported=yes ;;
 544     esac
 545     case "${canonical}" in
 546       *-sunos5.6* | *-solaris2.6* )
 547                 opsys=sol2-6
 548                 NON_GNU_CPP=/usr/ccs/lib/cpp
 549                 RANLIB="ar -ts"
 550                 ;;
 551       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 552                 opsys=sol2-6
 553                 emacs_check_sunpro_c=yes
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 ;;
 556       *-sunos5* | *-solaris* )
 557                 opsys=sol2-10
 558                 emacs_check_sunpro_c=yes
 559                 NON_GNU_CPP=/usr/ccs/lib/cpp
 560                 ;;
 561     esac
 562     ## Watch out for a compiler that we know will not work.
 563     case "${canonical}" in
 564      *-solaris* | *-sunos5* )
 565                 if [ "x$CC" = x/usr/ucb/cc ]; then
 566                   ## /usr/ucb/cc doesn't work;
 567                   ## we should find some other compiler that does work.
 568                   unset CC
 569                 fi
 570                 ;;
 571       *) ;;
 572     esac
 573   ;;
 574
 575   ## IA-64
 576   ia64*-*-linux* )
 577     machine=ia64 opsys=gnu-linux
 578   ;;
 579
 580   ## Intel 386 machines where we don't care about the manufacturer
 581   i[3456]86-*-* )
 582     machine=intel386
 583     case "${canonical}" in
 584       *-cygwin )                opsys=cygwin ;;
 585       *-darwin* )               opsys=darwin
 586                                 CPP="${CC-cc} -E -no-cpp-precomp"
 587                                 ;;
 588       *-linux-gnu* )            opsys=gnu-linux ;;
 589       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 593     esac
 594   ;;
 595
 596   ## m68k Linux-based GNU system
 597   m68k-*-linux-gnu* )
 598     machine=m68k opsys=gnu-linux
 599   ;;
 600
 601   ## Mips Linux-based GNU system
 602   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 603     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 604     machine=mips opsys=gnu-linux
 605   ;;
 606
 607   ## AMD x86-64 Linux-based GNU system
 608   x86_64-*-linux-gnu* )
 609     machine=amdx86-64 opsys=gnu-linux
 610   ;;
 611
 612   ## Tensilica Xtensa Linux-based GNU system
 613   xtensa*-*-linux-gnu* )
 614     machine=xtensa opsys=gnu-linux
 615     ;;
 616
 617   ## SuperH Linux-based GNU system
 618   sh[34]*-*-linux-gnu* )
 619     machine=sh3 opsys=gnu-linux
 620   ;;
 621
 622   * )
 623     unported=yes
 624   ;;
 625 esac
 626
 627 ### If the code above didn't choose an operating system, just choose
 628 ### an operating system based on the configuration name.  You really
 629 ### only want to use this when you have no idea what the right
 630 ### operating system is; if you know what operating systems a machine
 631 ### runs, it's cleaner to make it explicit in the case statement
 632 ### above.
 633 if test x"${opsys}" = x; then
 634   case "${canonical}" in
 635     *-gnu* )                            opsys=gnu ;;
 636     * )
 637       unported=yes
 638     ;;
 639   esac
 640 fi
 641
 642 ]
 643 dnl quotation ends
 644
 645 if test $unported = yes; then
 646   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 647 Check `etc/MACHINES' for recognized configuration names.])
 648 fi
 649
 650 machfile="m/${machine}.h"
 651 opsysfile="s/${opsys}.h"
 652
 653
 654 #### Choose a compiler.
 655 test -n "$CC" && cc_specified=yes
 656
 657 # Save the value of CFLAGS that the user specified.
 658 SPECIFIED_CFLAGS="$CFLAGS"
 659
 660 dnl Sets GCC=yes if using gcc.
 661 AC_PROG_CC
 662
 663 # On Suns, sometimes $CPP names a directory.
 664 if test -n "$CPP" && test -d "$CPP"; then
 665   CPP=
 666 fi
 667
 668 ## If not using gcc, and on Solaris, and no CPP specified, see if
 669 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 670 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 671  test x"$CPP" = x; then
 672   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 673   AC_CACHE_VAL(emacs_cv_sunpro_c,
 674   [AC_TRY_LINK([],
 675 [#ifndef __SUNPRO_C
 676 fail;
 677 #endif
 678 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 679   AC_MSG_RESULT($emacs_cv_sunpro_c)
 680
 681   if test x"$emacs_cv_sunpro_c" = xyes; then
 682     NON_GNU_CPP="$CC -E -Xs"
 683   fi
 684 fi
 685
 686 #### Some systems specify a CPP to use unless we are using GCC.
 687 #### Now that we know whether we are using GCC, we can decide whether
 688 #### to use that one.
 689 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 690 then
 691   CPP="$NON_GNU_CPP"
 692 fi
 693
 694 #### Some systems specify a CC to use unless we are using GCC.
 695 #### Now that we know whether we are using GCC, we can decide whether
 696 #### to use that one.
 697 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 698   test x$cc_specified != xyes
 699 then
 700   CC="$NON_GNU_CC"
 701 fi
 702
 703 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 704 then
 705   CC="$CC $GCC_TEST_OPTIONS"
 706 fi
 707
 708 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 709 then
 710   CC="$CC $NON_GCC_TEST_OPTIONS"
 711 fi
 712
 713 dnl checks for Unix variants
 714 AC_USE_SYSTEM_EXTENSIONS
 715
 716 ### Use -Wno-pointer-sign if the compiler supports it
 717 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 718 SAVE_CFLAGS="$CFLAGS"
 719 CFLAGS="$CFLAGS -Wno-pointer-sign"
 720 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 721 if test $has_option = yes; then
 722    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 723 fi
 724 AC_MSG_RESULT($has_option)
 725 CFLAGS="$SAVE_CFLAGS"
 726 unset has_option
 727 unset SAVE_CFLAGS
 728
 729 ### Use -Wdeclaration-after-statement if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 #### Some other nice autoconf tests.
 743
 744 dnl checks for programs
 745 AC_PROG_CPP
 746 AC_PROG_INSTALL
 747 if test "x$RANLIB" = x; then
 748   AC_PROG_RANLIB
 749 fi
 750
 751 ## Although we're running on an amd64 kernel, we're actually compiling for
 752 ## the x86 architecture.  The user should probably have provided an
 753 ## explicit --build to `configure', but if everything else than the kernel
 754 ## is running in i386 mode, we can help them out.
 755 if test "$machine" = "amdx86-64"; then
 756   AC_CHECK_DECL([i386])
 757   if test "$ac_cv_have_decl_i386" = "yes"; then
 758     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 759     machine=intel386
 760     machfile="m/${machine}.h"
 761   fi
 762 fi
 763
 764 AC_PATH_PROG(INSTALL_INFO, install-info)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 766 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 767 dnl Don't use GZIP, which is used by gzip for additional parameters.
 768 AC_PATH_PROG(GZIP_PROG, gzip)
 769
 770
 771 ## Need makeinfo >= 4.6 (?) to build the manuals.
 772 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 773 dnl By this stage, configure has already checked for egrep and set EGREP,
 774 dnl or exited with an error if no egrep was found.
 775 if test "$MAKEINFO" != "no" && \
 776   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 777    MAKEINFO=no
 778 fi
 779
 780 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 781 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 782 ## therefore in the category of "special tools" not normally required, which
 783 ## configure does not have to check for (eg autoconf itself).
 784 ## In a Bazaar checkout on the other hand, the manuals are not included.
 785 ## So makeinfo is a requirement to build from Bazaar, and configure
 786 ## should test for it as it does for any other build requirement.
 787 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 788 ## with pre-built manuals, from a Bazaar checkout.
 789 if test "$MAKEINFO" = "no"; then
 790   if test "x${with_makeinfo}" = "xno"; then
 791     MAKEINFO=off
 792   elif test ! -e $srcdir/info/emacs; then
 793     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 794 source tree does not seem to have pre-built manuals in the `info' directory.
 795 Either install a suitable version of makeinfo, or re-run configure
 796 with the `--without-makeinfo' option to build without the manuals.] )
 797   fi
 798 fi
 799
 800 dnl Add our options to ac_link now, after it is set up.
 801
 802 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 803 then
 804   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 805 fi
 806
 807 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 808 then
 809   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 813 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 814 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 815 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 816 dnl if not built to support GNU ld.
 817
 818 late_LDFLAGS=$LDFLAGS
 819 if test "$GCC" = yes; then
 820   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 821 else
 822   LDFLAGS="$LDFLAGS -znocombreloc"
 823 fi
 824
 825 AC_MSG_CHECKING([for -znocombreloc])
 826 AC_LINK_IFELSE([main(){return 0;}],
 827   [AC_MSG_RESULT(yes)],
 828   LDFLAGS=$late_LDFLAGS
 829   [AC_MSG_RESULT(no)])
 830
 831 #### Extract some information from the operating system and machine files.
 832
 833 AC_CHECKING([the machine- and system-dependent files to find out
 834  - which libraries the lib-src programs will want, and
 835  - whether the GNU malloc routines are usable])
 836
 837 ### First figure out CFLAGS (which we use for running the compiler here)
 838 ### and REAL_CFLAGS (which we use for real compilation).
 839 ### The two are the same except on a few systems, where they are made
 840 ### different to work around various lossages.  For example,
 841 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 842 ### as implying static linking.
 843
 844 ### If the CFLAGS env var is specified, we use that value
 845 ### instead of the default.
 846
 847 ### It's not important that this name contain the PID; you can't run
 848 ### two configures in the same directory and have anything work
 849 ### anyway.
 850 tempcname="conftest.c"
 851
 852 echo '
 853 #include "'${srcdir}'/src/'${opsysfile}'"
 854 #include "'${srcdir}'/src/'${machfile}'"
 855
 856 configure___ LIBX=-lX11
 857
 858 configure___ unexec=UNEXEC
 859
 860 #ifdef SYSTEM_MALLOC
 861 configure___ system_malloc=yes
 862 #else
 863 configure___ system_malloc=no
 864 #endif
 865
 866 #ifdef USE_MMAP_FOR_BUFFERS
 867 configure___ use_mmap_for_buffers=yes
 868 #else
 869 configure___ use_mmap_for_buffers=no
 870 #endif
 871
 872 #ifndef C_OPTIMIZE_SWITCH
 873 #ifdef __GNUC__
 874 #define C_OPTIMIZE_SWITCH -O2
 875 #else
 876 #define C_OPTIMIZE_SWITCH -O
 877 #endif
 878 #endif
 879
 880 #ifndef C_WARNINGS_SWITCH
 881 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 882 #endif
 883
 884 #ifdef THIS_IS_CONFIGURE
 885
 886 /* Get the CFLAGS for tests in configure.  */
 887 #ifdef __GNUC__
 888 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 889 #else
 890 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 891 #endif
 892
 893 #else /* not THIS_IS_CONFIGURE */
 894
 895 /* Get the CFLAGS for real compilation.  */
 896 #ifdef __GNUC__
 897 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 898 #else
 899 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 900 #endif
 901
 902 #endif /* not THIS_IS_CONFIGURE */
 903 ' > ${tempcname}
 904
 905 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 906
 907 # The value of CPP is a quoted variable reference, so we need to do this
 908 # to get its actual value...
 909 CPP=`eval "echo $CPP"`
 910 [eval `${CPP} -Isrc ${tempcname} \
 911        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 912 if test "x$SPECIFIED_CFLAGS" = x; then
 913   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 914          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 915 else
 916   REAL_CFLAGS="$CFLAGS"
 917 fi]
 918 rm ${tempcname}
 919
 920
 921 LD_SWITCH_SYSTEM=
 922 case "$opsys" in
 923   freebsd)
 924    ## Let `ld' find image libs and similar things in /usr/local/lib.
 925    ## The system compiler, GCC, has apparently been modified to not
 926    ## look there, contrary to what a stock GCC would do.
 927    LD_SWITCH_SYSTEM=-L/usr/local/lib
 928    ;;
 929
 930   gnu-linux)
 931    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 932    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 933    ;;
 934
 935   netbsd)
 936    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 937    ;;
 938
 939   openbsd)
 940    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 941    ## otherwise Emacs dumps core on elf systems.
 942    LD_SWITCH_SYSTEM="-Z"
 943    ;;
 944 esac
 945 AC_SUBST(LD_SWITCH_SYSTEM)
 946
 947 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 948
 949 ## This is fun.  Some settings of LD_SWITCH_SYSTEM reference
 950 ## LD_SWITCH_X_SITE_AUX, which has not been defined yet.  When using
 951 ## cpp, it was expanded to null.  Thus LD_SWITCH_SYSTEM had different
 952 ## values in configure and the Makefiles.  How helpful.
 953 ## FIXME why not use LD_SWITCH_SYSTEM_TEMACS (or somesuch) instead?
 954 case "$opsys" in
 955   gnu-linux)
 956    ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
 957    LD_SWITCH_SYSTEM="$LD_SWITCH_SYSTEM \$(LD_SWITCH_X_SITE_AUX)" ;;
 958
 959   netbsd|openbsd)
 960    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 961    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 962 esac
 963
 964
 965 C_SWITCH_MACHINE=
 966 if test "$machine" = "alpha"; then
 967   AC_CHECK_DECL([__ELF__])
 968   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 969     ## With ELF, make sure that all common symbols get allocated to in the
 970     ## data section.  Otherwise, the dump of temacs may miss variables in
 971     ## the shared library that have been initialized.  For example, with
 972     ## GNU libc, __malloc_initialized would normally be resolved to the
 973     ## shared library's .bss section, which is fatal.
 974     if test "x$GCC" = "xyes"; then
 975       C_SWITCH_MACHINE="-fno-common"
 976     else
 977       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 978     fi
 979   fi
 980 fi
 981 AC_SUBST(C_SWITCH_MACHINE)
 982
 983
 984 C_SWITCH_SYSTEM=
 985 ## Some programs in src produce warnings saying certain subprograms
 986 ## are too complex and need a MAXMEM value greater than 2000 for
 987 ## additional optimization.  --nils@exp-math.uni-essen.de
 988 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 989   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 990 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 991 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 992 AC_SUBST(C_SWITCH_SYSTEM)
 993
 994
 995 LIBS_SYSTEM=
 996 case "$opsys" in
 997   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 998   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 999
1000   freebsd) LIBS_SYSTEM="-lutil" ;;
1001
1002   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1003
1004   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1005
1006   ## Motif needs -lgen.
1007   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1008 esac
1009 AC_SUBST(LIBS_SYSTEM)
1010
1011
1012 ### Make sure subsequent tests use flags consistent with the build flags.
1013
1014 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1015   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1016 else
1017   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1018 fi
1019
1020 dnl For AC_FUNC_GETLOADAVG, at least:
1021 AC_CONFIG_LIBOBJ_DIR(src)
1022
1023 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1024 AC_SYS_LARGEFILE
1025
1026
1027 ## If user specified a crt-dir, use that unconditionally.
1028 if test "X$CRT_DIR" = "X"; then
1029
1030   case "$canonical" in
1031     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1032     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1033     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1034     ## For anything else (eg /usr/lib32), it is up the user to specify
1035     ## the location (bug#5655).
1036     ## Test for crtn.o, not just the directory, because sometimes the
1037     ## directory exists but does not have the relevant files (bug#1287).
1038     ## FIXME better to test for binary compatibility somehow.
1039     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1040     ;;
1041
1042     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1043   esac
1044
1045   case "$opsys" in
1046     hpux10-20) CRT_DIR=/lib ;;
1047   esac
1048
1049   ## Default is /usr/lib.
1050   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1051
1052 else
1053
1054   ## Some platforms don't use any of these files, so it is not
1055   ## appropriate to put this test outside the if block.
1056   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1057     AC_MSG_ERROR([crt*.o not found in specified location.])
1058
1059 fi
1060
1061 AC_SUBST(CRT_DIR)
1062
1063 LIB_MATH=-lm
1064 LIB_STANDARD=
1065 START_FILES=
1066
1067 case $opsys in
1068   cygwin )
1069     LIB_MATH=
1070     START_FILES='ecrt0.o'
1071     ;;
1072   darwin )
1073     ## Adding -lm confuses the dynamic linker, so omit it.
1074     LIB_MATH=
1075     START_FILES='pre-crt0.o'
1076     ;;
1077   freebsd )
1078     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1079     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1080     ;;
1081   gnu-linux | gnu-kfreebsd )
1082     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1083     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1084     ;;
1085   hpux10-20 | hpux11 )
1086     LIB_STANDARD=-lc
1087     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1088     ;;
1089   netbsd | openbsd )
1090     if test -f $CRT_DIR/crti.o; then
1091         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1092         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1093     else
1094         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1095         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1096     fi
1097     ;;
1098 esac
1099
1100 AC_SUBST(LIB_MATH)
1101 AC_SUBST(START_FILES)
1102
1103 dnl This function definition taken from Gnome 2.0
1104 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1105 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1106 dnl also defines GSTUFF_PKG_ERRORS on error
1107 AC_DEFUN([PKG_CHECK_MODULES], [
1108   succeeded=no
1109
1110   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1111
1112   if test "$PKG_CONFIG" = "no" ; then
1113      ifelse([$4], , [AC_MSG_ERROR([
1114       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1115   else
1116      PKG_CONFIG_MIN_VERSION=0.9.0
1117      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1118         AC_MSG_CHECKING(for $2)
1119
1120         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1121             AC_MSG_RESULT(yes)
1122             succeeded=yes
1123
1124             AC_MSG_CHECKING($1_CFLAGS)
1125             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1126             AC_MSG_RESULT($$1_CFLAGS)
1127
1128             AC_MSG_CHECKING($1_LIBS)
1129             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1130             AC_MSG_RESULT($$1_LIBS)
1131         else
1132             AC_MSG_RESULT(no)
1133             $1_CFLAGS=""
1134             $1_LIBS=""
1135             ## If we have a custom action on failure, don't print errors, but
1136             ## do set a variable so people can do so.
1137             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1138             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1139         fi
1140
1141         AC_SUBST($1_CFLAGS)
1142         AC_SUBST($1_LIBS)
1143      else
1144         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1145         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1146      fi
1147   fi
1148
1149   if test $succeeded = yes; then
1150      ifelse([$3], , :, [$3])
1151   else
1152      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1153   fi
1154 ])
1155
1156
1157 if test "${with_sound}" != "no"; then
1158   # Sound support for GNU/Linux and the free BSDs.
1159   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1160   # Emulation library used on NetBSD.
1161   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1162   AC_SUBST(LIBSOUND)
1163
1164   ALSA_REQUIRED=1.0.0
1165   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1166   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1167   if test $HAVE_ALSA = yes; then
1168     SAVE_CFLAGS="$CFLAGS"
1169     SAVE_LDFLAGS="$LDFLAGS"
1170     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1171     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1172     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1173                     emacs_alsa_normal=yes,
1174                     emacs_alsa_normal=no)
1175     if test "$emacs_alsa_normal" != yes; then
1176       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1177                      [snd_lib_error_set_handler (0);],
1178                      emacs_alsa_subdir=yes,
1179                      emacs_alsa_subdir=no)
1180       if test "$emacs_alsa_subdir" != yes; then
1181         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1182       fi
1183       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1184     fi
1185
1186     CFLAGS="$SAVE_CFLAGS"
1187     LDFLAGS="$SAVE_LDFLAGS"
1188     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1189     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1190     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1191   fi
1192   AC_SUBST(CFLAGS_SOUND)
1193 fi
1194
1195 dnl checks for header files
1196 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1197   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1198   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1199   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1200   sys/utsname.h pwd.h utmp.h)
1201
1202 AC_MSG_CHECKING(if personality LINUX32 can be set)
1203 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1204                emacs_cv_personality_linux32=yes,
1205                emacs_cv_personality_linux32=no)
1206 AC_MSG_RESULT($emacs_cv_personality_linux32)
1207
1208 if test $emacs_cv_personality_linux32 = yes; then
1209   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1210             [Define to 1 if personality LINUX32 can be set.])
1211 fi
1212
1213 dnl On Solaris 8 there's a compilation warning for term.h because
1214 dnl it doesn't define `bool'.
1215 AC_CHECK_HEADERS(term.h, , , -)
1216 AC_HEADER_STDC
1217 AC_HEADER_TIME
1218 AC_CHECK_DECLS([sys_siglist])
1219 if test $ac_cv_have_decl_sys_siglist != yes; then
1220   # For Tru64, at least:
1221   AC_CHECK_DECLS([__sys_siglist])
1222   if test $ac_cv_have_decl___sys_siglist = yes; then
1223     AC_DEFINE(sys_siglist, __sys_siglist,
1224               [Define to any substitute for sys_siglist.])
1225   fi
1226 fi
1227 AC_HEADER_SYS_WAIT
1228
1229 dnl Some systems have utime.h but don't declare the struct anyplace.
1230 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1231 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1232 #include <sys/time.h>
1233 #include <time.h>
1234 #else
1235 #ifdef HAVE_SYS_TIME_H
1236 #include <sys/time.h>
1237 #else
1238 #include <time.h>
1239 #endif
1240 #endif
1241 #ifdef HAVE_UTIME_H
1242 #include <utime.h>
1243 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1244   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1245 if test $emacs_cv_struct_utimbuf = yes; then
1246   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1247 fi
1248
1249 dnl checks for typedefs
1250 AC_TYPE_SIGNAL
1251
1252 dnl Check for speed_t typedef.
1253 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1254   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1255     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1256 if test $emacs_cv_speed_t = yes; then
1257   AC_DEFINE(HAVE_SPEED_T, 1,
1258            [Define to 1 if `speed_t' is declared by <termios.h>.])
1259 fi
1260
1261 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1262 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1263 #include <sys/time.h>
1264 #include <time.h>
1265 #else
1266 #ifdef HAVE_SYS_TIME_H
1267 #include <sys/time.h>
1268 #else
1269 #include <time.h>
1270 #endif
1271 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1272   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1273 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1274 if test $emacs_cv_struct_timeval = yes; then
1275   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1276 fi
1277
1278 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1279 AC_TRY_COMPILE([#include <math.h>],
1280 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1281   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1282 HAVE_EXCEPTION=$emacs_cv_struct_exception
1283 if test $emacs_cv_struct_exception != yes; then
1284   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1285 fi
1286
1287 AC_CHECK_HEADERS(sys/socket.h)
1288 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1289 #if HAVE_SYS_SOCKET_H
1290 #include <sys/socket.h>
1291 #endif])
1292
1293 dnl checks for structure members
1294 AC_STRUCT_TM
1295 AC_STRUCT_TIMEZONE
1296 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1297                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1298                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1299                 [#include <time.h>])
1300 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1301                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1302                   struct ifreq.ifr_addr], , ,
1303                  [AC_INCLUDES_DEFAULT
1304 #if HAVE_SYS_SOCKET_H
1305 #include <sys/socket.h>
1306 #endif
1307 #if HAVE_NET_IF_H
1308 #include <net/if.h>
1309 #endif])
1310
1311 dnl checks for compiler characteristics
1312
1313 dnl Testing __STDC__ to determine prototype support isn't good enough.
1314 dnl DEC C, for instance, doesn't define it with default options, and
1315 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1316 dnl and void *.
1317 AC_C_PROTOTYPES
1318 AC_C_VOLATILE
1319 AC_C_CONST
1320 dnl This isn't useful because we can't turn on use of `inline' unless
1321 dnl the compiler groks `extern inline'.
1322 dnl AC_C_INLINE
1323 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1324   [AC_TRY_COMPILE(, [void * foo;],
1325                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1326 if test $emacs_cv_void_star = yes; then
1327   AC_DEFINE(POINTER_TYPE, void)
1328 else
1329   AC_DEFINE(POINTER_TYPE, char)
1330 fi
1331 AH_TEMPLATE(POINTER_TYPE,
1332             [Define as `void' if your compiler accepts `void *'; otherwise
1333              define as `char'.])dnl
1334
1335
1336
1337 dnl This could be used for targets which can have both byte sexes.
1338 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1339 dnl AC_C_BIGENDIAN
1340
1341 dnl check for Make feature
1342 AC_PROG_MAKE_SET
1343
1344 DEPFLAGS=
1345 MKDEPDIR=":"
1346 deps_frag=deps.mk
1347 dnl check for GNU Make if we have GCC and autodepend is on.
1348 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1349    AC_MSG_CHECKING([whether we are using GNU Make])
1350    HAVE_GNU_MAKE=no
1351    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1352    if test "x$testval" != x; then
1353       HAVE_GNU_MAKE=yes
1354    else
1355       ac_enable_autodepend=no
1356    fi
1357    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1358    if test $HAVE_GNU_MAKE = yes; then
1359       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1360       SAVE_CFLAGS="$CFLAGS"
1361       CFLAGS="$CFLAGS -MMD -MF deps.d"
1362       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1363       CFLAGS="$SAVE_CFLAGS"
1364       test -f deps.d || ac_enable_autodepend=no
1365       rm -rf deps.d
1366       AC_MSG_RESULT([$ac_enable_autodepend])
1367    fi
1368    if test $ac_enable_autodepend = yes; then
1369       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1370       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR}'
1371       deps_frag=autodeps.mk
1372    fi
1373 fi
1374 deps_frag=$srcdir/src/$deps_frag
1375 AC_SUBST(MKDEPDIR)
1376 AC_SUBST(DEPFLAGS)
1377 AC_SUBST_FILE(deps_frag)
1378
1379
1380 dnl checks for operating system services
1381 AC_SYS_LONG_FILE_NAMES
1382
1383 #### Choose a window system.
1384
1385 AC_PATH_X
1386 if test "$no_x" = yes; then
1387   window_system=none
1388 else
1389   window_system=x11
1390 fi
1391
1392 ## Workaround for bug in autoconf <= 2.62.
1393 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1394 ## No need to do anything special for these standard directories.
1395 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1396
1397    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1398
1399 fi
1400
1401 LD_SWITCH_X_SITE_AUX=
1402 LD_SWITCH_X_SITE_AUX_RPATH=
1403 if test "${x_libraries}" != NONE; then
1404   if test -n "${x_libraries}"; then
1405     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1406     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1407     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1408   fi
1409   x_default_search_path=""
1410   x_search_path=${x_libraries}
1411   if test -z "${x_search_path}"; then
1412     x_search_path=/usr/lib
1413   fi
1414   for x_library in `echo ${x_search_path}: | \
1415                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1416     x_search_path="\
1417 ${x_library}/X11/%L/%T/%N%C%S:\
1418 ${x_library}/X11/%l/%T/%N%C%S:\
1419 ${x_library}/X11/%T/%N%C%S:\
1420 ${x_library}/X11/%L/%T/%N%S:\
1421 ${x_library}/X11/%l/%T/%N%S:\
1422 ${x_library}/X11/%T/%N%S"
1423     if test x"${x_default_search_path}" = x; then
1424       x_default_search_path=${x_search_path}
1425     else
1426       x_default_search_path="${x_search_path}:${x_default_search_path}"
1427     fi
1428   done
1429 fi
1430 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1431 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1432
1433 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1434   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1435 fi
1436
1437 if test x"${x_includes}" = x; then
1438   bitmapdir=/usr/include/X11/bitmaps
1439 else
1440   # accumulate include directories that have X11 bitmap subdirectories
1441   bmd_acc="dummyval"
1442   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1443     if test -d "${bmd}/X11/bitmaps"; then
1444       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1445     fi
1446     if test -d "${bmd}/bitmaps"; then
1447       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1448     fi
1449   done
1450   if test ${bmd_acc} != "dummyval"; then
1451     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1452   fi
1453 fi
1454
1455 HAVE_NS=no
1456 NS_IMPL_COCOA=no
1457 NS_IMPL_GNUSTEP=no
1458 NS_IMPL_GNUSTEP_INC=
1459 NS_IMPL_GNUSTEP_TEMACS_LDFLAGS=
1460 tmp_CPPFLAGS="$CPPFLAGS"
1461 tmp_CFLAGS="$CFLAGS"
1462 CPPFLAGS="$CPPFLAGS -x objective-c"
1463 CFLAGS="$CFLAGS -x objective-c"
1464 TEMACS_LDFLAGS2="\${LDFLAGS}"
1465 dnl I don't think it's especially important, but src/Makefile.in
1466 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1467 dnl trailing "/" to it, so now we do it here.
1468 if test "${with_ns}" != no; then
1469   if test "${opsys}" = darwin; then
1470      NS_IMPL_COCOA=yes
1471      ns_appdir=`pwd`/nextstep/Emacs.app/
1472      ns_appbindir=${ns_appdir}Contents/MacOS/
1473      ns_appresdir=${ns_appdir}Contents/Resources
1474      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1475   elif test -f $GNUSTEP_CONFIG_FILE; then
1476      NS_IMPL_GNUSTEP=yes
1477      ns_appdir=`pwd`/nextstep/Emacs.app/
1478      ns_appbindir=${ns_appdir}
1479      ns_appresdir=${ns_appdir}Resources
1480      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1481      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1482      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1483      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1484      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1485      ## Pull in stuff from GNUstep-make.
1486      NS_IMPL_GNUSTEP_INC="FOUNDATION_LIB=gnu
1487 GUI_LIB=gnu
1488 include $GNUSTEP_MAKEFILES/Additional/base.make
1489 include $GNUSTEP_MAKEFILES/Additional/gui.make
1490 shared=no
1491 "
1492      dnl Presumably ${CONFIG_SYSTEM_LIBS} is defined by above includes.
1493      NS_IMPL_GNUSTEP_TEMACS_LDFLAGS="-L${GNUSTEP_SYSTEM_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc \${CONFIG_SYSTEM_LIBS} -lpthread"
1494      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1495      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1496      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1497      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1498      LIB_STANDARD=
1499      START_FILES=
1500      TEMACS_LDFLAGS2=
1501   fi
1502   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1503                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1504   files are missing or cannot be compiled.])])
1505   NS_HAVE_NSINTEGER=yes
1506   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1507                                      [NSInteger i;])],
1508                     ns_have_nsinteger=yes,
1509                     ns_have_nsinteger=no)
1510   if test $ns_have_nsinteger = no; then
1511     NS_HAVE_NSINTEGER=no
1512   fi
1513 fi
1514 AC_SUBST(NS_IMPL_GNUSTEP_INC)
1515 AC_SUBST(NS_IMPL_GNUSTEP_TEMACS_LDFLAGS)
1516 AC_SUBST(TEMACS_LDFLAGS2)
1517
1518 NS_OBJ=
1519 NS_SUPPORT=
1520 if test "${HAVE_NS}" = yes; then
1521   window_system=nextstep
1522   with_xft=no
1523   # set up packaging dirs
1524   exec_prefix=${ns_appbindir}
1525   libexecdir=${ns_appbindir}/libexec
1526   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1527      prefix=${ns_appresdir}
1528   fi
1529   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1530   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1531 fi
1532 CFLAGS="$tmp_CFLAGS"
1533 CPPFLAGS="$tmp_CPPFLAGS"
1534 AC_SUBST(NS_OBJ)
1535 AC_SUBST(NS_SUPPORT)
1536 AC_SUBST(LIB_STANDARD)
1537
1538 case "${window_system}" in
1539   x11 )
1540     HAVE_X_WINDOWS=yes
1541     HAVE_X11=yes
1542     case "${with_x_toolkit}" in
1543       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1544       motif ) USE_X_TOOLKIT=MOTIF ;;
1545       gtk ) with_gtk=yes
1546 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1547 dnl USE_X_TOOLKIT is set.
1548             USE_X_TOOLKIT=none ;;
1549       no ) USE_X_TOOLKIT=none ;;
1550 dnl If user did not say whether to use a toolkit, make this decision later:
1551 dnl use the toolkit if we have gtk, or X11R5 or newer.
1552       * ) USE_X_TOOLKIT=maybe ;;
1553     esac
1554   ;;
1555   nextstep | none )
1556     HAVE_X_WINDOWS=no
1557     HAVE_X11=no
1558     USE_X_TOOLKIT=none
1559   ;;
1560 esac
1561
1562 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1563    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1564    if test "$HAVE_XSERVER" = true ||
1565       test -n "$DISPLAY" ||
1566       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1567         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1568 were found.  You should install the relevant development files for X
1569 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1570 sure you have development files for image handling, i.e.
1571 tiff, gif, jpeg, png and xpm.
1572 If you are sure you want Emacs compiled without X window support, pass
1573   --without-x
1574 to configure.])
1575    fi
1576 fi
1577
1578 ### If we're using X11, we should use the X menu package.
1579 HAVE_MENUS=no
1580 case ${HAVE_X11} in
1581   yes ) HAVE_MENUS=yes ;;
1582 esac
1583
1584 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1585 # Assume not, until told otherwise.
1586 GNU_MALLOC=yes
1587 doug_lea_malloc=yes
1588 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1589 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1590 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1591                emacs_cv_var___after_morecore_hook,
1592 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1593   emacs_cv_var___after_morecore_hook=yes,
1594   emacs_cv_var___after_morecore_hook=no)])
1595 if test $emacs_cv_var___after_morecore_hook = no; then
1596   doug_lea_malloc=no
1597 fi
1598
1599 if test "${system_malloc}" = "yes"; then
1600   GNU_MALLOC=no
1601   GNU_MALLOC_reason="
1602     (The GNU allocators don't work with this system configuration.)"
1603   GMALLOC_OBJ=
1604   VMLIMIT_OBJ=
1605 else
1606   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1607   VMLIMIT_OBJ=vm-limit.o
1608 fi
1609 AC_SUBST(GMALLOC_OBJ)
1610 AC_SUBST(VMLIMIT_OBJ)
1611
1612 if test "$doug_lea_malloc" = "yes" ; then
1613   if test "$GNU_MALLOC" = yes ; then
1614     GNU_MALLOC_reason="
1615       (Using Doug Lea's new malloc from the GNU C Library.)"
1616   fi
1617   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1618             [Define to 1 if you are using the GNU C Library.])
1619
1620   ## Use mmap directly for allocating larger buffers.
1621   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1622   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1623   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1624   case "$opsys" in
1625     gnu*) REL_ALLOC=no ;;
1626   esac
1627 fi
1628
1629 if test x"${REL_ALLOC}" = x; then
1630   REL_ALLOC=${GNU_MALLOC}
1631 fi
1632
1633 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1634 dnl the system configuration file (s/*.h) to turn the use of mmap
1635 dnl in the relocating allocator on.
1636
1637 AC_FUNC_MMAP
1638 if test $use_mmap_for_buffers = yes; then
1639   REL_ALLOC=no
1640 fi
1641
1642 LIBS="$LIBS_SYSTEM $LIBS"
1643
1644 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1645 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1646 AC_CHECK_LIB(dnet, dnet_ntoa)
1647 dnl This causes -lresolv to get used in subsequent tests,
1648 dnl which causes failures on some systems such as HPUX 9.
1649 dnl AC_CHECK_LIB(resolv, gethostbyname)
1650
1651 dnl FIXME replace main with a function we actually want from this library.
1652 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1653
1654 AC_CHECK_LIB(pthreads, cma_open)
1655
1656 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1657 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1658 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1659 ## added to LIBS in configure would never contain the pthreads part,
1660 ## but the value used in Makefiles might.  FIXME?
1661 ##
1662 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1663 ## be harmless on older versions of X where it happens to exist.
1664 test "$opsys" = "aix4-2" && \
1665   test $ac_cv_lib_pthreads_cma_open = yes && \
1666   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1667
1668 dnl Check for need for bigtoc support on IBM AIX
1669
1670 case ${host_os} in
1671 aix*)
1672   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1673     case $GCC in
1674     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1675     *) gdb_cv_bigtoc=-bbigtoc ;;
1676     esac
1677
1678     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1679     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1680   ])
1681   ;;
1682 esac
1683
1684 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1685 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1686 # REAL_CPPFLAGS later on.
1687
1688 REAL_CPPFLAGS="$CPPFLAGS"
1689
1690 if test "${HAVE_X11}" = "yes"; then
1691   DEFS="$C_SWITCH_X_SITE $DEFS"
1692   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1693   LIBS="$LIBX $LIBS"
1694   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1695   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1696
1697   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1698   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1699   # but it's more convenient here to set LD_RUN_PATH
1700   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1701   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1702     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1703     export LD_RUN_PATH
1704   fi
1705
1706   if test "${opsys}" = "gnu-linux"; then
1707     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1708     AC_TRY_LINK([],
1709      [XOpenDisplay ("foo");],
1710      [xlinux_first_failure=no],
1711      [xlinux_first_failure=yes])
1712     if test "${xlinux_first_failure}" = "yes"; then
1713       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1714       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1715       OLD_CPPFLAGS="$CPPFLAGS"
1716       OLD_LIBS="$LIBS"
1717       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1718       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1719       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1720       LIBS="$LIBS -b i486-linuxaout"
1721       AC_TRY_LINK([],
1722        [XOpenDisplay ("foo");],
1723        [xlinux_second_failure=no],
1724        [xlinux_second_failure=yes])
1725       if test "${xlinux_second_failure}" = "yes"; then
1726         # If we get the same failure with -b, there is no use adding -b.
1727         # So take it out.  This plays safe.
1728         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1729         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1730         CPPFLAGS="$OLD_CPPFLAGS"
1731         LIBS="$OLD_LIBS"
1732         AC_MSG_RESULT(no)
1733       else
1734         AC_MSG_RESULT(yes)
1735       fi
1736     else
1737       AC_MSG_RESULT(no)
1738     fi
1739   fi
1740
1741   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1742   # header files included from there.
1743   AC_MSG_CHECKING(for Xkb)
1744   AC_TRY_LINK([#include <X11/Xlib.h>
1745 #include <X11/XKBlib.h>],
1746         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1747         emacs_xkb=yes, emacs_xkb=no)
1748   AC_MSG_RESULT($emacs_xkb)
1749   if test $emacs_xkb = yes; then
1750     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1751   fi
1752
1753   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1754 XScreenNumberOfScreen XSetWMProtocols)
1755 fi
1756
1757 if test "${window_system}" = "x11"; then
1758   AC_MSG_CHECKING(X11 version 6)
1759   AC_CACHE_VAL(emacs_cv_x11_version_6,
1760   [AC_TRY_LINK([#include <X11/Xlib.h>],
1761 [#if XlibSpecificationRelease < 6
1762 fail;
1763 #endif
1764 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1765   if test $emacs_cv_x11_version_6 = yes; then
1766     AC_MSG_RESULT(6 or newer)
1767     AC_DEFINE(HAVE_X11R6, 1,
1768               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1769   else
1770     AC_MSG_RESULT(before 6)
1771   fi
1772 fi
1773
1774
1775 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1776 HAVE_RSVG=no
1777 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1778   if test "${with_rsvg}" != "no"; then
1779     RSVG_REQUIRED=2.11.0
1780     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1781
1782     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1783     AC_SUBST(RSVG_CFLAGS)
1784     AC_SUBST(RSVG_LIBS)
1785
1786     if test ".${RSVG_CFLAGS}" != "."; then
1787       HAVE_RSVG=yes
1788       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1789       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1790       LIBS="$RSVG_LIBS $LIBS"
1791     fi
1792   fi
1793 fi
1794
1795
1796 HAVE_GTK=no
1797 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1798   GLIB_REQUIRED=2.6
1799   GTK_REQUIRED=2.6
1800   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1801
1802   dnl Checks for libraries.
1803   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1804   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1805      AC_MSG_ERROR($GTK_PKG_ERRORS)
1806   fi
1807 fi
1808
1809
1810 GTK_OBJ=
1811 if test x"$pkg_check_gtk" = xyes; then
1812
1813   AC_SUBST(GTK_CFLAGS)
1814   AC_SUBST(GTK_LIBS)
1815   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1816   CFLAGS="$CFLAGS $GTK_CFLAGS"
1817   LIBS="$GTK_LIBS $LIBS"
1818   dnl Try to compile a simple GTK program.
1819   GTK_COMPILES=no
1820   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1821   if test "${GTK_COMPILES}" != "yes"; then
1822     if test "$USE_X_TOOLKIT" != "maybe"; then
1823       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1824     fi
1825   else
1826     HAVE_GTK=yes
1827     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1828     GTK_OBJ=gtkutil.o
1829     USE_X_TOOLKIT=none
1830     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1831       :
1832     else
1833       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1834        closing open displays.  This is no problem if you just use
1835        one display, but if you use more than one and close one of them
1836        Emacs may crash.]])
1837       sleep 3
1838     fi
1839   fi
1840
1841 fi
1842 AC_SUBST(GTK_OBJ)
1843
1844
1845 if test "${HAVE_GTK}" = "yes"; then
1846
1847   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1848   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1849   if test "$with_toolkit_scroll_bars" != no; then
1850     with_toolkit_scroll_bars=yes
1851   fi
1852
1853   dnl  Check if we can use multiple displays with this GTK version.
1854   dnl  If gdk_display_open exists, assume all others are there also.
1855   HAVE_GTK_MULTIDISPLAY=no
1856   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1857   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1858     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1859               [Define to 1 if GTK can handle more than one display.])
1860   fi
1861
1862   dnl  Check if we have the old file selection dialog declared and
1863   dnl  in the link library.  In 2.x it may be in the library,
1864   dnl  but not declared if deprecated featured has been selected out.
1865   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1866   HAVE_GTK_FILE_SELECTION=no
1867   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1868                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1869 #include <gtk/gtk.h>])
1870   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1871     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1872                    HAVE_GTK_FILE_SELECTION=no)
1873   fi
1874
1875   dnl  Check if we have the new file chooser dialog
1876   HAVE_GTK_FILE_CHOOSER=no
1877   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1878                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1879 #include <gtk/gtk.h>])
1880   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1881     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1882                    HAVE_GTK_FILE_CHOOSER=no)
1883   fi
1884
1885   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1886      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1887     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1888               [Define to 1 if GTK has both file selection and chooser dialog.])
1889   fi
1890
1891   dnl Check if pthreads are available.  Emacs only needs this when using
1892   dnl gtk_file_chooser under Gnome.
1893   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1894     HAVE_GTK_AND_PTHREAD=no
1895     AC_CHECK_HEADERS(pthread.h)
1896     if test "$ac_cv_header_pthread_h"; then
1897       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1898     fi
1899     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1900       case "${canonical}" in
1901         *-hpux*) ;;
1902         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1903       esac
1904       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1905                [Define to 1 if you have GTK and pthread (-lpthread).])
1906     fi
1907   fi
1908 fi
1909
1910 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1911 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1912 dnl also not configured.
1913 HAVE_DBUS=no
1914 DBUS_OBJ=
1915 if test "${with_dbus}" = "yes"; then
1916    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1917    if test "$HAVE_DBUS" = yes; then
1918      LIBS="$LIBS $DBUS_LIBS"
1919      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1920      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1921      DBUS_OBJ=dbusbind.o
1922    fi
1923 fi
1924 AC_SUBST(DBUS_OBJ)
1925
1926 dnl GConf has been tested under GNU/Linux only.
1927 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1928 HAVE_GCONF=no
1929 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1930    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1931    if test "$HAVE_GCONF" = yes; then
1932       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1933    fi
1934 fi
1935
1936 dnl SELinux is available for GNU/Linux only.
1937 HAVE_LIBSELINUX=no
1938 LIBSELINUX_LIBS=
1939 if test "${with_selinux}" = "yes"; then
1940    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1941    if test "$HAVE_LIBSELINUX" = yes; then
1942       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1943       LIBSELINUX_LIBS=-lselinux
1944    fi
1945 fi
1946 AC_SUBST(LIBSELINUX_LIBS)
1947
1948 dnl Do not put whitespace before the #include statements below.
1949 dnl Older compilers (eg sunos4 cc) choke on it.
1950 HAVE_XAW3D=no
1951 LUCID_LIBW=
1952 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1953   if test "$with_xaw3d" != no; then
1954     AC_MSG_CHECKING(for xaw3d)
1955     AC_CACHE_VAL(emacs_cv_xaw3d,
1956     [AC_TRY_LINK([
1957 #include <X11/Intrinsic.h>
1958 #include <X11/Xaw3d/Simple.h>],
1959       [],
1960       emacs_cv_xaw3d=yes,
1961       emacs_cv_xaw3d=no)])
1962   else
1963     emacs_cv_xaw3d=no
1964   fi
1965   if test $emacs_cv_xaw3d = yes; then
1966     AC_MSG_RESULT([yes; using Lucid toolkit])
1967     USE_X_TOOLKIT=LUCID
1968     HAVE_XAW3D=yes
1969     LUCID_LIBW=-lXaw3d
1970     AC_DEFINE(HAVE_XAW3D, 1,
1971               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1972   else
1973     AC_MSG_RESULT(no)
1974     AC_MSG_CHECKING(for libXaw)
1975     AC_CACHE_VAL(emacs_cv_xaw,
1976     [AC_TRY_LINK([
1977 #include <X11/Intrinsic.h>
1978 #include <X11/Xaw/Simple.h>],
1979       [],
1980       emacs_cv_xaw=yes,
1981       emacs_cv_xaw=no)])
1982     if test $emacs_cv_xaw = yes; then
1983       AC_MSG_RESULT([yes; using Lucid toolkit])
1984       USE_X_TOOLKIT=LUCID
1985       LUCID_LIBW=-lXaw
1986     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1987       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1988     else
1989       AC_MSG_RESULT([no; do not use toolkit by default])
1990       USE_X_TOOLKIT=none
1991     fi
1992   fi
1993 fi
1994
1995 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1996
1997 LIBXTR6=
1998 if test "${USE_X_TOOLKIT}" != "none"; then
1999   AC_MSG_CHECKING(X11 toolkit version)
2000   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2001   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2002 [#if XtSpecificationRelease < 6
2003 fail;
2004 #endif
2005 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2006   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2007   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2008     AC_MSG_RESULT(6 or newer)
2009     AC_DEFINE(HAVE_X11XTR6, 1,
2010               [Define to 1 if you have the X11R6 or newer version of Xt.])
2011     LIBXTR6="-lSM -lICE"
2012     case "$opsys" in
2013       ## Use libw.a along with X11R6 Xt.
2014       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2015     esac
2016   else
2017     AC_MSG_RESULT(before 6)
2018   fi
2019
2020 dnl If using toolkit, check whether libXmu.a exists.
2021 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2022   OLDLIBS="$LIBS"
2023   if test x$HAVE_X11XTR6 = xyes; then
2024     LIBS="-lXt -lSM -lICE $LIBS"
2025   else
2026     LIBS="-lXt $LIBS"
2027   fi
2028   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2029   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2030 fi
2031 AC_SUBST(LIBXTR6)
2032
2033 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2034 dnl Why not just test for libxmu in the normal way?
2035 LIBXMU=-lXmu
2036 case "$machine" in
2037   ## These machines don't supply Xmu.
2038   hpux* | aix4-2 )
2039     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2040     ;;
2041 esac
2042 AC_SUBST(LIBXMU)
2043
2044 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2045 if test "${HAVE_X11}" = "yes"; then
2046   if test "${USE_X_TOOLKIT}" != "none"; then
2047     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2048   fi
2049 fi
2050
2051 LIBXP=
2052 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2053   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2054   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2055     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2056 int x = 5;
2057 #else
2058 Motif version prior to 2.1.
2059 #endif],
2060     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2061   if test $emacs_cv_motif_version_2_1 = yes; then
2062     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2063   else
2064     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2065     # We put this in CFLAGS temporarily to precede other -I options
2066     # that might be in CFLAGS temporarily.
2067     # We put this in CPPFLAGS where it precedes the other -I options.
2068     OLD_CPPFLAGS=$CPPFLAGS
2069     OLD_CFLAGS=$CFLAGS
2070     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2071     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2072     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2073       [int x = 5;],
2074       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2075     if test $emacs_cv_lesstif = yes; then
2076       # Make sure this -I option remains in CPPFLAGS after it is set
2077       # back to REAL_CPPFLAGS.
2078       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2079       # have those other -I options anyway.  Ultimately, having this
2080       # directory ultimately in CPPFLAGS will be enough.
2081       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2082       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2083     else
2084       CFLAGS=$OLD_CFLAGS
2085       CPPFLAGS=$OLD_CPPFLAGS
2086     fi
2087   fi
2088 fi
2089
2090 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2091 dnl using Motif or Xaw3d is available, and unless
2092 dnl --with-toolkit-scroll-bars=no was specified.
2093
2094 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2095             [Define to 1 if we should use toolkit scroll bars.])dnl
2096 USE_TOOLKIT_SCROLL_BARS=no
2097 if test "${with_toolkit_scroll_bars}" != "no"; then
2098   if test "${USE_X_TOOLKIT}" != "none"; then
2099     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2100       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2101       HAVE_XAW3D=no
2102       USE_TOOLKIT_SCROLL_BARS=yes
2103     elif test "${HAVE_XAW3D}" = "yes"; then
2104       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2105       USE_TOOLKIT_SCROLL_BARS=yes
2106     fi
2107   elif test "${HAVE_GTK}" = "yes"; then
2108     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2109     USE_TOOLKIT_SCROLL_BARS=yes
2110   elif test "${HAVE_NS}" = "yes"; then
2111     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2112     USE_TOOLKIT_SCROLL_BARS=yes
2113   fi
2114 fi
2115
2116 dnl See if XIM is available.
2117 AC_TRY_COMPILE([
2118           #include <X11/Xlib.h>
2119           #include <X11/Xresource.h>],
2120          [XIMProc  callback;],
2121          [HAVE_XIM=yes
2122          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2123          HAVE_XIM=no)
2124
2125 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2126
2127 if test "${with_xim}" != "no"; then
2128   AC_DEFINE(USE_XIM, 1,
2129             [Define to 1 if we should use XIM, if it is available.])
2130 fi
2131
2132
2133 if test "${HAVE_XIM}" != "no"; then
2134   late_CFLAGS=$CFLAGS
2135   if test "$GCC" = yes; then
2136     CFLAGS="$CFLAGS --pedantic-errors"
2137   fi
2138   AC_TRY_COMPILE([
2139 #include <X11/Xlib.h>
2140 #include <X11/Xresource.h>],
2141 [Display *display;
2142 XrmDatabase db;
2143 char *res_name;
2144 char *res_class;
2145 XIMProc  callback;
2146 XPointer *client_data;
2147 #ifndef __GNUC__
2148 /* If we're not using GCC, it's probably not XFree86, and this is
2149    probably right, but we can't use something like --pedantic-errors.  */
2150 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2151                                            char*, XIMProc, XPointer*);
2152 #endif
2153 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2154    client_data);],
2155     [emacs_cv_arg6_star=yes])
2156   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2157          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2158 either XPointer or XPointer*.])dnl
2159   if test "$emacs_cv_arg6_star" = yes; then
2160     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2161   else
2162     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2163   fi
2164   CFLAGS=$late_CFLAGS
2165 fi
2166
2167 ### Start of font-backend (under any platform) section.
2168 # (nothing here yet -- this is a placeholder)
2169 ### End of font-backend (under any platform) section.
2170
2171 ### Start of font-backend (under X11) section.
2172 if test "${HAVE_X11}" = "yes"; then
2173    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2174
2175    ## Use -lXft if available, unless `--with-xft=no'.
2176    HAVE_XFT=maybe
2177     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2178       with_xft="no";
2179     fi
2180     if test "x${with_xft}" != "xno"; then
2181
2182       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2183       ## Because xftfont.c uses XRenderQueryExtension, we also
2184       ## need to link to -lXrender.
2185       HAVE_XRENDER=no
2186       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2187       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2188         OLD_CPPFLAGS="$CPPFLAGS"
2189         OLD_CFLAGS="$CFLAGS"
2190         OLD_LIBS="$LIBS"
2191         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2192         CFLAGS="$CFLAGS $XFT_CFLAGS"
2193         XFT_LIBS="-lXrender $XFT_LIBS"
2194         LIBS="$XFT_LIBS $LIBS"
2195         AC_CHECK_HEADER(X11/Xft/Xft.h,
2196           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2197
2198         if test "${HAVE_XFT}" = "yes"; then
2199           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2200             AC_SUBST(XFT_LIBS)
2201           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2202         else
2203           CPPFLAGS="$OLD_CPPFLAGS"
2204           CFLAGS="$OLD_CFLAGS"
2205           LIBS="$OLD_LIBS"
2206         fi                        # "${HAVE_XFT}" = "yes"
2207       fi                          # "$HAVE_XFT" != no
2208     fi                            # "x${with_xft}" != "xno"
2209
2210     dnl For the "Does Emacs use" message at the end.
2211     if test "$HAVE_XFT" != "yes"; then
2212        HAVE_XFT=no
2213     fi
2214
2215
2216     HAVE_FREETYPE=no
2217     ## We used to allow building with FreeType and without Xft.
2218     ## However, the ftx font backend driver is not in good shape.
2219     if test "${HAVE_XFT}" = "yes"; then
2220       dnl As we use Xft, we anyway use freetype.
2221       dnl There's no need for additional CFLAGS and LIBS.
2222       HAVE_FREETYPE=yes
2223       FONTCONFIG_CFLAGS=
2224       FONTCONFIG_LIBS=
2225     fi
2226
2227     HAVE_LIBOTF=no
2228     if test "${HAVE_FREETYPE}" = "yes"; then
2229       AC_DEFINE(HAVE_FREETYPE, 1,
2230                 [Define to 1 if using the freetype and fontconfig libraries.])
2231       if test "${with_libotf}" != "no"; then
2232         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2233                           HAVE_LIBOTF=no)
2234         if test "$HAVE_LIBOTF" = "yes"; then
2235           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2236           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2237                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2238                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2239           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2240             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2241                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2242           fi
2243         fi
2244       fi
2245     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2246     dnl Does the new font backend require it, or can it work without it?
2247     fi
2248
2249     HAVE_M17N_FLT=no
2250     if test "${HAVE_LIBOTF}" = yes; then
2251       if test "${with_m17n_flt}" != "no"; then
2252         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2253         if test "$HAVE_M17N_FLT" = "yes"; then
2254           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2255         fi
2256       fi
2257     fi
2258 else
2259     HAVE_XFT=no
2260     HAVE_FREETYPE=no
2261     HAVE_LIBOTF=no
2262     HAVE_M17N_FLT=no
2263 fi
2264
2265 ### End of font-backend (under X11) section.
2266
2267 AC_SUBST(FREETYPE_CFLAGS)
2268 AC_SUBST(FREETYPE_LIBS)
2269 AC_SUBST(FONTCONFIG_CFLAGS)
2270 AC_SUBST(FONTCONFIG_LIBS)
2271 AC_SUBST(LIBOTF_CFLAGS)
2272 AC_SUBST(LIBOTF_LIBS)
2273 AC_SUBST(M17N_FLT_CFLAGS)
2274 AC_SUBST(M17N_FLT_LIBS)
2275
2276 ### Use -lXpm if available, unless `--with-xpm=no'.
2277 HAVE_XPM=no
2278 LIBXPM=
2279 if test "${HAVE_X11}" = "yes"; then
2280   if test "${with_xpm}" != "no"; then
2281     AC_CHECK_HEADER(X11/xpm.h,
2282       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2283     if test "${HAVE_XPM}" = "yes"; then
2284       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2285       AC_EGREP_CPP(no_return_alloc_pixels,
2286       [#include "X11/xpm.h"
2287 #ifndef XpmReturnAllocPixels
2288 no_return_alloc_pixels
2289 #endif
2290       ], HAVE_XPM=no, HAVE_XPM=yes)
2291
2292       if test "${HAVE_XPM}" = "yes"; then
2293         AC_MSG_RESULT(yes)
2294       else
2295         AC_MSG_RESULT(no)
2296       fi
2297     fi
2298   fi
2299
2300   if test "${HAVE_XPM}" = "yes"; then
2301     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2302     LIBXPM=-lXpm
2303   fi
2304 fi
2305 AC_SUBST(LIBXPM)
2306
2307 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2308 HAVE_JPEG=no
2309 LIBJPEG=
2310 if test "${HAVE_X11}" = "yes"; then
2311   if test "${with_jpeg}" != "no"; then
2312     dnl Checking for jpeglib.h can lose because of a redefinition of
2313     dnl  HAVE_STDLIB_H.
2314     AC_CHECK_HEADER(jerror.h,
2315       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2316   fi
2317
2318   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2319   if test "${HAVE_JPEG}" = "yes"; then
2320     AC_DEFINE(HAVE_JPEG)
2321     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2322         [#include <jpeglib.h>
2323          version=JPEG_LIB_VERSION
2324 ],
2325         [AC_DEFINE(HAVE_JPEG)],
2326         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2327         HAVE_JPEG=no])
2328   fi
2329   if test "${HAVE_JPEG}" = "yes"; then
2330     LIBJPEG=-ljpeg
2331   fi
2332 fi
2333 AC_SUBST(LIBJPEG)
2334
2335 ### Use -lpng if available, unless `--with-png=no'.
2336 HAVE_PNG=no
2337 LIBPNG=
2338 if test "${HAVE_X11}" = "yes"; then
2339   if test "${with_png}" != "no"; then
2340     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2341     # in /usr/include/libpng.
2342     AC_CHECK_HEADERS(png.h libpng/png.h)
2343     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2344       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2345     fi
2346   fi
2347
2348   if test "${HAVE_PNG}" = "yes"; then
2349     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2350     LIBPNG="-lpng -lz -lm"
2351   fi
2352 fi
2353 AC_SUBST(LIBPNG)
2354
2355 ### Use -ltiff if available, unless `--with-tiff=no'.
2356 HAVE_TIFF=no
2357 LIBTIFF=
2358 if test "${HAVE_X11}" = "yes"; then
2359   if test "${with_tiff}" != "no"; then
2360     AC_CHECK_HEADER(tiffio.h,
2361       [tifflibs="-lz -lm"
2362       # At least one tiff package requires the jpeg library.
2363       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2364       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2365   fi
2366
2367   if test "${HAVE_TIFF}" = "yes"; then
2368     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2369     dnl FIXME -lz -lm, as per libpng?
2370     LIBTIFF=-ltiff
2371   fi
2372 fi
2373 AC_SUBST(LIBTIFF)
2374
2375 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2376 HAVE_GIF=no
2377 LIBGIF=
2378 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2379   AC_CHECK_HEADER(gif_lib.h,
2380 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2381 # Earlier versions can crash Emacs.
2382     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2383
2384   if test "$HAVE_GIF" = yes; then
2385     LIBGIF=-lgif
2386   elif test "$HAVE_GIF" = maybe; then
2387 # If gif_lib.h but no libgif, try libungif.
2388     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2389     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2390   fi
2391
2392   if test "${HAVE_GIF}" = "yes"; then
2393     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2394   fi
2395 fi
2396 AC_SUBST(LIBGIF)
2397
2398 dnl Check for required libraries.
2399 if test "${HAVE_X11}" = "yes"; then
2400   MISSING=""
2401   WITH_NO=""
2402   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2403     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2404   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2405     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2406   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2407     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2408   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2409     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2410   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2411     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2412
2413   if test "X${MISSING}" != X; then
2414     AC_MSG_ERROR([The following required libraries were not found:
2415     $MISSING
2416 Maybe some development libraries/packages are missing?
2417 If you don't want to link with them give
2418     $WITH_NO
2419 as options to configure])
2420   fi
2421 fi
2422
2423 ### Use -lgpm if available, unless `--with-gpm=no'.
2424 HAVE_GPM=no
2425 LIBGPM=
2426 MOUSE_SUPPORT=
2427 if test "${with_gpm}" != "no"; then
2428   AC_CHECK_HEADER(gpm.h,
2429     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2430
2431   if test "${HAVE_GPM}" = "yes"; then
2432     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2433     LIBGPM=-lgpm
2434     ## May be reset below.
2435     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2436   fi
2437 fi
2438 AC_SUBST(LIBGPM)
2439
2440 dnl Check for malloc/malloc.h on darwin
2441 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2442
2443 C_SWITCH_X_SYSTEM=
2444 ### Use NeXTstep API to implement GUI.
2445 if test "${HAVE_NS}" = "yes"; then
2446   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2447   if test "${NS_IMPL_COCOA}" = "yes"; then
2448     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2449     GNU_OBJC_CFLAGS=
2450   fi
2451   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2452     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2453     # See also .m.o rule in Makefile.in */
2454     # FIXME: are all these flags really needed?  Document here why.  */
2455     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2456     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2457   fi
2458   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2459     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2460   fi
2461   # We also have mouse menus.
2462   HAVE_MENUS=yes
2463   OTHER_FILES=ns-app
2464 fi
2465
2466
2467 ### Use session management (-lSM -lICE) if available
2468 HAVE_X_SM=no
2469 LIBXSM=
2470 if test "${HAVE_X11}" = "yes"; then
2471   AC_CHECK_HEADER(X11/SM/SMlib.h,
2472     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2473
2474   if test "${HAVE_X_SM}" = "yes"; then
2475     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2476     LIBXSM="-lSM -lICE"
2477     case "$LIBS" in
2478       *-lSM*) ;;
2479       *)      LIBS="$LIBXSM $LIBS" ;;
2480     esac
2481   fi
2482 fi
2483 AC_SUBST(LIBXSM)
2484
2485 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2486 AC_CACHE_CHECK(whether netdb declares h_errno,
2487                emacs_cv_netdb_declares_h_errno,
2488 [AC_TRY_LINK([#include <netdb.h>],
2489   [return h_errno;],
2490   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2491 if test $emacs_cv_netdb_declares_h_errno = yes; then
2492   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2493 fi
2494
2495 AC_FUNC_ALLOCA
2496
2497 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2498 dnl FIXME is there an autoconf test that does the right thing, without
2499 dnl needing to call A_M_E afterwards?
2500 if test x"$ac_cv_func_alloca_works" != xyes; then
2501    AC_MSG_ERROR( [a system implementation of alloca is required] )
2502 fi
2503
2504 # fmod, logb, and frexp are found in -lm on most systems.
2505 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2506 AC_CHECK_LIB(m, sqrt)
2507
2508 # Check for mail-locking functions in a "mail" library.  Probably this should
2509 # have the same check as for liblockfile below.
2510 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2511 if test $have_mail = yes; then
2512   LIBS_MAIL=-lmail
2513   LIBS="$LIBS_MAIL $LIBS"
2514   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2515 else
2516   LIBS_MAIL=
2517 fi
2518 dnl Debian, at least:
2519 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2520 if test $have_lockfile = yes; then
2521    LIBS_MAIL=-llockfile
2522    LIBS="$LIBS_MAIL $LIBS"
2523    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2524 else
2525 # If we have the shared liblockfile, assume we must use it for mail
2526 # locking (e.g. Debian).  If we couldn't link against liblockfile
2527 # (no liblockfile.a installed), ensure that we don't need to.
2528   dnl This works for files generally, not just executables.
2529   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2530   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2531                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2532   if test $ac_cv_prog_liblockfile = yes; then
2533     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2534 This probably means that movemail could lose mail.
2535 There may be a `development' package to install containing liblockfile.])
2536   fi
2537 fi
2538 AC_CHECK_FUNCS(touchlock)
2539 AC_CHECK_HEADERS(maillock.h)
2540 AC_SUBST(LIBS_MAIL)
2541
2542 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2543 ## interlock access to the mail spool.  The alternative is a lock file named
2544 ## /usr/spool/mail/$USER.lock.
2545 mail_lock=no
2546 case "$opsys" in
2547   aix4-2) mail_lock="lockf" ;;
2548
2549   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2550
2551   ## On GNU/Linux systems, both methods are used by various mail programs.
2552   ## I assume most people are using newer mailers that have heard of flock.
2553   ## Change this if you need to.
2554   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2555   ## configure gets the right answers, and that means *NOT* using flock.
2556   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2557   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2558   ## Debian maintainer hasn't provided a clean fix for Emacs.
2559   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2560   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2561   ## correct logic.  -- fx
2562   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2563   ## liblockfile is a Free Software replacement for libmail, used on
2564   ## Debian systems and elsewhere. -rfr.
2565   gnu-*)
2566     mail_lock="flock"
2567     if test $have_mail = yes || test $have_lockfile = yes; then
2568       test $ac_cv_header_maillock_h = yes && mail_lock=no
2569     fi
2570     ;;
2571 esac
2572
2573 BLESSMAIL_TARGET=
2574 case "$mail_lock" in
2575   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2576
2577   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2578
2579   *) BLESSMAIL_TARGET="need-blessmail" ;;
2580 esac
2581 AC_SUBST(BLESSMAIL_TARGET)
2582
2583
2584 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2585 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2586 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2587 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2588 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2589 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2590 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2591 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2592 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2593 cfmakeraw cfsetspeed isnan copysign)
2594
2595 AC_CHECK_HEADERS(sys/un.h)
2596
2597 AC_FUNC_MKTIME
2598 if test "$ac_cv_func_working_mktime" = no; then
2599   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2600 fi
2601
2602 AC_FUNC_GETLOADAVG
2603
2604 AC_FUNC_FSEEKO
2605
2606 # Configure getopt.
2607 m4_include([m4/getopt.m4])
2608 gl_GETOPT_IFELSE([
2609   gl_GETOPT_SUBSTITUTE_HEADER
2610   gl_PREREQ_GETOPT
2611   GETOPTOBJS='getopt.o getopt1.o'
2612 ])
2613 AC_SUBST(GETOPTOBJS)
2614
2615 AC_FUNC_GETPGRP
2616
2617 AC_FUNC_STRFTIME
2618
2619 # UNIX98 PTYs.
2620 AC_CHECK_FUNCS(grantpt)
2621
2622 # PTY-related GNU extensions.
2623 AC_CHECK_FUNCS(getpt)
2624
2625 # Check this now, so that we will NOT find the above functions in ncurses.
2626 # That is because we have not set up to link ncurses in lib-src.
2627 # It's better to believe a function is not available
2628 # than to expect to find it in ncurses.
2629 # Also we need tputs and friends to be able to build at all.
2630 have_tputs_et_al=true
2631 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2632 if test "$have_tputs_et_al" != true; then
2633   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2634 Maybe some development libraries/packages are missing?  Try installing
2635 libncurses-dev(el), libterminfo-dev(el) or similar.])
2636 fi
2637 # Must define this when any termcap library is found.
2638 AC_DEFINE(HAVE_LIBNCURSES, 1,
2639           [Define to 1 if you have the `ncurses' library (-lncurses).])
2640 ## FIXME This was the cpp logic, but I am not sure it is right.
2641 ## The above test has not necessarily found libncurses.
2642 HAVE_LIBNCURSES=yes
2643
2644 ## Use terminfo instead of termcap?
2645 ## Note only system files NOT using terminfo are:
2646 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2647 ## darwin|gnu without ncurses.
2648 TERMINFO=no
2649 LIBS_TERMCAP=
2650 case "$opsys" in
2651   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2652   ## hpux10-20: Use the system provided termcap(3) library.
2653   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2654   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2655   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2656
2657   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2658   ##  The ncurses library has been moved out of the System framework in
2659   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2660   ##  option to use it.
2661   darwin|gnu*)
2662     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2663     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2664       TERMINFO=yes
2665       LIBS_TERMCAP="-lncurses"
2666     fi
2667     ;;
2668
2669   freebsd)
2670     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2671     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2672     [AC_TRY_LINK([#include <osreldate.h>],
2673 [#if __FreeBSD_version < 400000
2674 fail;
2675 #endif
2676 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2677
2678     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2679
2680     if test $emacs_cv_freebsd_terminfo = yes; then
2681       TERMINFO=yes
2682       LIBS_TERMCAP="-lncurses"
2683     else
2684       LIBS_TERMCAP="-ltermcap"
2685     fi
2686     ;;
2687
2688   netbsd)
2689     if test $ac_cv_search_tputs = -lterminfo; then
2690       TERMINFO=yes
2691       LIBS_TERMCAP="-lterminfo"
2692     else
2693       LIBS_TERMCAP="-ltermcap"
2694     fi
2695     ;;
2696
2697 esac
2698
2699 case "$opsys" in
2700   ## hpux: Make sure we get select from libc rather than from libcurses
2701   ##  because libcurses on HPUX 10.10 has a broken version of select.
2702   ##  We used to use -lc -lcurses, but this may be cleaner.
2703   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2704
2705   openbsd) LIBS_TERMCAP="-lncurses" ;;
2706
2707   ## Must use system termcap, if we use any termcap.  It does special things.
2708   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2709 esac
2710
2711 TERMCAP_OBJ=tparam.o
2712 if test $TERMINFO = yes; then
2713   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2714
2715   ## Default used to be -ltermcap.  Add a case above if need something else.
2716   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2717
2718   TERMCAP_OBJ=terminfo.o
2719 fi
2720 AC_SUBST(LIBS_TERMCAP)
2721 AC_SUBST(TERMCAP_OBJ)
2722
2723
2724 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2725 resolv=no
2726 AC_TRY_LINK([#include <netinet/in.h>
2727 #include <arpa/nameser.h>
2728 #include <resolv.h>],
2729     [return res_init();],
2730     have_res_init=yes, have_res_init=no)
2731 if test "$have_res_init" = no; then
2732   OLIBS="$LIBS"
2733   LIBS="$LIBS -lresolv"
2734   AC_MSG_CHECKING(for res_init with -lresolv)
2735   AC_TRY_LINK([#include <netinet/in.h>
2736 #include <arpa/nameser.h>
2737 #include <resolv.h>],
2738     [return res_init();],
2739     have_res_init=yes, have_res_init=no)
2740   AC_MSG_RESULT($have_res_init)
2741   if test "$have_res_init" = yes ; then
2742     resolv=yes
2743   fi
2744   LIBS="$OLIBS"
2745 fi
2746
2747 if test "$have_res_init" = yes; then
2748   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2749 fi
2750
2751 # Do we need the Hesiod library to provide the support routines?
2752 LIBHESIOD=
2753 if test "$with_hesiod" != no ; then
2754   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2755   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2756      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2757                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2758   if test "$resolv" = yes ; then
2759     RESOLVLIB=-lresolv
2760   else
2761     RESOLVLIB=
2762   fi
2763   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2764         hesiod=yes, :, $RESOLVLIB)])
2765
2766   if test x"$hesiod" = xyes; then
2767     AC_DEFINE(HAVE_LIBHESIOD, 1,
2768               [Define to 1 if you have the hesiod library (-lhesiod).])
2769     LIBHESIOD=-lhesiod
2770   fi
2771 fi
2772 AC_SUBST(LIBHESIOD)
2773
2774 # Do we need libresolv (due to res_init or Hesiod)?
2775 if test "$resolv" = yes ; then
2776   AC_DEFINE(HAVE_LIBRESOLV, 1,
2777             [Define to 1 if you have the resolv library (-lresolv).])
2778   LIBRESOLV=-lresolv
2779 else
2780   LIBRESOLV=
2781 fi
2782 AC_SUBST(LIBRESOLV)
2783
2784 # These tell us which Kerberos-related libraries to use.
2785 COM_ERRLIB=
2786 CRYPTOLIB=
2787 KRB5LIB=
2788 DESLIB=
2789 KRB4LIB=
2790
2791 if test "${with_kerberos}" != no; then
2792   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2793   if test $have_com_err = yes; then
2794     COM_ERRLIB=-lcom_err
2795     LIBS="$COM_ERRLIB $LIBS"
2796     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2797   fi
2798   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2799   if test $have_crypto = yes; then
2800     CRYPTOLIB=-lcrypto
2801     LIBS="$CRYPTOLIB $LIBS"
2802     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2803   fi
2804   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2805   if test $have_k5crypto = yes; then
2806     CRYPTOLIB=-lk5crypto
2807     LIBS="$CRYPTOLIB $LIBS"
2808     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2809   fi
2810   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2811   if test $have_krb5=yes; then
2812     KRB5LIB=-lkrb5
2813     LIBS="$KRB5LIB $LIBS"
2814     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2815   fi
2816   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2817   if test "${with_kerberos5}" = no; then
2818     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2819     if test $have_des425 = yes; then
2820       DESLIB=-ldes425
2821       LIBS="$DESLIB $LIBS"
2822       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2823     else
2824       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2825       if test $have_des = yes; then
2826         DESLIB=-ldes
2827         LIBS="$DESLIB $LIBS"
2828         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2829       fi
2830     fi
2831     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2832     if test $have_krb4 = yes; then
2833       KRB4LIB=-lkrb4
2834       LIBS="$KRB4LIB $LIBS"
2835       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2836     else
2837       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2838       if test $have_krb = yes; then
2839         KRB4LIB=-lkrb
2840         LIBS="$KRB4LIB $LIBS"
2841         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2842       fi
2843     fi
2844   fi
2845
2846   if test "${with_kerberos5}" != no; then
2847     AC_CHECK_HEADERS(krb5.h,
2848       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2849                         [#include <krb5.h>])])
2850   else
2851     AC_CHECK_HEADERS(des.h,,
2852                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2853                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2854     AC_CHECK_HEADERS(krb.h,,
2855                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2856                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2857   fi
2858   AC_CHECK_HEADERS(com_err.h)
2859 fi
2860
2861 AC_SUBST(COM_ERRLIB)
2862 AC_SUBST(CRYPTOLIB)
2863 AC_SUBST(KRB5LIB)
2864 AC_SUBST(DESLIB)
2865 AC_SUBST(KRB4LIB)
2866
2867 # Solaris requires -lintl if you want strerror (which calls dgettext)
2868 # to return localized messages.
2869 AC_CHECK_LIB(intl, dgettext)
2870
2871 AC_MSG_CHECKING(whether localtime caches TZ)
2872 AC_CACHE_VAL(emacs_cv_localtime_cache,
2873 [if test x$ac_cv_func_tzset = xyes; then
2874 AC_TRY_RUN([#include <time.h>
2875 extern char **environ;
2876 unset_TZ ()
2877 {
2878   char **from, **to;
2879   for (to = from = environ; (*to = *from); from++)
2880     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2881       to++;
2882 }
2883 char TZ_GMT0[] = "TZ=GMT0";
2884 char TZ_PST8[] = "TZ=PST8";
2885 main()
2886 {
2887   time_t now = time ((time_t *) 0);
2888   int hour_GMT0, hour_unset;
2889   if (putenv (TZ_GMT0) != 0)
2890     exit (1);
2891   hour_GMT0 = localtime (&now)->tm_hour;
2892   unset_TZ ();
2893   hour_unset = localtime (&now)->tm_hour;
2894   if (putenv (TZ_PST8) != 0)
2895     exit (1);
2896   if (localtime (&now)->tm_hour == hour_GMT0)
2897     exit (1);
2898   unset_TZ ();
2899   if (localtime (&now)->tm_hour != hour_unset)
2900     exit (1);
2901   exit (0);
2902 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2903 [# If we have tzset, assume the worst when cross-compiling.
2904 emacs_cv_localtime_cache=yes])
2905 else
2906         # If we lack tzset, report that localtime does not cache TZ,
2907         # since we can't invalidate the cache if we don't have tzset.
2908         emacs_cv_localtime_cache=no
2909 fi])dnl
2910 AC_MSG_RESULT($emacs_cv_localtime_cache)
2911 if test $emacs_cv_localtime_cache = yes; then
2912   AC_DEFINE(LOCALTIME_CACHE, 1,
2913             [Define to 1 if localtime caches TZ.])
2914 fi
2915
2916 if test "x$HAVE_TIMEVAL" = xyes; then
2917   AC_CHECK_FUNCS(gettimeofday)
2918   if test $ac_cv_func_gettimeofday = yes; then
2919     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2920                    emacs_cv_gettimeofday_two_arguments,
2921     [AC_TRY_COMPILE([
2922 #ifdef TIME_WITH_SYS_TIME
2923 #include <sys/time.h>
2924 #include <time.h>
2925 #else
2926 #ifdef HAVE_SYS_TIME_H
2927 #include <sys/time.h>
2928 #else
2929 #include <time.h>
2930 #endif
2931 #endif],
2932       [struct timeval time;
2933        gettimeofday (&time, 0);],
2934       emacs_cv_gettimeofday_two_arguments=yes,
2935       emacs_cv_gettimeofday_two_arguments=no)])
2936     if test $emacs_cv_gettimeofday_two_arguments = no; then
2937       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2938                 [Define to 1 if gettimeofday accepts only one argument.])
2939     fi
2940   fi
2941 fi
2942
2943 ok_so_far=yes
2944 AC_CHECK_FUNC(socket, , ok_so_far=no)
2945 if test $ok_so_far = yes; then
2946   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2947 fi
2948 if test $ok_so_far = yes; then
2949   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2950 fi
2951 if test $ok_so_far = yes; then
2952 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2953   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2954             [Define to 1 if you have inet sockets.])
2955 fi
2956
2957 AC_CHECK_HEADERS(sys/ioctl.h)
2958
2959 if test -f /usr/lpp/X11/bin/smt.exp; then
2960   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2961             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2962 fi
2963
2964 AC_MSG_CHECKING(whether system supports dynamic ptys)
2965 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2966   AC_MSG_RESULT(yes)
2967   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2968 else
2969   AC_MSG_RESULT(no)
2970 fi
2971
2972 AC_FUNC_FORK
2973
2974 dnl Adapted from Haible's version.
2975 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2976   [AC_TRY_LINK([#include <langinfo.h>],
2977     [char* cs = nl_langinfo(CODESET);],
2978     emacs_cv_langinfo_codeset=yes,
2979     emacs_cv_langinfo_codeset=no)
2980   ])
2981 if test $emacs_cv_langinfo_codeset = yes; then
2982   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2983     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2984 fi
2985
2986 AC_CHECK_TYPES(size_t)
2987
2988 AC_TYPE_MBSTATE_T
2989
2990 dnl Restrict could probably be used effectively other than in regex.c.
2991 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2992   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2993                   emacs_cv_c_restrict=yes,
2994                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2995                                   emacs_cv_c_restrict=__restrict,
2996                                   emacs_cv_c_restrict=no)])])
2997 case "$emacs_cv_c_restrict" in
2998   yes) emacs_restrict=restrict;;
2999   no) emacs_restrict="";;
3000   *) emacs_restrict="$emacs_cv_c_restrict";;
3001 esac
3002 if test "$emacs_restrict" != __restrict; then
3003   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3004     [Define to compiler's equivalent of C99 restrict keyword.
3005      Don't define if equivalent is `__restrict'.])
3006 fi
3007
3008 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3009   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3010                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3011 if test "$emacs_cv_c_restrict_arr" = yes; then
3012   AC_DEFINE(__restrict_arr, __restrict,
3013     [Define to compiler's equivalent of C99 restrict keyword in array
3014      declarations.  Define as empty for no equivalent.])
3015 fi
3016
3017 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3018 dnl how the tty code is related to POSIX and/or other versions of termios.
3019 dnl The following looks like a useful start.
3020 dnl
3021 dnl AC_SYS_POSIX_TERMIOS
3022 dnl if test $ac_cv_sys_posix_termios = yes; then
3023 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3024 dnl                                and macros for terminal control.])
3025 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3026 dnl fi
3027
3028 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3029
3030 # Set up the CFLAGS for real compilation, so we can substitute it.
3031 CFLAGS="$REAL_CFLAGS"
3032 CPPFLAGS="$REAL_CPPFLAGS"
3033
3034 ## Hack to detect a buggy GCC version.
3035 if test "x$GCC" = xyes \
3036    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3037    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3038    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3039    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3040 fi
3041
3042 #### Find out which version of Emacs this is.
3043 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3044          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3045 if test x"${version}" = x; then
3046   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3047 fi
3048 if test x"${version}" != x"$PACKAGE_VERSION"; then
3049   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3050 fi
3051
3052 ### Specify what sort of things we'll be editing into Makefile and config.h.
3053 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3054 AC_SUBST(version)
3055 AC_SUBST(configuration)
3056 ## Unused?
3057 AC_SUBST(canonical)
3058 AC_SUBST(srcdir)
3059 AC_SUBST(prefix)
3060 AC_SUBST(exec_prefix)
3061 AC_SUBST(bindir)
3062 AC_SUBST(datadir)
3063 AC_SUBST(sharedstatedir)
3064 AC_SUBST(libexecdir)
3065 AC_SUBST(mandir)
3066 AC_SUBST(infodir)
3067 AC_SUBST(lispdir)
3068 AC_SUBST(locallisppath)
3069 AC_SUBST(lisppath)
3070 AC_SUBST(x_default_search_path)
3071 AC_SUBST(etcdir)
3072 AC_SUBST(archlibdir)
3073 AC_SUBST(docdir)
3074 AC_SUBST(bitmapdir)
3075 AC_SUBST(gamedir)
3076 AC_SUBST(gameuser)
3077 AC_SUBST(unexec)
3078 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3079 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3080 ## end of LIBX_BASE, but nothing ever set it.
3081 AC_SUBST(LD_SWITCH_X_SITE)
3082 AC_SUBST(C_SWITCH_X_SITE)
3083 AC_SUBST(C_SWITCH_X_SYSTEM)
3084 AC_SUBST(CFLAGS)
3085 ## Used in lwlib/Makefile.in.
3086 AC_SUBST(X_TOOLKIT_TYPE)
3087 AC_SUBST(machfile)
3088 AC_SUBST(opsysfile)
3089 AC_SUBST(GETLOADAVG_LIBS)
3090 AC_SUBST(ns_appdir)
3091 AC_SUBST(ns_appbindir)
3092 AC_SUBST(ns_appresdir)
3093 AC_SUBST(ns_appsrc)
3094 AC_SUBST(GNU_OBJC_CFLAGS)
3095 AC_SUBST(OTHER_FILES)
3096
3097 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3098                    [Define to the canonical Emacs configuration name.])
3099 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3100                    [Define to the options passed to configure.])
3101 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3102                    [Define to the used machine dependent file.])
3103 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3104                    [Define to the used os dependent file.])
3105
3106 XMENU_OBJ=
3107 XOBJ=
3108 FONT_OBJ=
3109 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3110   AC_DEFINE(HAVE_X_WINDOWS, 1,
3111             [Define to 1 if you want to use the X window system.])
3112   XMENU_OBJ=xmenu.o
3113   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3114   FONT_OBJ=xfont.o
3115   if test "$HAVE_XFT" = "yes"; then
3116     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3117   elif test "$HAVE_FREETYPE" = "yes"; then
3118     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3119   fi
3120   AC_SUBST(FONT_OBJ)
3121 fi
3122 AC_SUBST(XMENU_OBJ)
3123 AC_SUBST(XOBJ)
3124 AC_SUBST(FONT_OBJ)
3125
3126 WIDGET_OBJ=
3127 MOTIF_LIBW=
3128 if test "${USE_X_TOOLKIT}" != "none" ; then
3129   WIDGET_OBJ=widget.o
3130   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3131   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3132     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3133   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3134     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3135     MOTIF_LIBW=-lXm
3136     case "$opsys" in
3137       gnu-linux)
3138         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3139         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3140         ;;
3141
3142       unixware)
3143         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3144         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3145         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3146         ;;
3147
3148       aix4-2)
3149         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3150         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3151         ;;
3152     esac
3153     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3154   fi
3155 fi
3156 AC_SUBST(WIDGET_OBJ)
3157
3158 TOOLKIT_LIBW=
3159 case "$USE_X_TOOLKIT" in
3160   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3161   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3162   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3163 esac
3164 AC_SUBST(TOOLKIT_LIBW)
3165
3166 if test "$USE_X_TOOLKIT" = "none"; then
3167   LIBXT_OTHER="\$(LIBXSM)"
3168   OLDXMENU_TARGET="really-oldXMenu"
3169 else
3170   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3171   OLDXMENU_TARGET="really-lwlib"
3172 fi
3173 AC_SUBST(LIBXT_OTHER)
3174 AC_SUBST(OLDXMENU_TARGET)
3175
3176 ## The X Menu stuff is present in the X10 distribution, but missing
3177 ## from X11.  If we have X10, just use the installed library;
3178 ## otherwise, use our own copy.
3179 if test "${HAVE_X11}" = "yes" ; then
3180   AC_DEFINE(HAVE_X11, 1,
3181             [Define to 1 if you want to use version 11 of X windows.
3182              Otherwise, Emacs expects to use version 10.])
3183
3184   if test "$USE_X_TOOLKIT" = "none"; then
3185     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3186   else
3187     OLDXMENU="\${lwlibdir}liblw.a"
3188   fi
3189   LIBXMENU="\$(OLDXMENU)"
3190   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3191   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3192 else
3193   OLDXMENU=
3194   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3195   if test "${HAVE_X_WINDOWS}" = "yes"; then
3196     LIBXMENU="-lXMenu"
3197   else
3198     LIBXMENU=
3199   fi
3200   LIBX_OTHER=
3201   OLDXMENU_DEPS=
3202 fi
3203
3204 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3205   OLDXMENU=
3206   LIBXMENU=
3207   OLDXMENU_DEPS=
3208 fi
3209
3210 AC_SUBST(OLDXMENU)
3211 AC_SUBST(LIBXMENU)
3212 AC_SUBST(LIBX_OTHER)
3213 AC_SUBST(OLDXMENU_DEPS)
3214
3215 if test "${HAVE_MENUS}" = "yes" ; then
3216   AC_DEFINE(HAVE_MENUS, 1,
3217             [Define to 1 if you have mouse menus.
3218              (This is automatic if you use X, but the option to specify it remains.)
3219              It is also defined with other window systems that support xmenu.c.])
3220 fi
3221
3222 if test "${GNU_MALLOC}" = "yes" ; then
3223   AC_DEFINE(GNU_MALLOC, 1,
3224             [Define to 1 if you want to use the GNU memory allocator.])
3225 fi
3226
3227 RALLOC_OBJ=
3228 if test "${REL_ALLOC}" = "yes" ; then
3229   AC_DEFINE(REL_ALLOC, 1,
3230             [Define REL_ALLOC if you want to use the relocating allocator for
3231              buffer space.])
3232
3233   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3234 fi
3235 AC_SUBST(RALLOC_OBJ)
3236
3237 if test "$opsys" = "cygwin"; then
3238   CYGWIN_OBJ="sheap.o"
3239   ## Cygwin differs because of its unexec().
3240   PRE_ALLOC_OBJ=
3241   POST_ALLOC_OBJ=lastfile.o
3242 else
3243   CYGWIN_OBJ=
3244   PRE_ALLOC_OBJ=lastfile.o
3245   POST_ALLOC_OBJ=
3246 fi
3247 AC_SUBST(CYGWIN_OBJ)
3248 AC_SUBST(PRE_ALLOC_OBJ)
3249 AC_SUBST(POST_ALLOC_OBJ)
3250
3251
3252 case "$opsys" in
3253   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3254
3255   darwin)
3256   ## The -headerpad option tells ld (see man page) to leave room at the
3257   ## end of the header for adding load commands.  Needed for dumping.
3258   ## 0x690 is the total size of 30 segment load commands (at 56
3259   ## each); under Cocoa 31 commands are required.
3260   if test "$HAVE_NS" = "yes"; then
3261     libs_nsgui="-framework AppKit"
3262     headerpad_extra=6C8
3263   else
3264     libs_nsgui=
3265     headerpad_extra=690
3266   fi
3267   LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3268   ;;
3269
3270   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3271 esac
3272 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3273
3274
3275 ## This exists because src/Makefile.in did some extra fiddling around
3276 ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3277 ##   #ifndef LD_SWITCH_SYSTEM
3278 ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3279 ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3280 ## not using gcc, darwin system not on an alpha (ie darwin, since
3281 ## darwin + alpha does not occur).
3282 ## Note that unlike L_S_S, this is not used in ac_link.
3283 if test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3284    test "$opsys" = "darwin"; then
3285   LD_SWITCH_SYSTEM_EXTRA="-X"
3286 else
3287   LD_SWITCH_SYSTEM_EXTRA=
3288 fi
3289 AC_SUBST(LD_SWITCH_SYSTEM_EXTRA)
3290
3291
3292 LINKER=
3293 ORDINARY_LINK=
3294 case "$opsys" in
3295   ## gnu: GNU needs its own crt0.
3296   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3297
3298   cygwin) LINKER="\$(CC)" ;;
3299
3300   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3301   ## library search parth, i.e. it won't search /usr/lib for libc and
3302   ## friends.  Using -nostartfiles instead avoids this problem, and
3303   ## will also work on earlier NetBSD releases.
3304   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3305
3306   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3307   ##   MkLinux/LinuxPPC needs this.
3308   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3309   gnu-*)
3310     case "$machine" in
3311       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3312     esac
3313     ;;
3314 esac
3315
3316 ## A macro which other sections of Makefile can redefine to munge the
3317 ## flags before they are passed to LD.  This is helpful if you have
3318 ## redefined LD to something odd, like "gcc".
3319 ## (The YMF prefix is a holdover from the old name "ymakefile".)
3320 YMF_PASS_LDFLAGS=flags
3321 if test "x$ORDINARY_LINK" = "xyes"; then
3322
3323   LINKER="\$(CC)"
3324   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3325
3326 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3327 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3328 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3329
3330   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3331   ## places that are difficult to figure out at make time.  Fortunately,
3332   ## these same versions allow you to pass arbitrary flags on to the
3333   ## linker, so there is no reason not to use it as a linker.
3334   ##
3335   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3336   ## searching for libraries in its internal directories, so we have to
3337   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3338   LINKER="\$(CC) -nostdlib"
3339   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3340   ## See prefix-args.c for an explanation of why we do not do this with the
3341   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3342   ## their paths, so we must use ./prefix-args.
3343   ## TODO either make prefix-args check ORDINARY_LINK internally,
3344   ## or remove it altogether (bug#6184), removing the need for this macro.
3345   YMF_PASS_LDFLAGS='`./prefix-args -Xlinker flags`'
3346 fi
3347 AC_SUBST(YMF_PASS_LDFLAGS)
3348
3349 test "x$LINKER" = "x" && LINKER=ld
3350 ## FIXME? What setting of YMF_PASS_LDFLAGS should this have?
3351 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3352
3353 AC_SUBST(LINKER)
3354
3355
3356 ## FIXME? The logic here is not precisely the same as that above
3357 ## setting YMF_PASS_LDFLAGS.  There is no check here for a pre-defined
3358 ## LINKER.  Should we only be setting LIB_GCC if LD ~ -nostdlib?
3359 LIB_GCC=
3360 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3361
3362   case "$opsys" in
3363     ## cygwin: don't link against static libgcc.
3364     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3365
3366     gnu-*)
3367       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3368       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3369       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3370       if test "$machine" = "arm"; then
3371         LIB_GCC="-lgcc_s"
3372       else
3373         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3374         ## immediately undefine it again and redefine it to empty.
3375         ## Was the C_SWITCH_X_SITE part really necessary?
3376 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3377         LIB_GCC=
3378       fi
3379       ;;
3380
3381     ## Ask GCC where to find libgcc.a.
3382     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3383   esac
3384 fi                              dnl if $GCC
3385 AC_SUBST(LIB_GCC)
3386
3387
3388 TOOLTIP_SUPPORT=
3389 WINDOW_SUPPORT=
3390 ## If we're using X11/GNUstep, define some consequences.
3391 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3392   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3393   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3394   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3395   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3396
3397   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3398   test "$HAVE_X_WINDOWS" = "yes" && \
3399     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3400
3401 fi
3402 AC_SUBST(MOUSE_SUPPORT)
3403 AC_SUBST(TOOLTIP_SUPPORT)
3404 AC_SUBST(WINDOW_SUPPORT)
3405
3406
3407 AH_TOP([/* GNU Emacs site configuration template file.
3408    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3409      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3410
3411 This file is part of GNU Emacs.
3412
3413 GNU Emacs is free software: you can redistribute it and/or modify
3414 it under the terms of the GNU General Public License as published by
3415 the Free Software Foundation, either version 3 of the License, or
3416 (at your option) any later version.
3417
3418 GNU Emacs is distributed in the hope that it will be useful,
3419 but WITHOUT ANY WARRANTY; without even the implied warranty of
3420 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3421 GNU General Public License for more details.
3422
3423 You should have received a copy of the GNU General Public License
3424 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3425
3426
3427 /* No code in Emacs #includes config.h twice, but some bits of code
3428    intended to work with other packages as well (like gmalloc.c)
3429    think they can include it as many times as they like.  */
3430 #ifndef EMACS_CONFIG_H
3431 #define EMACS_CONFIG_H
3432 ])dnl
3433
3434 AH_BOTTOM([
3435 /* Define AMPERSAND_FULL_NAME if you use the convention
3436    that & in the full name stands for the login id.  */
3437 /* Turned on June 1996 supposing nobody will mind it.  */
3438 #define AMPERSAND_FULL_NAME
3439
3440 /* Define HAVE_SOUND if we have sound support.  We know it works
3441    and compiles only on the specified platforms.   For others,
3442    it probably doesn't make sense to try.  */
3443
3444 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3445 #ifdef HAVE_MACHINE_SOUNDCARD_H
3446 #define HAVE_SOUND 1
3447 #endif
3448 #ifdef HAVE_SYS_SOUNDCARD_H
3449 #define HAVE_SOUND 1
3450 #endif
3451 #ifdef HAVE_SOUNDCARD_H
3452 #define HAVE_SOUND 1
3453 #endif
3454 #ifdef HAVE_ALSA
3455 #define HAVE_SOUND 1
3456 #endif
3457 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3458
3459 /* If using GNU, then support inline function declarations.  */
3460 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3461    generally, because even if non-gcc compilers accept `inline', they
3462    may reject `extern inline'.  */
3463 #if defined (__GNUC__) && defined (OPTIMIZE)
3464 #define INLINE __inline__
3465 #else
3466 #define INLINE
3467 #endif
3468
3469 /* `subprocesses' should be defined if you want to
3470    have code for asynchronous subprocesses
3471    (as used in M-x compile and M-x shell).
3472    Only MSDOS does not support this (it overrides
3473    this in its config_opsysfile below).  */
3474
3475 #define subprocesses
3476
3477 /* Include the os and machine dependent files.  */
3478 #include config_opsysfile
3479 #include config_machfile
3480
3481 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3482   (There is probably a better place to do this, but right now the Cocoa
3483    side does this in s/darwin.h and we cannot
3484    parallel this exactly since GNUstep is multi-OS.  */
3485 #ifdef HAVE_NS
3486 # ifdef NS_IMPL_GNUSTEP
3487 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3488 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3489 #  define SYSTEM_PURESIZE_EXTRA 30000
3490 # endif /* NS_IMPL_GNUSTEP */
3491 #endif /* HAVE_NS */
3492
3493 /* SIGTYPE is the macro we actually use.  */
3494 #ifndef SIGTYPE
3495 #define SIGTYPE RETSIGTYPE
3496 #endif
3497
3498 #ifdef emacs /* Don't do this for lib-src.  */
3499 /* Tell regex.c to use a type compatible with Emacs.  */
3500 #define RE_TRANSLATE_TYPE Lisp_Object
3501 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3502 #ifdef make_number
3503 /* If make_number is a macro, use it.  */
3504 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3505 #else
3506 /* If make_number is a function, avoid it.  */
3507 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3508 #endif
3509 #endif
3510
3511 /* Avoid link-time collision with system mktime if we will use our own.  */
3512 #if ! HAVE_MKTIME || BROKEN_MKTIME
3513 #define mktime emacs_mktime
3514 #endif
3515
3516 #define my_strftime nstrftime   /* for strftime.c */
3517
3518 /* The rest of the code currently tests the CPP symbol BSTRING.
3519    Override any claims made by the system-description files.
3520    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3521 #undef BSTRING
3522 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3523 #define BSTRING
3524 #endif
3525
3526 /* Some of the files of Emacs which are intended for use with other
3527    programs assume that if you have a config.h file, you must declare
3528    the type of getenv.
3529
3530    This declaration shouldn't appear when alloca.s or Makefile.in
3531    includes config.h.  */
3532 #ifndef NOT_C_CODE
3533 extern char *getenv ();
3534 #endif
3535
3536 /* These default definitions are good for almost all machines.
3537    The exceptions override them in m/MACHINE.h.  */
3538
3539 #ifndef BITS_PER_CHAR
3540 #define BITS_PER_CHAR 8
3541 #endif
3542
3543 #ifndef BITS_PER_SHORT
3544 #define BITS_PER_SHORT 16
3545 #endif
3546
3547 /* Note that lisp.h uses this in a preprocessor conditional, so it
3548    would not work to use sizeof.  That being so, we do all of them
3549    without sizeof, for uniformity's sake.  */
3550 #ifndef BITS_PER_INT
3551 #define BITS_PER_INT 32
3552 #endif
3553
3554 #ifndef BITS_PER_LONG
3555 #ifdef _LP64
3556 #define BITS_PER_LONG 64
3557 #else
3558 #define BITS_PER_LONG 32
3559 #endif
3560 #endif
3561
3562 /* Define if the compiler supports function prototypes.  It may do so
3563    but not define __STDC__ (e.g. DEC C by default) or may define it as
3564    zero.  */
3565 #undef PROTOTYPES
3566 /* For mktime.c:  */
3567 #ifndef __P
3568 # if defined PROTOTYPES
3569 #  define __P(args) args
3570 # else
3571 #  define __P(args) ()
3572 # endif  /* GCC.  */
3573 #endif /* __P */
3574
3575 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3576 #ifndef NOT_C_CODE
3577 #ifdef HAVE_STRING_H
3578 #include "string.h"
3579 #endif
3580 #ifdef HAVE_STRINGS_H
3581 #include "strings.h"  /* May be needed for bcopy & al.  */
3582 #endif
3583 #ifdef HAVE_STDLIB_H
3584 #include <stdlib.h>
3585 #endif
3586 #ifndef __GNUC__
3587 # ifdef HAVE_ALLOCA_H
3588 #  include <alloca.h>
3589 # else /* AIX files deal with #pragma.  */
3590 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3591 char *alloca ();
3592 #  endif
3593 # endif /* HAVE_ALLOCA_H */
3594 #endif /* __GNUC__ */
3595 #ifndef HAVE_SIZE_T
3596 typedef unsigned size_t;
3597 #endif
3598 #endif /* NOT_C_CODE */
3599
3600 /* Define HAVE_X_I18N if we have usable i18n support.  */
3601
3602 #ifdef HAVE_X11R6
3603 #define HAVE_X_I18N
3604 #endif
3605
3606 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3607
3608 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3609 #define HAVE_X11R6_XIM
3610 #endif
3611
3612 #if defined __GNUC__ && (__GNUC__ > 2 \
3613                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3614 #define NO_RETURN       __attribute__ ((__noreturn__))
3615 #else
3616 #define NO_RETURN       /* nothing */
3617 #endif
3618
3619 /* These won't be used automatically yet.  We also need to know, at least,
3620    that the stack is continuous.  */
3621 #ifdef __GNUC__
3622 #  ifndef GC_SETJMP_WORKS
3623   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3624 #    define GC_SETJMP_WORKS 1
3625 #  endif
3626 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3627 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3628 #  endif
3629 #endif
3630
3631 #ifndef HAVE_BCOPY
3632 #define bcopy(a,b,s) memcpy (b,a,s)
3633 #endif
3634 #ifndef HAVE_BZERO
3635 #define bzero(a,s) memset (a,0,s)
3636 #endif
3637 #ifndef HAVE_BCMP
3638 #define BCMP memcmp
3639 #endif
3640
3641 #endif /* EMACS_CONFIG_H */
3642
3643 /*
3644 Local Variables:
3645 mode: c
3646 End:
3647 */
3648 ])dnl
3649
3650 #### Report on what we decided to do.
3651 #### Report GTK as a toolkit, even if it doesn't use Xt.
3652 #### It makes printing result more understandable as using GTK sets
3653 #### toolkit_scroll_bars to yes by default.
3654 if test "${HAVE_GTK}" = "yes"; then
3655   USE_X_TOOLKIT=GTK
3656 fi
3657
3658 echo "
3659 Configured for \`${canonical}'.
3660
3661   Where should the build process find the source code?    ${srcdir}
3662   What operating system and machine description files should Emacs use?
3663         \`${opsysfile}' and \`${machfile}'
3664   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3665   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3666   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3667   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3668   What window system should Emacs use?                    ${window_system}
3669   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3670
3671 if test -n "${x_includes}"; then
3672 echo "  Where do we find X Windows header files?                ${x_includes}"
3673 else
3674 echo "  Where do we find X Windows header files?                Standard dirs"
3675 fi
3676 if test -n "${x_libraries}"; then
3677 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3678 else
3679 echo "  Where do we find X Windows libraries?                   Standard dirs"
3680 fi
3681
3682 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3683 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3684 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3685 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3686 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3687 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3688 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3689 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3690 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3691 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3692 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3693
3694 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3695 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3696 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3697 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3698
3699 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3700 echo
3701
3702 if test $USE_XASSERTS = yes; then
3703    echo "  Compiling with asserts turned on."
3704    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3705 fi
3706
3707 echo
3708
3709 if test "$HAVE_NS" = "yes"; then
3710    echo
3711    echo "You must run \"make install\" in order to test the built application.
3712 The installed application will go to nextstep/Emacs.app and can be
3713 run or moved from there."
3714    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3715       echo "The application will be fully self-contained."
3716     else
3717       echo "The lisp resources for the application will be installed under ${prefix}.
3718 You may need to run \"make install\" with sudo.  The application will fail
3719 to run if these resources are not installed."
3720    fi
3721    echo
3722 fi
3723
3724 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3725   echo "D-Bus integration has been tested for GNU/Linux only."
3726   echo
3727 fi
3728
3729
3730 # Remove any trailing slashes in these variables.
3731 [test "${prefix}" != NONE &&
3732   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3733 test "${exec_prefix}" != NONE &&
3734   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3735
3736 # Now get this: Some word that is part of the ${srcdir} directory name
3737 # or the ${configuration} value might, just might, happen to be an
3738 # identifier like `sun4' or `i386' or something, and be predefined by
3739 # the C preprocessor to some helpful value like 1, or maybe the empty
3740 # string.  Needless to say consequent macro substitutions are less
3741 # than conducive to the makefile finding the correct directory.
3742 # src/Makefile.in used to treat X11 as equivalent to HAVE_X11.
3743 # But nothing in Emacs defines X11, and everywhere else uses HAVE_X11,
3744 # so that cannot have been doing anything.
3745 [cpp_undefs="`echo $srcdir $configuration $canonical unix mktime register X11 |
3746   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3747   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3748
3749 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3750 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3751 ## from Makefile.c can correctly provide the arg `-traditional' to the
3752 ## C preprocessor.
3753
3754 AC_EGREP_CPP(yes..yes,
3755         [yes..yes],
3756         CPP_NEED_TRADITIONAL=no,
3757         CPP_NEED_TRADITIONAL=yes)
3758
3759 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3760         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3761         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3762         lwlib/Makefile lisp/Makefile leim/Makefile, [
3763
3764 ### Make the necessary directories, if they don't exist.
3765 for dir in etc lisp ; do
3766   test -d ${dir} || mkdir ${dir}
3767 done
3768
3769 # Build src/Makefile from ${srcdir}/src/Makefile.c
3770 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3771 # This must be done after src/config.h is built, since we rely on that file.
3772
3773 echo creating src/epaths.h
3774 ${MAKE-make} epaths-force
3775
3776 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3777 # `..' to `. .'  unless invoked with -traditional
3778
3779 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3780   CPPFLAGS="$CPPFLAGS -traditional"
3781 fi
3782
3783 echo creating src/Makefile
3784 ( cd src
3785   rm -f junk.c junk1.c junk2.c
3786   sed -e '/start of cpp stuff/q' \
3787       < Makefile.c > junk1.c
3788   sed -e '1,/start of cpp stuff/d'\
3789       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3790       < Makefile.c > junk.c
3791   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3792       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3793   cat junk1.c junk2.c > Makefile.new
3794   rm -f junk.c junk1.c junk2.c
3795   chmod 444 Makefile.new
3796   mv -f Makefile.new Makefile
3797 )
3798
3799 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3800   echo creating src/.gdbinit
3801   echo source $srcdir/src/.gdbinit > src/.gdbinit
3802 fi
3803
3804 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3805
3806 m4_if(dnl       Do not change this comment
3807    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3808 )dnl