lisp/textmodes/page.el

   1 ;;; page.el --- page motion commands for Emacs
   2
   3 ;; Copyright (C) 1985, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: wp convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This code provides the page-oriented movement and selection commands
  27 ;; documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defun forward-page (&optional count)
  32   "Move forward to page boundary.  With arg, repeat, or go back if negative.
  33 A page boundary is any line whose beginning matches the regexp
  34 `page-delimiter'."
  35   (interactive "p")
  36   (or count (setq count 1))
  37   (while (and (> count 0) (not (eobp)))
  38     ;; In case the page-delimiter matches the null string,
  39     ;; don't find a match without moving.
  40     (if (bolp) (forward-char 1))
  41     (if (re-search-forward page-delimiter nil t)
  42         nil
  43       (goto-char (point-max)))
  44     (setq count (1- count)))
  45   (while (and (< count 0) (not (bobp)))
  46     ;; In case the page-delimiter matches the null string,
  47     ;; don't find a match without moving.
  48     (and (save-excursion (re-search-backward page-delimiter nil t))
  49          (= (match-end 0) (point))
  50          (goto-char (match-beginning 0)))
  51     (forward-char -1)
  52     (if (re-search-backward page-delimiter nil t)
  53         ;; We found one--move to the end of it.
  54         (goto-char (match-end 0))
  55       ;; We found nothing--go to beg of buffer.
  56       (goto-char (point-min)))
  57     (setq count (1+ count))))
  58
  59 (defun backward-page (&optional count)
  60   "Move backward to page boundary.  With arg, repeat, or go fwd if negative.
  61 A page boundary is any line whose beginning matches the regexp
  62 `page-delimiter'."
  63   (interactive "p")
  64   (or count (setq count 1))
  65   (forward-page (- count)))
  66
  67 (defun mark-page (&optional arg)
  68   "Put mark at end of page, point at beginning.
  69 A numeric arg specifies to move forward or backward by that many pages,
  70 thus marking a page other than the one point was originally in."
  71   (interactive "P")
  72   (setq arg (if arg (prefix-numeric-value arg) 0))
  73   (if (> arg 0)
  74       (forward-page arg)
  75     (if (< arg 0)
  76         (forward-page (1- arg))))
  77   (forward-page)
  78   (push-mark nil t t)
  79   (forward-page -1))
  80
  81 (defun narrow-to-page (&optional arg)
  82   "Make text outside current page invisible.
  83 A numeric arg specifies to move forward or backward by that many pages,
  84 thus showing a page other than the one point was originally in."
  85   (interactive "P")
  86   (setq arg (if arg (prefix-numeric-value arg) 0))
  87   (save-excursion
  88     (widen)
  89     (if (> arg 0)
  90         (forward-page arg)
  91       (if (< arg 0)
  92           (let ((adjust 0)
  93                 (opoint (point)))
  94             ;; If we are not now at the beginning of a page,
  95             ;; move back one extra time, to get to the start of this page.
  96             (save-excursion
  97               (beginning-of-line)
  98               (or (and (looking-at page-delimiter)
  99                        (eq (match-end 0) opoint))
 100                   (setq adjust 1)))
 101             (forward-page (- arg adjust)))))
 102     ;; Find the end of the page.
 103     (set-match-data nil)
 104     (forward-page)
 105     ;; If we stopped due to end of buffer, stay there.
 106     ;; If we stopped after a page delimiter, put end of restriction
 107     ;; at the beginning of that line.
 108     ;; Before checking the match that was found,
 109     ;; verify that forward-page actually set the match data.
 110     (if (and (match-beginning 0)
 111              (save-excursion
 112                (goto-char (match-beginning 0)) ; was (beginning-of-line)
 113                (looking-at page-delimiter)))
 114         (goto-char (match-beginning 0))) ; was (beginning-of-line)
 115     (narrow-to-region (point)
 116                       (progn
 117                         ;; Find the top of the page.
 118                         (forward-page -1)
 119                         ;; If we found beginning of buffer, stay there.
 120                         ;; If extra text follows page delimiter on same line,
 121                         ;; include it.
 122                         ;; Otherwise, show text starting with following line.
 123                         (if (and (eolp) (not (bobp)))
 124                             (forward-line 1))
 125                         (point)))))
 126 (put 'narrow-to-page 'disabled t)
 127
 128 (defun count-lines-page ()
 129   "Report number of lines on current page, and how many are before or after point."
 130   (interactive)
 131   (save-excursion
 132     (let ((opoint (point)) beg end
 133           total before after)
 134       (forward-page)
 135       (beginning-of-line)
 136       (or (looking-at page-delimiter)
 137           (end-of-line))
 138       (setq end (point))
 139       (backward-page)
 140       (setq beg (point))
 141       (setq total (count-lines beg end)
 142             before (count-lines beg opoint)
 143             after (count-lines opoint end))
 144       (message "Page has %d lines (%d + %d)" total before after))))
 145
 146 (defun what-page ()
 147   "Print page and line number of point."
 148   (interactive)
 149   (save-restriction
 150     (widen)
 151     (save-excursion
 152       (beginning-of-line)
 153       (let ((count 1)
 154             (opoint (point)))
 155         (goto-char 1)
 156         (while (re-search-forward page-delimiter opoint t)
 157           (setq count (1+ count)))
 158         (message "Page %d, line %d"
 159                  count
 160                  (1+ (count-lines (point) opoint)))))))
 161 \f
 162 ;;; Place `provide' at end of file.
 163 (provide 'page)
 164
 165 ;; arch-tag: e8d7a0bd-8655-4b6e-b852-f2ee25316a1d
 166 ;;; page.el ends here