lisp/hi-lock.el

   1 ;;; hi-lock.el --- minor mode for interactive automatic highlighting
   2
   3 ;; Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: David M. Koppelman, koppel@ee.lsu.edu
   6 ;; Keywords: faces, minor-mode, matching, display
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;;  With the hi-lock commands text matching interactively entered
  28 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  29 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  30 ;;  using a yellow background face.  New occurrences of `clearly' will
  31 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  32 ;;  will remove the highlighting.  Any existing face can be used for
  33 ;;  highlighting and a set of appropriate faces is provided.  The
  34 ;;  regexps can be written into the current buffer in a form that will
  35 ;;  be recognized the next time the corresponding file is read.
  36 ;;
  37 ;;  Applications:
  38 ;;
  39 ;;    In program source code highlight a variable to quickly see all
  40 ;;    places it is modified or referenced:
  41 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  42 ;;
  43 ;;    In a shell or other buffer that is showing lots of program
  44 ;;    output, highlight the parts of the output you're interested in:
  45 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  46 ;;
  47 ;;    In buffers displaying tables, highlight the lines you're interested in:
  48 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  49 ;;
  50 ;;    When writing text, highlight personal cliches.  This can be
  51 ;;    amusing.
  52 ;;    M-x highlight-phrase as can be seen RET RET
  53 ;;
  54 ;;  Setup:
  55 ;;
  56 ;;    Put the following code in your .emacs file.  This turns on
  57 ;;    hi-lock mode and adds a "Regexp Highlighting" entry
  58 ;;    to the edit menu.
  59 ;;
  60 ;;    (hi-lock-mode 1)
  61 ;;
  62 ;;    You might also want to bind the hi-lock commands to more
  63 ;;    finger-friendly sequences:
  64
  65 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  66 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  67 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  68 ;;    (define-key hi-lock-map "\C-zp" 'highlight-phrase)
  69 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  70 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  71
  72 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  73 ;;    additional instructions.
  74
  75 ;; Sample file patterns:
  76
  77 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  78 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  79 ; Hi-lock: end
  80
  81 ;;; Code:
  82
  83 (eval-and-compile
  84   (require 'font-lock))
  85
  86 (defgroup hi-lock-interactive-text-highlighting nil
  87   "Interactively add and remove font-lock patterns for highlighting text."
  88   :group 'faces)
  89
  90 ;;;###autoload
  91 (defcustom hi-lock-mode nil
  92   "Toggle hi-lock, for interactively adding font-lock text-highlighting patterns."
  93   :set (lambda (symbol value)
  94          (hi-lock-mode (or value 0)))
  95   :initialize 'custom-initialize-default
  96   :type 'boolean
  97   :group 'hi-lock-interactive-text-highlighting
  98   :require 'hi-lock)
  99
 100 (defcustom hi-lock-file-patterns-range 10000
 101   "Limit of search in a buffer for hi-lock patterns.
 102 When a file is visited and hi-lock mode is on patterns starting
 103 up to this limit are added to font-lock's patterns.  See documentation
 104 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 105   :type 'integer
 106   :group 'hi-lock-interactive-text-highlighting)
 107
 108 (defcustom hi-lock-exclude-modes
 109   '(rmail-mode mime/viewer-mode gnus-article-mode)
 110   "List of major modes in which hi-lock will not run.
 111 For security reasons since font lock patterns can specify function
 112 calls."
 113   :type '(repeat symbol)
 114   :group 'hi-lock-interactive-text-highlighting)
 115
 116
 117 (defgroup hi-lock-faces nil
 118   "Faces for hi-lock."
 119   :group 'hi-lock-interactive-text-highlighting)
 120
 121 (defface hi-yellow
 122   '((((background dark)) (:background "yellow" :foreground "black"))
 123     (t (:background "yellow")))
 124   "Default face for hi-lock mode."
 125   :group 'hi-lock-faces)
 126
 127 (defface hi-pink
 128   '((((background dark)) (:background "pink" :foreground "black"))
 129     (t (:background "pink")))
 130   "Face for hi-lock mode."
 131   :group 'hi-lock-faces)
 132
 133 (defface hi-green
 134   '((((background dark)) (:background "green" :foreground "black"))
 135     (t (:background "green")))
 136   "Face for hi-lock mode."
 137   :group 'hi-lock-faces)
 138
 139 (defface hi-blue
 140   '((((background dark)) (:background "light blue" :foreground "black"))
 141     (t (:background "light blue")))
 142   "Face for hi-lock mode."
 143   :group 'hi-lock-faces)
 144
 145 (defface hi-black-b
 146   '((t (:weight bold)))
 147   "Face for hi-lock mode."
 148   :group 'hi-lock-faces)
 149
 150 (defface hi-blue-b
 151   '((t (:weight bold :foreground "blue")))
 152   "Face for hi-lock mode."
 153   :group 'hi-lock-faces)
 154
 155 (defface hi-green-b
 156   '((t (:weight bold :foreground "green")))
 157   "Face for hi-lock mode."
 158   :group 'hi-lock-faces)
 159
 160 (defface hi-red-b
 161   '((t (:weight bold :foreground "red")))
 162   "Face for hi-lock mode."
 163   :group 'hi-lock-faces)
 164
 165 (defface hi-black-hb
 166   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 167   "Face for hi-lock mode."
 168   :group 'hi-lock-faces)
 169
 170 (defvar hi-lock-file-patterns nil
 171   "Patterns found in file for hi-lock.  Should not be changed.")
 172
 173 (defvar hi-lock-interactive-patterns nil
 174   "Patterns provided to hi-lock by user.  Should not be changed.")
 175
 176 (defvar hi-lock-face-history
 177   (list "hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 178         "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 179       "History list of faces for hi-lock interactive functions.")
 180
 181 ;(dolist (f hi-lock-face-history) (unless (facep f) (error "%s not a face" f)))
 182
 183 (defvar hi-lock-regexp-history nil
 184   "History of regexps used for interactive fontification.")
 185
 186 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 187   "Regexp for finding hi-lock patterns at top of file.")
 188
 189 (make-variable-buffer-local 'hi-lock-interactive-patterns)
 190 (put 'hi-lock-interactive-patterns 'permanent-local t)
 191 (make-variable-buffer-local 'hi-lock-regexp-history)
 192 (put 'hi-lock-regexp-history 'permanent-local t)
 193 (make-variable-buffer-local 'hi-lock-file-patterns)
 194 (put 'hi-lock-file-patterns 'permanent-local t)
 195
 196 (defvar hi-lock-menu (make-sparse-keymap "Hi Lock")
 197   "Menu for hi-lock mode.")
 198
 199 (define-key-after hi-lock-menu [highlight-regexp]
 200   '(menu-item "Highlight Regexp..." highlight-regexp
 201               :help "Highlight text matching PATTERN (a regexp)."))
 202
 203 (define-key-after hi-lock-menu [highlight-phrase]
 204   '(menu-item "Highlight Phrase..." highlight-phrase
 205               :help "Highlight text matching PATTERN (a regexp processed to match phrases)."))
 206
 207 (define-key-after hi-lock-menu [highlight-lines-matching-regexp]
 208   '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 209               :help "Highlight lines containing match of PATTERN (a regexp).."))
 210
 211 (define-key-after hi-lock-menu [unhighlight-regexp]
 212   '(menu-item "Remove Highlighting..." unhighlight-regexp
 213               :help "Remove previously entered highlighting pattern."
 214               :enable hi-lock-interactive-patterns))
 215
 216 (define-key-after hi-lock-menu [hi-lock-write-interactive-patterns]
 217   '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 218               :help "Insert interactively added REGEXPs into buffer at point."
 219               :enable hi-lock-interactive-patterns))
 220
 221 (define-key-after hi-lock-menu [hi-lock-find-patterns]
 222   '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 223               :help "Use patterns (if any) near top of buffer."))
 224
 225 (defvar hi-lock-map (make-sparse-keymap "Hi Lock")
 226   "Key map for hi-lock.")
 227
 228 (define-key hi-lock-map "\C-xwi" 'hi-lock-find-patterns)
 229 (define-key hi-lock-map "\C-xwl" 'highlight-lines-matching-regexp)
 230 (define-key hi-lock-map "\C-xwp" 'highlight-phrase)
 231 (define-key hi-lock-map "\C-xwh" 'highlight-regexp)
 232 (define-key hi-lock-map "\C-xwr" 'unhighlight-regexp)
 233 (define-key hi-lock-map "\C-xwb" 'hi-lock-write-interactive-patterns)
 234
 235 (unless (assq 'hi-lock-mode minor-mode-map-alist)
 236   (setq minor-mode-map-alist (cons (cons 'hi-lock-mode hi-lock-map)
 237                                    minor-mode-map-alist)))
 238
 239 (unless (assq 'hi-lock-mode minor-mode-alist)
 240   (setq minor-mode-alist (cons '(hi-lock-mode " H") minor-mode-alist)))
 241
 242
 243 ;; Visible Functions
 244
 245
 246 ;;;###autoload
 247 (defun hi-lock-mode (&optional arg)
 248   "Toggle minor mode for interactively adding font-lock highlighting patterns.
 249
 250 If ARG positive turn hi-lock on.  Issuing a hi-lock command will also
 251 turn hi-lock on.  When hi-lock is turned on, a \"Regexp Highlighting\"
 252 submenu is added to the \"Edit\" menu.  The commands in the submenu,
 253 which can be called interactively, are:
 254
 255 \\[highlight-regexp] REGEXP FACE
 256   Highlight matches of pattern REGEXP in current buffer with FACE.
 257
 258 \\[highlight-phrase] PHRASE FACE
 259   Highlight matches of phrase PHRASE in current buffer with FACE.
 260   (PHRASE can be any REGEXP, but spaces will be replaced by matches
 261   to whitespace and initial lower-case letters will become case insensitive.)
 262
 263 \\[highlight-lines-matching-regexp] REGEXP FACE
 264   Highlight lines containing matches of REGEXP in current buffer with FACE.
 265
 266 \\[unhighlight-regexp] REGEXP
 267   Remove highlighting on matches of REGEXP in current buffer.
 268
 269 \\[hi-lock-write-interactive-patterns]
 270   Write active REGEXPs into buffer as comments (if possible). They will
 271   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 272   is issued.  The inserted regexps are in the form of font lock keywords.
 273   (See `font-lock-keywords') They may be edited and re-loaded with \\[hi-lock-find-patterns],
 274   any valid `font-lock-keywords' form is acceptable.
 275
 276 \\[hi-lock-find-patterns]
 277   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 278
 279 When hi-lock is started and if the mode is not excluded, the
 280 beginning of the buffer is searched for lines of the form:
 281   Hi-lock: FOO
 282 where FOO is a list of patterns. These are added to the font lock keywords
 283 already present.  The patterns must start before position (number
 284 of characters into buffer) `hi-lock-file-patterns-range'.  Patterns
 285 will be read until
 286  Hi-lock: end
 287 is found. A mode is excluded if it's in the list `hi-lock-exclude-modes'."
 288   (interactive)
 289   (let ((hi-lock-mode-prev hi-lock-mode))
 290     (setq hi-lock-mode
 291           (if (null arg) (not hi-lock-mode)
 292             (> (prefix-numeric-value arg) 0)))
 293     ;; Turned on.
 294     (when (and (not hi-lock-mode-prev) hi-lock-mode)
 295       (add-hook 'find-file-hooks 'hi-lock-find-file-hook)
 296       (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook)
 297       (define-key-after menu-bar-edit-menu [hi-lock]
 298         (cons "Regexp Highlighting" hi-lock-menu))
 299       (dolist (buffer (buffer-list))
 300         (with-current-buffer buffer (hi-lock-find-patterns))))
 301     ;; Turned off.
 302     (when (and hi-lock-mode-prev (not hi-lock-mode))
 303       (dolist (buffer (buffer-list))
 304         (with-current-buffer buffer
 305           (when (or hi-lock-interactive-patterns hi-lock-file-patterns)
 306             (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 307             (font-lock-remove-keywords nil hi-lock-file-patterns)
 308             (setq hi-lock-interactive-patterns nil
 309                   hi-lock-file-patterns nil)
 310             (when font-lock-mode (hi-lock-refontify)))))
 311       (define-key-after menu-bar-edit-menu [hi-lock] nil)
 312       (remove-hook 'find-file-hooks 'hi-lock-find-file-hook)
 313       (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook))))
 314
 315
 316 ;;;###autoload
 317 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 318 ;;;###autoload
 319 (defun hi-lock-line-face-buffer (regexp &optional face)
 320   "Set face of all lines containing a match of REGEXP to FACE.
 321
 322 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 323 list maintained for regexps, global history maintained for faces.
 324 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 325 \(See info node `Minibuffer History')"
 326   (interactive
 327    (list
 328     (hi-lock-regexp-okay
 329      (read-from-minibuffer "Regexp to highlight line: "
 330                            (cons (or (car hi-lock-regexp-history) "") 1 )
 331                            nil nil 'hi-lock-regexp-history))
 332     (hi-lock-read-face-name)))
 333   (unless hi-lock-mode (hi-lock-mode))
 334   (or (facep face) (setq face 'rwl-yellow))
 335   (hi-lock-set-pattern
 336    ;; The \\(?:...\\) grouping construct ensures that a leading ^, +, * or ?
 337    ;; or a trailing $ in REGEXP will be interpreted correctly.
 338    (list (concat "^.*\\(?:" regexp "\\).*$") (list 0 (list 'quote face) t))))
 339
 340
 341 ;;;###autoload
 342 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 343 ;;;###autoload
 344 (defun hi-lock-face-buffer (regexp &optional face)
 345   "Set face of each match of REGEXP to FACE.
 346
 347 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 348 list maintained for regexps, global history maintained for faces.
 349 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 350 \(See info node `Minibuffer History')"
 351   (interactive
 352    (list
 353     (hi-lock-regexp-okay
 354      (read-from-minibuffer "Regexp to highlight: "
 355                            (cons (or (car hi-lock-regexp-history) "") 1 )
 356                            nil nil 'hi-lock-regexp-history))
 357     (hi-lock-read-face-name)))
 358   (or (facep face) (setq face 'rwl-yellow))
 359   (unless hi-lock-mode (hi-lock-mode))
 360   (hi-lock-set-pattern (list regexp (list 0 (list 'quote face) t))))
 361
 362 ;;;###autoload
 363 (defalias 'highlight-phrase 'hi-lock-face-phrase-buffer)
 364 ;;;###autoload
 365 (defun hi-lock-face-phrase-buffer (regexp &optional face)
 366   "Set face of each match of phrase REGEXP to FACE.
 367
 368 Whitespace in REGEXP converted to arbitrary whitespace and initial
 369 lower-case letters made case insensitive."
 370   (interactive
 371    (list
 372     (hi-lock-regexp-okay
 373      (hi-lock-process-phrase
 374       (read-from-minibuffer "Phrase to highlight: "
 375                             (cons (or (car hi-lock-regexp-history) "") 1 )
 376                             nil nil 'hi-lock-regexp-history)))
 377     (hi-lock-read-face-name)))
 378   (or (facep face) (setq face 'rwl-yellow))
 379   (unless hi-lock-mode (hi-lock-mode))
 380   (hi-lock-set-pattern (list regexp (list 0 (list 'quote face) t))))
 381
 382 ;;;###autoload
 383 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 384 ;;;###autoload
 385 (defun hi-lock-unface-buffer (regexp)
 386   "Remove highlighting of each match to REGEXP set by hi-lock.
 387
 388 Interactively, prompt for REGEXP.  Buffer-local history of inserted
 389 regexp's maintained.  Will accept only regexps inserted by hi-lock
 390 interactive functions.  \(See `hi-lock-interactive-patterns'.\)
 391 \\<minibuffer-local-must-match-map>Use \\[minibuffer-complete] to complete a partially typed regexp.
 392 \(See info node `Minibuffer History'.\)"
 393   (interactive
 394    (if (and (display-popup-menus-p) (vectorp (this-command-keys)))
 395        (catch 'snafu
 396          (or
 397           (x-popup-menu
 398            t
 399            (cons
 400             `keymap
 401             (cons "Select Pattern to Unhighlight"
 402                   (mapcar (lambda (pattern)
 403                             (list (car pattern)
 404                                   (format
 405                                    "%s (%s)" (car pattern)
 406                                    (symbol-name
 407                                     (car
 408                                      (cdr (car (cdr (car (cdr pattern))))))))
 409                                   (cons nil nil)
 410                                   (car pattern)))
 411                           hi-lock-interactive-patterns))))
 412           ;; If the user clicks outside the menu, meaning that they
 413           ;; change their mind, x-popup-menu returns nil, and
 414           ;; interactive signals a wrong number of arguments error.
 415           ;; To prevent that, we return an empty string, which will
 416           ;; effectively disable the rest of the function.
 417           (throw 'snafu '(""))))
 418      (let ((history-list (mapcar (lambda (p) (car p))
 419                                  hi-lock-interactive-patterns)))
 420        (unless hi-lock-interactive-patterns
 421          (error "No highlighting to remove"))
 422        (list
 423         (completing-read "Regexp to unhighlight: "
 424                          hi-lock-interactive-patterns nil t
 425                          (car (car hi-lock-interactive-patterns))
 426                          (cons 'history-list 1))))))
 427   (let ((keyword (assoc regexp hi-lock-interactive-patterns)))
 428     (when keyword
 429       (font-lock-remove-keywords nil (list keyword))
 430       (setq hi-lock-interactive-patterns
 431             (delq keyword hi-lock-interactive-patterns))
 432       (hi-lock-refontify))))
 433
 434 ;;;###autoload
 435 (defun hi-lock-write-interactive-patterns ()
 436   "Write interactively added patterns, if any, into buffer at point.
 437
 438 Interactively added patterns are those normally specified using
 439 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 440 be found in variable `hi-lock-interactive-patterns'."
 441   (interactive)
 442   (let ((prefix (format "%s %s:" (or comment-start "") "Hi-lock")))
 443     (when (> (+ (point) (length prefix)) hi-lock-file-patterns-range)
 444       (beep)
 445       (message
 446        "Warning, inserted keywords not close enough to top of file."))
 447     (mapcar
 448      (lambda (pattern)
 449        (insert (format "%s (%s) %s\n"
 450                        prefix (prin1-to-string pattern) (or comment-end ""))))
 451      hi-lock-interactive-patterns)))
 452
 453
 454 ;; Implementation Functions
 455
 456 (defun hi-lock-process-phrase (phrase)
 457   "Convert regexp PHRASE to a regexp that matches phrases.
 458
 459 Blanks in PHRASE replaced by regexp that matches arbitrary whitespace
 460 and initial lower-case letters made case insensitive."
 461   (let ((mod-phrase nil))
 462     (setq mod-phrase
 463           (replace-regexp-in-string
 464            "\\<[a-z]" (lambda (m) (format "[%s%s]" (upcase m) m)) phrase))
 465     (setq mod-phrase
 466           (replace-regexp-in-string
 467            "\\s-+" "[ \t\n]+" mod-phrase nil t))))
 468
 469 (defun hi-lock-regexp-okay (regexp)
 470   "Return REGEXP if it appears suitable for a font-lock pattern.
 471
 472 Otherwise signal an error.  A pattern that matches the null string is
 473 not suitable."
 474   (if (string-match regexp "")
 475       (error "Regexp cannot match an empty string")
 476     regexp))
 477
 478 (defun hi-lock-read-face-name ()
 479   "Read face name from minibuffer with completion and history."
 480   (intern (completing-read
 481            "Highlight using face: "
 482            obarray 'facep t
 483            (cons (car hi-lock-face-history)
 484                  (let ((prefix
 485                         (try-completion
 486                          (substring (car hi-lock-face-history) 0 1)
 487                          (mapcar (lambda (f) (cons f f))
 488                                  hi-lock-face-history))))
 489                    (if (and (stringp prefix)
 490                             (not (equal prefix (car hi-lock-face-history))))
 491                        (length prefix) 0)))
 492            '(hi-lock-face-history . 0))))
 493
 494 (defun hi-lock-find-file-hook ()
 495   "Add hi-lock patterns, if present."
 496   (hi-lock-find-patterns))
 497
 498 (defun hi-lock-current-line (&optional end)
 499   "Return line number of line at point.
 500 Optional argument END is maximum excursion."
 501   (interactive)
 502   (save-excursion
 503     (beginning-of-line)
 504     (1+ (count-lines 1 (or end (point))))))
 505
 506 (defun hi-lock-set-pattern (pattern)
 507   "Add PATTERN to list of interactively highlighted patterns and refontify."
 508   (hi-lock-set-patterns (list pattern)))
 509
 510 (defun hi-lock-set-patterns (patterns)
 511   "Add PATTERNS to list of interactively highlighted patterns and refontify.."
 512   (dolist (pattern patterns)
 513     (unless (member pattern hi-lock-interactive-patterns)
 514       (font-lock-add-keywords nil (list pattern))
 515       (add-to-list 'hi-lock-interactive-patterns pattern)))
 516   (hi-lock-refontify))
 517
 518 (defun hi-lock-set-file-patterns (patterns)
 519   "Replace file patterns list with PATTERNS and refontify."
 520   (when (or hi-lock-file-patterns patterns)
 521     (font-lock-remove-keywords nil hi-lock-file-patterns)
 522     (setq hi-lock-file-patterns patterns)
 523     (font-lock-add-keywords nil hi-lock-file-patterns)
 524     (hi-lock-refontify)))
 525
 526 (defun hi-lock-refontify ()
 527   "Unfontify then refontify buffer.  Used when hi-lock patterns change."
 528   (interactive)
 529   (unless font-lock-mode (font-lock-mode 1))
 530   (font-lock-fontify-buffer))
 531
 532 (defun hi-lock-find-patterns ()
 533   "Find patterns in current buffer for hi-lock."
 534   (interactive)
 535   (unless (memq major-mode hi-lock-exclude-modes)
 536     (let ((all-patterns nil)
 537           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 538       (save-excursion
 539         (save-restriction
 540           (widen)
 541           (goto-char (point-min))
 542           (re-search-forward target-regexp
 543                              (+ (point) hi-lock-file-patterns-range) t)
 544           (beginning-of-line)
 545           (while (and (re-search-forward target-regexp (+ (point) 100) t)
 546                       (not (looking-at "\\s-*end")))
 547             (let ((patterns
 548                    (condition-case nil
 549                        (read (current-buffer))
 550                      (error  (message
 551                               (format "Could not read expression at %d"
 552                                       (hi-lock-current-line))) nil))))
 553               (if patterns
 554                   (setq all-patterns (append patterns all-patterns)))))))
 555       (when hi-lock-mode (hi-lock-set-file-patterns all-patterns))
 556       (if (interactive-p)
 557         (message (format "Hi-lock added %d patterns." (length all-patterns)))))))
 558
 559 (defun hi-lock-font-lock-hook ()
 560   "Add hi lock patterns to font-lock's."
 561   (when hi-lock-mode
 562     (font-lock-add-keywords nil hi-lock-file-patterns)
 563     (font-lock-add-keywords nil hi-lock-interactive-patterns)))
 564
 565 (provide 'hi-lock)
 566
 567 ;;; hi-lock.el ends here