lisp/dired-aux.el

   1 ;;; dired-aux.el --- all of dired except what people usually use
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>.
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; The parts of dired mode not normally used.  This is a space-saving hack
  26 ;; to avoid having to load a large mode when all that's wanted are a few
  27 ;; functions.
  28
  29 ;; Rewritten in 1990/1991 to add tree features, file marking and
  30 ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>.
  31 ;; Finished up by rms in 1992.
  32
  33 ;;; Code:
  34
  35 ;; We need macros in dired.el to compile properly.
  36 (eval-when-compile (require 'dired))
  37
  38 ;;; 15K
  39 ;;;###begin dired-cmd.el
  40 ;; Diffing and compressing
  41
  42 ;;;###autoload
  43 (defun dired-diff (file &optional switches)
  44   "Compare file at point with file FILE using `diff'.
  45 FILE defaults to the file at the mark.
  46 The prompted-for file is the first file given to `diff'.
  47 With prefix arg, prompt for second argument SWITCHES,
  48  which is options for `diff'."
  49   (interactive
  50    (let ((default (if (mark t)
  51                       (save-excursion (goto-char (mark t))
  52                                       (dired-get-filename t t)))))
  53      (require 'diff)
  54      (list (read-file-name (format "Diff %s with: %s"
  55                                    (dired-get-filename t)
  56                                    (if default
  57                                        (concat "(default " default ") ")
  58                                      ""))
  59                            (dired-current-directory) default t)
  60            (if current-prefix-arg
  61                (read-string "Options for diff: "
  62                             (if (stringp diff-switches)
  63                                 diff-switches
  64                               (mapconcat 'identity diff-switches " ")))))))
  65   (diff file (dired-get-filename t) switches))
  66
  67 ;;;###autoload
  68 (defun dired-backup-diff (&optional switches)
  69   "Diff this file with its backup file or vice versa.
  70 Uses the latest backup, if there are several numerical backups.
  71 If this file is a backup, diff it with its original.
  72 The backup file is the first file given to `diff'.
  73 With prefix arg, prompt for argument SWITCHES which is options for `diff'."
  74   (interactive
  75     (if current-prefix-arg
  76         (list (read-string "Options for diff: "
  77                            (if (stringp diff-switches)
  78                                diff-switches
  79                              (mapconcat 'identity diff-switches " "))))
  80       nil))
  81   (diff-backup (dired-get-filename) switches))
  82
  83 (defun dired-do-chxxx (attribute-name program op-symbol arg)
  84   ;; Change file attributes (mode, group, owner) of marked files and
  85   ;; refresh their file lines.
  86   ;; ATTRIBUTE-NAME is a string describing the attribute to the user.
  87   ;; PROGRAM is the program used to change the attribute.
  88   ;; OP-SYMBOL is the type of operation (for use in dired-mark-pop-up).
  89   ;; ARG describes which files to use, as in dired-get-marked-files.
  90   (let* ((files (dired-get-marked-files t arg))
  91          (new-attribute
  92           (dired-mark-read-string
  93            (concat "Change " attribute-name " of %s to: ")
  94            nil op-symbol arg files))
  95          (operation (concat program " " new-attribute))
  96          failures)
  97     (setq failures
  98           (dired-bunch-files 10000
  99                              (function dired-check-process)
 100                              (list operation program new-attribute)
 101                              files))
 102     (dired-do-redisplay arg);; moves point if ARG is an integer
 103     (if failures
 104         (dired-log-summary
 105          (format "%s: error" operation)
 106          nil))))
 107
 108 ;;;###autoload
 109 (defun dired-do-chmod (&optional arg)
 110   "Change the mode of the marked (or next ARG) files.
 111 This calls chmod, thus symbolic modes like `g+w' are allowed."
 112   (interactive "P")
 113   (dired-do-chxxx "Mode" "chmod" 'chmod arg))
 114
 115 ;;;###autoload
 116 (defun dired-do-chgrp (&optional arg)
 117   "Change the group of the marked (or next ARG) files."
 118   (interactive "P")
 119   (dired-do-chxxx "Group" "chgrp" 'chgrp arg))
 120
 121 ;;;###autoload
 122 (defun dired-do-chown (&optional arg)
 123   "Change the owner of the marked (or next ARG) files."
 124   (interactive "P")
 125   (dired-do-chxxx "Owner" dired-chown-program 'chown arg))
 126
 127 ;; Process all the files in FILES in batches of a convenient size,
 128 ;; by means of (FUNCALL FUNCTION ARGS... SOME-FILES...).
 129 ;; Batches are chosen to need less than MAX chars for the file names,
 130 ;; allowing 3 extra characters of separator per file name.
 131 (defun dired-bunch-files (max function args files)
 132   (let (pending
 133         (pending-length 0)
 134         failures)
 135     ;; Accumulate files as long as they fit in MAX chars,
 136     ;; then process the ones accumulated so far.
 137     (while files
 138       (let* ((thisfile (car files))
 139              (thislength (+ (length thisfile) 3))
 140              (rest (cdr files)))
 141         ;; If we have at least 1 pending file
 142         ;; and this file won't fit in the length limit, process now.
 143         (if (and pending (> (+ thislength pending-length) max))
 144             (setq failures
 145                   (nconc (apply function (append args pending))
 146                          failures)
 147                   pending nil
 148                   pending-length 0))
 149         ;; Do (setq pending (cons thisfile pending))
 150         ;; but reuse the cons that was in `files'.
 151         (setcdr files pending)
 152         (setq pending files)
 153         (setq pending-length (+ thislength pending-length))
 154         (setq files rest)))
 155     (nconc (apply function (append args pending))
 156            failures)))
 157
 158 ;;;###autoload
 159 (defun dired-do-print (&optional arg)
 160   "Print the marked (or next ARG) files.
 161 Uses the shell command coming from variables `lpr-command' and
 162 `lpr-switches' as default."
 163   (interactive "P")
 164   (let* ((file-list (dired-get-marked-files t arg))
 165          (command (dired-mark-read-string
 166                    "Print %s with: "
 167                    (apply 'concat lpr-command " " lpr-switches)
 168                    'print arg file-list)))
 169     (dired-run-shell-command (dired-shell-stuff-it command file-list nil))))
 170
 171 ;; Read arguments for a marked-files command that wants a string
 172 ;; that is not a file name,
 173 ;; perhaps popping up the list of marked files.
 174 ;; ARG is the prefix arg and indicates whether the files came from
 175 ;; marks (ARG=nil) or a repeat factor (integerp ARG).
 176 ;; If the current file was used, the list has but one element and ARG
 177 ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)).
 178
 179 (defun dired-mark-read-string (prompt initial op-symbol arg files)
 180   ;; PROMPT for a string, with INITIAL input.
 181   ;; Other args are used to give user feedback and pop-up:
 182   ;; OP-SYMBOL of command, prefix ARG, marked FILES.
 183   (dired-mark-pop-up
 184    nil op-symbol files
 185    (function read-string)
 186    (format prompt (dired-mark-prompt arg files)) initial))
 187 \f
 188 ;;; Cleaning a directory: flagging some backups for deletion.
 189
 190 (defvar dired-file-version-alist)
 191
 192 (defun dired-clean-directory (keep)
 193   "Flag numerical backups for deletion.
 194 Spares `dired-kept-versions' latest versions, and `kept-old-versions' oldest.
 195 Positive prefix arg KEEP overrides `dired-kept-versions';
 196 Negative prefix arg KEEP overrides `kept-old-versions' with KEEP made positive.
 197
 198 To clear the flags on these files, you can use \\[dired-flag-backup-files]
 199 with a prefix argument."
 200   (interactive "P")
 201   (setq keep (if keep (prefix-numeric-value keep) dired-kept-versions))
 202   (let ((early-retention (if (< keep 0) (- keep) kept-old-versions))
 203         (late-retention (if (<= keep 0) dired-kept-versions keep))
 204         (dired-file-version-alist ()))
 205     (message "Cleaning numerical backups (keeping %d late, %d old)..."
 206              late-retention early-retention)
 207     ;; Look at each file.
 208     ;; If the file has numeric backup versions,
 209     ;; put on dired-file-version-alist an element of the form
 210     ;; (FILENAME . VERSION-NUMBER-LIST)
 211     (dired-map-dired-file-lines (function dired-collect-file-versions))
 212     ;; Sort each VERSION-NUMBER-LIST,
 213     ;; and remove the versions not to be deleted.
 214     (let ((fval dired-file-version-alist))
 215       (while fval
 216         (let* ((sorted-v-list (cons 'q (sort (cdr (car fval)) '<)))
 217                (v-count (length sorted-v-list)))
 218           (if (> v-count (+ early-retention late-retention))
 219               (rplacd (nthcdr early-retention sorted-v-list)
 220                       (nthcdr (- v-count late-retention)
 221                               sorted-v-list)))
 222           (rplacd (car fval)
 223                   (cdr sorted-v-list)))
 224         (setq fval (cdr fval))))
 225     ;; Look at each file.  If it is a numeric backup file,
 226     ;; find it in a VERSION-NUMBER-LIST and maybe flag it for deletion.
 227     (dired-map-dired-file-lines (function dired-trample-file-versions))
 228     (message "Cleaning numerical backups...done")))
 229
 230 ;;; Subroutines of dired-clean-directory.
 231
 232 (defun dired-map-dired-file-lines (fun)
 233   ;; Perform FUN with point at the end of each non-directory line.
 234   ;; FUN takes one argument, the filename (complete pathname).
 235   (save-excursion
 236     (let (file buffer-read-only)
 237       (goto-char (point-min))
 238       (while (not (eobp))
 239         (save-excursion
 240           (and (not (looking-at dired-re-dir))
 241                (not (eolp))
 242                (setq file (dired-get-filename nil t)) ; nil on non-file
 243                (progn (end-of-line)
 244                       (funcall fun file))))
 245         (forward-line 1)))))
 246
 247 (defun dired-collect-file-versions (fn)
 248   ;;  "If it looks like file FN has versions, return a list of the versions.
 249   ;;That is a list of strings which are file names.
 250   ;;The caller may want to flag some of these files for deletion."
 251     (let* ((base-versions
 252             (concat (file-name-nondirectory fn) ".~"))
 253            (bv-length (length base-versions))
 254            (possibilities (file-name-all-completions
 255                            base-versions
 256                            (file-name-directory fn)))
 257            (versions (mapcar 'backup-extract-version possibilities)))
 258       (if versions
 259           (setq dired-file-version-alist (cons (cons fn versions)
 260                                                dired-file-version-alist)))))
 261
 262 (defun dired-trample-file-versions (fn)
 263   (let* ((start-vn (string-match "\\.~[0-9]+~$" fn))
 264          base-version-list)
 265     (and start-vn
 266          (setq base-version-list        ; there was a base version to which
 267                (assoc (substring fn 0 start-vn) ; this looks like a
 268                       dired-file-version-alist))        ; subversion
 269          (not (memq (string-to-int (substring fn (+ 2 start-vn)))
 270                     base-version-list)) ; this one doesn't make the cut
 271          (progn (beginning-of-line)
 272                 (delete-char 1)
 273                 (insert dired-del-marker)))))
 274 \f
 275 ;;; Shell commands
 276 ;;>>> install (move this function into simple.el)
 277 (defun dired-shell-quote (filename)
 278   "Quote a file name for inferior shell (see variable `shell-file-name')."
 279   ;; Quote everything except POSIX filename characters.
 280   ;; This should be safe enough even for really weird shells.
 281   (let ((result "") (start 0) end)
 282     (while (string-match "[^-0-9a-zA-Z_./]" filename start)
 283       (setq end (match-beginning 0)
 284             result (concat result (substring filename start end)
 285                            "\\" (substring filename end (1+ end)))
 286             start (1+ end)))
 287     (concat result (substring filename start))))
 288
 289 (defun dired-read-shell-command (prompt arg files)
 290 ;;  "Read a dired shell command prompting with PROMPT (using read-string).
 291 ;;ARG is the prefix arg and may be used to indicate in the prompt which
 292 ;;  files are affected.
 293 ;;This is an extra function so that you can redefine it, e.g., to use gmhist."
 294   (dired-mark-pop-up
 295    nil 'shell files
 296    (function read-string)
 297    (format prompt (dired-mark-prompt arg files))))
 298
 299 ;; The in-background argument is only needed in Emacs 18 where
 300 ;; shell-command doesn't understand an appended ampersand `&'.
 301 ;;;###autoload
 302 (defun dired-do-shell-command (command &optional arg)
 303   "Run a shell command COMMAND on the marked files.
 304 If no files are marked or a specific numeric prefix arg is given,
 305 the next ARG files are used.  Just \\[universal-argument] means the current file.
 306 The prompt mentions the file(s) or the marker, as appropriate.
 307
 308 If there is output, it goes to a separate buffer.
 309
 310 Normally the command is run on each file individually.
 311 However, if there is a `*' in the command then it is run
 312 just once with the entire file list substituted there.
 313
 314 No automatic redisplay of dired buffers is attempted, as there's no
 315 telling what files the command may have changed.  Type
 316 \\[dired-do-redisplay] to redisplay the marked files.
 317
 318 The shell command has the top level directory as working directory, so
 319 output files usually are created there instead of in a subdir."
 320 ;;Functions dired-run-shell-command and dired-shell-stuff-it do the
 321 ;;actual work and can be redefined for customization.
 322   (interactive (list
 323                 ;; Want to give feedback whether this file or marked files are used:
 324                 (dired-read-shell-command (concat "! on "
 325                                                   "%s: ")
 326                                           current-prefix-arg
 327                                           (dired-get-marked-files
 328                                            t current-prefix-arg))
 329                 current-prefix-arg))
 330   (let* ((on-each (not (string-match "\\*" command)))
 331          (file-list (dired-get-marked-files t arg)))
 332     (if on-each
 333         (dired-bunch-files
 334          (- 10000 (length command))
 335          (function (lambda (&rest files)
 336                      (dired-run-shell-command
 337                       (dired-shell-stuff-it command files t arg))))
 338          nil
 339          file-list)
 340       ;; execute the shell command
 341       (dired-run-shell-command
 342        (dired-shell-stuff-it command file-list nil arg)))))
 343
 344 ;; Might use {,} for bash or csh:
 345 (defvar dired-mark-prefix ""
 346   "Prepended to marked files in dired shell commands.")
 347 (defvar dired-mark-postfix ""
 348   "Appended to marked files in dired shell commands.")
 349 (defvar dired-mark-separator " "
 350   "Separates marked files in dired shell commands.")
 351
 352 (defun dired-shell-stuff-it (command file-list on-each &optional raw-arg)
 353 ;; "Make up a shell command line from COMMAND and FILE-LIST.
 354 ;; If ON-EACH is t, COMMAND should be applied to each file, else
 355 ;; simply concat all files and apply COMMAND to this.
 356 ;; FILE-LIST's elements will be quoted for the shell."
 357 ;; Might be redefined for smarter things and could then use RAW-ARG
 358 ;; (coming from interactive P and currently ignored) to decide what to do.
 359 ;; Smart would be a way to access basename or extension of file names.
 360 ;; See dired-trns.el for an approach to this.
 361   ;; Bug: There is no way to quote a *
 362   ;; On the other hand, you can never accidentally get a * into your cmd.
 363   (let ((stuff-it
 364          (if (string-match "\\*" command)
 365              (function (lambda (x)
 366                          (dired-replace-in-string "\\*" x command)))
 367            (function (lambda (x) (concat command " " x))))))
 368     (if on-each
 369         (mapconcat stuff-it (mapcar 'dired-shell-quote file-list) ";")
 370       (let ((fns (mapconcat 'dired-shell-quote
 371                             file-list dired-mark-separator)))
 372         (if (> (length file-list) 1)
 373             (setq fns (concat dired-mark-prefix fns dired-mark-postfix)))
 374         (funcall stuff-it fns)))))
 375
 376 ;; This is an extra function so that it can be redefined by ange-ftp.
 377 (defun dired-run-shell-command (command)
 378   (shell-command command)
 379   ;; Return nil for sake of nconc in dired-bunch-files.
 380   nil)
 381 \f
 382 ;; In Emacs 19 this will return program's exit status.
 383 ;; This is a separate function so that ange-ftp can redefine it.
 384 (defun dired-call-process (program discard &rest arguments)
 385 ;  "Run PROGRAM with output to current buffer unless DISCARD is t.
 386 ;Remaining arguments are strings passed as command arguments to PROGRAM."
 387   (apply 'call-process program nil (not discard) nil arguments))
 388
 389 (defun dired-check-process (msg program &rest arguments)
 390 ;  "Display MSG while running PROGRAM, and check for output.
 391 ;Remaining arguments are strings passed as command arguments to PROGRAM.
 392 ; On error, insert output
 393 ; in a log buffer and return the offending ARGUMENTS or PROGRAM.
 394 ; Caller can cons up a list of failed args.
 395 ;Else returns nil for success."
 396   (let (err-buffer err (dir default-directory))
 397     (message "%s..." msg)
 398     (save-excursion
 399       ;; Get a clean buffer for error output:
 400       (setq err-buffer (get-buffer-create " *dired-check-process output*"))
 401       (set-buffer err-buffer)
 402       (erase-buffer)
 403       (setq default-directory dir       ; caller's default-directory
 404             err (/= 0
 405                  (apply (function dired-call-process) program nil arguments)))
 406       (if err
 407           (progn
 408             (dired-log (concat program " " (prin1-to-string arguments) "\n"))
 409             (dired-log err-buffer)
 410             (or arguments program t))
 411         (kill-buffer err-buffer)
 412         (message "%s...done" msg)
 413         nil))))
 414 \f
 415 ;; Commands that delete or redisplay part of the dired buffer.
 416
 417 (defun dired-kill-line (&optional arg)
 418   (interactive "P")
 419   (setq arg (prefix-numeric-value arg))
 420   (let (buffer-read-only file)
 421     (while (/= 0 arg)
 422       (setq file (dired-get-filename nil t))
 423       (if (not file)
 424           (error "Can only kill file lines.")
 425         (save-excursion (and file
 426                              (dired-goto-subdir file)
 427                              (dired-kill-subdir)))
 428         (delete-region (progn (beginning-of-line) (point))
 429                        (progn (forward-line 1) (point)))
 430         (if (> arg 0)
 431             (setq arg (1- arg))
 432           (setq arg (1+ arg))
 433           (forward-line -1))))
 434     (dired-move-to-filename)))
 435
 436 ;;;###autoload
 437 (defun dired-do-kill-lines (&optional arg fmt)
 438   "Kill all marked lines (not the files).
 439 With a prefix argument, kill that many lines starting with the current line.
 440 \(A negative argument kills lines before the current line.)
 441 To kill an entire subdirectory, go to its directory header line
 442 and use this command with a prefix argument (the value does not matter)."
 443   ;; Returns count of killed lines.  FMT="" suppresses message.
 444   (interactive "P")
 445   (if arg
 446       (if (dired-get-subdir)
 447           (dired-kill-subdir)
 448         (dired-kill-line arg))
 449     (save-excursion
 450       (goto-char (point-min))
 451       (let (buffer-read-only (count 0))
 452         (if (not arg)                   ; kill marked lines
 453             (let ((regexp (dired-marker-regexp)))
 454               (while (and (not (eobp))
 455                           (re-search-forward regexp nil t))
 456                 (setq count (1+ count))
 457                 (delete-region (progn (beginning-of-line) (point))
 458                                (progn (forward-line 1) (point)))))
 459           ;; else kill unmarked lines
 460           (while (not (eobp))
 461             (if (or (dired-between-files)
 462                     (not (looking-at "^  ")))
 463                 (forward-line 1)
 464               (setq count (1+ count))
 465               (delete-region (point) (save-excursion
 466                                        (forward-line 1)
 467                                        (point))))))
 468         (or (equal "" fmt)
 469             (message (or fmt "Killed %d line%s.") count (dired-plural-s count)))
 470         count))))
 471
 472 ;;;###end dired-cmd.el
 473 \f
 474 ;;; 30K
 475 ;;;###begin dired-cp.el
 476
 477 (defun dired-compress ()
 478   ;; Compress or uncompress the current file.
 479   ;; Return nil for success, offending filename else.
 480   (let* (buffer-read-only
 481          (from-file (dired-get-filename))
 482          (new-file (dired-compress-file from-file)))
 483     (if new-file
 484         (let ((start (point)))
 485           ;; Remove any preexisting entry for the name NEW-FILE.
 486           (condition-case nil
 487               (dired-remove-entry new-file)
 488             (error nil))
 489           (goto-char start)
 490           ;; Now replace the current line with an entry for NEW-FILE.
 491           (dired-update-file-line new-file) nil)
 492       (dired-log (concat "Failed to compress" from-file))
 493       from-file)))
 494
 495 ;;;###autoload
 496 (defun dired-compress-file (file)
 497   ;; Compress or uncompress FILE.
 498   ;; Return the name of the compressed or uncompressed file.
 499   ;; Return nil if no change in files.
 500   (let ((handler (find-file-name-handler file 'dired-compress-file)))
 501     (cond (handler
 502            (funcall handler 'dired-compress-file file))
 503           ((file-symlink-p file)
 504            nil)
 505           ((let (case-fold-search)
 506              (string-match "\\.Z$" file))
 507            (if (not (dired-check-process (concat "Uncompressing " file)
 508                                          "uncompress" file))
 509                (substring file 0 -2)))
 510           ((let (case-fold-search)
 511              (string-match "\\.gz$" file))
 512            (if (not (dired-check-process (concat "Uncompressing " file)
 513                                          "gunzip" file))
 514                (substring file 0 -3)))
 515           ;; For .z, try gunzip.  It might be an old gzip file,
 516           ;; or it might be from compact? pack? (which?) but gunzip handles
 517           ;; both.
 518           ((let (case-fold-search)
 519              (string-match "\\.z$" file))
 520            (if (not (dired-check-process (concat "Uncompressing " file)
 521                                          "gunzip" file))
 522                (substring file 0 -2)))
 523           (t
 524            ;;; Try gzip; if we don't have that, use compress.
 525            (condition-case nil
 526                (if (not (dired-check-process (concat "Compressing " file)
 527                                              "gzip" "-f" file))
 528                    (cond ((file-exists-p (concat file ".gz"))
 529                           (concat file ".gz"))
 530                          (t (concat file ".z"))))
 531              (file-error
 532               (if (not (dired-check-process (concat "Compressing " file)
 533                                             "compress" "-f" file))
 534                   (concat file ".Z"))))))))
 535 \f
 536 (defun dired-mark-confirm (op-symbol arg)
 537   ;; Request confirmation from the user that the operation described
 538   ;; by OP-SYMBOL is to be performed on the marked files.
 539   ;; Confirmation consists in a y-or-n question with a file list
 540   ;; pop-up unless OP-SYMBOL is a member of `dired-no-confirm'.
 541   ;; The files used are determined by ARG (as in dired-get-marked-files).
 542   (or (memq op-symbol dired-no-confirm)
 543       (let ((files (dired-get-marked-files t arg))
 544             (string (if (eq op-symbol 'compress) "Compress or uncompress"
 545                       (capitalize (symbol-name op-symbol)))))
 546         (dired-mark-pop-up nil op-symbol files (function y-or-n-p)
 547                            (concat string " "
 548                                    (dired-mark-prompt arg files) "? ")))))
 549
 550 (defun dired-map-over-marks-check (fun arg op-symbol &optional show-progress)
 551 ;  "Map FUN over marked files (with second ARG like in dired-map-over-marks)
 552 ; and display failures.
 553
 554 ; FUN takes zero args.  It returns non-nil (the offending object, e.g.
 555 ; the short form of the filename) for a failure and probably logs a
 556 ; detailed error explanation using function `dired-log'.
 557
 558 ; OP-SYMBOL is a symbol describing the operation performed (e.g.
 559 ; `compress').  It is used with `dired-mark-pop-up' to prompt the user
 560 ; (e.g. with `Compress * [2 files]? ') and to display errors (e.g.
 561 ; `Failed to compress 1 of 2 files - type W to see why ("foo")')
 562
 563 ; SHOW-PROGRESS if non-nil means redisplay dired after each file."
 564   (if (dired-mark-confirm op-symbol arg)
 565       (let* ((total-list;; all of FUN's return values
 566               (dired-map-over-marks (funcall fun) arg show-progress))
 567              (total (length total-list))
 568              (failures (delq nil total-list))
 569              (count (length failures))
 570              (string (if (eq op-symbol 'compress) "Compress or uncompress"
 571                        (capitalize (symbol-name op-symbol)))))
 572         (if (not failures)
 573             (message "%s: %d file%s."
 574                      string total (dired-plural-s total))
 575           ;; end this bunch of errors:
 576           (dired-log-summary
 577            (format "Failed to %s %d of %d file%s"
 578                    (downcase string) count total (dired-plural-s total))
 579            failures)))))
 580
 581 (defvar dired-query-alist
 582   '((?\y . y) (?\040 . y)               ; `y' or SPC means accept once
 583     (?n . n) (?\177 . n)                ; `n' or DEL skips once
 584     (?! . yes)                          ; `!' accepts rest
 585     (?q. no) (?\e . no)                 ; `q' or ESC skips rest
 586     ;; None of these keys quit - use C-g for that.
 587     ))
 588
 589 (defun dired-query (qs-var qs-prompt &rest qs-args)
 590   ;; Query user and return nil or t.
 591   ;; Store answer in symbol VAR (which must initially be bound to nil).
 592   ;; Format PROMPT with ARGS.
 593   ;; Binding variable help-form will help the user who types the help key.
 594   (let* ((char (symbol-value qs-var))
 595          (action (cdr (assoc char dired-query-alist))))
 596     (cond ((eq 'yes action)
 597            t)                           ; accept, and don't ask again
 598           ((eq 'no action)
 599            nil)                         ; skip, and don't ask again
 600           (t;; no lasting effects from last time we asked - ask now
 601            (let ((qprompt (concat qs-prompt
 602                                   (if help-form
 603                                       (format " [Type yn!q or %s] "
 604                                               (key-description
 605                                                (char-to-string help-char)))
 606                                     " [Type y, n, q or !] ")))
 607                  result elt)
 608              ;; Actually it looks nicer without cursor-in-echo-area - you can
 609              ;; look at the dired buffer instead of at the prompt to decide.
 610              (apply 'message qprompt qs-args)
 611              (setq char (set qs-var (read-char)))
 612              (while (not (setq elt (assoc char dired-query-alist)))
 613                (message "Invalid char - type %c for help." help-char)
 614                (ding)
 615                (sit-for 1)
 616                (apply 'message qprompt qs-args)
 617                (setq char (set qs-var (read-char))))
 618              (memq (cdr elt) '(t y yes)))))))
 619 \f
 620 ;;;###autoload
 621 (defun dired-do-compress (&optional arg)
 622   "Compress or uncompress marked (or next ARG) files."
 623   (interactive "P")
 624   (dired-map-over-marks-check (function dired-compress) arg 'compress t))
 625
 626 ;; Commands for Emacs Lisp files - load and byte compile
 627
 628 (defun dired-byte-compile ()
 629   ;; Return nil for success, offending file name else.
 630   (let* ((filename (dired-get-filename))
 631          (elc-file
 632           (if (eq system-type 'vax-vms)
 633               (concat (substring filename 0 (string-match ";" filename)) "c")
 634             (concat filename "c")))
 635          buffer-read-only failure)
 636     (condition-case err
 637         (save-excursion (byte-compile-file filename))
 638       (error
 639        (setq failure err)))
 640     (if failure
 641         (progn
 642           (dired-log "Byte compile error for %s:\n%s\n" filename failure)
 643           (dired-make-relative filename))
 644       (dired-remove-file elc-file)
 645       (forward-line)                    ; insert .elc after its .el file
 646       (dired-add-file elc-file)
 647       nil)))
 648
 649 ;;;###autoload
 650 (defun dired-do-byte-compile (&optional arg)
 651   "Byte compile marked (or next ARG) Emacs Lisp files."
 652   (interactive "P")
 653   (dired-map-over-marks-check (function dired-byte-compile) arg 'byte-compile t))
 654
 655 (defun dired-load ()
 656   ;; Return nil for success, offending file name else.
 657   (let ((file (dired-get-filename)) failure)
 658     (condition-case err
 659       (load file nil nil t)
 660       (error (setq failure err)))
 661     (if (not failure)
 662         nil
 663       (dired-log "Load error for %s:\n%s\n" file failure)
 664       (dired-make-relative file))))
 665
 666 ;;;###autoload
 667 (defun dired-do-load (&optional arg)
 668   "Load the marked (or next ARG) Emacs Lisp files."
 669   (interactive "P")
 670   (dired-map-over-marks-check (function dired-load) arg 'load t))
 671
 672 ;;;###autoload
 673 (defun dired-do-redisplay (&optional arg test-for-subdir)
 674   "Redisplay all marked (or next ARG) files.
 675 If on a subdir line, redisplay that subdirectory.  In that case,
 676 a prefix arg lets you edit the `ls' switches used for the new listing."
 677   ;; Moves point if the next ARG files are redisplayed.
 678   (interactive "P\np")
 679   (if (and test-for-subdir (dired-get-subdir))
 680       (dired-insert-subdir
 681        (dired-get-subdir)
 682        (if arg (read-string "Switches for listing: " dired-actual-switches)))
 683     (message "Redisplaying...")
 684     ;; message much faster than making dired-map-over-marks show progress
 685     (dired-map-over-marks (let ((fname (dired-get-filename)))
 686                             (message "Redisplaying... %s" fname)
 687                             (dired-update-file-line fname))
 688                           arg)
 689     (dired-move-to-filename)
 690     (message "Redisplaying...done")))
 691 \f
 692 (defun dired-update-file-line (file)
 693   ;; Delete the current line, and insert an entry for FILE.
 694   ;; If FILE is nil, then just delete the current line.
 695   ;; Keeps any marks that may be present in column one (doing this
 696   ;; here is faster than with dired-add-entry's optional arg).
 697   ;; Does not update other dired buffers.  Use dired-relist-entry for that.
 698   (beginning-of-line)
 699   (let ((char (following-char)) (opoint (point))
 700         (buffer-read-only))
 701     (delete-region (point) (progn (forward-line 1) (point)))
 702     (if file
 703         (progn
 704           (dired-add-entry file)
 705           ;; Replace space by old marker without moving point.
 706           ;; Faster than goto+insdel inside a save-excursion?
 707           (subst-char-in-region opoint (1+ opoint) ?\040 char))))
 708   (dired-move-to-filename))
 709
 710 (defun dired-fun-in-all-buffers (directory fun &rest args)
 711   ;; In all buffers dired'ing DIRECTORY, run FUN with ARGS.
 712   ;; Return list of buffers where FUN succeeded (i.e., returned non-nil).
 713   (let ((buf-list (dired-buffers-for-dir directory))
 714         (obuf (current-buffer))
 715         buf success-list)
 716     (while buf-list
 717       (setq buf (car buf-list)
 718             buf-list (cdr buf-list))
 719       (unwind-protect
 720           (progn
 721             (set-buffer buf)
 722             (if (apply fun args)
 723                 (setq success-list (cons (buffer-name buf) success-list))))
 724         (set-buffer obuf)))
 725     success-list))
 726
 727 ;;;###autoload
 728 (defun dired-add-file (filename &optional marker-char)
 729   (dired-fun-in-all-buffers
 730    (file-name-directory filename)
 731    (function dired-add-entry) filename marker-char))
 732
 733 (defun dired-add-entry (filename &optional marker-char)
 734   ;; Add a new entry for FILENAME, optionally marking it
 735   ;; with MARKER-CHAR (a character, else dired-marker-char is used).
 736   ;; Note that this adds the entry `out of order' if files sorted by
 737   ;; time, etc.
 738   ;; At least this version inserts in the right subdirectory (if present).
 739   ;; And it skips "." or ".." (see `dired-trivial-filenames').
 740   ;; Hidden subdirs are exposed if a file is added there.
 741   (setq filename (directory-file-name filename))
 742   ;; Entry is always for files, even if they happen to also be directories
 743   (let ((opoint (point))
 744         (cur-dir (dired-current-directory))
 745         (directory (file-name-directory filename))
 746         reason)
 747     (setq filename (file-name-nondirectory filename)
 748           reason
 749           (catch 'not-found
 750             (if (string= directory cur-dir)
 751                 (progn
 752                   (skip-chars-forward "^\r\n")
 753                   (if (eq (following-char) ?\r)
 754                       (dired-unhide-subdir))
 755                   ;; We are already where we should be, except when
 756                   ;; point is before the subdir line or its total line.
 757                   (let ((p (dired-after-subdir-garbage cur-dir)))
 758                     (if (< (point) p)
 759                         (goto-char p))))
 760               ;; else try to find correct place to insert
 761               (if (dired-goto-subdir directory)
 762                   (progn;; unhide if necessary
 763                     (if (looking-at "\r");; point is at end of subdir line
 764                         (dired-unhide-subdir))
 765                     ;; found - skip subdir and `total' line
 766                     ;; and uninteresting files like . and ..
 767                     ;; This better not moves into the next subdir!
 768                     (dired-goto-next-nontrivial-file))
 769                 ;; not found
 770                 (throw 'not-found "Subdir not found")))
 771             (let (buffer-read-only opoint)
 772               (beginning-of-line)
 773               (setq opoint (point))
 774               (dired-add-entry-do-indentation marker-char)
 775               ;; don't expand `.'.  Show just the file name within directory.
 776               (let ((default-directory directory))
 777                 (insert-directory filename
 778                                   (concat dired-actual-switches "d")))
 779               (dired-insert-set-properties opoint (point))
 780               (forward-line -1)
 781               (if dired-after-readin-hook;; the subdir-alist is not affected...
 782                   (save-excursion;; ...so we can run it right now:
 783                     (save-restriction
 784                       (beginning-of-line)
 785                       (narrow-to-region (point) (save-excursion
 786                                                   (forward-line 1) (point)))
 787                       (run-hooks 'dired-after-readin-hook))))
 788               (dired-move-to-filename))
 789             ;; return nil if all went well
 790             nil))
 791     (if reason                          ; don't move away on failure
 792         (goto-char opoint))
 793     (not reason)))                      ; return t on success, nil else
 794
 795 ;; This is a separate function for the sake of nested dired format.
 796 (defun dired-add-entry-do-indentation (marker-char)
 797   ;; two spaces or a marker plus a space:
 798   (insert (if marker-char
 799               (if (integerp marker-char) marker-char dired-marker-char)
 800             ?\040)
 801           ?\040))
 802
 803 (defun dired-after-subdir-garbage (dir)
 804   ;; Return pos of first file line of DIR, skipping header and total
 805   ;; or wildcard lines.
 806   ;; Important: never moves into the next subdir.
 807   ;; DIR is assumed to be unhidden.
 808   ;; Will probably be redefined for VMS etc.
 809   (save-excursion
 810     (or (dired-goto-subdir dir) (error "This cannot happen"))
 811     (forward-line 1)
 812     (while (and (not (eolp))            ; don't cross subdir boundary
 813                 (not (dired-move-to-filename)))
 814         (forward-line 1))
 815     (point)))
 816
 817 ;;;###autoload
 818 (defun dired-remove-file (file)
 819   (dired-fun-in-all-buffers
 820    (file-name-directory file) (function dired-remove-entry) file))
 821
 822 (defun dired-remove-entry (file)
 823   (save-excursion
 824     (and (dired-goto-file file)
 825          (let (buffer-read-only)
 826            (delete-region (progn (beginning-of-line) (point))
 827                           (save-excursion (forward-line 1) (point)))))))
 828
 829 ;;;###autoload
 830 (defun dired-relist-file (file)
 831   (dired-fun-in-all-buffers (file-name-directory file)
 832                             (function dired-relist-entry) file))
 833
 834 (defun dired-relist-entry (file)
 835   ;; Relist the line for FILE, or just add it if it did not exist.
 836   ;; FILE must be an absolute pathname.
 837   (let (buffer-read-only marker)
 838     ;; If cursor is already on FILE's line delete-region will cause
 839     ;; save-excursion to fail because of floating makers,
 840     ;; moving point to beginning of line.  Sigh.
 841     (save-excursion
 842       (and (dired-goto-file file)
 843            (delete-region (progn (beginning-of-line)
 844                                  (setq marker (following-char))
 845                                  (point))
 846                           (save-excursion (forward-line 1) (point))))
 847       (setq file (directory-file-name file))
 848       (dired-add-entry file (if (eq ?\040 marker) nil marker)))))
 849 \f
 850 ;;; Copy, move/rename, making hard and symbolic links
 851
 852 (defvar dired-backup-overwrite nil
 853   "*Non-nil if Dired should ask about making backups before overwriting files.
 854 Special value `always' suppresses confirmation.")
 855
 856 (defvar dired-overwrite-confirmed)
 857
 858 (defun dired-handle-overwrite (to)
 859   ;; Save old version of a to be overwritten file TO.
 860   ;; `dired-overwrite-confirmed' and `overwrite-backup-query' are fluid vars
 861   ;; from dired-create-files.
 862   (if (and dired-backup-overwrite
 863            dired-overwrite-confirmed
 864            (or (eq 'always dired-backup-overwrite)
 865                (dired-query 'overwrite-backup-query
 866                         (format "Make backup for existing file `%s'? " to))))
 867       (let ((backup (car (find-backup-file-name to))))
 868         (rename-file to backup 0)       ; confirm overwrite of old backup
 869         (dired-relist-entry backup))))
 870
 871 ;;;###autoload
 872 (defun dired-copy-file (from to ok-flag)
 873   (dired-handle-overwrite to)
 874   (copy-file from to ok-flag dired-copy-preserve-time))
 875
 876 ;;;###autoload
 877 (defun dired-rename-file (from to ok-flag)
 878   (dired-handle-overwrite to)
 879   (rename-file from to ok-flag)         ; error is caught in -create-files
 880   ;; Silently rename the visited file of any buffer visiting this file.
 881   (and (get-file-buffer from)
 882        (save-excursion
 883          (set-buffer (get-file-buffer from))
 884          (let ((modflag (buffer-modified-p)))
 885            (set-visited-file-name to)
 886            (set-buffer-modified-p modflag))))
 887   (dired-remove-file from)
 888   ;; See if it's an inserted subdir, and rename that, too.
 889   (dired-rename-subdir from to))
 890
 891 (defun dired-rename-subdir (from-dir to-dir)
 892   (setq from-dir (file-name-as-directory from-dir)
 893         to-dir (file-name-as-directory to-dir))
 894   (dired-fun-in-all-buffers from-dir
 895                             (function dired-rename-subdir-1) from-dir to-dir)
 896   ;; Update visited file name of all affected buffers
 897   (let ((blist (buffer-list)))
 898     (while blist
 899       (save-excursion
 900         (set-buffer (car blist))
 901         (if (and buffer-file-name
 902                  (dired-in-this-tree buffer-file-name from-dir))
 903             (let ((modflag (buffer-modified-p))
 904                   (to-file (dired-replace-in-string
 905                             (concat "^" (regexp-quote from-dir))
 906                             to-dir
 907                             buffer-file-name)))
 908               (set-visited-file-name to-file)
 909               (set-buffer-modified-p modflag))))
 910       (setq blist (cdr blist)))))
 911
 912 (defun dired-rename-subdir-1 (dir to)
 913   ;; Rename DIR to TO in headerlines and dired-subdir-alist, if DIR or
 914   ;; one of its subdirectories is expanded in this buffer.
 915   (let ((alist dired-subdir-alist)
 916         (elt nil))
 917     (while alist
 918       (setq elt (car alist)
 919             alist (cdr alist))
 920       (if (dired-in-this-tree (car elt) dir)
 921           ;; ELT's subdir is affected by the rename
 922           (dired-rename-subdir-2 elt dir to)))
 923     (if (equal dir default-directory)
 924         ;; if top level directory was renamed, lots of things have to be
 925         ;; updated:
 926         (progn
 927           (dired-unadvertise dir)       ; we no longer dired DIR...
 928           (setq default-directory to
 929                 dired-directory (expand-file-name;; this is correct
 930                                  ;; with and without wildcards
 931                                  (file-name-nondirectory dired-directory)
 932                                  to))
 933           (let ((new-name (file-name-nondirectory
 934                            (directory-file-name dired-directory))))
 935             ;; try to rename buffer, but just leave old name if new
 936             ;; name would already exist (don't try appending "<%d>")
 937             (or (get-buffer new-name)
 938                 (rename-buffer new-name)))
 939           ;; ... we dired TO now:
 940           (dired-advertise)))))
 941
 942 (defun dired-rename-subdir-2 (elt dir to)
 943   ;; Update the headerline and dired-subdir-alist element of directory
 944   ;; described by alist-element ELT to reflect the moving of DIR to TO.
 945   ;; Thus, ELT describes either DIR itself or a subdir of DIR.
 946   (save-excursion
 947     (let ((regexp (regexp-quote (directory-file-name dir)))
 948           (newtext (directory-file-name to))
 949           buffer-read-only)
 950       (goto-char (dired-get-subdir-min elt))
 951       ;; Update subdir headerline in buffer
 952       (if (not (looking-at dired-subdir-regexp))
 953           (error "%s not found where expected - dired-subdir-alist broken?"
 954                  dir)
 955         (goto-char (match-beginning 1))
 956         (if (re-search-forward regexp (match-end 1) t)
 957             (replace-match newtext t t)
 958           (error "Expected to find `%s' in headerline of %s" dir (car elt))))
 959       ;; Update buffer-local dired-subdir-alist
 960       (setcar elt
 961               (dired-normalize-subdir
 962                (dired-replace-in-string regexp newtext (car elt)))))))
 963 \f
 964 ;; Cloning replace-match to work on strings instead of in buffer:
 965 ;; The FIXEDCASE parameter of replace-match is not implemented.
 966 ;;;###autoload
 967 (defun dired-string-replace-match (regexp string newtext
 968                                           &optional literal global)
 969   "Replace first match of REGEXP in STRING with NEWTEXT.
 970 If it does not match, nil is returned instead of the new string.
 971 Optional arg LITERAL means to take NEWTEXT literally.
 972 Optional arg GLOBAL means to replace all matches."
 973   (if global
 974         (let ((result "") (start 0) mb me)
 975           (while (string-match regexp string start)
 976             (setq mb (match-beginning 0)
 977                   me (match-end 0)
 978                   result (concat result
 979                                  (substring string start mb)
 980                                  (if literal
 981                                      newtext
 982                                    (dired-expand-newtext string newtext)))
 983                   start me))
 984           (if mb                        ; matched at least once
 985               (concat result (substring string start))
 986             nil))
 987     ;; not GLOBAL
 988     (if (not (string-match regexp string 0))
 989         nil
 990       (concat (substring string 0 (match-beginning 0))
 991               (if literal newtext (dired-expand-newtext string newtext))
 992               (substring string (match-end 0))))))
 993
 994 (defun dired-expand-newtext (string newtext)
 995   ;; Expand \& and \1..\9 (referring to STRING) in NEWTEXT, using match data.
 996   ;; Note that in Emacs 18 match data are clipped to current buffer
 997   ;; size...so the buffer should better not be smaller than STRING.
 998   (let ((pos 0)
 999         (len (length newtext))
1000         (expanded-newtext ""))
1001     (while (< pos len)
1002       (setq expanded-newtext
1003             (concat expanded-newtext
1004                     (let ((c (aref newtext pos)))
1005                       (if (= ?\\ c)
1006                           (cond ((= ?\& (setq c
1007                                               (aref newtext
1008                                                     (setq pos (1+ pos)))))
1009                                  (substring string
1010                                             (match-beginning 0)
1011                                             (match-end 0)))
1012                                 ((and (>= c ?1) (<= c ?9))
1013                                  ;; return empty string if N'th
1014                                  ;; sub-regexp did not match:
1015                                  (let ((n (- c ?0)))
1016                                    (if (match-beginning n)
1017                                        (substring string
1018                                                   (match-beginning n)
1019                                                   (match-end n))
1020                                      "")))
1021                                 (t
1022                                  (char-to-string c)))
1023                         (char-to-string c)))))
1024       (setq pos (1+ pos)))
1025     expanded-newtext))
1026 \f
1027 ;; The basic function for half a dozen variations on cp/mv/ln/ln -s.
1028 (defun dired-create-files (file-creator operation fn-list name-constructor
1029                                         &optional marker-char)
1030
1031 ;; Create a new file for each from a list of existing files.  The user
1032 ;; is queried, dired buffers are updated, and at the end a success or
1033 ;; failure message is displayed
1034
1035 ;; FILE-CREATOR must accept three args: oldfile newfile ok-if-already-exists
1036
1037 ;; It is called for each file and must create newfile, the entry of
1038 ;; which will be added.  The user will be queried if the file already
1039 ;; exists.  If oldfile is removed by FILE-CREATOR (i.e, it is a
1040 ;; rename), it is FILE-CREATOR's responsibility to update dired
1041 ;; buffers.  FILE-CREATOR must abort by signalling a file-error if it
1042 ;; could not create newfile.  The error is caught and logged.
1043
1044 ;; OPERATION (a capitalized string, e.g. `Copy') describes the
1045 ;; operation performed.  It is used for error logging.
1046
1047 ;; FN-LIST is the list of files to copy (full absolute pathnames).
1048
1049 ;; NAME-CONSTRUCTOR returns a newfile for every oldfile, or nil to
1050 ;; skip.  If it skips files for other reasons than a direct user
1051 ;; query, it is supposed to tell why (using dired-log).
1052
1053 ;; Optional MARKER-CHAR is a character with which to mark every
1054 ;; newfile's entry, or t to use the current marker character if the
1055 ;; oldfile was marked.
1056
1057   (let (failures skipped (success-count 0) (total (length fn-list)))
1058     (let (to overwrite-query
1059              overwrite-backup-query)    ; for dired-handle-overwrite
1060       (mapcar
1061        (function
1062         (lambda (from)
1063           (setq to (funcall name-constructor from))
1064           (if (equal to from)
1065               (progn
1066                 (setq to nil)
1067                 (dired-log "Cannot %s to same file: %s\n"
1068                            (downcase operation) from)))
1069           (if (not to)
1070               (setq skipped (cons (dired-make-relative from) skipped))
1071             (let* ((overwrite (file-exists-p to))
1072                    (dired-overwrite-confirmed   ; for dired-handle-overwrite
1073                     (and overwrite
1074                          (let ((help-form '(format "\
1075 Type SPC or `y' to overwrite file `%s',
1076 DEL or `n' to skip to next,
1077 ESC or `q' to not overwrite any of the remaining files,
1078 `!' to overwrite all remaining files with no more questions." to)))
1079                            (dired-query 'overwrite-query
1080                                         "Overwrite `%s'?" to))))
1081                    ;; must determine if FROM is marked before file-creator
1082                    ;; gets a chance to delete it (in case of a move).
1083                    (actual-marker-char
1084                     (cond  ((integerp marker-char) marker-char)
1085                            (marker-char (dired-file-marker from)) ; slow
1086                            (t nil))))
1087               (condition-case err
1088                   (progn
1089                     (funcall file-creator from to dired-overwrite-confirmed)
1090                     (if overwrite
1091                         ;; If we get here, file-creator hasn't been aborted
1092                         ;; and the old entry (if any) has to be deleted
1093                         ;; before adding the new entry.
1094                         (dired-remove-file to))
1095                     (setq success-count (1+ success-count))
1096                     (message "%s: %d of %d" operation success-count total)
1097                     (dired-add-file to actual-marker-char))
1098                 (file-error             ; FILE-CREATOR aborted
1099                  (progn
1100                    (setq failures (cons (dired-make-relative from) failures))
1101                    (dired-log "%s `%s' to `%s' failed:\n%s\n"
1102                               operation from to err))))))))
1103        fn-list))
1104     (cond
1105      (failures
1106       (dired-log-summary
1107        (format "%s failed for %d of %d file%s"
1108                 operation (length failures) total
1109                 (dired-plural-s total))
1110        failures))
1111      (skipped
1112       (dired-log-summary
1113        (format "%s: %d of %d file%s skipped"
1114                 operation (length skipped) total
1115                 (dired-plural-s total))
1116        skipped))
1117      (t
1118       (message "%s: %s file%s"
1119                operation success-count (dired-plural-s success-count)))))
1120   (dired-move-to-filename))
1121 \f
1122 (defun dired-do-create-files (op-symbol file-creator operation arg
1123                                              &optional marker-char op1
1124                                              how-to)
1125   ;; Create a new file for each marked file.
1126   ;; Prompts user for target, which is a directory in which to create
1127   ;;   the new files.  Target may be a plain file if only one marked
1128   ;;   file exists.
1129   ;; OP-SYMBOL is the symbol for the operation.  Function `dired-mark-pop-up'
1130   ;;   will determine whether pop-ups are appropriate for this OP-SYMBOL.
1131   ;; FILE-CREATOR and OPERATION as in dired-create-files.
1132   ;; ARG as in dired-get-marked-files.
1133   ;; Optional arg OP1 is an alternate form for OPERATION if there is
1134   ;;   only one file.
1135   ;; Optional arg MARKER-CHAR as in dired-create-files.
1136   ;; Optional arg HOW-TO determines how to treat target:
1137   ;;   If HOW-TO is not given (or nil), and target is a directory, the
1138   ;;     file(s) are created inside the target directory.  If target
1139   ;;     is not a directory, there must be exactly one marked file,
1140   ;;     else error.
1141   ;;   If HOW-TO is t, then target is not modified.  There must be
1142   ;;     exactly one marked file, else error.
1143   ;; Else HOW-TO is assumed to be a function of one argument, target,
1144   ;;     that looks at target and returns a value for the into-dir
1145   ;;     variable.  The function dired-into-dir-with-symlinks is provided
1146   ;;     for the case (common when creating symlinks) that symbolic
1147   ;;     links to directories are not to be considered as directories
1148   ;;     (as file-directory-p would if HOW-TO had been nil).
1149   (or op1 (setq op1 operation))
1150   (let* ((fn-list (dired-get-marked-files nil arg))
1151          (fn-count (length fn-list))
1152          (target (expand-file-name
1153                    (dired-mark-read-file-name
1154                     (concat (if (= 1 fn-count) op1 operation) " %s to: ")
1155                     (dired-dwim-target-directory)
1156                     op-symbol arg (mapcar (function dired-make-relative) fn-list))))
1157          (into-dir (cond ((null how-to) (file-directory-p target))
1158                          ((eq how-to t) nil)
1159                          (t (funcall how-to target)))))
1160     (if (and (> fn-count 1)
1161              (not into-dir))
1162         (error "Marked %s: target must be a directory: %s" operation target))
1163     ;; rename-file bombs when moving directories unless we do this:
1164     (or into-dir (setq target (directory-file-name target)))
1165     (dired-create-files
1166      file-creator operation fn-list
1167      (if into-dir                       ; target is a directory
1168          ;; This function uses fluid vars into-dir and target when called
1169          ;; inside dired-create-files:
1170          (function (lambda (from)
1171                      (expand-file-name (file-name-nondirectory from) target)))
1172        (function (lambda (from) target)))
1173      marker-char)))
1174
1175 ;; Read arguments for a marked-files command that wants a file name,
1176 ;; perhaps popping up the list of marked files.
1177 ;; ARG is the prefix arg and indicates whether the files came from
1178 ;; marks (ARG=nil) or a repeat factor (integerp ARG).
1179 ;; If the current file was used, the list has but one element and ARG
1180 ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)).
1181
1182 (defun dired-mark-read-file-name (prompt dir op-symbol arg files)
1183   (dired-mark-pop-up
1184    nil op-symbol files
1185    (function read-file-name)
1186    (format prompt (dired-mark-prompt arg files)) dir))
1187
1188 (defun dired-dwim-target-directory ()
1189   ;; Try to guess which target directory the user may want.
1190   ;; If there is a dired buffer displayed in the next window, use
1191   ;; its current subdir, else use current subdir of this dired buffer.
1192   (let ((this-dir (and (eq major-mode 'dired-mode)
1193                        (dired-current-directory))))
1194     ;; non-dired buffer may want to profit from this function, e.g. vm-uudecode
1195     (if dired-dwim-target
1196         (let* ((other-buf (window-buffer (next-window)))
1197                (other-dir (save-excursion
1198                             (set-buffer other-buf)
1199                             (and (eq major-mode 'dired-mode)
1200                                  (dired-current-directory)))))
1201           (or other-dir this-dir))
1202       this-dir)))
1203 \f
1204 ;;;###autoload
1205 (defun dired-create-directory (directory)
1206   "Create a directory called DIRECTORY."
1207   (interactive
1208    (list (read-file-name "Create directory: " (dired-current-directory))))
1209   (let ((expanded (directory-file-name (expand-file-name directory))))
1210     (make-directory expanded)
1211     (dired-add-file expanded)
1212     (dired-move-to-filename)))
1213
1214 (defun dired-into-dir-with-symlinks (target)
1215   (and (file-directory-p target)
1216        (not (file-symlink-p target))))
1217 ;; This may not always be what you want, especially if target is your
1218 ;; home directory and it happens to be a symbolic link, as is often the
1219 ;; case with NFS and automounters.  Or if you want to make symlinks
1220 ;; into directories that themselves are only symlinks, also quite
1221 ;; common.
1222
1223 ;; So we don't use this function as value for HOW-TO in
1224 ;; dired-do-symlink, which has the minor disadvantage of
1225 ;; making links *into* a symlinked-dir, when you really wanted to
1226 ;; *overwrite* that symlink.  In that (rare, I guess) case, you'll
1227 ;; just have to remove that symlink by hand before making your marked
1228 ;; symlinks.
1229
1230 ;;;###autoload
1231 (defun dired-do-copy (&optional arg)
1232   "Copy all marked (or next ARG) files, or copy the current file.
1233 This normally preserves the last-modified date when copying.
1234 When operating on just the current file, you specify the new name.
1235 When operating on multiple or marked files, you specify a directory
1236 and new symbolic links are made in that directory
1237 with the same names that the files currently have."
1238   (interactive "P")
1239   (dired-do-create-files 'copy (function dired-copy-file)
1240                            (if dired-copy-preserve-time "Copy [-p]" "Copy")
1241                            arg dired-keep-marker-copy))
1242
1243 ;;;###autoload
1244 (defun dired-do-symlink (&optional arg)
1245   "Make symbolic links to current file or all marked (or next ARG) files.
1246 When operating on just the current file, you specify the new name.
1247 When operating on multiple or marked files, you specify a directory
1248 and new symbolic links are made in that directory
1249 with the same names that the files currently have."
1250   (interactive "P")
1251   (dired-do-create-files 'symlink (function make-symbolic-link)
1252                            "Symlink" arg dired-keep-marker-symlink))
1253
1254 ;;;###autoload
1255 (defun dired-do-hardlink (&optional arg)
1256   "Add names (hard links) current file or all marked (or next ARG) files.
1257 When operating on just the current file, you specify the new name.
1258 When operating on multiple or marked files, you specify a directory
1259 and new hard links are made in that directory
1260 with the same names that the files currently have."
1261   (interactive "P")
1262   (dired-do-create-files 'hardlink (function add-name-to-file)
1263                            "Hardlink" arg dired-keep-marker-hardlink))
1264
1265 ;;;###autoload
1266 (defun dired-do-rename (&optional arg)
1267   "Rename current file or all marked (or next ARG) files.
1268 When renaming just the current file, you specify the new name.
1269 When renaming multiple or marked files, you specify a directory."
1270   (interactive "P")
1271   (dired-do-create-files 'move (function dired-rename-file)
1272                          "Move" arg dired-keep-marker-rename "Rename"))
1273 ;;;###end dired-cp.el
1274 \f
1275 ;;; 5K
1276 ;;;###begin dired-re.el
1277 (defun dired-do-create-files-regexp
1278   (file-creator operation arg regexp newname &optional whole-path marker-char)
1279   ;; Create a new file for each marked file using regexps.
1280   ;; FILE-CREATOR and OPERATION as in dired-create-files.
1281   ;; ARG as in dired-get-marked-files.
1282   ;; Matches each marked file against REGEXP and constructs the new
1283   ;;   filename from NEWNAME (like in function replace-match).
1284   ;; Optional arg WHOLE-PATH means match/replace the whole pathname
1285   ;;   instead of only the non-directory part of the file.
1286   ;; Optional arg MARKER-CHAR as in dired-create-files.
1287   (let* ((fn-list (dired-get-marked-files nil arg))
1288          (fn-count (length fn-list))
1289          (operation-prompt (concat operation " `%s' to `%s'?"))
1290          (rename-regexp-help-form (format "\
1291 Type SPC or `y' to %s one match, DEL or `n' to skip to next,
1292 `!' to %s all remaining matches with no more questions."
1293                                           (downcase operation)
1294                                           (downcase operation)))
1295          (regexp-name-constructor
1296           ;; Function to construct new filename using REGEXP and NEWNAME:
1297           (if whole-path                ; easy (but rare) case
1298               (function
1299                (lambda (from)
1300                  (let ((to (dired-string-replace-match regexp from newname))
1301                        ;; must bind help-form directly around call to
1302                        ;; dired-query
1303                        (help-form rename-regexp-help-form))
1304                    (if to
1305                        (and (dired-query 'rename-regexp-query
1306                                          operation-prompt
1307                                          from
1308                                          to)
1309                             to)
1310                      (dired-log "%s: %s did not match regexp %s\n"
1311                                 operation from regexp)))))
1312             ;; not whole-path, replace non-directory part only
1313             (function
1314              (lambda (from)
1315                (let* ((new (dired-string-replace-match
1316                             regexp (file-name-nondirectory from) newname))
1317                       (to (and new      ; nil means there was no match
1318                                (expand-file-name new
1319                                                  (file-name-directory from))))
1320                       (help-form rename-regexp-help-form))
1321                  (if to
1322                      (and (dired-query 'rename-regexp-query
1323                                        operation-prompt
1324                                        (dired-make-relative from)
1325                                        (dired-make-relative to))
1326                           to)
1327                    (dired-log "%s: %s did not match regexp %s\n"
1328                               operation (file-name-nondirectory from) regexp)))))))
1329          rename-regexp-query)
1330     (dired-create-files
1331      file-creator operation fn-list regexp-name-constructor marker-char)))
1332
1333 (defun dired-mark-read-regexp (operation)
1334   ;; Prompt user about performing OPERATION.
1335   ;; Read and return list of: regexp newname arg whole-path.
1336   (let* ((whole-path
1337           (equal 0 (prefix-numeric-value current-prefix-arg)))
1338          (arg
1339           (if whole-path nil current-prefix-arg))
1340          (regexp
1341           (dired-read-regexp
1342            (concat (if whole-path "Path " "") operation " from (regexp): ")))
1343          (newname
1344           (read-string
1345            (concat (if whole-path "Path " "") operation " " regexp " to: "))))
1346     (list regexp newname arg whole-path)))
1347
1348 ;;;###autoload
1349 (defun dired-do-rename-regexp (regexp newname &optional arg whole-path)
1350   "Rename marked files containing REGEXP to NEWNAME.
1351 As each match is found, the user must type a character saying
1352   what to do with it.  For directions, type \\[help-command] at that time.
1353 NEWNAME may contain \\=\\<n> or \\& as in `query-replace-regexp'.
1354 REGEXP defaults to the last regexp used.
1355 With a zero prefix arg, renaming by regexp affects the complete
1356   pathname - usually only the non-directory part of file names is used
1357   and changed."
1358   (interactive (dired-mark-read-regexp "Rename"))
1359   (dired-do-create-files-regexp
1360    (function dired-rename-file)
1361    "Rename" arg regexp newname whole-path dired-keep-marker-rename))
1362
1363 ;;;###autoload
1364 (defun dired-do-copy-regexp (regexp newname &optional arg whole-path)
1365   "Copy all marked files containing REGEXP to NEWNAME.
1366 See function `dired-rename-regexp' for more info."
1367   (interactive (dired-mark-read-regexp "Copy"))
1368   (dired-do-create-files-regexp
1369    (function dired-copy-file)
1370    (if dired-copy-preserve-time "Copy [-p]" "Copy")
1371    arg regexp newname whole-path dired-keep-marker-copy))
1372
1373 ;;;###autoload
1374 (defun dired-do-hardlink-regexp (regexp newname &optional arg whole-path)
1375   "Hardlink all marked files containing REGEXP to NEWNAME.
1376 See function `dired-rename-regexp' for more info."
1377   (interactive (dired-mark-read-regexp "HardLink"))
1378   (dired-do-create-files-regexp
1379    (function add-name-to-file)
1380    "HardLink" arg regexp newname whole-path dired-keep-marker-hardlink))
1381
1382 ;;;###autoload
1383 (defun dired-do-symlink-regexp (regexp newname &optional arg whole-path)
1384   "Symlink all marked files containing REGEXP to NEWNAME.
1385 See function `dired-rename-regexp' for more info."
1386   (interactive (dired-mark-read-regexp "SymLink"))
1387   (dired-do-create-files-regexp
1388    (function make-symbolic-link)
1389    "SymLink" arg regexp newname whole-path dired-keep-marker-symlink))
1390
1391 (defun dired-create-files-non-directory
1392   (file-creator basename-constructor operation arg)
1393   ;; Perform FILE-CREATOR on the non-directory part of marked files
1394   ;; using function BASENAME-CONSTRUCTOR, with query for each file.
1395   ;; OPERATION like in dired-create-files, ARG as in dired-get-marked-files.
1396   (let (rename-non-directory-query)
1397     (dired-create-files
1398      file-creator
1399      operation
1400      (dired-get-marked-files nil arg)
1401      (function
1402       (lambda (from)
1403         (let ((to (concat (file-name-directory from)
1404                           (funcall basename-constructor
1405                                    (file-name-nondirectory from)))))
1406           (and (let ((help-form (format "\
1407 Type SPC or `y' to %s one file, DEL or `n' to skip to next,
1408 `!' to %s all remaining matches with no more questions."
1409                                         (downcase operation)
1410                                         (downcase operation))))
1411                  (dired-query 'rename-non-directory-query
1412                               (concat operation " `%s' to `%s'")
1413                               (dired-make-relative from)
1414                               (dired-make-relative to)))
1415                to))))
1416      dired-keep-marker-rename)))
1417
1418 (defun dired-rename-non-directory (basename-constructor operation arg)
1419   (dired-create-files-non-directory
1420    (function dired-rename-file)
1421    basename-constructor operation arg))
1422
1423 ;;;###autoload
1424 (defun dired-upcase (&optional arg)
1425   "Rename all marked (or next ARG) files to upper case."
1426   (interactive "P")
1427   (dired-rename-non-directory (function upcase) "Rename upcase" arg))
1428
1429 ;;;###autoload
1430 (defun dired-downcase (&optional arg)
1431   "Rename all marked (or next ARG) files to lower case."
1432   (interactive "P")
1433   (dired-rename-non-directory (function downcase) "Rename downcase" arg))
1434
1435 ;;;###end dired-re.el
1436 \f
1437 ;;; 13K
1438 ;;;###begin dired-ins.el
1439
1440 ;;;###autoload
1441 (defun dired-maybe-insert-subdir (dirname &optional
1442                                           switches no-error-if-not-dir-p)
1443   "Insert this subdirectory into the same dired buffer.
1444 If it is already present, just move to it (type \\[dired-do-redisplay] to refresh),
1445   else inserts it at its natural place (as `ls -lR' would have done).
1446 With a prefix arg, you may edit the ls switches used for this listing.
1447   You can add `R' to the switches to expand the whole tree starting at
1448   this subdirectory.
1449 This function takes some pains to conform to `ls -lR' output."
1450   (interactive
1451    (list (dired-get-filename)
1452          (if current-prefix-arg
1453              (read-string "Switches for listing: " dired-actual-switches))))
1454   (let ((opoint (point)))
1455     ;; We don't need a marker for opoint as the subdir is always
1456     ;; inserted *after* opoint.
1457     (setq dirname (file-name-as-directory dirname))
1458     (or (and (not switches)
1459              (dired-goto-subdir dirname))
1460         (dired-insert-subdir dirname switches no-error-if-not-dir-p))
1461     ;; Push mark so that it's easy to find back.  Do this after the
1462     ;; insert message so that the user sees the `Mark set' message.
1463     (push-mark opoint)))
1464
1465 (defun dired-insert-subdir (dirname &optional switches no-error-if-not-dir-p)
1466   "Insert this subdirectory into the same dired buffer.
1467 If it is already present, overwrites previous entry,
1468   else inserts it at its natural place (as `ls -lR' would have done).
1469 With a prefix arg, you may edit the `ls' switches used for this listing.
1470   You can add `R' to the switches to expand the whole tree starting at
1471   this subdirectory.
1472 This function takes some pains to conform to `ls -lR' output."
1473   ;; NO-ERROR-IF-NOT-DIR-P needed for special filesystems like
1474   ;; Prospero where dired-ls does the right thing, but
1475   ;; file-directory-p has not been redefined.
1476   (interactive
1477    (list (dired-get-filename)
1478          (if current-prefix-arg
1479              (read-string "Switches for listing: " dired-actual-switches))))
1480   (setq dirname (file-name-as-directory (expand-file-name dirname)))
1481   (dired-insert-subdir-validate dirname switches)
1482   (or no-error-if-not-dir-p
1483       (file-directory-p dirname)
1484       (error  "Attempt to insert a non-directory: %s" dirname))
1485   (let ((elt (assoc dirname dired-subdir-alist))
1486          switches-have-R mark-alist case-fold-search buffer-read-only)
1487     ;; case-fold-search is nil now, so we can test for capital `R':
1488     (if (setq switches-have-R (and switches (string-match "R" switches)))
1489         ;; avoid duplicated subdirs
1490         (setq mark-alist (dired-kill-tree dirname t)))
1491     (if elt
1492         ;; If subdir is already present, remove it and remember its marks
1493         (setq mark-alist (nconc (dired-insert-subdir-del elt) mark-alist))
1494       (dired-insert-subdir-newpos dirname)) ; else compute new position
1495     (dired-insert-subdir-doupdate
1496      dirname elt (dired-insert-subdir-doinsert dirname switches))
1497     (if switches-have-R (dired-build-subdir-alist))
1498     (dired-initial-position dirname)
1499     (save-excursion (dired-mark-remembered mark-alist))))
1500
1501 ;; This is a separate function for dired-vms.
1502 (defun dired-insert-subdir-validate (dirname &optional switches)
1503   ;; Check that it is valid to insert DIRNAME with SWITCHES.
1504   ;; Signal an error if invalid (e.g. user typed `i' on `..').
1505   (or (dired-in-this-tree dirname (expand-file-name default-directory))
1506       (error  "%s: not in this directory tree" dirname))
1507   (if switches
1508       (let (case-fold-search)
1509         (mapcar
1510          (function
1511           (lambda (x)
1512             (or (eq (null (string-match x switches))
1513                     (null (string-match x dired-actual-switches)))
1514                 (error "Can't have dirs with and without -%s switches together"
1515                        x))))
1516          ;; all switches that make a difference to dired-get-filename:
1517          '("F" "b")))))
1518
1519 (defun dired-alist-add (dir new-marker)
1520   ;; Add new DIR at NEW-MARKER.  Sort alist.
1521   (dired-alist-add-1 dir new-marker)
1522   (dired-alist-sort))
1523
1524 (defun dired-alist-sort ()
1525   ;; Keep the alist sorted on buffer position.
1526   (setq dired-subdir-alist
1527         (sort dired-subdir-alist
1528               (function (lambda (elt1 elt2)
1529                           (> (dired-get-subdir-min elt1)
1530                              (dired-get-subdir-min elt2)))))))
1531
1532 (defun dired-kill-tree (dirname &optional remember-marks)
1533   ;;"Kill all proper subdirs of DIRNAME, excluding DIRNAME itself.
1534   ;; With optional arg REMEMBER-MARKS, return an alist of marked files."
1535   (interactive "DKill tree below directory: ")
1536   (let ((s-alist dired-subdir-alist) dir m-alist)
1537     (while s-alist
1538       (setq dir (car (car s-alist))
1539             s-alist (cdr s-alist))
1540       (if (and (not (string-equal dir dirname))
1541                (dired-in-this-tree dir dirname)
1542                (dired-goto-subdir dir))
1543           (setq m-alist (nconc (dired-kill-subdir remember-marks) m-alist))))
1544     m-alist))
1545
1546 (defun dired-insert-subdir-newpos (new-dir)
1547   ;; Find pos for new subdir, according to tree order.
1548   ;;(goto-char (point-max))
1549   (let ((alist dired-subdir-alist) elt dir pos new-pos)
1550     (while alist
1551       (setq elt (car alist)
1552             alist (cdr alist)
1553             dir (car elt)
1554             pos (dired-get-subdir-min elt))
1555       (if (dired-tree-lessp dir new-dir)
1556           ;; Insert NEW-DIR after DIR
1557           (setq new-pos (dired-get-subdir-max elt)
1558                 alist nil)))
1559     (goto-char new-pos))
1560   ;; want a separating newline between subdirs
1561   (or (eobp)
1562       (forward-line -1))
1563   (insert "\n")
1564   (point))
1565
1566 (defun dired-insert-subdir-del (element)
1567   ;; Erase an already present subdir (given by ELEMENT) from buffer.
1568   ;; Move to that buffer position.  Return a mark-alist.
1569   (let ((begin-marker (dired-get-subdir-min element)))
1570     (goto-char begin-marker)
1571     ;; Are at beginning of subdir (and inside it!).  Now determine its end:
1572     (goto-char (dired-subdir-max))
1573     (or (eobp);; want a separating newline _between_ subdirs:
1574         (forward-char -1))
1575     (prog1
1576         (dired-remember-marks begin-marker (point))
1577       (delete-region begin-marker (point)))))
1578
1579 (defun dired-insert-subdir-doinsert (dirname switches)
1580   ;; Insert ls output after point and put point on the correct
1581   ;; position for the subdir alist.
1582   ;; Return the boundary of the inserted text (as list of BEG and END).
1583   (let ((begin (point)) end)
1584     (message "Reading directory %s..." dirname)
1585     (let ((dired-actual-switches
1586            (or switches
1587                (dired-replace-in-string "R" "" dired-actual-switches))))
1588       (if (equal dirname (car (car (reverse dired-subdir-alist))))
1589           ;; top level directory may contain wildcards:
1590           (dired-readin-insert dired-directory)
1591         (let ((opoint (point)))
1592           (insert-directory dirname dired-actual-switches nil t)
1593           (dired-insert-set-properties opoint (point)))))
1594     (message "Reading directory %s...done" dirname)
1595     (setq end (point-marker))
1596     (indent-rigidly begin end 2)
1597     ;;  call dired-insert-headerline afterwards, as under VMS dired-ls
1598     ;;  does insert the headerline itself and the insert function just
1599     ;;  moves point.
1600     ;;  Need a marker for END as this inserts text.
1601     (goto-char begin)
1602     (dired-insert-headerline dirname)
1603     ;; point is now like in dired-build-subdir-alist
1604     (prog1
1605         (list begin (marker-position end))
1606       (set-marker end nil))))
1607
1608 (defun dired-insert-subdir-doupdate (dirname elt beg-end)
1609   ;; Point is at the correct subdir alist position for ELT,
1610   ;; BEG-END is the subdir-region (as list of begin and end).
1611   (if elt                               ; subdir was already present
1612       ;; update its position (should actually be unchanged)
1613       (set-marker (dired-get-subdir-min elt) (point-marker))
1614     (dired-alist-add dirname (point-marker)))
1615   ;; The hook may depend on the subdir-alist containing the just
1616   ;; inserted subdir, so run it after dired-alist-add:
1617   (if dired-after-readin-hook
1618       (save-excursion
1619         (let ((begin (nth 0 beg-end))
1620               (end (nth 1 beg-end)))
1621           (goto-char begin)
1622           (save-restriction
1623             (narrow-to-region begin end)
1624             ;; hook may add or delete lines, but the subdir boundary
1625             ;; marker floats
1626             (run-hooks 'dired-after-readin-hook))))))
1627
1628 (defun dired-tree-lessp (dir1 dir2)
1629   ;; Lexicographic order on pathname components, like `ls -lR':
1630   ;; DIR1 < DIR2 iff DIR1 comes *before* DIR2 in an `ls -lR' listing,
1631   ;;   i.e., iff DIR1 is a (grand)parent dir of DIR2,
1632   ;;   or DIR1 and DIR2 are in the same parentdir and their last
1633   ;;   components are string-lessp.
1634   ;; Thus ("/usr/" "/usr/bin") and ("/usr/a/" "/usr/b/") are tree-lessp.
1635   ;; string-lessp could arguably be replaced by file-newer-than-file-p
1636   ;;   if dired-actual-switches contained `t'.
1637   (setq dir1 (file-name-as-directory dir1)
1638         dir2 (file-name-as-directory dir2))
1639   (let ((components-1 (dired-split "/" dir1))
1640         (components-2 (dired-split "/" dir2)))
1641     (while (and components-1
1642                 components-2
1643                 (equal (car components-1) (car components-2)))
1644       (setq components-1 (cdr components-1)
1645             components-2 (cdr components-2)))
1646     (let ((c1 (car components-1))
1647           (c2 (car components-2)))
1648
1649       (cond ((and c1 c2)
1650              (string-lessp c1 c2))
1651             ((and (null c1) (null c2))
1652              nil)                       ; they are equal, not lessp
1653             ((null c1)                  ; c2 is a subdir of c1: c1<c2
1654              t)
1655             ((null c2)                  ; c1 is a subdir of c2: c1>c2
1656              nil)
1657             (t (error "This can't happen"))))))
1658
1659 ;; There should be a builtin split function - inverse to mapconcat.
1660 (defun dired-split (pat str &optional limit)
1661   "Splitting on regexp PAT, turn string STR into a list of substrings.
1662 Optional third arg LIMIT (>= 1) is a limit to the length of the
1663 resulting list.
1664 Thus, if SEP is a regexp that only matches itself,
1665
1666    (mapconcat 'identity (dired-split SEP STRING) SEP)
1667
1668 is always equal to STRING."
1669   (let* ((start (string-match pat str))
1670          (result (list (substring str 0 start)))
1671          (count 1)
1672          (end (if start (match-end 0))))
1673     (if end                             ; else nothing left
1674         (while (and (or (not (integerp limit))
1675                         (< count limit))
1676                     (string-match pat str end))
1677           (setq start (match-beginning 0)
1678                 count (1+ count)
1679                 result (cons (substring str end start) result)
1680                 end (match-end 0)
1681                 start end)
1682           ))
1683     (if (and (or (not (integerp limit))
1684                  (< count limit))
1685              end)                       ; else nothing left
1686         (setq result
1687               (cons (substring str end) result)))
1688     (nreverse result)))
1689 \f
1690 ;;; moving by subdirectories
1691
1692 ;;;###autoload
1693 (defun dired-prev-subdir (arg &optional no-error-if-not-found no-skip)
1694   "Go to previous subdirectory, regardless of level.
1695 When called interactively and not on a subdir line, go to this subdir's line."
1696   ;;(interactive "p")
1697   (interactive
1698    (list (if current-prefix-arg
1699              (prefix-numeric-value current-prefix-arg)
1700            ;; if on subdir start already, don't stay there!
1701            (if (dired-get-subdir) 1 0))))
1702   (dired-next-subdir (- arg) no-error-if-not-found no-skip))
1703
1704 (defun dired-subdir-min ()
1705   (save-excursion
1706     (if (not (dired-prev-subdir 0 t t))
1707         (error "Not in a subdir!")
1708       (point))))
1709
1710 ;;;###autoload
1711 (defun dired-goto-subdir (dir)
1712   "Go to end of header line of DIR in this dired buffer.
1713 Return value of point on success, otherwise return nil.
1714 The next char is either \\n, or \\r if DIR is hidden."
1715   (interactive
1716    (prog1                               ; let push-mark display its message
1717        (list (expand-file-name
1718               (completing-read "Goto in situ directory: " ; prompt
1719                                dired-subdir-alist ; table
1720                                nil      ; predicate
1721                                t        ; require-match
1722                                (dired-current-directory))))
1723      (push-mark)))
1724   (setq dir (file-name-as-directory dir))
1725   (let ((elt (assoc dir dired-subdir-alist)))
1726     (and elt
1727          (goto-char (dired-get-subdir-min elt))
1728          ;; dired-subdir-hidden-p and dired-add-entry depend on point being
1729          ;; at either \r or \n after this function succeeds.
1730          (progn (skip-chars-forward "^\r\n")
1731                 (point)))))
1732 \f
1733 ;;;###autoload
1734 (defun dired-mark-subdir-files ()
1735   "Mark all files except `.' and `..'."
1736   (interactive "P")
1737   (let ((p-min (dired-subdir-min)))
1738     (dired-mark-files-in-region p-min (dired-subdir-max))))
1739
1740 ;;;###autoload
1741 (defun dired-kill-subdir (&optional remember-marks)
1742   "Remove all lines of current subdirectory.
1743 Lower levels are unaffected."
1744   ;; With optional REMEMBER-MARKS, return a mark-alist.
1745   (interactive)
1746   (let ((beg (dired-subdir-min))
1747         (end (dired-subdir-max))
1748         buffer-read-only cur-dir)
1749     (setq cur-dir (dired-current-directory))
1750     (if (equal cur-dir default-directory)
1751         (error "Attempt to kill top level directory"))
1752     (prog1
1753         (if remember-marks (dired-remember-marks beg end))
1754       (delete-region beg end)
1755       (if (eobp)                        ; don't leave final blank line
1756           (delete-char -1))
1757       (dired-unsubdir cur-dir))))
1758
1759 (defun dired-unsubdir (dir)
1760   ;; Remove DIR from the alist
1761   (setq dired-subdir-alist
1762         (delq (assoc dir dired-subdir-alist) dired-subdir-alist)))
1763
1764 ;;;###autoload
1765 (defun dired-tree-up (arg)
1766   "Go up ARG levels in the dired tree."
1767   (interactive "p")
1768   (let ((dir (dired-current-directory)))
1769     (while (>= arg 1)
1770       (setq arg (1- arg)
1771             dir (file-name-directory (directory-file-name dir))))
1772     ;;(setq dir (expand-file-name dir))
1773     (or (dired-goto-subdir dir)
1774         (error "Cannot go up to %s - not in this tree." dir))))
1775
1776 ;;;###autoload
1777 (defun dired-tree-down ()
1778   "Go down in the dired tree."
1779   (interactive)
1780   (let ((dir (dired-current-directory)) ; has slash
1781         pos case-fold-search)           ; filenames are case sensitive
1782     (let ((rest (reverse dired-subdir-alist)) elt)
1783       (while rest
1784         (setq elt (car rest)
1785               rest (cdr rest))
1786         (if (dired-in-this-tree (directory-file-name (car elt)) dir)
1787             (setq rest nil
1788                   pos (dired-goto-subdir (car elt))))))
1789     (if pos
1790         (goto-char pos)
1791       (error "At the bottom"))))
1792 \f
1793 ;;; hiding
1794
1795 (defun dired-unhide-subdir ()
1796   (let (buffer-read-only)
1797     (subst-char-in-region (dired-subdir-min) (dired-subdir-max) ?\r ?\n)))
1798
1799 (defun dired-hide-check ()
1800   (or selective-display
1801       (error "selective-display must be t for subdir hiding to work!")))
1802
1803 (defun dired-subdir-hidden-p (dir)
1804   (and selective-display
1805        (save-excursion
1806          (dired-goto-subdir dir)
1807          (looking-at "\r"))))
1808
1809 ;;;###autoload
1810 (defun dired-hide-subdir (arg)
1811   "Hide or unhide the current subdirectory and move to next directory.
1812 Optional prefix arg is a repeat factor.
1813 Use \\[dired-hide-all] to (un)hide all directories."
1814   (interactive "p")
1815   (dired-hide-check)
1816   (while (>=  (setq arg (1- arg)) 0)
1817     (let* ((cur-dir (dired-current-directory))
1818            (hidden-p (dired-subdir-hidden-p cur-dir))
1819            (elt (assoc cur-dir dired-subdir-alist))
1820            (end-pos (1- (dired-get-subdir-max elt)))
1821            buffer-read-only)
1822       ;; keep header line visible, hide rest
1823       (goto-char (dired-get-subdir-min elt))
1824       (skip-chars-forward "^\n\r")
1825       (if hidden-p
1826           (subst-char-in-region (point) end-pos ?\r ?\n)
1827         (subst-char-in-region (point) end-pos ?\n ?\r)))
1828     (dired-next-subdir 1 t)))
1829
1830 ;;;###autoload
1831 (defun dired-hide-all (arg)
1832   "Hide all subdirectories, leaving only their header lines.
1833 If there is already something hidden, make everything visible again.
1834 Use \\[dired-hide-subdir] to (un)hide a particular subdirectory."
1835   (interactive "P")
1836   (dired-hide-check)
1837   (let (buffer-read-only)
1838     (if (save-excursion
1839           (goto-char (point-min))
1840           (search-forward "\r" nil t))
1841         ;; unhide - bombs on \r in filenames
1842         (subst-char-in-region (point-min) (point-max) ?\r ?\n)
1843       ;; hide
1844       (let ((pos (point-max))           ; pos of end of last directory
1845             (alist dired-subdir-alist))
1846         (while alist                    ; while there are dirs before pos
1847           (subst-char-in-region (dired-get-subdir-min (car alist)) ; pos of prev dir
1848                                 (save-excursion
1849                                   (goto-char pos) ; current dir
1850                                   ;; we're somewhere on current dir's line
1851                                   (forward-line -1)
1852                                   (point))
1853                                 ?\n ?\r)
1854           (setq pos (dired-get-subdir-min (car alist))) ; prev dir gets current dir
1855           (setq alist (cdr alist)))))))
1856
1857 ;;;###end dired-ins.el
1858
1859 ;;; dired-aux.el ends here