lisp/timezone.el

   1 ;;; timezone.el --- time zone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1996, 1999, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu Umeda
   7 ;; Maintainer: umerin@mse.kyutech.ac.jp
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defvar timezone-world-timezones
  30   '(("PST" .  -800)
  31     ("PDT" .  -700)
  32     ("MST" .  -700)
  33     ("MDT" .  -600)
  34     ("CST" .  -600)
  35     ("CDT" .  -500)
  36     ("EST" .  -500)
  37     ("EDT" .  -400)
  38     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  39     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  40     ("UT"  .  +000)
  41     ("GMT" .  +000)
  42     ("BST" .  +100)
  43     ("MET" .  +100)
  44     ("EET" .  +200)
  45     ("JST" .  +900)
  46     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  47     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  48     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  49     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  50     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  51     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  52     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  53     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  54   "*Time differentials of timezone from GMT in +-HHMM form.
  55 This list is obsolescent, and is present only for backwards compatibility,
  56 because time zone names are ambiguous in practice.
  57 Use `current-time-zone' instead.")
  58
  59 (defvar timezone-months-assoc
  60   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  61     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  62     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  63     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  64   "Alist of first three letters of a month and its numerical representation.")
  65
  66 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  67   "Convert DATE to an arpanet standard date.
  68 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  69 if nil, GMT is assumed.
  70 Optional 3rd argument TIMEZONE specifies a time zone to be represented in;
  71 if nil, the local time zone is assumed."
  72   (let ((new (timezone-fix-time date local timezone)))
  73     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  74                              (timezone-make-time-string
  75                               (aref new 3) (aref new 4) (aref new 5))
  76                              (aref new 6))
  77     ))
  78
  79 (defun timezone-make-date-sortable (date &optional local timezone)
  80   "Convert DATE to a sortable date string.
  81 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  82 if nil, GMT is assumed.
  83 Optional 3rd argument TIMEZONE specifies a timezone to be represented in;
  84 if nil, the local time zone is assumed."
  85   (let ((new (timezone-fix-time date local timezone)))
  86     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  87                                  (timezone-make-time-string
  88                                   (aref new 3) (aref new 4) (aref new 5)))
  89     ))
  90
  91 \f
  92 ;;
  93 ;; Parsers and Constructors of Date and Time
  94 ;;
  95
  96 (defun timezone-make-arpa-date (year month day time &optional timezone)
  97   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  98 Optional argument TIMEZONE specifies a time zone."
  99   (let ((zone
 100          (if (listp timezone)
 101              (let* ((m (timezone-zone-to-minute timezone))
 102                     (absm (if (< m 0) (- m) m)))
 103                (format "%c%02d%02d"
 104                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 105            timezone)))
 106     (format "%02d %s %04d %s %s"
 107             day
 108             (capitalize (car (rassq month timezone-months-assoc)))
 109             year
 110             time
 111             zone)))
 112
 113 (defun timezone-make-sortable-date (year month day time)
 114   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 115   (format "%4d%02d%02d%s"
 116           year month day time))
 117
 118 (defun timezone-make-time-string (hour minute second)
 119   "Make time string from HOUR, MINUTE, and SECOND."
 120   (format "%02d:%02d:%02d" hour minute second))
 121
 122 (defun timezone-parse-date (date)
 123   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 124 Two-digit dates are `windowed'.  Those <69 have 2000 added; otherwise 1900
 125 is added.  Three-digit dates have 1900 added.
 126 TIMEZONE is nil for DATEs without a zone field.
 127
 128 Understands the following styles:
 129  (1) 14 Apr 89 03:20[:12] [GMT]
 130  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 131  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 132  (4) 6 May 1992 1641-JST (Wednesday)
 133  (5) 22-AUG-1993 10:59:12.82
 134  (6) Thu, 11 Apr 16:17:12 91 [MET]
 135  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]
 136  (8) 1996-06-24 21:13:12 [GMT]
 137  (9) 1996-06-24 21:13-ZONE"
 138  ;; Get rid of any text properties.
 139   (and (stringp date)
 140        (or (text-properties-at 0 date)
 141            (next-property-change 0 date))
 142        (setq date (copy-sequence date))
 143        (set-text-properties 0 (length date) nil date))
 144   (let ((date (or date ""))
 145         (year nil)
 146         (month nil)
 147         (day nil)
 148         (time nil)
 149         (zone nil))                     ;This may be nil.
 150     (cond ((string-match
 151             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 152            ;; Styles: (1) and (2) with timezone and buggy timezone
 153            ;; This is most common in mail and news,
 154            ;; so it is worth trying first.
 155            (setq year 3 month 2 day 1 time 4 zone 5))
 156           ((string-match
 157             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 158            ;; Styles: (1) and (2) without timezone
 159            (setq year 3 month 2 day 1 time 4 zone nil))
 160           ((string-match
 161             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 162            ;; Styles: (6) and (7) without timezone
 163            (setq year 6 month 3 day 2 time 4 zone nil))
 164           ((string-match
 165             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 166            ;; Styles: (6) and (7) with timezone and buggy timezone
 167            (setq year 6 month 3 day 2 time 4 zone 7))
 168           ((string-match
 169             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 170            ;; Styles: (3) without timezone
 171            (setq year 4 month 1 day 2 time 3 zone nil))
 172           ((string-match
 173             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 174            ;; Styles: (3) with timezone
 175            (setq year 5 month 1 day 2 time 3 zone 4))
 176           ((string-match
 177             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 178            ;; Styles: (4) with timezone
 179            (setq year 3 month 2 day 1 time 4 zone 5))
 180           ((string-match
 181             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 182            ;; Styles: (5) with timezone.
 183            (setq year 3 month 2 day 1 time 4 zone 6))
 184           ((string-match
 185             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?" date)
 186            ;; Styles: (5) without timezone.
 187            (setq year 3 month 2 day 1 time 4 zone nil))
 188           ((string-match
 189             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 190            ;; Styles: (8) with timezone.
 191            (setq year 1 month 2 day 3 time 4 zone 5))
 192           ((string-match
 193             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[T \t]+\\([0-9]+:[0-9]+\\)[ \t]+\\([-+a-zA-Z0-9:]+\\)" date)
 194            ;; Styles: (8) with timezone with a colon in it.
 195            (setq year 1 month 2 day 3 time 4 zone 5))
 196           ((string-match
 197             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[T \t]+\\([0-9]+:[0-9]+:[0-9]+\\)" date)
 198            ;; Styles: (8) without timezone.
 199            (setq year 1 month 2 day 3 time 4 zone nil))
 200           )
 201     (when year
 202       (setq year (match-string year date))
 203       ;; Guess ambiguous years.  Assume years < 69 don't predate the
 204       ;; Unix Epoch, so are 2000+.  Three-digit years are assumed to
 205       ;; be relative to 1900.
 206       (if (< (length year) 4)
 207           (let ((y (string-to-number year)))
 208             (if (< y 69)
 209                 (setq y (+ y 100)))
 210             (setq year (int-to-string (+ 1900 y)))))
 211       (setq month
 212             (if (= (aref date (+ (match-beginning month) 2)) ?-)
 213                 ;; Handle numeric months, spanning exactly two digits.
 214                 (substring date
 215                            (match-beginning month)
 216                            (+ (match-beginning month) 2))
 217               (let* ((string (substring date
 218                                         (match-beginning month)
 219                                         (+ (match-beginning month) 3)))
 220                      (monthnum
 221                       (cdr (assoc (upcase string) timezone-months-assoc))))
 222                 (if monthnum
 223                     (int-to-string monthnum)))))
 224       (setq day (match-string day date))
 225       (setq time (match-string time date)))
 226     (if zone (setq zone (match-string zone date)))
 227     ;; Return a vector.
 228     (if (and year month)
 229         (vector year month day time zone)
 230       (vector "0" "0" "0" "0" nil))))
 231
 232 (defun timezone-parse-time (time)
 233   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 234 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 235   (let ((time (or time ""))
 236         hour minute second)
 237     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 238            ;; HH:MM:SS
 239            (setq hour 1 minute 2 second 3))
 240           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 241            ;; HH:MM
 242            (setq hour 1 minute 2 second nil))
 243           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 244            ;; HHMMSS
 245            (setq hour 1 minute 2 second 3))
 246           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 247            ;; HHMM
 248            (setq hour 1 minute 2 second nil))
 249           )
 250     ;; Return [hour minute second]
 251     (vector
 252      (if hour (match-string hour time) "0")
 253      (if minute (match-string minute time) "0")
 254      (if second (match-string second time) "0"))))
 255
 256 \f
 257 ;; Miscellaneous
 258
 259 (defun timezone-zone-to-minute (timezone)
 260   "Translate TIMEZONE to an integer minute offset from GMT.
 261 TIMEZONE can be a cons cell containing the output of `current-time-zone',
 262 or an integer of the form +-HHMM, or a time zone name."
 263   (cond
 264      ((consp timezone)
 265       (/ (car timezone) 60))
 266      (timezone
 267       (progn
 268         (setq timezone
 269               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 270                   ;; +900
 271                   timezone))
 272         (if (stringp timezone)
 273             (setq timezone (string-to-number timezone)))
 274         ;; Taking account of minute in timezone.
 275         ;; HHMM -> MM
 276         (let* ((abszone (abs timezone))
 277                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 278           (if (< timezone 0) (- minutes) minutes))))
 279      (t 0)))
 280
 281 (defun timezone-time-from-absolute (date seconds)
 282   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 283 Return a list suitable as an argument to `current-time-zone',
 284 or nil if the date cannot be thus represented.
 285 DATE is the number of days elapsed since the (imaginary)
 286 Gregorian date Sunday, December 31, 1 BC."
 287   (let* ((current-time-origin 719163)
 288             ;; (timezone-absolute-from-gregorian 1 1 1970)
 289          (days (- date current-time-origin))
 290          (seconds-per-day (float 86400))
 291          (seconds (+ seconds (* days seconds-per-day)))
 292          (current-time-arithmetic-base (float 65536))
 293          (hi (floor (/ seconds current-time-arithmetic-base)))
 294          (hibase (* hi current-time-arithmetic-base))
 295          (lo (floor (- seconds hibase))))
 296      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 297           (cons hi lo))))
 298
 299 (defun timezone-time-zone-from-absolute (date seconds)
 300   "Compute the local time zone for DATE at time SECONDS after midnight.
 301 Return a list in the same format as `current-time-zone's result,
 302 or nil if the local time zone could not be computed.
 303 DATE is the number of days elapsed since the (imaginary)
 304 Gregorian date Sunday, December 31, 1 BC."
 305    (and (fboundp 'current-time-zone)
 306         (let ((utc-time (timezone-time-from-absolute date seconds)))
 307           (and utc-time
 308                (let ((zone (current-time-zone utc-time)))
 309                  (and (car zone) zone))))))
 310
 311 (defun timezone-fix-time (date local timezone)
 312   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 313 If LOCAL is nil, it is assumed to be GMT.
 314 If TIMEZONE is nil, use the local time zone."
 315   (let* ((date   (timezone-parse-date date))
 316          (year   (string-to-number (aref date 0)))
 317          (year   (cond ((< year 69)
 318                         (+ year 2000))
 319                        ((< year 100)
 320                         (+ year 1900))
 321                        ((< year 1000)   ; possible 3-digit years.
 322                         (+ year 1900))
 323                        (t year)))
 324          (month  (string-to-number (aref date 1)))
 325          (day    (string-to-number (aref date 2)))
 326          (time   (timezone-parse-time (aref date 3)))
 327          (hour   (string-to-number (aref time 0)))
 328          (minute (string-to-number (aref time 1)))
 329          (second (string-to-number (aref time 2)))
 330          (local  (or (aref date 4) local)) ;Use original if defined
 331          (timezone
 332           (or timezone
 333               (timezone-time-zone-from-absolute
 334                (timezone-absolute-from-gregorian month day year)
 335                (+ second (* 60 (+ minute (* 60 hour)))))))
 336          (diff   (- (timezone-zone-to-minute timezone)
 337                     (timezone-zone-to-minute local)))
 338          (minute (+ minute diff))
 339          (hour-fix (floor minute 60)))
 340     (setq hour (+ hour hour-fix))
 341     (setq minute (- minute (* 60 hour-fix)))
 342     ;; HOUR may be larger than 24 or smaller than 0.
 343     (cond ((<= 24 hour)                 ;24 -> 00
 344            (setq hour (- hour 24))
 345            (setq day  (1+ day))
 346            (when (< (timezone-last-day-of-month month year) day)
 347              (setq month (1+ month))
 348              (setq day 1)
 349              (when (< 12 month)
 350                (setq month 1)
 351                (setq year (1+ year)))))
 352           ((> 0 hour)
 353            (setq hour (+ hour 24))
 354            (setq day  (1- day))
 355            (when (> 1 day)
 356              (setq month (1- month))
 357              (when (> 1 month)
 358                (setq month 12)
 359                (setq year (1- year)))
 360              (setq day (timezone-last-day-of-month month year)))))
 361     (vector year month day hour minute second timezone)))
 362
 363 ;; Partly copied from Calendar program by Edward M. Reingold.
 364 ;; Thanks a lot.
 365
 366 (defun timezone-last-day-of-month (month year)
 367   "The last day in MONTH during YEAR."
 368   (if (and (= month 2) (timezone-leap-year-p year))
 369       29
 370     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 371
 372 (defun timezone-leap-year-p (year)
 373   "Return t if YEAR is a Gregorian leap year."
 374   (or (and (zerop  (% year 4))
 375            (not (zerop (% year 100))))
 376       (zerop (% year 400))))
 377
 378 (defun timezone-day-number (month day year)
 379   "Return the day number within the year of the date month/day/year."
 380   (let ((day-of-year (+ day (* 31 (1- month)))))
 381     (if (> month 2)
 382         (progn
 383           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 384           (if (timezone-leap-year-p year)
 385               (setq day-of-year (1+ day-of-year)))))
 386     day-of-year))
 387
 388 (defun timezone-absolute-from-gregorian (month day year)
 389   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 390 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 391   (+ (timezone-day-number month day year);; Days this year
 392      (* 365 (1- year));;        + Days in prior years
 393      (/ (1- year) 4);;          + Julian leap years
 394      (- (/ (1- year) 100));;    - century years
 395      (/ (1- year) 400)));;      + Gregorian leap years
 396
 397 (provide 'timezone)
 398
 399 ;; arch-tag: e23d5bc6-f32d-48ba-8996-323e9d654b3f
 400 ;;; timezone.el ends here