configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.0)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h)
   8
   9 bindir='${exec_prefix}/bin'
  10 datadir='${prefix}/share'
  11 sharedstatedir='${prefix}/com'
  12 libexecdir='${exec_prefix}/libexec'
  13 mandir='${prefix}/man/man1'
  14 infodir='${prefix}/info'
  15 lispdir='${datadir}/emacs/${version}/lisp'
  16 locallisppath='${datadir}/emacs/site-lisp'
  17 lisppath='${locallisppath}:${lispdir}'
  18 etcdir='${datadir}/emacs/${version}/etc'
  19 lockdir='${sharedstatedir}/emacs/lock'
  20 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  21 docdir='${datadir}/emacs/${version}/etc'
  22
  23 AC_ARG_WITH(gcc,
  24 [  --with-gcc              use GCC to compile Emacs])
  25 AC_ARG_WITH(pop,
  26 [  --with-pop              support POP for mail retrieval],
  27 [AC_DEFINE(MAIL_USE_POP)])
  28 AC_ARG_WITH(kerberos,
  29 [  --with-kerberos         support Kerberos-authenticated POP],
  30 [AC_DEFINE(KERBEROS)])
  31 AC_ARG_WITH(hesiod,
  32 [  --with-hesiod           support Hesiod to get the POP server host],
  33 [AC_DEFINE(HESIOD)])
  34 dnl This should be the last --with option, because --with-x is
  35 dnl added later on when we find the path of X, and it's best to
  36 dnl keep them together visually.
  37 AC_ARG_WITH(x-toolkit,
  38 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif)],
  39 [         case "${withval}" in
  40             y | ye | yes )      val=athena ;;
  41             n | no )            val=no  ;;
  42             l | lu | luc | luci | lucid )       val=lucid ;;
  43             a | at | ath | athe | athena )      val=athena ;;
  44             m | mo | mot | moti | motif )       val=motif ;;
  45 dnl These don't currently work.
  46 dnl         o | op | ope | open | open- | open-l | open-lo \
  47 dnl             | open-loo | open-look )        val=open-look ;;
  48             * )
  49 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  50 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  51 AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  52 which is \`yes', \`no', \`lucid', \`athena', or \`motif'.
  53 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  54             ;;
  55           esac
  56           with_x_toolkit=$val
  57 ])
  58
  59 #### Make srcdir absolute, if it isn't already.  It's important to
  60 #### avoid running the path through pwd unnecessary, since pwd can
  61 #### give you automounter prefixes, which can go away.  We do all this
  62 #### so Emacs can find its files when run uninstalled.
  63 case "${srcdir}" in
  64   /* ) ;;
  65   . )
  66     ## We may be able to use the $PWD environment variable to make this
  67     ## absolute.  But sometimes PWD is inaccurate.
  68     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  69     then
  70       srcdir="$PWD"
  71     else
  72       srcdir="`(cd ${srcdir}; pwd)`"
  73     fi
  74   ;;
  75   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  76 esac
  77
  78 #### Check if the source directory already has a configured system in it.
  79 if test `pwd` != `(cd ${srcdir} && pwd)` \
  80    && test -f "${srcdir}/src/config.h" ; then
  81   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  82    as a build directory right now; it has been configured in its own
  83    right.  To configure in another directory as well, you MUST
  84    use GNU make.  If you do not have GNU make, then you must
  85    now do \`make distclean' in ${srcdir},
  86    and then run $0 again.])
  87
  88 changequote(, )dnl
  89   extrasub='/^VPATH[     ]*=/c\
  90 changequote([, ])dnl
  91 vpath %.c $(srcdir)\
  92 vpath %.h $(srcdir)\
  93 vpath %.y $(srcdir)\
  94 vpath %.l $(srcdir)\
  95 vpath %.s $(srcdir)\
  96 vpath %.in $(srcdir)'
  97 fi
  98
  99 #### Given the configuration name, set machfile and opsysfile to the
 100 #### names of the m/*.h and s/*.h files we should use.
 101
 102 ### Canonicalize the configuration name.
 103
 104 AC_CANONICAL_HOST
 105 canonical=$host
 106 configuration=$host_alias
 107
 108 changequote(, )dnl
 109
 110 ### If you add support for a new configuration, add code to this
 111 ### switch statement to recognize your configuration name and select
 112 ### the appropriate operating system and machine description files.
 113
 114 ### You would hope that you could choose an m/*.h file pretty much
 115 ### based on the machine portion of the configuration name, and an s-
 116 ### file based on the operating system portion.  However, it turns out
 117 ### that each m/*.h file is pretty manufacturer-specific - for
 118 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 119 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 120 ### machines.  So we basically have to have a special case for each
 121 ### configuration name.
 122 ###
 123 ### As far as handling version numbers on operating systems is
 124 ### concerned, make sure things will fail in a fixable way.  If
 125 ### /etc/MACHINES doesn't say anything about version numbers, be
 126 ### prepared to handle anything reasonably.  If version numbers
 127 ### matter, be sure /etc/MACHINES says something about it.
 128 ###
 129 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 130 ### "System V Release 4"; he writes, "The old convention encouraged
 131 ### confusion between `system' and `release' levels'."
 132
 133 machine='' opsys='' unported=no
 134 case "${canonical}" in
 135
 136   ## NetBSD ports
 137   *-*-netbsd* )
 138     opsys=netbsd
 139     case "${canonical}" in
 140       i[345]86-*-netbsd*) machine=intel386 ;;
 141       m68k-*-netbsd*)
 142                         # This is somewhat bogus.
 143                         machine=hp9000s300 ;;
 144       mips-*-netbsd*)   machine=pmax ;;
 145       ns32k-*-netbsd*)  machine=ns32000 ;;
 146       sparc-*-netbsd*)  machine=sparc ;;
 147     esac
 148   ;;
 149
 150   ## Acorn RISCiX:
 151   arm-acorn-riscix1.1* )
 152     machine=acorn opsys=riscix1-1
 153   ;;
 154   arm-acorn-riscix1.2* | arm-acorn-riscix )
 155     machine=acorn opsys=riscix1-2
 156   ;;
 157
 158   ## Alliant machines
 159   ## Strictly speaking, we need the version of the alliant operating
 160   ## system to choose the right machine file, but currently the
 161   ## configuration name doesn't tell us enough to choose the right
 162   ## one; we need to give alliants their own operating system name to
 163   ## do this right.  When someone cares, they can help us.
 164   fx80-alliant-* )
 165     machine=alliant4 opsys=bsd4-2
 166   ;;
 167   i860-alliant-* )
 168     machine=alliant-2800 opsys=bsd4-3
 169   ;;
 170
 171   alpha-dec-osf* )
 172     machine=alpha opsys=osf1
 173   ;;
 174
 175   ## Altos 3068
 176   m68*-altos-sysv* )
 177     machine=altos opsys=usg5-2
 178   ;;
 179
 180   ## Amdahl UTS
 181   580-amdahl-sysv* )
 182     machine=amdahl opsys=usg5-2-2
 183   ;;
 184
 185   ## Appallings - I mean, Apollos - running Domain
 186   m68*-apollo* )
 187     machine=apollo opsys=domain NON_GNU_CPP=/usr/lib/cpp
 188   ;;
 189
 190   ## AT&T 3b2, 3b5, 3b15, 3b20
 191   we32k-att-sysv* )
 192     machine=att3b opsys=usg5-2-2
 193   ;;
 194
 195   ## AT&T 3b1 - The Mighty Unix PC!
 196   m68*-att-sysv* )
 197     machine=7300 opsys=usg5-2-2
 198   ;;
 199
 200   ## Bull dpx20
 201   rs6000-bull-bosx* )
 202     machine=ibmrs6000 opsys=aix3-2
 203   ;;
 204
 205   ## Bull dpx2
 206   m68*-bull-sysv3* )
 207     machine=dpx2 opsys=usg5-3
 208   ;;
 209
 210   ## Bull sps7
 211   m68*-bull-sysv2* )
 212     machine=sps7 opsys=usg5-2
 213   ;;
 214
 215   ## CCI 5/32, 6/32 -- see "Tahoe".
 216
 217   ## Celerity
 218   ## I don't know what configuration name to use for this; config.sub
 219   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 220   ## in touch with us!
 221   celerity-celerity-bsd* )
 222     machine=celerity opsys=bsd4-2
 223   ;;
 224
 225   ## Clipper
 226   ## What operating systems does this chip run that Emacs has been
 227   ## tested on?
 228   clipper-* )
 229     machine=clipper
 230     ## We'll use the catch-all code at the bottom to guess the
 231     ## operating system.
 232   ;;
 233
 234   ## Convex
 235   *-convex-bsd* | *-convex-convexos* )
 236     machine=convex opsys=bsd4-3
 237     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 238     NON_GNU_CPP="cc -E -P"
 239   ;;
 240
 241   ## Cubix QBx/386
 242   i[345]86-cubix-sysv* )
 243     machine=intel386 opsys=usg5-3
 244   ;;
 245
 246   ## Cydra 5
 247   cydra*-cydrome-sysv* )
 248     machine=cydra5 opsys=usg5-3
 249   ;;
 250
 251   ## Data General AViiON Machines
 252   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 253     machine=aviion opsys=dgux5-4r3
 254   ;;
 255   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 256     machine=aviion opsys=dgux5-4r2
 257   ;;
 258   m88k-dg-dgux* )
 259     machine=aviion opsys=dgux
 260   ;;
 261
 262   ## DECstations
 263   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 264     machine=pmax opsys=bsd4-2
 265   ;;
 266   mips-dec-ultrix* | mips-dec-bsd* )
 267     machine=pmax opsys=bsd4-3
 268   ;;
 269   mips-dec-osf* )
 270     machine=pmax opsys=osf1
 271   ;;
 272
 273   ## Motorola Delta machines
 274   m68k-motorola-sysv* | m68000-motorola-sysv* )
 275     machine=delta opsys=usg5-3
 276     if test -z "`type gnucc | grep 'not found'`"
 277     then CC=gnucc
 278     else
 279       if test -z "`type gcc | grep 'not found'`"
 280       then CC=gcc
 281       else CC=cc
 282       fi
 283     fi
 284   ;;
 285   m88k-motorola-sysv4* )
 286     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 287     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 288     # I hope there are not other 4.0 versions for this machine
 289     # which really need usg5-4 instead.
 290     machine=delta88k opsys=usg5-4-2
 291   ;;
 292   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 293     machine=delta88k opsys=usg5-3
 294   ;;
 295
 296   ## Dual machines
 297   m68*-dual-sysv* )
 298     machine=dual opsys=usg5-2
 299   ;;
 300   m68*-dual-uniplus* )
 301     machine=dual opsys=unipl5-2
 302   ;;
 303
 304   ## Elxsi 6400
 305   elxsi-elxsi-sysv* )
 306     machine=elxsi opsys=usg5-2
 307   ;;
 308
 309   ## Encore machines
 310   ns16k-encore-bsd* )
 311     machine=ns16000 opsys=umax
 312   ;;
 313
 314   ## The GEC 93 - apparently, this port isn't really finished yet.
 315
 316   ## Gould Power Node and NP1
 317   pn-gould-bsd4.2* )
 318     machine=gould opsys=bsd4-2
 319   ;;
 320   pn-gould-bsd4.3* )
 321     machine=gould opsys=bsd4-3
 322   ;;
 323   np1-gould-bsd* )
 324     machine=gould-np1 opsys=bsd4-3
 325   ;;
 326
 327   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 328   ## as far as Emacs is concerned).
 329   m88k-harris-cxux* )
 330     # Build needs to be different on 7.0 and later releases
 331     case "`uname -r`" in
 332        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 333        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 334     esac
 335   ;;
 336   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 337   m68k-harris-cxux* )
 338     machine=nh3000 opsys=cxux
 339   ;;
 340
 341   ## Honeywell XPS100
 342   xps*-honeywell-sysv* )
 343     machine=xps100 opsys=usg5-2
 344   ;;
 345
 346   ## HP 9000 series 200 or 300
 347   m68*-hp-bsd* )
 348     machine=hp9000s300 opsys=bsd4-3
 349   ;;
 350   ## HP/UX 7, 8 and 9 are supported on these machines.
 351   m68*-hp-hpux* )
 352     case "`uname -r`" in
 353       ## Someone's system reports A.B8.05 for this.
 354       ## I wonder what other possibilities there are.
 355       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 356       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 357       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 358       *) machine=hp9000s300 opsys=hpux ;;
 359     esac
 360   ;;
 361
 362   ## HP 9000 series 700 and 800, running HP/UX
 363   hppa*-hp-hpux7* )
 364     machine=hp800 opsys=hpux
 365   ;;
 366   hppa*-hp-hpux8* )
 367     machine=hp800 opsys=hpux8
 368   ;;
 369   hppa*-hp-hpux9shr* )
 370     machine=hp800 opsys=hpux9shr
 371   ;;
 372   hppa*-hp-hpux9* )
 373     machine=hp800 opsys=hpux9
 374   ;;
 375
 376   ## HP 9000 series 700 and 800, running HP/UX
 377   hppa*-hp-hpux* )
 378     ## Cross-compilation?  Nah!
 379     case "`uname -r`" in
 380       ## Someone's system reports A.B8.05 for this.
 381       ## I wonder what other possibilities there are.
 382       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 383       *.08.* ) machine=hp800 opsys=hpux8 ;;
 384       *.09.* ) machine=hp800 opsys=hpux9 ;;
 385       *) machine=hp800 opsys=hpux ;;
 386     esac
 387   ;;
 388
 389   ## Orion machines
 390   orion-orion-bsd* )
 391     machine=orion opsys=bsd4-2
 392   ;;
 393   clipper-orion-bsd* )
 394     machine=orion105 opsys=bsd4-2
 395   ;;
 396
 397   ## IBM machines
 398   i[345]86-ibm-aix1.1* )
 399     machine=ibmps2-aix opsys=usg5-2-2
 400   ;;
 401   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 402     machine=ibmps2-aix opsys=usg5-3
 403   ;;
 404   i370-ibm-aix*)
 405     machine=ibm370aix opsys=usg5-3
 406   ;;
 407   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 408     machine=ibmrs6000 opsys=aix3-1
 409   ;;
 410   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 411     machine=ibmrs6000 opsys=aix3-2-5
 412   ;;
 413   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 414     machine=ibmrs6000 opsys=aix4-1
 415   ;;
 416   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 417     machine=ibmrs6000 opsys=aix4
 418   ;;
 419   rs6000-ibm-aix* | powerpc-ibm-aix* )
 420     machine=ibmrs6000 opsys=aix3-2
 421   ;;
 422   romp-ibm-bsd4.3* )
 423     machine=ibmrt opsys=bsd4-3
 424   ;;
 425   romp-ibm-bsd4.2* )
 426     machine=ibmrt opsys=bsd4-2
 427   ;;
 428   romp-ibm-aos4.3* )
 429     machine=ibmrt opsys=bsd4-3
 430   ;;
 431   romp-ibm-aos4.2* )
 432     machine=ibmrt opsys=bsd4-2
 433   ;;
 434   romp-ibm-aos* )
 435     machine=ibmrt opsys=bsd4-3
 436   ;;
 437   romp-ibm-bsd* )
 438     machine=ibmrt opsys=bsd4-3
 439   ;;
 440   romp-ibm-aix* )
 441     machine=ibmrt-aix opsys=usg5-2-2
 442   ;;
 443
 444   ## Integrated Solutions `Optimum V'
 445   m68*-isi-bsd4.2* )
 446     machine=isi-ov opsys=bsd4-2
 447   ;;
 448   m68*-isi-bsd4.3* )
 449     machine=isi-ov opsys=bsd4-3
 450   ;;
 451
 452   ## Intel 386 machines where we do care about the manufacturer
 453   i[345]86-intsys-sysv* )
 454     machine=is386 opsys=usg5-2-2
 455   ;;
 456
 457   ## Prime EXL
 458   i[345]86-prime-sysv* )
 459     machine=i386 opsys=usg5-3
 460   ;;
 461
 462   ## Sequent Symmetry running Dynix
 463   i[345]86-sequent-bsd* )
 464     machine=symmetry opsys=bsd4-3
 465   ;;
 466
 467   ## Sequent Symmetry running DYNIX/ptx
 468   ## Use the old cpp rather than the newer ANSI one.
 469   i[345]86-sequent-ptx* )
 470     machine=sequent-ptx opsys=ptx
 471     NON_GNU_CPP="/lib/cpp"
 472   ;;
 473
 474   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 475   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 476   i[345]86-ncr-sysv* )
 477     machine=intel386 opsys=usg5-4-2
 478   ;;
 479
 480   ## Intel Paragon OSF/1
 481   i860-intel-osf1* )
 482     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 483   ;;
 484
 485   ## Intel 860
 486   i860-*-sysv4* )
 487     machine=i860 opsys=usg5-4
 488     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 489     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 490   ;;
 491
 492   ## Masscomp machines
 493   m68*-masscomp-rtu* )
 494     machine=masscomp opsys=rtu
 495   ;;
 496
 497   ## Megatest machines
 498   m68*-megatest-bsd* )
 499     machine=mega68 opsys=bsd4-2
 500   ;;
 501
 502   ## Workstations sold by MIPS
 503   ## This is not necessarily all workstations using the MIPS processor -
 504   ## Irises are produced by SGI, and DECstations by DEC.
 505
 506   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 507   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 508   ## it gives for choosing between the alternatives seems to be "Use
 509   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 510   ## the BSD world."  I'll assume that these are instructions for
 511   ## handling two odd situations, and that every other situation
 512   ## should use mips.h and usg5-2-2, they being listed first.
 513   mips-mips-usg* )
 514     machine=mips4
 515     ## Fall through to the general code at the bottom to decide on the OS.
 516   ;;
 517   mips-mips-riscos4* )
 518     machine=mips4 opsys=bsd4-3
 519     NON_GNU_CC="cc -systype bsd43"
 520     NON_GNU_CPP="cc -systype bsd43 -E"
 521   ;;
 522   mips-mips-bsd* )
 523     machine=mips opsys=bsd4-3
 524   ;;
 525   mips-mips-* )
 526     machine=mips opsys=usg5-2-2
 527   ;;
 528
 529   ## NeXT
 530   m68*-next-* | i[345]86-next-* )
 531     machine=next opsys=mach2
 532   ;;
 533
 534   ## The complete machine from National Semiconductor
 535   ns32k-ns-genix* )
 536     machine=ns32000 opsys=usg5-2
 537   ;;
 538
 539   ## NCR machines
 540   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 541     machine=tower32 opsys=usg5-2-2
 542   ;;
 543   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 544     machine=tower32v3 opsys=usg5-3
 545   ;;
 546
 547   ## Nixdorf Targon 31
 548   m68*-nixdorf-sysv* )
 549     machine=targon31 opsys=usg5-2-2
 550   ;;
 551
 552   ## Nu (TI or LMI)
 553   m68*-nu-sysv* )
 554     machine=nu opsys=usg5-2
 555   ;;
 556
 557   ## Plexus
 558   m68*-plexus-sysv* )
 559     machine=plexus opsys=usg5-2
 560   ;;
 561
 562   ## Pyramid machines
 563   ## I don't really have any idea what sort of processor the Pyramid has,
 564   ## so I'm assuming it is its own architecture.
 565   pyramid-pyramid-bsd* )
 566     machine=pyramid opsys=bsd4-2
 567   ;;
 568
 569   ## Sequent Balance
 570   ns32k-sequent-bsd4.2* )
 571     machine=sequent opsys=bsd4-2
 572   ;;
 573   ns32k-sequent-bsd4.3* )
 574     machine=sequent opsys=bsd4-3
 575   ;;
 576
 577   ## Siemens Nixdorf
 578   mips-siemens-sysv* )
 579     machine=mips-siemens opsys=usg5-4
 580     NON_GNU_CC=/usr/ccs/bin/cc
 581     NON_GNU_CPP=/usr/ccs/lib/cpp
 582   ;;
 583
 584   ## Silicon Graphics machines
 585   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 586   m68*-sgi-iris3.5* )
 587     machine=irist opsys=iris3-5
 588   ;;
 589   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 590     machine=irist opsys=iris3-6
 591   ;;
 592   ## Iris 4D
 593   mips-sgi-irix3* )
 594     machine=iris4d opsys=irix3-3
 595   ;;
 596   mips-sgi-irix4* )
 597     machine=iris4d opsys=irix4-0
 598   ;;
 599   mips-sgi-irix6* )
 600     machine=iris4d opsys=irix6-0
 601   ;;
 602   mips-sgi-irix5.[01]* )
 603     machine=iris4d opsys=irix5-0
 604   ;;
 605   mips-sgi-irix5* | mips-sgi-irix* )
 606     machine=iris4d opsys=irix5-2
 607   ;;
 608
 609   ## SONY machines
 610   m68*-sony-bsd4.2* )
 611     machine=news opsys=bsd4-2
 612   ;;
 613   m68*-sony-bsd4.3* )
 614     machine=news opsys=bsd4-3
 615   ;;
 616   m68*-sony-newsos3* | m68*-sony-news3*)
 617     machine=news opsys=bsd4-3
 618   ;;
 619   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 620     machine=news-risc opsys=bsd4-3
 621   ;;
 622   mips-sony-news* )
 623     machine=news-risc opsys=newsos5
 624   ;;
 625
 626   ## Stride
 627   m68*-stride-sysv* )
 628     machine=stride opsys=usg5-2
 629   ;;
 630
 631   ## Suns
 632   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* | i[345]86-*-solaris2* | i[345]86-*-sunos5* )
 633     case "${canonical}" in
 634       m68*-sunos1* )    machine=sun1 ;;
 635       m68*-sunos2* )    machine=sun2 ;;
 636       m68* )            machine=sun3 ;;
 637       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 638       i[345]86-*-* )     machine=intel386 ;;
 639       sparc* )          machine=sparc ;;
 640       * )               unported=yes ;;
 641     esac
 642     case "${canonical}" in
 643       ## The Sun386 didn't get past 4.0.
 644       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 645       *-sunos4.0*         ) opsys=sunos4-0 ;;
 646       *-sunos4.1.3*       ) opsys=sunos4-1-3
 647                 NON_GCC_TEST_OPTIONS=-Bstatic
 648                 GCC_TEST_OPTIONS=-static
 649                 NON_GNU_CPP=/usr/lib/cpp
 650                 ;;
 651       *-sunos4shr*        ) opsys=sunos4shr
 652                 NON_GNU_CPP=/usr/lib/cpp
 653                 ;;
 654       *-sunos4* | *-sunos ) opsys=sunos4-1
 655                 NON_GCC_TEST_OPTIONS=-Bstatic
 656                 GCC_TEST_OPTIONS=-static
 657                 ;;
 658       *-sunos5.3* | *-solaris2.3* )
 659                 opsys=sol2-3
 660                 NON_GNU_CPP=/usr/ccs/lib/cpp
 661                 ;;
 662       *-sunos5.4* | *-solaris2.4* )
 663                 opsys=sol2-4
 664                 NON_GNU_CPP=/usr/ccs/lib/cpp
 665                 ;;
 666       *-sunos5* | *-solaris* )
 667                 opsys=sol2
 668                 NON_GNU_CPP=/usr/ccs/lib/cpp
 669                 ;;
 670       *                   ) opsys=bsd4-2   ;;
 671     esac
 672   ;;
 673
 674   ## Tadpole 68k
 675   m68*-tadpole-sysv* )
 676     machine=tad68k opsys=usg5-3
 677   ;;
 678
 679   ## Tahoe machines
 680   tahoe-tahoe-bsd4.2* )
 681     machine=tahoe opsys=bsd4-2
 682   ;;
 683   tahoe-tahoe-bsd4.3* )
 684     machine=tahoe opsys=bsd4-3
 685   ;;
 686
 687   ## Tandem Integrity S2
 688   mips-tandem-sysv* )
 689     machine=tandem-s2 opsys=usg5-3
 690   ;;
 691
 692   ## Tektronix XD88
 693   m88k-tektronix-sysv3* )
 694   machine=tekxd88 opsys=usg5-3
 695   ;;
 696
 697   ## Tektronix 16000 box (6130?)
 698   ns16k-tektronix-bsd* )
 699     machine=ns16000 opsys=bsd4-2
 700   ;;
 701   ## Tektronix 4300
 702   ## src/m/tek4300.h hints that this is a m68k machine.
 703   m68*-tektronix-bsd* )
 704     machine=tek4300 opsys=bsd4-3
 705   ;;
 706
 707   ## Titan P2 or P3
 708   ## We seem to have lost the machine-description file titan.h!
 709   titan-titan-sysv* )
 710     machine=titan opsys=usg5-3
 711   ;;
 712
 713   ## Ustation E30 (SS5E)
 714   m68*-unisys-uniplus* )
 715     machine=ustation opsystem=unipl5-2
 716   ;;
 717
 718   ## Vaxen.
 719   vax-dec-* )
 720     machine=vax
 721     case "${canonical}" in
 722       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 723       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 724       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 725       *-bsd386* | *-bsdi* )                             opsys=bsd386 ;;
 726       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 727       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 728       *-vms* )                                          opsys=vms ;;
 729       * )                                               unported=yes
 730     esac
 731   ;;
 732
 733   ## Whitechapel MG1
 734   ns16k-whitechapel-* )
 735     machine=mg1
 736     ## We don't know what sort of OS runs on these; we'll let the
 737     ## operating system guessing code below try.
 738   ;;
 739
 740   ## Wicat
 741   m68*-wicat-sysv* )
 742     machine=wicat opsys=usg5-2
 743   ;;
 744
 745   ## Intel 386 machines where we don't care about the manufacturer
 746   i[345]86-*-* )
 747     machine=intel386
 748     case "${canonical}" in
 749       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 750       *-isc2.2* )               opsys=isc2-2 ;;
 751       *-isc4.0* )               opsys=isc4-0 ;;
 752       *-isc4.* )                opsys=isc4-1 ;;
 753       *-isc* )                  opsys=isc3-0 ;;
 754       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 755       *-esix* )                 opsys=esix ;;
 756       *-xenix* )                opsys=xenix ;;
 757       *-linux* )                opsys=linux ;;
 758       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 759       *-bsd386* | *-bsdi* )     opsys=bsd386 ;;
 760       *-386bsd* )               opsys=386bsd ;;
 761       *-freebsd* )              opsys=freebsd ;;
 762       *-nextstep* )             opsys=mach2 ;;
 763       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 764     esac
 765   ;;
 766
 767   * )
 768     unported=yes
 769   ;;
 770 esac
 771
 772 ### If the code above didn't choose an operating system, just choose
 773 ### an operating system based on the configuration name.  You really
 774 ### only want to use this when you have no idea what the right
 775 ### operating system is; if you know what operating systems a machine
 776 ### runs, it's cleaner to make it explicit in the case statement
 777 ### above.
 778 if test x"${opsys}" = x; then
 779   case "${canonical}" in
 780     *-gnu* )                            opsys=gnu ;;
 781     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 782     *-bsd4.2 )                          opsys=bsd4-2 ;;
 783     *-bsd4.3 )                          opsys=bsd4-3 ;;
 784     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 785     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 786     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 787     *-sysv3 | *-sysvr3 )                opsys=usg5-3 ;;
 788     *-sysv4 | *-sysvr4 )                opsys=usg5-4 ;;
 789     *-sysv4.1 | *-sysvr4.1 )
 790         NON_GNU_CPP=/usr/lib/cpp
 791         opsys=usg5-4 ;;
 792     *-sysv4.2 | *-sysvr4.2 )
 793         if [ x$NON_GNU_CPP = x ]; then
 794           NON_GNU_CPP=/usr/ccs/lib/cpp
 795         fi
 796         opsys=usg5-4-2 ;;
 797     * )
 798       unported=yes
 799     ;;
 800   esac
 801 fi
 802
 803 changequote([, ])dnl
 804
 805 if test $unported = yes; then
 806   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 807 Check \`etc/MACHINES' for recognized configuration names.])
 808 fi
 809
 810 machfile="m/${machine}.h"
 811 opsysfile="s/${opsys}.h"
 812
 813
 814 #### Choose a compiler.
 815 test -n "$CC" && cc_specified=yes
 816
 817 case ${with_gcc} in
 818   "yes" ) CC="gcc" GCC=yes ;;
 819   "no"  ) : ${CC=cc} ;;
 820   * ) AC_PROG_CC
 821 esac
 822
 823 # On Suns, sometimes $CPP names a directory.
 824 if test -n "$CPP" && test -d "$CPP"; then
 825   CPP=
 826 fi
 827
 828 #### Some systems specify a CPP to use unless we are using GCC.
 829 #### Now that we know whether we are using GCC, we can decide whether
 830 #### to use that one.
 831 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 832 then
 833   CPP="$NON_GNU_CPP"
 834 fi
 835
 836 #### Some systems specify a CC to use unless we are using GCC.
 837 #### Now that we know whether we are using GCC, we can decide whether
 838 #### to use that one.
 839 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 840   test x$cc_specified != xyes
 841 then
 842   CC="$NON_GNU_CC"
 843 fi
 844
 845 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 846 then
 847   CC="$CC $GCC_TEST_OPTIONS"
 848 fi
 849
 850 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 851 then
 852   CC="$CC $NON_GCC_TEST_OPTIONS"
 853 fi
 854
 855 #### Some other nice autoconf tests.  If you add a test here which
 856 #### should make an entry in src/config.h, don't forget to add an
 857 #### #undef clause to src/config.h.in for autoconf to modify.
 858
 859 dnl checks for programs
 860 AC_PROG_LN_S
 861 AC_PROG_CPP
 862 AC_PROG_INSTALL
 863 AC_PROG_YACC
 864
 865 dnl checks for Unix variants
 866 AC_AIX
 867
 868 dnl checks for header files
 869 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
 870 AC_HEADER_STDC
 871 AC_HEADER_TIME
 872 AC_DECL_SYS_SIGLIST
 873
 874 dnl Some systems have utime.h but don't declare the struct anyplace.
 875 AC_MSG_CHECKING(for struct utimbuf)
 876 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 877 #include <sys/time.h>
 878 #include <time.h>
 879 #else
 880 #ifdef HAVE_SYS_TIME_H
 881 #include <sys/time.h>
 882 #else
 883 #include <time.h>
 884 #endif
 885 #endif
 886 #ifdef HAVE_UTIME_H
 887 #include <utime.h>
 888 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 889   [AC_MSG_RESULT(yes)
 890    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 891   AC_MSG_RESULT(no))
 892
 893 dnl checks for typedefs
 894 AC_TYPE_SIGNAL
 895
 896 AC_MSG_CHECKING(for struct timeval)
 897 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 898 #include <sys/time.h>
 899 #include <time.h>
 900 #else
 901 #ifdef HAVE_SYS_TIME_H
 902 #include <sys/time.h>
 903 #else
 904 #include <time.h>
 905 #endif
 906 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 907   [AC_MSG_RESULT(yes)
 908    AC_DEFINE(HAVE_TIMEVAL)],
 909   AC_MSG_RESULT(no))
 910
 911 dnl checks for structure members
 912 AC_STRUCT_TM
 913 AC_STRUCT_TIMEZONE
 914
 915 dnl checks for compiler characteristics
 916 AC_C_CONST
 917
 918 dnl check for Make feature
 919 AC_PROG_MAKE_SET
 920
 921 dnl checks for operating system services
 922 AC_SYS_LONG_FILE_NAMES
 923
 924 #### Choose a window system.
 925
 926 AC_PATH_X
 927 if test "$no_x" = yes; then
 928   window_system=none
 929 else
 930   window_system=x11
 931 fi
 932
 933 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
 934   LD_SWITCH_X_SITE="-L${x_libraries}"
 935   LD_SWITCH_X_SITE_AUX="-R${x_libraries}"
 936 fi
 937 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
 938   C_SWITCH_X_SITE="-I${x_includes}"
 939 fi
 940
 941 if test x"${x_includes}" = x; then
 942   bitmapdir=/usr/include/X11/bitmaps
 943 else
 944   bitmapdir="${x_includes}/bitmaps"
 945 fi
 946
 947 case "${window_system}" in
 948   x11 )
 949     HAVE_X_WINDOWS=yes
 950     HAVE_X11=yes
 951     case "${with_x_toolkit}" in
 952       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
 953       motif ) USE_X_TOOLKIT=MOTIF ;;
 954 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
 955       * ) USE_X_TOOLKIT=none ;;
 956     esac
 957   ;;
 958   none )
 959     HAVE_X_WINDOWS=no
 960     HAVE_X11=no
 961     USE_X_TOOLKIT=none
 962   ;;
 963 esac
 964 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
 965
 966 ### If we're using X11, we should use the X menu package.
 967 HAVE_X_MENU=no
 968 case ${HAVE_X11} in
 969   yes ) HAVE_X_MENU=yes ;;
 970 esac
 971
 972 #### Extract some information from the operating system and machine files.
 973
 974 AC_CHECKING([the machine- and system-dependent files to find out
 975  - which libraries the lib-src programs will want, and
 976  - whether the GNU malloc routines are usable])
 977
 978 ### First figure out CFLAGS (which we use for running the compiler here)
 979 ### and REAL_CFLAGS (which we use for real compilation).
 980 ### The two are the same except on a few systems, where they are made
 981 ### different to work around various lossages.  For example,
 982 ### GCC 2.5 on Linux needs them to be different because it treats -g
 983 ### as implying static linking.
 984
 985 ### If the CFLAGS env var is specified, we use that value
 986 ### instead of the default.
 987
 988 ### It's not important that this name contain the PID; you can't run
 989 ### two configures in the same directory and have anything work
 990 ### anyway.
 991 tempcname="conftest.c"
 992
 993 echo '
 994 #include "'${srcdir}'/src/'${opsysfile}'"
 995 #include "'${srcdir}'/src/'${machfile}'"
 996 #ifndef LIBS_MACHINE
 997 #define LIBS_MACHINE
 998 #endif
 999 #ifndef LIBS_SYSTEM
1000 #define LIBS_SYSTEM
1001 #endif
1002 #ifndef C_SWITCH_SYSTEM
1003 #define C_SWITCH_SYSTEM
1004 #endif
1005 #ifndef C_SWITCH_MACHINE
1006 #define C_SWITCH_MACHINE
1007 #endif
1008 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1009 configure___ c_switch_system=C_SWITCH_SYSTEM
1010 configure___ c_switch_machine=C_SWITCH_MACHINE
1011
1012 #ifndef LIB_X11_LIB
1013 #define LIB_X11_LIB -lX11
1014 #endif
1015
1016 #ifndef LIBX11_MACHINE
1017 #define LIBX11_MACHINE
1018 #endif
1019
1020 #ifndef LIBX11_SYSTEM
1021 #define LIBX11_SYSTEM
1022 #endif
1023 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1024
1025 #ifdef UNEXEC
1026 configure___ unexec=UNEXEC
1027 #else
1028 configure___ unexec=unexec.o
1029 #endif
1030
1031 #ifdef SYSTEM_MALLOC
1032 configure___ system_malloc=yes
1033 #else
1034 configure___ system_malloc=no
1035 #endif
1036
1037 #ifndef C_DEBUG_SWITCH
1038 #define C_DEBUG_SWITCH -g
1039 #endif
1040
1041 #ifndef C_OPTIMIZE_SWITCH
1042 #define C_OPTIMIZE_SWITCH -O
1043 #endif
1044
1045 #ifdef THIS_IS_CONFIGURE
1046
1047 /* Get the CFLAGS for tests in configure.  */
1048 #ifdef __GNUC__
1049 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1050 #else
1051 configure___ CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1052 #endif
1053
1054 #else /* not THIS_IS_CONFIGURE */
1055
1056 /* Get the CFLAGS for real compilation.  */
1057 #ifdef __GNUC__
1058 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1059 #else
1060 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1061 #endif
1062
1063 #endif /* not THIS_IS_CONFIGURE */
1064 ' > ${tempcname}
1065
1066 # The value of CPP is a quoted variable reference, so we need to do this
1067 # to get its actual value...
1068 CPP=`eval "echo $CPP"`
1069 changequote(, )dnl
1070 eval `${CPP} -Isrc ${tempcname} \
1071        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1072 if test "x$CFLAGS" = x; then
1073   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1074          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1075 else
1076   REAL_CFLAGS="$CFLAGS"
1077 fi
1078 changequote([, ])dnl
1079 rm ${tempcname}
1080
1081 ### Compute the unexec source name from the object name.
1082 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1083
1084 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1085 # Assume not, until told otherwise.
1086 GNU_MALLOC=yes
1087 if test "${system_malloc}" = "yes"; then
1088   GNU_MALLOC=no
1089   GNU_MALLOC_reason="
1090   (The GNU allocators don't work with this system configuration.)"
1091 fi
1092
1093 if test x"${REL_ALLOC}" = x; then
1094   REL_ALLOC=${GNU_MALLOC}
1095 fi
1096
1097 LISP_FLOAT_TYPE=yes
1098
1099
1100 #### Add the libraries to LIBS and check for some functions.
1101
1102 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1103 LIBS="$libsrc_libs"
1104
1105 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1106 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1107 AC_CHECK_LIB(dnet, dnet_ntoa)
1108 dnl This causes -lresolv to get used in subsequent tests,
1109 dnl which causes failures on some systems such as HPUX 9.
1110 dnl AC_CHECK_LIB(resolv, gethostbyname)
1111
1112 dnl FIXME replace main with a function we actually want from this library.
1113 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1114
1115 AC_MSG_CHECKING(for XFree86)
1116 if test -d /usr/X386/include; then
1117   HAVE_XFREE386=yes
1118   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1119 else
1120   HAVE_XFREE386=no
1121 fi
1122 AC_MSG_RESULT($HAVE_XFREE386)
1123
1124 # We change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1125 # for the tests that follow.
1126
1127 if test "${HAVE_X11}" = "yes"; then
1128   DEFS="$C_SWITCH_X_SITE $DEFS"
1129   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1130   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1131   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1132 XScreenNumberOfScreen XSetWMProtocols)
1133 fi
1134
1135 if test "${USE_X_TOOLKIT}" != "none"; then
1136   AC_MSG_CHECKING(X11 toolkit version)
1137   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1138 [#if XtSpecificationRelease < 6
1139 fail;
1140 #endif
1141 ], [AC_MSG_RESULT(6)
1142     AC_DEFINE(HAVE_X11XTR6)],
1143    [AC_MSG_RESULT(not 6)])
1144 fi
1145
1146 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1147 AC_MSG_CHECKING(whether netdb declarares h_errno)
1148 AC_TRY_LINK([#include <netdb.h>],
1149   [return h_errno;],
1150   [AC_MSG_RESULT(yes)
1151    AC_DEFINE(HAVE_H_ERRNO)],
1152   [AC_MSG_RESULT(no)])
1153
1154 AC_FUNC_ALLOCA
1155
1156 # logb and frexp are found in -lm on most systems.
1157 AC_CHECK_LIB(m, logb)
1158 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1159 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1160 strerror fpathconf select mktime eaccess getpagesize)
1161
1162 ok_so_far=yes
1163 AC_CHECK_FUNC(socket, , ok_so_far=no)
1164 if test $ok_so_far = yes; then
1165   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1166 fi
1167 if test $ok_so_far = yes; then
1168   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1169 fi
1170 if test $ok_so_far = yes; then
1171   AC_DEFINE(HAVE_INET_SOCKETS)
1172 fi
1173
1174 if test -f /usr/lpp/X11/bin/smt.exp; then
1175   AC_DEFINE(HAVE_AIX_SMT_EXP)
1176 fi
1177
1178 # Set up the CFLAGS for real compilation, so we can substitute it.
1179 CFLAGS="$REAL_CFLAGS"
1180
1181 changequote(, )dnl
1182 #### Find out which version of Emacs this is.
1183 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1184          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1185 changequote([, ])dnl
1186 if test x"${version}" = x; then
1187   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1188 fi
1189
1190 ### Specify what sort of things we'll be editing into Makefile and config.h.
1191 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1192 AC_SUBST(version)
1193 AC_SUBST(configuration)
1194 AC_SUBST(canonical)
1195 AC_SUBST(srcdir)
1196 AC_SUBST(prefix)
1197 AC_SUBST(exec_prefix)
1198 AC_SUBST(bindir)
1199 AC_SUBST(datadir)
1200 AC_SUBST(sharedstatedir)
1201 AC_SUBST(libexecdir)
1202 AC_SUBST(mandir)
1203 AC_SUBST(infodir)
1204 AC_SUBST(lispdir)
1205 AC_SUBST(locallisppath)
1206 AC_SUBST(lisppath)
1207 AC_SUBST(etcdir)
1208 AC_SUBST(lockdir)
1209 AC_SUBST(archlibdir)
1210 AC_SUBST(docdir)
1211 AC_SUBST(bitmapdir)
1212 AC_SUBST(c_switch_system)
1213 AC_SUBST(c_switch_machine)
1214 AC_SUBST(LD_SWITCH_X_SITE)
1215 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1216 AC_SUBST(C_SWITCH_X_SITE)
1217 AC_SUBST(CFLAGS)
1218 AC_SUBST(X_TOOLKIT_TYPE)
1219 AC_SUBST(machfile)
1220 AC_SUBST(opsysfile)
1221
1222 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1223 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1224 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1225 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1226 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1227 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1228 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1229 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1230
1231 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1232   AC_DEFINE(HAVE_X_WINDOWS)
1233 fi
1234 if test "${USE_X_TOOLKIT}" != "none" ; then
1235   AC_DEFINE(USE_X_TOOLKIT)
1236 fi
1237 if test "${HAVE_X11}" = "yes" ; then
1238   AC_DEFINE(HAVE_X11)
1239 fi
1240 if test "${HAVE_XFREE386}" = "yes" ; then
1241   AC_DEFINE(HAVE_XFREE386)
1242 fi
1243 if test "${HAVE_X_MENU}" = "yes" ; then
1244   AC_DEFINE(HAVE_X_MENU)
1245 fi
1246 if test "${GNU_MALLOC}" = "yes" ; then
1247   AC_DEFINE(GNU_MALLOC)
1248 fi
1249 if test "${REL_ALLOC}" = "yes" ; then
1250   AC_DEFINE(REL_ALLOC)
1251 fi
1252 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1253   AC_DEFINE(LISP_FLOAT_TYPE)
1254 fi
1255
1256 #### Report on what we decided to do.
1257 echo "
1258
1259 Configured for \`${canonical}'.
1260
1261   Where should the build process find the source code?    ${srcdir}
1262   What operating system and machine description files should Emacs use?
1263         \`${opsysfile}' and \`${machfile}'
1264   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1265   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1266   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1267   What window system should Emacs use?                    ${window_system}
1268   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}${x_includes+
1269   Where do we find X Windows header files?                }${x_includes}${x_libraries+
1270   Where do we find X Windows libraries?                   }${x_libraries}
1271
1272 "
1273
1274 # Remove any trailing slashes in these variables.
1275 changequote(, )dnl
1276 test "${prefix}" != NONE &&
1277   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1278 test "${exec_prefix}" != NONE &&
1279   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1280 changequote([, ])dnl
1281
1282 AC_OUTPUT(Makefile lib-src/Makefile.in oldXMenu/Makefile \
1283         man/Makefile lwlib/Makefile src/Makefile.in, [
1284
1285 ### Make the necessary directories, if they don't exist.
1286 for dir in cpp etc ; do
1287   test -d ${dir} || mkdir ${dir}
1288 done
1289
1290 # Build src/Makefile from ${srcdir}/src/Makefile.in.  This must be done
1291 # after src/config.h is built, since we rely on that file.
1292
1293 changequote(, )dnl The horror, the horror.
1294 # Now get this: Some word that is part of the ${srcdir} directory name
1295 # or the ${configuration} value might, just might, happen to be an
1296 # identifier like `sun4' or `i386' or something, and be predefined by
1297 # the C preprocessor to some helpful value like 1, or maybe the empty
1298 # string.  Needless to say consequent macro substitutions are less
1299 # than conducive to the makefile finding the correct directory.
1300 undefs="`echo $top_srcdir $configuration $canonical |
1301 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1302     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1303 `"
1304 changequote([, ])dnl
1305
1306 echo creating lib-src/Makefile
1307 ( cd lib-src
1308   rm -f junk.c junk1.c junk2.c
1309   sed -e '/start of cpp stuff/q' \
1310       < Makefile.in > junk1.c
1311   sed -e '1,/start of cpp stuff/d'\
1312       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1313       < Makefile.in > junk.c
1314   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1315       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1316   cat junk1.c junk2.c > Makefile.new
1317   rm -f junk.c junk1.c junk2.c
1318   chmod 444 Makefile.new
1319   mv -f Makefile.new Makefile
1320 )
1321
1322 echo creating src/Makefile
1323 ( cd src
1324   rm -f junk.c junk1.c junk2.c
1325   sed -e '/start of cpp stuff/q' \
1326       < Makefile.in > junk1.c
1327   sed -e '1,/start of cpp stuff/d'\
1328       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1329       < Makefile.in > junk.c
1330   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1331       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1332   cat junk1.c junk2.c > Makefile.new
1333   rm -f junk.c junk1.c junk2.c
1334   chmod 444 Makefile.new
1335   mv -f Makefile.new Makefile
1336 )
1337
1338 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1339   echo creating src/.gdbinit
1340   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1341 fi
1342
1343 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])