lisp/password-cache.el

   1 ;;; password-cache.el --- Read passwords, possibly using a password cache.
   2
   3 ;; Copyright (C) 1999, 2000, 2003, 2004, 2005, 2006, 2007, 2008
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <simon@josefsson.org>
   7 ;; Created: 2003-12-21
   8 ;; Keywords: password cache passphrase key
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Greatly influenced by pgg.el written by Daiki Ueno, with timer
  30 ;; fixes for XEmacs by Katsumi Yamaoka.  In fact, this is mostly just
  31 ;; a rip-off.
  32 ;;
  33 ;; (password-read "Password? " "test")
  34 ;; ;; Minibuffer prompt for password.
  35 ;;  => "foo"
  36 ;;
  37 ;; (password-cache-add "test" "foo")
  38 ;;  => nil
  39
  40 ;; (password-read "Password? " "test")
  41 ;; ;; No minibuffer prompt
  42 ;;  => "foo"
  43 ;;
  44 ;; (password-read "Password? " "test")
  45 ;; ;; No minibuffer prompt
  46 ;;  => "foo"
  47 ;;
  48 ;; ;; Wait `password-cache-expiry' seconds.
  49 ;;
  50 ;; (password-read "Password? " "test")
  51 ;; ;; Minibuffer prompt for password is back.
  52 ;;  => "foo"
  53
  54 ;;; Code:
  55
  56 (defcustom password-cache t
  57   "Whether to cache passwords."
  58   :group 'password
  59   :type 'boolean)
  60
  61 (defcustom password-cache-expiry 16
  62   "How many seconds passwords are cached, or nil to disable expiring.
  63 Whether passwords are cached at all is controlled by `password-cache'."
  64   :group 'password
  65   :type '(choice (const :tag "Never" nil)
  66                  (integer :tag "Seconds")))
  67
  68 (defvar password-data (make-vector 7 0))
  69
  70 (defun password-read-from-cache (key)
  71   "Obtain passphrase for KEY from time-limited passphrase cache.
  72 Custom variables `password-cache' and `password-cache-expiry'
  73 regulate cache behavior."
  74   (and password-cache
  75        key
  76        (symbol-value (intern-soft key password-data))))
  77
  78 (defun password-read (prompt &optional key)
  79   "Read password, for use with KEY, from user, or from cache if wanted.
  80 KEY indicate the purpose of the password, so the cache can
  81 separate passwords.  The cache is not used if KEY is nil.  It is
  82 typically a string.
  83 The variable `password-cache' control whether the cache is used."
  84   (or (password-read-from-cache key)
  85       (read-passwd prompt)))
  86
  87 (defun password-read-and-add (prompt &optional key)
  88   "Read password, for use with KEY, from user, or from cache if wanted.
  89 Then store the password in the cache.  Uses `password-read' and
  90 `password-cache-add'.  Custom variables `password-cache' and
  91 `password-cache-expiry' regulate cache behavior.
  92
  93 Warning: the password is cached without checking that it is
  94 correct.  It is better to check the password before caching.  If
  95 you must use this function, take care to check passwords and
  96 remove incorrect ones from the cache."
  97   (let ((password (password-read prompt key)))
  98     (when (and password key)
  99       (password-cache-add key password))
 100     password))
 101
 102 (make-obsolete 'password-read-and-add 'password-read "23.1")
 103
 104 (defun password-cache-remove (key)
 105   "Remove password indexed by KEY from password cache.
 106 This is typically run be a timer setup from `password-cache-add',
 107 but can be invoked at any time to forcefully remove passwords
 108 from the cache.  This may be useful when it has been detected
 109 that a password is invalid, so that `password-read' query the
 110 user again."
 111   (let ((password (symbol-value (intern-soft key password-data))))
 112     (when password
 113       (if (fboundp 'clear-string)
 114           (clear-string password)
 115         (fillarray password ?_))
 116       (unintern key password-data))))
 117
 118 (defun password-cache-add (key password)
 119   "Add password to cache.
 120 The password is removed by a timer after `password-cache-expiry' seconds."
 121   (when (and password-cache-expiry (null (intern-soft key password-data)))
 122     (run-at-time password-cache-expiry nil
 123                  #'password-cache-remove
 124                  key))
 125   (set (intern key password-data) password)
 126   nil)
 127
 128 (defun password-reset ()
 129   "Clear the password cache."
 130   (interactive)
 131   (fillarray password-data 0))
 132
 133 (provide 'password-cache)
 134
 135 ;;; arch-tag: ab160494-16c8-4c68-a4a1-73eebf6686e5
 136 ;;; password-cache.el ends here